qcsrc/client/hud.qc

   1 #include "hud.qh"
   2
   3 #include "hud_config.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "teamradar.qh"
   7 #include "t_items.qh"
   8 #include "../common/buffs/all.qh"
   9 #include "../common/deathtypes.qh"
  10 #include "../common/items/all.qc"
  11 #include "../common/mapinfo.qh"
  12 #include "../common/mutators/mutator/waypoints/all.qh"
  13 #include "../common/nades/all.qh"
  14 #include "../common/stats.qh"
  15 #include "../lib/csqcmodel/cl_player.qh"
  16 #include "../server/mutators/gamemode_ctf.qh"
  17
  18
  19 /*
  20 ==================
  21 Misc HUD functions
  22 ==================
  23 */
  24
  25 vector HUD_Get_Num_Color (float x, float maxvalue)
  26 {
  27         float blinkingamt;
  28         vector color;
  29         if(x >= maxvalue) {
  30                 color.x = sin(2*M_PI*time);
  31                 color.y = 1;
  32                 color.z = sin(2*M_PI*time);
  33         }
  34         else if(x > maxvalue * 0.75) {
  35                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
  36                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
  37                 color.z = 0;
  38         }
  39         else if(x > maxvalue * 0.5) {
  40                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
  41                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
  42                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
  43         }
  44         else if(x > maxvalue * 0.25) {
  45                 color.x = 1;
  46                 color.y = 1;
  47                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
  48         }
  49         else if(x > maxvalue * 0.1) {
  50                 color.x = 1;
  51                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
  52                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
  53         }
  54         else {
  55                 color.x = 1;
  56                 color.y = 0;
  57                 color.z = 0;
  58         }
  59
  60         blinkingamt = (1 - x/maxvalue/0.25);
  61         if(blinkingamt > 0)
  62         {
  63                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
  64                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
  65                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
  66         }
  67         return color;
  68 }
  69
  70 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
  71 {
  72         float aspect = size_y / size_x;
  73         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
  74 }
  75
  76 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect)
  77 {
  78         float columns, rows;
  79         float ratio, best_ratio = 0;
  80         float best_columns = 1, best_rows = 1;
  81         bool vertical = (psize.x / psize.y >= item_aspect);
  82         if(vertical)
  83         {
  84                 psize = eX * psize.y + eY * psize.x;
  85                 item_aspect = 1 / item_aspect;
  86         }
  87
  88         rows = ceil(sqrt(item_count));
  89         columns = ceil(item_count/rows);
  90         while(columns >= 1)
  91         {
  92                 ratio = (psize.x/columns) / (psize.y/rows);
  93                 if(ratio > item_aspect)
  94                         ratio = item_aspect * item_aspect / ratio;
  95
  96                 if(ratio <= best_ratio)
  97                         break; // ratio starts decreasing by now, skip next configurations
  98
  99                 best_columns = columns;
 100                 best_rows = rows;
 101                 best_ratio = ratio;
 102
 103                 if(columns == 1)
 104                         break;
 105
 106                 --columns;
 107                 rows = ceil(item_count/columns);
 108         }
 109
 110         if(vertical)
 111                 return eX * best_rows + eY * best_columns;
 112         else
 113                 return eX * best_columns + eY * best_rows;
 114 }
 115
 116 // return the string of the onscreen race timer
 117 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 118 {
 119         string col;
 120         string timestr;
 121         string cpname;
 122         string lapstr;
 123         lapstr = "";
 124
 125         if(theirtime == 0) // goal hit
 126         {
 127                 if(mytime > 0)
 128                 {
 129                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 130                         col = "^1";
 131                 }
 132                 else if(mytime == 0)
 133                 {
 134                         timestr = "+0.0";
 135                         col = "^3";
 136                 }
 137                 else
 138                 {
 139                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 140                         col = "^2";
 141                 }
 142
 143                 if(lapdelta > 0)
 144                 {
 145                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 146                         col = "^2";
 147                 }
 148                 else if(lapdelta < 0)
 149                 {
 150                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 151                         col = "^1";
 152                 }
 153         }
 154         else if(theirtime > 0) // anticipation
 155         {
 156                 if(mytime >= theirtime)
 157                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 158                 else
 159                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 160                 col = "^3";
 161         }
 162         else
 163         {
 164                 col = "^7";
 165                 timestr = "";
 166         }
 167
 168         if(cp == 254)
 169                 cpname = _("Start line");
 170         else if(cp == 255)
 171                 cpname = _("Finish line");
 172         else if(cp)
 173                 cpname = sprintf(_("Intermediate %d"), cp);
 174         else
 175                 cpname = _("Finish line");
 176
 177         if(theirtime < 0)
 178                 return strcat(col, cpname);
 179         else if(theirname == "")
 180                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 181         else
 182                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 183 }
 184
 185 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 186 int race_CheckName(string net_name)
 187 {
 188         int i;
 189         for (i=RANKINGS_CNT-1;i>=0;--i)
 190                 if(grecordholder[i] == net_name)
 191                         return i+1;
 192         return 0;
 193 }
 194
 195 /*
 196 ==================
 197 HUD panels
 198 ==================
 199 */
 200
 201 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 202 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 203 {
 204         if(!length_ratio || !theAlpha)
 205                 return;
 206         if(length_ratio > 1)
 207                 length_ratio = 1;
 208         if (baralign == 3)
 209         {
 210                 if(length_ratio < -1)
 211                         length_ratio = -1;
 212         }
 213         else if(length_ratio < 0)
 214                 return;
 215
 216         vector square;
 217         vector width, height;
 218         if(vertical) {
 219                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 220                 if(precache_pic(pic) == "") {
 221                         pic = "gfx/hud/default/progressbar_vertical";
 222                 }
 223
 224         if (baralign == 1) // bottom align
 225                         theOrigin.y += (1 - length_ratio) * theSize.y;
 226         else if (baralign == 2) // center align
 227             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 228         else if (baralign == 3) // center align, positive values down, negative up
 229                 {
 230                         theSize.y *= 0.5;
 231                         if (length_ratio > 0)
 232                                 theOrigin.y += theSize.y;
 233                         else
 234                         {
 235                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 236                                 length_ratio = -length_ratio;
 237                         }
 238                 }
 239                 theSize.y *= length_ratio;
 240
 241                 vector bH;
 242                 width = eX * theSize.x;
 243                 height = eY * theSize.y;
 244                 if(theSize.y <= theSize.x * 2)
 245                 {
 246                         // button not high enough
 247                         // draw just upper and lower part then
 248                         square = eY * theSize.y * 0.5;
 249                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 250                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 251                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 252                 }
 253                 else
 254                 {
 255                         square = eY * theSize.x;
 256                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 257                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 258                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 259                 }
 260         } else {
 261                 pic = strcat(hud_skin_path, "/", pic);
 262                 if(precache_pic(pic) == "") {
 263                         pic = "gfx/hud/default/progressbar";
 264                 }
 265
 266                 if (baralign == 1) // right align
 267                         theOrigin.x += (1 - length_ratio) * theSize.x;
 268         else if (baralign == 2) // center align
 269             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 270         else if (baralign == 3) // center align, positive values on the right, negative on the left
 271                 {
 272                         theSize.x *= 0.5;
 273                         if (length_ratio > 0)
 274                                 theOrigin.x += theSize.x;
 275                         else
 276                         {
 277                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 278                                 length_ratio = -length_ratio;
 279                         }
 280                 }
 281                 theSize.x *= length_ratio;
 282
 283                 vector bW;
 284                 width = eX * theSize.x;
 285                 height = eY * theSize.y;
 286                 if(theSize.x <= theSize.y * 2)
 287                 {
 288                         // button not wide enough
 289                         // draw just left and right part then
 290                         square = eX * theSize.x * 0.5;
 291                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 292                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 293                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 294                 }
 295                 else
 296                 {
 297                         square = eX * theSize.y;
 298                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 299                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 300                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 301                 }
 302         }
 303 }
 304
 305 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 306 {
 307         if(!theAlpha)
 308                 return;
 309
 310         string pic;
 311         pic = strcat(hud_skin_path, "/num_leading");
 312         if(precache_pic(pic) == "") {
 313                 pic = "gfx/hud/default/num_leading";
 314         }
 315
 316         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 317         if(mySize.x/mySize.y > 2)
 318                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 319         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 320 }
 321
 322 // Weapon icons (#0)
 323 //
 324 entity weaponorder[Weapons_MAX];
 325 void weaponorder_swap(int i, int j, entity pass)
 326 {
 327         entity h = weaponorder[i];
 328         weaponorder[i] = weaponorder[j];
 329         weaponorder[j] = h;
 330 }
 331
 332 string weaponorder_cmp_str;
 333 int weaponorder_cmp(int i, int j, entity pass)
 334 {
 335         int ai, aj;
 336         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 337         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 338         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 339 }
 340
 341 void HUD_Weapons(void)
 342 {SELFPARAM();
 343         // declarations
 344         WepSet weapons_stat = WepSet_GetFromStat();
 345         int i;
 346         float f, a;
 347         float screen_ar;
 348         vector center = '0 0 0';
 349         int weapon_count, weapon_id;
 350         int row, column, rows = 0, columns = 0;
 351         bool vertical_order = true;
 352         float aspect = autocvar_hud_panel_weapons_aspect;
 353
 354         float timeout = autocvar_hud_panel_weapons_timeout;
 355         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 356         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 357
 358         vector barsize = '0 0 0', baroffset = '0 0 0';
 359         vector ammo_color = '1 0 1';
 360         float ammo_alpha = 1;
 361
 362         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 363         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 364
 365         vector weapon_pos, weapon_size = '0 0 0';
 366         vector color;
 367
 368         // check to see if we want to continue
 369         if(intermission == 2) return;
 370         if(hud != HUD_NORMAL) return;
 371
 372         if(!autocvar__hud_configure)
 373         {
 374                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 375                         return;
 376                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 377                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 378                 {
 379                         weaponprevtime = time;
 380                         return;
 381                 }
 382         }
 383
 384         // update generic hud functions
 385         HUD_Panel_UpdateCvars();
 386
 387         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 388         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 389         {
 390                 int weapon_cnt;
 391                 if(weaponorder_bypriority)
 392                         strunzone(weaponorder_bypriority);
 393                 if(weaponorder_byimpulse)
 394                         strunzone(weaponorder_byimpulse);
 395
 396                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 397                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 398                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 399
 400                 weapon_cnt = 0;
 401                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 402                 {
 403                         setself(get_weaponinfo(i));
 404                         if(self.impulse >= 0)
 405                         {
 406                                 weaponorder[weapon_cnt] = self;
 407                                 ++weapon_cnt;
 408                         }
 409                 }
 410                 for(i = weapon_cnt; i < Weapons_MAX; ++i)
 411                         weaponorder[i] = world;
 412                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 413
 414                 weaponorder_cmp_str = string_null;
 415         }
 416
 417         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 418                 complain_weapon = 0;
 419
 420         if(autocvar__hud_configure)
 421         {
 422                 if(!weapons_stat)
 423                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 424                                 weapons_stat |= WepSet_FromWeapon(i);
 425
 426                 #if 0
 427                 /// debug code
 428                 if(cvar("wep_add"))
 429                 {
 430                         weapons_stat = '0 0 0';
 431                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % (Weapons_COUNT - 1));
 432                         for(i = WEP_FIRST; i <= countw; ++i)
 433                                 weapons_stat |= WepSet_FromWeapon(i);
 434                 }
 435                 #endif
 436         }
 437
 438         // determine which weapons are going to be shown
 439         if (autocvar_hud_panel_weapons_onlyowned)
 440         {
 441                 if(autocvar__hud_configure)
 442                 {
 443                         if(menu_enabled != 2)
 444                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 445                 }
 446
 447                 // do we own this weapon?
 448                 weapon_count = 0;
 449                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 450                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 451                                 ++weapon_count;
 452
 453
 454                 // might as well commit suicide now, no reason to live ;)
 455                 if (weapon_count == 0)
 456                         return;
 457
 458                 vector old_panel_size = panel_size;
 459                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 460
 461                 // get the all-weapons layout
 462                 int nHidden = 0;
 463                 WepSet weapons_stat = WepSet_GetFromStat();
 464                 for (int i = WEP_FIRST; i <= WEP_LAST; ++i) {
 465                         WepSet weapons_wep = WepSet_FromWeapon(i);
 466                         if (weapons_stat & weapons_wep) continue;
 467                         Weapon w = get_weaponinfo(i);
 468                         if (w.spawnflags & WEP_FLAG_MUTATORBLOCKED) nHidden += 1;
 469                 }
 470                 vector table_size = HUD_GetTableSize_BestItemAR((Weapons_COUNT - 1) - nHidden, padded_panel_size, aspect);
 471                 columns = table_size.x;
 472                 rows = table_size.y;
 473                 weapon_size.x = padded_panel_size.x / columns;
 474                 weapon_size.y = padded_panel_size.y / rows;
 475
 476                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 477                 // we enlarge them a bit when possible to better match the desired aspect ratio
 478                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 479                 {
 480                         // maximum number of rows that allows to display items with the desired aspect ratio
 481                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 482                         columns = min(columns, ceil(weapon_count / max_rows));
 483                         rows = ceil(weapon_count / columns);
 484                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 485                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 486                         vertical_order = false;
 487                 }
 488                 else
 489                 {
 490                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 491                         rows = min(rows, ceil(weapon_count / max_columns));
 492                         columns = ceil(weapon_count / rows);
 493                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 494                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 495                         vertical_order = true;
 496                 }
 497
 498                 // reduce size of the panel
 499                 panel_size.x = columns * weapon_size.x;
 500                 panel_size.y = rows * weapon_size.y;
 501                 panel_size += '2 2 0' * panel_bg_padding;
 502
 503                 // center the resized panel, or snap it to the screen edge when close enough
 504                 if(panel_pos.x > vid_conwidth * 0.001)
 505                 {
 506                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 507                                 panel_pos.x += old_panel_size.x - panel_size.x;
 508                         else
 509                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 510                 }
 511                 else if(old_panel_size.x > vid_conwidth * 0.999)
 512                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 513
 514                 if(panel_pos.y > vid_conheight * 0.001)
 515                 {
 516                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 517                                 panel_pos.y += old_panel_size.y - panel_size.y;
 518                         else
 519                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 520                 }
 521                 else if(old_panel_size.y > vid_conheight * 0.999)
 522                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 523         }
 524         else
 525                 weapon_count = (Weapons_COUNT - 1);
 526
 527         // animation for fading in/out the panel respectively when not in use
 528         if(!autocvar__hud_configure)
 529         {
 530                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 531                 {
 532                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 533
 534                         // fade the panel alpha
 535                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 536                         {
 537                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 538                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 539                         }
 540                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 541                         {
 542                                 panel_bg_alpha *= (1 - f);
 543                                 panel_fg_alpha *= (1 - f);
 544                         }
 545
 546                         // move the panel off the screen
 547                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 548                         {
 549                                 f *= f; // for a cooler movement
 550                                 center.x = panel_pos.x + panel_size.x/2;
 551                                 center.y = panel_pos.y + panel_size.y/2;
 552                                 screen_ar = vid_conwidth/vid_conheight;
 553                                 if (center.x/center.y < screen_ar) //bottom left
 554                                 {
 555                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 556                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 557                                         else //left
 558                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 559                                 }
 560                                 else //top right
 561                                 {
 562                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 563                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 564                                         else //top
 565                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 566                                 }
 567                                 if(f == 1)
 568                                         center.x = -1; // mark the panel as off screen
 569                         }
 570                         weaponprevtime = time - (1 - f) * timein_effect_length;
 571                 }
 572                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 573                 {
 574                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 575
 576                         // fade the panel alpha
 577                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 578                         {
 579                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 580                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 581                         }
 582                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 583                         {
 584                                 panel_bg_alpha *= (f);
 585                                 panel_fg_alpha *= (f);
 586                         }
 587
 588                         // move the panel back on screen
 589                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 590                         {
 591                                 f *= f; // for a cooler movement
 592                                 f = 1 - f;
 593                                 center.x = panel_pos.x + panel_size.x/2;
 594                                 center.y = panel_pos.y + panel_size.y/2;
 595                                 screen_ar = vid_conwidth/vid_conheight;
 596                                 if (center.x/center.y < screen_ar) //bottom left
 597                                 {
 598                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 599                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 600                                         else //left
 601                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 602                                 }
 603                                 else //top right
 604                                 {
 605                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 606                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 607                                         else //top
 608                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 609                                 }
 610                         }
 611                 }
 612         }
 613
 614         // draw the background, then change the virtual size of it to better fit other items inside
 615         HUD_Panel_DrawBg(1);
 616
 617         if(center.x == -1)
 618                 return;
 619
 620         if(panel_bg_padding)
 621         {
 622                 panel_pos += '1 1 0' * panel_bg_padding;
 623                 panel_size -= '2 2 0' * panel_bg_padding;
 624         }
 625
 626         // after the sizing and animations are done, update the other values
 627
 628         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 629         {
 630                 vector table_size = HUD_GetTableSize_BestItemAR((Weapons_COUNT - 1), panel_size, aspect);
 631                 columns = table_size.x;
 632                 rows = table_size.y;
 633                 weapon_size.x = panel_size.x / columns;
 634                 weapon_size.y = panel_size.y / rows;
 635                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 636         }
 637
 638         // calculate position/size for visual bar displaying ammount of ammo status
 639         if (autocvar_hud_panel_weapons_ammo)
 640         {
 641                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 642                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 643
 644                 if(weapon_size.x/weapon_size.y > aspect)
 645                 {
 646                         barsize.x = aspect * weapon_size.y;
 647                         barsize.y = weapon_size.y;
 648                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 649                 }
 650                 else
 651                 {
 652                         barsize.y = 1/aspect * weapon_size.x;
 653                         barsize.x = weapon_size.x;
 654                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 655                 }
 656         }
 657         if(autocvar_hud_panel_weapons_accuracy)
 658                 Accuracy_LoadColors();
 659
 660         // draw items
 661         row = column = 0;
 662         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 663         vector noncurrent_pos = '0 0 0';
 664         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 665         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 666         bool isCurrent;
 667
 668         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 669         {
 670                 // retrieve information about the current weapon to be drawn
 671                 setself(weaponorder[i]);
 672                 weapon_id = self.impulse;
 673                 isCurrent = (self.weapon == switchweapon);
 674
 675                 // skip if this weapon doesn't exist
 676                 if(!self || weapon_id < 0) { continue; }
 677
 678                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 679                 if(autocvar_hud_panel_weapons_onlyowned)
 680                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 681                         continue;
 682
 683                 // figure out the drawing position of weapon
 684                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 685                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 686                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 687
 688                 // draw background behind currently selected weapon
 689                 if(isCurrent)
 690                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 691
 692                 // draw the weapon accuracy
 693                 if(autocvar_hud_panel_weapons_accuracy)
 694                 {
 695                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 696                         if(panel_weapon_accuracy >= 0)
 697                         {
 698                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 699                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 700                         }
 701                 }
 702
 703                 // drawing all the weapon items
 704                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 705                 {
 706                         // draw the weapon image
 707                         if(isCurrent)
 708                                 drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 709                         else
 710                                 drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 711
 712                         // draw weapon label string
 713                         switch(autocvar_hud_panel_weapons_label)
 714                         {
 715                                 case 1: // weapon number
 716                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 717                                         break;
 718
 719                                 case 2: // bind
 720                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 721                                         break;
 722
 723                                 case 3: // weapon name
 724                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 725                                         break;
 726
 727                                 default: // nothing
 728                                         break;
 729                         }
 730
 731                         // draw ammo status bar
 732                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 733                         {
 734                                 float ammo_full;
 735                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 736
 737                                 if(a > 0)
 738                                 {
 739                                         switch(self.ammo_field)
 740                                         {
 741                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 742                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 743                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 744                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 745                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 746                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 747                                                 default: ammo_full = 60;
 748                                         }
 749
 750                                         drawsetcliparea(
 751                                                 weapon_pos.x + baroffset.x,
 752                                                 weapon_pos.y + baroffset.y,
 753                                                 barsize.x * bound(0, a/ammo_full, 1),
 754                                                 barsize.y
 755                                         );
 756
 757                                         drawpic_aspect_skin(
 758                                                 weapon_pos,
 759                                                 "weapon_ammo",
 760                                                 weapon_size,
 761                                                 ammo_color,
 762                                                 ammo_alpha,
 763                                                 DRAWFLAG_NORMAL
 764                                         );
 765
 766                                         drawresetcliparea();
 767                                 }
 768                         }
 769                 }
 770                 else // draw a "ghost weapon icon" if you don't have the weapon
 771                 {
 772                         drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 773                 }
 774
 775                 // draw the complain message
 776                 if(self.weapon == complain_weapon)
 777                 {
 778                         if(fadetime)
 779                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 780                         else
 781                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 782
 783                         string s;
 784                         if(complain_weapon_type == 0) {
 785                                 s = _("Out of ammo");
 786                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 787                         }
 788                         else if(complain_weapon_type == 1) {
 789                                 s = _("Don't have");
 790                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 791                         }
 792                         else {
 793                                 s = _("Unavailable");
 794                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 795                         }
 796                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 797                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 798                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 799                 }
 800
 801                 #if 0
 802                 /// debug code
 803                 if(!autocvar_hud_panel_weapons_onlyowned)
 804                 {
 805                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 806                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 807                 }
 808                 #endif
 809
 810                 // continue with new position for the next weapon
 811                 if(vertical_order)
 812                 {
 813                         ++column;
 814                         if(column >= columns)
 815                         {
 816                                 column = 0;
 817                                 ++row;
 818                         }
 819                 }
 820                 else
 821                 {
 822                         ++row;
 823                         if(row >= rows)
 824                         {
 825                                 row = 0;
 826                                 ++column;
 827                         }
 828                 }
 829         }
 830 }
 831
 832 // Ammo (#1)
 833 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 834 {
 835         HUD_Panel_DrawProgressBar(
 836                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 837                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 838                 autocvar_hud_panel_ammo_progressbar_name,
 839                 progress, 0, 0, color,
 840                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 841 }
 842
 843 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 844 {
 845         float bonusNades    = getstatf(STAT_NADE_BONUS);
 846         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 847         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 848         vector nadeColor    = Nades[bonusType].m_color;
 849         string nadeIcon     = Nades[bonusType].m_icon;
 850
 851         vector iconPos, textPos;
 852
 853         if(autocvar_hud_panel_ammo_iconalign)
 854         {
 855                 iconPos = myPos + eX * 2 * mySize.y;
 856                 textPos = myPos;
 857         }
 858         else
 859         {
 860                 iconPos = myPos;
 861                 textPos = myPos + eX * mySize.y;
 862         }
 863
 864         if(bonusNades > 0 || bonusProgress > 0)
 865         {
 866                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 867
 868                 if(autocvar_hud_panel_ammo_text)
 869                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 870
 871                 if(draw_expanding)
 872                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 873
 874                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 875         }
 876 }
 877
 878 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
 879 {
 880         if(ammoType == ammo_none)
 881                 return;
 882
 883         // Initialize variables
 884
 885         int ammo;
 886         if(autocvar__hud_configure)
 887         {
 888                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
 889                 ammo = 60;
 890         }
 891         else
 892                 ammo = getstati(GetAmmoStat(ammoType));
 893
 894         if(!isCurrent)
 895         {
 896                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
 897                 myPos = myPos + (mySize - mySize * scale) * 0.5;
 898                 mySize = mySize * scale;
 899         }
 900
 901         vector iconPos, textPos;
 902         if(autocvar_hud_panel_ammo_iconalign)
 903         {
 904                 iconPos = myPos + eX * 2 * mySize.y;
 905                 textPos = myPos;
 906         }
 907         else
 908         {
 909                 iconPos = myPos;
 910                 textPos = myPos + eX * mySize.y;
 911         }
 912
 913         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
 914
 915         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
 916         vector textColor;
 917         if(isInfinite)
 918                 textColor = '0.2 0.95 0';
 919         else if(isShadowed)
 920                 textColor = '0 0 0';
 921         else if(ammo < 10)
 922                 textColor = '0.8 0.04 0';
 923         else
 924                 textColor = '1 1 1';
 925
 926         float alpha;
 927         if(isCurrent)
 928                 alpha = panel_fg_alpha;
 929         else if(isShadowed)
 930                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
 931         else
 932                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
 933
 934         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
 935
 936         // Draw item
 937
 938         if(isCurrent)
 939                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 940
 941         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
 942                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
 943
 944         if(autocvar_hud_panel_ammo_text)
 945                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
 946
 947         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
 948 }
 949
 950 int nade_prevstatus;
 951 int nade_prevframe;
 952 float nade_statuschange_time;
 953 void HUD_Ammo(void)
 954 {
 955         if(intermission == 2) return;
 956         if(hud != HUD_NORMAL) return;
 957         if(!autocvar__hud_configure)
 958         {
 959                 if(!autocvar_hud_panel_ammo) return;
 960                 if(spectatee_status == -1) return;
 961         }
 962
 963         HUD_Panel_UpdateCvars();
 964
 965         draw_beginBoldFont();
 966
 967         vector pos, mySize;
 968         pos = panel_pos;
 969         mySize = panel_size;
 970
 971         HUD_Panel_DrawBg(1);
 972         if(panel_bg_padding)
 973         {
 974                 pos += '1 1 0' * panel_bg_padding;
 975                 mySize -= '2 2 0' * panel_bg_padding;
 976         }
 977
 978         int rows = 0, columns, row, column;
 979         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
 980         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
 981         float nade_statuschange_elapsedtime;
 982         int total_ammo_count;
 983
 984         vector ammo_size;
 985         if (autocvar_hud_panel_ammo_onlycurrent)
 986                 total_ammo_count = 1;
 987         else
 988                 total_ammo_count = AMMO_COUNT;
 989
 990         if(draw_nades)
 991         {
 992                 ++total_ammo_count;
 993                 if (nade_cnt != nade_prevframe)
 994                 {
 995                         nade_statuschange_time = time;
 996                         nade_prevstatus = nade_prevframe;
 997                         nade_prevframe = nade_cnt;
 998                 }
 999         }
1000         else
1001                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1002
1003         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1004         columns = ceil((total_ammo_count)/rows);
1005         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1006
1007         vector offset = '0 0 0'; // fteqcc sucks
1008         float newSize;
1009         if(ammo_size.x/ammo_size.y > 3)
1010         {
1011                 newSize = 3 * ammo_size.y;
1012                 offset.x = ammo_size.x - newSize;
1013                 pos.x += offset.x/2;
1014                 ammo_size.x = newSize;
1015         }
1016         else
1017         {
1018                 newSize = 1/3 * ammo_size.x;
1019                 offset.y = ammo_size.y - newSize;
1020                 pos.y += offset.y/2;
1021                 ammo_size.y = newSize;
1022         }
1023
1024         int i;
1025         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1026         row = column = 0;
1027         if(autocvar_hud_panel_ammo_onlycurrent)
1028         {
1029                 if(autocvar__hud_configure)
1030                 {
1031                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1032                 }
1033                 else
1034                 {
1035                         DrawAmmoItem(
1036                                 pos,
1037                                 ammo_size,
1038                                 (get_weaponinfo(switchweapon)).ammo_field,
1039                                 true,
1040                                 infinite_ammo
1041                         );
1042                 }
1043
1044                 ++row;
1045                 if(row >= rows)
1046                 {
1047                         row = 0;
1048                         column = column + 1;
1049                 }
1050         }
1051         else
1052         {
1053                 .int ammotype;
1054                 row = column = 0;
1055                 for(i = 0; i < AMMO_COUNT; ++i)
1056                 {
1057                         ammotype = GetAmmoFieldFromNum(i);
1058                         DrawAmmoItem(
1059                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1060                                 ammo_size,
1061                                 ammotype,
1062                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1063                                 infinite_ammo
1064                         );
1065
1066                         ++row;
1067                         if(row >= rows)
1068                         {
1069                                 row = 0;
1070                                 column = column + 1;
1071                         }
1072                 }
1073         }
1074
1075         if (draw_nades)
1076         {
1077                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1078
1079                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1080
1081                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1082         }
1083
1084         draw_endBoldFont();
1085 }
1086
1087 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1088 {
1089         vector newPos = '0 0 0', newSize = '0 0 0';
1090         vector picpos, numpos;
1091
1092         if (vertical)
1093         {
1094                 if(mySize.y/mySize.x > 2)
1095                 {
1096                         newSize.y = 2 * mySize.x;
1097                         newSize.x = mySize.x;
1098
1099                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1100                         newPos.x = myPos.x;
1101                 }
1102                 else
1103                 {
1104                         newSize.x = 1/2 * mySize.y;
1105                         newSize.y = mySize.y;
1106
1107                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1108                         newPos.y = myPos.y;
1109                 }
1110
1111                 if(icon_right_align)
1112                 {
1113                         numpos = newPos;
1114                         picpos = newPos + eY * newSize.x;
1115                 }
1116                 else
1117                 {
1118                         picpos = newPos;
1119                         numpos = newPos + eY * newSize.x;
1120                 }
1121
1122                 newSize.y /= 2;
1123                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1124                 // make number smaller than icon, it looks better
1125                 // reduce only y to draw numbers with different number of digits with the same y size
1126                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1127                 newSize.y *= 0.7;
1128                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1129                 return;
1130         }
1131
1132         if(mySize.x/mySize.y > 3)
1133         {
1134                 newSize.x = 3 * mySize.y;
1135                 newSize.y = mySize.y;
1136
1137                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1138                 newPos.y = myPos.y;
1139         }
1140         else
1141         {
1142                 newSize.y = 1/3 * mySize.x;
1143                 newSize.x = mySize.x;
1144
1145                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1146                 newPos.x = myPos.x;
1147         }
1148
1149         if(icon_right_align) // right align
1150         {
1151                 numpos = newPos;
1152                 picpos = newPos + eX * 2 * newSize.y;
1153         }
1154         else // left align
1155         {
1156                 numpos = newPos + eX * newSize.y;
1157                 picpos = newPos;
1158         }
1159
1160         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1161         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1162         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1163         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1164 }
1165
1166 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1167 {
1168         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1169 }
1170
1171 // Powerups (#2)
1172 //
1173
1174 // Powerup item fields (reusing existing fields)
1175 .string message;  // Human readable name
1176 .string netname;  // Icon name
1177 .vector colormod; // Color
1178 .float count;     // Time left
1179 .float lifetime;  // Maximum time
1180
1181 entity powerupItems;
1182 int powerupItemsCount;
1183
1184 void resetPowerupItems()
1185 {
1186         entity item;
1187         for(item = powerupItems; item; item = item.chain)
1188                 item.count = 0;
1189
1190         powerupItemsCount = 0;
1191 }
1192
1193 void addPowerupItem(string name, string icon, vector color, float currentTime, float lifeTime)
1194 {
1195         if(!powerupItems)
1196                 powerupItems = spawn();
1197
1198         entity item;
1199         for(item = powerupItems; item.count; item = item.chain)
1200                 if(!item.chain)
1201                         item.chain = spawn();
1202
1203         item.message  = name;
1204         item.netname  = icon;
1205         item.colormod = color;
1206         item.count    = currentTime;
1207         item.lifetime = lifeTime;
1208
1209         ++powerupItemsCount;
1210 }
1211
1212 int getPowerupItemAlign(int align, int column, int row, int columns, int rows, bool isVertical)
1213 {
1214         if(align < 2)
1215                 return align;
1216
1217         bool isTop    =  isVertical && rows > 1 && row == 0;
1218         bool isBottom =  isVertical && rows > 1 && row == rows-1;
1219         bool isLeft   = !isVertical && columns > 1 && column == 0;
1220         bool isRight  = !isVertical && columns > 1 && column == columns-1;
1221
1222         if(isTop    || isLeft)  return (align == 2) ? 1 : 0;
1223         if(isBottom || isRight) return (align == 2) ? 0 : 1;
1224
1225         return 2;
1226 }
1227
1228 void HUD_Powerups()
1229 {
1230         if(intermission == 2) return;
1231
1232         int allItems = getstati(STAT_ITEMS, 0, 24);
1233         int allBuffs = getstati(STAT_BUFFS, 0, 24);
1234         int strengthTime, shieldTime, superTime;
1235
1236         // Initialize items
1237         if(!autocvar__hud_configure)
1238         {
1239                 if(!autocvar_hud_panel_powerups) return;
1240                 if(spectatee_status == -1) return;
1241                 if(getstati(STAT_HEALTH) <= 0) return;
1242                 if(!(allItems & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON)) && !allBuffs) return;
1243
1244                 strengthTime = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1245                 shieldTime = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1246                 superTime = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1247
1248                 if(allItems & IT_UNLIMITED_SUPERWEAPONS)
1249                         superTime = 99;
1250
1251                 // Prevent stuff to show up on mismatch that will be fixed next frame
1252                 if(!(allItems & IT_SUPERWEAPON))
1253                         superTime = 0;
1254         }
1255         else
1256         {
1257                 strengthTime = 15;
1258                 shieldTime = 27;
1259                 superTime = 13;
1260                 allBuffs = 0;
1261         }
1262
1263         // Add items to linked list
1264         resetPowerupItems();
1265
1266         if(strengthTime)
1267                 addPowerupItem("Strength", "strength", autocvar_hud_progressbar_strength_color, strengthTime, 30);
1268         if(shieldTime)
1269                 addPowerupItem("Shield", "shield", autocvar_hud_progressbar_shield_color, shieldTime, 30);
1270         if(superTime)
1271                 addPowerupItem("Superweapons", "superweapons", autocvar_hud_progressbar_superweapons_color, superTime, 30);
1272
1273         FOREACH(Buffs, it.m_itemid & allBuffs, LAMBDA(
1274                 addPowerupItem(it.m_prettyName, strcat("buff_", it.m_name), it.m_color, bound(0, getstatf(STAT_BUFF_TIME) - time, 99), 60);
1275         ));
1276
1277         if(!powerupItemsCount)
1278                 return;
1279
1280         // Draw panel background
1281         HUD_Panel_UpdateCvars();
1282         HUD_Panel_DrawBg(1);
1283
1284         // Set drawing area
1285         vector pos = panel_pos;
1286         vector size = panel_size;
1287         bool isVertical = size.y > size.x;
1288
1289         if(panel_bg_padding)
1290         {
1291                 pos += '1 1 0' * panel_bg_padding;
1292                 size -= '2 2 0' * panel_bg_padding;
1293         }
1294
1295         // Find best partitioning of the drawing area
1296         const float DESIRED_ASPECT = 6;
1297         float aspect = 0, a;
1298         int columns = 0, c;
1299         int rows = 0, r;
1300         int i = 1;
1301
1302         do
1303         {
1304                 c = floor(powerupItemsCount / i);
1305                 r = ceil(powerupItemsCount / c);
1306                 a = isVertical ? (size.y/r) / (size.x/c) : (size.x/c) / (size.y/r);
1307
1308                 if(i == 1 || fabs(DESIRED_ASPECT - a) < fabs(DESIRED_ASPECT - aspect))
1309                 {
1310                         aspect = a;
1311                         columns = c;
1312                         rows = r;
1313                 }
1314         }
1315         while(++i <= powerupItemsCount);
1316
1317         // Prevent single items from getting too wide
1318         if(powerupItemsCount == 1 && aspect > DESIRED_ASPECT)
1319         {
1320                 if(isVertical)
1321                 {
1322                         size.y *= 0.5;
1323                         pos.y += size.y * 0.5;
1324                 }
1325                 else
1326                 {
1327                         size.x *= 0.5;
1328                         pos.x += size.x * 0.5;
1329                 }
1330         }
1331
1332         // Draw items from linked list
1333         vector itemPos = pos;
1334         vector itemSize = eX * (size.x / columns) + eY * (size.y / rows);
1335         vector textColor = '1 1 1';
1336
1337         int fullSeconds = 0;
1338         int align = 0;
1339         int column = 0;
1340         int row = 0;
1341
1342         draw_beginBoldFont();
1343         for(entity item = powerupItems; item.count; item = item.chain)
1344         {
1345                 itemPos = eX * (pos.x + column * itemSize.x) + eY * (pos.y + row * itemSize.y);
1346
1347                 // Draw progressbar
1348                 if(autocvar_hud_panel_powerups_progressbar)
1349                 {
1350                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_baralign, column, row, columns, rows, isVertical);
1351                         HUD_Panel_DrawProgressBar(itemPos, itemSize, "progressbar", item.count / item.lifetime, isVertical, align, item.colormod, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1352                 }
1353
1354                 // Draw icon and text
1355                 if(autocvar_hud_panel_powerups_text)
1356                 {
1357                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_iconalign, column, row, columns, rows, isVertical);
1358                         fullSeconds = ceil(item.count);
1359                         textColor = '0.6 0.6 0.6' + (item.colormod * 0.4);
1360
1361                         if(item.count > 1)
1362                                 DrawNumIcon(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha);
1363                         if(item.count <= 5)
1364                                 DrawNumIcon_expanding(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha, bound(0, (fullSeconds - item.count) / 0.5, 1));
1365                 }
1366
1367                 // Determine next section
1368                 if(isVertical)
1369                 {
1370                         if(++column >= columns)
1371                         {
1372                                 column = 0;
1373                                 ++row;
1374                         }
1375                 }
1376                 else
1377                 {
1378                         if(++row >= rows)
1379                         {
1380                                 row = 0;
1381                                 ++column;
1382                         }
1383                 }
1384         }
1385         draw_endBoldFont();
1386 }
1387
1388 // Health/armor (#3)
1389 //
1390
1391
1392 void HUD_HealthArmor(void)
1393 {
1394         int armor, health, fuel;
1395         if(intermission == 2) return;
1396         if(!autocvar__hud_configure)
1397         {
1398                 if(!autocvar_hud_panel_healtharmor) return;
1399                 if(hud != HUD_NORMAL) return;
1400                 if(spectatee_status == -1) return;
1401
1402                 health = getstati(STAT_HEALTH);
1403                 if(health <= 0)
1404                 {
1405                         prev_health = -1;
1406                         return;
1407                 }
1408                 armor = getstati(STAT_ARMOR);
1409
1410                 // code to check for spectatee_status changes is in Ent_ClientData()
1411                 // prev_p_health and prev_health can be set to -1 there
1412
1413                 if (prev_p_health == -1)
1414                 {
1415                         // no effect
1416                         health_beforedamage = 0;
1417                         armor_beforedamage = 0;
1418                         health_damagetime = 0;
1419                         armor_damagetime = 0;
1420                         prev_health = health;
1421                         prev_armor = armor;
1422                         old_p_health = health;
1423                         old_p_armor = armor;
1424                         prev_p_health = health;
1425                         prev_p_armor = armor;
1426                 }
1427                 else if (prev_health == -1)
1428                 {
1429                         //start the load effect
1430                         health_damagetime = 0;
1431                         armor_damagetime = 0;
1432                         prev_health = 0;
1433                         prev_armor = 0;
1434                 }
1435                 fuel = getstati(STAT_FUEL);
1436         }
1437         else
1438         {
1439                 health = 150;
1440                 armor = 75;
1441                 fuel = 20;
1442         }
1443
1444         HUD_Panel_UpdateCvars();
1445
1446         draw_beginBoldFont();
1447
1448         vector pos, mySize;
1449         pos = panel_pos;
1450         mySize = panel_size;
1451
1452         HUD_Panel_DrawBg(1);
1453         if(panel_bg_padding)
1454         {
1455                 pos += '1 1 0' * panel_bg_padding;
1456                 mySize -= '2 2 0' * panel_bg_padding;
1457         }
1458
1459         int baralign = autocvar_hud_panel_healtharmor_baralign;
1460         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1461
1462     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1463     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1464         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1465         {
1466                 vector v;
1467                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1468
1469                 float x;
1470                 x = floor(v.x + 1);
1471
1472         float maxtotal = maxhealth + maxarmor;
1473                 string biggercount;
1474                 if(v.z) // NOT fully armored
1475                 {
1476                         biggercount = "health";
1477                         if(autocvar_hud_panel_healtharmor_progressbar)
1478                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1479                         if(armor)
1480             if(autocvar_hud_panel_healtharmor_text)
1481                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1482                 }
1483                 else
1484                 {
1485                         biggercount = "armor";
1486                         if(autocvar_hud_panel_healtharmor_progressbar)
1487                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1488                         if(health)
1489             if(autocvar_hud_panel_healtharmor_text)
1490                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1491                 }
1492         if(autocvar_hud_panel_healtharmor_text)
1493                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1494
1495                 if(fuel)
1496                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1497         }
1498         else
1499         {
1500                 float panel_ar = mySize.x/mySize.y;
1501                 bool is_vertical = (panel_ar < 1);
1502                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1503                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1504                 {
1505                         mySize.x *= 0.5;
1506                         if (autocvar_hud_panel_healtharmor_flip)
1507                                 health_offset.x = mySize.x;
1508                         else
1509                                 armor_offset.x = mySize.x;
1510                 }
1511                 else
1512                 {
1513                         mySize.y *= 0.5;
1514                         if (autocvar_hud_panel_healtharmor_flip)
1515                                 health_offset.y = mySize.y;
1516                         else
1517                                 armor_offset.y = mySize.y;
1518                 }
1519
1520                 bool health_baralign, armor_baralign, fuel_baralign;
1521                 bool health_iconalign, armor_iconalign;
1522                 if (autocvar_hud_panel_healtharmor_flip)
1523                 {
1524                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1525                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1526                         fuel_baralign = health_baralign;
1527                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1528                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1529                 }
1530                 else
1531                 {
1532                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1533                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1534                         fuel_baralign = armor_baralign;
1535                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1536                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1537                 }
1538
1539                 //if(health)
1540                 {
1541                         if(autocvar_hud_panel_healtharmor_progressbar)
1542                         {
1543                                 float p_health, pain_health_alpha;
1544                                 p_health = health;
1545                                 pain_health_alpha = 1;
1546                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1547                                 {
1548                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1549                                         {
1550                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1551                                                 {
1552                                                         if (time - old_p_healthtime < 1)
1553                                                                 old_p_health = prev_p_health;
1554                                                         else
1555                                                                 old_p_health = prev_health;
1556                                                         old_p_healthtime = time;
1557                                                 }
1558                                                 if (time - old_p_healthtime < 1)
1559                                                 {
1560                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1561                                                         prev_p_health = p_health;
1562                                                 }
1563                                         }
1564                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1565                                         {
1566                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1567                                                 {
1568                                                         if (time - health_damagetime >= 1)
1569                                                                 health_beforedamage = prev_health;
1570                                                         health_damagetime = time;
1571                                                 }
1572                                                 if (time - health_damagetime < 1)
1573                                                 {
1574                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1575                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1576                                                 }
1577                                         }
1578                                         prev_health = health;
1579
1580                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1581                                         {
1582                                                 float BLINK_FACTOR = 0.15;
1583                                                 float BLINK_BASE = 0.85;
1584                                                 float BLINK_FREQ = 9;
1585                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1586                                         }
1587                                 }
1588                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1589                         }
1590                         if(autocvar_hud_panel_healtharmor_text)
1591                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1592                 }
1593
1594                 if(armor)
1595                 {
1596                         if(autocvar_hud_panel_healtharmor_progressbar)
1597                         {
1598                                 float p_armor;
1599                                 p_armor = armor;
1600                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1601                                 {
1602                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1603                                         {
1604                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1605                                                 {
1606                                                         if (time - old_p_armortime < 1)
1607                                                                 old_p_armor = prev_p_armor;
1608                                                         else
1609                                                                 old_p_armor = prev_armor;
1610                                                         old_p_armortime = time;
1611                                                 }
1612                                                 if (time - old_p_armortime < 1)
1613                                                 {
1614                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1615                                                         prev_p_armor = p_armor;
1616                                                 }
1617                                         }
1618                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1619                                         {
1620                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1621                                                 {
1622                                                         if (time - armor_damagetime >= 1)
1623                                                                 armor_beforedamage = prev_armor;
1624                                                         armor_damagetime = time;
1625                                                 }
1626                                                 if (time - armor_damagetime < 1)
1627                                                 {
1628                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1629                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1630                                                 }
1631                                         }
1632                                         prev_armor = armor;
1633                                 }
1634                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1635                         }
1636                         if(autocvar_hud_panel_healtharmor_text)
1637                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1638                 }
1639
1640                 if(fuel)
1641                 {
1642                         if (is_vertical)
1643                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1644                         else
1645                                 mySize.y *= 0.2;
1646                         if (panel_ar >= 4)
1647                                 mySize.x *= 2; //restore full panel size
1648                         else if (panel_ar < 1/4)
1649                                 mySize.y *= 2; //restore full panel size
1650                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1651                 }
1652         }
1653
1654         draw_endBoldFont();
1655 }
1656
1657 // Notification area (#4)
1658 //
1659
1660 void HUD_Notify_Push(string icon, string attacker, string victim)
1661 {
1662         if (icon == "")
1663                 return;
1664
1665         ++notify_count;
1666         --notify_index;
1667
1668         if (notify_index == -1)
1669                 notify_index = NOTIFY_MAX_ENTRIES-1;
1670
1671         // Free old strings
1672         if (notify_attackers[notify_index])
1673                 strunzone(notify_attackers[notify_index]);
1674
1675         if (notify_victims[notify_index])
1676                 strunzone(notify_victims[notify_index]);
1677
1678         if (notify_icons[notify_index])
1679                 strunzone(notify_icons[notify_index]);
1680
1681         // Allocate new strings
1682         if (victim != "")
1683         {
1684                 notify_attackers[notify_index] = strzone(attacker);
1685                 notify_victims[notify_index] = strzone(victim);
1686         }
1687         else
1688         {
1689                 // In case of a notification without a victim, the attacker
1690                 // is displayed on the victim's side. Instead of special
1691                 // treatment later on, we can simply switch them here.
1692                 notify_attackers[notify_index] = string_null;
1693                 notify_victims[notify_index] = strzone(attacker);
1694         }
1695
1696         notify_icons[notify_index] = strzone(icon);
1697         notify_times[notify_index] = time;
1698 }
1699
1700 void HUD_Notify(void)
1701 {
1702         if(intermission == 2) return;
1703         if (!autocvar__hud_configure)
1704                 if (!autocvar_hud_panel_notify)
1705                         return;
1706
1707         HUD_Panel_UpdateCvars();
1708         HUD_Panel_DrawBg(1);
1709
1710         if (!autocvar__hud_configure)
1711                 if (notify_count == 0)
1712                         return;
1713
1714         vector pos, size;
1715         pos  = panel_pos;
1716         size = panel_size;
1717
1718         if (panel_bg_padding)
1719         {
1720                 pos  += '1 1 0' * panel_bg_padding;
1721                 size -= '2 2 0' * panel_bg_padding;
1722         }
1723
1724         float fade_start = max(0, autocvar_hud_panel_notify_time);
1725         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1726         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1727
1728         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1729         float entry_height = size.y / entry_count;
1730
1731         float panel_width_half = size.x * 0.5;
1732         float icon_width_half = entry_height * icon_aspect / 2;
1733         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1734
1735         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1736         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1737         vector icon_left = eX * (panel_width_half - icon_width_half);
1738         vector attacker_right = eX * name_maxwidth;
1739         vector victim_left = eX * (size.x - name_maxwidth);
1740
1741         vector attacker_pos, victim_pos, icon_pos;
1742         string attacker, victim, icon;
1743         int i, j, count, step, limit;
1744         float alpha;
1745
1746         if (autocvar_hud_panel_notify_flip)
1747         {
1748                 // Order items from the top down
1749                 i = 0;
1750                 step = +1;
1751                 limit = entry_count;
1752         }
1753         else
1754         {
1755                 // Order items from the bottom up
1756                 i = entry_count - 1;
1757                 step = -1;
1758                 limit = -1;
1759         }
1760
1761         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1762         {
1763                 if(autocvar__hud_configure)
1764                 {
1765                         attacker = sprintf(_("Player %d"), count + 1);
1766                         victim = sprintf(_("Player %d"), count + 2);
1767                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1768                         alpha = bound(0, 1.2 - count / entry_count, 1);
1769                 }
1770                 else
1771                 {
1772                         if (j == NOTIFY_MAX_ENTRIES)
1773                                 j = 0;
1774
1775                         if (notify_times[j] + fade_start > time)
1776                                 alpha = 1;
1777                         else if (fade_time != 0)
1778                         {
1779                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1780                                 if (alpha == 0)
1781                                         break;
1782                         }
1783                         else
1784                                 break;
1785
1786                         attacker = notify_attackers[j];
1787                         victim = notify_victims[j];
1788                         icon = notify_icons[j];
1789                 }
1790
1791                 if (icon != "" && victim != "")
1792                 {
1793                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1794
1795                         icon_pos = pos + icon_left + eY * i * entry_height;
1796                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1797
1798                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1799                         victim_pos = pos + victim_left + name_top;
1800                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1801
1802                         if (attacker != "")
1803                         {
1804                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1805                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1806                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1807                         }
1808                 }
1809         }
1810
1811         notify_count = count;
1812 }
1813
1814 void HUD_Timer(void)
1815 {
1816         if(intermission == 2) return;
1817         if(!autocvar__hud_configure)
1818         {
1819                 if(!autocvar_hud_panel_timer) return;
1820         }
1821
1822         HUD_Panel_UpdateCvars();
1823
1824         draw_beginBoldFont();
1825
1826         vector pos, mySize;
1827         pos = panel_pos;
1828         mySize = panel_size;
1829
1830         HUD_Panel_DrawBg(1);
1831         if(panel_bg_padding)
1832         {
1833                 pos += '1 1 0' * panel_bg_padding;
1834                 mySize -= '2 2 0' * panel_bg_padding;
1835         }
1836
1837         string timer;
1838         float timelimit, elapsedTime, timeleft, minutesLeft;
1839
1840         timelimit = getstatf(STAT_TIMELIMIT);
1841
1842         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1843         timeleft = ceil(timeleft);
1844
1845         minutesLeft = floor(timeleft / 60);
1846
1847         vector timer_color;
1848         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1849                 timer_color = '1 1 1'; //white
1850         else if(minutesLeft >= 1)
1851                 timer_color = '1 1 0'; //yellow
1852         else
1853                 timer_color = '1 0 0'; //red
1854
1855         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1856                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1857                         //while restart is still active, show 00:00
1858                         timer = seconds_tostring(0);
1859                 } else {
1860                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1861                         timer = seconds_tostring(elapsedTime);
1862                 }
1863         } else {
1864                 timer = seconds_tostring(timeleft);
1865         }
1866
1867         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1868
1869         draw_endBoldFont();
1870 }
1871
1872 // Radar (#6)
1873 //
1874
1875 float HUD_Radar_Clickable()
1876 {
1877         return hud_panel_radar_mouse && !hud_panel_radar_temp_hidden;
1878 }
1879
1880 void HUD_Radar_Show_Maximized(bool doshow,float clickable)
1881 {
1882         hud_panel_radar_maximized = doshow;
1883         hud_panel_radar_temp_hidden = 0;
1884
1885         if ( doshow )
1886         {
1887                 if (clickable)
1888                 {
1889                         if(autocvar_hud_cursormode)
1890                                 setcursormode(1);
1891                         hud_panel_radar_mouse = 1;
1892                 }
1893         }
1894         else if ( hud_panel_radar_mouse )
1895         {
1896                 hud_panel_radar_mouse = 0;
1897                 mouseClicked = 0;
1898                 if(autocvar_hud_cursormode)
1899                 if(!mv_active)
1900                         setcursormode(0);
1901         }
1902 }
1903 void HUD_Radar_Hide_Maximized()
1904 {
1905         HUD_Radar_Show_Maximized(false,false);
1906 }
1907
1908
1909 float HUD_Radar_InputEvent(float bInputType, float nPrimary, float nSecondary)
1910 {
1911         if(!hud_panel_radar_maximized || !hud_panel_radar_mouse ||
1912                 autocvar__hud_configure || mv_active)
1913                 return false;
1914
1915         if(bInputType == 3)
1916         {
1917                 mousepos_x = nPrimary;
1918                 mousepos_y = nSecondary;
1919                 return true;
1920         }
1921
1922         if(nPrimary == K_MOUSE1)
1923         {
1924                 if(bInputType == 0) // key pressed
1925                         mouseClicked |= S_MOUSE1;
1926                 else if(bInputType == 1) // key released
1927                         mouseClicked -= (mouseClicked & S_MOUSE1);
1928         }
1929         else if(nPrimary == K_MOUSE2)
1930         {
1931                 if(bInputType == 0) // key pressed
1932                         mouseClicked |= S_MOUSE2;
1933                 else if(bInputType == 1) // key released
1934                         mouseClicked -= (mouseClicked & S_MOUSE2);
1935         }
1936         else if ( nPrimary == K_ESCAPE && bInputType == 0 )
1937         {
1938                 HUD_Radar_Hide_Maximized();
1939         }
1940         else
1941         {
1942                 // allow console/use binds to work without hiding the map
1943                 string con_keys;
1944                 float keys;
1945                 float i;
1946                 con_keys = strcat(findkeysforcommand("toggleconsole", 0)," ",findkeysforcommand("+use", 0)) ;
1947                 keys = tokenize(con_keys); // findkeysforcommand returns data for this
1948                 for (i = 0; i < keys; ++i)
1949                 {
1950                         if(nPrimary == stof(argv(i)))
1951                                 return false;
1952                 }
1953
1954                 if ( getstati(STAT_HEALTH) <= 0 )
1955                 {
1956                         // Show scoreboard
1957                         if ( bInputType < 2 )
1958                         {
1959                                 con_keys = findkeysforcommand("+showscores", 0);
1960                                 keys = tokenize(con_keys);
1961                                 for (i = 0; i < keys; ++i)
1962                                 {
1963                                         if ( nPrimary == stof(argv(i)) )
1964                                         {
1965                                                 hud_panel_radar_temp_hidden = bInputType == 0;
1966                                                 return false;
1967                                         }
1968                                 }
1969                         }
1970                 }
1971                 else if ( bInputType == 0 )
1972                         HUD_Radar_Hide_Maximized();
1973
1974                 return false;
1975         }
1976
1977         return true;
1978 }
1979
1980 void HUD_Radar_Mouse()
1981 {
1982         if ( !hud_panel_radar_mouse ) return;
1983         if(mv_active) return;
1984
1985         if ( intermission )
1986         {
1987                 HUD_Radar_Hide_Maximized();
1988                 return;
1989         }
1990
1991         if(mouseClicked & S_MOUSE2)
1992         {
1993                 HUD_Radar_Hide_Maximized();
1994                 return;
1995         }
1996
1997         if(!autocvar_hud_cursormode)
1998         {
1999                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
2000
2001                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
2002                 mousepos_y = bound(0, mousepos_y, vid_conheight);
2003         }
2004
2005         HUD_Panel_UpdateCvars();
2006
2007
2008         panel_size = autocvar_hud_panel_radar_maximized_size;
2009         panel_size_x = bound(0.2, panel_size_x, 1) * vid_conwidth;
2010         panel_size_y = bound(0.2, panel_size_y, 1) * vid_conheight;
2011         panel_pos_x = (vid_conwidth - panel_size_x) / 2;
2012         panel_pos_y = (vid_conheight - panel_size_y) / 2;
2013
2014         if(mouseClicked & S_MOUSE1)
2015         {
2016                 // click outside
2017                 if ( mousepos_x < panel_pos_x || mousepos_x > panel_pos_x + panel_size_x ||
2018                          mousepos_y < panel_pos_y || mousepos_y > panel_pos_y + panel_size_y )
2019                 {
2020                         HUD_Radar_Hide_Maximized();
2021                         return;
2022                 }
2023                 vector pos = teamradar_texcoord_to_3dcoord(teamradar_2dcoord_to_texcoord(mousepos),view_origin_z);
2024                 localcmd(sprintf("cmd ons_spawn %f %f %f",pos_x,pos_y,pos_z));
2025
2026                 HUD_Radar_Hide_Maximized();
2027                 return;
2028         }
2029
2030
2031         const vector cursor_size = '32 32 0';
2032         drawpic(mousepos-'8 4 0', strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursor_size, '1 1 1', 0.8, DRAWFLAG_NORMAL);
2033 }
2034
2035 void HUD_Radar(void)
2036 {
2037         if(intermission == 2) return;
2038         if (!autocvar__hud_configure)
2039         {
2040                 if (hud_panel_radar_maximized)
2041                 {
2042                         if (!hud_draw_maximized) return;
2043                 }
2044                 else
2045                 {
2046                         if (autocvar_hud_panel_radar == 0) return;
2047                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
2048                         if(radar_panel_modified)
2049                         {
2050                                 panel.update_time = time; // forces reload of panel attributes
2051                                 radar_panel_modified = false;
2052                         }
2053                 }
2054         }
2055
2056         if ( hud_panel_radar_temp_hidden )
2057                 return;
2058
2059         HUD_Panel_UpdateCvars();
2060
2061         float f = 0;
2062
2063         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2064         {
2065                 panel_size = autocvar_hud_panel_radar_maximized_size;
2066                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2067                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2068                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2069                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2070
2071                 string panel_bg;
2072                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2073                 if(precache_pic(panel_bg) == "")
2074                         panel_bg = "gfx/hud/default/border_default"; // fallback
2075                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2076                         radar_panel_modified = true;
2077                 if(panel.current_panel_bg)
2078                         strunzone(panel.current_panel_bg);
2079                 panel.current_panel_bg = strzone(panel_bg);
2080
2081                 switch(hud_panel_radar_maximized_zoommode)
2082                 {
2083                         default:
2084                         case 0:
2085                                 f = current_zoomfraction;
2086                                 break;
2087                         case 1:
2088                                 f = 1 - current_zoomfraction;
2089                                 break;
2090                         case 2:
2091                                 f = 0;
2092                                 break;
2093                         case 3:
2094                                 f = 1;
2095                                 break;
2096                 }
2097
2098                 switch(hud_panel_radar_maximized_rotation)
2099                 {
2100                         case 0:
2101                                 teamradar_angle = view_angles.y - 90;
2102                                 break;
2103                         default:
2104                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2105                                 break;
2106                 }
2107         }
2108         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2109         {
2110                 switch(hud_panel_radar_zoommode)
2111                 {
2112                         default:
2113                         case 0:
2114                                 f = current_zoomfraction;
2115                                 break;
2116                         case 1:
2117                                 f = 1 - current_zoomfraction;
2118                                 break;
2119                         case 2:
2120                                 f = 0;
2121                                 break;
2122                         case 3:
2123                                 f = 1;
2124                                 break;
2125                 }
2126
2127                 switch(hud_panel_radar_rotation)
2128                 {
2129                         case 0:
2130                                 teamradar_angle = view_angles.y - 90;
2131                                 break;
2132                         default:
2133                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2134                                 break;
2135                 }
2136         }
2137
2138         vector pos, mySize;
2139         pos = panel_pos;
2140         mySize = panel_size;
2141
2142         HUD_Panel_DrawBg(1);
2143         if(panel_bg_padding)
2144         {
2145                 pos += '1 1 0' * panel_bg_padding;
2146                 mySize -= '2 2 0' * panel_bg_padding;
2147         }
2148
2149         int color2;
2150         entity tm;
2151         float scale2d, normalsize, bigsize;
2152
2153         teamradar_origin2d = pos + 0.5 * mySize;
2154         teamradar_size2d = mySize;
2155
2156         if(minimapname == "")
2157                 return;
2158
2159         teamradar_loadcvars();
2160
2161         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2162         teamradar_size2d = mySize;
2163
2164         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2165
2166         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2167         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2168         {
2169                 // max-min distance must fit the radar in any rotation
2170                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2171         }
2172         else
2173         {
2174                 vector c0, c1, c2, c3, span;
2175                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2176                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2177                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2178                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2179                 span = '0 0 0';
2180                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2181                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2182
2183                 // max-min distance must fit the radar in x=x, y=y
2184                 bigsize = min(
2185                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2186                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2187                 );
2188         }
2189
2190         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2191         if(bigsize > normalsize)
2192                 normalsize = bigsize;
2193
2194         teamradar_size =
2195                   f * bigsize
2196                 + (1 - f) * normalsize;
2197         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2198                   f * mi_center
2199                 + (1 - f) * view_origin);
2200
2201         drawsetcliparea(
2202                 pos.x,
2203                 pos.y,
2204                 mySize.x,
2205                 mySize.y
2206         );
2207
2208         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2209
2210         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2211                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2212
2213         vector coord;
2214         vector brightcolor;
2215         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2216         {
2217                 if ( hud_panel_radar_mouse )
2218                 if ( tm.health > 0 )
2219                 if ( tm.team == myteam+1 )
2220                 {
2221                         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(tm.origin));
2222                         if ( vlen(mousepos-coord) < 8 )
2223                         {
2224                                 brightcolor_x = min(1,tm.teamradar_color_x*1.5);
2225                                 brightcolor_y = min(1,tm.teamradar_color_y*1.5);
2226                                 brightcolor_z = min(1,tm.teamradar_color_z*1.5);
2227                                 drawpic(coord - '8 8 0', "gfx/teamradar_icon_glow", '16 16 0', brightcolor, panel_fg_alpha, 0);
2228                         }
2229                 }
2230                 entity icon = RadarIcons[tm.teamradar_icon];
2231                 draw_teamradar_icon(tm.origin, icon, tm, spritelookupcolor(tm, icon.netname, tm.teamradar_color), panel_fg_alpha);
2232         }
2233         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2234         {
2235                 color2 = GetPlayerColor(tm.sv_entnum);
2236                 //if(color == NUM_SPECTATOR || color == color2)
2237                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2238         }
2239         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2240
2241         drawresetcliparea();
2242
2243         if ( hud_panel_radar_mouse )
2244         {
2245                 string message = "Click to select teleport destination";
2246
2247                 if ( getstati(STAT_HEALTH) <= 0 )
2248                 {
2249                         message = "Click to select spawn location";
2250                 }
2251
2252                 drawcolorcodedstring(pos + '0.5 0 0' * (mySize_x - stringwidth(message, true, hud_fontsize)) - '0 1 0' * hud_fontsize_y * 2,
2253                                                          message, hud_fontsize, hud_panel_radar_foreground_alpha, DRAWFLAG_NORMAL);
2254
2255                 hud_panel_radar_bottom = pos_y + mySize_y + hud_fontsize_y;
2256         }
2257 }
2258
2259 // Score (#7)
2260 //
2261 void HUD_UpdatePlayerTeams();
2262 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2263 {
2264         float score;
2265         entity tm = world, pl;
2266         int SCOREPANEL_MAX_ENTRIES = 6;
2267         float SCOREPANEL_ASPECTRATIO = 2;
2268         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2269         vector fontsize = '1 1 0' * (mySize.y/entries);
2270
2271         vector rgb, score_color;
2272         rgb = '1 1 1';
2273         score_color = '1 1 1';
2274
2275         float name_size = mySize.x*0.75;
2276         float spacing_size = mySize.x*0.04;
2277         const float highlight_alpha = 0.2;
2278         int i = 0, first_pl = 0;
2279         bool me_printed = false;
2280         string s;
2281         if (autocvar__hud_configure)
2282         {
2283                 float players_per_team = 0;
2284                 if (team_count)
2285                 {
2286                         // show team scores in the first line
2287                         float score_size = mySize.x / team_count;
2288                         players_per_team = max(2, ceil((entries - 1) / team_count));
2289                         for(i=0; i<team_count; ++i) {
2290                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2291                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2292                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2293                         }
2294                         first_pl = 1;
2295                         pos.y += fontsize.y;
2296                 }
2297                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2298                 for (i=first_pl; i<entries; ++i)
2299                 {
2300                         //simulate my score is lower than all displayed players,
2301                         //so that I don't appear at all showing pure rankings.
2302                         //This is to better show the difference between the 2 ranking views
2303                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2304                         {
2305                                 rgb = '1 1 0';
2306                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2307                                 s = GetPlayerName(player_localnum);
2308                                 score = 7;
2309                         }
2310                         else
2311                         {
2312                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2313                                 score -= 3;
2314                         }
2315
2316                         if (team_count)
2317                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2318                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2319                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2320                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2321                         pos.y += fontsize.y;
2322                 }
2323                 return;
2324         }
2325
2326         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2327                 HUD_UpdatePlayerTeams();
2328         if (team_count)
2329         {
2330                 // show team scores in the first line
2331                 float score_size = mySize.x / team_count;
2332                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2333                         if(tm.team == NUM_SPECTATOR)
2334                                 continue;
2335                         if (tm.team == myteam)
2336                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2337                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2338                         ++i;
2339                 }
2340                 first_pl = 1;
2341                 pos.y += fontsize.y;
2342                 tm = teams.sort_next;
2343         }
2344         i = first_pl;
2345
2346         do
2347         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2348         {
2349                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2350                         continue;
2351
2352                 if (i == entries-1 && !me_printed && pl != me)
2353                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2354                 {
2355                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2356                                 if (pl.team != NUM_SPECTATOR)
2357                                         break;
2358
2359                         if (pl)
2360                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2361                         else
2362                                 rgb = '1 0 0'; //last: red
2363                         pl = me;
2364                 }
2365
2366                 if (pl == me)
2367                 {
2368                         if (i == first_pl)
2369                                 rgb = '0 1 0'; //first: green
2370                         me_printed = true;
2371                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2372                 }
2373                 if (team_count)
2374                         score_color = Team_ColorRGB(pl.team) * 0.8;
2375                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2376                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2377                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2378                 pos.y += fontsize.y;
2379                 ++i;
2380         }
2381         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2382 }
2383
2384 void HUD_Score(void)
2385 {
2386         if(intermission == 2) return;
2387         if(!autocvar__hud_configure)
2388         {
2389                 if(!autocvar_hud_panel_score) return;
2390                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2391         }
2392
2393         HUD_Panel_UpdateCvars();
2394         vector pos, mySize;
2395         pos = panel_pos;
2396         mySize = panel_size;
2397
2398         HUD_Panel_DrawBg(1);
2399         if(panel_bg_padding)
2400         {
2401                 pos += '1 1 0' * panel_bg_padding;
2402                 mySize -= '2 2 0' * panel_bg_padding;
2403         }
2404
2405         float score, distribution = 0;
2406         string sign;
2407         vector distribution_color;
2408         entity tm, pl, me;
2409
2410         me = playerslots[current_player];
2411
2412         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2413                 string timer, distrtimer;
2414
2415                 pl = players.sort_next;
2416                 if(pl == me)
2417                         pl = pl.sort_next;
2418                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2419                         if(pl.scores[ps_primary] == 0)
2420                                 pl = world;
2421
2422                 score = me.(scores[ps_primary]);
2423                 timer = TIME_ENCODED_TOSTRING(score);
2424
2425                 draw_beginBoldFont();
2426                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2427                         // distribution display
2428                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2429
2430                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2431
2432                         if (distribution <= 0) {
2433                                 distribution_color = '0 1 0';
2434                                 sign = "-";
2435                         }
2436                         else {
2437                                 distribution_color = '1 0 0';
2438                                 sign = "+";
2439                         }
2440                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2441                 }
2442                 // race record display
2443                 if (distribution <= 0)
2444                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2445                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2446                 draw_endBoldFont();
2447         } else if (!teamplay) { // non-teamgames
2448                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2449                 {
2450                         HUD_Score_Rankings(pos, mySize, me);
2451                         return;
2452                 }
2453                 // me vector := [team/connected frags id]
2454                 pl = players.sort_next;
2455                 if(pl == me)
2456                         pl = pl.sort_next;
2457
2458                 if(autocvar__hud_configure)
2459                         distribution = 42;
2460                 else if(pl)
2461                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2462                 else
2463                         distribution = 0;
2464
2465                 score = me.(scores[ps_primary]);
2466                 if(autocvar__hud_configure)
2467                         score = 123;
2468
2469                 if(distribution >= 5)
2470                         distribution_color = eY;
2471                 else if(distribution >= 0)
2472                         distribution_color = '1 1 1';
2473                 else if(distribution >= -5)
2474                         distribution_color = '1 1 0';
2475                 else
2476                         distribution_color = eX;
2477
2478                 string distribution_str;
2479                 distribution_str = ftos(distribution);
2480                 draw_beginBoldFont();
2481                 if (distribution >= 0)
2482                 {
2483                         if (distribution > 0)
2484                                 distribution_str = strcat("+", distribution_str);
2485                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2486                 }
2487                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2488                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2489                 draw_endBoldFont();
2490         } else { // teamgames
2491                 float row, column, rows = 0, columns = 0;
2492                 vector offset = '0 0 0';
2493                 vector score_pos, score_size; //for scores other than myteam
2494                 if(autocvar_hud_panel_score_rankings)
2495                 {
2496                         HUD_Score_Rankings(pos, mySize, me);
2497                         return;
2498                 }
2499                 if(spectatee_status == -1)
2500                 {
2501                         rows = HUD_GetRowCount(team_count, mySize, 3);
2502                         columns = ceil(team_count/rows);
2503                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2504
2505                         float newSize;
2506                         if(score_size.x/score_size.y > 3)
2507                         {
2508                                 newSize = 3 * score_size.y;
2509                                 offset.x = score_size.x - newSize;
2510                                 pos.x += offset.x/2;
2511                                 score_size.x = newSize;
2512                         }
2513                         else
2514                         {
2515                                 newSize = 1/3 * score_size.x;
2516                                 offset.y = score_size.y - newSize;
2517                                 pos.y += offset.y/2;
2518                                 score_size.y = newSize;
2519                         }
2520                 }
2521                 else
2522                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2523
2524                 float max_fragcount;
2525                 max_fragcount = -99;
2526                 draw_beginBoldFont();
2527                 row = column = 0;
2528                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2529                         if(tm.team == NUM_SPECTATOR)
2530                                 continue;
2531                         score = tm.(teamscores[ts_primary]);
2532                         if(autocvar__hud_configure)
2533                                 score = 123;
2534
2535                         if (score > max_fragcount)
2536                                 max_fragcount = score;
2537
2538                         if (spectatee_status == -1)
2539                         {
2540                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2541                                 if (max_fragcount == score)
2542                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2543                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2544                                 ++row;
2545                                 if(row >= rows)
2546                                 {
2547                                         row = 0;
2548                                         ++column;
2549                                 }
2550                         }
2551                         else if(tm.team == myteam) {
2552                                 if (max_fragcount == score)
2553                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2554                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2555                         } else {
2556                                 if (max_fragcount == score)
2557                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2558                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2559                                 ++rows;
2560                         }
2561                 }
2562                 draw_endBoldFont();
2563         }
2564 }
2565
2566 // Race timer (#8)
2567 //
2568 void HUD_RaceTimer (void)
2569 {
2570         if(intermission == 2) return;
2571         if(!autocvar__hud_configure)
2572         {
2573                 if(!autocvar_hud_panel_racetimer) return;
2574                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2575                 if(spectatee_status == -1) return;
2576         }
2577
2578         HUD_Panel_UpdateCvars();
2579
2580         vector pos, mySize;
2581         pos = panel_pos;
2582         mySize = panel_size;
2583
2584         HUD_Panel_DrawBg(1);
2585         if(panel_bg_padding)
2586         {
2587                 pos += '1 1 0' * panel_bg_padding;
2588                 mySize -= '2 2 0' * panel_bg_padding;
2589         }
2590
2591         // always force 4:1 aspect
2592         vector newSize = '0 0 0';
2593         if(mySize.x/mySize.y > 4)
2594         {
2595                 newSize.x = 4 * mySize.y;
2596                 newSize.y = mySize.y;
2597
2598                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2599         }
2600         else
2601         {
2602                 newSize.y = 1/4 * mySize.x;
2603                 newSize.x = mySize.x;
2604
2605                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2606         }
2607         mySize = newSize;
2608
2609         float a, t;
2610         string s, forcetime;
2611
2612         if(autocvar__hud_configure)
2613         {
2614                 s = "0:13:37";
2615                 draw_beginBoldFont();
2616                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2617                 draw_endBoldFont();
2618                 s = _("^1Intermediate 1 (+15.42)");
2619                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2620                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2621                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2622         }
2623         else if(race_checkpointtime)
2624         {
2625                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2626                 s = "";
2627                 forcetime = "";
2628                 if(a > 0) // just hit a checkpoint?
2629                 {
2630                         if(race_checkpoint != 254)
2631                         {
2632                                 if(race_time && race_previousbesttime)
2633                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2634                                 else
2635                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2636                                 if(race_time)
2637                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2638                         }
2639                 }
2640                 else
2641                 {
2642                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2643                         {
2644                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2645                                 if(a > 0) // next one?
2646                                 {
2647                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2648                                 }
2649                         }
2650                 }
2651
2652                 if(s != "" && a > 0)
2653                 {
2654                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2655                 }
2656
2657                 if(race_penaltytime)
2658                 {
2659                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2660                         if(a > 0)
2661                         {
2662                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2663                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2664                         }
2665                 }
2666
2667                 draw_beginBoldFont();
2668
2669                 if(forcetime != "")
2670                 {
2671                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2672                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2673                 }
2674                 else
2675                         a = 1;
2676
2677                 if(race_laptime && race_checkpoint != 255)
2678                 {
2679                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2680                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2681                 }
2682
2683                 draw_endBoldFont();
2684         }
2685         else
2686         {
2687                 if(race_mycheckpointtime)
2688                 {
2689                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2690                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2691                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2692                 }
2693                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2694                 {
2695                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2696                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2697                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2698                 }
2699
2700                 if(race_penaltytime && !race_penaltyaccumulator)
2701                 {
2702                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2703                         a = bound(0, (1 + t - time), 1);
2704                         if(a > 0)
2705                         {
2706                                 if(time < t)
2707                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2708                                 else
2709                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2710                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2711                         }
2712                 }
2713         }
2714 }
2715
2716 // Vote window (#9)
2717 //
2718
2719 void HUD_Vote(void)
2720 {
2721         if(intermission == 2) return;
2722         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2723         {
2724                 vote_active = 1;
2725                 if (autocvar__hud_configure)
2726                 {
2727                         vote_yescount = 0;
2728                         vote_nocount = 0;
2729                         LOG_INFO(_("^1You must answer before entering hud configure mode\n"));
2730                         cvar_set("_hud_configure", "0");
2731                 }
2732                 if(vote_called_vote)
2733                         strunzone(vote_called_vote);
2734                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2735                 uid2name_dialog = 1;
2736         }
2737
2738         if(!autocvar__hud_configure)
2739         {
2740                 if(!autocvar_hud_panel_vote) return;
2741
2742                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2743                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2744
2745                 if(panel_bg_alpha_str == "") {
2746                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2747                 }
2748                 panel_bg_alpha = stof(panel_bg_alpha_str);
2749         }
2750         else
2751         {
2752                 vote_yescount = 3;
2753                 vote_nocount = 2;
2754                 vote_needed = 4;
2755         }
2756
2757         string s;
2758         float a;
2759         if(vote_active != vote_prev) {
2760                 vote_change = time;
2761                 vote_prev = vote_active;
2762         }
2763
2764         if(vote_active || autocvar__hud_configure)
2765                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2766         else
2767                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2768
2769         if(!vote_alpha)
2770                 return;
2771
2772         HUD_Panel_UpdateCvars();
2773
2774         if(uid2name_dialog)
2775         {
2776                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2777                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2778         }
2779
2780     // these must be below above block
2781         vector pos, mySize;
2782         pos = panel_pos;
2783         mySize = panel_size;
2784
2785         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2786         HUD_Panel_DrawBg(a);
2787         a = panel_fg_alpha * a;
2788
2789         if(panel_bg_padding)
2790         {
2791                 pos += '1 1 0' * panel_bg_padding;
2792                 mySize -= '2 2 0' * panel_bg_padding;
2793         }
2794
2795         // always force 3:1 aspect
2796         vector newSize = '0 0 0';
2797         if(mySize.x/mySize.y > 3)
2798         {
2799                 newSize.x = 3 * mySize.y;
2800                 newSize.y = mySize.y;
2801
2802                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2803         }
2804         else
2805         {
2806                 newSize.y = 1/3 * mySize.x;
2807                 newSize.x = mySize.x;
2808
2809                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2810         }
2811         mySize = newSize;
2812
2813         s = _("A vote has been called for:");
2814         if(uid2name_dialog)
2815                 s = _("Allow servers to store and display your name?");
2816         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2817         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2818         if(autocvar__hud_configure)
2819                 s = _("^1Configure the HUD");
2820         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2821
2822         // print the yes/no counts
2823     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2824         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2825     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2826         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2827
2828         // draw the progress bar backgrounds
2829         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2830
2831         // draw the highlights
2832         if(vote_highlighted == 1) {
2833                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2834                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2835         }
2836         else if(vote_highlighted == -1) {
2837                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2838                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2839         }
2840
2841         // draw the progress bars
2842         if(vote_yescount && vote_needed)
2843         {
2844                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2845                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2846         }
2847
2848         if(vote_nocount && vote_needed)
2849         {
2850                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2851                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2852         }
2853
2854         drawresetcliparea();
2855 }
2856
2857 // Mod icons panel (#10)
2858 //
2859
2860 bool mod_active; // is there any active mod icon?
2861
2862 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2863 {
2864         int stat = -1;
2865         string pic = "";
2866         vector color = '0 0 0';
2867         switch(i)
2868         {
2869                 case 0:
2870                         stat = getstati(STAT_REDALIVE);
2871                         pic = "player_red.tga";
2872                         color = '1 0 0';
2873                         break;
2874                 case 1:
2875                         stat = getstati(STAT_BLUEALIVE);
2876                         pic = "player_blue.tga";
2877                         color = '0 0 1';
2878                         break;
2879                 case 2:
2880                         stat = getstati(STAT_YELLOWALIVE);
2881                         pic = "player_yellow.tga";
2882                         color = '1 1 0';
2883                         break;
2884                 default:
2885                 case 3:
2886                         stat = getstati(STAT_PINKALIVE);
2887                         pic = "player_pink.tga";
2888                         color = '1 0 1';
2889                         break;
2890         }
2891
2892         if(mySize.x/mySize.y > aspect_ratio)
2893         {
2894                 i = aspect_ratio * mySize.y;
2895                 myPos.x = myPos.x + (mySize.x - i) / 2;
2896                 mySize.x = i;
2897         }
2898         else
2899         {
2900                 i = 1/aspect_ratio * mySize.x;
2901                 myPos.y = myPos.y + (mySize.y - i) / 2;
2902                 mySize.y = i;
2903         }
2904
2905         if(layout)
2906         {
2907                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2908                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2909         }
2910         else
2911                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2912 }
2913
2914 // Clan Arena and Freeze Tag HUD modicons
2915 void HUD_Mod_CA(vector myPos, vector mySize)
2916 {
2917         mod_active = 1; // required in each mod function that always shows something
2918
2919         int layout;
2920         if(gametype == MAPINFO_TYPE_CA)
2921                 layout = autocvar_hud_panel_modicons_ca_layout;
2922         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2923                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2924         int rows, columns;
2925         float aspect_ratio;
2926         aspect_ratio = (layout) ? 2 : 1;
2927         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2928         columns = ceil(team_count/rows);
2929
2930         int i;
2931         float row = 0, column = 0;
2932         vector pos, itemSize;
2933         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2934         for(i=0; i<team_count; ++i)
2935         {
2936                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2937
2938                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2939
2940                 ++row;
2941                 if(row >= rows)
2942                 {
2943                         row = 0;
2944                         ++column;
2945                 }
2946         }
2947 }
2948
2949 // CTF HUD modicon section
2950 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
2951 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
2952 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
2953
2954 void HUD_Mod_CTF_Reset(void)
2955 {
2956         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
2957         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
2958         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
2959 }
2960
2961 void HUD_Mod_CTF(vector pos, vector mySize)
2962 {
2963         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
2964         vector flag_size;
2965         float f; // every function should have that
2966
2967         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
2968         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime, yellowflag_statuschange_elapsedtime, pinkflag_statuschange_elapsedtime, neutralflag_statuschange_elapsedtime; // time since the status changed
2969         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
2970         int stat_items = getstati(STAT_CTF_FLAGSTATUS, 0, 24);
2971         float fs, fs2, fs3, size1, size2;
2972         vector e1, e2;
2973
2974         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
2975         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
2976         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
2977         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
2978         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
2979
2980         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
2981
2982         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag);
2983
2984         if (autocvar__hud_configure) {
2985                 redflag = 1;
2986                 blueflag = 2;
2987                 if (team_count >= 3)
2988                         yellowflag = 2;
2989                 if (team_count >= 4)
2990                         pinkflag = 3;
2991                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
2992         }
2993
2994         // when status CHANGES, set old status into prevstatus and current status into status
2995         #define X(team) do {                                                                                                                    \
2996                 if (team##flag != team##flag_prevframe) {                                                                       \
2997                 team##flag_statuschange_time = time;                                                                    \
2998                 team##flag_prevstatus = team##flag_prevframe;                                                   \
2999                 team##flag_prevframe = team##flag;                                                                              \
3000         }                                                                                                                                                       \
3001         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
3002     } while (0)
3003         X(red);
3004         X(blue);
3005         X(yellow);
3006         X(pink);
3007         X(neutral);
3008         #undef X
3009
3010         const float BLINK_FACTOR = 0.15;
3011         const float BLINK_BASE = 0.85;
3012         // note:
3013         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
3014         // thus
3015         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
3016         // ensure RMS == 1
3017         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
3018
3019         #define X(team, cond) \
3020         string team##_icon, team##_icon_prevstatus; \
3021         int team##_alpha, team##_alpha_prevstatus; \
3022         team##_alpha = team##_alpha_prevstatus = 1; \
3023         do { \
3024                 switch (team##flag) { \
3025                         case 1: team##_icon = "flag_" #team "_taken"; break; \
3026                         case 2: team##_icon = "flag_" #team "_lost"; break; \
3027                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
3028                         default: \
3029                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
3030                                         team##_icon = "flag_" #team "_shielded"; \
3031                                 } else { \
3032                                         team##_icon = string_null; \
3033                                 } \
3034                                 break; \
3035                 } \
3036                 switch (team##flag_prevstatus) { \
3037                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
3038                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
3039                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
3040                         default: \
3041                                 if (team##flag == 3) { \
3042                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
3043                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
3044                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
3045                                 } else { \
3046                                         team##_icon_prevstatus = string_null; \
3047                                 } \
3048                                 break; \
3049                 } \
3050         } while (0)
3051         X(red, myteam != NUM_TEAM_1);
3052         X(blue, myteam != NUM_TEAM_2);
3053         X(yellow, myteam != NUM_TEAM_3);
3054         X(pink, myteam != NUM_TEAM_4);
3055         X(neutral, true);
3056         #undef X
3057
3058         if (ctf_oneflag) {
3059                 // hacky, but these aren't needed
3060                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
3061                 fs = fs2 = fs3 = 1;
3062         } else switch (team_count) {
3063                 default:
3064                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
3065                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
3066                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
3067         }
3068
3069         if (mySize_x > mySize_y) {
3070                 size1 = mySize_x;
3071                 size2 = mySize_y;
3072                 e1 = eX;
3073                 e2 = eY;
3074         } else {
3075                 size1 = mySize_y;
3076                 size2 = mySize_x;
3077                 e1 = eY;
3078                 e2 = eX;
3079         }
3080
3081         switch (myteam) {
3082                 default:
3083                 case NUM_TEAM_1: {
3084                         redflag_pos = pos;
3085                         blueflag_pos = pos + eX * fs2 * size1;
3086                         yellowflag_pos = pos - eX * fs2 * size1;
3087                         pinkflag_pos = pos + eX * fs3 * size1;
3088                         break;
3089                 }
3090                 case NUM_TEAM_2: {
3091                         redflag_pos = pos + eX * fs2 * size1;
3092                         blueflag_pos = pos;
3093                         yellowflag_pos = pos - eX * fs2 * size1;
3094                         pinkflag_pos = pos + eX * fs3 * size1;
3095                         break;
3096                 }
3097                 case NUM_TEAM_3: {
3098                         redflag_pos = pos + eX * fs3 * size1;
3099                         blueflag_pos = pos - eX * fs2 * size1;
3100                         yellowflag_pos = pos;
3101                         pinkflag_pos = pos + eX * fs2 * size1;
3102                         break;
3103                 }
3104                 case NUM_TEAM_4: {
3105                         redflag_pos = pos - eX * fs2 * size1;
3106                         blueflag_pos = pos + eX * fs3 * size1;
3107                         yellowflag_pos = pos + eX * fs2 * size1;
3108                         pinkflag_pos = pos;
3109                         break;
3110                 }
3111         }
3112         neutralflag_pos = pos;
3113         flag_size = e1 * fs * size1 + e2 * size2;
3114
3115         #define X(team) do { \
3116                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
3117                 if (team##_icon_prevstatus && f < 1) \
3118                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
3119                 if (team##_icon) \
3120                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
3121         } while (0)
3122         X(red);
3123         X(blue);
3124         X(yellow);
3125         X(pink);
3126         X(neutral);
3127         #undef X
3128 }
3129
3130 // Keyhunt HUD modicon section
3131 vector KH_SLOTS[4];
3132
3133 void HUD_Mod_KH(vector pos, vector mySize)
3134 {
3135         mod_active = 1; // keyhunt should never hide the mod icons panel
3136
3137         // Read current state
3138
3139         int state = getstati(STAT_KH_KEYS);
3140         int i, key_state;
3141         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3142         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3143
3144         for(i = 0; i < 4; ++i)
3145         {
3146                 key_state = (bitshift(state, i * -5) & 31) - 1;
3147
3148                 if(key_state == -1)
3149                         continue;
3150
3151                 if(key_state == 30)
3152                 {
3153                         ++carrying_keys;
3154                         key_state = myteam;
3155                 }
3156
3157                 switch(key_state)
3158                 {
3159                         case NUM_TEAM_1: ++team1_keys; break;
3160                         case NUM_TEAM_2: ++team2_keys; break;
3161                         case NUM_TEAM_3: ++team3_keys; break;
3162                         case NUM_TEAM_4: ++team4_keys; break;
3163                         case 29: ++dropped_keys; break;
3164                 }
3165
3166                 ++all_keys;
3167         }
3168
3169         // Calculate slot measurements
3170
3171         vector slot_size;
3172
3173         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3174         {
3175                 // Quadratic arrangement
3176                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3177                 KH_SLOTS[0] = pos;
3178                 KH_SLOTS[1] = pos + eX * slot_size.x;
3179                 KH_SLOTS[2] = pos + eY * slot_size.y;
3180                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3181         }
3182         else
3183         {
3184                 if(mySize.x > mySize.y)
3185                 {
3186                         // Horizontal arrangement
3187                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3188                         for(i = 0; i < all_keys; ++i)
3189                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3190                 }
3191                 else
3192                 {
3193                         // Vertical arrangement
3194                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3195                         for(i = 0; i < all_keys; ++i)
3196                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3197                 }
3198         }
3199
3200         // Make icons blink in case of RUN HERE
3201
3202         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3203         float alpha;
3204         alpha = 1;
3205
3206         if(carrying_keys)
3207                 switch(myteam)
3208                 {
3209                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3210                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3211                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3212                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3213                 }
3214
3215         // Draw icons
3216
3217         i = 0;
3218
3219         while(team1_keys--)
3220                 if(myteam == NUM_TEAM_1 && carrying_keys)
3221                 {
3222                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3223                         --carrying_keys;
3224                 }
3225                 else
3226                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3227
3228         while(team2_keys--)
3229                 if(myteam == NUM_TEAM_2 && carrying_keys)
3230                 {
3231                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3232                         --carrying_keys;
3233                 }
3234                 else
3235                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3236
3237         while(team3_keys--)
3238                 if(myteam == NUM_TEAM_3 && carrying_keys)
3239                 {
3240                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3241                         --carrying_keys;
3242                 }
3243                 else
3244                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3245
3246         while(team4_keys--)
3247                 if(myteam == NUM_TEAM_4 && carrying_keys)
3248                 {
3249                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3250                         --carrying_keys;
3251                 }
3252                 else
3253                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3254
3255         while(dropped_keys--)
3256                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3257 }
3258
3259 // Keepaway HUD mod icon
3260 int kaball_prevstatus; // last remembered status
3261 float kaball_statuschange_time; // time when the status changed
3262
3263 // we don't need to reset for keepaway since it immediately
3264 // autocorrects prevstatus as to if the player has the ball or not
3265
3266 void HUD_Mod_Keepaway(vector pos, vector mySize)
3267 {
3268         mod_active = 1; // keepaway should always show the mod HUD
3269
3270         float BLINK_FACTOR = 0.15;
3271         float BLINK_BASE = 0.85;
3272         float BLINK_FREQ = 5;
3273         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3274
3275         int stat_items = getstati(STAT_ITEMS, 0, 24);
3276         int kaball = (stat_items/IT_KEY1) & 1;
3277
3278         if(kaball != kaball_prevstatus)
3279         {
3280                 kaball_statuschange_time = time;
3281                 kaball_prevstatus = kaball;
3282         }
3283
3284         vector kaball_pos, kaball_size;
3285
3286         if(mySize.x > mySize.y) {
3287                 kaball_pos = pos + eX * 0.25 * mySize.x;
3288                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3289         } else {
3290                 kaball_pos = pos + eY * 0.25 * mySize.y;
3291                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3292         }
3293
3294         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3295         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3296
3297         if(kaball_prevstatus && f < 1)
3298                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3299
3300         if(kaball)
3301                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3302 }
3303
3304
3305 // Nexball HUD mod icon
3306 void HUD_Mod_NexBall(vector pos, vector mySize)
3307 {
3308         float nb_pb_starttime, dt, p;
3309         int stat_items;
3310
3311         stat_items = getstati(STAT_ITEMS, 0, 24);
3312         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3313
3314         if (stat_items & IT_KEY1)
3315                 mod_active = 1;
3316         else
3317                 mod_active = 0;
3318
3319         //Manage the progress bar if any
3320         if (nb_pb_starttime > 0)
3321         {
3322                 dt = (time - nb_pb_starttime) % nb_pb_period;
3323                 // one period of positive triangle
3324                 p = 2 * dt / nb_pb_period;
3325                 if (p > 1)
3326                         p = 2 - p;
3327
3328                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3329         }
3330
3331         if (stat_items & IT_KEY1)
3332                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3333 }
3334
3335 // Race/CTS HUD mod icons
3336 float crecordtime_prev; // last remembered crecordtime
3337 float crecordtime_change_time; // time when crecordtime last changed
3338 float srecordtime_prev; // last remembered srecordtime
3339 float srecordtime_change_time; // time when srecordtime last changed
3340
3341 float race_status_time;
3342 int race_status_prev;
3343 string race_status_name_prev;
3344 void HUD_Mod_Race(vector pos, vector mySize)
3345 {
3346         mod_active = 1; // race should never hide the mod icons panel
3347         entity me;
3348         me = playerslots[player_localnum];
3349         float t, score;
3350         float f; // yet another function has this
3351         score = me.(scores[ps_primary]);
3352
3353         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3354                 return; // no records in the actual race
3355
3356         // clientside personal record
3357         string rr;
3358         if(gametype == MAPINFO_TYPE_CTS)
3359                 rr = CTS_RECORD;
3360         else
3361                 rr = RACE_RECORD;
3362         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3363
3364         if(score && (score < t || !t)) {
3365                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3366                 if(autocvar_cl_autodemo_delete_keeprecords)
3367                 {
3368                         f = autocvar_cl_autodemo_delete;
3369                         f &= ~1;
3370                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3371                 }
3372         }
3373
3374         if(t != crecordtime_prev) {
3375                 crecordtime_prev = t;
3376                 crecordtime_change_time = time;
3377         }
3378
3379         vector textPos, medalPos;
3380         float squareSize;
3381         if(mySize.x > mySize.y) {
3382                 // text on left side
3383                 squareSize = min(mySize.y, mySize.x/2);
3384                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3385                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3386         } else {
3387                 // text on top
3388                 squareSize = min(mySize.x, mySize.y/2);
3389                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3390                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3391         }
3392
3393         f = time - crecordtime_change_time;
3394
3395         if (f > 1) {
3396                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3397                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3398         } else {
3399                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3400                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3401                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3402                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3403         }
3404
3405         // server record
3406         t = race_server_record;
3407         if(t != srecordtime_prev) {
3408                 srecordtime_prev = t;
3409                 srecordtime_change_time = time;
3410         }
3411         f = time - srecordtime_change_time;
3412
3413         if (f > 1) {
3414                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3415                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3416         } else {
3417                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3418                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3419                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3420                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3421         }
3422
3423         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3424                 race_status_time = time + 5;
3425                 race_status_prev = race_status;
3426                 if (race_status_name_prev)
3427                         strunzone(race_status_name_prev);
3428                 race_status_name_prev = strzone(race_status_name);
3429         }
3430
3431         // race "awards"
3432         float a;
3433         a = bound(0, race_status_time - time, 1);
3434
3435         string s;
3436         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3437
3438         float rank;
3439         if(race_status > 0)
3440                 rank = race_CheckName(race_status_name);
3441         else
3442                 rank = 0;
3443         string rankname;
3444         rankname = count_ordinal(rank);
3445
3446         vector namepos;
3447         namepos = medalPos + '0 0.8 0' * squareSize;
3448         vector rankpos;
3449         rankpos = medalPos + '0 0.15 0' * squareSize;
3450
3451         if(race_status == 0)
3452                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3453         else if(race_status == 1) {
3454                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3455                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3456                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3457         } else if(race_status == 2) {
3458                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3459                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3460                 else
3461                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3462                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3463                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3464         } else if(race_status == 3) {
3465                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3466                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3467                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3468         }
3469
3470         if (race_status_time - time <= 0) {
3471                 race_status_prev = -1;
3472                 race_status = -1;
3473                 if(race_status_name)
3474                         strunzone(race_status_name);
3475                 race_status_name = string_null;
3476                 if(race_status_name_prev)
3477                         strunzone(race_status_name_prev);
3478                 race_status_name_prev = string_null;
3479         }
3480 }
3481
3482 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3483 {
3484         float stat = -1;
3485         string pic = "";
3486         vector color = '0 0 0';
3487         switch(i)
3488         {
3489                 case 0:
3490                         stat = getstatf(STAT_DOM_PPS_RED);
3491                         pic = "dom_icon_red";
3492                         color = '1 0 0';
3493                         break;
3494                 case 1:
3495                         stat = getstatf(STAT_DOM_PPS_BLUE);
3496                         pic = "dom_icon_blue";
3497                         color = '0 0 1';
3498                         break;
3499                 case 2:
3500                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3501                         pic = "dom_icon_yellow";
3502                         color = '1 1 0';
3503                         break;
3504                 default:
3505                 case 3:
3506                         stat = getstatf(STAT_DOM_PPS_PINK);
3507                         pic = "dom_icon_pink";
3508                         color = '1 0 1';
3509                         break;
3510         }
3511         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3512
3513         if(mySize.x/mySize.y > aspect_ratio)
3514         {
3515                 i = aspect_ratio * mySize.y;
3516                 myPos.x = myPos.x + (mySize.x - i) / 2;
3517                 mySize.x = i;
3518         }
3519         else
3520         {
3521                 i = 1/aspect_ratio * mySize.x;
3522                 myPos.y = myPos.y + (mySize.y - i) / 2;
3523                 mySize.y = i;
3524         }
3525
3526         if (layout) // show text too
3527         {
3528                 //draw the text
3529                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3530                 if (layout == 2) // average pps
3531                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3532                 else // percentage of average pps
3533                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3534         }
3535
3536         //draw the icon
3537         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3538         if (stat > 0)
3539         {
3540                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3541                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3542                 drawresetcliparea();
3543         }
3544 }
3545
3546 void HUD_Mod_Dom(vector myPos, vector mySize)
3547 {
3548         mod_active = 1; // required in each mod function that always shows something
3549
3550         int layout = autocvar_hud_panel_modicons_dom_layout;
3551         int rows, columns;
3552         float aspect_ratio;
3553         aspect_ratio = (layout) ? 3 : 1;
3554         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3555         columns = ceil(team_count/rows);
3556
3557         int i;
3558         float row = 0, column = 0;
3559         vector pos, itemSize;
3560         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3561         for(i=0; i<team_count; ++i)
3562         {
3563                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3564
3565                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3566
3567                 ++row;
3568                 if(row >= rows)
3569                 {
3570                         row = 0;
3571                         ++column;
3572                 }
3573         }
3574 }
3575
3576 void HUD_ModIcons_SetFunc()
3577 {
3578         switch(gametype)
3579         {
3580                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3581                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3582                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3583                 case MAPINFO_TYPE_CTS:
3584                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3585                 case MAPINFO_TYPE_CA:
3586                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3587                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3588                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3589         }
3590 }
3591
3592 int mod_prev; // previous state of mod_active to check for a change
3593 float mod_alpha;
3594 float mod_change; // "time" when mod_active changed
3595
3596 void HUD_ModIcons(void)
3597 {
3598         if(intermission == 2) return;
3599         if(!autocvar__hud_configure)
3600         {
3601                 if(!autocvar_hud_panel_modicons) return;
3602                 if(!HUD_ModIcons_GameType) return;
3603         }
3604
3605         HUD_Panel_UpdateCvars();
3606
3607         draw_beginBoldFont();
3608
3609         if(mod_active != mod_prev) {
3610                 mod_change = time;
3611                 mod_prev = mod_active;
3612         }
3613
3614         if(mod_active || autocvar__hud_configure)
3615                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3616         else
3617                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3618
3619         if(mod_alpha)
3620                 HUD_Panel_DrawBg(mod_alpha);
3621
3622         if(panel_bg_padding)
3623         {
3624                 panel_pos += '1 1 0' * panel_bg_padding;
3625                 panel_size -= '2 2 0' * panel_bg_padding;
3626         }
3627
3628         if(autocvar__hud_configure)
3629                 HUD_Mod_CTF(panel_pos, panel_size);
3630         else
3631                 HUD_ModIcons_GameType(panel_pos, panel_size);
3632
3633         draw_endBoldFont();
3634 }
3635
3636 // Draw pressed keys (#11)
3637 //
3638 void HUD_PressedKeys(void)
3639 {
3640         if(intermission == 2) return;
3641         if(!autocvar__hud_configure)
3642         {
3643                 if(!autocvar_hud_panel_pressedkeys) return;
3644                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3645         }
3646
3647         HUD_Panel_UpdateCvars();
3648         vector pos, mySize;
3649         pos = panel_pos;
3650         mySize = panel_size;
3651
3652         HUD_Panel_DrawBg(1);
3653         if(panel_bg_padding)
3654         {
3655                 pos += '1 1 0' * panel_bg_padding;
3656                 mySize -= '2 2 0' * panel_bg_padding;
3657         }
3658
3659         // force custom aspect
3660         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3661         if(aspect)
3662         {
3663                 vector newSize = '0 0 0';
3664                 if(mySize.x/mySize.y > aspect)
3665                 {
3666                         newSize.x = aspect * mySize.y;
3667                         newSize.y = mySize.y;
3668
3669                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3670                 }
3671                 else
3672                 {
3673                         newSize.y = 1/aspect * mySize.x;
3674                         newSize.x = mySize.x;
3675
3676                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3677                 }
3678                 mySize = newSize;
3679         }
3680
3681         vector keysize;
3682         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3683         float pressedkeys;
3684         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3685
3686         if(autocvar_hud_panel_pressedkeys_attack)
3687         {
3688                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3689                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3690                 pos.y += keysize.y;
3691         }
3692
3693         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3694         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3695         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3696         pos.y += keysize.y;
3697         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3698         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3699         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3700 }
3701
3702 // Handle chat as a panel (#12)
3703 //
3704 void HUD_Chat(void)
3705 {
3706         if(!autocvar__hud_configure)
3707         {
3708                 if (!autocvar_hud_panel_chat)
3709                 {
3710                         if (!autocvar_con_chatrect)
3711                                 cvar_set("con_chatrect", "0");
3712                         return;
3713                 }
3714                 if(autocvar__con_chat_maximized)
3715                 {
3716                         if(!hud_draw_maximized) return;
3717                 }
3718                 else if(chat_panel_modified)
3719                 {
3720                         panel.update_time = time; // forces reload of panel attributes
3721                         chat_panel_modified = false;
3722                 }
3723         }
3724
3725         HUD_Panel_UpdateCvars();
3726
3727         if(intermission == 2)
3728         {
3729                 // reserve some more space to the mapvote panel
3730                 // by resizing and moving chat panel to the bottom
3731                 panel_size.y = min(panel_size.y, vid_conheight * 0.2);
3732                 panel_pos.y = vid_conheight - panel_size.y - panel_bg_border * 2;
3733                 chat_posy = panel_pos.y;
3734                 chat_sizey = panel_size.y;
3735         }
3736         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3737         {
3738                 panel_pos.y = panel_bg_border;
3739                 panel_size.y = vid_conheight - panel_bg_border * 2;
3740                 if(panel.current_panel_bg == "0") // force a border when maximized
3741                 {
3742                         string panel_bg;
3743                         panel_bg = strcat(hud_skin_path, "/border_default");
3744                         if(precache_pic(panel_bg) == "")
3745                                 panel_bg = "gfx/hud/default/border_default";
3746                         if(panel.current_panel_bg)
3747                                 strunzone(panel.current_panel_bg);
3748                         panel.current_panel_bg = strzone(panel_bg);
3749                         chat_panel_modified = true;
3750                 }
3751                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3752         }
3753
3754         vector pos, mySize;
3755         pos = panel_pos;
3756         mySize = panel_size;
3757
3758         HUD_Panel_DrawBg(1);
3759
3760         if(panel_bg_padding)
3761         {
3762                 pos += '1 1 0' * panel_bg_padding;
3763                 mySize -= '2 2 0' * panel_bg_padding;
3764         }
3765
3766         if (!autocvar_con_chatrect)
3767                 cvar_set("con_chatrect", "1");
3768
3769         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3770         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3771
3772         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3773         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3774
3775         if(autocvar__hud_configure)
3776         {
3777                 vector chatsize;
3778                 chatsize = '1 1 0' * autocvar_con_chatsize;
3779                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3780                 float i, a;
3781                 for(i = 0; i < autocvar_con_chat; ++i)
3782                 {
3783                         if(i == autocvar_con_chat - 1)
3784                                 a = panel_fg_alpha;
3785                         else
3786                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3787                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3788                         pos.y += chatsize.y;
3789                 }
3790         }
3791 }
3792
3793 // Engine info panel (#13)
3794 //
3795 float prevfps;
3796 float prevfps_time;
3797 int framecounter;
3798
3799 float frametimeavg;
3800 float frametimeavg1; // 1 frame ago
3801 float frametimeavg2; // 2 frames ago
3802 void HUD_EngineInfo(void)
3803 {
3804         //if(intermission == 2) return;
3805         if(!autocvar__hud_configure)
3806         {
3807                 if(!autocvar_hud_panel_engineinfo) return;
3808         }
3809
3810         HUD_Panel_UpdateCvars();
3811         vector pos, mySize;
3812         pos = panel_pos;
3813         mySize = panel_size;
3814
3815         HUD_Panel_DrawBg(1);
3816         if(panel_bg_padding)
3817         {
3818                 pos += '1 1 0' * panel_bg_padding;
3819                 mySize -= '2 2 0' * panel_bg_padding;
3820         }
3821
3822         float currentTime = gettime(GETTIME_REALTIME);
3823         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3824         {
3825                 float currentframetime = currentTime - prevfps_time;
3826                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3827                 frametimeavg2 = frametimeavg1;
3828                 frametimeavg1 = frametimeavg;
3829
3830                 float weight;
3831                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3832                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3833                 {
3834                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3835                                 prevfps = (1/currentframetime);
3836                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3837                 }
3838                 prevfps_time = currentTime;
3839         }
3840         else
3841         {
3842                 framecounter += 1;
3843                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3844                 {
3845                         prevfps = framecounter/(currentTime - prevfps_time);
3846                         framecounter = 0;
3847                         prevfps_time = currentTime;
3848                 }
3849         }
3850
3851         vector color;
3852         color = HUD_Get_Num_Color (prevfps, 100);
3853         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3854 }
3855
3856 // Info messages panel (#14)
3857 //
3858 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3859         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3860                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3861         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3862         o.y += fontsize.y;                                                                                                                                                                                              \
3863 } while(0)
3864 void HUD_InfoMessages(void)
3865 {
3866         if(intermission == 2) return;
3867         if(!autocvar__hud_configure)
3868         {
3869                 if(!autocvar_hud_panel_infomessages) return;
3870         }
3871
3872         HUD_Panel_UpdateCvars();
3873         vector pos, mySize;
3874         pos = panel_pos;
3875         mySize = panel_size;
3876
3877         HUD_Panel_DrawBg(1);
3878         if(panel_bg_padding)
3879         {
3880                 pos += '1 1 0' * panel_bg_padding;
3881                 mySize -= '2 2 0' * panel_bg_padding;
3882         }
3883
3884         // always force 5:1 aspect
3885         vector newSize = '0 0 0';
3886         if(mySize.x/mySize.y > 5)
3887         {
3888                 newSize.x = 5 * mySize.y;
3889                 newSize.y = mySize.y;
3890
3891                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3892         }
3893         else
3894         {
3895                 newSize.y = 1/5 * mySize.x;
3896                 newSize.x = mySize.x;
3897
3898                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3899         }
3900
3901         mySize = newSize;
3902         entity tm;
3903         vector o;
3904         o = pos;
3905
3906         vector fontsize;
3907         fontsize = '0.20 0.20 0' * mySize.y;
3908
3909         float a;
3910         a = panel_fg_alpha;
3911
3912         string s;
3913         if(!autocvar__hud_configure)
3914         {
3915                 if(spectatee_status && !intermission)
3916                 {
3917                         a = 1;
3918                         if(spectatee_status == -1)
3919                                 s = _("^1Observing");
3920                         else
3921                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3922                         drawInfoMessage(s);
3923
3924                         if(spectatee_status == -1)
3925                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3926                         else
3927                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3928                         drawInfoMessage(s);
3929
3930                         if(spectatee_status == -1)
3931                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3932                         else
3933                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3934                         drawInfoMessage(s);
3935
3936                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3937                         drawInfoMessage(s);
3938
3939                         if(gametype == MAPINFO_TYPE_LMS)
3940                         {
3941                                 entity sk;
3942                                 sk = playerslots[player_localnum];
3943                                 if(sk.(scores[ps_primary]) >= 666)
3944                                         s = _("^1Match has already begun");
3945                                 else if(sk.(scores[ps_primary]) > 0)
3946                                         s = _("^1You have no more lives left");
3947                                 else
3948                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3949                         }
3950                         else
3951                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3952                         drawInfoMessage(s);
3953
3954                         //show restart countdown:
3955                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3956                                 float countdown;
3957                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3958                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3959                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3960                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3961                                 o.y += fontsize.y;
3962                         }
3963                 }
3964                 if(warmup_stage && !intermission)
3965                 {
3966                         s = _("^2Currently in ^1warmup^2 stage!");
3967                         drawInfoMessage(s);
3968                 }
3969
3970                 string blinkcolor;
3971                 if(time % 1 >= 0.5)
3972                         blinkcolor = "^1";
3973                 else
3974                         blinkcolor = "^3";
3975
3976                 if(ready_waiting && !intermission && !spectatee_status)
3977                 {
3978                         if(ready_waiting_for_me)
3979                         {
3980                                 if(warmup_stage)
3981                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3982                                 else
3983                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3984                         }
3985                         else
3986                         {
3987                                 if(warmup_stage)
3988                                         s = _("^2Waiting for others to ready up to end warmup...");
3989                                 else
3990                                         s = _("^2Waiting for others to ready up...");
3991                         }
3992                         drawInfoMessage(s);
3993                 }
3994                 else if(warmup_stage && !intermission && !spectatee_status)
3995                 {
3996                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3997                         drawInfoMessage(s);
3998                 }
3999
4000                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
4001                 {
4002                         float ts_min = 0, ts_max = 0;
4003                         tm = teams.sort_next;
4004                         if (tm)
4005                         {
4006                                 for (; tm.sort_next; tm = tm.sort_next)
4007                                 {
4008                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
4009                                                 continue;
4010                                         if(!ts_min) ts_min = tm.team_size;
4011                                         else ts_min = min(ts_min, tm.team_size);
4012                                         if(!ts_max) ts_max = tm.team_size;
4013                                         else ts_max = max(ts_max, tm.team_size);
4014                                 }
4015                                 if ((ts_max - ts_min) > 1)
4016                                 {
4017                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
4018                                         tm = GetTeam(myteam, false);
4019                                         if (tm)
4020                                         if (tm.team != NUM_SPECTATOR)
4021                                         if (tm.team_size == ts_max)
4022                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
4023                                         drawInfoMessage(s);
4024                                 }
4025                         }
4026                 }
4027         }
4028         else
4029         {
4030                 s = _("^7Press ^3ESC ^7to show HUD options.");
4031                 drawInfoMessage(s);
4032                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
4033                 drawInfoMessage(s);
4034                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
4035                 drawInfoMessage(s);
4036                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
4037                 drawInfoMessage(s);
4038         }
4039 }
4040
4041 // Physics panel (#15)
4042 //
4043 vector acc_prevspeed;
4044 float acc_prevtime, acc_avg, top_speed, top_speed_time;
4045 float physics_update_time, discrete_speed, discrete_acceleration;
4046 void HUD_Physics(void)
4047 {
4048         if(intermission == 2) return;
4049         if(!autocvar__hud_configure)
4050         {
4051                 if(!autocvar_hud_panel_physics) return;
4052                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
4053                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
4054         }
4055
4056         HUD_Panel_UpdateCvars();
4057
4058         draw_beginBoldFont();
4059
4060         HUD_Panel_DrawBg(1);
4061         if(panel_bg_padding)
4062         {
4063                 panel_pos += '1 1 0' * panel_bg_padding;
4064                 panel_size -= '2 2 0' * panel_bg_padding;
4065         }
4066
4067         float acceleration_progressbar_scale = 0;
4068         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
4069                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
4070
4071         float text_scale;
4072         if (autocvar_hud_panel_physics_text_scale <= 0)
4073                 text_scale = 1;
4074         else
4075                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
4076
4077         //compute speed
4078         float speed, conversion_factor;
4079         string unit;
4080
4081         switch(autocvar_hud_panel_physics_speed_unit)
4082         {
4083                 default:
4084                 case 1:
4085                         unit = _(" qu/s");
4086                         conversion_factor = 1.0;
4087                         break;
4088                 case 2:
4089                         unit = _(" m/s");
4090                         conversion_factor = 0.0254;
4091                         break;
4092                 case 3:
4093                         unit = _(" km/h");
4094                         conversion_factor = 0.0254 * 3.6;
4095                         break;
4096                 case 4:
4097                         unit = _(" mph");
4098                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
4099                         break;
4100                 case 5:
4101                         unit = _(" knots");
4102                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
4103                         break;
4104         }
4105
4106         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
4107
4108         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
4109         if (autocvar__hud_configure)
4110                 speed = floor( max_speed * 0.65 + 0.5 );
4111         else if(autocvar_hud_panel_physics_speed_vertical)
4112                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
4113         else
4114                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
4115
4116         //compute acceleration
4117         float acceleration, f;
4118         if (autocvar__hud_configure)
4119                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
4120         else
4121         {
4122                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
4123                 f = time - acc_prevtime;
4124                 if(autocvar_hud_panel_physics_acceleration_vertical)
4125                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
4126                 else
4127                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4128
4129                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4130
4131                 acc_prevspeed = vel;
4132                 acc_prevtime = time;
4133
4134                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
4135                 {
4136                         f = bound(0, f * 10, 1);
4137                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4138                         acceleration = acc_avg;
4139                 }
4140         }
4141
4142         int acc_decimals = 2;
4143         if(time > physics_update_time)
4144         {
4145                 // workaround for ftos_decimals returning a negative 0
4146                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4147                         discrete_acceleration = 0;
4148                 discrete_acceleration = acceleration;
4149                 discrete_speed = speed;
4150                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4151         }
4152
4153         //compute layout
4154         float panel_ar = panel_size.x/panel_size.y;
4155         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4156         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4157         {
4158                 panel_size.x *= 0.5;
4159                 if (autocvar_hud_panel_physics_flip)
4160                         speed_offset.x = panel_size.x;
4161                 else
4162                         acceleration_offset.x = panel_size.x;
4163         }
4164         else
4165         {
4166                 panel_size.y *= 0.5;
4167                 if (autocvar_hud_panel_physics_flip)
4168                         speed_offset.y = panel_size.y;
4169                 else
4170                         acceleration_offset.y = panel_size.y;
4171         }
4172         int speed_baralign, acceleration_baralign;
4173         if (autocvar_hud_panel_physics_baralign == 1)
4174                 acceleration_baralign = speed_baralign = 1;
4175     else if(autocvar_hud_panel_physics_baralign == 4)
4176                 acceleration_baralign = speed_baralign = 2;
4177         else if (autocvar_hud_panel_physics_flip)
4178         {
4179                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4180                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4181         }
4182         else
4183         {
4184                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4185                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4186         }
4187         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4188                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4189
4190         //draw speed
4191         if(speed)
4192         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4193                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4194         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4195         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4196         {
4197                 tmp_size.x = panel_size.x * 0.75;
4198                 tmp_size.y = panel_size.y * text_scale;
4199                 if (speed_baralign)
4200                         tmp_offset.x = panel_size.x - tmp_size.x;
4201                 //else
4202                         //tmp_offset_x = 0;
4203                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4204                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4205
4206                 //draw speed unit
4207                 if (speed_baralign)
4208                         tmp_offset.x = 0;
4209                 else
4210                         tmp_offset.x = tmp_size.x;
4211                 if (autocvar_hud_panel_physics_speed_unit_show)
4212                 {
4213                         //tmp_offset_y = 0;
4214                         tmp_size.x = panel_size.x * (1 - 0.75);
4215                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4216                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4217                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4218                 }
4219         }
4220
4221         //compute and draw top speed
4222         if (autocvar_hud_panel_physics_topspeed)
4223         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4224         {
4225                 if (autocvar__hud_configure)
4226                 {
4227                         top_speed = floor( max_speed * 0.75 + 0.5 );
4228                         f = 1;
4229                 }
4230                 else
4231                 {
4232                         if (speed >= top_speed)
4233                         {
4234                                 top_speed = speed;
4235                                 top_speed_time = time;
4236                         }
4237                         if (top_speed != 0)
4238                         {
4239                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4240                                 // divide by f to make it start from 1
4241                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4242                         }
4243             else //hide top speed 0, it would be stupid
4244                                 f = 0;
4245                 }
4246                 if (f > 0)
4247                 {
4248                         //top speed progressbar peak
4249                         if(speed < top_speed)
4250                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4251                         {
4252                                 float peak_offsetX;
4253                                 vector peak_size = '0 0 0';
4254                                 if (speed_baralign == 0)
4255                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4256                 else if (speed_baralign == 1)
4257                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4258                 else // if (speed_baralign == 2)
4259                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4260                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4261                 peak_size.y = panel_size.y;
4262                 if (speed_baralign == 2) // draw two peaks, on both sides
4263                 {
4264                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4265                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4266                 }
4267                 else
4268                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4269                         }
4270
4271                         //top speed
4272                         tmp_offset.y = panel_size.y * 0.4;
4273                         tmp_size.x = panel_size.x * (1 - 0.75);
4274                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4275                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4276                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4277                 }
4278                 else
4279                         top_speed = 0;
4280         }
4281
4282         //draw acceleration
4283         if(acceleration)
4284         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4285         {
4286                 vector progressbar_color;
4287                 if(acceleration < 0)
4288                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4289                 else
4290                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4291
4292                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4293                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4294                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4295
4296                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4297                 {
4298                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4299
4300                         if (acceleration_baralign == 1)
4301                                 tmp_offset.x = panel_size.x - tmp_size.x;
4302                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4303                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4304                         else
4305                                 tmp_offset.x = 0;
4306                         tmp_offset.y = 0;
4307                 }
4308                 else
4309                 {
4310                         tmp_size = panel_size;
4311                         tmp_offset = '0 0 0';
4312                 }
4313
4314                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4315         }
4316
4317         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4318         {
4319                 tmp_size.x = panel_size.x;
4320                 tmp_size.y = panel_size.y * text_scale;
4321                 tmp_offset.x = 0;
4322                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4323
4324                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4325         }
4326
4327         draw_endBoldFont();
4328 }
4329
4330 // CenterPrint (#16)
4331 //
4332 const int CENTERPRINT_MAX_MSGS = 10;
4333 const int CENTERPRINT_MAX_ENTRIES = 50;
4334 const float CENTERPRINT_SPACING = 0.7;
4335 int cpm_index;
4336 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4337 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4338 float centerprint_time[CENTERPRINT_MAX_MSGS];
4339 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4340 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4341 bool centerprint_showing;
4342
4343 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4344 {
4345         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4346         int i, j;
4347
4348         if(strMessage == "" && new_id == 0)
4349                 return;
4350
4351         // strip trailing newlines
4352         j = strlen(strMessage) - 1;
4353         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4354                 --j;
4355         if (j < strlen(strMessage) - 1)
4356                 strMessage = substring(strMessage, 0, j + 1);
4357
4358         if(strMessage == "" && new_id == 0)
4359                 return;
4360
4361         // strip leading newlines
4362         j = 0;
4363         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4364                 ++j;
4365         if (j > 0)
4366                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4367
4368         if(strMessage == "" && new_id == 0)
4369                 return;
4370
4371         if (!centerprint_showing)
4372                 centerprint_showing = true;
4373
4374         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4375         {
4376                 if (j == CENTERPRINT_MAX_MSGS)
4377                         j = 0;
4378                 if (new_id && new_id == centerprint_msgID[j])
4379                 {
4380                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4381                         {
4382                                 // fade out the current msg (duration and countdown_num are ignored)
4383                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4384                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4385                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4386                                 return;
4387                         }
4388                         break; // found a msg with the same id, at position j
4389                 }
4390         }
4391
4392         if (i == CENTERPRINT_MAX_MSGS)
4393         {
4394                 // a msg with the same id was not found, add the msg at the next position
4395                 --cpm_index;
4396                 if (cpm_index == -1)
4397                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4398                 j = cpm_index;
4399         }
4400         if(centerprint_messages[j])
4401                 strunzone(centerprint_messages[j]);
4402         centerprint_messages[j] = strzone(strMessage);
4403         centerprint_msgID[j] = new_id;
4404         if (duration < 0)
4405         {
4406                 centerprint_time[j] = -1;
4407                 centerprint_expire_time[j] = time;
4408         }
4409         else
4410         {
4411                 if(duration == 0)
4412                         duration = max(1, autocvar_hud_panel_centerprint_time);
4413                 centerprint_time[j] = duration;
4414                 centerprint_expire_time[j] = time + duration;
4415         }
4416         centerprint_countdown_num[j] = countdown_num;
4417 }
4418
4419 void centerprint_hud(string strMessage)
4420 {
4421         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4422 }
4423
4424 void reset_centerprint_messages(void)
4425 {
4426         int i;
4427         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4428         {
4429                 centerprint_expire_time[i] = 0;
4430                 centerprint_time[i] = 1;
4431                 centerprint_msgID[i] = 0;
4432                 if(centerprint_messages[i])
4433                         strunzone(centerprint_messages[i]);
4434                 centerprint_messages[i] = string_null;
4435         }
4436 }
4437 float hud_configure_cp_generation_time;
4438 void HUD_CenterPrint (void)
4439 {
4440         if(intermission == 2) return;
4441         if(!autocvar__hud_configure)
4442         {
4443                 if(!autocvar_hud_panel_centerprint) return;
4444
4445                 if(hud_configure_prev)
4446                         reset_centerprint_messages();
4447         }
4448         else
4449         {
4450                 if(!hud_configure_prev)
4451                         reset_centerprint_messages();
4452                 if (time > hud_configure_cp_generation_time)
4453                 {
4454                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
4455                         {
4456                                 float r;
4457                                 r = random();
4458                                 if (r > 0.8)
4459                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4460                                 else if (r > 0.55)
4461                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4462                                 else
4463                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4464                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4465                         }
4466                         else
4467                         {
4468                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4469                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4470                         }
4471                 }
4472         }
4473
4474         // this panel fades only when the menu does
4475         float hud_fade_alpha_save = 0;
4476         if(scoreboard_fade_alpha)
4477         {
4478                 hud_fade_alpha_save = hud_fade_alpha;
4479                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4480         }
4481         HUD_Panel_UpdateCvars();
4482
4483         if ( HUD_Radar_Clickable() )
4484         {
4485                 if (hud_panel_radar_bottom >= 0.96 * vid_conheight)
4486                         return;
4487
4488                 panel_pos = eY * hud_panel_radar_bottom + eX * 0.5 * (vid_conwidth - panel_size_x);
4489                 panel_size_y = min(panel_size_y, vid_conheight - hud_panel_radar_bottom);
4490         }
4491         else if(scoreboard_fade_alpha)
4492         {
4493                 hud_fade_alpha = hud_fade_alpha_save;
4494
4495                 // move the panel below the scoreboard
4496                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4497                         return;
4498                 vector target_pos;
4499
4500                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4501
4502                 if(target_pos.y > panel_pos.y)
4503                 {
4504                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4505                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4506                 }
4507         }
4508
4509         HUD_Panel_DrawBg(1);
4510
4511         if (!centerprint_showing)
4512                 return;
4513
4514         if(panel_bg_padding)
4515         {
4516                 panel_pos += '1 1 0' * panel_bg_padding;
4517                 panel_size -= '2 2 0' * panel_bg_padding;
4518         }
4519
4520         int entries;
4521         float height;
4522         vector fontsize;
4523         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4524         // height = panel_size_y/entries;
4525         // fontsize = '1 1 0' * height;
4526         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4527         fontsize = '1 1 0' * height;
4528         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4529
4530         int i, j, k, n, g;
4531         float a, sz, align, current_msg_posY = 0, msg_size;
4532         vector pos;
4533         string ts;
4534         bool all_messages_expired = true;
4535
4536         pos = panel_pos;
4537         if (autocvar_hud_panel_centerprint_flip)
4538                 pos.y += panel_size.y;
4539         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4540         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4541         {
4542                 if (j == CENTERPRINT_MAX_MSGS)
4543                         j = 0;
4544                 if (centerprint_expire_time[j] <= time)
4545                 {
4546                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4547                         {
4548                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4549                                 if (centerprint_countdown_num[j] == 0)
4550                                         continue;
4551                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4552                         }
4553                         else if(centerprint_time[j] != -1)
4554                                 continue;
4555                 }
4556
4557                 all_messages_expired = false;
4558
4559                 // fade the centerprint_hud in/out
4560                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4561                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4562                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4563                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4564                 else // Expiring soon, so fade it out.
4565                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4566
4567                 // while counting down show it anyway in order to hold the current message position
4568                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4569                         continue;
4570                 if (a > 1)
4571                         a = 1;
4572
4573                 // set the size from fading in/out before subsequent fading
4574                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4575
4576                 // also fade it based on positioning
4577                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4578                 {
4579                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4580                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4581                 }
4582                 a *= panel_fg_alpha;
4583
4584                 // finally set the size based on the new theAlpha from subsequent fading
4585                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4586                 drawfontscale = sz * '1 1 0';
4587
4588                 if (centerprint_countdown_num[j])
4589                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4590                 else
4591                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4592
4593                 if (autocvar_hud_panel_centerprint_flip)
4594                 {
4595                         // check if the message can be entirely shown
4596                         for(k = 0; k < n; ++k)
4597                         {
4598                                 getWrappedLine_remaining = argv(k);
4599                                 while(getWrappedLine_remaining)
4600                                 {
4601                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4602                                         if (ts != "")
4603                                                 pos.y -= fontsize.y;
4604                                         else
4605                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4606                                 }
4607                         }
4608                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4609                 }
4610
4611                 msg_size = pos.y;
4612                 for(k = 0; k < n; ++k)
4613                 {
4614                         getWrappedLine_remaining = argv(k);
4615                         while(getWrappedLine_remaining)
4616                         {
4617                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4618                                 if (ts != "")
4619                                 {
4620                                         if (align)
4621                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4622                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4623                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4624                                         pos.y += fontsize.y;
4625                                 }
4626                                 else
4627                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4628                         }
4629                 }
4630
4631                 ++g; // move next position number up
4632
4633                 msg_size = pos.y - msg_size;
4634                 if (autocvar_hud_panel_centerprint_flip)
4635                 {
4636                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4637                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4638                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4639
4640                         if (pos.y < panel_pos.y) // check if the next message can be shown
4641                         {
4642                                 drawfontscale = '1 1 0';
4643                                 return;
4644                         }
4645                 }
4646                 else
4647                 {
4648                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4649                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4650                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4651
4652                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4653                         {
4654                                 drawfontscale = '1 1 0';
4655                                 return;
4656                         }
4657                 }
4658         }
4659         drawfontscale = '1 1 0';
4660         if (all_messages_expired)
4661         {
4662                 centerprint_showing = false;
4663                 reset_centerprint_messages();
4664         }
4665 }
4666
4667
4668 // Minigame
4669 //
4670 #include "../common/minigames/cl_minigames_hud.qc"
4671
4672
4673 // QuickMenu (#23)
4674 //
4675 #include "quickmenu.qc"
4676
4677
4678 /*
4679 ==================
4680 Main HUD system
4681 ==================
4682 */
4683
4684 bool HUD_Panel_CheckFlags(int showflags)
4685 {
4686         if ( HUD_Minigame_Showpanels() )
4687                 return showflags & PANEL_SHOW_MINIGAME;
4688         return showflags & PANEL_SHOW_MAINGAME;
4689 }
4690
4691 void HUD_Panel_Draw(entity panent)
4692 {
4693         panel = panent;
4694         if ( HUD_Panel_CheckFlags(panel.panel_showflags) )
4695                 panel.panel_draw();
4696 }
4697
4698 void HUD_Reset (void)
4699 {
4700         // reset gametype specific icons
4701         if(gametype == MAPINFO_TYPE_CTF)
4702                 HUD_Mod_CTF_Reset();
4703 }
4704
4705 void HUD_Main (void)
4706 {
4707         int i;
4708         // global hud theAlpha fade
4709         if(menu_enabled == 1)
4710                 hud_fade_alpha = 1;
4711         else
4712                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4713
4714         if(scoreboard_fade_alpha)
4715                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4716
4717         HUD_Configure_Frame();
4718
4719         // panels that we want to be active together with the scoreboard
4720         // they must fade only when the menu does
4721         if(scoreboard_fade_alpha == 1)
4722         {
4723                 HUD_Panel_Draw(HUD_PANEL(CENTERPRINT));
4724                 return;
4725         }
4726
4727         if(!autocvar__hud_configure && !hud_fade_alpha)
4728         {
4729                 hud_fade_alpha = 1;
4730                 HUD_Panel_Draw(HUD_PANEL(VOTE));
4731                 hud_fade_alpha = 0;
4732                 return;
4733         }
4734
4735         // Drawing stuff
4736         if (hud_skin_prev != autocvar_hud_skin)
4737         {
4738                 if (hud_skin_path)
4739                         strunzone(hud_skin_path);
4740                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4741                 if (hud_skin_prev)
4742                         strunzone(hud_skin_prev);
4743                 hud_skin_prev = strzone(autocvar_hud_skin);
4744         }
4745
4746         // draw the dock
4747         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4748         {
4749                 int f;
4750                 vector color;
4751                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4752                 if((teamplay) && hud_dock_color_team) {
4753                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4754                                 color = '1 0 0' * hud_dock_color_team;
4755                         else
4756                                 color = myteamcolors * hud_dock_color_team;
4757                 }
4758                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4759                         color = '1 0 0' * hud_dock_color_team;
4760                 }
4761                 else
4762                 {
4763                         string hud_dock_color = autocvar_hud_dock_color;
4764                         if(hud_dock_color == "shirt") {
4765                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4766                                 color = colormapPaletteColor(floor(f / 16), 0);
4767                         }
4768                         else if(hud_dock_color == "pants") {
4769                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4770                                 color = colormapPaletteColor(f % 16, 1);
4771                         }
4772                         else
4773                                 color = stov(hud_dock_color);
4774                 }
4775
4776                 string pic;
4777                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4778                 if(precache_pic(pic) == "") {
4779                         pic = strcat(hud_skin_path, "/dock_medium");
4780                         if(precache_pic(pic) == "") {
4781                                 pic = "gfx/hud/default/dock_medium";
4782                         }
4783                 }
4784                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4785         }
4786
4787         // cache the panel order into the panel_order array
4788         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4789                 for(i = 0; i < hud_panels_COUNT; ++i)
4790                         panel_order[i] = -1;
4791                 string s = "";
4792                 int p_num;
4793                 bool warning = false;
4794                 int argc = tokenize_console(autocvar__hud_panelorder);
4795                 if (argc > hud_panels_COUNT)
4796                         warning = true;
4797                 //first detect wrong/missing panel numbers
4798                 for(i = 0; i < hud_panels_COUNT; ++i) {
4799                         p_num = stoi(argv(i));
4800                         if (p_num >= 0 && p_num < hud_panels_COUNT) { //correct panel number?
4801                                 if (panel_order[p_num] == -1) //found for the first time?
4802                                         s = strcat(s, ftos(p_num), " ");
4803                                 panel_order[p_num] = 1; //mark as found
4804                         }
4805                         else
4806                                 warning = true;
4807                 }
4808                 for(i = 0; i < hud_panels_COUNT; ++i) {
4809                         if (panel_order[i] == -1) {
4810                                 warning = true;
4811                                 s = strcat(s, ftos(i), " "); //add missing panel number
4812                         }
4813                 }
4814                 if (warning)
4815                         LOG_TRACE("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4816
4817                 cvar_set("_hud_panelorder", s);
4818                 if(hud_panelorder_prev)
4819                         strunzone(hud_panelorder_prev);
4820                 hud_panelorder_prev = strzone(s);
4821
4822                 //now properly set panel_order
4823                 tokenize_console(s);
4824                 for(i = 0; i < hud_panels_COUNT; ++i) {
4825                         panel_order[i] = stof(argv(i));
4826                 }
4827         }
4828
4829         hud_draw_maximized = 0;
4830         // draw panels in the order specified by panel_order array
4831         for(i = hud_panels_COUNT - 1; i >= 0; --i)
4832                 HUD_Panel_Draw(hud_panels[panel_order[i]]);
4833
4834         hud_draw_maximized = 1; // panels that may be maximized must check this var
4835         // draw maximized panels on top
4836         if(hud_panel_radar_maximized)
4837                 HUD_Panel_Draw(HUD_PANEL(RADAR));
4838         if(autocvar__con_chat_maximized)
4839                 HUD_Panel_Draw(HUD_PANEL(CHAT));
4840         if(hud_panel_quickmenu)
4841                 HUD_Panel_Draw(HUD_PANEL(QUICKMENU));
4842
4843         HUD_Configure_PostDraw();
4844
4845         hud_configure_prev = autocvar__hud_configure;
4846 }