qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <common/notifications/all.qh>
   6
   7 // CenterPrint (#16)
   8
   9 void HUD_CenterPrint_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_centerprint_align");
  13         HUD_Write_Cvar("hud_panel_centerprint_flip");
  14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
  15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
  16         HUD_Write_Cvar("hud_panel_centerprint_time");
  17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
  18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
  19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
  20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
  21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
  22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
  23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
  24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
  25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
  26 }
  27
  28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
  29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
  30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
  31 // by Local_Notification.
  32 // HUD_CenterPrint draws all the messages on screen
  33
  34 const int CENTERPRINT_MAX_MSGS = 10;
  35 const int CENTERPRINT_MAX_ENTRIES = 50;
  36 const float CENTERPRINT_BASE_SIZE = 1.3;
  37 const float CENTERPRINT_SPACING = 0.3;
  38 const float CENTERPRINT_TITLE_SPACING = 0.35;
  39 int cpm_index;
  40 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  41 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  42 float centerprint_time[CENTERPRINT_MAX_MSGS];
  43 float centerprint_start_time[CENTERPRINT_MAX_MSGS];
  44 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  45 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  46 bool centerprint_showing;
  47
  48 string centerprint_title;
  49 string centerprint_title_left;
  50 string centerprint_title_right;
  51
  52 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
  53 {
  54         TC(int, new_id); TC(int, countdown_num);
  55         //LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
  56         int i, j;
  57
  58         if(strMessage == "" && new_id == 0)
  59                 return;
  60
  61         // strip trailing newlines
  62         j = strlen(strMessage) - 1;
  63         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  64                 --j;
  65         if (j < strlen(strMessage) - 1)
  66                 strMessage = substring(strMessage, 0, j + 1);
  67
  68         if(strMessage == "" && new_id == 0)
  69                 return;
  70
  71         // strip leading newlines
  72         j = 0;
  73         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  74                 ++j;
  75         if (j > 0)
  76                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  77
  78         if(strMessage == "" && new_id == 0)
  79                 return;
  80
  81         if (!centerprint_showing)
  82                 centerprint_showing = true;
  83
  84         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  85         {
  86                 if (j == CENTERPRINT_MAX_MSGS)
  87                         j = 0;
  88                 if (new_id && new_id == centerprint_msgID[j])
  89                 {
  90                         if (strMessage == "" && centerprint_messages[j] != "")
  91                         {
  92                                 // fade out the current msg (duration and countdown_num are ignored)
  93                                 centerprint_start_time[j] = 0;
  94                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  95                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
  96                                 return;
  97                         }
  98                         break; // found a msg with the same id, at position j
  99                 }
 100         }
 101
 102         if (strMessage == "")
 103                 return;
 104
 105         if (i == CENTERPRINT_MAX_MSGS)
 106         {
 107                 // a msg with the same id was not found, add the msg at the next position
 108                 --cpm_index;
 109                 if (cpm_index == -1)
 110                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
 111                 j = cpm_index;
 112         }
 113         strcpy(centerprint_messages[j], strMessage);
 114         centerprint_start_time[j] = time;
 115         centerprint_msgID[j] = new_id;
 116         if (duration < 0)
 117         {
 118                 centerprint_time[j] = -1;
 119                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 120         }
 121         else
 122         {
 123                 if(duration == 0)
 124                         duration = max(1, autocvar_hud_panel_centerprint_time);
 125                 centerprint_time[j] = duration;
 126                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 127         }
 128         centerprint_countdown_num[j] = countdown_num;
 129 }
 130
 131 void centerprint_Kill(int id)
 132 {
 133         TC(int, id);
 134         centerprint_Add(id, "", 0, 0);
 135 }
 136
 137 void centerprint_AddStandard(string strMessage)
 138 {
 139         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 140 }
 141
 142 void centerprint_KillAll()
 143 {
 144         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 145         {
 146                 centerprint_start_time[i] = 0;
 147                 centerprint_expire_time[i] = 0;
 148                 centerprint_time[i] = 1;
 149                 centerprint_msgID[i] = 0;
 150                 strfree(centerprint_messages[i]);
 151         }
 152 }
 153
 154 void centerprint_SetDuelTitle(string left, string right, string div)
 155 {
 156         float namesize = autocvar_hud_panel_scoreboard_namesize * hud_fontsize.x;
 157         strcpy(centerprint_title_left, textShortenToWidth(left, namesize, hud_fontsize, stringwidth_colors));
 158         strcpy(centerprint_title_right, textShortenToWidth(right, namesize, hud_fontsize, stringwidth_colors));
 159         centerprint_SetTitle(sprintf("^BG%s^BG  %s  %s", centerprint_title_left, div, centerprint_title_right));
 160 }
 161
 162 void centerprint_SetTitle(string title)
 163 {
 164         if(title != centerprint_title)
 165                 strcpy(centerprint_title, CCR(title));
 166 }
 167
 168 void centerprint_ClearTitle()
 169 {
 170         strfree(centerprint_title);
 171         strfree(centerprint_title_left);
 172         strfree(centerprint_title_right);
 173 }
 174
 175 float hud_configure_cp_generation_time;
 176 void HUD_CenterPrint()
 177 {
 178         if(!autocvar__hud_configure)
 179         {
 180                 if(!autocvar_hud_panel_centerprint) return;
 181
 182                 if(hud_configure_prev) {
 183                         centerprint_ClearTitle();
 184                         centerprint_KillAll();
 185                 }
 186         }
 187         else
 188         {
 189                 if(!hud_configure_prev)
 190                 {
 191                         centerprint_KillAll();
 192                         hud_configure_cp_generation_time = time; // show a message immediately
 193                 }
 194                 if (time > hud_configure_cp_generation_time)
 195                 {
 196                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 197                         {
 198                                 centerprint_SetTitle(sprintf(_("Title at %s"), seconds_tostring(hud_configure_cp_generation_time)));
 199
 200                                 float r;
 201                                 r = random();
 202                                 if (r > 0.8)
 203                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
 204                                 else if (r > 0.55)
 205                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^BOLDlasts longer than normal"), seconds_tostring(time)), 20, 0);
 206                                 else
 207                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
 208                                 hud_configure_cp_generation_time = time + 1 + random()*4;
 209                         }
 210                         else
 211                         {
 212                                 centerprint_Add(0, _("Generic message"), 10, 0);
 213                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 214                         }
 215                 }
 216         }
 217
 218         HUD_Panel_LoadCvars();
 219
 220         if ( HUD_Radar_Clickable() )
 221         {
 222                 if (hud_panel_radar_bottom >= vid_conheight)
 223                         return;
 224
 225                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
 226                 panel_pos.y = hud_panel_radar_bottom;
 227                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
 228         }
 229         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
 230         {
 231                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
 232                 if(target_pos.y > panel_pos.y)
 233                 {
 234                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 235                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 236                 }
 237
 238                 // move the panel below the scoreboard
 239                 if (panel_pos.y >= vid_conheight)
 240                         return;
 241         }
 242
 243         if (autocvar_hud_panel_centerprint_dynamichud)
 244                 HUD_Scale_Enable();
 245         else
 246                 HUD_Scale_Disable();
 247         HUD_Panel_DrawBg();
 248
 249         if (!centerprint_showing)
 250                 return;
 251
 252         if(panel_bg_padding)
 253         {
 254                 panel_pos += '1 1 0' * panel_bg_padding;
 255                 panel_size -= '2 2 0' * panel_bg_padding;
 256         }
 257
 258         int i, j, k, n, g;
 259         float a = 1, sz, align, current_msg_posY = 0, msg_size;
 260         vector pos;
 261         vector cp_fontsize = hud_fontsize * CENTERPRINT_BASE_SIZE;
 262         string ts = "";
 263         bool all_messages_expired = true;
 264
 265         pos = panel_pos;
 266         if (autocvar_hud_panel_centerprint_flip)
 267                 pos.y += panel_size.y;
 268         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 269
 270         // Show title if available
 271         if(centerprint_title) {
 272                 vector fontsize = cp_fontsize * autocvar_hud_panel_centerprint_fontscale_title;
 273                 float width = stringwidth(centerprint_title, true, fontsize);
 274
 275                 pos.x = panel_pos.x + (panel_size.x - width) * align;
 276
 277                 if (autocvar_hud_panel_centerprint_flip)
 278                         pos.y -= fontsize.y;
 279                 float right_width = 0;
 280                 float left_width = 0;
 281                 if (centerprint_title_left != "")
 282                 {
 283                         right_width = stringwidth(centerprint_title_right, true, fontsize);
 284                         left_width = stringwidth(centerprint_title_left, true, fontsize);
 285                         if (align == 0.5) // Center line at the main word (for duels)
 286                                 pos.x += (right_width - left_width) / 2;
 287                 }
 288
 289                 drawcolorcodedstring(pos, centerprint_title, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 290
 291                 if (autocvar_hud_panel_centerprint_flip)
 292                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 293                 else
 294                         pos.y += fontsize.y + (hud_fontsize.y * CENTERPRINT_TITLE_SPACING);
 295
 296                 if (centerprint_title_left != "")
 297                 {
 298                         drawfill(pos, vec2(left_width, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 299                         drawfill(pos + vec2(width - right_width, 1), vec2(right_width, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 300                 }
 301                 else
 302                         drawfill(pos, vec2(width, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 303
 304                 if (autocvar_hud_panel_centerprint_flip)
 305                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 306                 else
 307                         pos.y += cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 308
 309                 all_messages_expired = false;
 310         }
 311
 312         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 313         {
 314                 if (j == CENTERPRINT_MAX_MSGS)
 315                         j = 0;
 316                 if (centerprint_expire_time[j] == -1)
 317                 {
 318                         // here we are sure the time variable is not altered by CSQC_Ent_Update
 319                         centerprint_expire_time[j] = time;
 320                         if (centerprint_time[j] > 0)
 321                                 centerprint_expire_time[j] += centerprint_time[j];
 322                 }
 323                 if (centerprint_expire_time[j] <= time)
 324                 {
 325                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0 && centerprint_start_time[j])
 326                         {
 327                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 328                                 if (centerprint_countdown_num[j] == 0)
 329                                         continue;
 330                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 331                         }
 332                         else if(centerprint_time[j] != -1)
 333                                 continue;
 334                 }
 335
 336                 all_messages_expired = false;
 337
 338                 if (time < centerprint_start_time[j]) continue;
 339
 340                 float fade_in_time = autocvar_hud_panel_centerprint_fade_in;
 341                 float fade_out_time = autocvar_hud_panel_centerprint_fade_out;
 342
 343                 if (centerprint_countdown_num[j] && centerprint_start_time[j]) {
 344                         fade_in_time = 0;
 345                         fade_out_time = 0;
 346                 }
 347
 348                 // fade
 349                 if(fade_in_time && centerprint_start_time[j] && time < centerprint_start_time[j] + fade_in_time) // Fade in
 350                         a = (time - centerprint_start_time[j]) / fade_in_time;
 351                 else if(time < centerprint_expire_time[j] - fade_out_time || centerprint_time[j] < 0) // Regularily printed or forced
 352                         a = 1;
 353                 else if(fade_out_time) // Expiring soon, so fade it out.
 354                         a = (centerprint_expire_time[j] - time) / fade_out_time;
 355
 356                 if(centerprint_msgID[j] == ORDINAL(CPID_TIMEIN))
 357                         a = 1;
 358
 359                 // while counting down show it anyway in order to hold the current message position
 360                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 361                         continue;
 362
 363                 // also fade it based on positioning
 364                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 365                 {
 366                         // pass one: all messages after the first have half alpha
 367                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 368                         // pass two: after that, gradually lower alpha even more for each message
 369                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 370                 }
 371                 a *= panel_fg_alpha;
 372
 373                 // finally set the size based on the alpha
 374                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 375                 drawfontscale = hud_scale * sz;
 376
 377                 if (centerprint_countdown_num[j])
 378                         n = tokenizebyseparator(strreplace("^COUNT", ftos(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 379                 else
 380                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 381
 382                 if (autocvar_hud_panel_centerprint_flip)
 383                 {
 384                         // check if the message can be entirely shown
 385                         for(k = 0; k < n; ++k)
 386                         {
 387                                 getWrappedLine_remaining = argv(k);
 388                                 while(getWrappedLine_remaining)
 389                                 {
 390                                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 391                                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 392
 393                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 394                                         if (ts != "")
 395                                                 pos.y -= fontsize.y;
 396                                         else
 397                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 398                                 }
 399                         }
 400                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 401                 }
 402
 403                 msg_size = pos.y;
 404                 for(k = 0; k < n; ++k)
 405                 {
 406                         getWrappedLine_remaining = argv(k);
 407
 408                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 409                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 410                         if (is_bold)
 411                                 getWrappedLine_remaining = substring(getWrappedLine_remaining, 5, -1);
 412
 413                         while(getWrappedLine_remaining)
 414                         {
 415                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 416                                 if (ts != "")
 417                                 {
 418                                         if (align)
 419                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 420                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 421                                                 if (is_bold) draw_beginBoldFont();
 422                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 423                                                 if (is_bold) draw_endBoldFont();
 424                                         pos.y += fontsize.y;
 425                                 }
 426                                 else
 427                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 428                         }
 429                 }
 430
 431                 ++g; // move next position number up
 432
 433                 msg_size = pos.y - msg_size;
 434
 435                 if (autocvar_hud_panel_centerprint_flip)
 436                 {
 437                         pos.y -= msg_size + CENTERPRINT_SPACING * cp_fontsize.y;
 438                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 439                                 pos.y += (1 - sqrt(a));
 440
 441                         if (pos.y < panel_pos.y) // check if the next message can be shown
 442                         {
 443                                 drawfontscale = hud_scale;
 444                                 return;
 445                         }
 446                 }
 447                 else
 448                 {
 449                         pos.y += CENTERPRINT_SPACING * cp_fontsize.y;
 450                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 451                                 pos.y -= (1 - sqrt(a));
 452
 453                         if(pos.y > panel_pos.y + panel_size.y - cp_fontsize.y) // check if the next message can be shown
 454                         {
 455                                 drawfontscale = hud_scale;
 456                                 return;
 457                         }
 458                 }
 459         }
 460
 461         drawfontscale = hud_scale;
 462         if (all_messages_expired)
 463         {
 464                 centerprint_showing = false;
 465                 centerprint_KillAll();
 466         }
 467 }