qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2
   3 #include <client/mutators/_mod.qh>
   4 #include <client/player_skeleton.qh>
   5 #include <client/weapons/projectile.qh>
   6 #include <common/animdecide.qh>
   7 #include <common/effects/all.inc>
   8 #include <common/effects/all.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/viewloc.qh>
  15 #include <lib/csqcmodel/cl_model.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17 #include <lib/csqcmodel/interpolate.qh>
  18
  19 .float death_time;
  20 .int modelflags;
  21
  22 // FEATURE: LOD
  23 .int lodmodelindex0;
  24 .int lodmodelindex1;
  25 .int lodmodelindex2;
  26 void CSQCPlayer_LOD_Apply(entity this)
  27 {
  28         // LOD model loading
  29         if(this.lodmodelindex0 != this.modelindex)
  30         {
  31                 string modelname = this.model;
  32                 string s;
  33
  34                 vector mi = this.mins;
  35                 vector ma = this.maxs;
  36
  37                 // set modelindex
  38                 this.lodmodelindex0 = this.modelindex;
  39                 this.lodmodelindex1 = this.modelindex;
  40                 this.lodmodelindex2 = this.modelindex;
  41
  42                 // FIXME: this only supports 3-letter extensions
  43                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  44                 if(fexists(s))
  45                 {
  46                         precache_model(s);
  47                         _setmodel(this, s);
  48                         if(this.modelindex)
  49                                 this.lodmodelindex1 = this.modelindex;
  50                 }
  51
  52                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  53                 if(fexists(s))
  54                 {
  55                         precache_model(s);
  56                         _setmodel(this, s);
  57                         if(this.modelindex)
  58                                 this.lodmodelindex2 = this.modelindex;
  59                 }
  60
  61                 _setmodel(this, modelname); // make everything normal again
  62                 setsize(this, mi, ma);
  63         }
  64
  65         // apply LOD
  66         if(autocvar_cl_playerdetailreduction <= 0)
  67         {
  68                 if(autocvar_cl_playerdetailreduction <= -2)
  69                         this.modelindex = this.lodmodelindex2;
  70                 else if(autocvar_cl_playerdetailreduction <= -1)
  71                         this.modelindex = this.lodmodelindex1;
  72                 else
  73                         this.modelindex = this.lodmodelindex0;
  74         }
  75         else
  76         {
  77                 float distance = vlen(this.origin - view_origin);
  78                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  79                 f *= 1.0 / bound(0.01, view_quality, 1);
  80                 if(f > autocvar_cl_loddistance2)
  81                         this.modelindex = this.lodmodelindex2;
  82                 else if(f > autocvar_cl_loddistance1)
  83                         this.modelindex = this.lodmodelindex1;
  84                 else
  85                         this.modelindex = this.lodmodelindex0;
  86         }
  87 }
  88
  89 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  90 string forceplayermodels_model;
  91 bool forceplayermodels_modelisgoodmodel;
  92 int forceplayermodels_modelindex;
  93 int forceplayermodels_skin;
  94
  95 string forceplayermodels_mymodel;
  96 bool forceplayermodels_myisgoodmodel;
  97 int forceplayermodels_mymodelindex;
  98
  99 bool forceplayermodels_attempted;
 100
 101 .string forceplayermodels_savemodel;
 102 .int forceplayermodels_savemodelindex;
 103 .int forceplayermodels_saveskin;
 104 .int forceplayermodels_savecolormap;
 105
 106 .string forceplayermodels_isgoodmodel_mdl;
 107 .bool forceplayermodels_isgoodmodel;
 108
 109 string forceplayermodels_goodmodel;
 110 int forceplayermodels_goodmodelindex;
 111
 112 .vector glowmod;
 113
 114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 115 {
 116         this.model = this.forceplayermodels_savemodel;
 117         this.modelindex = this.forceplayermodels_savemodelindex;
 118         this.skin = this.forceplayermodels_saveskin;
 119         this.colormap = this.forceplayermodels_savecolormap;
 120 }
 121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 122 {
 123         this.forceplayermodels_savemodel = this.model;
 124         this.forceplayermodels_savemodelindex = this.modelindex;
 125         this.forceplayermodels_saveskin = this.skin;
 126         this.forceplayermodels_savecolormap = this.colormap;
 127
 128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 129         {
 130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 132                 if(!this.forceplayermodels_isgoodmodel)
 133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 134         }
 135 }
 136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 137 {
 138         int cm = this.forceplayermodels_savecolormap;
 139         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 140
 141         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 142                 goto skipforcemodels;
 143
 144         // FORCEMODEL
 145         // which one is ALWAYS good?
 146         if (!forceplayermodels_goodmodel)
 147         {
 148                 entity e = spawn();
 149                 precache_model(cvar_defstring("_cl_playermodel"));
 150                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 151                 forceplayermodels_goodmodel = e.model;
 152                 forceplayermodels_goodmodelindex = e.modelindex;
 153                 delete(e);
 154         }
 155
 156         // first, try finding it from the server
 157         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 158         {
 159                 if(islocalplayer)
 160                 {
 161                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 162                         {
 163                                 // trust server's idea of "own player model"
 164                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 165                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 166                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 167                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 168                                 forceplayermodels_attempted = 1;
 169                         }
 170                 }
 171         }
 172
 173         // forcemodel finding
 174         if(!forceplayermodels_attempted)
 175         {
 176                 forceplayermodels_attempted = 1;
 177
 178                 // only if this failed, find it out on our own
 179                 entity e = spawn();
 180                 precache_model(autocvar__cl_playermodel);
 181                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 182                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 183                 forceplayermodels_model = e.model;
 184                 forceplayermodels_modelindex = e.modelindex;
 185                 forceplayermodels_skin = autocvar__cl_playerskin;
 186                 delete(e);
 187         }
 188
 189         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 190         {
 191                 entity e = spawn();
 192                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 193                 forceplayermodels_myisgoodmodel = fexists(e.model);
 194                 forceplayermodels_mymodel = e.model;
 195                 forceplayermodels_mymodelindex = e.modelindex;
 196                 delete(e);
 197         }
 198
 199         // apply it
 200         bool isfriend;
 201
 202         if(teamplay)
 203                 isfriend = (cm == 1024 + 17 * myteam);
 204         else
 205                 isfriend = islocalplayer;
 206
 207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 208         {
 209                 this.model = forceplayermodels_mymodel;
 210                 this.modelindex = forceplayermodels_mymodelindex;
 211                 this.skin = autocvar_cl_forcemyplayerskin;
 212         }
 213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 214         {
 215                 this.model = forceplayermodels_model;
 216                 this.modelindex = forceplayermodels_modelindex;
 217                 this.skin = forceplayermodels_skin;
 218         }
 219         else if(this.forceplayermodels_isgoodmodel)
 220         {
 221                 this.model = this.forceplayermodels_savemodel;
 222                 this.modelindex = this.forceplayermodels_savemodelindex;
 223                 this.skin = this.forceplayermodels_saveskin;
 224         }
 225         else
 226         {
 227                 this.model = forceplayermodels_goodmodel;
 228                 this.modelindex = forceplayermodels_goodmodelindex;
 229                 this.skin = this.forceplayermodels_saveskin;
 230         }
 231
 232         LABEL(skipforcemodels)
 233
 234         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
 235                 goto skipforcecolors;
 236
 237         // forceplayercolors too
 238         if(teamplay)
 239         {
 240                 // own team's color is never forced
 241                 int forcecolor_friend = 0;
 242                 int forcecolor_enemy = 0;
 243                 entity tm;
 244
 245                 if(autocvar_cl_forcemyplayercolors)
 246                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 247                 if(autocvar_cl_forceplayercolors != 3 && autocvar_cl_forceplayercolors == 2 && team_count == 2)
 248                         forcecolor_enemy = 1024 + autocvar__cl_color;
 249
 250                 if(forcecolor_enemy && !forcecolor_friend)
 251                 {
 252                         // only enemy color is forced?
 253                         // verify it is not equal to the friend color
 254                         if(forcecolor_enemy == 1024 + 17 * myteam)
 255                                 forcecolor_enemy = 0;
 256                 }
 257
 258                 if(forcecolor_friend && !forcecolor_enemy)
 259                 {
 260                         // only friend color is forced?
 261                         // verify it is not equal to the enemy color
 262                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 263                                 // note: we even compare against our own team.
 264                                 // if we rejected because we matched our OWN team color,
 265                                 // this is not bad; we then simply keep our color as is
 266                                 // anyway.
 267                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 268                                         forcecolor_friend = 0;
 269                 }
 270
 271                 if(cm == 1024 + 17 * myteam)
 272                 {
 273                         if(forcecolor_friend)
 274                                 this.colormap = forcecolor_friend;
 275                 }
 276                 else
 277                 {
 278                         if(forcecolor_enemy)
 279                                 this.colormap = forcecolor_enemy;
 280                 }
 281         }
 282         else
 283         {
 284                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 285                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 286                 else if(autocvar_cl_forceplayercolors && (autocvar_cl_forceplayercolors != 3 || ISGAMETYPE(DUEL)))
 287                         this.colormap = player_localnum + 1;
 288         }
 289
 290         LABEL(skipforcecolors)
 291
 292         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
 293         {
 294                 this.glowmod = '0 0 0';
 295                 this.colormap = 0;
 296                 return;
 297         }
 298
 299         // GLOWMOD AND DEATH FADING
 300         if(this.colormap > 0)
 301                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
 302         else
 303                 this.glowmod = '1 1 1';
 304
 305         if(autocvar_cl_deathglow > 0)
 306         {
 307                 if(this.csqcmodel_isdead)
 308                 {
 309                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 310                         if(this.colormap > 0)
 311                                 min_factor /= 2;
 312                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 313                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 314                         if (this.glowmod == '0 0 0')
 315                                 this.glowmod.x = 0.000001;
 316                 }
 317         }
 318
 319         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 320 }
 321
 322 // FEATURE: fallback frames
 323 .int csqcmodel_saveframe;
 324 .int csqcmodel_saveframe2;
 325 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 326 .int csqcmodel_saveframe3;
 327 .int csqcmodel_saveframe4;
 328 #endif
 329 .int csqcmodel_framecount;
 330
 331 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 332 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 333 {
 334         this.frame = this.csqcmodel_saveframe;
 335         this.frame2 = this.csqcmodel_saveframe2;
 336 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 337         this.frame3 = this.csqcmodel_saveframe3;
 338         this.frame4 = this.csqcmodel_saveframe4;
 339 #endif
 340 }
 341 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 342 {
 343         this.csqcmodel_saveframe = this.frame;
 344         this.csqcmodel_saveframe2 = this.frame2;
 345 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 346         this.csqcmodel_saveframe3 = this.frame3;
 347         this.csqcmodel_saveframe4 = this.frame4;
 348 #endif
 349
 350         // hack for death animations: set their frametime to zero in case a
 351         // player "pops in"
 352         if(isnew)
 353         {
 354 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 355                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 356                         this.ft = this.death_time; \
 357 MACRO_END
 358                 FIX_FRAMETIME(frame, frame1time);
 359                 FIX_FRAMETIME(frame2, frame2time);
 360 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 361                 FIX_FRAMETIME(frame3, frame3time);
 362                 FIX_FRAMETIME(frame4, frame4time);
 363 #endif
 364         }
 365         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 366 }
 367 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 368 {
 369         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 370 }
 371 int CSQCPlayer_FallbackFrame(entity this, int f)
 372 {
 373         TC(int, f);
 374         if(frameduration(this.modelindex, f) > 0)
 375                 return f; // goooooood
 376         if(frameduration(this.modelindex, 1) <= 0)
 377                 return f; // this is a static model. We can't fix it if we wanted to
 378         switch(f)
 379         {
 380                 case 23: return 11; // anim_melee -> anim_shoot
 381                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 382                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 383                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 384                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 385                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 386                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 387                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 388         }
 389         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 390         return f;
 391 }
 392 void CSQCPlayer_FallbackFrame_Apply(entity this)
 393 {
 394         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 395         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 396 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 397         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 398         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 399 #endif
 400 }
 401
 402 // FEATURE: auto tag_index
 403 .entity tag_entity;
 404 .int tag_entity_lastmodelindex;
 405 .int tag_index;
 406 void CSQCModel_AutoTagIndex_Apply(entity this)
 407 {
 408         if(this.tag_entity && wasfreed(this.tag_entity))
 409                 this.tag_entity = NULL;
 410
 411         MUTATOR_CALLHOOK(TagIndex_Update, this);
 412
 413         if(this.tag_networkentity)
 414         {
 415                 // we are ATTACHED!
 416                 bool changed = 0;
 417                 if(this.tag_entity.entnum != this.tag_networkentity)
 418                 {
 419                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 420                         changed = 1;
 421                 }
 422
 423                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 424                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
 425                 {
 426                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 427                 }
 428
 429                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 430                 {
 431                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 432                         changed = 1;
 433                 }
 434                 if(changed)
 435                 {
 436                         if(this.tag_entity)
 437                         {
 438                                 // the best part is: IT EXISTS
 439                                 if(substring(this.model, 0, 14) == "models/weapons")
 440                                 {
 441                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 442                                         {
 443                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 444                                                 if(!this.tag_index)
 445                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 446                                                 if(!this.tag_index)
 447                                                 {
 448                                                         // we need to prevent this from 'appening
 449                                                         this.tag_entity = NULL;
 450                                                         this.drawmask = 0;
 451                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 452                                                 }
 453                                         }
 454                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 455                                         {
 456                                                 skeleton_loadinfo(this.tag_entity);
 457                                                 this.tag_index = this.tag_entity.bone_weapon;
 458                                         }
 459                                 }
 460
 461                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 462                                 {
 463                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 464                                         if(!this.tag_index)
 465                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 466                                 }
 467
 468                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 469                         }
 470                         else
 471                         {
 472                                 // damn, see you next frame
 473                                 this.drawmask = 0;
 474                         }
 475                 }
 476         }
 477 }
 478
 479 void CSQCModel_Effects_PreUpdate(entity this)
 480 {
 481         this.effects = this.csqcmodel_effects;
 482         this.modelflags = this.csqcmodel_modelflags;
 483         this.traileffect = this.csqcmodel_traileffect;
 484 }
 485 void Reset_ArcBeam();
 486 void CSQCModel_Effects_PostUpdate(entity this)
 487 {
 488         if (this == csqcplayer) {
 489                 if (this.csqcmodel_teleported) {
 490                         Reset_ArcBeam();
 491                 }
 492         }
 493         this.csqcmodel_effects = this.effects;
 494         this.csqcmodel_modelflags = this.modelflags;
 495         this.csqcmodel_traileffect = this.traileffect;
 496         this.effects = 0;
 497         this.modelflags = 0;
 498         if(this.csqcmodel_teleported)
 499                 Projectile_ResetTrail(this, this.origin);
 500 }
 501 .int snd_looping;
 502 void CSQCModel_Effects_Apply(entity this)
 503 {
 504         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 505         int tref = this.csqcmodel_traileffect;
 506
 507         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 508         this.effects = 0;
 509         this.traileffect = 0;
 510
 511         if(eff & EF_BRIGHTFIELD)
 512                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 513         // ignoring EF_MUZZLEFLASH
 514         if(eff & EF_BRIGHTLIGHT)
 515                 adddynamiclight(this.origin, 400, '3 3 3');
 516         if(eff & EF_DIMLIGHT)
 517                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 518         if((eff & EF_NODRAW) || (this.alpha < 0))
 519                 this.drawmask = 0;
 520         if(eff & EF_ADDITIVE)
 521                 this.renderflags |= RF_ADDITIVE;
 522         if(eff & EF_BLUE)
 523                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 524         if(eff & EF_RED)
 525                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 526         // ignoring EF_NOGUNBOB
 527         if(eff & EF_FULLBRIGHT)
 528                 this.renderflags |= RF_FULLBRIGHT;
 529         if(eff & EF_FLAME)
 530         {
 531                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 532                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 533         }
 534         if(eff & EF_STARDUST)
 535         {
 536                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 537                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 538         }
 539         if(eff & EF_NOSHADOW)
 540                 this.renderflags |= RF_NOSHADOW;
 541         if(eff & EF_NODEPTHTEST)
 542                 this.renderflags |= RF_DEPTHHACK;
 543         // ignoring EF_SELECTABLE
 544         if(eff & EF_DOUBLESIDED)
 545                 this.effects |= EF_DOUBLESIDED;
 546         if(eff & EF_NOSELFSHADOW)
 547                 this.effects |= EF_NOSELFSHADOW;
 548         if(eff & EF_DYNAMICMODELLIGHT)
 549                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 550         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 551         if(this.csqcmodel_modelflags & MF_ROCKET)
 552                 tref = EFFECT_TR_ROCKET.m_id;
 553         if(this.csqcmodel_modelflags & MF_GRENADE)
 554                 tref = EFFECT_TR_GRENADE.m_id;
 555         if(this.csqcmodel_modelflags & MF_GIB)
 556                 tref = EFFECT_TR_BLOOD.m_id;
 557         if(this.csqcmodel_modelflags & MF_ROTATE)
 558         {
 559                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 560                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 561                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 562                 this.renderflags |= RF_USEAXIS;
 563                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 564         }
 565         if(this.csqcmodel_modelflags & MF_TRACER)
 566                 tref = EFFECT_TR_WIZSPIKE.m_id;
 567         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 568                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 569         if(this.csqcmodel_modelflags & MF_TRACER2)
 570                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 571         if(this.csqcmodel_modelflags & MF_TRACER3)
 572                 tref = EFFECT_TR_VORESPIKE.m_id;
 573
 574         this.traileffect = tref;
 575
 576         if(this.drawmask)
 577                 Projectile_DrawTrail(this, this.origin);
 578         else
 579                 Projectile_ResetTrail(this, this.origin);
 580
 581         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 582                 this.renderflags |= RF_ADDITIVE;
 583                 // also special in CSQCPlayer_GlowMod_Apply
 584
 585         if(this.csqcmodel_modelflags & MF_ROCKET)
 586         {
 587                 if(!this.snd_looping)
 588                 {
 589                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 590                         this.snd_looping = CH_TRIGGER_SINGLE;
 591                 }
 592         }
 593         else
 594         {
 595                 if(this.snd_looping)
 596                 {
 597                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 598                         this.snd_looping = 0;
 599                 }
 600         }
 601 }
 602
 603 // general functions
 604 .int csqcmodel_predraw_run;
 605 .int anim_frame;
 606 .int anim_frame1time;
 607 .int anim_frame2;
 608 .int anim_frame2time;
 609 .int anim_saveframe;
 610 .int anim_saveframe1time;
 611 .int anim_saveframe2;
 612 .int anim_saveframe2time;
 613 .int anim_prev_pmove_flags;
 614 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 615 {
 616         if(this.csqcmodel_predraw_run == framecount)
 617                 return;
 618         this.csqcmodel_predraw_run = framecount;
 619
 620         if(!this.modelindex || this.model == "null")
 621         {
 622                 this.drawmask = 0;
 623                 if(this.snd_looping > 0)
 624                 {
 625                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 626                         this.snd_looping = 0;
 627                 }
 628                 return;
 629         }
 630         else
 631                 this.drawmask = MASK_NORMAL;
 632
 633         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 634         {
 635                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 636                 CSQCPlayer_LOD_Apply(this);
 637
 638                 if(!isplayer)
 639                 {
 640                         skeleton_loadinfo(this);
 641                         bool doblend = (this.bone_upperbody >= 0);
 642                         CSQCPlayer_FallbackFrame_Apply(this);
 643                         if(doblend)
 644                         {
 645                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 646                         }
 647                         else
 648                         {
 649                                 free_skeleton_from_frames(this);
 650                                 // just in case, clear these (we're animating in frame and frame3)
 651                                 this.lerpfrac = 0;
 652                                 this.lerpfrac4 = 0;
 653                         }
 654                 }
 655                 else
 656                 {
 657                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 658                         skeleton_loadinfo(this);
 659                         bool doblend = (this.bone_upperbody >= 0);
 660                         bool onground = 0;
 661                         if(this == csqcplayer)
 662                         {
 663                                 if(IS_ONGROUND(this))
 664                                         onground = 1;
 665                                 this.anim_prev_pmove_flags = this.flags;
 666                                 if(this.flags & FL_DUCKED)
 667                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 668                                 else if(this.anim_state & ANIMSTATE_DUCK)
 669                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 670                         }
 671                         else
 672                         {
 673                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 674                                 if(trace_startsolid || trace_fraction < 1)
 675                                         onground = 1;
 676                                 // predicted clients handle smoothing in the prediction code
 677                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
 678                         }
 679                         animdecide_load_if_needed(this);
 680                         animdecide_setimplicitstate(this, onground);
 681                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 682                         int sf = 0;
 683                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 684                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 685                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 686                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 687                         this.anim_saveframe = this.anim_frame;
 688                         this.anim_saveframe1time = this.anim_frame1time;
 689                         this.anim_saveframe2 = this.anim_frame2;
 690                         this.anim_saveframe2time = this.anim_frame2time;
 691                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 692                         // This ensures that .frame etc. are always written.
 693                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 694                         this.lerpfrac = (doblend ? 0.5 : 0);
 695                         this.frame = this.anim_frame;
 696                         this.frame1time = this.anim_frame1time;
 697                         this.frame2 = this.anim_frame2;
 698                         this.frame2time = this.anim_frame2time;
 699                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 700                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 701                         if(doblend)
 702                         {
 703                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 704                         }
 705                         else
 706                         {
 707                                 free_skeleton_from_frames(this);
 708                                 // just in case, clear these (we're animating in frame and frame3)
 709                                 this.lerpfrac = 0;
 710                                 this.lerpfrac4 = 0;
 711                         }
 712                 }
 713         }
 714
 715         CSQCModel_AutoTagIndex_Apply(this);
 716
 717         CSQCModel_Effects_Apply(this);
 718 }
 719
 720 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 721 {
 722         // interpolate v_angle
 723         this.iflags |= IFLAG_V_ANGLE_X;
 724         // revert to values from server
 725         CSQCModel_Effects_PreUpdate(this);
 726         if((this.isplayermodel & ISPLAYER_MODEL))
 727         {
 728                 if(!isplayer)
 729                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 730                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 731         }
 732 }
 733
 734 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 735 {
 736         // is it a player model? (shared state)
 737         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 738                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 739         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 740         this.csqcmodel_isdead = false; // workaround for dead players who become a spectator
 741
 742         // save values set by server
 743         if((this.isplayermodel & ISPLAYER_MODEL))
 744         {
 745                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 746                 if(isplayer)
 747                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 748                 else
 749                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 750         }
 751         CSQCModel_Effects_PostUpdate(this);
 752 }