qcsrc/client/damage.qc

   1 void Ent_DamageInfo(float isNew)
   2 {
   3         float dmg, rad, edge, thisdmg, forcemul;
   4         vector force, thisforce;
   5         entity oldself;
   6
   7         oldself = self;
   8
   9         w_deathtype = ReadShort();
  10         w_issilent = (w_deathtype & 0x8000);
  11         w_deathtype = (w_deathtype & 0x7FFF);
  12
  13         w_org_x = ReadCoord();
  14         w_org_y = ReadCoord();
  15         w_org_z = ReadCoord();
  16
  17         dmg = ReadByte();
  18         rad = ReadByte();
  19         edge = ReadByte();
  20         force = decompressShortVector(ReadShort());
  21
  22         if not(isNew)
  23                 return;
  24
  25         if(rad < 0)
  26         {
  27                 rad = -rad;
  28                 forcemul = -1;
  29         }
  30         else
  31                 forcemul = 1;
  32
  33         for(self = findradius(w_org, rad); self; self = self.chain)
  34         {
  35                 if(rad)
  36                 {
  37                         thisdmg = vlen(self.origin - w_org) / rad;
  38                         if(thisdmg >= 1)
  39                                 continue;
  40                         if(dmg)
  41                         {
  42                                 thisdmg = dmg + (edge - dmg) * thisdmg;
  43                                 thisforce = forcemul * vlen(force) * (thisdmg / dmg) * normalize(self.origin - w_org);
  44                         }
  45                         else
  46                         {
  47                                 thisdmg = 0;
  48                                 thisforce = forcemul * vlen(force) * normalize(self.origin - w_org);
  49                         }
  50                 }
  51                 else
  52                 {
  53                         thisdmg = dmg;
  54                         thisforce = forcemul * force;
  55                 }
  56
  57                 if(self.damageforcescale)
  58                         if(vlen(thisforce))
  59                         {
  60                                 self.move_velocity = self.move_velocity + damage_explosion_calcpush(self.damageforcescale * thisforce, self.move_velocity, autocvar_g_balance_damagepush_speedfactor);
  61                                 self.move_flags &~= FL_ONGROUND;
  62                         }
  63
  64                 if(w_issilent)
  65                         self.silent = 1;
  66
  67                 if(self.event_damage)
  68                         self.event_damage(thisdmg, w_deathtype, w_org, thisforce);
  69         }
  70
  71         self = oldself;
  72
  73         if(DEATH_ISVEHICLE(w_deathtype))
  74         {
  75             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
  76             if(trace_plane_normal != '0 0 0')
  77             w_backoff = trace_plane_normal;
  78         else
  79             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
  80
  81             setorigin(self, w_org + w_backoff * 2); // for sound() calls
  82
  83             switch(w_deathtype)
  84             {
  85             case DEATH_VHCRUSH:
  86                 break;
  87
  88             case DEATH_SBMINIGUN:
  89                 string _snd;
  90                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
  91                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
  92                 pointparticles(particleeffectnum("spiderbot_minigun_impact"), self.origin, w_backoff * 1000, 1);
  93                 break;
  94             case DEATH_SBROCKET:
  95                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  96                 pointparticles(particleeffectnum("spiderbot_rocket_explode"), self.origin, w_backoff * 1000, 1);
  97                 break;
  98             case DEATH_SBBLOWUP:
  99                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 100                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 101                 break;
 102
 103             case DEATH_WAKIGUN:
 104                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 105                 pointparticles(particleeffectnum("wakizashi_gun_impact"), self.origin, w_backoff * 1000, 1);
 106                 break;
 107             case DEATH_WAKIROCKET:
 108                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 109                 pointparticles(particleeffectnum("wakizashi_rocket_explode"), self.origin, w_backoff * 1000, 1);
 110                 break;
 111             case DEATH_WAKIBLOWUP:
 112                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 113                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 114                 break;
 115
 116             case DEATH_RAPTOR_CANNON:
 117                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 118                 pointparticles(particleeffectnum("raptor_cannon_impact"), self.origin, w_backoff * 1000, 1);
 119                 break;
 120             case DEATH_RAPTOR_BOMB_SPLIT:
 121                 float i;
 122                 vector ang, vel;
 123                 for(i = 1; i < 4; ++i)
 124                 {
 125                     vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
 126                     ang = vectoangles(vel);
 127                     RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
 128                 }
 129
 130
 131                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 132                 pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, w_backoff * 1000, 1);
 133                 break;
 134             case DEATH_RAPTOR_BOMB:
 135                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 136                 pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, w_backoff * 1000, 1);
 137                 break;
 138             case DEATH_RAPTOR_DEATH:
 139                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 140                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 141                 break;
 142             }
 143         }
 144
 145
 146         if(DEATH_ISTURRET(w_deathtype))
 147         {
 148             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 149             if(trace_plane_normal != '0 0 0')
 150             w_backoff = trace_plane_normal;
 151         else
 152             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
 153
 154             setorigin(self, w_org + w_backoff * 2); // for sound() calls
 155
 156             switch(w_deathtype)
 157             {
 158              case DEATH_TURRET_EWHEEL:
 159                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 160                 pointparticles(particleeffectnum("electro_impact"), self.origin, w_backoff * 1000, 1);
 161                 break;
 162
 163              case DEATH_TURRET_FLAC:
 164                 vector org2;
 165                 org2 = w_org + w_backoff * 6;
 166                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 167                 if (w_random<0.15)
 168                     sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 169                 else if (w_random<0.7)
 170                     sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 171                 else
 172                     sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 173
 174                 break;
 175
 176              case DEATH_TURRET_MLRS:
 177              case DEATH_TURRET_HK:
 178              case DEATH_TURRET_WALKER_ROCKET:
 179              case DEATH_TURRET_HELLION:
 180                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 181                 pointparticles(particleeffectnum("rocket_explode"), self.origin, w_backoff * 1000, 1);
 182                 break;
 183
 184              case DEATH_TURRET_MACHINEGUN:
 185              case DEATH_TURRET_WALKER_GUN:
 186                 string _snd;
 187                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
 188                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 189                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, w_backoff * 1000, 1);
 190                 break;
 191
 192              case DEATH_TURRET_PLASMA:
 193                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_MIN);
 194                 pointparticles(particleeffectnum("electro_impact"), self.origin, w_backoff * 1000, 1);
 195                 break;
 196
 197              case DEATH_TURRET_WALKER_MEELE:
 198                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_MIN);
 199                 pointparticles(particleeffectnum("TE_SPARK"), self.origin, w_backoff * 1000, 1);
 200                 break;
 201
 202              case DEATH_TURRET_PHASER:
 203                 break;
 204
 205              case DEATH_TURRET_TESLA:
 206                 te_smallflash(self.origin);
 207                 break;
 208
 209         }
 210         }
 211
 212         // TODO spawn particle effects and sounds based on w_deathtype
 213         if(!DEATH_ISSPECIAL(w_deathtype))
 214         {
 215                 float hitwep;
 216
 217                 hitwep = DEATH_WEAPONOFWEAPONDEATH(w_deathtype);
 218                 w_random = prandom();
 219
 220                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 221                 if(trace_fraction < 1 && hitwep != WEP_NEX && hitwep != WEP_MINSTANEX)
 222                         w_backoff = trace_plane_normal;
 223                 else
 224                         w_backoff = -1 * normalize(force);
 225                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
 226
 227                 (get_weaponinfo(hitwep)).weapon_func(WR_IMPACTEFFECT);
 228         }
 229 }
 230
 231 void DamageInfo_Precache()
 232 {
 233         float i;
 234         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 235                 (get_weaponinfo(i)).weapon_func(WR_PRECACHE);
 236 }
 237
 238 .entity dmgeffect;
 239 .float partnum;
 240
 241 void Ent_DamageEffect_Think()
 242 {
 243         self.nextthink = time;
 244
 245         entity entcs;
 246         entcs = entcs_receiver[self.team];
 247         if(!entcs)
 248                 return;
 249
 250         // Scan the owner of all gibs in the world. If a gib owner is the same as the player we're applying
 251         // the effect to, it means our player is gibbed. Therefore, apply particles to the gibs instead.
 252         float foundgib;
 253         entity head;
 254         for(head = world; (head = find(head, classname, "gib")); )
 255         {
 256                 if(head.team == self.team)
 257                 {
 258                         if(autocvar_cl_damageeffect_gibs)
 259                                 pointparticles(self.partnum, head.origin, '0 0 0', 1);
 260                         foundgib = TRUE;
 261                 }
 262         }
 263         if(foundgib) // don't show effects on the invisible dead body if gibs exist
 264                 return;
 265
 266         // if we aren't in third person mode, hide our own damage effect
 267         if(self.team == player_localentnum - 1 && !autocvar_chase_active)
 268                 return;
 269
 270         // Now apply the effect to actual players
 271         pointparticles(self.partnum, entcs.origin, '0 0 0', 1);
 272 }
 273
 274 void Ent_DamageEffect()
 275 {
 276         float dmg, type, specnum1, specnum2, entnumber;
 277         vector org;
 278         string specstr, effectnum;
 279         entity e;
 280
 281         dmg = ReadByte(); // damage amount
 282         type = ReadByte(); // damage weapon
 283         specnum1 = ReadByte(); // player species
 284         entnumber = ReadByte(); // player entnum
 285
 286         if not(autocvar_cl_damageeffect)
 287                 return;
 288         if(autocvar_cl_gentle || autocvar_cl_gentle_damage)
 289                 return;
 290
 291         specnum2 = (specnum1 & 0x78) / 8; // blood type: using four bits (0..7, bit indexes 3,4,5)
 292         specstr = species_prefix(specnum2);
 293
 294         e = get_weaponinfo(type);
 295         effectnum = strcat("weapondamage_", e.netname);
 296         // If the weapon is a bullet weapon, its damage effect is blood.
 297         // Since blood is species dependent, we make this effect per-species.
 298         if(type == WEP_SHOTGUN || type == WEP_UZI || type == WEP_RIFLE)
 299         if(specstr != "")
 300         {
 301                 effectnum = strcat(effectnum, "_", specstr);
 302                 effectnum = substring(effectnum, 0, strlen(effectnum) - 1); // remove the _ symbol at the end of the species name
 303         }
 304
 305         // if the player already has a damage effect, replace it with the new one
 306         entity head;
 307         for(head = world; (head = find(head, classname, "dmgeffect")); )
 308         {
 309                 if(head.team == entnumber - 1)
 310                 {
 311                         remove(head);
 312                         head = world;
 313                 }
 314         }
 315
 316         entity e;
 317         e = spawn();
 318         e.classname = "dmgeffect";
 319         e.team = entnumber - 1;
 320         e.partnum = particleeffectnum(effectnum);
 321         e.think = Ent_DamageEffect_Think;
 322         e.nextthink = time;
 323 }