qcsrc/client/hud/panel/centerprint.qc

   1 #include "centerprint.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/panel/scoreboard.qh>
   5 #include <common/notifications/all.qh>
   6
   7 // CenterPrint (#16)
   8
   9 void HUD_CenterPrint_Export(int fh)
  10 {
  11         // allow saving cvars that aesthetically change the panel into hud skin files
  12         HUD_Write_Cvar("hud_panel_centerprint_align");
  13         HUD_Write_Cvar("hud_panel_centerprint_flip");
  14         HUD_Write_Cvar("hud_panel_centerprint_fontscale");
  15         HUD_Write_Cvar("hud_panel_centerprint_fontscale_bold");
  16         HUD_Write_Cvar("hud_panel_centerprint_time");
  17         HUD_Write_Cvar("hud_panel_centerprint_fade_in");
  18         HUD_Write_Cvar("hud_panel_centerprint_fade_out");
  19         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent");
  20         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone");
  21         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passone_minalpha");
  22         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo");
  23         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_passtwo_minalpha");
  24         HUD_Write_Cvar("hud_panel_centerprint_fade_subsequent_minfontsize");
  25         HUD_Write_Cvar("hud_panel_centerprint_fade_minfontsize");
  26 }
  27
  28 // These are the functions that draw the text at the center of the screen (e.g. frag messages and server MOTD).
  29 // centerprint_Add parses a message and puts it in the circular buffer centerprint_messages
  30 // centerprint_Add is usually called by Local_Notification_centerprint_Add, which is called
  31 // by Local_Notification.
  32 // HUD_CenterPrint draws all the messages on screen
  33
  34 const int CENTERPRINT_MAX_MSGS = 10;
  35 const int CENTERPRINT_MAX_ENTRIES = 50;
  36 const float CENTERPRINT_BASE_SIZE = 1.3;
  37 const float CENTERPRINT_SPACING = 0.3;
  38 const float CENTERPRINT_TITLE_SPACING = 0.35;
  39 int cpm_index;
  40 string centerprint_messages[CENTERPRINT_MAX_MSGS];
  41 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
  42 float centerprint_time[CENTERPRINT_MAX_MSGS];
  43 float centerprint_start_time[CENTERPRINT_MAX_MSGS];
  44 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
  45 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
  46 bool centerprint_showing;
  47
  48 string centerprint_title;
  49 string centerprint_title_left;
  50 string centerprint_title_right;
  51
  52 void centerprint_Add(int new_id, string strMessage, float duration, int countdown_num)
  53 {
  54         TC(int, new_id); TC(int, countdown_num);
  55         //LOG_INFOF("centerprint_Add: ^2id: %d ^3dur: %d ^5countdown: %d\n'%s'", new_id, duration, countdown_num, strreplace("\n", "^7\\n^7", strMessage));
  56         int i, j;
  57
  58         if(strMessage == "" && new_id == 0)
  59                 return;
  60
  61         // strip trailing newlines
  62         j = strlen(strMessage) - 1;
  63         while(substring(strMessage, j, 1) == "\n" && j >= 0)
  64                 --j;
  65         if (j < strlen(strMessage) - 1)
  66                 strMessage = substring(strMessage, 0, j + 1);
  67
  68         if(strMessage == "" && new_id == 0)
  69                 return;
  70
  71         // strip leading newlines
  72         j = 0;
  73         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
  74                 ++j;
  75         if (j > 0)
  76                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
  77
  78         if(strMessage == "" && new_id == 0)
  79                 return;
  80
  81         if (!centerprint_showing)
  82                 centerprint_showing = true;
  83
  84         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
  85         {
  86                 if (j == CENTERPRINT_MAX_MSGS)
  87                         j = 0;
  88                 if (new_id && new_id == centerprint_msgID[j])
  89                 {
  90                         if (strMessage == "" && centerprint_messages[j] != "")
  91                         {
  92                                 // fade out the current msg (duration and countdown_num are ignored)
  93                                 centerprint_start_time[j] = 0;
  94                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
  95                                 centerprint_expire_time[j] = -1; // don't use the variable time here!
  96                                 return;
  97                         }
  98                         break; // found a msg with the same id, at position j
  99                 }
 100         }
 101
 102         if (strMessage == "")
 103                 return;
 104
 105         if (i == CENTERPRINT_MAX_MSGS)
 106         {
 107                 // a msg with the same id was not found, add the msg at the next position
 108                 --cpm_index;
 109                 if (cpm_index == -1)
 110                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
 111                 j = cpm_index;
 112         }
 113         strcpy(centerprint_messages[j], strMessage);
 114         centerprint_start_time[j] = time;
 115         centerprint_msgID[j] = new_id;
 116         if (duration < 0)
 117         {
 118                 centerprint_time[j] = -1;
 119                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 120         }
 121         else
 122         {
 123                 if(duration == 0)
 124                         duration = max(1, autocvar_hud_panel_centerprint_time);
 125                 centerprint_time[j] = duration;
 126                 centerprint_expire_time[j] = -1; // don't use the variable time here!
 127         }
 128         centerprint_countdown_num[j] = countdown_num;
 129 }
 130
 131 void centerprint_Kill(int id)
 132 {
 133         TC(int, id);
 134         centerprint_Add(id, "", 0, 0);
 135 }
 136
 137 void centerprint_AddStandard(string strMessage)
 138 {
 139         centerprint_Add(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
 140 }
 141
 142 void centerprint_KillAll()
 143 {
 144         for (int i=0; i<CENTERPRINT_MAX_MSGS; ++i)
 145         {
 146                 centerprint_start_time[i] = 0;
 147                 centerprint_expire_time[i] = 0;
 148                 centerprint_time[i] = 1;
 149                 centerprint_msgID[i] = 0;
 150                 strfree(centerprint_messages[i]);
 151         }
 152 }
 153
 154 void centerprint_SetDuelTitle(string left, string right, string div)
 155 {
 156         strcpy(centerprint_title_left, left);
 157         strcpy(centerprint_title_right, right);
 158         centerprint_SetTitle(sprintf("^BG%s^BG  %s  %s", left, div, right));
 159 }
 160
 161 void centerprint_SetTitle(string title)
 162 {
 163         if(title != centerprint_title)
 164                 strcpy(centerprint_title, CCR(title));
 165 }
 166
 167 void centerprint_ClearTitle()
 168 {
 169         strfree(centerprint_title);
 170         strfree(centerprint_title_left);
 171         strfree(centerprint_title_right);
 172 }
 173
 174 float hud_configure_cp_generation_time;
 175 void HUD_CenterPrint()
 176 {
 177         if(!autocvar__hud_configure)
 178         {
 179                 if(!autocvar_hud_panel_centerprint) return;
 180
 181                 if(hud_configure_prev) {
 182                         centerprint_ClearTitle();
 183                         centerprint_KillAll();
 184                 }
 185         }
 186         else
 187         {
 188                 if(!hud_configure_prev)
 189                 {
 190                         centerprint_KillAll();
 191                         hud_configure_cp_generation_time = time; // show a message immediately
 192                 }
 193                 if (time > hud_configure_cp_generation_time)
 194                 {
 195                         if(highlightedPanel == HUD_PANEL(CENTERPRINT))
 196                         {
 197                                 centerprint_SetTitle(sprintf(_("Title at %s"), seconds_tostring(hud_configure_cp_generation_time)));
 198
 199                                 float r;
 200                                 r = random();
 201                                 if (r > 0.8)
 202                                         centerprint_Add(floor(r*1000), sprintf(_("^3Countdown message at time %s, seconds left: ^COUNT"), seconds_tostring(time)), 1, 10);
 203                                 else if (r > 0.55)
 204                                         centerprint_Add(0, sprintf(_("^1Multiline message at time %s that\n^BOLDlasts longer than normal"), seconds_tostring(time)), 20, 0);
 205                                 else
 206                                         centerprint_AddStandard(sprintf(_("Message at time %s"), seconds_tostring(time)));
 207                                 hud_configure_cp_generation_time = time + 1 + random()*4;
 208                         }
 209                         else
 210                         {
 211                                 centerprint_Add(0, _("Generic message"), 10, 0);
 212                                 hud_configure_cp_generation_time = time + 10 - random()*3;
 213                         }
 214                 }
 215         }
 216
 217         HUD_Panel_LoadCvars();
 218
 219         if ( HUD_Radar_Clickable() )
 220         {
 221                 if (hud_panel_radar_bottom >= vid_conheight)
 222                         return;
 223
 224                 panel_pos.x = 0.5 * (vid_conwidth - panel_size.x);
 225                 panel_pos.y = hud_panel_radar_bottom;
 226                 panel_size.y = min(panel_size.y, vid_conheight - hud_panel_radar_bottom);
 227         }
 228         else if(!autocvar__hud_configure && scoreboard_fade_alpha)
 229         {
 230                 vector target_pos = vec2(0.5 * (vid_conwidth - panel_size.x), scoreboard_bottom);
 231                 if(target_pos.y > panel_pos.y)
 232                 {
 233                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
 234                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
 235                 }
 236
 237                 // move the panel below the scoreboard
 238                 if (panel_pos.y >= vid_conheight)
 239                         return;
 240         }
 241
 242         if (autocvar_hud_panel_centerprint_dynamichud)
 243                 HUD_Scale_Enable();
 244         else
 245                 HUD_Scale_Disable();
 246         HUD_Panel_DrawBg();
 247
 248         if (!centerprint_showing)
 249                 return;
 250
 251         if(panel_bg_padding)
 252         {
 253                 panel_pos += '1 1 0' * panel_bg_padding;
 254                 panel_size -= '2 2 0' * panel_bg_padding;
 255         }
 256
 257         int i, j, k, n, g;
 258         float a = 1, sz, align, current_msg_posY = 0, msg_size;
 259         vector pos;
 260         vector cp_fontsize = hud_fontsize * CENTERPRINT_BASE_SIZE;
 261         string ts = "";
 262         bool all_messages_expired = true;
 263
 264         pos = panel_pos;
 265         if (autocvar_hud_panel_centerprint_flip)
 266                 pos.y += panel_size.y;
 267         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
 268
 269         // Show title if available
 270         if(centerprint_title) {
 271                 vector fontsize = cp_fontsize * autocvar_hud_panel_centerprint_fontscale_title;
 272                 float width = stringwidth(centerprint_title, true, fontsize);
 273
 274                 pos.x = panel_pos.x + (panel_size.x - width) * align;
 275
 276                 if (autocvar_hud_panel_centerprint_flip)
 277                         pos.y -= fontsize.y;
 278                 if (centerprint_title_left != "" && align == 0.5) // Center line at the main word (for duels)
 279                         pos.x += (stringwidth(centerprint_title_right, true, fontsize) - stringwidth(centerprint_title_left, true, fontsize)) / 2;
 280
 281                 drawcolorcodedstring(pos, centerprint_title, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 282
 283                 if (autocvar_hud_panel_centerprint_flip)
 284                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 285                 else
 286                         pos.y += fontsize.y + (hud_fontsize.y * CENTERPRINT_TITLE_SPACING);
 287
 288                 drawfill(pos, vec2(width, 1), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 289
 290                 if (autocvar_hud_panel_centerprint_flip)
 291                         pos.y -= cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 292                 else
 293                         pos.y += cp_fontsize.y * CENTERPRINT_TITLE_SPACING;
 294
 295                 all_messages_expired = false;
 296         }
 297
 298         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
 299         {
 300                 if (j == CENTERPRINT_MAX_MSGS)
 301                         j = 0;
 302                 if (centerprint_expire_time[j] == -1)
 303                 {
 304                         // here we are sure the time variable is not altered by CSQC_Ent_Update
 305                         centerprint_expire_time[j] = time;
 306                         if (centerprint_time[j] > 0)
 307                                 centerprint_expire_time[j] += centerprint_time[j];
 308                 }
 309                 if (centerprint_expire_time[j] <= time)
 310                 {
 311                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0 && centerprint_start_time[j])
 312                         {
 313                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
 314                                 if (centerprint_countdown_num[j] == 0)
 315                                         continue;
 316                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
 317                         }
 318                         else if(centerprint_time[j] != -1)
 319                                 continue;
 320                 }
 321
 322                 all_messages_expired = false;
 323
 324                 if (time < centerprint_start_time[j]) continue;
 325
 326                 float fade_in_time = autocvar_hud_panel_centerprint_fade_in;
 327                 float fade_out_time = autocvar_hud_panel_centerprint_fade_out;
 328
 329                 if (centerprint_countdown_num[j] && centerprint_start_time[j]) {
 330                         fade_in_time = 0;
 331                         fade_out_time = 0;
 332                 }
 333
 334                 // fade
 335                 if(fade_in_time && centerprint_start_time[j] && time < centerprint_start_time[j] + fade_in_time) // Fade in
 336                         a = (time - centerprint_start_time[j]) / fade_in_time;
 337                 else if(time < centerprint_expire_time[j] - fade_out_time || centerprint_time[j] < 0) // Regularily printed or forced
 338                         a = 1;
 339                 else if(fade_out_time) // Expiring soon, so fade it out.
 340                         a = (centerprint_expire_time[j] - time) / fade_out_time;
 341
 342                 if(centerprint_msgID[j] == ORDINAL(CPID_TIMEIN))
 343                         a = 1;
 344
 345                 // while counting down show it anyway in order to hold the current message position
 346                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
 347                         continue;
 348
 349                 // also fade it based on positioning
 350                 if(autocvar_hud_panel_centerprint_fade_subsequent)
 351                 {
 352                         // pass one: all messages after the first have half alpha
 353                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1);
 354                         // pass two: after that, gradually lower alpha even more for each message
 355                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1);
 356                 }
 357                 a *= panel_fg_alpha;
 358
 359                 // finally set the size based on the alpha
 360                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
 361                 drawfontscale = hud_scale * sz;
 362
 363                 if (centerprint_countdown_num[j])
 364                         n = tokenizebyseparator(strreplace("^COUNT", ftos(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
 365                 else
 366                         n = tokenizebyseparator(centerprint_messages[j], "\n");
 367
 368                 if (autocvar_hud_panel_centerprint_flip)
 369                 {
 370                         // check if the message can be entirely shown
 371                         for(k = 0; k < n; ++k)
 372                         {
 373                                 getWrappedLine_remaining = argv(k);
 374                                 while(getWrappedLine_remaining)
 375                                 {
 376                                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 377                                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 378
 379                                         ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 380                                         if (ts != "")
 381                                                 pos.y -= fontsize.y;
 382                                         else
 383                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
 384                                 }
 385                         }
 386                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
 387                 }
 388
 389                 msg_size = pos.y;
 390                 for(k = 0; k < n; ++k)
 391                 {
 392                         getWrappedLine_remaining = argv(k);
 393
 394                         bool is_bold = (substring(getWrappedLine_remaining, 0, 5) == BOLD_OPERATOR);
 395                         vector fontsize = cp_fontsize * (is_bold ? autocvar_hud_panel_centerprint_fontscale_bold : autocvar_hud_panel_centerprint_fontscale);
 396                         if (is_bold)
 397                                 getWrappedLine_remaining = substring(getWrappedLine_remaining, 5, -1);
 398
 399                         while(getWrappedLine_remaining)
 400                         {
 401                                 ts = getWrappedLine(panel_size.x * hud_scale.x * sz, fontsize, stringwidth_colors);
 402                                 if (ts != "")
 403                                 {
 404                                         if (align)
 405                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize) * sz) * align;
 406                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
 407                                                 if (is_bold) draw_beginBoldFont();
 408                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz * hud_scale.x) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
 409                                                 if (is_bold) draw_endBoldFont();
 410                                         pos.y += fontsize.y;
 411                                 }
 412                                 else
 413                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
 414                         }
 415                 }
 416
 417                 ++g; // move next position number up
 418
 419                 msg_size = pos.y - msg_size;
 420
 421                 if (autocvar_hud_panel_centerprint_flip)
 422                 {
 423                         pos.y -= msg_size + CENTERPRINT_SPACING * cp_fontsize.y;
 424                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 425                                 pos.y += (1 - sqrt(a));
 426
 427                         if (pos.y < panel_pos.y) // check if the next message can be shown
 428                         {
 429                                 drawfontscale = hud_scale;
 430                                 return;
 431                         }
 432                 }
 433                 else
 434                 {
 435                         pos.y += CENTERPRINT_SPACING * cp_fontsize.y;
 436                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
 437                                 pos.y -= (1 - sqrt(a));
 438
 439                         if(pos.y > panel_pos.y + panel_size.y - cp_fontsize.y) // check if the next message can be shown
 440                         {
 441                                 drawfontscale = hud_scale;
 442                                 return;
 443                         }
 444                 }
 445         }
 446
 447         drawfontscale = hud_scale;
 448         if (all_messages_expired)
 449         {
 450                 centerprint_showing = false;
 451                 centerprint_KillAll();
 452         }
 453 }