qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2
   3 #include <client/mutators/_mod.qh>
   4 #include <client/player_skeleton.qh>
   5 #include <client/weapons/projectile.qh>
   6 #include <common/animdecide.qh>
   7 #include <common/effects/all.inc>
   8 #include <common/effects/all.qh>
   9 #include <common/ent_cs.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/viewloc.qh>
  15 #include <lib/csqcmodel/cl_model.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17 #include <lib/csqcmodel/interpolate.qh>
  18
  19 .float death_time;
  20 .int modelflags;
  21
  22 // FEATURE: LOD
  23 .int lodmodelindex0;
  24 .int lodmodelindex1;
  25 .int lodmodelindex2;
  26 void CSQCPlayer_LOD_Apply(entity this)
  27 {
  28         // LOD model loading
  29         if(this.lodmodelindex0 != this.modelindex)
  30         {
  31                 string modelname = this.model;
  32                 string s;
  33
  34                 vector mi = this.mins;
  35                 vector ma = this.maxs;
  36
  37                 // set modelindex
  38                 this.lodmodelindex0 = this.modelindex;
  39                 this.lodmodelindex1 = this.modelindex;
  40                 this.lodmodelindex2 = this.modelindex;
  41
  42                 // FIXME: this only supports 3-letter extensions
  43                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  44                 if(fexists(s))
  45                 {
  46                         precache_model(s);
  47                         _setmodel(this, s);
  48                         if(this.modelindex)
  49                                 this.lodmodelindex1 = this.modelindex;
  50                 }
  51
  52                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  53                 if(fexists(s))
  54                 {
  55                         precache_model(s);
  56                         _setmodel(this, s);
  57                         if(this.modelindex)
  58                                 this.lodmodelindex2 = this.modelindex;
  59                 }
  60
  61                 _setmodel(this, modelname); // make everything normal again
  62                 setsize(this, mi, ma);
  63         }
  64
  65         // apply LOD
  66         if(autocvar_cl_playerdetailreduction <= 0)
  67         {
  68                 if(autocvar_cl_playerdetailreduction <= -2)
  69                         this.modelindex = this.lodmodelindex2;
  70                 else if(autocvar_cl_playerdetailreduction <= -1)
  71                         this.modelindex = this.lodmodelindex1;
  72                 else
  73                         this.modelindex = this.lodmodelindex0;
  74         }
  75         else
  76         {
  77                 float distance = vlen(this.origin - view_origin);
  78                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  79                 f *= 1.0 / bound(0.01, view_quality, 1);
  80                 if(f > autocvar_cl_loddistance2)
  81                         this.modelindex = this.lodmodelindex2;
  82                 else if(f > autocvar_cl_loddistance1)
  83                         this.modelindex = this.lodmodelindex1;
  84                 else
  85                         this.modelindex = this.lodmodelindex0;
  86         }
  87 }
  88
  89 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  90 string forceplayermodels_model;
  91 bool forceplayermodels_modelisgoodmodel;
  92 int forceplayermodels_modelindex;
  93 int forceplayermodels_skin;
  94
  95 string forceplayermodels_mymodel;
  96 bool forceplayermodels_myisgoodmodel;
  97 int forceplayermodels_mymodelindex;
  98
  99 bool forceplayermodels_attempted;
 100
 101 .string forceplayermodels_savemodel;
 102 .int forceplayermodels_savemodelindex;
 103 .int forceplayermodels_saveskin;
 104 .int forceplayermodels_savecolormap;
 105
 106 .string forceplayermodels_isgoodmodel_mdl;
 107 .bool forceplayermodels_isgoodmodel;
 108
 109 string forceplayermodels_goodmodel;
 110 int forceplayermodels_goodmodelindex;
 111
 112 .vector glowmod;
 113
 114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 115 {
 116         this.model = this.forceplayermodels_savemodel;
 117         this.modelindex = this.forceplayermodels_savemodelindex;
 118         this.skin = this.forceplayermodels_saveskin;
 119         this.colormap = this.forceplayermodels_savecolormap;
 120 }
 121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 122 {
 123         this.forceplayermodels_savemodel = this.model;
 124         this.forceplayermodels_savemodelindex = this.modelindex;
 125         this.forceplayermodels_saveskin = this.skin;
 126         this.forceplayermodels_savecolormap = this.colormap;
 127
 128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 129         {
 130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 132                 if(!this.forceplayermodels_isgoodmodel)
 133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 134         }
 135 }
 136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 137 {
 138         int cm = this.forceplayermodels_savecolormap;
 139         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 140
 141         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 142                 goto skipforcemodels;
 143
 144         // FORCEMODEL
 145         // which one is ALWAYS good?
 146         if (!forceplayermodels_goodmodel)
 147         {
 148                 entity e = spawn();
 149                 precache_model(cvar_defstring("_cl_playermodel"));
 150                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 151                 forceplayermodels_goodmodel = e.model;
 152                 forceplayermodels_goodmodelindex = e.modelindex;
 153                 delete(e);
 154         }
 155
 156         // first, try finding it from the server
 157         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 158         {
 159                 if(islocalplayer)
 160                 {
 161                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 162                         {
 163                                 // trust server's idea of "own player model"
 164                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 165                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 166                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 167                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 168                                 forceplayermodels_attempted = 1;
 169                         }
 170                 }
 171         }
 172
 173         // forcemodel finding
 174         if(!forceplayermodels_attempted)
 175         {
 176                 forceplayermodels_attempted = 1;
 177
 178                 // only if this failed, find it out on our own
 179                 entity e = spawn();
 180                 precache_model(autocvar__cl_playermodel);
 181                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 182                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 183                 forceplayermodels_model = e.model;
 184                 forceplayermodels_modelindex = e.modelindex;
 185                 forceplayermodels_skin = autocvar__cl_playerskin;
 186                 delete(e);
 187         }
 188
 189         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 190         {
 191                 entity e = spawn();
 192                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 193                 forceplayermodels_myisgoodmodel = fexists(e.model);
 194                 forceplayermodels_mymodel = e.model;
 195                 forceplayermodels_mymodelindex = e.modelindex;
 196                 delete(e);
 197         }
 198
 199         // apply it
 200         bool isfriend;
 201
 202         if(teamplay)
 203                 isfriend = (cm == 1024 + 17 * myteam);
 204         else
 205                 isfriend = islocalplayer;
 206
 207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 208         {
 209                 this.model = forceplayermodels_mymodel;
 210                 this.modelindex = forceplayermodels_mymodelindex;
 211                 this.skin = autocvar_cl_forcemyplayerskin;
 212         }
 213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 214         {
 215                 this.model = forceplayermodels_model;
 216                 this.modelindex = forceplayermodels_modelindex;
 217                 this.skin = forceplayermodels_skin;
 218         }
 219         else if(this.forceplayermodels_isgoodmodel)
 220         {
 221                 this.model = this.forceplayermodels_savemodel;
 222                 this.modelindex = this.forceplayermodels_savemodelindex;
 223                 this.skin = this.forceplayermodels_saveskin;
 224         }
 225         else
 226         {
 227                 this.model = forceplayermodels_goodmodel;
 228                 this.modelindex = forceplayermodels_goodmodelindex;
 229                 this.skin = this.forceplayermodels_saveskin;
 230         }
 231
 232         LABEL(skipforcemodels)
 233
 234         if(MUTATOR_CALLHOOK(ForcePlayercolors_Skip, this, islocalplayer))
 235                 goto skipforcecolors;
 236
 237         // forceplayercolors too
 238         if(teamplay)
 239         {
 240                 // own team's color is never forced
 241                 int forcecolor_friend = 0;
 242                 int forcecolor_enemy = 0;
 243                 entity tm;
 244
 245                 if(autocvar_cl_forcemyplayercolors)
 246                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 247                 if((autocvar_cl_forceplayercolors == 2 && team_count == 2)
 248                         || (autocvar_cl_forceplayercolors == 3 && IS_GAMETYPE(DUEL)))
 249                         forcecolor_enemy = 1024 + autocvar__cl_color;
 250
 251                 if(forcecolor_enemy && !forcecolor_friend)
 252                 {
 253                         // only enemy color is forced?
 254                         // verify it is not equal to the friend color
 255                         if(forcecolor_enemy == 1024 + 17 * myteam)
 256                                 forcecolor_enemy = 0;
 257                 }
 258
 259                 if(forcecolor_friend && !forcecolor_enemy)
 260                 {
 261                         // only friend color is forced?
 262                         // verify it is not equal to the enemy color
 263                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 264                                 // note: we even compare against our own team.
 265                                 // if we rejected because we matched our OWN team color,
 266                                 // this is not bad; we then simply keep our color as is
 267                                 // anyway.
 268                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 269                                         forcecolor_friend = 0;
 270                 }
 271
 272                 if(cm == 1024 + 17 * myteam)
 273                 {
 274                         if(forcecolor_friend)
 275                                 this.colormap = forcecolor_friend;
 276                 }
 277                 else
 278                 {
 279                         if(forcecolor_enemy)
 280                                 this.colormap = forcecolor_enemy;
 281                 }
 282         }
 283         else
 284         {
 285                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 286                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 287                 else if(autocvar_cl_forceplayercolors)
 288                         this.colormap = player_localnum + 1;
 289         }
 290
 291         LABEL(skipforcecolors)
 292
 293         if((this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST) && !autocvar_cl_respawn_ghosts_keepcolors)
 294         {
 295                 this.glowmod = '0 0 0';
 296                 this.colormap = 0;
 297                 return;
 298         }
 299
 300         // GLOWMOD AND DEATH FADING
 301         if(this.colormap > 0)
 302                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true);
 303         else
 304                 this.glowmod = '1 1 1';
 305
 306         if(autocvar_cl_deathglow > 0)
 307         {
 308                 if(this.csqcmodel_isdead)
 309                 {
 310                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 311                         if(this.colormap > 0)
 312                                 min_factor /= 2;
 313                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 314                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 315                         if (this.glowmod == '0 0 0')
 316                                 this.glowmod.x = 0.000001;
 317                 }
 318         }
 319
 320         // don't let the engine increase player's glowmod
 321         if (autocvar_r_hdr_glowintensity > 1)
 322                 this.glowmod /= autocvar_r_hdr_glowintensity;
 323
 324         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 325 }
 326
 327 // FEATURE: fallback frames
 328 .int csqcmodel_saveframe;
 329 .int csqcmodel_saveframe2;
 330 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 331 .int csqcmodel_saveframe3;
 332 .int csqcmodel_saveframe4;
 333 #endif
 334 .int csqcmodel_framecount;
 335
 336 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 337 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 338 {
 339         this.frame = this.csqcmodel_saveframe;
 340         this.frame2 = this.csqcmodel_saveframe2;
 341 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 342         this.frame3 = this.csqcmodel_saveframe3;
 343         this.frame4 = this.csqcmodel_saveframe4;
 344 #endif
 345 }
 346 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 347 {
 348         this.csqcmodel_saveframe = this.frame;
 349         this.csqcmodel_saveframe2 = this.frame2;
 350 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 351         this.csqcmodel_saveframe3 = this.frame3;
 352         this.csqcmodel_saveframe4 = this.frame4;
 353 #endif
 354
 355         // hack for death animations: set their frametime to zero in case a
 356         // player "pops in"
 357         if(isnew)
 358         {
 359 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 360                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 361                         this.ft = this.death_time; \
 362 MACRO_END
 363                 FIX_FRAMETIME(frame, frame1time);
 364                 FIX_FRAMETIME(frame2, frame2time);
 365 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 366                 FIX_FRAMETIME(frame3, frame3time);
 367                 FIX_FRAMETIME(frame4, frame4time);
 368 #endif
 369         }
 370         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 371 }
 372 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 373 {
 374         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 375 }
 376 int CSQCPlayer_FallbackFrame(entity this, int f)
 377 {
 378         TC(int, f);
 379         if(frameduration(this.modelindex, f) > 0)
 380                 return f; // goooooood
 381         if(frameduration(this.modelindex, 1) <= 0)
 382                 return f; // this is a static model. We can't fix it if we wanted to
 383         switch(f)
 384         {
 385                 case 23: return 11; // anim_melee -> anim_shoot
 386                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 387                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 388                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 389                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 390                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 391                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 392                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 393         }
 394         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 395         return f;
 396 }
 397 void CSQCPlayer_FallbackFrame_Apply(entity this)
 398 {
 399         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 400         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 401 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 402         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 403         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 404 #endif
 405 }
 406
 407 // FEATURE: auto tag_index
 408 .entity tag_entity;
 409 .int tag_entity_lastmodelindex;
 410 .int tag_index;
 411 void CSQCModel_AutoTagIndex_Apply(entity this)
 412 {
 413         if(this.tag_entity && wasfreed(this.tag_entity))
 414                 this.tag_entity = NULL;
 415
 416         MUTATOR_CALLHOOK(TagIndex_Update, this);
 417
 418         if(this.tag_networkentity)
 419         {
 420                 // we are ATTACHED!
 421                 bool changed = 0;
 422                 if(this.tag_entity.entnum != this.tag_networkentity)
 423                 {
 424                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 425                         changed = 1;
 426                 }
 427
 428                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 429                 if(this.tag_entity.classname == "ENT_CLIENT_MODEL")
 430                 {
 431                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 432                 }
 433
 434                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 435                 {
 436                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 437                         changed = 1;
 438                 }
 439                 if(changed)
 440                 {
 441                         if(this.tag_entity)
 442                         {
 443                                 // the best part is: IT EXISTS
 444                                 if(substring(this.model, 0, 14) == "models/weapons")
 445                                 {
 446                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 447                                         {
 448                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 449                                                 if(!this.tag_index)
 450                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 451                                                 if(!this.tag_index)
 452                                                 {
 453                                                         // we need to prevent this from 'appening
 454                                                         this.tag_entity = NULL;
 455                                                         this.drawmask = 0;
 456                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 457                                                 }
 458                                         }
 459                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 460                                         {
 461                                                 skeleton_loadinfo(this.tag_entity);
 462                                                 this.tag_index = this.tag_entity.bone_weapon;
 463                                         }
 464                                 }
 465
 466                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 467                                 {
 468                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 469                                         if(!this.tag_index)
 470                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 471                                 }
 472
 473                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 474                         }
 475                         else
 476                         {
 477                                 // damn, see you next frame
 478                                 this.drawmask = 0;
 479                         }
 480                 }
 481         }
 482 }
 483
 484 void CSQCModel_Effects_PreUpdate(entity this)
 485 {
 486         this.effects = this.csqcmodel_effects;
 487         this.modelflags = this.csqcmodel_modelflags;
 488         this.traileffect = this.csqcmodel_traileffect;
 489 }
 490 void Reset_ArcBeam();
 491 void CSQCModel_Effects_PostUpdate(entity this)
 492 {
 493         if (this == csqcplayer) {
 494                 if (this.csqcmodel_teleported) {
 495                         Reset_ArcBeam();
 496                 }
 497         }
 498         this.csqcmodel_effects = this.effects;
 499         this.csqcmodel_modelflags = this.modelflags;
 500         this.csqcmodel_traileffect = this.traileffect;
 501         this.effects = 0;
 502         this.modelflags = 0;
 503         if(this.csqcmodel_teleported)
 504                 Projectile_ResetTrail(this, this.origin);
 505 }
 506 .int snd_looping;
 507 void CSQCModel_Effects_Apply(entity this)
 508 {
 509         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 510         int tref = this.csqcmodel_traileffect;
 511
 512         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 513         this.effects = 0;
 514         this.traileffect = 0;
 515
 516         if(eff & EF_BRIGHTFIELD)
 517                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 518         // ignoring EF_MUZZLEFLASH
 519         if(eff & EF_BRIGHTLIGHT)
 520                 adddynamiclight(this.origin, 400, '3 3 3');
 521         if(eff & EF_DIMLIGHT)
 522                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 523         if((eff & EF_NODRAW) || (this.alpha < 0))
 524                 this.drawmask = 0;
 525         if(eff & EF_ADDITIVE)
 526                 this.renderflags |= RF_ADDITIVE;
 527         if(eff & EF_BLUE)
 528                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 529         if(eff & EF_RED)
 530                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 531         // ignoring EF_NOGUNBOB
 532         if(eff & EF_FULLBRIGHT)
 533                 this.renderflags |= RF_FULLBRIGHT;
 534         if(eff & EF_FLAME)
 535         {
 536                 boxparticles(particleeffectnum(EFFECT_EF_FLAME), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 537                 //pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 538         }
 539         if(eff & EF_STARDUST)
 540         {
 541                 boxparticles(particleeffectnum(EFFECT_EF_STARDUST), this, this.absmin, this.absmax, this.velocity, this.velocity, bound(0, frametime, 0.1), 0);
 542                 //pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 543         }
 544         if(eff & EF_NOSHADOW)
 545                 this.renderflags |= RF_NOSHADOW;
 546         if(eff & EF_NODEPTHTEST)
 547                 this.renderflags |= RF_DEPTHHACK;
 548         // ignoring EF_SELECTABLE
 549         if(eff & EF_DOUBLESIDED)
 550                 this.effects |= EF_DOUBLESIDED;
 551         if(eff & EF_NOSELFSHADOW)
 552                 this.effects |= EF_NOSELFSHADOW;
 553         if(eff & EF_DYNAMICMODELLIGHT)
 554                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 555         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 556         if(this.csqcmodel_modelflags & MF_ROCKET)
 557                 tref = EFFECT_TR_ROCKET.m_id;
 558         if(this.csqcmodel_modelflags & MF_GRENADE)
 559                 tref = EFFECT_TR_GRENADE.m_id;
 560         if(this.csqcmodel_modelflags & MF_GIB)
 561                 tref = EFFECT_TR_BLOOD.m_id;
 562         if(this.csqcmodel_modelflags & MF_ROTATE)
 563         {
 564                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 565                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 566                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 567                 this.renderflags |= RF_USEAXIS;
 568                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 569         }
 570         if(this.csqcmodel_modelflags & MF_TRACER)
 571                 tref = EFFECT_TR_WIZSPIKE.m_id;
 572         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 573                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 574         if(this.csqcmodel_modelflags & MF_TRACER2)
 575                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 576         if(this.csqcmodel_modelflags & MF_TRACER3)
 577                 tref = EFFECT_TR_VORESPIKE.m_id;
 578
 579         this.traileffect = tref;
 580
 581         if(this.drawmask)
 582                 Projectile_DrawTrail(this, this.origin);
 583         else
 584                 Projectile_ResetTrail(this, this.origin);
 585
 586         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 587                 this.renderflags |= RF_ADDITIVE;
 588                 // also special in CSQCPlayer_GlowMod_Apply
 589
 590         if(this.csqcmodel_modelflags & MF_ROCKET)
 591         {
 592                 if(!this.snd_looping)
 593                 {
 594                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 595                         this.snd_looping = CH_TRIGGER_SINGLE;
 596                 }
 597         }
 598         else
 599         {
 600                 if(this.snd_looping)
 601                 {
 602                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 603                         this.snd_looping = 0;
 604                 }
 605         }
 606 }
 607
 608 // general functions
 609 .int csqcmodel_predraw_run;
 610 .int anim_frame;
 611 .int anim_frame1time;
 612 .int anim_frame2;
 613 .int anim_frame2time;
 614 .int anim_saveframe;
 615 .int anim_saveframe1time;
 616 .int anim_saveframe2;
 617 .int anim_saveframe2time;
 618 .int anim_prev_pmove_flags;
 619 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 620 {
 621         if(this.csqcmodel_predraw_run == framecount)
 622                 return;
 623         this.csqcmodel_predraw_run = framecount;
 624
 625         if(!this.modelindex || this.model == "null")
 626         {
 627                 this.drawmask = 0;
 628                 if(this.snd_looping > 0)
 629                 {
 630                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 631                         this.snd_looping = 0;
 632                 }
 633                 return;
 634         }
 635         else
 636                 this.drawmask = MASK_NORMAL;
 637
 638         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 639         {
 640                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 641                 CSQCPlayer_LOD_Apply(this);
 642
 643                 if(!isplayer)
 644                 {
 645                         skeleton_loadinfo(this);
 646                         bool doblend = (this.bone_upperbody >= 0);
 647                         CSQCPlayer_FallbackFrame_Apply(this);
 648                         if(doblend)
 649                         {
 650                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 651                         }
 652                         else
 653                         {
 654                                 free_skeleton_from_frames(this);
 655                                 // just in case, clear these (we're animating in frame and frame3)
 656                                 this.lerpfrac = 0;
 657                                 this.lerpfrac4 = 0;
 658                         }
 659                 }
 660                 else
 661                 {
 662                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 663                         skeleton_loadinfo(this);
 664                         bool doblend = (this.bone_upperbody >= 0);
 665                         bool onground = 0;
 666                         if(this == csqcplayer)
 667                         {
 668                                 if(IS_ONGROUND(this))
 669                                         onground = 1;
 670                                 this.anim_prev_pmove_flags = this.flags;
 671                                 if(this.flags & FL_DUCKED)
 672                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 673                                 else if(this.anim_state & ANIMSTATE_DUCK)
 674                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 675                         }
 676                         else
 677                         {
 678                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 679                                 if(trace_startsolid || trace_fraction < 1)
 680                                         onground = 1;
 681                                 // predicted clients handle smoothing in the prediction code
 682                                 this.origin = CSQCModel_ApplyStairSmoothing(this, onground, this.origin);
 683                         }
 684                         animdecide_load_if_needed(this);
 685                         animdecide_setimplicitstate(this, onground);
 686                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 687                         int sf = 0;
 688                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 689                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 690                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 691                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 692                         this.anim_saveframe = this.anim_frame;
 693                         this.anim_saveframe1time = this.anim_frame1time;
 694                         this.anim_saveframe2 = this.anim_frame2;
 695                         this.anim_saveframe2time = this.anim_frame2time;
 696                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 697                         // This ensures that .frame etc. are always written.
 698                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 699                         this.lerpfrac = (doblend ? 0.5 : 0);
 700                         this.frame = this.anim_frame;
 701                         this.frame1time = this.anim_frame1time;
 702                         this.frame2 = this.anim_frame2;
 703                         this.frame2time = this.anim_frame2time;
 704                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 705                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 706                         if(doblend)
 707                         {
 708                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 709                         }
 710                         else
 711                         {
 712                                 free_skeleton_from_frames(this);
 713                                 // just in case, clear these (we're animating in frame and frame3)
 714                                 this.lerpfrac = 0;
 715                                 this.lerpfrac4 = 0;
 716                         }
 717                 }
 718         }
 719
 720         CSQCModel_AutoTagIndex_Apply(this);
 721
 722         CSQCModel_Effects_Apply(this);
 723 }
 724
 725 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 726 {
 727         // interpolate v_angle
 728         this.iflags |= IFLAG_V_ANGLE_X;
 729         // revert to values from server
 730         CSQCModel_Effects_PreUpdate(this);
 731         if((this.isplayermodel & ISPLAYER_MODEL))
 732         {
 733                 if(!isplayer)
 734                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 735                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 736         }
 737 }
 738
 739 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 740 {
 741         // is it a player model? (shared state)
 742         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 743                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 744         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 745
 746         // save values set by server
 747         if((this.isplayermodel & ISPLAYER_MODEL))
 748         {
 749                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 750                 if(isplayer)
 751                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 752                 else
 753                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 754         }
 755         CSQCModel_Effects_PostUpdate(this);
 756 }