qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/items/all.qc"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/nades.qh"
  17
  18 #include "../server/mutators/gamemode_ctf.qh"
  19
  20 #include "../common/stats.qh"
  21
  22 #include "../csqcmodellib/cl_player.qh"
  23
  24 #include "../warpzonelib/mathlib.qh"
  25
  26 /*
  27 ==================
  28 Misc HUD functions
  29 ==================
  30 */
  31
  32 // a border picture is a texture containing nine parts:
  33 //   1/4 width: left part
  34 //   1/2 width: middle part (stretched)
  35 //   1/4 width: right part
  36 // divided into
  37 //   1/4 height: top part
  38 //   1/2 height: middle part (stretched)
  39 //   1/4 height: bottom part
  40 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  41 {
  42     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  43     {
  44                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  45                 return;
  46     }
  47         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  48         {
  49                 // draw only the central part
  50                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  51                 return;
  52         }
  53
  54         vector dX, dY;
  55         vector width, height;
  56         vector bW, bH;
  57         //pic = draw_UseSkinFor(pic);
  58         width = eX * theSize.x;
  59         height = eY * theSize.y;
  60         if(theSize.x <= theBorderSize.x * 2)
  61         {
  62                 // not wide enough... draw just left and right then
  63                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  64                 if(theSize.y <= theBorderSize.y * 2)
  65                 {
  66                         // not high enough... draw just corners
  67                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  68                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  71                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  72                 }
  73                 else
  74                 {
  75                         dY = theBorderSize.x * eY;
  76                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  81                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  82                 }
  83         }
  84         else
  85         {
  86                 if(theSize.y <= theBorderSize.y * 2)
  87                 {
  88                         // not high enough... draw just top and bottom then
  89                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  90                         dX = theBorderSize.x * eX;
  91                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  94                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  95                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  96                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  97                 }
  98                 else
  99                 {
 100                         dX = theBorderSize.x * eX;
 101                         dY = theBorderSize.x * eY;
 102                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 107                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 108                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 109                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 110                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 111                 }
 112         }
 113 }
 114
 115 vector HUD_Get_Num_Color (float x, float maxvalue)
 116 {
 117         float blinkingamt;
 118         vector color;
 119         if(x >= maxvalue) {
 120                 color.x = sin(2*M_PI*time);
 121                 color.y = 1;
 122                 color.z = sin(2*M_PI*time);
 123         }
 124         else if(x > maxvalue * 0.75) {
 125                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 126                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 127                 color.z = 0;
 128         }
 129         else if(x > maxvalue * 0.5) {
 130                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 131                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 132                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 133         }
 134         else if(x > maxvalue * 0.25) {
 135                 color.x = 1;
 136                 color.y = 1;
 137                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 138         }
 139         else if(x > maxvalue * 0.1) {
 140                 color.x = 1;
 141                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 142                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 143         }
 144         else {
 145                 color.x = 1;
 146                 color.y = 0;
 147                 color.z = 0;
 148         }
 149
 150         blinkingamt = (1 - x/maxvalue/0.25);
 151         if(blinkingamt > 0)
 152         {
 153                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 154                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 155                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 156         }
 157         return color;
 158 }
 159
 160 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 161 {
 162         float aspect = size_y / size_x;
 163         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 164 }
 165
 166 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect)
 167 {
 168         float columns, rows;
 169         float ratio, best_ratio = 0;
 170         float best_columns = 1, best_rows = 1;
 171         bool vertical = (psize.x / psize.y >= item_aspect);
 172         if(vertical)
 173         {
 174                 psize = eX * psize.y + eY * psize.x;
 175                 item_aspect = 1 / item_aspect;
 176         }
 177
 178         rows = ceil(sqrt(item_count));
 179         columns = ceil(item_count/rows);
 180         while(columns >= 1)
 181         {
 182                 ratio = (psize.x/columns) / (psize.y/rows);
 183                 if(ratio > item_aspect)
 184                         ratio = item_aspect * item_aspect / ratio;
 185
 186                 if(ratio <= best_ratio)
 187                         break; // ratio starts decreasing by now, skip next configurations
 188
 189                 best_columns = columns;
 190                 best_rows = rows;
 191                 best_ratio = ratio;
 192
 193                 if(columns == 1)
 194                         break;
 195
 196                 --columns;
 197                 rows = ceil(item_count/columns);
 198         }
 199
 200         if(vertical)
 201                 return eX * best_rows + eY * best_columns;
 202         else
 203                 return eX * best_columns + eY * best_rows;
 204 }
 205
 206 float stringwidth_colors(string s, vector theSize)
 207 {
 208         return stringwidth(s, true, theSize);
 209 }
 210
 211 float stringwidth_nocolors(string s, vector theSize)
 212 {
 213         return stringwidth(s, false, theSize);
 214 }
 215
 216 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 217 {
 218         position.x -= 2 / 3 * strlen(text) * theScale.x;
 219         drawstring(position, text, theScale, rgb, theAlpha, flag);
 220 }
 221
 222 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 223 {
 224         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 225         drawstring(position, text, theScale, rgb, theAlpha, flag);
 226 }
 227
 228 // return the string of the onscreen race timer
 229 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 230 {
 231         string col;
 232         string timestr;
 233         string cpname;
 234         string lapstr;
 235         lapstr = "";
 236
 237         if(theirtime == 0) // goal hit
 238         {
 239                 if(mytime > 0)
 240                 {
 241                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 242                         col = "^1";
 243                 }
 244                 else if(mytime == 0)
 245                 {
 246                         timestr = "+0.0";
 247                         col = "^3";
 248                 }
 249                 else
 250                 {
 251                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 252                         col = "^2";
 253                 }
 254
 255                 if(lapdelta > 0)
 256                 {
 257                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 258                         col = "^2";
 259                 }
 260                 else if(lapdelta < 0)
 261                 {
 262                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 263                         col = "^1";
 264                 }
 265         }
 266         else if(theirtime > 0) // anticipation
 267         {
 268                 if(mytime >= theirtime)
 269                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 270                 else
 271                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 272                 col = "^3";
 273         }
 274         else
 275         {
 276                 col = "^7";
 277                 timestr = "";
 278         }
 279
 280         if(cp == 254)
 281                 cpname = _("Start line");
 282         else if(cp == 255)
 283                 cpname = _("Finish line");
 284         else if(cp)
 285                 cpname = sprintf(_("Intermediate %d"), cp);
 286         else
 287                 cpname = _("Finish line");
 288
 289         if(theirtime < 0)
 290                 return strcat(col, cpname);
 291         else if(theirname == "")
 292                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 293         else
 294                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 295 }
 296
 297 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 298 int race_CheckName(string net_name)
 299 {
 300         int i;
 301         for (i=RANKINGS_CNT-1;i>=0;--i)
 302                 if(grecordholder[i] == net_name)
 303                         return i+1;
 304         return 0;
 305 }
 306
 307 int GetPlayerColorForce(int i)
 308 {
 309         if(!teamplay)
 310                 return 0;
 311         else
 312                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 313 }
 314
 315 int GetPlayerColor(int i)
 316 {
 317         if(!playerslots[i].gotscores) // unconnected
 318                 return NUM_SPECTATOR;
 319         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 320                 return NUM_SPECTATOR;
 321         else
 322                 return GetPlayerColorForce(i);
 323 }
 324
 325 string GetPlayerName(int i)
 326 {
 327         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 328 }
 329
 330
 331 /*
 332 ==================
 333 HUD panels
 334 ==================
 335 */
 336
 337 // draw the background/borders
 338 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 339         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 340                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 341 } while(0)
 342
 343 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 344 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 345 {
 346         if(!length_ratio || !theAlpha)
 347                 return;
 348         if(length_ratio > 1)
 349                 length_ratio = 1;
 350         if (baralign == 3)
 351         {
 352                 if(length_ratio < -1)
 353                         length_ratio = -1;
 354         }
 355         else if(length_ratio < 0)
 356                 return;
 357
 358         vector square;
 359         vector width, height;
 360         if(vertical) {
 361                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 362                 if(precache_pic(pic) == "") {
 363                         pic = "gfx/hud/default/progressbar_vertical";
 364                 }
 365
 366         if (baralign == 1) // bottom align
 367                         theOrigin.y += (1 - length_ratio) * theSize.y;
 368         else if (baralign == 2) // center align
 369             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 370         else if (baralign == 3) // center align, positive values down, negative up
 371                 {
 372                         theSize.y *= 0.5;
 373                         if (length_ratio > 0)
 374                                 theOrigin.y += theSize.y;
 375                         else
 376                         {
 377                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 378                                 length_ratio = -length_ratio;
 379                         }
 380                 }
 381                 theSize.y *= length_ratio;
 382
 383                 vector bH;
 384                 width = eX * theSize.x;
 385                 height = eY * theSize.y;
 386                 if(theSize.y <= theSize.x * 2)
 387                 {
 388                         // button not high enough
 389                         // draw just upper and lower part then
 390                         square = eY * theSize.y * 0.5;
 391                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 392                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 393                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 394                 }
 395                 else
 396                 {
 397                         square = eY * theSize.x;
 398                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 399                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 400                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 401                 }
 402         } else {
 403                 pic = strcat(hud_skin_path, "/", pic);
 404                 if(precache_pic(pic) == "") {
 405                         pic = "gfx/hud/default/progressbar";
 406                 }
 407
 408                 if (baralign == 1) // right align
 409                         theOrigin.x += (1 - length_ratio) * theSize.x;
 410         else if (baralign == 2) // center align
 411             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 412         else if (baralign == 3) // center align, positive values on the right, negative on the left
 413                 {
 414                         theSize.x *= 0.5;
 415                         if (length_ratio > 0)
 416                                 theOrigin.x += theSize.x;
 417                         else
 418                         {
 419                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 420                                 length_ratio = -length_ratio;
 421                         }
 422                 }
 423                 theSize.x *= length_ratio;
 424
 425                 vector bW;
 426                 width = eX * theSize.x;
 427                 height = eY * theSize.y;
 428                 if(theSize.x <= theSize.y * 2)
 429                 {
 430                         // button not wide enough
 431                         // draw just left and right part then
 432                         square = eX * theSize.x * 0.5;
 433                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 434                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 435                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 436                 }
 437                 else
 438                 {
 439                         square = eX * theSize.y;
 440                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 441                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 442                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 443                 }
 444         }
 445 }
 446
 447 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 448 {
 449         if(!theAlpha)
 450                 return;
 451
 452         string pic;
 453         pic = strcat(hud_skin_path, "/num_leading");
 454         if(precache_pic(pic) == "") {
 455                 pic = "gfx/hud/default/num_leading";
 456         }
 457
 458         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 459         if(mySize.x/mySize.y > 2)
 460                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 461         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 462 }
 463
 464 // Weapon icons (#0)
 465 //
 466 entity weaponorder[WEP_MAXCOUNT];
 467 void weaponorder_swap(int i, int j, entity pass)
 468 {
 469         entity h = weaponorder[i];
 470         weaponorder[i] = weaponorder[j];
 471         weaponorder[j] = h;
 472 }
 473
 474 string weaponorder_cmp_str;
 475 int weaponorder_cmp(int i, int j, entity pass)
 476 {
 477         int ai, aj;
 478         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 479         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 480         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 481 }
 482
 483 void HUD_Weapons(void)
 484 {
 485         // declarations
 486         WepSet weapons_stat = WepSet_GetFromStat();
 487         int i;
 488         float f, a;
 489         float screen_ar;
 490         vector center = '0 0 0';
 491         int weapon_count, weapon_id;
 492         int row, column, rows = 0, columns = 0;
 493         bool vertical_order = true;
 494         float aspect = autocvar_hud_panel_weapons_aspect;
 495
 496         float timeout = autocvar_hud_panel_weapons_timeout;
 497         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 498         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 499
 500         vector barsize = '0 0 0', baroffset = '0 0 0';
 501         vector ammo_color = '1 0 1';
 502         float ammo_alpha = 1;
 503
 504         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 505         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 506
 507         vector weapon_pos, weapon_size = '0 0 0';
 508         vector color;
 509
 510         // check to see if we want to continue
 511         if(intermission == 2) return;
 512         if(hud != HUD_NORMAL) return;
 513
 514         if(!autocvar__hud_configure)
 515         {
 516                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 517                         return;
 518                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 519                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 520                 {
 521                         weaponprevtime = time;
 522                         return;
 523                 }
 524         }
 525
 526         // update generic hud functions
 527         HUD_Panel_UpdateCvars();
 528
 529         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 530         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 531         {
 532                 int weapon_cnt;
 533                 if(weaponorder_bypriority)
 534                         strunzone(weaponorder_bypriority);
 535                 if(weaponorder_byimpulse)
 536                         strunzone(weaponorder_byimpulse);
 537
 538                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 539                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 540                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 541
 542                 weapon_cnt = 0;
 543                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 544                 {
 545                         self = get_weaponinfo(i);
 546                         if(self.impulse >= 0)
 547                         {
 548                                 weaponorder[weapon_cnt] = self;
 549                                 ++weapon_cnt;
 550                         }
 551                 }
 552                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 553                         weaponorder[i] = world;
 554                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 555
 556                 weaponorder_cmp_str = string_null;
 557         }
 558
 559         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 560                 complain_weapon = 0;
 561
 562         if(autocvar__hud_configure)
 563         {
 564                 if(!weapons_stat)
 565                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 566                                 weapons_stat |= WepSet_FromWeapon(i);
 567
 568                 #if 0
 569                 /// debug code
 570                 if(cvar("wep_add"))
 571                 {
 572                         weapons_stat = '0 0 0';
 573                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 574                         for(i = WEP_FIRST; i <= countw; ++i)
 575                                 weapons_stat |= WepSet_FromWeapon(i);
 576                 }
 577                 #endif
 578         }
 579
 580         // determine which weapons are going to be shown
 581         if (autocvar_hud_panel_weapons_onlyowned)
 582         {
 583                 if(autocvar__hud_configure)
 584                 {
 585                         if(menu_enabled != 2)
 586                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 587                 }
 588
 589                 // do we own this weapon?
 590                 weapon_count = 0;
 591                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 592                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 593                                 ++weapon_count;
 594
 595
 596                 // might as well commit suicide now, no reason to live ;)
 597                 if (weapon_count == 0)
 598                         return;
 599
 600                 vector old_panel_size = panel_size;
 601                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 602
 603                 // get the all-weapons layout
 604                 vector table_size = HUD_GetTableSize_BestItemAR(WEP_COUNT, padded_panel_size, aspect);
 605                 columns = table_size.x;
 606                 rows = table_size.y;
 607                 weapon_size.x = padded_panel_size.x / columns;
 608                 weapon_size.y = padded_panel_size.y / rows;
 609
 610                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 611                 // we enlarge them a bit when possible to better match the desired aspect ratio
 612                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 613                 {
 614                         // maximum number of rows that allows to display items with the desired aspect ratio
 615                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 616                         columns = min(columns, ceil(weapon_count / max_rows));
 617                         rows = ceil(weapon_count / columns);
 618                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 619                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 620                         vertical_order = false;
 621                 }
 622                 else
 623                 {
 624                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 625                         rows = min(rows, ceil(weapon_count / max_columns));
 626                         columns = ceil(weapon_count / rows);
 627                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 628                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 629                         vertical_order = true;
 630                 }
 631
 632                 // reduce size of the panel
 633                 panel_size.x = columns * weapon_size.x;
 634                 panel_size.y = rows * weapon_size.y;
 635                 panel_size += '2 2 0' * panel_bg_padding;
 636
 637                 // center the resized panel, or snap it to the screen edge when close enough
 638                 if(panel_pos.x > vid_conwidth * 0.001)
 639                 {
 640                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 641                                 panel_pos.x += old_panel_size.x - panel_size.x;
 642                         else
 643                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 644                 }
 645                 else if(old_panel_size.x > vid_conwidth * 0.999)
 646                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 647
 648                 if(panel_pos.y > vid_conheight * 0.001)
 649                 {
 650                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 651                                 panel_pos.y += old_panel_size.y - panel_size.y;
 652                         else
 653                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 654                 }
 655                 else if(old_panel_size.y > vid_conheight * 0.999)
 656                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 657         }
 658         else
 659                 weapon_count = WEP_COUNT;
 660
 661         // animation for fading in/out the panel respectively when not in use
 662         if(!autocvar__hud_configure)
 663         {
 664                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 665                 {
 666                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 667
 668                         // fade the panel alpha
 669                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 670                         {
 671                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 672                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 673                         }
 674                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 675                         {
 676                                 panel_bg_alpha *= (1 - f);
 677                                 panel_fg_alpha *= (1 - f);
 678                         }
 679
 680                         // move the panel off the screen
 681                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 682                         {
 683                                 f *= f; // for a cooler movement
 684                                 center.x = panel_pos.x + panel_size.x/2;
 685                                 center.y = panel_pos.y + panel_size.y/2;
 686                                 screen_ar = vid_conwidth/vid_conheight;
 687                                 if (center.x/center.y < screen_ar) //bottom left
 688                                 {
 689                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 690                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 691                                         else //left
 692                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 693                                 }
 694                                 else //top right
 695                                 {
 696                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 697                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 698                                         else //top
 699                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 700                                 }
 701                                 if(f == 1)
 702                                         center.x = -1; // mark the panel as off screen
 703                         }
 704                         weaponprevtime = time - (1 - f) * timein_effect_length;
 705                 }
 706                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 707                 {
 708                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 709
 710                         // fade the panel alpha
 711                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 712                         {
 713                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 714                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 715                         }
 716                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 717                         {
 718                                 panel_bg_alpha *= (f);
 719                                 panel_fg_alpha *= (f);
 720                         }
 721
 722                         // move the panel back on screen
 723                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 724                         {
 725                                 f *= f; // for a cooler movement
 726                                 f = 1 - f;
 727                                 center.x = panel_pos.x + panel_size.x/2;
 728                                 center.y = panel_pos.y + panel_size.y/2;
 729                                 screen_ar = vid_conwidth/vid_conheight;
 730                                 if (center.x/center.y < screen_ar) //bottom left
 731                                 {
 732                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 733                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 734                                         else //left
 735                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 736                                 }
 737                                 else //top right
 738                                 {
 739                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 740                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 741                                         else //top
 742                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 743                                 }
 744                         }
 745                 }
 746         }
 747
 748         // draw the background, then change the virtual size of it to better fit other items inside
 749         HUD_Panel_DrawBg(1);
 750
 751         if(center.x == -1)
 752                 return;
 753
 754         if(panel_bg_padding)
 755         {
 756                 panel_pos += '1 1 0' * panel_bg_padding;
 757                 panel_size -= '2 2 0' * panel_bg_padding;
 758         }
 759
 760         // after the sizing and animations are done, update the other values
 761
 762         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 763         {
 764                 vector table_size = HUD_GetTableSize_BestItemAR(WEP_COUNT, panel_size, aspect);
 765                 columns = table_size.x;
 766                 rows = table_size.y;
 767                 weapon_size.x = panel_size.x / columns;
 768                 weapon_size.y = panel_size.y / rows;
 769                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 770         }
 771
 772         // calculate position/size for visual bar displaying ammount of ammo status
 773         if (autocvar_hud_panel_weapons_ammo)
 774         {
 775                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 776                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 777
 778                 if(weapon_size.x/weapon_size.y > aspect)
 779                 {
 780                         barsize.x = aspect * weapon_size.y;
 781                         barsize.y = weapon_size.y;
 782                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 783                 }
 784                 else
 785                 {
 786                         barsize.y = 1/aspect * weapon_size.x;
 787                         barsize.x = weapon_size.x;
 788                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 789                 }
 790         }
 791         if(autocvar_hud_panel_weapons_accuracy)
 792                 Accuracy_LoadColors();
 793
 794         // draw items
 795         row = column = 0;
 796         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 797         vector noncurrent_pos = '0 0 0';
 798         vector noncurrent_size = weapon_size * bound(0, autocvar_hud_panel_weapons_noncurrent_scale, 1);
 799         float noncurrent_alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_weapons_noncurrent_alpha, 1);
 800         bool isCurrent;
 801
 802         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 803         {
 804                 // retrieve information about the current weapon to be drawn
 805                 self = weaponorder[i];
 806                 weapon_id = self.impulse;
 807                 isCurrent = (self.weapon == switchweapon);
 808
 809                 // skip if this weapon doesn't exist
 810                 if(!self || weapon_id < 0) { continue; }
 811
 812                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 813                 if(autocvar_hud_panel_weapons_onlyowned)
 814                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 815                         continue;
 816
 817                 // figure out the drawing position of weapon
 818                 weapon_pos = (panel_pos + eX * column * weapon_size.x + eY * row * weapon_size.y);
 819                 noncurrent_pos.x = weapon_pos.x + (weapon_size.x - noncurrent_size.x) / 2;
 820                 noncurrent_pos.y = weapon_pos.y + (weapon_size.y - noncurrent_size.y) / 2;
 821
 822                 // draw background behind currently selected weapon
 823                 if(isCurrent)
 824                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 825
 826                 // draw the weapon accuracy
 827                 if(autocvar_hud_panel_weapons_accuracy)
 828                 {
 829                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 830                         if(panel_weapon_accuracy >= 0)
 831                         {
 832                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 833                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 834                         }
 835                 }
 836
 837                 // drawing all the weapon items
 838                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 839                 {
 840                         // draw the weapon image
 841                         if(isCurrent)
 842                                 drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 843                         else
 844                                 drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '1 1 1', noncurrent_alpha, DRAWFLAG_NORMAL);
 845
 846                         // draw weapon label string
 847                         switch(autocvar_hud_panel_weapons_label)
 848                         {
 849                                 case 1: // weapon number
 850                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 851                                         break;
 852
 853                                 case 2: // bind
 854                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 855                                         break;
 856
 857                                 case 3: // weapon name
 858                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 859                                         break;
 860
 861                                 default: // nothing
 862                                         break;
 863                         }
 864
 865                         // draw ammo status bar
 866                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 867                         {
 868                                 float ammo_full;
 869                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 870
 871                                 if(a > 0)
 872                                 {
 873                                         switch(self.ammo_field)
 874                                         {
 875                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 876                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 877                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 878                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 879                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 880                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 881                                                 default: ammo_full = 60;
 882                                         }
 883
 884                                         drawsetcliparea(
 885                                                 weapon_pos.x + baroffset.x,
 886                                                 weapon_pos.y + baroffset.y,
 887                                                 barsize.x * bound(0, a/ammo_full, 1),
 888                                                 barsize.y
 889                                         );
 890
 891                                         drawpic_aspect_skin(
 892                                                 weapon_pos,
 893                                                 "weapon_ammo",
 894                                                 weapon_size,
 895                                                 ammo_color,
 896                                                 ammo_alpha,
 897                                                 DRAWFLAG_NORMAL
 898                                         );
 899
 900                                         drawresetcliparea();
 901                                 }
 902                         }
 903                 }
 904                 else // draw a "ghost weapon icon" if you don't have the weapon
 905                 {
 906                         drawpic_aspect_skin(noncurrent_pos, self.model2, noncurrent_size, '0.2 0.2 0.2', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 907                 }
 908
 909                 // draw the complain message
 910                 if(self.weapon == complain_weapon)
 911                 {
 912                         if(fadetime)
 913                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 914                         else
 915                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 916
 917                         string s;
 918                         if(complain_weapon_type == 0) {
 919                                 s = _("Out of ammo");
 920                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 921                         }
 922                         else if(complain_weapon_type == 1) {
 923                                 s = _("Don't have");
 924                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 925                         }
 926                         else {
 927                                 s = _("Unavailable");
 928                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 929                         }
 930                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 931                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 932                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 933                 }
 934
 935                 #if 0
 936                 /// debug code
 937                 if(!autocvar_hud_panel_weapons_onlyowned)
 938                 {
 939                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 940                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 941                 }
 942                 #endif
 943
 944                 // continue with new position for the next weapon
 945                 if(vertical_order)
 946                 {
 947                         ++column;
 948                         if(column >= columns)
 949                         {
 950                                 column = 0;
 951                                 ++row;
 952                         }
 953                 }
 954                 else
 955                 {
 956                         ++row;
 957                         if(row >= rows)
 958                         {
 959                                 row = 0;
 960                                 ++column;
 961                         }
 962                 }
 963         }
 964 }
 965
 966 // Ammo (#1)
 967 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 968 {
 969         HUD_Panel_DrawProgressBar(
 970                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 971                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 972                 autocvar_hud_panel_ammo_progressbar_name,
 973                 progress, 0, 0, color,
 974                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 975 }
 976
 977 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 978 {
 979         float bonusNades    = getstatf(STAT_NADE_BONUS);
 980         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 981         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 982         vector nadeColor    = NADES[bonusType].m_color;
 983         string nadeIcon     = NADES[bonusType].m_icon;
 984
 985         vector iconPos, textPos;
 986
 987         if(autocvar_hud_panel_ammo_iconalign)
 988         {
 989                 iconPos = myPos + eX * 2 * mySize.y;
 990                 textPos = myPos;
 991         }
 992         else
 993         {
 994                 iconPos = myPos;
 995                 textPos = myPos + eX * mySize.y;
 996         }
 997
 998         if(bonusNades > 0 || bonusProgress > 0)
 999         {
1000                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
1001
1002                 if(autocvar_hud_panel_ammo_text)
1003                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1004
1005                 if(draw_expanding)
1006                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
1007
1008                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1009         }
1010 }
1011
1012 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
1013 {
1014         if(ammoType == ammo_none)
1015                 return;
1016
1017         // Initialize variables
1018
1019         int ammo;
1020         if(autocvar__hud_configure)
1021         {
1022                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1023                 ammo = 60;
1024         }
1025         else
1026                 ammo = getstati(GetAmmoStat(ammoType));
1027
1028         if(!isCurrent)
1029         {
1030                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1031                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1032                 mySize = mySize * scale;
1033         }
1034
1035         vector iconPos, textPos;
1036         if(autocvar_hud_panel_ammo_iconalign)
1037         {
1038                 iconPos = myPos + eX * 2 * mySize.y;
1039                 textPos = myPos;
1040         }
1041         else
1042         {
1043                 iconPos = myPos;
1044                 textPos = myPos + eX * mySize.y;
1045         }
1046
1047         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1048
1049         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1050         vector textColor;
1051         if(isInfinite)
1052                 textColor = '0.2 0.95 0';
1053         else if(isShadowed)
1054                 textColor = '0 0 0';
1055         else if(ammo < 10)
1056                 textColor = '0.8 0.04 0';
1057         else
1058                 textColor = '1 1 1';
1059
1060         float alpha;
1061         if(isCurrent)
1062                 alpha = panel_fg_alpha;
1063         else if(isShadowed)
1064                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1065         else
1066                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1067
1068         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1069
1070         // Draw item
1071
1072         if(isCurrent)
1073                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1074
1075         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1076                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1077
1078         if(autocvar_hud_panel_ammo_text)
1079                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1080
1081         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1082 }
1083
1084 int nade_prevstatus;
1085 int nade_prevframe;
1086 float nade_statuschange_time;
1087 void HUD_Ammo(void)
1088 {
1089         if(intermission == 2) return;
1090         if(hud != HUD_NORMAL) return;
1091         if(!autocvar__hud_configure)
1092         {
1093                 if(!autocvar_hud_panel_ammo) return;
1094                 if(spectatee_status == -1) return;
1095         }
1096
1097         HUD_Panel_UpdateCvars();
1098
1099         draw_beginBoldFont();
1100
1101         vector pos, mySize;
1102         pos = panel_pos;
1103         mySize = panel_size;
1104
1105         HUD_Panel_DrawBg(1);
1106         if(panel_bg_padding)
1107         {
1108                 pos += '1 1 0' * panel_bg_padding;
1109                 mySize -= '2 2 0' * panel_bg_padding;
1110         }
1111
1112         int rows = 0, columns, row, column;
1113         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1114         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1115         float nade_statuschange_elapsedtime;
1116         int total_ammo_count;
1117
1118         vector ammo_size;
1119         if (autocvar_hud_panel_ammo_onlycurrent)
1120                 total_ammo_count = 1;
1121         else
1122                 total_ammo_count = AMMO_COUNT;
1123
1124         if(draw_nades)
1125         {
1126                 ++total_ammo_count;
1127                 if (nade_cnt != nade_prevframe)
1128                 {
1129                         nade_statuschange_time = time;
1130                         nade_prevstatus = nade_prevframe;
1131                         nade_prevframe = nade_cnt;
1132                 }
1133         }
1134         else
1135                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1136
1137         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1138         columns = ceil((total_ammo_count)/rows);
1139         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1140
1141         vector offset = '0 0 0'; // fteqcc sucks
1142         float newSize;
1143         if(ammo_size.x/ammo_size.y > 3)
1144         {
1145                 newSize = 3 * ammo_size.y;
1146                 offset.x = ammo_size.x - newSize;
1147                 pos.x += offset.x/2;
1148                 ammo_size.x = newSize;
1149         }
1150         else
1151         {
1152                 newSize = 1/3 * ammo_size.x;
1153                 offset.y = ammo_size.y - newSize;
1154                 pos.y += offset.y/2;
1155                 ammo_size.y = newSize;
1156         }
1157
1158         int i;
1159         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1160         row = column = 0;
1161         if(autocvar_hud_panel_ammo_onlycurrent)
1162         {
1163                 if(autocvar__hud_configure)
1164                 {
1165                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1166                 }
1167                 else
1168                 {
1169                         DrawAmmoItem(
1170                                 pos,
1171                                 ammo_size,
1172                                 (get_weaponinfo(switchweapon)).ammo_field,
1173                                 true,
1174                                 infinite_ammo
1175                         );
1176                 }
1177
1178                 ++row;
1179                 if(row >= rows)
1180                 {
1181                         row = 0;
1182                         column = column + 1;
1183                 }
1184         }
1185         else
1186         {
1187                 .int ammotype;
1188                 row = column = 0;
1189                 for(i = 0; i < AMMO_COUNT; ++i)
1190                 {
1191                         ammotype = GetAmmoFieldFromNum(i);
1192                         DrawAmmoItem(
1193                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1194                                 ammo_size,
1195                                 ammotype,
1196                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1197                                 infinite_ammo
1198                         );
1199
1200                         ++row;
1201                         if(row >= rows)
1202                         {
1203                                 row = 0;
1204                                 column = column + 1;
1205                         }
1206                 }
1207         }
1208
1209         if (draw_nades)
1210         {
1211                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1212
1213                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1214
1215                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1216         }
1217
1218         draw_endBoldFont();
1219 }
1220
1221 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1222 {
1223         vector newPos = '0 0 0', newSize = '0 0 0';
1224         vector picpos, numpos;
1225
1226         if (vertical)
1227         {
1228                 if(mySize.y/mySize.x > 2)
1229                 {
1230                         newSize.y = 2 * mySize.x;
1231                         newSize.x = mySize.x;
1232
1233                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1234                         newPos.x = myPos.x;
1235                 }
1236                 else
1237                 {
1238                         newSize.x = 1/2 * mySize.y;
1239                         newSize.y = mySize.y;
1240
1241                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1242                         newPos.y = myPos.y;
1243                 }
1244
1245                 if(icon_right_align)
1246                 {
1247                         numpos = newPos;
1248                         picpos = newPos + eY * newSize.x;
1249                 }
1250                 else
1251                 {
1252                         picpos = newPos;
1253                         numpos = newPos + eY * newSize.x;
1254                 }
1255
1256                 newSize.y /= 2;
1257                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1258                 // make number smaller than icon, it looks better
1259                 // reduce only y to draw numbers with different number of digits with the same y size
1260                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1261                 newSize.y *= 0.7;
1262                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1263                 return;
1264         }
1265
1266         if(mySize.x/mySize.y > 3)
1267         {
1268                 newSize.x = 3 * mySize.y;
1269                 newSize.y = mySize.y;
1270
1271                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1272                 newPos.y = myPos.y;
1273         }
1274         else
1275         {
1276                 newSize.y = 1/3 * mySize.x;
1277                 newSize.x = mySize.x;
1278
1279                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1280                 newPos.x = myPos.x;
1281         }
1282
1283         if(icon_right_align) // right align
1284         {
1285                 numpos = newPos;
1286                 picpos = newPos + eX * 2 * newSize.y;
1287         }
1288         else // left align
1289         {
1290                 numpos = newPos + eX * newSize.y;
1291                 picpos = newPos;
1292         }
1293
1294         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1295         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1296         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1297         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1298 }
1299
1300 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1301 {
1302         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1303 }
1304
1305 // Powerups (#2)
1306 //
1307
1308 // Powerup item fields (reusing existing fields)
1309 .string message;  // Human readable name
1310 .string netname;  // Icon name
1311 .vector colormod; // Color
1312 .float count;     // Time left
1313 .float lifetime;  // Maximum time
1314
1315 entity powerupItems;
1316 int powerupItemsCount;
1317
1318 void resetPowerupItems()
1319 {
1320         entity item;
1321         for(item = powerupItems; item; item = item.chain)
1322                 item.count = 0;
1323
1324         powerupItemsCount = 0;
1325 }
1326
1327 void addPowerupItem(string name, string icon, vector color, float currentTime, float lifeTime)
1328 {
1329         if(!powerupItems)
1330                 powerupItems = spawn();
1331
1332         entity item;
1333         for(item = powerupItems; item.count; item = item.chain)
1334                 if(!item.chain)
1335                         item.chain = spawn();
1336
1337         item.message  = name;
1338         item.netname  = icon;
1339         item.colormod = color;
1340         item.count    = currentTime;
1341         item.lifetime = lifeTime;
1342
1343         ++powerupItemsCount;
1344 }
1345
1346 int getPowerupItemAlign(int align, int column, int row, int columns, int rows, bool isVertical)
1347 {
1348         if(align < 2)
1349                 return align;
1350
1351         bool isTop    =  isVertical && rows > 1 && row == 0;
1352         bool isBottom =  isVertical && rows > 1 && row == rows-1;
1353         bool isLeft   = !isVertical && columns > 1 && column == 0;
1354         bool isRight  = !isVertical && columns > 1 && column == columns-1;
1355
1356         if(isTop    || isLeft)  return (align == 2) ? 1 : 0;
1357         if(isBottom || isRight) return (align == 2) ? 0 : 1;
1358
1359         return 2;
1360 }
1361
1362 void HUD_Powerups()
1363 {
1364         if(intermission == 2) return;
1365
1366         int allItems = getstati(STAT_ITEMS, 0, 24);
1367         int allBuffs = getstati(STAT_BUFFS, 0, 24);
1368         int strengthTime, shieldTime, superTime;
1369
1370         // Initialize items
1371         if(!autocvar__hud_configure)
1372         {
1373                 if(!autocvar_hud_panel_powerups) return;
1374                 if(spectatee_status == -1) return;
1375                 if(getstati(STAT_HEALTH) <= 0) return;
1376                 if(!(allItems & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON)) && !allBuffs) return;
1377
1378                 strengthTime = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1379                 shieldTime = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1380                 superTime = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1381
1382                 if(allItems & IT_UNLIMITED_SUPERWEAPONS)
1383                         superTime = 99;
1384
1385                 // Prevent stuff to show up on mismatch that will be fixed next frame
1386                 if(!(allItems & IT_SUPERWEAPON))
1387                         superTime = 0;
1388         }
1389         else
1390         {
1391                 strengthTime = 15;
1392                 shieldTime = 27;
1393                 superTime = 13;
1394                 allBuffs = 0;
1395         }
1396
1397         // Add items to linked list
1398         resetPowerupItems();
1399
1400         if(strengthTime)
1401                 addPowerupItem("Strength", "strength", autocvar_hud_progressbar_strength_color, strengthTime, 30);
1402         if(shieldTime)
1403                 addPowerupItem("Shield", "shield", autocvar_hud_progressbar_shield_color, shieldTime, 30);
1404         if(superTime)
1405                 addPowerupItem("Superweapons", "superweapons", autocvar_hud_progressbar_superweapons_color, superTime, 30);
1406
1407         FOREACH(BUFFS, it.m_itemid & allBuffs, LAMBDA(
1408                 addPowerupItem(it.m_prettyName, strcat("buff_", it.m_name), it.m_color, bound(0, getstatf(STAT_BUFF_TIME) - time, 99), 60);
1409         ));
1410
1411         if(!powerupItemsCount)
1412                 return;
1413
1414         // Draw panel background
1415         HUD_Panel_UpdateCvars();
1416         HUD_Panel_DrawBg(1);
1417
1418         // Set drawing area
1419         vector pos = panel_pos;
1420         vector size = panel_size;
1421         bool isVertical = size.y > size.x;
1422
1423         if(panel_bg_padding)
1424         {
1425                 pos += '1 1 0' * panel_bg_padding;
1426                 size -= '2 2 0' * panel_bg_padding;
1427         }
1428
1429         // Find best partitioning of the drawing area
1430         const float DESIRED_ASPECT = 6;
1431         float aspect = 0, a;
1432         int columns = 0, c;
1433         int rows = 0, r;
1434         int i = 1;
1435
1436         do
1437         {
1438                 c = floor(powerupItemsCount / i);
1439                 r = ceil(powerupItemsCount / c);
1440                 a = isVertical ? (size.y/r) / (size.x/c) : (size.x/c) / (size.y/r);
1441
1442                 if(i == 1 || fabs(DESIRED_ASPECT - a) < fabs(DESIRED_ASPECT - aspect))
1443                 {
1444                         aspect = a;
1445                         columns = c;
1446                         rows = r;
1447                 }
1448         }
1449         while(++i <= powerupItemsCount);
1450
1451         // Prevent single items from getting too wide
1452         if(powerupItemsCount == 1 && aspect > DESIRED_ASPECT)
1453         {
1454                 if(isVertical)
1455                 {
1456                         size.y *= 0.5;
1457                         pos.y += size.y * 0.5;
1458                 }
1459                 else
1460                 {
1461                         size.x *= 0.5;
1462                         pos.x += size.x * 0.5;
1463                 }
1464         }
1465
1466         // Draw items from linked list
1467         vector itemPos = pos;
1468         vector itemSize = eX * (size.x / columns) + eY * (size.y / rows);
1469         vector textColor = '1 1 1';
1470
1471         int fullSeconds = 0;
1472         int align = 0;
1473         int column = 0;
1474         int row = 0;
1475
1476         draw_beginBoldFont();
1477         for(entity item = powerupItems; item.count; item = item.chain)
1478         {
1479                 itemPos = eX * (pos.x + column * itemSize.x) + eY * (pos.y + row * itemSize.y);
1480
1481                 // Draw progressbar
1482                 if(autocvar_hud_panel_powerups_progressbar)
1483                 {
1484                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_baralign, column, row, columns, rows, isVertical);
1485                         HUD_Panel_DrawProgressBar(itemPos, itemSize, "progressbar", item.count / item.lifetime, isVertical, align, item.colormod, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1486                 }
1487
1488                 // Draw icon and text
1489                 if(autocvar_hud_panel_powerups_text)
1490                 {
1491                         align = getPowerupItemAlign(autocvar_hud_panel_powerups_iconalign, column, row, columns, rows, isVertical);
1492                         fullSeconds = ceil(item.count);
1493                         textColor = '0.6 0.6 0.6' + (item.colormod * 0.4);
1494
1495                         if(item.count > 1)
1496                                 DrawNumIcon(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha);
1497                         if(item.count <= 5)
1498                                 DrawNumIcon_expanding(itemPos, itemSize, fullSeconds, item.netname, isVertical, align, textColor, panel_fg_alpha, bound(0, (fullSeconds - item.count) / 0.5, 1));
1499                 }
1500
1501                 // Determine next section
1502                 if(isVertical)
1503                 {
1504                         if(++column >= columns)
1505                         {
1506                                 column = 0;
1507                                 ++row;
1508                         }
1509                 }
1510                 else
1511                 {
1512                         if(++row >= rows)
1513                         {
1514                                 row = 0;
1515                                 ++column;
1516                         }
1517                 }
1518         }
1519         draw_endBoldFont();
1520 }
1521
1522 // Health/armor (#3)
1523 //
1524
1525
1526 void HUD_HealthArmor(void)
1527 {
1528         int armor, health, fuel;
1529         if(intermission == 2) return;
1530         if(!autocvar__hud_configure)
1531         {
1532                 if(!autocvar_hud_panel_healtharmor) return;
1533                 if(hud != HUD_NORMAL) return;
1534                 if(spectatee_status == -1) return;
1535
1536                 health = getstati(STAT_HEALTH);
1537                 if(health <= 0)
1538                 {
1539                         prev_health = -1;
1540                         return;
1541                 }
1542                 armor = getstati(STAT_ARMOR);
1543
1544                 // code to check for spectatee_status changes is in Ent_ClientData()
1545                 // prev_p_health and prev_health can be set to -1 there
1546
1547                 if (prev_p_health == -1)
1548                 {
1549                         // no effect
1550                         health_beforedamage = 0;
1551                         armor_beforedamage = 0;
1552                         health_damagetime = 0;
1553                         armor_damagetime = 0;
1554                         prev_health = health;
1555                         prev_armor = armor;
1556                         old_p_health = health;
1557                         old_p_armor = armor;
1558                         prev_p_health = health;
1559                         prev_p_armor = armor;
1560                 }
1561                 else if (prev_health == -1)
1562                 {
1563                         //start the load effect
1564                         health_damagetime = 0;
1565                         armor_damagetime = 0;
1566                         prev_health = 0;
1567                         prev_armor = 0;
1568                 }
1569                 fuel = getstati(STAT_FUEL);
1570         }
1571         else
1572         {
1573                 health = 150;
1574                 armor = 75;
1575                 fuel = 20;
1576         }
1577
1578         HUD_Panel_UpdateCvars();
1579
1580         draw_beginBoldFont();
1581
1582         vector pos, mySize;
1583         pos = panel_pos;
1584         mySize = panel_size;
1585
1586         HUD_Panel_DrawBg(1);
1587         if(panel_bg_padding)
1588         {
1589                 pos += '1 1 0' * panel_bg_padding;
1590                 mySize -= '2 2 0' * panel_bg_padding;
1591         }
1592
1593         int baralign = autocvar_hud_panel_healtharmor_baralign;
1594         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1595
1596     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1597     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1598         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1599         {
1600                 vector v;
1601                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1602
1603                 float x;
1604                 x = floor(v.x + 1);
1605
1606         float maxtotal = maxhealth + maxarmor;
1607                 string biggercount;
1608                 if(v.z) // NOT fully armored
1609                 {
1610                         biggercount = "health";
1611                         if(autocvar_hud_panel_healtharmor_progressbar)
1612                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1613                         if(armor)
1614             if(autocvar_hud_panel_healtharmor_text)
1615                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1616                 }
1617                 else
1618                 {
1619                         biggercount = "armor";
1620                         if(autocvar_hud_panel_healtharmor_progressbar)
1621                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1622                         if(health)
1623             if(autocvar_hud_panel_healtharmor_text)
1624                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1625                 }
1626         if(autocvar_hud_panel_healtharmor_text)
1627                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1628
1629                 if(fuel)
1630                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1631         }
1632         else
1633         {
1634                 float panel_ar = mySize.x/mySize.y;
1635                 bool is_vertical = (panel_ar < 1);
1636                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1637                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1638                 {
1639                         mySize.x *= 0.5;
1640                         if (autocvar_hud_panel_healtharmor_flip)
1641                                 health_offset.x = mySize.x;
1642                         else
1643                                 armor_offset.x = mySize.x;
1644                 }
1645                 else
1646                 {
1647                         mySize.y *= 0.5;
1648                         if (autocvar_hud_panel_healtharmor_flip)
1649                                 health_offset.y = mySize.y;
1650                         else
1651                                 armor_offset.y = mySize.y;
1652                 }
1653
1654                 bool health_baralign, armor_baralign, fuel_baralign;
1655                 bool health_iconalign, armor_iconalign;
1656                 if (autocvar_hud_panel_healtharmor_flip)
1657                 {
1658                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1659                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1660                         fuel_baralign = health_baralign;
1661                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1662                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1663                 }
1664                 else
1665                 {
1666                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1667                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1668                         fuel_baralign = armor_baralign;
1669                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1670                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1671                 }
1672
1673                 //if(health)
1674                 {
1675                         if(autocvar_hud_panel_healtharmor_progressbar)
1676                         {
1677                                 float p_health, pain_health_alpha;
1678                                 p_health = health;
1679                                 pain_health_alpha = 1;
1680                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1681                                 {
1682                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1683                                         {
1684                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1685                                                 {
1686                                                         if (time - old_p_healthtime < 1)
1687                                                                 old_p_health = prev_p_health;
1688                                                         else
1689                                                                 old_p_health = prev_health;
1690                                                         old_p_healthtime = time;
1691                                                 }
1692                                                 if (time - old_p_healthtime < 1)
1693                                                 {
1694                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1695                                                         prev_p_health = p_health;
1696                                                 }
1697                                         }
1698                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1699                                         {
1700                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1701                                                 {
1702                                                         if (time - health_damagetime >= 1)
1703                                                                 health_beforedamage = prev_health;
1704                                                         health_damagetime = time;
1705                                                 }
1706                                                 if (time - health_damagetime < 1)
1707                                                 {
1708                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1709                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1710                                                 }
1711                                         }
1712                                         prev_health = health;
1713
1714                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1715                                         {
1716                                                 float BLINK_FACTOR = 0.15;
1717                                                 float BLINK_BASE = 0.85;
1718                                                 float BLINK_FREQ = 9;
1719                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1720                                         }
1721                                 }
1722                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1723                         }
1724                         if(autocvar_hud_panel_healtharmor_text)
1725                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1726                 }
1727
1728                 if(armor)
1729                 {
1730                         if(autocvar_hud_panel_healtharmor_progressbar)
1731                         {
1732                                 float p_armor;
1733                                 p_armor = armor;
1734                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1735                                 {
1736                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1737                                         {
1738                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1739                                                 {
1740                                                         if (time - old_p_armortime < 1)
1741                                                                 old_p_armor = prev_p_armor;
1742                                                         else
1743                                                                 old_p_armor = prev_armor;
1744                                                         old_p_armortime = time;
1745                                                 }
1746                                                 if (time - old_p_armortime < 1)
1747                                                 {
1748                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1749                                                         prev_p_armor = p_armor;
1750                                                 }
1751                                         }
1752                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1753                                         {
1754                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1755                                                 {
1756                                                         if (time - armor_damagetime >= 1)
1757                                                                 armor_beforedamage = prev_armor;
1758                                                         armor_damagetime = time;
1759                                                 }
1760                                                 if (time - armor_damagetime < 1)
1761                                                 {
1762                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1763                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1764                                                 }
1765                                         }
1766                                         prev_armor = armor;
1767                                 }
1768                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1769                         }
1770                         if(autocvar_hud_panel_healtharmor_text)
1771                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1772                 }
1773
1774                 if(fuel)
1775                 {
1776                         if (is_vertical)
1777                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1778                         else
1779                                 mySize.y *= 0.2;
1780                         if (panel_ar >= 4)
1781                                 mySize.x *= 2; //restore full panel size
1782                         else if (panel_ar < 1/4)
1783                                 mySize.y *= 2; //restore full panel size
1784                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1785                 }
1786         }
1787
1788         draw_endBoldFont();
1789 }
1790
1791 // Notification area (#4)
1792 //
1793
1794 void HUD_Notify_Push(string icon, string attacker, string victim)
1795 {
1796         if (icon == "")
1797                 return;
1798
1799         ++notify_count;
1800         --notify_index;
1801
1802         if (notify_index == -1)
1803                 notify_index = NOTIFY_MAX_ENTRIES-1;
1804
1805         // Free old strings
1806         if (notify_attackers[notify_index])
1807                 strunzone(notify_attackers[notify_index]);
1808
1809         if (notify_victims[notify_index])
1810                 strunzone(notify_victims[notify_index]);
1811
1812         if (notify_icons[notify_index])
1813                 strunzone(notify_icons[notify_index]);
1814
1815         // Allocate new strings
1816         if (victim != "")
1817         {
1818                 notify_attackers[notify_index] = strzone(attacker);
1819                 notify_victims[notify_index] = strzone(victim);
1820         }
1821         else
1822         {
1823                 // In case of a notification without a victim, the attacker
1824                 // is displayed on the victim's side. Instead of special
1825                 // treatment later on, we can simply switch them here.
1826                 notify_attackers[notify_index] = string_null;
1827                 notify_victims[notify_index] = strzone(attacker);
1828         }
1829
1830         notify_icons[notify_index] = strzone(icon);
1831         notify_times[notify_index] = time;
1832 }
1833
1834 void HUD_Notify(void)
1835 {
1836         if(intermission == 2) return;
1837         if (!autocvar__hud_configure)
1838                 if (!autocvar_hud_panel_notify)
1839                         return;
1840
1841         HUD_Panel_UpdateCvars();
1842         HUD_Panel_DrawBg(1);
1843
1844         if (!autocvar__hud_configure)
1845                 if (notify_count == 0)
1846                         return;
1847
1848         vector pos, size;
1849         pos  = panel_pos;
1850         size = panel_size;
1851
1852         if (panel_bg_padding)
1853         {
1854                 pos  += '1 1 0' * panel_bg_padding;
1855                 size -= '2 2 0' * panel_bg_padding;
1856         }
1857
1858         float fade_start = max(0, autocvar_hud_panel_notify_time);
1859         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1860         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1861
1862         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1863         float entry_height = size.y / entry_count;
1864
1865         float panel_width_half = size.x * 0.5;
1866         float icon_width_half = entry_height * icon_aspect / 2;
1867         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1868
1869         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1870         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1871         vector icon_left = eX * (panel_width_half - icon_width_half);
1872         vector attacker_right = eX * name_maxwidth;
1873         vector victim_left = eX * (size.x - name_maxwidth);
1874
1875         vector attacker_pos, victim_pos, icon_pos;
1876         string attacker, victim, icon;
1877         int i, j, count, step, limit;
1878         float alpha;
1879
1880         if (autocvar_hud_panel_notify_flip)
1881         {
1882                 // Order items from the top down
1883                 i = 0;
1884                 step = +1;
1885                 limit = entry_count;
1886         }
1887         else
1888         {
1889                 // Order items from the bottom up
1890                 i = entry_count - 1;
1891                 step = -1;
1892                 limit = -1;
1893         }
1894
1895         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1896         {
1897                 if(autocvar__hud_configure)
1898                 {
1899                         attacker = sprintf(_("Player %d"), count + 1);
1900                         victim = sprintf(_("Player %d"), count + 2);
1901                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1902                         alpha = bound(0, 1.2 - count / entry_count, 1);
1903                 }
1904                 else
1905                 {
1906                         if (j == NOTIFY_MAX_ENTRIES)
1907                                 j = 0;
1908
1909                         if (notify_times[j] + fade_start > time)
1910                                 alpha = 1;
1911                         else if (fade_time != 0)
1912                         {
1913                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1914                                 if (alpha == 0)
1915                                         break;
1916                         }
1917                         else
1918                                 break;
1919
1920                         attacker = notify_attackers[j];
1921                         victim = notify_victims[j];
1922                         icon = notify_icons[j];
1923                 }
1924
1925                 if (icon != "" && victim != "")
1926                 {
1927                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1928
1929                         icon_pos = pos + icon_left + eY * i * entry_height;
1930                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1931
1932                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1933                         victim_pos = pos + victim_left + name_top;
1934                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1935
1936                         if (attacker != "")
1937                         {
1938                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1939                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1940                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1941                         }
1942                 }
1943         }
1944
1945         notify_count = count;
1946 }
1947
1948 // Timer (#5)
1949 //
1950 // TODO: macro
1951 string seconds_tostring(float sec)
1952 {
1953         float minutes;
1954         minutes = floor(sec / 60);
1955
1956         sec -= minutes * 60;
1957         return sprintf("%d:%02d", minutes, sec);
1958 }
1959
1960 void HUD_Timer(void)
1961 {
1962         if(intermission == 2) return;
1963         if(!autocvar__hud_configure)
1964         {
1965                 if(!autocvar_hud_panel_timer) return;
1966         }
1967
1968         HUD_Panel_UpdateCvars();
1969
1970         draw_beginBoldFont();
1971
1972         vector pos, mySize;
1973         pos = panel_pos;
1974         mySize = panel_size;
1975
1976         HUD_Panel_DrawBg(1);
1977         if(panel_bg_padding)
1978         {
1979                 pos += '1 1 0' * panel_bg_padding;
1980                 mySize -= '2 2 0' * panel_bg_padding;
1981         }
1982
1983         string timer;
1984         float timelimit, elapsedTime, timeleft, minutesLeft;
1985
1986         timelimit = getstatf(STAT_TIMELIMIT);
1987
1988         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1989         timeleft = ceil(timeleft);
1990
1991         minutesLeft = floor(timeleft / 60);
1992
1993         vector timer_color;
1994         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1995                 timer_color = '1 1 1'; //white
1996         else if(minutesLeft >= 1)
1997                 timer_color = '1 1 0'; //yellow
1998         else
1999                 timer_color = '1 0 0'; //red
2000
2001         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
2002                 if (time < getstatf(STAT_GAMESTARTTIME)) {
2003                         //while restart is still active, show 00:00
2004                         timer = seconds_tostring(0);
2005                 } else {
2006                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
2007                         timer = seconds_tostring(elapsedTime);
2008                 }
2009         } else {
2010                 timer = seconds_tostring(timeleft);
2011         }
2012
2013         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2014
2015         draw_endBoldFont();
2016 }
2017
2018 // Radar (#6)
2019 //
2020 void HUD_Radar(void)
2021 {
2022         if(intermission == 2) return;
2023         if (!autocvar__hud_configure)
2024         {
2025                 if (hud_panel_radar_maximized)
2026                 {
2027                         if (!hud_draw_maximized) return;
2028                 }
2029                 else
2030                 {
2031                         if (autocvar_hud_panel_radar == 0) return;
2032                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
2033                         if(radar_panel_modified)
2034                         {
2035                                 panel.update_time = time; // forces reload of panel attributes
2036                                 radar_panel_modified = false;
2037                         }
2038                 }
2039         }
2040
2041         HUD_Panel_UpdateCvars();
2042
2043         float f = 0;
2044
2045         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2046         {
2047                 panel_size = autocvar_hud_panel_radar_maximized_size;
2048                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2049                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2050                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2051                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2052
2053                 string panel_bg;
2054                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2055                 if(precache_pic(panel_bg) == "")
2056                         panel_bg = "gfx/hud/default/border_default"; // fallback
2057                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2058                         radar_panel_modified = true;
2059                 if(panel.current_panel_bg)
2060                         strunzone(panel.current_panel_bg);
2061                 panel.current_panel_bg = strzone(panel_bg);
2062
2063                 switch(hud_panel_radar_maximized_zoommode)
2064                 {
2065                         default:
2066                         case 0:
2067                                 f = current_zoomfraction;
2068                                 break;
2069                         case 1:
2070                                 f = 1 - current_zoomfraction;
2071                                 break;
2072                         case 2:
2073                                 f = 0;
2074                                 break;
2075                         case 3:
2076                                 f = 1;
2077                                 break;
2078                 }
2079
2080                 switch(hud_panel_radar_maximized_rotation)
2081                 {
2082                         case 0:
2083                                 teamradar_angle = view_angles.y - 90;
2084                                 break;
2085                         default:
2086                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2087                                 break;
2088                 }
2089         }
2090         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2091         {
2092                 switch(hud_panel_radar_zoommode)
2093                 {
2094                         default:
2095                         case 0:
2096                                 f = current_zoomfraction;
2097                                 break;
2098                         case 1:
2099                                 f = 1 - current_zoomfraction;
2100                                 break;
2101                         case 2:
2102                                 f = 0;
2103                                 break;
2104                         case 3:
2105                                 f = 1;
2106                                 break;
2107                 }
2108
2109                 switch(hud_panel_radar_rotation)
2110                 {
2111                         case 0:
2112                                 teamradar_angle = view_angles.y - 90;
2113                                 break;
2114                         default:
2115                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2116                                 break;
2117                 }
2118         }
2119
2120         vector pos, mySize;
2121         pos = panel_pos;
2122         mySize = panel_size;
2123
2124         HUD_Panel_DrawBg(1);
2125         if(panel_bg_padding)
2126         {
2127                 pos += '1 1 0' * panel_bg_padding;
2128                 mySize -= '2 2 0' * panel_bg_padding;
2129         }
2130
2131         int color2;
2132         entity tm;
2133         float scale2d, normalsize, bigsize;
2134
2135         teamradar_origin2d = pos + 0.5 * mySize;
2136         teamradar_size2d = mySize;
2137
2138         if(minimapname == "")
2139                 return;
2140
2141         teamradar_loadcvars();
2142
2143         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2144         teamradar_size2d = mySize;
2145
2146         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2147
2148         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2149         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2150         {
2151                 // max-min distance must fit the radar in any rotation
2152                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2153         }
2154         else
2155         {
2156                 vector c0, c1, c2, c3, span;
2157                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2158                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2159                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2160                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2161                 span = '0 0 0';
2162                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2163                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2164
2165                 // max-min distance must fit the radar in x=x, y=y
2166                 bigsize = min(
2167                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2168                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2169                 );
2170         }
2171
2172         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2173         if(bigsize > normalsize)
2174                 normalsize = bigsize;
2175
2176         teamradar_size =
2177                   f * bigsize
2178                 + (1 - f) * normalsize;
2179         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2180                   f * mi_center
2181                 + (1 - f) * view_origin);
2182
2183         drawsetcliparea(
2184                 pos.x,
2185                 pos.y,
2186                 mySize.x,
2187                 mySize.y
2188         );
2189
2190         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2191
2192         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2193                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2194         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2195                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2196         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2197         {
2198                 color2 = GetPlayerColor(tm.sv_entnum);
2199                 //if(color == NUM_SPECTATOR || color == color2)
2200                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2201         }
2202         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2203
2204         drawresetcliparea();
2205 }
2206
2207 // Score (#7)
2208 //
2209 void HUD_UpdatePlayerTeams();
2210 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2211 {
2212         float score;
2213         entity tm = world, pl;
2214         int SCOREPANEL_MAX_ENTRIES = 6;
2215         float SCOREPANEL_ASPECTRATIO = 2;
2216         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2217         vector fontsize = '1 1 0' * (mySize.y/entries);
2218
2219         vector rgb, score_color;
2220         rgb = '1 1 1';
2221         score_color = '1 1 1';
2222
2223         float name_size = mySize.x*0.75;
2224         float spacing_size = mySize.x*0.04;
2225         const float highlight_alpha = 0.2;
2226         int i = 0, first_pl = 0;
2227         bool me_printed = false;
2228         string s;
2229         if (autocvar__hud_configure)
2230         {
2231                 float players_per_team = 0;
2232                 if (team_count)
2233                 {
2234                         // show team scores in the first line
2235                         float score_size = mySize.x / team_count;
2236                         players_per_team = max(2, ceil((entries - 1) / team_count));
2237                         for(i=0; i<team_count; ++i) {
2238                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2239                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2240                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2241                         }
2242                         first_pl = 1;
2243                         pos.y += fontsize.y;
2244                 }
2245                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2246                 for (i=first_pl; i<entries; ++i)
2247                 {
2248                         //simulate my score is lower than all displayed players,
2249                         //so that I don't appear at all showing pure rankings.
2250                         //This is to better show the difference between the 2 ranking views
2251                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2252                         {
2253                                 rgb = '1 1 0';
2254                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2255                                 s = GetPlayerName(player_localnum);
2256                                 score = 7;
2257                         }
2258                         else
2259                         {
2260                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2261                                 score -= 3;
2262                         }
2263
2264                         if (team_count)
2265                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2266                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2267                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2268                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2269                         pos.y += fontsize.y;
2270                 }
2271                 return;
2272         }
2273
2274         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2275                 HUD_UpdatePlayerTeams();
2276         if (team_count)
2277         {
2278                 // show team scores in the first line
2279                 float score_size = mySize.x / team_count;
2280                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2281                         if(tm.team == NUM_SPECTATOR)
2282                                 continue;
2283                         if (tm.team == myteam)
2284                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2285                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2286                         ++i;
2287                 }
2288                 first_pl = 1;
2289                 pos.y += fontsize.y;
2290                 tm = teams.sort_next;
2291         }
2292         i = first_pl;
2293
2294         do
2295         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2296         {
2297                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2298                         continue;
2299
2300                 if (i == entries-1 && !me_printed && pl != me)
2301                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2302                 {
2303                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2304                                 if (pl.team != NUM_SPECTATOR)
2305                                         break;
2306
2307                         if (pl)
2308                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2309                         else
2310                                 rgb = '1 0 0'; //last: red
2311                         pl = me;
2312                 }
2313
2314                 if (pl == me)
2315                 {
2316                         if (i == first_pl)
2317                                 rgb = '0 1 0'; //first: green
2318                         me_printed = true;
2319                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2320                 }
2321                 if (team_count)
2322                         score_color = Team_ColorRGB(pl.team) * 0.8;
2323                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2324                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2325                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2326                 pos.y += fontsize.y;
2327                 ++i;
2328         }
2329         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2330 }
2331
2332 void HUD_Score(void)
2333 {
2334         if(intermission == 2) return;
2335         if(!autocvar__hud_configure)
2336         {
2337                 if(!autocvar_hud_panel_score) return;
2338                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2339         }
2340
2341         HUD_Panel_UpdateCvars();
2342         vector pos, mySize;
2343         pos = panel_pos;
2344         mySize = panel_size;
2345
2346         HUD_Panel_DrawBg(1);
2347         if(panel_bg_padding)
2348         {
2349                 pos += '1 1 0' * panel_bg_padding;
2350                 mySize -= '2 2 0' * panel_bg_padding;
2351         }
2352
2353         float score, distribution = 0;
2354         string sign;
2355         vector distribution_color;
2356         entity tm, pl, me;
2357
2358         me = playerslots[current_player];
2359
2360         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2361                 string timer, distrtimer;
2362
2363                 pl = players.sort_next;
2364                 if(pl == me)
2365                         pl = pl.sort_next;
2366                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2367                         if(pl.scores[ps_primary] == 0)
2368                                 pl = world;
2369
2370                 score = me.(scores[ps_primary]);
2371                 timer = TIME_ENCODED_TOSTRING(score);
2372
2373                 draw_beginBoldFont();
2374                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2375                         // distribution display
2376                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2377
2378                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2379
2380                         if (distribution <= 0) {
2381                                 distribution_color = '0 1 0';
2382                                 sign = "-";
2383                         }
2384                         else {
2385                                 distribution_color = '1 0 0';
2386                                 sign = "+";
2387                         }
2388                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2389                 }
2390                 // race record display
2391                 if (distribution <= 0)
2392                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2393                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2394                 draw_endBoldFont();
2395         } else if (!teamplay) { // non-teamgames
2396                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2397                 {
2398                         HUD_Score_Rankings(pos, mySize, me);
2399                         return;
2400                 }
2401                 // me vector := [team/connected frags id]
2402                 pl = players.sort_next;
2403                 if(pl == me)
2404                         pl = pl.sort_next;
2405
2406                 if(autocvar__hud_configure)
2407                         distribution = 42;
2408                 else if(pl)
2409                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2410                 else
2411                         distribution = 0;
2412
2413                 score = me.(scores[ps_primary]);
2414                 if(autocvar__hud_configure)
2415                         score = 123;
2416
2417                 if(distribution >= 5)
2418                         distribution_color = eY;
2419                 else if(distribution >= 0)
2420                         distribution_color = '1 1 1';
2421                 else if(distribution >= -5)
2422                         distribution_color = '1 1 0';
2423                 else
2424                         distribution_color = eX;
2425
2426                 string distribution_str;
2427                 distribution_str = ftos(distribution);
2428                 draw_beginBoldFont();
2429                 if (distribution >= 0)
2430                 {
2431                         if (distribution > 0)
2432                                 distribution_str = strcat("+", distribution_str);
2433                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2434                 }
2435                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2436                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2437                 draw_endBoldFont();
2438         } else { // teamgames
2439                 float row, column, rows = 0, columns = 0;
2440                 vector offset = '0 0 0';
2441                 vector score_pos, score_size; //for scores other than myteam
2442                 if(autocvar_hud_panel_score_rankings)
2443                 {
2444                         HUD_Score_Rankings(pos, mySize, me);
2445                         return;
2446                 }
2447                 if(spectatee_status == -1)
2448                 {
2449                         rows = HUD_GetRowCount(team_count, mySize, 3);
2450                         columns = ceil(team_count/rows);
2451                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2452
2453                         float newSize;
2454                         if(score_size.x/score_size.y > 3)
2455                         {
2456                                 newSize = 3 * score_size.y;
2457                                 offset.x = score_size.x - newSize;
2458                                 pos.x += offset.x/2;
2459                                 score_size.x = newSize;
2460                         }
2461                         else
2462                         {
2463                                 newSize = 1/3 * score_size.x;
2464                                 offset.y = score_size.y - newSize;
2465                                 pos.y += offset.y/2;
2466                                 score_size.y = newSize;
2467                         }
2468                 }
2469                 else
2470                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2471
2472                 float max_fragcount;
2473                 max_fragcount = -99;
2474                 draw_beginBoldFont();
2475                 row = column = 0;
2476                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2477                         if(tm.team == NUM_SPECTATOR)
2478                                 continue;
2479                         score = tm.(teamscores[ts_primary]);
2480                         if(autocvar__hud_configure)
2481                                 score = 123;
2482
2483                         if (score > max_fragcount)
2484                                 max_fragcount = score;
2485
2486                         if (spectatee_status == -1)
2487                         {
2488                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2489                                 if (max_fragcount == score)
2490                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2491                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2492                                 ++row;
2493                                 if(row >= rows)
2494                                 {
2495                                         row = 0;
2496                                         ++column;
2497                                 }
2498                         }
2499                         else if(tm.team == myteam) {
2500                                 if (max_fragcount == score)
2501                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2502                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2503                         } else {
2504                                 if (max_fragcount == score)
2505                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2506                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2507                                 ++rows;
2508                         }
2509                 }
2510                 draw_endBoldFont();
2511         }
2512 }
2513
2514 // Race timer (#8)
2515 //
2516 void HUD_RaceTimer (void)
2517 {
2518         if(intermission == 2) return;
2519         if(!autocvar__hud_configure)
2520         {
2521                 if(!autocvar_hud_panel_racetimer) return;
2522                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2523                 if(spectatee_status == -1) return;
2524         }
2525
2526         HUD_Panel_UpdateCvars();
2527
2528         vector pos, mySize;
2529         pos = panel_pos;
2530         mySize = panel_size;
2531
2532         HUD_Panel_DrawBg(1);
2533         if(panel_bg_padding)
2534         {
2535                 pos += '1 1 0' * panel_bg_padding;
2536                 mySize -= '2 2 0' * panel_bg_padding;
2537         }
2538
2539         // always force 4:1 aspect
2540         vector newSize = '0 0 0';
2541         if(mySize.x/mySize.y > 4)
2542         {
2543                 newSize.x = 4 * mySize.y;
2544                 newSize.y = mySize.y;
2545
2546                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2547         }
2548         else
2549         {
2550                 newSize.y = 1/4 * mySize.x;
2551                 newSize.x = mySize.x;
2552
2553                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2554         }
2555         mySize = newSize;
2556
2557         float a, t;
2558         string s, forcetime;
2559
2560         if(autocvar__hud_configure)
2561         {
2562                 s = "0:13:37";
2563                 draw_beginBoldFont();
2564                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2565                 draw_endBoldFont();
2566                 s = _("^1Intermediate 1 (+15.42)");
2567                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2568                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2569                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2570         }
2571         else if(race_checkpointtime)
2572         {
2573                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2574                 s = "";
2575                 forcetime = "";
2576                 if(a > 0) // just hit a checkpoint?
2577                 {
2578                         if(race_checkpoint != 254)
2579                         {
2580                                 if(race_time && race_previousbesttime)
2581                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2582                                 else
2583                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2584                                 if(race_time)
2585                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2586                         }
2587                 }
2588                 else
2589                 {
2590                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2591                         {
2592                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2593                                 if(a > 0) // next one?
2594                                 {
2595                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2596                                 }
2597                         }
2598                 }
2599
2600                 if(s != "" && a > 0)
2601                 {
2602                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2603                 }
2604
2605                 if(race_penaltytime)
2606                 {
2607                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2608                         if(a > 0)
2609                         {
2610                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2611                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2612                         }
2613                 }
2614
2615                 draw_beginBoldFont();
2616
2617                 if(forcetime != "")
2618                 {
2619                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2620                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2621                 }
2622                 else
2623                         a = 1;
2624
2625                 if(race_laptime && race_checkpoint != 255)
2626                 {
2627                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2628                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2629                 }
2630
2631                 draw_endBoldFont();
2632         }
2633         else
2634         {
2635                 if(race_mycheckpointtime)
2636                 {
2637                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2638                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2639                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2640                 }
2641                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2642                 {
2643                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2644                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2645                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2646                 }
2647
2648                 if(race_penaltytime && !race_penaltyaccumulator)
2649                 {
2650                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2651                         a = bound(0, (1 + t - time), 1);
2652                         if(a > 0)
2653                         {
2654                                 if(time < t)
2655                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2656                                 else
2657                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2658                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2659                         }
2660                 }
2661         }
2662 }
2663
2664 // Vote window (#9)
2665 //
2666
2667 void HUD_Vote(void)
2668 {
2669         if(intermission == 2) return;
2670         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2671         {
2672                 vote_active = 1;
2673                 if (autocvar__hud_configure)
2674                 {
2675                         vote_yescount = 0;
2676                         vote_nocount = 0;
2677                         print(_("^1You must answer before entering hud configure mode\n"));
2678                         cvar_set("_hud_configure", "0");
2679                 }
2680                 if(vote_called_vote)
2681                         strunzone(vote_called_vote);
2682                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2683                 uid2name_dialog = 1;
2684         }
2685
2686         if(!autocvar__hud_configure)
2687         {
2688                 if(!autocvar_hud_panel_vote) return;
2689
2690                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2691                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2692
2693                 if(panel_bg_alpha_str == "") {
2694                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2695                 }
2696                 panel_bg_alpha = stof(panel_bg_alpha_str);
2697         }
2698         else
2699         {
2700                 vote_yescount = 3;
2701                 vote_nocount = 2;
2702                 vote_needed = 4;
2703         }
2704
2705         string s;
2706         float a;
2707         if(vote_active != vote_prev) {
2708                 vote_change = time;
2709                 vote_prev = vote_active;
2710         }
2711
2712         if(vote_active || autocvar__hud_configure)
2713                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2714         else
2715                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2716
2717         if(!vote_alpha)
2718                 return;
2719
2720         HUD_Panel_UpdateCvars();
2721
2722         if(uid2name_dialog)
2723         {
2724                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2725                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2726         }
2727
2728     // these must be below above block
2729         vector pos, mySize;
2730         pos = panel_pos;
2731         mySize = panel_size;
2732
2733         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2734         HUD_Panel_DrawBg(a);
2735         a = panel_fg_alpha * a;
2736
2737         if(panel_bg_padding)
2738         {
2739                 pos += '1 1 0' * panel_bg_padding;
2740                 mySize -= '2 2 0' * panel_bg_padding;
2741         }
2742
2743         // always force 3:1 aspect
2744         vector newSize = '0 0 0';
2745         if(mySize.x/mySize.y > 3)
2746         {
2747                 newSize.x = 3 * mySize.y;
2748                 newSize.y = mySize.y;
2749
2750                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2751         }
2752         else
2753         {
2754                 newSize.y = 1/3 * mySize.x;
2755                 newSize.x = mySize.x;
2756
2757                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2758         }
2759         mySize = newSize;
2760
2761         s = _("A vote has been called for:");
2762         if(uid2name_dialog)
2763                 s = _("Allow servers to store and display your name?");
2764         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2765         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2766         if(autocvar__hud_configure)
2767                 s = _("^1Configure the HUD");
2768         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2769
2770         // print the yes/no counts
2771     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2772         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2773     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2774         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2775
2776         // draw the progress bar backgrounds
2777         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2778
2779         // draw the highlights
2780         if(vote_highlighted == 1) {
2781                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2782                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2783         }
2784         else if(vote_highlighted == -1) {
2785                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2786                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2787         }
2788
2789         // draw the progress bars
2790         if(vote_yescount && vote_needed)
2791         {
2792                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2793                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2794         }
2795
2796         if(vote_nocount && vote_needed)
2797         {
2798                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2799                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2800         }
2801
2802         drawresetcliparea();
2803 }
2804
2805 // Mod icons panel (#10)
2806 //
2807
2808 bool mod_active; // is there any active mod icon?
2809
2810 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2811 {
2812         int stat = -1;
2813         string pic = "";
2814         vector color = '0 0 0';
2815         switch(i)
2816         {
2817                 case 0:
2818                         stat = getstati(STAT_REDALIVE);
2819                         pic = "player_red.tga";
2820                         color = '1 0 0';
2821                         break;
2822                 case 1:
2823                         stat = getstati(STAT_BLUEALIVE);
2824                         pic = "player_blue.tga";
2825                         color = '0 0 1';
2826                         break;
2827                 case 2:
2828                         stat = getstati(STAT_YELLOWALIVE);
2829                         pic = "player_yellow.tga";
2830                         color = '1 1 0';
2831                         break;
2832                 default:
2833                 case 3:
2834                         stat = getstati(STAT_PINKALIVE);
2835                         pic = "player_pink.tga";
2836                         color = '1 0 1';
2837                         break;
2838         }
2839
2840         if(mySize.x/mySize.y > aspect_ratio)
2841         {
2842                 i = aspect_ratio * mySize.y;
2843                 myPos.x = myPos.x + (mySize.x - i) / 2;
2844                 mySize.x = i;
2845         }
2846         else
2847         {
2848                 i = 1/aspect_ratio * mySize.x;
2849                 myPos.y = myPos.y + (mySize.y - i) / 2;
2850                 mySize.y = i;
2851         }
2852
2853         if(layout)
2854         {
2855                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2856                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2857         }
2858         else
2859                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2860 }
2861
2862 // Clan Arena and Freeze Tag HUD modicons
2863 void HUD_Mod_CA(vector myPos, vector mySize)
2864 {
2865         mod_active = 1; // required in each mod function that always shows something
2866
2867         int layout;
2868         if(gametype == MAPINFO_TYPE_CA)
2869                 layout = autocvar_hud_panel_modicons_ca_layout;
2870         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2871                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2872         int rows, columns;
2873         float aspect_ratio;
2874         aspect_ratio = (layout) ? 2 : 1;
2875         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2876         columns = ceil(team_count/rows);
2877
2878         int i;
2879         float row = 0, column = 0;
2880         vector pos, itemSize;
2881         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2882         for(i=0; i<team_count; ++i)
2883         {
2884                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2885
2886                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2887
2888                 ++row;
2889                 if(row >= rows)
2890                 {
2891                         row = 0;
2892                         ++column;
2893                 }
2894         }
2895 }
2896
2897 // CTF HUD modicon section
2898 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
2899 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
2900 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
2901
2902 void HUD_Mod_CTF_Reset(void)
2903 {
2904         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
2905         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
2906         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
2907 }
2908
2909 void HUD_Mod_CTF(vector pos, vector mySize)
2910 {
2911         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
2912         vector flag_size;
2913         float f; // every function should have that
2914
2915         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
2916         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime, yellowflag_statuschange_elapsedtime, pinkflag_statuschange_elapsedtime, neutralflag_statuschange_elapsedtime; // time since the status changed
2917         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
2918         int stat_items = getstati(STAT_CTF_FLAGSTATUS, 0, 24);
2919         float fs, fs2, fs3, size1, size2;
2920         vector e1, e2;
2921
2922         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
2923         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
2924         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
2925         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
2926         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
2927
2928         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
2929
2930         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag);
2931
2932         if (autocvar__hud_configure) {
2933                 redflag = 1;
2934                 blueflag = 2;
2935                 if (team_count >= 3)
2936                         yellowflag = 2;
2937                 if (team_count >= 4)
2938                         pinkflag = 3;
2939                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
2940         }
2941
2942         // when status CHANGES, set old status into prevstatus and current status into status
2943         #define X(team) do {                                                                                                                    \
2944                 if (team##flag != team##flag_prevframe) {                                                                       \
2945                 team##flag_statuschange_time = time;                                                                    \
2946                 team##flag_prevstatus = team##flag_prevframe;                                                   \
2947                 team##flag_prevframe = team##flag;                                                                              \
2948         }                                                                                                                                                       \
2949         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
2950     } while (0)
2951         X(red);
2952         X(blue);
2953         X(yellow);
2954         X(pink);
2955         X(neutral);
2956         #undef X
2957
2958         const float BLINK_FACTOR = 0.15;
2959         const float BLINK_BASE = 0.85;
2960         // note:
2961         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2962         // thus
2963         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2964         // ensure RMS == 1
2965         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2966
2967         #define X(team, cond) \
2968         string team##_icon, team##_icon_prevstatus; \
2969         int team##_alpha, team##_alpha_prevstatus; \
2970         team##_alpha = team##_alpha_prevstatus = 1; \
2971         do { \
2972                 switch (team##flag) { \
2973                         case 1: team##_icon = "flag_" #team "_taken"; break; \
2974                         case 2: team##_icon = "flag_" #team "_lost"; break; \
2975                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2976                         default: \
2977                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
2978                                         team##_icon = "flag_" #team "_shielded"; \
2979                                 } else { \
2980                                         team##_icon = string_null; \
2981                                 } \
2982                                 break; \
2983                 } \
2984                 switch (team##flag_prevstatus) { \
2985                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
2986                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
2987                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2988                         default: \
2989                                 if (team##flag == 3) { \
2990                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
2991                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
2992                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
2993                                 } else { \
2994                                         team##_icon_prevstatus = string_null; \
2995                                 } \
2996                                 break; \
2997                 } \
2998         } while (0)
2999         X(red, myteam != NUM_TEAM_1);
3000         X(blue, myteam != NUM_TEAM_2);
3001         X(yellow, myteam != NUM_TEAM_3);
3002         X(pink, myteam != NUM_TEAM_4);
3003         X(neutral, true);
3004         #undef X
3005
3006         if (ctf_oneflag) {
3007                 // hacky, but these aren't needed
3008                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
3009                 fs = fs2 = fs3 = 1;
3010         } else switch (team_count) {
3011                 default:
3012                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
3013                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
3014                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
3015         }
3016
3017         if (mySize_x > mySize_y) {
3018                 size1 = mySize_x;
3019                 size2 = mySize_y;
3020                 e1 = eX;
3021                 e2 = eY;
3022         } else {
3023                 size1 = mySize_y;
3024                 size2 = mySize_x;
3025                 e1 = eY;
3026                 e2 = eX;
3027         }
3028
3029         switch (myteam) {
3030                 default:
3031                 case NUM_TEAM_1: {
3032                         redflag_pos = pos;
3033                         blueflag_pos = pos + eX * fs2 * size1;
3034                         yellowflag_pos = pos - eX * fs2 * size1;
3035                         pinkflag_pos = pos + eX * fs3 * size1;
3036                         break;
3037                 }
3038                 case NUM_TEAM_2: {
3039                         redflag_pos = pos + eX * fs2 * size1;
3040                         blueflag_pos = pos;
3041                         yellowflag_pos = pos - eX * fs2 * size1;
3042                         pinkflag_pos = pos + eX * fs3 * size1;
3043                         break;
3044                 }
3045                 case NUM_TEAM_3: {
3046                         redflag_pos = pos + eX * fs3 * size1;
3047                         blueflag_pos = pos - eX * fs2 * size1;
3048                         yellowflag_pos = pos;
3049                         pinkflag_pos = pos + eX * fs2 * size1;
3050                         break;
3051                 }
3052                 case NUM_TEAM_4: {
3053                         redflag_pos = pos - eX * fs2 * size1;
3054                         blueflag_pos = pos + eX * fs3 * size1;
3055                         yellowflag_pos = pos + eX * fs2 * size1;
3056                         pinkflag_pos = pos;
3057                         break;
3058                 }
3059         }
3060         neutralflag_pos = pos;
3061         flag_size = e1 * fs * size1 + e2 * size2;
3062
3063         #define X(team) do { \
3064                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
3065                 if (team##_icon_prevstatus && f < 1) \
3066                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
3067                 if (team##_icon) \
3068                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
3069         } while (0)
3070         X(red);
3071         X(blue);
3072         X(yellow);
3073         X(pink);
3074         X(neutral);
3075         #undef X
3076 }
3077
3078 // Keyhunt HUD modicon section
3079 vector KH_SLOTS[4];
3080
3081 void HUD_Mod_KH(vector pos, vector mySize)
3082 {
3083         mod_active = 1; // keyhunt should never hide the mod icons panel
3084
3085         // Read current state
3086
3087         int state = getstati(STAT_KH_KEYS);
3088         int i, key_state;
3089         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3090         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3091
3092         for(i = 0; i < 4; ++i)
3093         {
3094                 key_state = (bitshift(state, i * -5) & 31) - 1;
3095
3096                 if(key_state == -1)
3097                         continue;
3098
3099                 if(key_state == 30)
3100                 {
3101                         ++carrying_keys;
3102                         key_state = myteam;
3103                 }
3104
3105                 switch(key_state)
3106                 {
3107                         case NUM_TEAM_1: ++team1_keys; break;
3108                         case NUM_TEAM_2: ++team2_keys; break;
3109                         case NUM_TEAM_3: ++team3_keys; break;
3110                         case NUM_TEAM_4: ++team4_keys; break;
3111                         case 29: ++dropped_keys; break;
3112                 }
3113
3114                 ++all_keys;
3115         }
3116
3117         // Calculate slot measurements
3118
3119         vector slot_size;
3120
3121         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3122         {
3123                 // Quadratic arrangement
3124                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3125                 KH_SLOTS[0] = pos;
3126                 KH_SLOTS[1] = pos + eX * slot_size.x;
3127                 KH_SLOTS[2] = pos + eY * slot_size.y;
3128                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3129         }
3130         else
3131         {
3132                 if(mySize.x > mySize.y)
3133                 {
3134                         // Horizontal arrangement
3135                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3136                         for(i = 0; i < all_keys; ++i)
3137                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3138                 }
3139                 else
3140                 {
3141                         // Vertical arrangement
3142                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3143                         for(i = 0; i < all_keys; ++i)
3144                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3145                 }
3146         }
3147
3148         // Make icons blink in case of RUN HERE
3149
3150         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3151         float alpha;
3152         alpha = 1;
3153
3154         if(carrying_keys)
3155                 switch(myteam)
3156                 {
3157                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3158                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3159                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3160                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3161                 }
3162
3163         // Draw icons
3164
3165         i = 0;
3166
3167         while(team1_keys--)
3168                 if(myteam == NUM_TEAM_1 && carrying_keys)
3169                 {
3170                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3171                         --carrying_keys;
3172                 }
3173                 else
3174                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3175
3176         while(team2_keys--)
3177                 if(myteam == NUM_TEAM_2 && carrying_keys)
3178                 {
3179                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3180                         --carrying_keys;
3181                 }
3182                 else
3183                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3184
3185         while(team3_keys--)
3186                 if(myteam == NUM_TEAM_3 && carrying_keys)
3187                 {
3188                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3189                         --carrying_keys;
3190                 }
3191                 else
3192                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3193
3194         while(team4_keys--)
3195                 if(myteam == NUM_TEAM_4 && carrying_keys)
3196                 {
3197                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3198                         --carrying_keys;
3199                 }
3200                 else
3201                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3202
3203         while(dropped_keys--)
3204                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3205 }
3206
3207 // Keepaway HUD mod icon
3208 int kaball_prevstatus; // last remembered status
3209 float kaball_statuschange_time; // time when the status changed
3210
3211 // we don't need to reset for keepaway since it immediately
3212 // autocorrects prevstatus as to if the player has the ball or not
3213
3214 void HUD_Mod_Keepaway(vector pos, vector mySize)
3215 {
3216         mod_active = 1; // keepaway should always show the mod HUD
3217
3218         float BLINK_FACTOR = 0.15;
3219         float BLINK_BASE = 0.85;
3220         float BLINK_FREQ = 5;
3221         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3222
3223         int stat_items = getstati(STAT_ITEMS, 0, 24);
3224         int kaball = (stat_items/IT_KEY1) & 1;
3225
3226         if(kaball != kaball_prevstatus)
3227         {
3228                 kaball_statuschange_time = time;
3229                 kaball_prevstatus = kaball;
3230         }
3231
3232         vector kaball_pos, kaball_size;
3233
3234         if(mySize.x > mySize.y) {
3235                 kaball_pos = pos + eX * 0.25 * mySize.x;
3236                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3237         } else {
3238                 kaball_pos = pos + eY * 0.25 * mySize.y;
3239                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3240         }
3241
3242         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3243         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3244
3245         if(kaball_prevstatus && f < 1)
3246                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3247
3248         if(kaball)
3249                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3250 }
3251
3252
3253 // Nexball HUD mod icon
3254 void HUD_Mod_NexBall(vector pos, vector mySize)
3255 {
3256         float nb_pb_starttime, dt, p;
3257         int stat_items;
3258
3259         stat_items = getstati(STAT_ITEMS, 0, 24);
3260         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3261
3262         if (stat_items & IT_KEY1)
3263                 mod_active = 1;
3264         else
3265                 mod_active = 0;
3266
3267         //Manage the progress bar if any
3268         if (nb_pb_starttime > 0)
3269         {
3270                 dt = (time - nb_pb_starttime) % nb_pb_period;
3271                 // one period of positive triangle
3272                 p = 2 * dt / nb_pb_period;
3273                 if (p > 1)
3274                         p = 2 - p;
3275
3276                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3277         }
3278
3279         if (stat_items & IT_KEY1)
3280                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3281 }
3282
3283 // Race/CTS HUD mod icons
3284 float crecordtime_prev; // last remembered crecordtime
3285 float crecordtime_change_time; // time when crecordtime last changed
3286 float srecordtime_prev; // last remembered srecordtime
3287 float srecordtime_change_time; // time when srecordtime last changed
3288
3289 float race_status_time;
3290 int race_status_prev;
3291 string race_status_name_prev;
3292 void HUD_Mod_Race(vector pos, vector mySize)
3293 {
3294         mod_active = 1; // race should never hide the mod icons panel
3295         entity me;
3296         me = playerslots[player_localnum];
3297         float t, score;
3298         float f; // yet another function has this
3299         score = me.(scores[ps_primary]);
3300
3301         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3302                 return; // no records in the actual race
3303
3304         // clientside personal record
3305         string rr;
3306         if(gametype == MAPINFO_TYPE_CTS)
3307                 rr = CTS_RECORD;
3308         else
3309                 rr = RACE_RECORD;
3310         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3311
3312         if(score && (score < t || !t)) {
3313                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3314                 if(autocvar_cl_autodemo_delete_keeprecords)
3315                 {
3316                         f = autocvar_cl_autodemo_delete;
3317                         f &= ~1;
3318                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3319                 }
3320         }
3321
3322         if(t != crecordtime_prev) {
3323                 crecordtime_prev = t;
3324                 crecordtime_change_time = time;
3325         }
3326
3327         vector textPos, medalPos;
3328         float squareSize;
3329         if(mySize.x > mySize.y) {
3330                 // text on left side
3331                 squareSize = min(mySize.y, mySize.x/2);
3332                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3333                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3334         } else {
3335                 // text on top
3336                 squareSize = min(mySize.x, mySize.y/2);
3337                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3338                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3339         }
3340
3341         f = time - crecordtime_change_time;
3342
3343         if (f > 1) {
3344                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3345                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3346         } else {
3347                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3348                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3349                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3350                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3351         }
3352
3353         // server record
3354         t = race_server_record;
3355         if(t != srecordtime_prev) {
3356                 srecordtime_prev = t;
3357                 srecordtime_change_time = time;
3358         }
3359         f = time - srecordtime_change_time;
3360
3361         if (f > 1) {
3362                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3363                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3364         } else {
3365                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3366                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3367                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3368                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3369         }
3370
3371         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3372                 race_status_time = time + 5;
3373                 race_status_prev = race_status;
3374                 if (race_status_name_prev)
3375                         strunzone(race_status_name_prev);
3376                 race_status_name_prev = strzone(race_status_name);
3377         }
3378
3379         // race "awards"
3380         float a;
3381         a = bound(0, race_status_time - time, 1);
3382
3383         string s;
3384         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3385
3386         float rank;
3387         if(race_status > 0)
3388                 rank = race_CheckName(race_status_name);
3389         else
3390                 rank = 0;
3391         string rankname;
3392         rankname = count_ordinal(rank);
3393
3394         vector namepos;
3395         namepos = medalPos + '0 0.8 0' * squareSize;
3396         vector rankpos;
3397         rankpos = medalPos + '0 0.15 0' * squareSize;
3398
3399         if(race_status == 0)
3400                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3401         else if(race_status == 1) {
3402                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3403                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3404                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3405         } else if(race_status == 2) {
3406                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3407                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3408                 else
3409                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3410                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3411                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3412         } else if(race_status == 3) {
3413                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3414                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3415                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3416         }
3417
3418         if (race_status_time - time <= 0) {
3419                 race_status_prev = -1;
3420                 race_status = -1;
3421                 if(race_status_name)
3422                         strunzone(race_status_name);
3423                 race_status_name = string_null;
3424                 if(race_status_name_prev)
3425                         strunzone(race_status_name_prev);
3426                 race_status_name_prev = string_null;
3427         }
3428 }
3429
3430 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3431 {
3432         float stat = -1;
3433         string pic = "";
3434         vector color = '0 0 0';
3435         switch(i)
3436         {
3437                 case 0:
3438                         stat = getstatf(STAT_DOM_PPS_RED);
3439                         pic = "dom_icon_red";
3440                         color = '1 0 0';
3441                         break;
3442                 case 1:
3443                         stat = getstatf(STAT_DOM_PPS_BLUE);
3444                         pic = "dom_icon_blue";
3445                         color = '0 0 1';
3446                         break;
3447                 case 2:
3448                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3449                         pic = "dom_icon_yellow";
3450                         color = '1 1 0';
3451                         break;
3452                 default:
3453                 case 3:
3454                         stat = getstatf(STAT_DOM_PPS_PINK);
3455                         pic = "dom_icon_pink";
3456                         color = '1 0 1';
3457                         break;
3458         }
3459         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3460
3461         if(mySize.x/mySize.y > aspect_ratio)
3462         {
3463                 i = aspect_ratio * mySize.y;
3464                 myPos.x = myPos.x + (mySize.x - i) / 2;
3465                 mySize.x = i;
3466         }
3467         else
3468         {
3469                 i = 1/aspect_ratio * mySize.x;
3470                 myPos.y = myPos.y + (mySize.y - i) / 2;
3471                 mySize.y = i;
3472         }
3473
3474         if (layout) // show text too
3475         {
3476                 //draw the text
3477                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3478                 if (layout == 2) // average pps
3479                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3480                 else // percentage of average pps
3481                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3482         }
3483
3484         //draw the icon
3485         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3486         if (stat > 0)
3487         {
3488                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3489                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3490                 drawresetcliparea();
3491         }
3492 }
3493
3494 void HUD_Mod_Dom(vector myPos, vector mySize)
3495 {
3496         mod_active = 1; // required in each mod function that always shows something
3497
3498         int layout = autocvar_hud_panel_modicons_dom_layout;
3499         int rows, columns;
3500         float aspect_ratio;
3501         aspect_ratio = (layout) ? 3 : 1;
3502         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3503         columns = ceil(team_count/rows);
3504
3505         int i;
3506         float row = 0, column = 0;
3507         vector pos, itemSize;
3508         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3509         for(i=0; i<team_count; ++i)
3510         {
3511                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3512
3513                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3514
3515                 ++row;
3516                 if(row >= rows)
3517                 {
3518                         row = 0;
3519                         ++column;
3520                 }
3521         }
3522 }
3523
3524 void HUD_ModIcons_SetFunc()
3525 {
3526         switch(gametype)
3527         {
3528                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3529                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3530                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3531                 case MAPINFO_TYPE_CTS:
3532                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3533                 case MAPINFO_TYPE_CA:
3534                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3535                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3536                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3537         }
3538 }
3539
3540 int mod_prev; // previous state of mod_active to check for a change
3541 float mod_alpha;
3542 float mod_change; // "time" when mod_active changed
3543
3544 void HUD_ModIcons(void)
3545 {
3546         if(intermission == 2) return;
3547         if(!autocvar__hud_configure)
3548         {
3549                 if(!autocvar_hud_panel_modicons) return;
3550                 if(!HUD_ModIcons_GameType) return;
3551         }
3552
3553         HUD_Panel_UpdateCvars();
3554
3555         draw_beginBoldFont();
3556
3557         if(mod_active != mod_prev) {
3558                 mod_change = time;
3559                 mod_prev = mod_active;
3560         }
3561
3562         if(mod_active || autocvar__hud_configure)
3563                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3564         else
3565                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3566
3567         if(mod_alpha)
3568                 HUD_Panel_DrawBg(mod_alpha);
3569
3570         if(panel_bg_padding)
3571         {
3572                 panel_pos += '1 1 0' * panel_bg_padding;
3573                 panel_size -= '2 2 0' * panel_bg_padding;
3574         }
3575
3576         if(autocvar__hud_configure)
3577                 HUD_Mod_CTF(panel_pos, panel_size);
3578         else
3579                 HUD_ModIcons_GameType(panel_pos, panel_size);
3580
3581         draw_endBoldFont();
3582 }
3583
3584 // Draw pressed keys (#11)
3585 //
3586 void HUD_PressedKeys(void)
3587 {
3588         if(intermission == 2) return;
3589         if(!autocvar__hud_configure)
3590         {
3591                 if(!autocvar_hud_panel_pressedkeys) return;
3592                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3593         }
3594
3595         HUD_Panel_UpdateCvars();
3596         vector pos, mySize;
3597         pos = panel_pos;
3598         mySize = panel_size;
3599
3600         HUD_Panel_DrawBg(1);
3601         if(panel_bg_padding)
3602         {
3603                 pos += '1 1 0' * panel_bg_padding;
3604                 mySize -= '2 2 0' * panel_bg_padding;
3605         }
3606
3607         // force custom aspect
3608         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3609         if(aspect)
3610         {
3611                 vector newSize = '0 0 0';
3612                 if(mySize.x/mySize.y > aspect)
3613                 {
3614                         newSize.x = aspect * mySize.y;
3615                         newSize.y = mySize.y;
3616
3617                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3618                 }
3619                 else
3620                 {
3621                         newSize.y = 1/aspect * mySize.x;
3622                         newSize.x = mySize.x;
3623
3624                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3625                 }
3626                 mySize = newSize;
3627         }
3628
3629         vector keysize;
3630         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3631         float pressedkeys;
3632         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3633
3634         if(autocvar_hud_panel_pressedkeys_attack)
3635         {
3636                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3637                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3638                 pos.y += keysize.y;
3639         }
3640
3641         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3642         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3643         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3644         pos.y += keysize.y;
3645         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3646         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3647         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3648 }
3649
3650 // Handle chat as a panel (#12)
3651 //
3652 void HUD_Chat(void)
3653 {
3654         if(!autocvar__hud_configure)
3655         {
3656                 if (!autocvar_hud_panel_chat)
3657                 {
3658                         if (!autocvar_con_chatrect)
3659                                 cvar_set("con_chatrect", "0");
3660                         return;
3661                 }
3662                 if(autocvar__con_chat_maximized)
3663                 {
3664                         if(!hud_draw_maximized) return;
3665                 }
3666                 else if(chat_panel_modified)
3667                 {
3668                         panel.update_time = time; // forces reload of panel attributes
3669                         chat_panel_modified = false;
3670                 }
3671         }
3672
3673         HUD_Panel_UpdateCvars();
3674
3675         if(intermission == 2)
3676         {
3677                 // reserve some more space to the mapvote panel
3678                 // by resizing and moving chat panel to the bottom
3679                 panel_size.y = min(panel_size.y, vid_conheight * 0.2);
3680                 panel_pos.y = vid_conheight - panel_size.y - panel_bg_border * 2;
3681                 chat_posy = panel_pos.y;
3682                 chat_sizey = panel_size.y;
3683         }
3684         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3685         {
3686                 panel_pos.y = panel_bg_border;
3687                 panel_size.y = vid_conheight - panel_bg_border * 2;
3688                 if(panel.current_panel_bg == "0") // force a border when maximized
3689                 {
3690                         string panel_bg;
3691                         panel_bg = strcat(hud_skin_path, "/border_default");
3692                         if(precache_pic(panel_bg) == "")
3693                                 panel_bg = "gfx/hud/default/border_default";
3694                         if(panel.current_panel_bg)
3695                                 strunzone(panel.current_panel_bg);
3696                         panel.current_panel_bg = strzone(panel_bg);
3697                         chat_panel_modified = true;
3698                 }
3699                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3700         }
3701
3702         vector pos, mySize;
3703         pos = panel_pos;
3704         mySize = panel_size;
3705
3706         HUD_Panel_DrawBg(1);
3707
3708         if(panel_bg_padding)
3709         {
3710                 pos += '1 1 0' * panel_bg_padding;
3711                 mySize -= '2 2 0' * panel_bg_padding;
3712         }
3713
3714         if (!autocvar_con_chatrect)
3715                 cvar_set("con_chatrect", "1");
3716
3717         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3718         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3719
3720         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3721         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3722
3723         if(autocvar__hud_configure)
3724         {
3725                 vector chatsize;
3726                 chatsize = '1 1 0' * autocvar_con_chatsize;
3727                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3728                 float i, a;
3729                 for(i = 0; i < autocvar_con_chat; ++i)
3730                 {
3731                         if(i == autocvar_con_chat - 1)
3732                                 a = panel_fg_alpha;
3733                         else
3734                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3735                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3736                         pos.y += chatsize.y;
3737                 }
3738         }
3739 }
3740
3741 // Engine info panel (#13)
3742 //
3743 float prevfps;
3744 float prevfps_time;
3745 int framecounter;
3746
3747 float frametimeavg;
3748 float frametimeavg1; // 1 frame ago
3749 float frametimeavg2; // 2 frames ago
3750 void HUD_EngineInfo(void)
3751 {
3752         //if(intermission == 2) return;
3753         if(!autocvar__hud_configure)
3754         {
3755                 if(!autocvar_hud_panel_engineinfo) return;
3756         }
3757
3758         HUD_Panel_UpdateCvars();
3759         vector pos, mySize;
3760         pos = panel_pos;
3761         mySize = panel_size;
3762
3763         HUD_Panel_DrawBg(1);
3764         if(panel_bg_padding)
3765         {
3766                 pos += '1 1 0' * panel_bg_padding;
3767                 mySize -= '2 2 0' * panel_bg_padding;
3768         }
3769
3770         float currentTime = gettime(GETTIME_REALTIME);
3771         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3772         {
3773                 float currentframetime = currentTime - prevfps_time;
3774                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3775                 frametimeavg2 = frametimeavg1;
3776                 frametimeavg1 = frametimeavg;
3777
3778                 float weight;
3779                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3780                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3781                 {
3782                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3783                                 prevfps = (1/currentframetime);
3784                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3785                 }
3786                 prevfps_time = currentTime;
3787         }
3788         else
3789         {
3790                 framecounter += 1;
3791                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3792                 {
3793                         prevfps = framecounter/(currentTime - prevfps_time);
3794                         framecounter = 0;
3795                         prevfps_time = currentTime;
3796                 }
3797         }
3798
3799         vector color;
3800         color = HUD_Get_Num_Color (prevfps, 100);
3801         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3802 }
3803
3804 // Info messages panel (#14)
3805 //
3806 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3807         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3808                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3809         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3810         o.y += fontsize.y;                                                                                                                                                                                              \
3811 } while(0)
3812 void HUD_InfoMessages(void)
3813 {
3814         if(intermission == 2) return;
3815         if(!autocvar__hud_configure)
3816         {
3817                 if(!autocvar_hud_panel_infomessages) return;
3818         }
3819
3820         HUD_Panel_UpdateCvars();
3821         vector pos, mySize;
3822         pos = panel_pos;
3823         mySize = panel_size;
3824
3825         HUD_Panel_DrawBg(1);
3826         if(panel_bg_padding)
3827         {
3828                 pos += '1 1 0' * panel_bg_padding;
3829                 mySize -= '2 2 0' * panel_bg_padding;
3830         }
3831
3832         // always force 5:1 aspect
3833         vector newSize = '0 0 0';
3834         if(mySize.x/mySize.y > 5)
3835         {
3836                 newSize.x = 5 * mySize.y;
3837                 newSize.y = mySize.y;
3838
3839                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3840         }
3841         else
3842         {
3843                 newSize.y = 1/5 * mySize.x;
3844                 newSize.x = mySize.x;
3845
3846                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3847         }
3848
3849         mySize = newSize;
3850         entity tm;
3851         vector o;
3852         o = pos;
3853
3854         vector fontsize;
3855         fontsize = '0.20 0.20 0' * mySize.y;
3856
3857         float a;
3858         a = panel_fg_alpha;
3859
3860         string s;
3861         if(!autocvar__hud_configure)
3862         {
3863                 if(spectatee_status && !intermission)
3864                 {
3865                         a = 1;
3866                         if(spectatee_status == -1)
3867                                 s = _("^1Observing");
3868                         else
3869                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3870                         drawInfoMessage(s);
3871
3872                         if(spectatee_status == -1)
3873                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3874                         else
3875                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3876                         drawInfoMessage(s);
3877
3878                         if(spectatee_status == -1)
3879                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3880                         else
3881                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3882                         drawInfoMessage(s);
3883
3884                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3885                         drawInfoMessage(s);
3886
3887                         if(gametype == MAPINFO_TYPE_LMS)
3888                         {
3889                                 entity sk;
3890                                 sk = playerslots[player_localnum];
3891                                 if(sk.(scores[ps_primary]) >= 666)
3892                                         s = _("^1Match has already begun");
3893                                 else if(sk.(scores[ps_primary]) > 0)
3894                                         s = _("^1You have no more lives left");
3895                                 else
3896                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3897                         }
3898                         else
3899                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3900                         drawInfoMessage(s);
3901
3902                         //show restart countdown:
3903                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3904                                 float countdown;
3905                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3906                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3907                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3908                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3909                                 o.y += fontsize.y;
3910                         }
3911                 }
3912                 if(warmup_stage && !intermission)
3913                 {
3914                         s = _("^2Currently in ^1warmup^2 stage!");
3915                         drawInfoMessage(s);
3916                 }
3917
3918                 string blinkcolor;
3919                 if(time % 1 >= 0.5)
3920                         blinkcolor = "^1";
3921                 else
3922                         blinkcolor = "^3";
3923
3924                 if(ready_waiting && !intermission && !spectatee_status)
3925                 {
3926                         if(ready_waiting_for_me)
3927                         {
3928                                 if(warmup_stage)
3929                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3930                                 else
3931                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3932                         }
3933                         else
3934                         {
3935                                 if(warmup_stage)
3936                                         s = _("^2Waiting for others to ready up to end warmup...");
3937                                 else
3938                                         s = _("^2Waiting for others to ready up...");
3939                         }
3940                         drawInfoMessage(s);
3941                 }
3942                 else if(warmup_stage && !intermission && !spectatee_status)
3943                 {
3944                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3945                         drawInfoMessage(s);
3946                 }
3947
3948                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3949                 {
3950                         float ts_min = 0, ts_max = 0;
3951                         tm = teams.sort_next;
3952                         if (tm)
3953                         {
3954                                 for (; tm.sort_next; tm = tm.sort_next)
3955                                 {
3956                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3957                                                 continue;
3958                                         if(!ts_min) ts_min = tm.team_size;
3959                                         else ts_min = min(ts_min, tm.team_size);
3960                                         if(!ts_max) ts_max = tm.team_size;
3961                                         else ts_max = max(ts_max, tm.team_size);
3962                                 }
3963                                 if ((ts_max - ts_min) > 1)
3964                                 {
3965                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3966                                         tm = GetTeam(myteam, false);
3967                                         if (tm)
3968                                         if (tm.team != NUM_SPECTATOR)
3969                                         if (tm.team_size == ts_max)
3970                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3971                                         drawInfoMessage(s);
3972                                 }
3973                         }
3974                 }
3975         }
3976         else
3977         {
3978                 s = _("^7Press ^3ESC ^7to show HUD options.");
3979                 drawInfoMessage(s);
3980                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3981                 drawInfoMessage(s);
3982                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3983                 drawInfoMessage(s);
3984                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3985                 drawInfoMessage(s);
3986         }
3987 }
3988
3989 // Physics panel (#15)
3990 //
3991 vector acc_prevspeed;
3992 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3993 float physics_update_time, discrete_speed, discrete_acceleration;
3994 void HUD_Physics(void)
3995 {
3996         if(intermission == 2) return;
3997         if(!autocvar__hud_configure)
3998         {
3999                 if(!autocvar_hud_panel_physics) return;
4000                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
4001                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
4002         }
4003
4004         HUD_Panel_UpdateCvars();
4005
4006         draw_beginBoldFont();
4007
4008         HUD_Panel_DrawBg(1);
4009         if(panel_bg_padding)
4010         {
4011                 panel_pos += '1 1 0' * panel_bg_padding;
4012                 panel_size -= '2 2 0' * panel_bg_padding;
4013         }
4014
4015         float acceleration_progressbar_scale = 0;
4016         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
4017                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
4018
4019         float text_scale;
4020         if (autocvar_hud_panel_physics_text_scale <= 0)
4021                 text_scale = 1;
4022         else
4023                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
4024
4025         //compute speed
4026         float speed, conversion_factor;
4027         string unit;
4028
4029         switch(autocvar_hud_panel_physics_speed_unit)
4030         {
4031                 default:
4032                 case 1:
4033                         unit = _(" qu/s");
4034                         conversion_factor = 1.0;
4035                         break;
4036                 case 2:
4037                         unit = _(" m/s");
4038                         conversion_factor = 0.0254;
4039                         break;
4040                 case 3:
4041                         unit = _(" km/h");
4042                         conversion_factor = 0.0254 * 3.6;
4043                         break;
4044                 case 4:
4045                         unit = _(" mph");
4046                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
4047                         break;
4048                 case 5:
4049                         unit = _(" knots");
4050                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
4051                         break;
4052         }
4053
4054         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
4055
4056         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
4057         if (autocvar__hud_configure)
4058                 speed = floor( max_speed * 0.65 + 0.5 );
4059         else if(autocvar_hud_panel_physics_speed_vertical)
4060                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
4061         else
4062                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
4063
4064         //compute acceleration
4065         float acceleration, f;
4066         if (autocvar__hud_configure)
4067                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
4068         else
4069         {
4070                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
4071                 f = time - acc_prevtime;
4072                 if(autocvar_hud_panel_physics_acceleration_vertical)
4073                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
4074                 else
4075                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4076
4077                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4078
4079                 acc_prevspeed = vel;
4080                 acc_prevtime = time;
4081
4082                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
4083                 {
4084                         f = bound(0, f * 10, 1);
4085                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4086                         acceleration = acc_avg;
4087                 }
4088         }
4089
4090         int acc_decimals = 2;
4091         if(time > physics_update_time)
4092         {
4093                 // workaround for ftos_decimals returning a negative 0
4094                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4095                         discrete_acceleration = 0;
4096                 discrete_acceleration = acceleration;
4097                 discrete_speed = speed;
4098                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4099         }
4100
4101         //compute layout
4102         float panel_ar = panel_size.x/panel_size.y;
4103         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4104         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4105         {
4106                 panel_size.x *= 0.5;
4107                 if (autocvar_hud_panel_physics_flip)
4108                         speed_offset.x = panel_size.x;
4109                 else
4110                         acceleration_offset.x = panel_size.x;
4111         }
4112         else
4113         {
4114                 panel_size.y *= 0.5;
4115                 if (autocvar_hud_panel_physics_flip)
4116                         speed_offset.y = panel_size.y;
4117                 else
4118                         acceleration_offset.y = panel_size.y;
4119         }
4120         int speed_baralign, acceleration_baralign;
4121         if (autocvar_hud_panel_physics_baralign == 1)
4122                 acceleration_baralign = speed_baralign = 1;
4123     else if(autocvar_hud_panel_physics_baralign == 4)
4124                 acceleration_baralign = speed_baralign = 2;
4125         else if (autocvar_hud_panel_physics_flip)
4126         {
4127                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4128                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4129         }
4130         else
4131         {
4132                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4133                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4134         }
4135         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4136                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4137
4138         //draw speed
4139         if(speed)
4140         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4141                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4142         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4143         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4144         {
4145                 tmp_size.x = panel_size.x * 0.75;
4146                 tmp_size.y = panel_size.y * text_scale;
4147                 if (speed_baralign)
4148                         tmp_offset.x = panel_size.x - tmp_size.x;
4149                 //else
4150                         //tmp_offset_x = 0;
4151                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4152                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4153
4154                 //draw speed unit
4155                 if (speed_baralign)
4156                         tmp_offset.x = 0;
4157                 else
4158                         tmp_offset.x = tmp_size.x;
4159                 if (autocvar_hud_panel_physics_speed_unit_show)
4160                 {
4161                         //tmp_offset_y = 0;
4162                         tmp_size.x = panel_size.x * (1 - 0.75);
4163                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4164                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4165                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4166                 }
4167         }
4168
4169         //compute and draw top speed
4170         if (autocvar_hud_panel_physics_topspeed)
4171         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4172         {
4173                 if (autocvar__hud_configure)
4174                 {
4175                         top_speed = floor( max_speed * 0.75 + 0.5 );
4176                         f = 1;
4177                 }
4178                 else
4179                 {
4180                         if (speed >= top_speed)
4181                         {
4182                                 top_speed = speed;
4183                                 top_speed_time = time;
4184                         }
4185                         if (top_speed != 0)
4186                         {
4187                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4188                                 // divide by f to make it start from 1
4189                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4190                         }
4191             else //hide top speed 0, it would be stupid
4192                                 f = 0;
4193                 }
4194                 if (f > 0)
4195                 {
4196                         //top speed progressbar peak
4197                         if(speed < top_speed)
4198                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4199                         {
4200                                 float peak_offsetX;
4201                                 vector peak_size = '0 0 0';
4202                                 if (speed_baralign == 0)
4203                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4204                 else if (speed_baralign == 1)
4205                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4206                 else // if (speed_baralign == 2)
4207                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4208                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4209                 peak_size.y = panel_size.y;
4210                 if (speed_baralign == 2) // draw two peaks, on both sides
4211                 {
4212                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4213                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4214                 }
4215                 else
4216                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4217                         }
4218
4219                         //top speed
4220                         tmp_offset.y = panel_size.y * 0.4;
4221                         tmp_size.x = panel_size.x * (1 - 0.75);
4222                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4223                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4224                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4225                 }
4226                 else
4227                         top_speed = 0;
4228         }
4229
4230         //draw acceleration
4231         if(acceleration)
4232         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4233         {
4234                 vector progressbar_color;
4235                 if(acceleration < 0)
4236                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4237                 else
4238                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4239
4240                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4241                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4242                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4243
4244                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4245                 {
4246                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4247
4248                         if (acceleration_baralign == 1)
4249                                 tmp_offset.x = panel_size.x - tmp_size.x;
4250                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4251                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4252                         else
4253                                 tmp_offset.x = 0;
4254                         tmp_offset.y = 0;
4255                 }
4256                 else
4257                 {
4258                         tmp_size = panel_size;
4259                         tmp_offset = '0 0 0';
4260                 }
4261
4262                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4263         }
4264
4265         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4266         {
4267                 tmp_size.x = panel_size.x;
4268                 tmp_size.y = panel_size.y * text_scale;
4269                 tmp_offset.x = 0;
4270                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4271
4272                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4273         }
4274
4275         draw_endBoldFont();
4276 }
4277
4278 // CenterPrint (#16)
4279 //
4280 const int CENTERPRINT_MAX_MSGS = 10;
4281 const int CENTERPRINT_MAX_ENTRIES = 50;
4282 const float CENTERPRINT_SPACING = 0.7;
4283 int cpm_index;
4284 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4285 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4286 float centerprint_time[CENTERPRINT_MAX_MSGS];
4287 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4288 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4289 bool centerprint_showing;
4290
4291 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4292 {
4293         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4294         int i, j;
4295
4296         if(strMessage == "" && new_id == 0)
4297                 return;
4298
4299         // strip trailing newlines
4300         j = strlen(strMessage) - 1;
4301         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4302                 --j;
4303         if (j < strlen(strMessage) - 1)
4304                 strMessage = substring(strMessage, 0, j + 1);
4305
4306         if(strMessage == "" && new_id == 0)
4307                 return;
4308
4309         // strip leading newlines
4310         j = 0;
4311         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4312                 ++j;
4313         if (j > 0)
4314                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4315
4316         if(strMessage == "" && new_id == 0)
4317                 return;
4318
4319         if (!centerprint_showing)
4320                 centerprint_showing = true;
4321
4322         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4323         {
4324                 if (j == CENTERPRINT_MAX_MSGS)
4325                         j = 0;
4326                 if (new_id && new_id == centerprint_msgID[j])
4327                 {
4328                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4329                         {
4330                                 // fade out the current msg (duration and countdown_num are ignored)
4331                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4332                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4333                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4334                                 return;
4335                         }
4336                         break; // found a msg with the same id, at position j
4337                 }
4338         }
4339
4340         if (i == CENTERPRINT_MAX_MSGS)
4341         {
4342                 // a msg with the same id was not found, add the msg at the next position
4343                 --cpm_index;
4344                 if (cpm_index == -1)
4345                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4346                 j = cpm_index;
4347         }
4348         if(centerprint_messages[j])
4349                 strunzone(centerprint_messages[j]);
4350         centerprint_messages[j] = strzone(strMessage);
4351         centerprint_msgID[j] = new_id;
4352         if (duration < 0)
4353         {
4354                 centerprint_time[j] = -1;
4355                 centerprint_expire_time[j] = time;
4356         }
4357         else
4358         {
4359                 if(duration == 0)
4360                         duration = max(1, autocvar_hud_panel_centerprint_time);
4361                 centerprint_time[j] = duration;
4362                 centerprint_expire_time[j] = time + duration;
4363         }
4364         centerprint_countdown_num[j] = countdown_num;
4365 }
4366
4367 void centerprint_hud(string strMessage)
4368 {
4369         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4370 }
4371
4372 void reset_centerprint_messages(void)
4373 {
4374         int i;
4375         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4376         {
4377                 centerprint_expire_time[i] = 0;
4378                 centerprint_time[i] = 1;
4379                 centerprint_msgID[i] = 0;
4380                 if(centerprint_messages[i])
4381                         strunzone(centerprint_messages[i]);
4382                 centerprint_messages[i] = string_null;
4383         }
4384 }
4385 float hud_configure_cp_generation_time;
4386 void HUD_CenterPrint (void)
4387 {
4388         if(intermission == 2) return;
4389         if(!autocvar__hud_configure)
4390         {
4391                 if(!autocvar_hud_panel_centerprint) return;
4392
4393                 if(hud_configure_prev)
4394                         reset_centerprint_messages();
4395         }
4396         else
4397         {
4398                 if(!hud_configure_prev)
4399                         reset_centerprint_messages();
4400                 if (time > hud_configure_cp_generation_time)
4401                 {
4402                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4403                         {
4404                                 float r;
4405                                 r = random();
4406                                 if (r > 0.8)
4407                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4408                                 else if (r > 0.55)
4409                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4410                                 else
4411                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4412                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4413                         }
4414                         else
4415                         {
4416                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4417                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4418                         }
4419                 }
4420         }
4421
4422         // this panel fades only when the menu does
4423         float hud_fade_alpha_save = 0;
4424         if(scoreboard_fade_alpha)
4425         {
4426                 hud_fade_alpha_save = hud_fade_alpha;
4427                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4428         }
4429         HUD_Panel_UpdateCvars();
4430
4431         if(scoreboard_fade_alpha)
4432         {
4433                 hud_fade_alpha = hud_fade_alpha_save;
4434
4435                 // move the panel below the scoreboard
4436                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4437                         return;
4438                 vector target_pos;
4439
4440                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4441
4442                 if(target_pos.y > panel_pos.y)
4443                 {
4444                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4445                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4446                 }
4447         }
4448
4449         HUD_Panel_DrawBg(1);
4450
4451         if (!centerprint_showing)
4452                 return;
4453
4454         if(panel_bg_padding)
4455         {
4456                 panel_pos += '1 1 0' * panel_bg_padding;
4457                 panel_size -= '2 2 0' * panel_bg_padding;
4458         }
4459
4460         int entries;
4461         float height;
4462         vector fontsize;
4463         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4464         // height = panel_size_y/entries;
4465         // fontsize = '1 1 0' * height;
4466         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4467         fontsize = '1 1 0' * height;
4468         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4469
4470         int i, j, k, n, g;
4471         float a, sz, align, current_msg_posY = 0, msg_size;
4472         vector pos;
4473         string ts;
4474         bool all_messages_expired = true;
4475
4476         pos = panel_pos;
4477         if (autocvar_hud_panel_centerprint_flip)
4478                 pos.y += panel_size.y;
4479         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4480         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4481         {
4482                 if (j == CENTERPRINT_MAX_MSGS)
4483                         j = 0;
4484                 if (centerprint_expire_time[j] <= time)
4485                 {
4486                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4487                         {
4488                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4489                                 if (centerprint_countdown_num[j] == 0)
4490                                         continue;
4491                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4492                         }
4493                         else if(centerprint_time[j] != -1)
4494                                 continue;
4495                 }
4496
4497                 all_messages_expired = false;
4498
4499                 // fade the centerprint_hud in/out
4500                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4501                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4502                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4503                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4504                 else // Expiring soon, so fade it out.
4505                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4506
4507                 // while counting down show it anyway in order to hold the current message position
4508                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4509                         continue;
4510                 if (a > 1)
4511                         a = 1;
4512
4513                 // set the size from fading in/out before subsequent fading
4514                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4515
4516                 // also fade it based on positioning
4517                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4518                 {
4519                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4520                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4521                 }
4522                 a *= panel_fg_alpha;
4523
4524                 // finally set the size based on the new theAlpha from subsequent fading
4525                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4526                 drawfontscale = sz * '1 1 0';
4527
4528                 if (centerprint_countdown_num[j])
4529                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4530                 else
4531                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4532
4533                 if (autocvar_hud_panel_centerprint_flip)
4534                 {
4535                         // check if the message can be entirely shown
4536                         for(k = 0; k < n; ++k)
4537                         {
4538                                 getWrappedLine_remaining = argv(k);
4539                                 while(getWrappedLine_remaining)
4540                                 {
4541                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4542                                         if (ts != "")
4543                                                 pos.y -= fontsize.y;
4544                                         else
4545                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4546                                 }
4547                         }
4548                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4549                 }
4550
4551                 msg_size = pos.y;
4552                 for(k = 0; k < n; ++k)
4553                 {
4554                         getWrappedLine_remaining = argv(k);
4555                         while(getWrappedLine_remaining)
4556                         {
4557                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4558                                 if (ts != "")
4559                                 {
4560                                         if (align)
4561                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4562                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4563                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4564                                         pos.y += fontsize.y;
4565                                 }
4566                                 else
4567                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4568                         }
4569                 }
4570
4571                 ++g; // move next position number up
4572
4573                 msg_size = pos.y - msg_size;
4574                 if (autocvar_hud_panel_centerprint_flip)
4575                 {
4576                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4577                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4578                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4579
4580                         if (pos.y < panel_pos.y) // check if the next message can be shown
4581                         {
4582                                 drawfontscale = '1 1 0';
4583                                 return;
4584                         }
4585                 }
4586                 else
4587                 {
4588                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4589                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4590                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4591
4592                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4593                         {
4594                                 drawfontscale = '1 1 0';
4595                                 return;
4596                         }
4597                 }
4598         }
4599         drawfontscale = '1 1 0';
4600         if (all_messages_expired)
4601         {
4602                 centerprint_showing = false;
4603                 reset_centerprint_messages();
4604         }
4605 }
4606
4607 // ItemsTime (#XX)
4608 //
4609 const float ITEMSTIME_MAXITEMS = 10;
4610 float ItemsTime_time[ITEMSTIME_MAXITEMS];
4611 float ItemsTime_availableTime[ITEMSTIME_MAXITEMS];
4612 string GetItemsTimePicture(float i)
4613 {
4614         switch(i)
4615         {
4616                 case 0: return "item_large_armor";
4617                 case 1: return "item_mega_health";
4618                 case 2: return "strength";
4619                 case 3: return "shield";
4620                 case 4: return "item_mega_health";
4621                 case 5: return "strength";
4622                 case 6: return "shield";
4623                 case 7: return "fuelregen";
4624                 case 8: return "jetpack";
4625                 case 9: return "superweapons";
4626                 default: return "";
4627         }
4628 }
4629
4630 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, float itemcode, float item_time, bool item_available, float item_availableTime)
4631 {
4632         float t = 0;
4633         vector color = '0 0 0';
4634         float picalpha;
4635
4636         if(autocvar_hud_panel_itemstime_hidespawned == 2)
4637                 picalpha = 1;
4638         else if(item_available)
4639         {
4640                 float BLINK_FACTOR = 0.15;
4641                 float BLINK_BASE = 0.85;
4642                 float BLINK_FREQ = 5;
4643                 picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
4644         }
4645         else
4646                 picalpha = 0.5;
4647         t = floor(item_time - time + 0.999);
4648         if(t < 5)
4649                 color = '0.7 0 0';
4650         else if(t < 10)
4651                 color = '0.7 0.7 0';
4652         else
4653                 color = '1 1 1';
4654
4655         vector picpos, numpos;
4656         if(autocvar_hud_panel_itemstime_iconalign)
4657         {
4658                 numpos = myPos;
4659                 picpos = myPos + eX * (ar - 1) * mySize_y;
4660         }
4661         else
4662         {
4663                 numpos = myPos + eX * mySize_y;
4664                 picpos = myPos;
4665         }
4666
4667         if(t > 0 && autocvar_hud_panel_itemstime_progressbar)
4668         {
4669                 vector p_pos, p_size;
4670                 if(autocvar_hud_panel_itemstime_progressbar_reduced)
4671                 {
4672                         p_pos = numpos;
4673                         p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
4674                 }
4675                 else
4676                 {
4677                         p_pos = myPos;
4678                         p_size = mySize;
4679                 }
4680                 HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4681         }
4682
4683         if(t > 0 && autocvar_hud_panel_itemstime_text)
4684                 drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
4685         else
4686                 picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
4687         if(item_availableTime)
4688                 drawpic_aspect_skin_expanding(picpos, GetItemsTimePicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
4689         drawpic_aspect_skin(picpos, GetItemsTimePicture(itemcode), '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
4690 }
4691
4692 void HUD_ItemsTime(void)
4693 {
4694         if(!autocvar__hud_configure)
4695         {
4696                 if(!(
4697                         (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
4698                 ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
4699                         )) { return; }
4700
4701                 ItemsTime_time[0] = getstatf(STAT_ARMOR_LARGE_TIME);
4702                 ItemsTime_time[1] = getstatf(STAT_HEALTH_MEGA_TIME);
4703                 ItemsTime_time[2] = getstatf(STAT_INVISIBLE_TIME);
4704                 ItemsTime_time[3] = getstatf(STAT_SPEED_TIME);
4705                 ItemsTime_time[4] = getstatf(STAT_EXTRALIFE_TIME);
4706                 ItemsTime_time[5] = getstatf(STAT_STRENGTH_TIME);
4707                 ItemsTime_time[6] = getstatf(STAT_SHIELD_TIME);
4708                 ItemsTime_time[7] = getstatf(STAT_FUELREGEN_TIME);
4709                 ItemsTime_time[8] = getstatf(STAT_JETPACK_TIME);
4710                 ItemsTime_time[9] = getstatf(STAT_SUPERWEAPONS_TIME);
4711         }
4712         else
4713         {
4714                 // do not show here mutator-dependent items
4715                 ItemsTime_time[0] = time + 0;
4716                 ItemsTime_time[1] = time + 8;
4717                 ItemsTime_time[2] = -1; // mutator-dependent
4718                 ItemsTime_time[3] = -1; // mutator-dependent
4719                 ItemsTime_time[4] = -1; // mutator-dependent
4720                 ItemsTime_time[5] = time + 0;
4721                 ItemsTime_time[6] = time + 4;
4722                 ItemsTime_time[7] = time + 49;
4723                 ItemsTime_time[8] = -1;
4724                 ItemsTime_time[9] = time + 28;
4725         }
4726
4727         float i;
4728         float count = 0;
4729         if(autocvar_hud_panel_itemstime_hidespawned == 1)
4730                 for (i = 0; i < ITEMSTIME_MAXITEMS; ++i)
4731                         count += (ItemsTime_time[i] > time || -ItemsTime_time[i] > time);
4732         else if(autocvar_hud_panel_itemstime_hidespawned == 2)
4733                 for (i = 0; i < ITEMSTIME_MAXITEMS; ++i)
4734                         count += (ItemsTime_time[i] > time);
4735         else
4736                 for (i = 0; i < ITEMSTIME_MAXITEMS; ++i)
4737                         count += (ItemsTime_time[i] != -1);
4738         if (count == 0)
4739                 return;
4740
4741         HUD_Panel_UpdateCvars();
4742
4743         vector pos, mySize;
4744         pos = panel_pos;
4745         mySize = panel_size;
4746
4747         if(panel_bg_padding)
4748         {
4749                 pos += '1 1 0' * panel_bg_padding;
4750                 mySize -= '2 2 0' * panel_bg_padding;
4751         }
4752
4753         float rows, columns;
4754         float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
4755         rows = HUD_GetRowCount(count, mySize, ar);
4756         columns = ceil(count/rows);
4757
4758         vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
4759
4760         vector offset = '0 0 0';
4761         float newSize;
4762         if(autocvar_hud_panel_itemstime_dynamicsize)
4763         {
4764                 if(autocvar__hud_configure)
4765                 if(menu_enabled != 2)
4766                         HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
4767
4768                 // reduce panel to avoid spacing items
4769                 if(itemstime_size.x / itemstime_size.y < ar)
4770                 {
4771                         newSize = rows * itemstime_size.x / ar;
4772                         pos.y += (mySize.y - newSize) / 2;
4773                         mySize.y = newSize;
4774                         itemstime_size.y = mySize.y / rows;
4775                 }
4776                 else
4777                 {
4778                         newSize = columns * itemstime_size.y * ar;
4779                         pos.x += (mySize.x - newSize) / 2;
4780                         mySize.x = newSize;
4781                         itemstime_size.x = mySize.x / columns;
4782                 }
4783                 panel_pos = pos - '1 1 0' * panel_bg_padding;
4784                 panel_size = mySize + '2 2 0' * panel_bg_padding;
4785         }
4786         else
4787         {
4788                 if(itemstime_size.x/itemstime_size.y > ar)
4789                 {
4790                         newSize = ar * itemstime_size.y;
4791                         offset.x = itemstime_size.x - newSize;
4792                         pos.x += offset.x/2;
4793                         itemstime_size.x = newSize;
4794                 }
4795                 else
4796                 {
4797                         newSize = 1/ar * itemstime_size.x;
4798                         offset.y = itemstime_size.y - newSize;
4799                         pos.y += offset.y/2;
4800                         itemstime_size.y = newSize;
4801                 }
4802         }
4803
4804         HUD_Panel_DrawBg(1);
4805
4806         float row = 0, column = 0;
4807         bool item_available;
4808         for (i = 0; i < ITEMSTIME_MAXITEMS; ++i) {
4809                 if (ItemsTime_time[i] == -1)
4810                         continue;
4811
4812                 float item_time = ItemsTime_time[i];
4813                 if(item_time < -1)
4814                 {
4815                         item_available = true;
4816                         item_time = -item_time;
4817                 }
4818                 else
4819                         item_available = (item_time <= time);
4820
4821                 if(ItemsTime_time[i] >= 0)
4822                 {
4823                         if(time <= ItemsTime_time[i])
4824                                 ItemsTime_availableTime[i] = 0;
4825                         else if(ItemsTime_availableTime[i] == 0)
4826                                 ItemsTime_availableTime[i] = time;
4827                 }
4828                 else if(ItemsTime_availableTime[i] == 0)
4829                         ItemsTime_availableTime[i] = time;
4830
4831                 float f = (time - ItemsTime_availableTime[i]) * 2;
4832                 f = (f > 1) ? 0 : bound(0, f, 1);
4833
4834                 if(autocvar_hud_panel_itemstime_hidespawned == 1)
4835                         if(!(ItemsTime_time[i] > time || -ItemsTime_time[i] > time))
4836                                 continue;
4837
4838                 if(autocvar_hud_panel_itemstime_hidespawned == 2)
4839                         if(!(ItemsTime_time[i] > time))
4840                                 continue;
4841
4842                 DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, i, item_time, item_available, f);
4843                 ++row;
4844                 if(row >= rows)
4845                 {
4846                         row = 0;
4847                         column = column + 1;
4848                 }
4849         }
4850 }
4851
4852
4853 /*
4854 ==================
4855 Main HUD system
4856 ==================
4857 */
4858
4859 void HUD_Reset (void)
4860 {
4861         // reset gametype specific icons
4862         if(gametype == MAPINFO_TYPE_CTF)
4863                 HUD_Mod_CTF_Reset();
4864 }
4865
4866 void HUD_Main (void)
4867 {
4868         int i;
4869         // global hud theAlpha fade
4870         if(menu_enabled == 1)
4871                 hud_fade_alpha = 1;
4872         else
4873                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4874
4875         if(scoreboard_fade_alpha)
4876                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4877
4878         HUD_Configure_Frame();
4879
4880         // panels that we want to be active together with the scoreboard
4881         // they must fade only when the menu does
4882         if(scoreboard_fade_alpha == 1)
4883         {
4884                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4885                 return;
4886         }
4887
4888         if(!autocvar__hud_configure && !hud_fade_alpha)
4889                 return;
4890
4891         // Drawing stuff
4892         if (hud_skin_prev != autocvar_hud_skin)
4893         {
4894                 if (hud_skin_path)
4895                         strunzone(hud_skin_path);
4896                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4897                 if (hud_skin_prev)
4898                         strunzone(hud_skin_prev);
4899                 hud_skin_prev = strzone(autocvar_hud_skin);
4900         }
4901
4902         // draw the dock
4903         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4904         {
4905                 int f;
4906                 vector color;
4907                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4908                 if((teamplay) && hud_dock_color_team) {
4909                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4910                                 color = '1 0 0' * hud_dock_color_team;
4911                         else
4912                                 color = myteamcolors * hud_dock_color_team;
4913                 }
4914                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4915                         color = '1 0 0' * hud_dock_color_team;
4916                 }
4917                 else
4918                 {
4919                         string hud_dock_color = autocvar_hud_dock_color;
4920                         if(hud_dock_color == "shirt") {
4921                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4922                                 color = colormapPaletteColor(floor(f / 16), 0);
4923                         }
4924                         else if(hud_dock_color == "pants") {
4925                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4926                                 color = colormapPaletteColor(f % 16, 1);
4927                         }
4928                         else
4929                                 color = stov(hud_dock_color);
4930                 }
4931
4932                 string pic;
4933                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4934                 if(precache_pic(pic) == "") {
4935                         pic = strcat(hud_skin_path, "/dock_medium");
4936                         if(precache_pic(pic) == "") {
4937                                 pic = "gfx/hud/default/dock_medium";
4938                         }
4939                 }
4940                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4941         }
4942
4943         // cache the panel order into the panel_order array
4944         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4945                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4946                         panel_order[i] = -1;
4947                 string s = "";
4948                 int p_num;
4949                 bool warning = false;
4950                 int argc = tokenize_console(autocvar__hud_panelorder);
4951                 if (argc > HUD_PANEL_NUM)
4952                         warning = true;
4953                 //first detect wrong/missing panel numbers
4954                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4955                         p_num = stoi(argv(i));
4956                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4957                                 if (panel_order[p_num] == -1) //found for the first time?
4958                                         s = strcat(s, ftos(p_num), " ");
4959                                 panel_order[p_num] = 1; //mark as found
4960                         }
4961                         else
4962                                 warning = true;
4963                 }
4964                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4965                         if (panel_order[i] == -1) {
4966                                 warning = true;
4967                                 s = strcat(s, ftos(i), " "); //add missing panel number
4968                         }
4969                 }
4970                 if (warning)
4971                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4972
4973                 cvar_set("_hud_panelorder", s);
4974                 if(hud_panelorder_prev)
4975                         strunzone(hud_panelorder_prev);
4976                 hud_panelorder_prev = strzone(s);
4977
4978                 //now properly set panel_order
4979                 tokenize_console(s);
4980                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4981                         panel_order[i] = stof(argv(i));
4982                 }
4983         }
4984
4985         hud_draw_maximized = 0;
4986         // draw panels in the order specified by panel_order array
4987         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4988                 (panel = hud_panel[panel_order[i]]).panel_draw();
4989
4990         hud_draw_maximized = 1; // panels that may be maximized must check this var
4991         // draw maximized panels on top
4992         if(hud_panel_radar_maximized)
4993                 (panel = HUD_PANEL(RADAR)).panel_draw();
4994         if(autocvar__con_chat_maximized)
4995                 (panel = HUD_PANEL(CHAT)).panel_draw();
4996
4997         HUD_Configure_PostDraw();
4998
4999         hud_configure_prev = autocvar__hud_configure;
5000 }