qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2 // QuickMenu (#23)
   3
   4 #include <common/ent_cs.qh>
   5 #include <client/hud/all.qh>
   6 #include <client/mapvoting.qh>
   7
   8 // QUICKMENU_MAXLINES must be <= 10
   9 const int QUICKMENU_MAXLINES = 10;
  10 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  11 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  12 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  13 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  14 int QuickMenu_Page_Entries;
  15 int QuickMenu_Page;
  16 int QuickMenu_Page_ActivatedEntry = -1;
  17 bool QuickMenu_Page_ActivatedEntry_Close;
  18 float QuickMenu_Page_ActivatedEntry_Time;
  19 bool QuickMenu_IsLastPage;
  20 // all the entries are loaded into QuickMenu_Buffer
  21 // each entry (submenu or command) is composed of 2 entries
  22 const int QUICKMENU_MAXENTRIES = 256;
  23 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  24 int QuickMenu_Buffer = -1;
  25 int QuickMenu_Buffer_Size;
  26 int QuickMenu_Buffer_Index;
  27 string QuickMenu_CurrentSubMenu;
  28 float QuickMenu_TimeOut;
  29
  30 // QuickMenu_Buffer are labeled with these tags
  31 #define QM_TAG_TITLE "T"
  32 #define QM_TAG_SUBMENU "S"
  33 #define QM_TAG_COMMAND "C"
  34 #define QM_TAG_PLCOMMAND "P"
  35
  36 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  37 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  38
  39 // if s1 is not empty s will be displayed as command otherwise as submenu
  40 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  41 {
  42     TC(int, i);
  43         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  44         if (QuickMenu_Page_Description[i])
  45                 strunzone(QuickMenu_Page_Description[i]);
  46         QuickMenu_Page_Description[i] = strzone(s);
  47         if (QuickMenu_Page_Command[i])
  48                 strunzone(QuickMenu_Page_Command[i]);
  49         QuickMenu_Page_Command[i] = strzone(s1);
  50 }
  51
  52 void QuickMenu_Page_ClearEntry(int i)
  53 {
  54     TC(int, i);
  55         if (QuickMenu_Page_Description[i])
  56                 strunzone(QuickMenu_Page_Description[i]);
  57         QuickMenu_Page_Description[i] = string_null;
  58         if (QuickMenu_Page_Command[i])
  59                 strunzone(QuickMenu_Page_Command[i]);
  60         QuickMenu_Page_Command[i] = string_null;
  61         QuickMenu_Page_Command_Type[i] = 0;
  62 }
  63
  64 float QuickMenu_Page_Load(string target_submenu, float new_page);
  65 void QuickMenu_Default(string submenu);
  66 bool QuickMenu_Open(string mode, string submenu)
  67 {
  68         int fh = -1;
  69         string s;
  70
  71         if(mode == "")
  72         {
  73                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  74                         mode = "default";
  75                 else
  76                         mode = "file";
  77         }
  78
  79         if(mode == "file")
  80         {
  81                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  82                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  83                 else
  84                 {
  85                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  86                         if(fh < 0)
  87                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  88                 }
  89                 if(fh < 0)
  90                         mode = "default";
  91         }
  92
  93         if(mode == "default")
  94         {
  95                 QuickMenu_Buffer = buf_create();
  96                 if(QuickMenu_Buffer < 0)
  97                         return false;
  98
  99                 QuickMenu_Default(submenu);
 100         }
 101         else if(mode == "file")
 102         {
 103                 QuickMenu_Buffer = buf_create();
 104                 if(QuickMenu_Buffer < 0)
 105                 {
 106                         fclose(fh);
 107                         return false;
 108                 }
 109
 110                 QuickMenu_Buffer_Size = 0;
 111                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 112                 {
 113                         // first skip invalid entries, so we don't check them anymore
 114                         float argc;
 115                         argc = tokenize_console(s);
 116                         if(argc == 0 || argv(0) == "")
 117                                 continue;
 118                         if(argc == 1)
 119                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 120                         else if(argc == 2)
 121                         {
 122                                 if(argv(1) == "")
 123                                         continue;
 124                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 125                                 ++QuickMenu_Buffer_Size;
 126                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 127                         }
 128                         else if(argc == 3)
 129                         {
 130                                 // check for special keywords
 131                                 float teamplayers = 0, without_me = 0;
 132                                 switch(argv(2))
 133                                 {
 134                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 135                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 136                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 137                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 138                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 139                                         default: continue;
 140                                 }
 141
 142                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 143                                 {
 144                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 145                                         ++QuickMenu_Buffer_Size;
 146                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 147                                         ++QuickMenu_Buffer_Size;
 148                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 149                                         ++QuickMenu_Buffer_Size;
 150                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 151                                 }
 152                         }
 153                         ++QuickMenu_Buffer_Size;
 154                 }
 155                 fclose(fh);
 156         }
 157         else
 158         {
 159                 LOG_WARNF("Unrecognized mode %s", mode);
 160                 return false;
 161         }
 162
 163         if (QuickMenu_Buffer_Size <= 0)
 164         {
 165                 buf_del(QuickMenu_Buffer);
 166                 QuickMenu_Buffer = -1;
 167                 return false;
 168         }
 169
 170         if(mode == "file")
 171                 QuickMenu_Page_Load(submenu, 0);
 172         else
 173                 QuickMenu_Page_Load("", 0);
 174
 175         hud_panel_quickmenu = 1;
 176         if(autocvar_hud_cursormode)
 177                 setcursormode(1);
 178         hudShiftState = 0;
 179
 180         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 181         return true;
 182 }
 183
 184 void QuickMenu_Buffer_Close()
 185 {
 186         if (QuickMenu_Buffer >= 0)
 187         {
 188                 buf_del(QuickMenu_Buffer);
 189                 QuickMenu_Buffer = -1;
 190                 QuickMenu_Buffer_Size = 0;
 191         }
 192 }
 193
 194 void QuickMenu_Close()
 195 {
 196         if (QuickMenu_CurrentSubMenu)
 197                 strunzone(QuickMenu_CurrentSubMenu);
 198         QuickMenu_CurrentSubMenu = string_null;
 199         int i;
 200         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 201                 QuickMenu_Page_ClearEntry(i);
 202         QuickMenu_Page_Entries = 0;
 203         hud_panel_quickmenu = 0;
 204         mouseClicked = 0;
 205         prevMouseClicked = 0;
 206         QuickMenu_Buffer_Close();
 207
 208         if(autocvar_hud_cursormode)
 209         if(!mv_active)
 210                 setcursormode(0);
 211 }
 212
 213 // It assumes submenu open tag is already detected
 214 void QuickMenu_skip_submenu(string submenu)
 215 {
 216         string s, z_submenu;
 217         z_submenu = strzone(submenu);
 218         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 219         {
 220                 s = QuickMenu_Buffer_Get();
 221                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 222                         continue;
 223                 if(substring(s, 1, -1) == z_submenu) // submenu end
 224                         break;
 225                 QuickMenu_skip_submenu(substring(s, 1, -1));
 226         }
 227         strunzone(z_submenu);
 228 }
 229
 230 bool QuickMenu_IsOpened()
 231 {
 232         return (QuickMenu_Page_Entries > 0);
 233 }
 234
 235 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 236 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 237 {
 238     TC(int, teamplayers); TC(bool, without_me);
 239         int i;
 240         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 241                 QuickMenu_Page_ClearEntry(i);
 242         QuickMenu_Buffer_Close();
 243
 244         QuickMenu_Buffer = buf_create();
 245         if(QuickMenu_Buffer < 0)
 246                 return false;
 247
 248         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 249
 250         if(QuickMenu_Buffer_Size <= 0)
 251         {
 252                 buf_del(QuickMenu_Buffer);
 253                 QuickMenu_Buffer = -1;
 254                 return false;
 255         }
 256         return true;
 257 }
 258
 259 // new_page 0 means page 0, new_page != 0 means next page
 260 int QuickMenu_Buffer_Index_Prev;
 261 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 262 {
 263     TC(bool, new_page);
 264         string s = string_null, cmd = string_null, z_submenu;
 265
 266         if (new_page == 0)
 267                 QuickMenu_Page = 0;
 268         else
 269                 ++QuickMenu_Page;
 270
 271         z_submenu = strzone(target_submenu);
 272         if (QuickMenu_CurrentSubMenu)
 273                 strunzone(QuickMenu_CurrentSubMenu);
 274         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 275
 276         QuickMenu_IsLastPage = true;
 277         QuickMenu_Page_Entries = 0;
 278
 279         QuickMenu_Buffer_Index = 0;
 280         if (z_submenu != "")
 281         {
 282                 // skip everything until the submenu open tag is found
 283                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 284                 {
 285                         s = QuickMenu_Buffer_Get();
 286                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 287                         {
 288                                 // printf("^3 beginning of %s\n", z_submenu);
 289                                 ++QuickMenu_Buffer_Index;
 290                                 break; // target_submenu found!
 291                         }
 292                         // printf("^1 skipping %s\n", s);
 293                 }
 294                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 295                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 296         }
 297
 298         // only the last page can contain up to QUICKMENU_MAXLINES entries
 299         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 300         // so that the panel can show an empty row and "Continue..."
 301         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 302         int entry_num = 0; // counts entries in target_submenu
 303         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 304         {
 305                 s = QuickMenu_Buffer_Get();
 306
 307                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 308                 {
 309                         // printf("^3 end of %s\n", z_submenu);
 310                         break;
 311                 }
 312
 313                 if(entry_num >= first_entry)
 314                 {
 315                         ++QuickMenu_Page_Entries;
 316                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 317                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 318                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 319                         {
 320                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 321                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 322                                 QuickMenu_IsLastPage = false;
 323                                 break;
 324                         }
 325                 }
 326
 327                 // NOTE: entries are loaded starting from 1, not from 0
 328                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 329                 {
 330                         if(entry_num >= first_entry)
 331                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 332                         QuickMenu_skip_submenu(substring(s, 1, -1));
 333                 }
 334                 else if(entry_num >= first_entry && substring(s, 0, 1) == QM_TAG_TITLE)
 335                 {
 336                         ++QuickMenu_Buffer_Index;
 337                         cmd = QuickMenu_Buffer_Get();
 338                         string command_code = substring(cmd, 0, 1);
 339                         if(command_code == QM_TAG_COMMAND)
 340                                 cmd = substring(cmd, 1, -1);
 341                         else if(command_code == QM_TAG_PLCOMMAND)
 342                         {
 343                                 // throw away the current quickmenu buffer and load a new one
 344                                 cmd = substring(cmd, 1, -1);
 345                                 strunzone(z_submenu);
 346                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 347                                         return QuickMenu_Page_Load("", 0);
 348                                 QuickMenu_Close();
 349                                 return false;
 350                         }
 351
 352                         tokenize_console(cmd);
 353                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 354
 355                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 356                 }
 357
 358                 ++entry_num;
 359         }
 360         strunzone(z_submenu);
 361         if (QuickMenu_Page_Entries == 0)
 362         {
 363                 QuickMenu_Close();
 364                 return false;
 365         }
 366         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 367         return true;
 368 }
 369
 370 bool QuickMenu_ActionForNumber(int num)
 371 {
 372     TC(int, num);
 373         if (!QuickMenu_IsLastPage)
 374         {
 375                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 376                         return false;
 377                 if (num == QUICKMENU_MAXLINES - 1)
 378                         return false;
 379                 if (num == 0)
 380                 {
 381                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 382                         return false;
 383                 }
 384         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 385                 return false;
 386
 387         if (QuickMenu_Page_Command[num] != "")
 388         {
 389                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 390                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 391                 return true;
 392         }
 393         if (QuickMenu_Page_Description[num] != "")
 394                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 395         return false;
 396 }
 397
 398 void QuickMenu_Page_ActiveEntry(int entry_num)
 399 {
 400     TC(int, entry_num);
 401         QuickMenu_Page_ActivatedEntry = entry_num;
 402         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 403         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 404         {
 405                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 406                 // toggle commands don't close the quickmenu
 407                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 408                         QuickMenu_Page_ActivatedEntry_Close = false;
 409                 else
 410                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 411         }
 412         else
 413                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 414 }
 415
 416 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 417 {
 418     TC(int, bInputType);
 419         // we only care for keyboard events
 420         if(bInputType == 2)
 421                 return false;
 422
 423         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 424                 return false;
 425
 426         if(bInputType == 3)
 427         {
 428                 mousepos.x = nPrimary;
 429                 mousepos.y = nSecondary;
 430                 return true;
 431         }
 432
 433         // allow console bind to work
 434         string con_keys = findkeysforcommand("toggleconsole", 0);
 435         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 436         bool hit_con_bind = false;
 437         int i;
 438         for (i = 0; i < keys; ++i)
 439         {
 440                 if(nPrimary == stof(argv(i)))
 441                         hit_con_bind = true;
 442         }
 443
 444         if(bInputType == 0) {
 445                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 446                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 447                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 448         }
 449         else if(bInputType == 1) {
 450                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 451                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 452                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 453         }
 454
 455         if(nPrimary == K_ESCAPE)
 456         {
 457                 if (bInputType == 1)
 458                         return true;
 459                 QuickMenu_Close();
 460         }
 461         else if(nPrimary >= '0' && nPrimary <= '9')
 462         {
 463                 if (bInputType == 1)
 464                         return true;
 465                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 466         }
 467         if(nPrimary == K_MOUSE1)
 468         {
 469                 if(bInputType == 0) // key pressed
 470                         mouseClicked |= S_MOUSE1;
 471                 else if(bInputType == 1) // key released
 472                         mouseClicked -= (mouseClicked & S_MOUSE1);
 473         }
 474         else if(nPrimary == K_MOUSE2)
 475         {
 476                 if(bInputType == 0) // key pressed
 477                         mouseClicked |= S_MOUSE2;
 478                 else if(bInputType == 1) // key released
 479                         mouseClicked -= (mouseClicked & S_MOUSE2);
 480         }
 481         else if(hit_con_bind)
 482                 return false;
 483
 484         return true;
 485 }
 486
 487 void QuickMenu_Mouse()
 488 {
 489         if(mv_active) return;
 490
 491         if(!mouseClicked)
 492         if(prevMouseClicked & S_MOUSE2)
 493         {
 494                 QuickMenu_Close();
 495                 return;
 496         }
 497
 498         if(!autocvar_hud_cursormode)
 499         {
 500                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 501
 502                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 503                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 504         }
 505
 506         HUD_Panel_UpdateCvars();
 507
 508         if(panel_bg_padding)
 509         {
 510                 panel_pos += '1 1 0' * panel_bg_padding;
 511                 panel_size -= '2 2 0' * panel_bg_padding;
 512         }
 513
 514         float first_entry_pos, entries_height;
 515         vector fontsize;
 516         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 517         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 518         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 519
 520         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 521         {
 522                 float entry_num;
 523                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 524                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 525                 {
 526                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 527                         vector color;
 528                         if(mouseClicked & S_MOUSE1)
 529                                 color = '0.5 1 0.5';
 530                         else if(hudShiftState & S_CTRL)
 531                                 color = '1 1 0.3';
 532                         else
 533                                 color = '1 1 1';
 534                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 535
 536                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 537                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 538                 }
 539         }
 540
 541         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 542
 543         prevMouseClicked = mouseClicked;
 544 }
 545
 546 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 547 {
 548         string entry;
 549         float offset;
 550         float desc_width = panel_size.x;
 551         if(option)
 552         {
 553                 string pic = strcat(hud_skin_path, "/", option);
 554                 if(precache_pic(pic) == "")
 555                         pic = strcat("gfx/hud/default/", option);
 556                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 557                 desc_width -= option_size.x;
 558                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 559                 desc_width -= fontsize.x / 4;
 560         }
 561         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 562         if (autocvar_hud_panel_quickmenu_align > 0)
 563         {
 564                 float real_desc_width = stringwidth_colors(entry, fontsize);
 565                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 566
 567                 if(option)
 568                 {
 569                         // when there's enough room align description regardless the checkbox
 570                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 571                         if(offset + real_desc_width + extra_offset < desc_width)
 572                                 offset += extra_offset;
 573                         else
 574                                 offset = max(0, desc_width - real_desc_width);
 575                 }
 576                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 577         }
 578         else
 579                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 580 }
 581
 582 void HUD_QuickMenu()
 583 {
 584         if(!autocvar__hud_configure)
 585         {
 586                 if (hud_configure_prev && hud_configure_prev != -1)
 587                         QuickMenu_Close();
 588
 589                 if(!hud_draw_maximized) return;
 590                 if(mv_active) return;
 591                 //if(!autocvar_hud_panel_quickmenu) return;
 592                 if(!hud_panel_quickmenu) return;
 593
 594                 if(QuickMenu_TimeOut)
 595                 if(time > QuickMenu_TimeOut)
 596                 {
 597                         QuickMenu_Close();
 598                         return;
 599                 }
 600         }
 601         else
 602         {
 603                 if(!QuickMenu_IsOpened())
 604                 {
 605                         QuickMenu_Page_Entries = 1;
 606                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 607                         ++QuickMenu_Page_Entries;
 608                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 609                         ++QuickMenu_Page_Entries;
 610                         // although real command doesn't matter here, it must not be empty
 611                         // otherwise the entry is displayed like a submenu
 612                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 613                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 614                         ++QuickMenu_Page_Entries;
 615                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 616                         QuickMenu_IsLastPage = false;
 617                 }
 618         }
 619
 620         HUD_Panel_UpdateCvars();
 621
 622         HUD_Scale_Disable();
 623         HUD_Panel_DrawBg(1);
 624
 625         if(panel_bg_padding)
 626         {
 627                 panel_pos += '1 1 0' * panel_bg_padding;
 628                 panel_size -= '2 2 0' * panel_bg_padding;
 629         }
 630
 631         int i;
 632         vector fontsize;
 633         string color;
 634         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 635
 636         if (!QuickMenu_IsLastPage)
 637         {
 638                 color = "^5";
 639                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 640         }
 641         else
 642                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 643
 644         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 645                 if (QuickMenu_Page_Description[i] == "")
 646                         break;
 647                 string option = string_null;
 648                 if (QuickMenu_Page_Command[i] == "")
 649                         color = "^4";
 650                 else
 651                 {
 652                         color = "^3";
 653                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 654                         {
 655                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 656                                 if(end < 0)
 657                                         tokenize_console(QuickMenu_Page_Command[i]);
 658                                 else
 659                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 660
 661                                 if(argv(1) && argv(0) == "toggle")
 662                                 {
 663                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 664                                         // "disable feature xxx" "toggle xxx 0 1"
 665                                         float ON_value = 1, OFF_value = 0;
 666                                         if(argv(2))
 667                                                 ON_value = stof(argv(2));
 668
 669                                         if(argv(3))
 670                                                 OFF_value = stof(argv(3));
 671                                         else
 672                                                 OFF_value = !ON_value;
 673
 674                                         float value = cvar(argv(1));
 675                                         if(value == ON_value)
 676                                                 option = "checkbox_checked";
 677                                         else if(value == OFF_value)
 678                                                 option = "checkbox_empty";
 679                                         else
 680                                                 option = "checkbox_undefined";
 681                                 }
 682                         }
 683                 }
 684                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 685
 686                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 687                         && QuickMenu_Page_ActivatedEntry == i)
 688                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 689
 690                 panel_pos.y += fontsize.y;
 691         }
 692
 693         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 694         {
 695                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 696                 {
 697                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 698                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 699                                 QuickMenu_Close();
 700                 }
 701                 else if(QuickMenu_Page_ActivatedEntry_Close)
 702                         QuickMenu_Close();
 703                 QuickMenu_Page_ActivatedEntry = -1;
 704                 QuickMenu_Page_ActivatedEntry_Time = 0;
 705         }
 706 }
 707
 708
 709 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 710         if(target_submenu == eng_submenu && target_submenu_found) \
 711                 return; /* target_submenu entries are now loaded, exit */ \
 712         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 713                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 714         ++QuickMenu_Buffer_Size; \
 715         if(target_submenu == eng_submenu && !target_submenu_found) { \
 716                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 717                 target_submenu_found = true; \
 718         } \
 719 }
 720
 721 #define QUICKMENU_ENTRY(title,command) { \
 722         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 723         { \
 724                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 725                 ++QuickMenu_Buffer_Size; \
 726                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 727         } \
 728         ++QuickMenu_Buffer_Size; \
 729 }
 730
 731 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 732         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 733                 QUICKMENU_SMENU(submenu,eng_submenu) \
 734                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 735                 ++QuickMenu_Buffer_Size; \
 736                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 737                 ++QuickMenu_Buffer_Size; \
 738                 QUICKMENU_SMENU(submenu,eng_submenu) \
 739         } \
 740 }
 741
 742
 743
 744 // useful to Translate a string inside the Command
 745 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 746         if(prvm_language == "en") \
 747                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 748         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 749                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 750         else \
 751                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 752 }
 753
 754 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 755 {
 756     TC(int, teamplayers); TC(bool, without_me);
 757         entity pl;
 758         if(teamplayers && !team_count)
 759                 return;
 760
 761         for(pl = players.sort_next; pl; pl = pl.sort_next)
 762         {
 763                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 764                         continue;
 765                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 766                         continue;
 767                 if(without_me && pl.sv_entnum == player_localnum)
 768                         continue;
 769                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 770         }
 771
 772         return;
 773 }
 774
 775
 776 // Specifying target_submenu, this function only loads entries inside target_submenu
 777 // NOTE: alternatively we could have loaded the whole default quickmenu and
 778 // then called QuickMenu_Page_Load(target_submenu, 0);
 779 // but this sytem is more reliable since we can always refer to target_submenu
 780 // with the English title even if a translation is active
 781 void QuickMenu_Default(string target_submenu)
 782 {
 783         bool target_submenu_found = false;
 784         if(target_submenu != "")
 785                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 786
 787         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 791         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 792
 793         if(teamplay)
 794         {
 795         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 797                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 811         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 812         }
 813
 814         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 815
 816         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 817                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 818                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 819                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 824                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 825
 826                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 827                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 829                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 830
 831                 if(spectatee_status > 0)
 832                 {
 833                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 834                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 835                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 837                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 838                 }
 839
 840                 if(spectatee_status == -1)
 841                 {
 842                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 843                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 844                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 845                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 846                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 847                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 848                 }
 849
 850                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 851                 if(prvm_language != "en")
 852                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 853         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 854
 855         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 856                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 857                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 858                 if(STAT(TIMELIMIT) > 0)
 859                 {
 860                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 861                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 862                 }
 863                 if(teamplay)
 864                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 865         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 866
 867         if(target_submenu != "" && !target_submenu_found)
 868         {
 869                 LOG_WARNF("Couldn't find submenu \"%s\"", target_submenu);
 870                 if(prvm_language != "en")
 871                         LOG_WARNF("^3Warning: submenu must be in English", target_submenu);
 872                 QuickMenu_Buffer_Size = 0;
 873         }
 874 }
 875 #undef QUICKMENU_SMENU
 876 #undef QUICKMENU_ENTRY
 877 #undef QUICKMENU_ENTRY_TC