Slightly extend underline of normal centerprint titles (it looks better and is consis...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / hud / panel / centerprint.qc
1 #include "centerprint.qh"
2
3 #include <client/draw.qh>
4 #include <client/hud/panel/scoreboard.qh>
5 #include <common/notifications/all.qh>
6
7 // CenterPrint (#16)
8
9 void HUD_CenterPrint_Export(int fh)
10 {
11         // allow saving cvars that aesthetically change the panel into hud skin files
12         HUD_Write_Cvar("hud_panel_centerprint_align");
13         HUD_Write_Cvar("hud_panel_centerprint_flip");
14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
16         HUD_Write_Cvar("hud_panel_centerprint_time");
17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
26 }
27
28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
31 // by Local_Notification.
32 // HUD_CenterPrint draws all the messages on screen
33
34 const int CENTERPRINT_MAX_MSGS = 10;
35 const int CENTERPRINT_MAX_ENTRIES = 50;
36 const float CENTERPRINT_BASE_SIZE = 1.3;
37 const float CENTERPRINT_SPACING = 0.3;
38 const float CENTERPRINT_TITLE_SPACING = 0.35;
39 int cpm_index;
40 string centerprint_messages[CENTERPRINT_MAX_MSGS];
41 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
42 float centerprint_time[CENTERPRINT_MAX_MSGS];
43 float centerprint_start_time[CENTERPRINT_MAX_MSGS];
44 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
45 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
46 bool centerprint_showing;
47
48 string centerprint_title;
49 string centerprint_title_left;
50 string centerprint_title_right;
51
52 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
53 {
54         TC(int, new_id); TC(int, countdown_num);
55         //LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
56         int i, j;
57
58         if(strMessage == "" && new_id == 0)
59                 return;
60
61         // strip trailing newlines
62         j = strlen(strMessage) - 1;
63         while(substring(strMessage, j, 1) == "\n" && j >= 0)
64                 --j;
65         if (j < strlen(strMessage) - 1)
66                 strMessage = substring(strMessage, 0, j + 1);
67
68         if(strMessage == "" && new_id == 0)
69                 return;
70
71         // strip leading newlines
72         j = 0;
73         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
74                 ++j;
75         if (j > 0)
76                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
77
78         if(strMessage == "" && new_id == 0)
79                 return;
80
81         if (!centerprint_showing)
82                 centerprint_showing = true;
83
84         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
85         {
86                 if (j == CENTERPRINT_MAX_MSGS)
87                         j = 0;
88                 if (new_id && new_id == centerprint_msgID[j])
89                 {
90                         if (strMessage == "" && centerprint_messages[j] != "")
91                         {
92                                 // fade out the current msg (duration and countdown_num are ignored)
93                                 centerprint_start_time[j] = 0;
94                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
95                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
96                                 return;
97                         }
98                         break; // found a msg with the same id, at position j
99                 }
100         }
101
102         if (strMessage == "")
103                 return;
104
105         if (i == CENTERPRINT_MAX_MSGS)
106         {
107                 // a msg with the same id was not found, add the msg at the next position
108                 --cpm_index;
109                 if (cpm_index == -1)
110                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
111                 j = cpm_index;
112         }
113         strcpy(centerprint_messages[j], strMessage);
114         centerprint_start_time[j] = time;
115         centerprint_msgID[j] = new_id;
116         if (duration < 0)
117         {
118                 centerprint_time[j] = -1;
119                 centerprint_expire_time[j] = -1; // don't use the variable time here!
120         }
121         else
122         {
123                 if(duration == 0)
124                         duration = max(1, autocvar_hud_panel_centerprint_time);
125                 centerprint_time[j] = duration;
126                 centerprint_expire_time[j] = -1; // don't use the variable time here!
127         }
128         centerprint_countdown_num[j] = countdown_num;
129 }
130
131 void centerprint_Kill(int id)
132 {
133         TC(int, id);
134         centerprint_Add(id, "", 0, 0);
135 }
136
137 void centerprint_AddStandard(string strMessage)
138 {
139         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
140 }
141
142 void centerprint_KillAll()
143 {
144         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
145         {
146                 centerprint_start_time[i] = 0;
147                 centerprint_expire_time[i] = 0;
148                 centerprint_time[i] = 1;
149                 centerprint_msgID[i] = 0;
150                 strfree(centerprint_messages[i]);
151         }
152 }
153
154 void centerprint_SetDuelTitle(string left, string right)
155 {
156         float namesize = autocvar_hud_panel_scoreboard_namesize * hud_fontsize.x;
157         strcpy(centerprint_title_left, textShortenToWidth(left, namesize, hud_fontsize, stringwidth_colors));
158         strcpy(centerprint_title_right, textShortenToWidth(right, namesize, hud_fontsize, stringwidth_colors));
159 }
160
161 void centerprint_SetTitle(string title)
162 {
163         if(title != centerprint_title)
164                 strcpy(centerprint_title, CCR(title));
165 }
166
167 void centerprint_ClearTitle()
168 {
169         strfree(centerprint_title);
170         strfree(centerprint_title_left);
171         strfree(centerprint_title_right);
172 }
173
174 float hud_configure_cp_generation_time;
175 void HUD_CenterPrint()
176 {
177         if(!autocvar__hud_configure)
178         {
179                 if(!autocvar_hud_panel_centerprint) return;
180
181                 if(hud_configure_prev) {
182                         centerprint_ClearTitle();
183                         centerprint_KillAll();
184                 }
185         }
186         else
187         {
188                 if(!hud_configure_prev)
189                 {
190                         centerprint_KillAll();
191                         hud_configure_cp_generation_time = time; // show a message immediately
192                 }
193                 if (time > hud_configure_cp_generation_time)
194                 {
195                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
196                         {
197                                 centerprint_SetTitle(sprintf(_("Title at %s"), seconds_tostring(hud_configure_cp_generation_time)));
198
199                                 float r;
200                                 r = random();
201                                 if (r > 0.8)
202                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
203                                 else if (r > 0.55)
204                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^BOLDlasts longer than normal"), seconds_tostring(time)), 20, 0);
205                                 else
206                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
207                                 hud_configure_cp_generation_time = time + 1 + random()*4;
208                         }
209                         else
210                         {
211                                 centerprint_Add(0, _("Generic message"), 10, 0);
212                                 hud_configure_cp_generation_time = time + 10 - random()*3;
213                         }
214                 }
215         }
216
217         HUD_Panel_LoadCvars();
218
219         if ( HUD_Radar_Clickable() )
220         {
221                 if (hud_panel_radar_bottom >= vid_conheight)
222                         return;
223
224                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
225                 panel_pos.y = hud_panel_radar_bottom;
226                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
227         }
228         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
229         {
230                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
231                 if(target_pos.y > panel_pos.y)
232                 {
233                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
234                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
235                 }
236
237                 // move the panel below the scoreboard
238                 if (panel_pos.y >= vid_conheight)
239                         return;
240         }
241
242         if (autocvar_hud_panel_centerprint_dynamichud)
243                 HUD_Scale_Enable();
244         else
245                 HUD_Scale_Disable();
246         HUD_Panel_DrawBg();
247
248         if (!centerprint_showing)
249                 return;
250
251         if(panel_bg_padding)
252         {
253                 panel_pos += '1 1 0' * panel_bg_padding;
254                 panel_size -= '2 2 0' * panel_bg_padding;
255         }
256
257         int i, j, k, n, g;
258         float a = 1, sz, align, current_msg_posY = 0, msg_size;
259         vector pos;
260         vector cp_fontsize = hud_fontsize * CENTERPRINT_BASE_SIZE;
261         string ts = "";
262         bool all_messages_expired = true;
263
264         pos = panel_pos;
265         if (autocvar_hud_panel_centerprint_flip)
266                 pos.y += panel_size.y;
267         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
268
269         // Show title if available
270         if(centerprint_title != "" || centerprint_title_left != "") {
271                 vector fontsize = cp_fontsize * autocvar_hud_panel_centerprint_fontscale_title;
272                 float width = 0, right_width = 0, left_width = 0, max_rl_width = 0;
273                 if (centerprint_title != "")
274                         width = stringwidth(centerprint_title, true, fontsize);
275                 else
276                 {
277                         right_width = stringwidth(centerprint_title_right, true, fontsize);
278                         left_width = stringwidth(centerprint_title_left, true, fontsize);
279                 }
280
281                 if (autocvar_hud_panel_centerprint_flip)
282                         pos.y -= fontsize.y;
283
284                 vector duel_title_pos = '0 0 0';
285                 float padding = stringwidth(" ", false, fontsize) * 2;
286                 if (centerprint_title_left != "")
287                 {
288                         if (left_width > right_width)
289                                 max_rl_width = left_width;
290                         else
291                                 max_rl_width = right_width;
292
293                         width = max_rl_width * 2 + padding * 6 + stringwidth(_("vs"), false, fontsize);
294                         pos.x += (panel_size.x - width) * align;
295                         duel_title_pos = pos;
296
297                         pos.x += padding;
298                         if (left_width < right_width)
299                                 pos.x += (max_rl_width - left_width) * 0.5;
300                         drawcolorcodedstring(pos, centerprint_title_left, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
301
302                         pos.x = duel_title_pos.x + max_rl_width + padding * 3;
303                         drawstring(pos, _("vs"), fontsize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
304
305                         pos.x = duel_title_pos.x + width - padding - max_rl_width;
306                         if (left_width >= right_width)
307                                 pos.x += (max_rl_width - right_width) * 0.5;
308                         drawcolorcodedstring(pos, centerprint_title_right, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
309                 }
310                 else
311                 {
312                         pos.x = panel_pos.x + (panel_size.x - width) * align;
313                         drawcolorcodedstring(pos, centerprint_title, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
314                 }
315
316                 if (autocvar_hud_panel_centerprint_flip)
317                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
318                 else
319                         pos.y += fontsize.y + (hud_fontsize.y * CENTERPRINT_TITLE_SPACING);
320
321                 if (centerprint_title_left != "")
322                 {
323                         pos.x = duel_title_pos.x;
324                         drawfill(pos, vec2(max_rl_width + padding * 2, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
325                         drawfill(pos + vec2(width - max_rl_width - padding * 2, 0), vec2(max_rl_width + padding * 2, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
326                 }
327                 else
328                         drawfill(pos - eX * padding, vec2(width + 2 * padding, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
329
330                 if (autocvar_hud_panel_centerprint_flip)
331                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
332                 else
333                         pos.y += cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
334
335                 all_messages_expired = false;
336         }
337
338         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
339         {
340                 if (j == CENTERPRINT_MAX_MSGS)
341                         j = 0;
342                 if (centerprint_expire_time[j] == -1)
343                 {
344                         // here we are sure the time variable is not altered by CSQC_Ent_Update
345                         centerprint_expire_time[j] = time;
346                         if (centerprint_time[j] > 0)
347                                 centerprint_expire_time[j] += centerprint_time[j];
348                 }
349                 if (centerprint_expire_time[j] <= time)
350                 {
351                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0 && centerprint_start_time[j])
352                         {
353                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
354                                 if (centerprint_countdown_num[j] == 0)
355                                         continue;
356                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
357                         }
358                         else if(centerprint_time[j] != -1)
359                                 continue;
360                 }
361
362                 all_messages_expired = false;
363
364                 if (time < centerprint_start_time[j]) continue;
365
366                 float fade_in_time = autocvar_hud_panel_centerprint_fade_in;
367                 float fade_out_time = autocvar_hud_panel_centerprint_fade_out;
368
369                 if (centerprint_countdown_num[j] && centerprint_start_time[j]) {
370                         fade_in_time = 0;
371                         fade_out_time = 0;
372                 }
373
374                 // fade
375                 if(fade_in_time && centerprint_start_time[j] && time < centerprint_start_time[j] + fade_in_time) // Fade in
376                         a = (time - centerprint_start_time[j]) / fade_in_time;
377                 else if(time < centerprint_expire_time[j] - fade_out_time || centerprint_time[j] < 0) // Regularily printed or forced
378                         a = 1;
379                 else if(fade_out_time) // Expiring soon, so fade it out.
380                         a = (centerprint_expire_time[j] - time) / fade_out_time;
381
382                 if(centerprint_msgID[j] == ORDINAL(CPID_TIMEIN))
383                         a = 1;
384
385                 // while counting down show it anyway in order to hold the current message position
386                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
387                         continue;
388
389                 // also fade it based on positioning
390                 if(autocvar_hud_panel_centerprint_fade_subsequent)
391                 {
392                         // pass one: all messages after the first have half alpha
393                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
394                         // pass two: after that, gradually lower alpha even more for each message
395                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
396                 }
397                 a *= panel_fg_alpha;
398
399                 // finally set the size based on the alpha
400                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
401                 drawfontscale = hud_scale * sz;
402
403                 if (centerprint_countdown_num[j])
404                         n = tokenizebyseparator(strreplace("^COUNT", ftos(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
405                 else
406                         n = tokenizebyseparator(centerprint_messages[j], "\n");
407
408                 if (autocvar_hud_panel_centerprint_flip)
409                 {
410                         // check if the message can be entirely shown
411                         for(k = 0; k < n; ++k)
412                         {
413                                 getWrappedLine_remaining = argv(k);
414                                 while(getWrappedLine_remaining)
415                                 {
416                                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
417                                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
418
419                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
420                                         if (ts != "")
421                                                 pos.y -= fontsize.y;
422                                         else
423                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
424                                 }
425                         }
426                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
427                 }
428
429                 msg_size = pos.y;
430                 for(k = 0; k < n; ++k)
431                 {
432                         getWrappedLine_remaining = argv(k);
433
434                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
435                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
436                         if (is_bold)
437                                 getWrappedLine_remaining = substring(getWrappedLine_remaining, 5, -1);
438
439                         while(getWrappedLine_remaining)
440                         {
441                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
442                                 if (ts != "")
443                                 {
444                                         if (align)
445                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
446                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
447                                                 if (is_bold) draw_beginBoldFont();
448                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
449                                                 if (is_bold) draw_endBoldFont();
450                                         pos.y += fontsize.y;
451                                 }
452                                 else
453                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
454                         }
455                 }
456
457                 ++g; // move next position number up
458
459                 msg_size = pos.y - msg_size;
460
461                 if (autocvar_hud_panel_centerprint_flip)
462                 {
463                         pos.y -= msg_size + CENTERPRINT_SPACING * cp_fontsize.y;
464                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
465                                 pos.y += (1 - sqrt(a));
466
467                         if (pos.y < panel_pos.y) // check if the next message can be shown
468                         {
469                                 drawfontscale = hud_scale;
470                                 return;
471                         }
472                 }
473                 else
474                 {
475                         pos.y += CENTERPRINT_SPACING * cp_fontsize.y;
476                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
477                                 pos.y -= (1 - sqrt(a));
478
479                         if(pos.y > panel_pos.y + panel_size.y - cp_fontsize.y) // check if the next message can be shown
480                         {
481                                 drawfontscale = hud_scale;
482                                 return;
483                         }
484                 }
485         }
486
487         drawfontscale = hud_scale;
488         if (all_messages_expired)
489         {
490                 centerprint_showing = false;
491                 centerprint_KillAll();
492         }
493 }