qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <common/notifications/all.qh>
   6
   7 // CenterPrint (#16)
   8
   9 void HUD_CenterPrint_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_centerprint_align");
  13         HUD_Write_Cvar("hud_panel_centerprint_flip");
  14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
  15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
  16         HUD_Write_Cvar("hud_panel_centerprint_time");
  17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
  18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
  19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
  20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
  21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
  22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
  23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
  24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
  25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
  26 }
  27
  28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
  29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
  30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
  31 // by Local_Notification.
  32 // HUD_CenterPrint draws all the messages on screen
  33
  34 const int CENTERPRINT_MAX_MSGS = 10;
  35 const int CENTERPRINT_MAX_ENTRIES = 50;
  36 const float CENTERPRINT_SPACING = 0.5;
  37 const float CENTERPRINT_TITLE_SPACING = 1;
  38 int cpm_index;
  39 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  40 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  41 float centerprint_time[CENTERPRINT_MAX_MSGS];
  42 float centerprint_start_time[CENTERPRINT_MAX_MSGS];
  43 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  44 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  45 bool centerprint_showing;
  46
  47 bool centerprint_title_show;
  48 string centerprint_title;
  49
  50 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
  51 {
  52         TC(int, new_id); TC(int, countdown_num);
  53         LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
  54         int i, j;
  55
  56         if(strMessage == "" && new_id == 0)
  57                 return;
  58
  59         // strip trailing newlines
  60         j = strlen(strMessage) - 1;
  61         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  62                 --j;
  63         if (j < strlen(strMessage) - 1)
  64                 strMessage = substring(strMessage, 0, j + 1);
  65
  66         if(strMessage == "" && new_id == 0)
  67                 return;
  68
  69         // strip leading newlines
  70         j = 0;
  71         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  72                 ++j;
  73         if (j > 0)
  74                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  75
  76         if(strMessage == "" && new_id == 0)
  77                 return;
  78
  79         if (!centerprint_showing)
  80                 centerprint_showing = true;
  81
  82         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  83         {
  84                 if (j == CENTERPRINT_MAX_MSGS)
  85                         j = 0;
  86                 if (new_id && new_id == centerprint_msgID[j])
  87                 {
  88                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
  89                         {
  90                                 // fade out the current msg (duration and countdown_num are ignored)
  91                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  92                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
  93                                 return;
  94                         }
  95                         break; // found a msg with the same id, at position j
  96                 }
  97         }
  98
  99         if (i == CENTERPRINT_MAX_MSGS)
 100         {
 101                 // a msg with the same id was not found, add the msg at the next position
 102                 --cpm_index;
 103                 if (cpm_index == -1)
 104                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
 105                 j = cpm_index;
 106         }
 107         strcpy(centerprint_messages[j], strMessage);
 108         centerprint_start_time[j] = time;
 109         centerprint_msgID[j] = new_id;
 110         if (duration < 0)
 111         {
 112                 centerprint_time[j] = -1;
 113                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 114         }
 115         else
 116         {
 117                 if(duration == 0)
 118                         duration = max(1, autocvar_hud_panel_centerprint_time);
 119                 centerprint_time[j] = duration;
 120                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 121         }
 122         centerprint_countdown_num[j] = countdown_num;
 123 }
 124
 125 void centerprint_Kill(int id)
 126 {
 127         TC(int, id);
 128         centerprint_Add(id, "", 0, 0);
 129 }
 130
 131 void centerprint_AddStandard(string strMessage)
 132 {
 133         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 134 }
 135
 136 void centerprint_KillAll()
 137 {
 138         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 139         {
 140                 centerprint_start_time[i] = 0;
 141                 centerprint_expire_time[i] = 0;
 142                 centerprint_time[i] = 1;
 143                 centerprint_msgID[i] = 0;
 144                 strfree(centerprint_messages[i]);
 145         }
 146 }
 147
 148 void centerprint_ClearTitle()
 149 {
 150         strfree(centerprint_title);
 151         centerprint_title_show = false;
 152 }
 153
 154 void centerprint_SetTitle(string title)
 155 {
 156         if(title != centerprint_title) {
 157                 if(centerprint_title)
 158                         strfree(centerprint_title);
 159
 160                 centerprint_title = strzone(title);
 161                 centerprint_title_show = true;
 162         }
 163 }
 164
 165 float hud_configure_cp_generation_time;
 166 void HUD_CenterPrint()
 167 {
 168         if(!autocvar__hud_configure)
 169         {
 170                 if(!autocvar_hud_panel_centerprint) return;
 171
 172                 if(hud_configure_prev) {
 173                         centerprint_ClearTitle();
 174                         centerprint_KillAll();
 175                 }
 176         }
 177         else
 178         {
 179                 if(!hud_configure_prev)
 180                 {
 181                         centerprint_KillAll();
 182                         hud_configure_cp_generation_time = time; // show a message immediately
 183                 }
 184                 if (time > hud_configure_cp_generation_time)
 185                 {
 186                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 187                         {
 188                                 centerprint_SetTitle(strcat("test", ftos(hud_configure_cp_generation_time)));
 189
 190                                 float r;
 191                                 r = random();
 192                                 if (r > 0.8)
 193                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
 194                                 else if (r > 0.55)
 195                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^BOLDlasts longer than normal"), seconds_tostring(time)), 20, 0);
 196                                 else
 197                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
 198                                 //hud_configure_cp_generation_time = time + 1 + random()*4;
 199                                 hud_configure_cp_generation_time = time + 1;
 200                         }
 201                         else
 202                         {
 203                                 centerprint_Add(0, _("Generic message"), 10, 0);
 204                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 205                         }
 206                 }
 207         }
 208
 209         HUD_Panel_LoadCvars();
 210
 211         if ( HUD_Radar_Clickable() )
 212         {
 213                 if (hud_panel_radar_bottom >= vid_conheight)
 214                         return;
 215
 216                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
 217                 panel_pos.y = hud_panel_radar_bottom;
 218                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
 219         }
 220         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
 221         {
 222                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
 223                 if(target_pos.y > panel_pos.y)
 224                 {
 225                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 226                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 227                 }
 228
 229                 // move the panel below the scoreboard
 230                 if (panel_pos.y >= vid_conheight)
 231                         return;
 232         }
 233
 234         if (autocvar_hud_panel_centerprint_dynamichud)
 235                 HUD_Scale_Enable();
 236         else
 237                 HUD_Scale_Disable();
 238         HUD_Panel_DrawBg();
 239
 240         if (!centerprint_showing)
 241                 return;
 242
 243         if(panel_bg_padding)
 244         {
 245                 panel_pos += '1 1 0' * panel_bg_padding;
 246                 panel_size -= '2 2 0' * panel_bg_padding;
 247         }
 248
 249         int i, j, k, n, g;
 250         float a = 1, sz, align, current_msg_posY = 0, msg_size;
 251         vector pos;
 252         string ts = "";
 253         bool all_messages_expired = true;
 254
 255         pos = panel_pos;
 256         if (autocvar_hud_panel_centerprint_flip)
 257                 pos.y += panel_size.y;
 258         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 259
 260         // Show title if available
 261         if(centerprint_title_show) {
 262                 vector fontsize = hud_fontsize * autocvar_hud_panel_centerprint_fontscale_title;
 263
 264                 pos.x = panel_pos.x + (panel_size.x - stringwidth(centerprint_title, true, fontsize)) * align;
 265                 drawcolorcodedstring(pos, centerprint_title, fontsize, 1, DRAWFLAG_NORMAL);
 266
 267                 if (autocvar_hud_panel_centerprint_flip)
 268                         pos.y -= fontsize.y + CENTERPRINT_TITLE_SPACING;
 269                 else
 270                         pos.y += fontsize.y + CENTERPRINT_TITLE_SPACING;
 271
 272                 all_messages_expired = false;
 273         }
 274
 275         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 276         {
 277                 if (j == CENTERPRINT_MAX_MSGS)
 278                         j = 0;
 279                 if (centerprint_expire_time[j] == -1)
 280                 {
 281                         // here we are sure the time variable is not altered by CSQC_Ent_Update
 282                         centerprint_expire_time[j] = time;
 283                         if (centerprint_time[j] > 0)
 284                                 centerprint_expire_time[j] += centerprint_time[j];
 285                 }
 286                 if (centerprint_expire_time[j] <= time)
 287                 {
 288                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
 289                         {
 290                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 291                                 if (centerprint_countdown_num[j] == 0)
 292                                         continue;
 293                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 294                         }
 295                         else if(centerprint_time[j] != -1)
 296                                 continue;
 297                 }
 298
 299                 all_messages_expired = false;
 300
 301                 if (time < centerprint_start_time[j]) continue;
 302
 303                 float fade_in_time = autocvar_hud_panel_centerprint_fade_in;
 304                 float fade_out_time = autocvar_hud_panel_centerprint_fade_out;
 305
 306                 if (centerprint_countdown_num[j]) {
 307                         fade_in_time = autocvar_hud_panel_centerprint_fade_in_short;
 308                         fade_out_time = 0;
 309                 }
 310
 311                 // fade
 312                 if(fade_in_time && centerprint_start_time[j] && time < centerprint_start_time[j] + fade_in_time) // Fade in
 313                         a = (time - centerprint_start_time[j]) / fade_in_time;
 314                 else if(time < centerprint_expire_time[j] - fade_out_time || centerprint_time[j] < 0) // Regularily printed or forced
 315                         a = 1;
 316                 else if(fade_out_time) // Expiring soon, so fade it out.
 317                         a = (centerprint_expire_time[j] - time) / fade_out_time;
 318
 319                 if(centerprint_msgID[j] == ORDINAL(CPID_TIMEIN))
 320                         a = 1;
 321
 322                 // while counting down show it anyway in order to hold the current message position
 323                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 324                         continue;
 325
 326                 // set the size from fading in/out before subsequent fading
 327                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 328
 329                 // also fade it based on positioning
 330                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 331                 {
 332                         // pass one: all messages after the first have half alpha
 333                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 334                         // pass two: after that, gradually lower alpha even more for each message
 335                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 336                 }
 337                 a *= panel_fg_alpha;
 338
 339                 // finally set the size based on the new alpha from subsequent fading
 340                 // TODO: Apply this only if subsequent, otherwise it fucks it up
 341                 if(g)
 342                         sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
 343                 drawfontscale = hud_scale * sz;
 344
 345                 if (centerprint_countdown_num[j])
 346                         n = tokenizebyseparator(strreplace("^COUNT", ftos(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 347                 else
 348                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 349
 350                 if (autocvar_hud_panel_centerprint_flip)
 351                 {
 352                         // check if the message can be entirely shown
 353                         for(k = 0; k < n; ++k)
 354                         {
 355                                 getWrappedLine_remaining = argv(k);
 356                                 while(getWrappedLine_remaining)
 357                                 {
 358                                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 359                                         vector fontsize = hud_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 360
 361                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 362                                         if (ts != "")
 363                                                 pos.y -= fontsize.y;
 364                                         else
 365                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 366                                 }
 367                         }
 368                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 369                 }
 370
 371                 msg_size = pos.y;
 372                 for(k = 0; k < n; ++k)
 373                 {
 374                         getWrappedLine_remaining = argv(k);
 375
 376                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 377                         vector fontsize = hud_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 378                         if (is_bold)
 379                                 getWrappedLine_remaining = substring(getWrappedLine_remaining, 5, -1);
 380
 381                         while(getWrappedLine_remaining)
 382                         {
 383                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 384                                 if (ts != "")
 385                                 {
 386                                         if (align)
 387                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 388                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 389                                                 if (is_bold) draw_beginBoldFont();
 390                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 391                                                 if (is_bold) draw_endBoldFont();
 392                                         pos.y += fontsize.y;
 393                                 }
 394                                 else
 395                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 396                         }
 397                 }
 398
 399                 ++g; // move next position number up
 400
 401                 msg_size = pos.y - msg_size;
 402
 403                 if (autocvar_hud_panel_centerprint_flip)
 404                 {
 405                         pos.y -= msg_size + CENTERPRINT_SPACING * hud_fontsize.y;
 406                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 407                                 pos.y += (1 - sqrt(a));
 408
 409                         if (pos.y < panel_pos.y) // check if the next message can be shown
 410                         {
 411                                 drawfontscale = hud_scale;
 412                                 return;
 413                         }
 414                 }
 415                 else
 416                 {
 417                         pos.y += CENTERPRINT_SPACING * hud_fontsize.y;
 418                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 419                                 pos.y -= (1 - sqrt(a));
 420
 421                         if(pos.y > panel_pos.y + panel_size.y - hud_fontsize.y) // check if the next message can be shown
 422                         {
 423                                 drawfontscale = hud_scale;
 424                                 return;
 425                         }
 426                 }
 427         }
 428
 429         drawfontscale = hud_scale;
 430         if (all_messages_expired)
 431         {
 432                 centerprint_showing = false;
 433                 centerprint_KillAll();
 434         }
 435 }