qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/draw.qh>
   4 #include <client/hud/_mod.qh>
   5 #include <client/mapvoting.qh>
   6 #include <common/ent_cs.qh>
   7 #include <common/minigames/cl_minigames.qh>
   8
   9 // QuickMenu (#23)
  10
  11 void HUD_QuickMenu_Export(int fh)
  12 {
  13         // allow saving cvars that aesthetically change the panel into hud skin files
  14         HUD_Write_Cvar("hud_panel_quickmenu_align");
  15 }
  16
  17 // QUICKMENU_MAXLINES must be <= 10
  18 const int QUICKMENU_MAXLINES = 10;
  19 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  20 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  21 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  22 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  23 int QuickMenu_Page_Entries;
  24 int QuickMenu_Page;
  25 int QuickMenu_Page_ActivatedEntry = -1;
  26 bool QuickMenu_Page_ActivatedEntry_Close;
  27 float QuickMenu_Page_ActivatedEntry_Time;
  28 bool QuickMenu_IsLastPage;
  29 // all the entries are loaded into QuickMenu_Buffer
  30 // each entry (submenu or command) is composed of 2 entries
  31 const int QUICKMENU_MAXENTRIES = 256;
  32 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  33 int QuickMenu_Buffer = -1;
  34 int QuickMenu_Buffer_Size;
  35 int QuickMenu_Buffer_Index;
  36 string QuickMenu_CurrentSubMenu;
  37 float QuickMenu_TimeOut;
  38
  39 // QuickMenu_Buffer are labeled with these tags
  40 #define QM_TAG_TITLE "T"
  41 #define QM_TAG_SUBMENU "S"
  42 #define QM_TAG_COMMAND "C"
  43 #define QM_TAG_PLCOMMAND "P"
  44
  45 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  46 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  47
  48 void QuickMenu_TimeOut_Set()
  49 {
  50         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
  51 }
  52
  53 // if s1 is not empty s will be displayed as command otherwise as submenu
  54 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  55 {
  56         TC(int, i);
  57         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  58         strcpy(QuickMenu_Page_Description[i], s);
  59         strcpy(QuickMenu_Page_Command[i], s1);
  60 }
  61
  62 void QuickMenu_Page_ClearEntry(int i)
  63 {
  64         TC(int, i);
  65         strfree(QuickMenu_Page_Description[i]);
  66         strfree(QuickMenu_Page_Command[i]);
  67         QuickMenu_Page_Command_Type[i] = 0;
  68 }
  69
  70 bool HUD_QuickMenu_Forbidden()
  71 {
  72         return (mv_active
  73                 || (hud_configure_prev && hud_configure_prev != -1)
  74                 || HUD_MinigameMenu_IsOpened()
  75                 || (QuickMenu_TimeOut && time > QuickMenu_TimeOut));
  76 }
  77
  78 // returns true if succeded, false otherwise
  79 bool QuickMenu_Open(string mode, string submenu, string file)
  80 {
  81         QuickMenu_TimeOut = 0;
  82         if (HUD_QuickMenu_Forbidden())
  83                 return false;
  84
  85         int fh = -1;
  86         string s;
  87
  88         if(mode == "")
  89         {
  90                 if(file == "" || file == "0")
  91                         mode = "default";
  92                 else
  93                         mode = "file";
  94         }
  95
  96         if(mode == "file")
  97         {
  98                 if(file == "" || file == "0")
  99                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
 100                 else
 101                 {
 102                         fh = fopen(file, FILE_READ);
 103                         if(fh < 0)
 104                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
 105                 }
 106                 if(fh < 0)
 107                         mode = "default";
 108         }
 109
 110         if(mode == "default")
 111         {
 112                 QuickMenu_Buffer = buf_create();
 113                 if(QuickMenu_Buffer < 0)
 114                         return false;
 115
 116                 QuickMenu_Default(submenu);
 117         }
 118         else if(mode == "file")
 119         {
 120                 QuickMenu_Buffer = buf_create();
 121                 if(QuickMenu_Buffer < 0)
 122                 {
 123                         fclose(fh);
 124                         return false;
 125                 }
 126
 127                 QuickMenu_Buffer_Size = 0;
 128                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 129                 {
 130                         // first skip invalid entries, so we don't check them anymore
 131                         int argc;
 132                         argc = tokenize_console(s);
 133                         if(argc == 0 || argv(0) == "")
 134                                 continue;
 135                         if(argc == 1)
 136                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 137                         else if(argc == 2)
 138                         {
 139                                 if(argv(1) == "")
 140                                         continue;
 141                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 142                                 ++QuickMenu_Buffer_Size;
 143                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 144                         }
 145                         else if(argc == 3)
 146                         {
 147                                 // check for special keywords
 148                                 float teamplayers = 0, without_me = 0;
 149                                 switch(argv(2))
 150                                 {
 151                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 152                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 153                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 154                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 155                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 156                                         default: continue;
 157                                 }
 158
 159                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 160                                 {
 161                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 162                                         ++QuickMenu_Buffer_Size;
 163                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 164                                         ++QuickMenu_Buffer_Size;
 165                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 166                                         ++QuickMenu_Buffer_Size;
 167                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 168                                 }
 169                         }
 170                         ++QuickMenu_Buffer_Size;
 171                 }
 172                 fclose(fh);
 173         }
 174         else
 175         {
 176                 LOG_WARNF("Unrecognized mode %s", mode);
 177                 return false;
 178         }
 179
 180         if (QuickMenu_Buffer_Size <= 0)
 181         {
 182                 buf_del(QuickMenu_Buffer);
 183                 QuickMenu_Buffer = -1;
 184                 return false;
 185         }
 186
 187         if(mode == "file")
 188                 QuickMenu_Page_Load(submenu, 0);
 189         else
 190                 QuickMenu_Page_Load("", 0);
 191
 192         mouseClicked = 0;
 193         hudShiftState = 0;
 194
 195         // we must unset the player's buttons, as they aren't released elsewhere
 196         localcmd("-fire\n");
 197         localcmd("-fire2\n");
 198         localcmd("-use\n");
 199         localcmd("-hook\n");
 200         localcmd("-jump\n");
 201
 202         QuickMenu_TimeOut_Set();
 203         return true;
 204 }
 205
 206 void QuickMenu_Buffer_Close()
 207 {
 208         if (QuickMenu_Buffer >= 0)
 209         {
 210                 buf_del(QuickMenu_Buffer);
 211                 QuickMenu_Buffer = -1;
 212                 QuickMenu_Buffer_Size = 0;
 213         }
 214 }
 215
 216 void QuickMenu_Close()
 217 {
 218         strfree(QuickMenu_CurrentSubMenu);
 219         int i;
 220         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 221                 QuickMenu_Page_ClearEntry(i);
 222         QuickMenu_Page_Entries = 0;
 223         mouseClicked = 0;
 224         prevMouseClicked = 0;
 225         QuickMenu_Buffer_Close();
 226 }
 227
 228 // It assumes submenu open tag is already detected
 229 void QuickMenu_skip_submenu(string submenu)
 230 {
 231         string z_submenu = string_null; strcpy(z_submenu, submenu);
 232         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 233         {
 234                 string s = QuickMenu_Buffer_Get();
 235                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 236                         continue;
 237                 if(substring(s, 1, -1) == z_submenu) // submenu end
 238                         break;
 239                 QuickMenu_skip_submenu(substring(s, 1, -1));
 240         }
 241         strfree(z_submenu);
 242 }
 243
 244 bool QuickMenu_IsOpened()
 245 {
 246         return (QuickMenu_Page_Entries > 0);
 247 }
 248
 249 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 250 {
 251         TC(int, teamplayers); TC(bool, without_me);
 252         int i;
 253         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 254                 QuickMenu_Page_ClearEntry(i);
 255         QuickMenu_Buffer_Close();
 256
 257         QuickMenu_Buffer = buf_create();
 258         if(QuickMenu_Buffer < 0)
 259                 return false;
 260
 261         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 262
 263         if(QuickMenu_Buffer_Size <= 0)
 264         {
 265                 buf_del(QuickMenu_Buffer);
 266                 QuickMenu_Buffer = -1;
 267                 return false;
 268         }
 269         return true;
 270 }
 271
 272 // new_page 0 means page 0, new_page != 0 means next page
 273 int QuickMenu_Buffer_Index_Prev;
 274 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 275 {
 276         TC(bool, new_page);
 277         string s = string_null, cmd = string_null, z_submenu;
 278
 279         QuickMenu_Page_ActivatedEntry = -1;
 280         if (new_page == 0)
 281                 QuickMenu_Page = 0;
 282         else
 283                 ++QuickMenu_Page;
 284
 285         z_submenu = strzone(target_submenu);
 286         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 287
 288         QuickMenu_IsLastPage = true;
 289         QuickMenu_Page_Entries = 0;
 290
 291         QuickMenu_Buffer_Index = 0;
 292         if (z_submenu != "")
 293         {
 294                 // skip everything until the submenu open tag is found
 295                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 296                 {
 297                         s = QuickMenu_Buffer_Get();
 298                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 299                         {
 300                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 301                                 ++QuickMenu_Buffer_Index;
 302                                 break; // target_submenu found!
 303                         }
 304                         //LOG_INFOF("^1 skipping %s\n", s);
 305                 }
 306                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 307                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 308         }
 309
 310         // only the last page can contain up to QUICKMENU_MAXLINES entries
 311         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 312         // so that the panel can show an empty row and "Continue..."
 313         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 314         int entry_num = 0; // counts entries in target_submenu
 315         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 316         {
 317                 s = QuickMenu_Buffer_Get();
 318
 319                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 320                 {
 321                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 322                         break;
 323                 }
 324
 325                 if(entry_num >= first_entry)
 326                 {
 327                         ++QuickMenu_Page_Entries;
 328                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 329                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 330                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 331                         {
 332                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 333                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 334                                 QuickMenu_IsLastPage = false;
 335                                 break;
 336                         }
 337                 }
 338
 339                 // NOTE: entries are loaded starting from 1, not from 0
 340                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 341                 {
 342                         if(entry_num >= first_entry)
 343                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 344                         QuickMenu_skip_submenu(substring(s, 1, -1));
 345                 }
 346                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 347                 {
 348                         ++QuickMenu_Buffer_Index;
 349                         if(entry_num >= first_entry)
 350                         {
 351                                 cmd = QuickMenu_Buffer_Get();
 352                                 string command_code = substring(cmd, 0, 1);
 353                                 if(command_code == QM_TAG_COMMAND)
 354                                         cmd = substring(cmd, 1, -1);
 355                                 else if(command_code == QM_TAG_PLCOMMAND)
 356                                 {
 357                                         // throw away the current quickmenu buffer and load a new one
 358                                         cmd = substring(cmd, 1, -1);
 359                                         strunzone(z_submenu);
 360                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 361                                                 return QuickMenu_Page_Load("", 0);
 362                                         QuickMenu_Close();
 363                                         return false;
 364                                 }
 365
 366                                 tokenize_console(cmd);
 367                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 368
 369                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 370                         }
 371
 372                 }
 373
 374                 ++entry_num;
 375         }
 376         strunzone(z_submenu);
 377         if (QuickMenu_Page_Entries == 0)
 378         {
 379                 QuickMenu_Close();
 380                 return false;
 381         }
 382         QuickMenu_TimeOut_Set();
 383         return true;
 384 }
 385
 386 bool QuickMenu_ActionForNumber(int num)
 387 {
 388         TC(int, num);
 389         if (!QuickMenu_IsLastPage)
 390         {
 391                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 392                         return false;
 393                 if (num == QUICKMENU_MAXLINES - 1)
 394                         return false;
 395                 if (num == 0)
 396                 {
 397                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 398                         return false;
 399                 }
 400         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 401                 return false;
 402
 403         if (QuickMenu_Page_Command[num] != "")
 404         {
 405                 QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 406                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 407                 QuickMenu_TimeOut_Set();
 408                 return true;
 409         }
 410         if (QuickMenu_Page_Description[num] != "")
 411                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 412         return false;
 413 }
 414
 415 void QuickMenu_Page_ActiveEntry(int entry_num)
 416 {
 417         TC(int, entry_num);
 418         QuickMenu_Page_ActivatedEntry = entry_num;
 419         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 420         {
 421                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 422                 // toggle commands don't close the quickmenu
 423                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 424                         QuickMenu_Page_ActivatedEntry_Close = false;
 425                 else
 426                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 427         }
 428         else
 429                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 430 }
 431
 432 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 433 {
 434         TC(int, bInputType);
 435
 436         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 437                 return false;
 438
 439         if(bInputType == 3)
 440         {
 441                 mousepos.x = nPrimary;
 442                 mousepos.y = nSecondary;
 443                 return true;
 444         }
 445
 446         if(bInputType == 2)
 447                 return false;
 448
 449         // at this point bInputType can only be 0 or 1 (key pressed or released)
 450         bool key_pressed = (bInputType == 0);
 451
 452         int hudShiftState_prev = hudShiftState;
 453         int mouseClicked_prev = mouseClicked;
 454         if(key_pressed)
 455         {
 456                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 457                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 458                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 459                 if(nPrimary == K_MOUSE1) mouseClicked |= S_MOUSE1;
 460                 if(nPrimary == K_MOUSE2) mouseClicked |= S_MOUSE2;
 461         }
 462         else
 463         {
 464                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 465                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 466                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 467                 if(nPrimary == K_MOUSE1) mouseClicked -= (mouseClicked & S_MOUSE1);
 468                 if(nPrimary == K_MOUSE2) mouseClicked -= (mouseClicked & S_MOUSE2);
 469         }
 470
 471         if(nPrimary == K_ESCAPE && key_pressed)
 472         {
 473                 QuickMenu_Close();
 474         }
 475         else if(nPrimary >= '0' && nPrimary <= '9' && key_pressed)
 476         {
 477                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 478         }
 479         else if (hudShiftState_prev == hudShiftState && mouseClicked_prev == mouseClicked)
 480         {
 481                 // allow console bind to work
 482                 string con_keys = findkeysforcommand("toggleconsole", 0);
 483                 int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 484                 for (int i = 0; i < keys; ++i)
 485                 {
 486                         if(nPrimary == stof(argv(i)))
 487                                 return false; // hit console bind
 488                 }
 489                 if (key_pressed)
 490                         QuickMenu_Close();
 491                 return false;
 492         }
 493
 494         return true;
 495 }
 496
 497 int entry_num_prev = 0;
 498 void QuickMenu_Mouse()
 499 {
 500         if(mv_active) return;
 501
 502         if(!mouseClicked)
 503         if(prevMouseClicked & S_MOUSE2)
 504         {
 505                 QuickMenu_Close();
 506                 return;
 507         }
 508
 509         panel = HUD_PANEL(QUICKMENU);
 510         HUD_Panel_LoadCvars();
 511
 512         if(panel_bg_padding)
 513         {
 514                 panel_pos += '1 1 0' * panel_bg_padding;
 515                 panel_size -= '2 2 0' * panel_bg_padding;
 516         }
 517
 518         float first_entry_pos, entries_height;
 519         vector fontsize;
 520         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 521         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 522         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 523
 524         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 525         {
 526                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 527                 if (entry_num != entry_num_prev)
 528                 {
 529                         QuickMenu_TimeOut_Set();
 530                         entry_num_prev = entry_num;
 531                 }
 532                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 533                 {
 534                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 535                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 536
 537                         if (time > QuickMenu_Page_ActivatedEntry_Time)
 538                         {
 539                                 vector entry_pos = panel_pos;
 540                                 entry_pos.y = first_entry_pos + entry_num * fontsize.y;
 541                                 vector color;
 542                                 if (mouseClicked & S_MOUSE1)
 543                                         color = '0.5 1 0.5';
 544                                 else if (hudShiftState & S_CTRL)
 545                                         color = '1 1 0.3';
 546                                 else
 547                                         color = '1 1 1';
 548                                 drawfill(entry_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 549                         }
 550                 }
 551         }
 552 }
 553
 554 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 555 {
 556         string entry;
 557         float offset;
 558         float desc_width = panel_size.x;
 559         if(option)
 560         {
 561                 string pic = strcat(hud_skin_path, "/", option);
 562                 if(precache_pic(pic) == "")
 563                         pic = strcat("gfx/hud/default/", option);
 564                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 565                 desc_width -= option_size.x;
 566                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 567                 desc_width -= fontsize.x / 4;
 568         }
 569         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 570         if (autocvar_hud_panel_quickmenu_align > 0)
 571         {
 572                 float real_desc_width = stringwidth_colors(entry, fontsize);
 573                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 574
 575                 if(option)
 576                 {
 577                         // when there's enough room align description regardless the checkbox
 578                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 579                         if(offset + real_desc_width + extra_offset < desc_width)
 580                                 offset += extra_offset;
 581                         else
 582                                 offset = max(0, desc_width - real_desc_width);
 583                 }
 584                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 585         }
 586         else
 587                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 588 }
 589
 590 void HUD_QuickMenu()
 591 {
 592         if(!autocvar__hud_configure)
 593         {
 594                 if (!hud_draw_maximized || !QuickMenu_IsOpened())
 595                         return;
 596
 597                 if (HUD_QuickMenu_Forbidden())
 598                 {
 599                         QuickMenu_Close();
 600                         return;
 601                 }
 602         }
 603         else
 604         {
 605                 if(!QuickMenu_IsOpened())
 606                 {
 607                         QuickMenu_Page_Entries = 1;
 608                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 609                         ++QuickMenu_Page_Entries;
 610                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 611                         ++QuickMenu_Page_Entries;
 612                         // although real command doesn't matter here, it must not be empty
 613                         // otherwise the entry is displayed like a submenu
 614                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 615                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 616                         ++QuickMenu_Page_Entries;
 617                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 618                         QuickMenu_IsLastPage = false;
 619                 }
 620         }
 621
 622         HUD_Panel_LoadCvars();
 623
 624         HUD_Scale_Disable();
 625         HUD_Panel_DrawBg();
 626
 627         if(panel_bg_padding)
 628         {
 629                 panel_pos += '1 1 0' * panel_bg_padding;
 630                 panel_size -= '2 2 0' * panel_bg_padding;
 631         }
 632
 633         int i;
 634         vector fontsize;
 635         string color;
 636         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 637
 638         if (!QuickMenu_IsLastPage)
 639         {
 640                 color = "^5";
 641                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 642         }
 643         else
 644                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 645
 646         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 647                 if (QuickMenu_Page_Description[i] == "")
 648                         break;
 649                 string option = string_null;
 650                 if (QuickMenu_Page_Command[i] == "")
 651                         color = "^4";
 652                 else
 653                 {
 654                         color = "^3";
 655                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 656                         {
 657                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 658                                 if(end < 0)
 659                                         tokenize_console(QuickMenu_Page_Command[i]);
 660                                 else
 661                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 662
 663                                 if(argv(1) && argv(0) == "toggle")
 664                                 {
 665                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 666                                         // "disable feature xxx" "toggle xxx 0 1"
 667                                         float ON_value = 1, OFF_value = 0;
 668                                         if(argv(2))
 669                                                 ON_value = stof(argv(2));
 670
 671                                         if(argv(3))
 672                                                 OFF_value = stof(argv(3));
 673                                         else
 674                                                 OFF_value = !ON_value;
 675
 676                                         float value = cvar(argv(1));
 677                                         if(value == ON_value)
 678                                                 option = "checkbox_checked";
 679                                         else if(value == OFF_value)
 680                                                 option = "checkbox_empty";
 681                                         else
 682                                                 option = "checkbox_undefined";
 683                                 }
 684                         }
 685                 }
 686                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 687
 688                 if (time < QuickMenu_Page_ActivatedEntry_Time && QuickMenu_Page_ActivatedEntry == i)
 689                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 690
 691                 panel_pos.y += fontsize.y;
 692         }
 693
 694         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 695         {
 696                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 697                 {
 698                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 699                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 700                                 QuickMenu_Close();
 701                 }
 702                 else if(QuickMenu_Page_ActivatedEntry_Close)
 703                         QuickMenu_Close();
 704                 QuickMenu_Page_ActivatedEntry = -1;
 705                 QuickMenu_Page_ActivatedEntry_Time = 0;
 706         }
 707 }
 708
 709
 710 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 711         if(target_submenu == eng_submenu && target_submenu_found) \
 712                 return; /* target_submenu entries are now loaded, exit */ \
 713         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 714                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 715         ++QuickMenu_Buffer_Size; \
 716         if(target_submenu == eng_submenu && !target_submenu_found) { \
 717                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 718                 target_submenu_found = true; \
 719         } \
 720 }
 721
 722 #define QUICKMENU_ENTRY(title,command) { \
 723         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 724         { \
 725                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 726                 ++QuickMenu_Buffer_Size; \
 727                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 728         } \
 729         ++QuickMenu_Buffer_Size; \
 730 }
 731
 732 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 733         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 734                 QUICKMENU_SMENU(submenu,eng_submenu) \
 735                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 736                 ++QuickMenu_Buffer_Size; \
 737                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 738                 ++QuickMenu_Buffer_Size; \
 739                 QUICKMENU_SMENU(submenu,eng_submenu) \
 740         } \
 741 }
 742
 743
 744
 745 // useful to Translate a string inside the Command
 746 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 747         if(prvm_language == "en") { \
 748                 tc_title = title; \
 749                 tc_cmd = sprintf(command, text); \
 750         } \
 751         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 752                 tc_title = strcat("(en)", title); \
 753                 tc_cmd = sprintf(command, text); \
 754         } \
 755         else { \
 756                 tc_title = strcat("(", prvm_language, ")", title); \
 757                 tc_cmd = sprintf(command, translated_text); \
 758         } \
 759         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 760 }
 761
 762 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 763 {
 764         TC(int, teamplayers); TC(bool, without_me);
 765         entity pl;
 766         if(teamplayers && !team_count)
 767                 return;
 768
 769         for(pl = players.sort_next; pl; pl = pl.sort_next)
 770         {
 771                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 772                         continue;
 773                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 774                         continue;
 775                 if(without_me && pl.sv_entnum == player_localnum)
 776                         continue;
 777                 QUICKMENU_ENTRY(strcat("^7", entcs_GetName(pl.sv_entnum)), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 778         }
 779
 780         return;
 781 }
 782
 783
 784 // Specifying target_submenu, this function only loads entries inside target_submenu
 785 // NOTE: alternatively we could have loaded the whole default quickmenu and
 786 // then called QuickMenu_Page_Load(target_submenu, 0);
 787 // but this sytem is more reliable since we can always refer to target_submenu
 788 // with the English title even if a translation is active
 789 void QuickMenu_Default(string target_submenu)
 790 {
 791         bool target_submenu_found = false;
 792         if(target_submenu != "")
 793                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 794
 795         string tc_title;
 796         string tc_cmd;
 797
 798         QUICKMENU_SMENU(_("Chat"), "Chat")
 799                 QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send public message to")), "Send public message to", "commandmode say %s:^7", 0, 1)
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 803                 if(prvm_language != "en")
 804                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 805         QUICKMENU_SMENU(_("Chat"), "Chat")
 806
 807         if(teamplay)
 808         {
 809         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^strength soon")), "say_team %s", "strength soon", CTX(_("QMCMD^strength soon")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 813                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 814                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 815                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 816                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 817                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 818                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 819                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 820                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 821                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 822                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 823                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 824                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 825         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 826         }
 827
 828         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 829
 830         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 831                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 832                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 833                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 834                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 835                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 836                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 837                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 838                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 839
 840                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 841                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 842                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 843                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 844
 845                 if(spectatee_status > 0)
 846                 {
 847                 QUICKMENU_ENTRY(CTX(_("QMCMD^Change spectator camera")), "dropweapon")
 848                 }
 849
 850                 if(spectatee_status == -1)
 851                 {
 852                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 853                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 854                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 855                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision")), "toggle cl_clippedspectating")
 856                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 857                 }
 858
 859                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 860         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 861
 862         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 863                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 864                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 865                 if(STAT(TIMELIMIT) > 0)
 866                 {
 867                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 868                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 869                 }
 870                 if(teamplay)
 871                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 872         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 873
 874         if(spectatee_status != 0)
 875         {
 876         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Spectate a player")), "Spectate a player", "spectate \"%s^7\"", 0, 1)
 877         }
 878
 879         if(target_submenu != "" && !target_submenu_found)
 880         {
 881                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 882                 if(prvm_language != "en")
 883                         LOG_INFO("^3Warning: submenu title must be in English");
 884                 QuickMenu_Buffer_Size = 0;
 885         }
 886 }
 887 #undef QUICKMENU_SMENU
 888 #undef QUICKMENU_ENTRY
 889 #undef QUICKMENU_ENTRY_TC