qcsrc/client/hud/panel/pressedkeys.qc

   1 #include "pressedkeys.qh"
   2
   3
   4 // Pressed keys (#11)
   5
   6 void HUD_PressedKeys()
   7 {
   8         if(!autocvar__hud_configure)
   9         {
  10                 if(!autocvar_hud_panel_pressedkeys) return;
  11                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
  12         }
  13
  14         HUD_Panel_LoadCvars();
  15         vector pos, mySize;
  16         pos = panel_pos;
  17         mySize = panel_size;
  18
  19         if (autocvar_hud_panel_pressedkeys_dynamichud)
  20                 HUD_Scale_Enable();
  21         else
  22                 HUD_Scale_Disable();
  23         HUD_Panel_DrawBg();
  24         if(panel_bg_padding)
  25         {
  26                 pos += '1 1 0' * panel_bg_padding;
  27                 mySize -= '2 2 0' * panel_bg_padding;
  28         }
  29
  30         // force custom aspect
  31         float aspect = autocvar_hud_panel_pressedkeys_aspect;
  32         if(aspect)
  33         {
  34                 vector newSize = '0 0 0';
  35                 if(mySize.x/mySize.y > aspect)
  36                 {
  37                         newSize.x = aspect * mySize.y;
  38                         newSize.y = mySize.y;
  39
  40                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
  41                 }
  42                 else
  43                 {
  44                         newSize.y = 1/aspect * mySize.x;
  45                         newSize.x = mySize.x;
  46
  47                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
  48                 }
  49                 mySize = newSize;
  50         }
  51
  52         vector keysize = vec2(mySize.x / 3, mySize.y / (3 - !autocvar_hud_panel_pressedkeys_attack));
  53         int pressedkeys = STAT(PRESSED_KEYS);
  54
  55         if(autocvar_hud_panel_pressedkeys_attack)
  56         {
  57                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  58                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  59                 pos.y += keysize.y;
  60         }
  61
  62         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  63         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  64         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  65         pos.y += keysize.y;
  66         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  67         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  68         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  69 }