qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/draw.qh>
   5 #include <common/ent_cs.qh>
   6 #include <common/minigames/cl_minigames.qh>
   7 #include <client/hud/_mod.qh>
   8 #include <client/mapvoting.qh>
   9
  10 // QuickMenu (#23)
  11
  12 void HUD_QuickMenu_Export(int fh)
  13 {
  14         // allow saving cvars that aesthetically change the panel into hud skin files
  15         HUD_Write_Cvar("hud_panel_quickmenu_align");
  16 }
  17
  18 // QUICKMENU_MAXLINES must be <= 10
  19 const int QUICKMENU_MAXLINES = 10;
  20 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  21 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  22 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  23 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  24 int QuickMenu_Page_Entries;
  25 int QuickMenu_Page;
  26 int QuickMenu_Page_ActivatedEntry = -1;
  27 bool QuickMenu_Page_ActivatedEntry_Close;
  28 float QuickMenu_Page_ActivatedEntry_Time;
  29 bool QuickMenu_IsLastPage;
  30 // all the entries are loaded into QuickMenu_Buffer
  31 // each entry (submenu or command) is composed of 2 entries
  32 const int QUICKMENU_MAXENTRIES = 256;
  33 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  34 int QuickMenu_Buffer = -1;
  35 int QuickMenu_Buffer_Size;
  36 int QuickMenu_Buffer_Index;
  37 string QuickMenu_CurrentSubMenu;
  38 float QuickMenu_TimeOut;
  39
  40 // QuickMenu_Buffer are labeled with these tags
  41 #define QM_TAG_TITLE "T"
  42 #define QM_TAG_SUBMENU "S"
  43 #define QM_TAG_COMMAND "C"
  44 #define QM_TAG_PLCOMMAND "P"
  45
  46 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  47 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  48
  49 // if s1 is not empty s will be displayed as command otherwise as submenu
  50 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  51 {
  52         TC(int, i);
  53         //LOG_INFOF("^xc80 entry %d: %s, %s\n", i, s, s1);
  54         strcpy(QuickMenu_Page_Description[i], s);
  55         strcpy(QuickMenu_Page_Command[i], s1);
  56 }
  57
  58 void QuickMenu_Page_ClearEntry(int i)
  59 {
  60         TC(int, i);
  61         strfree(QuickMenu_Page_Description[i]);
  62         strfree(QuickMenu_Page_Command[i]);
  63         QuickMenu_Page_Command_Type[i] = 0;
  64 }
  65
  66 bool HUD_QuickMenu_Forbidden()
  67 {
  68         return (mv_active
  69                 || (hud_configure_prev && hud_configure_prev != -1)
  70                 || HUD_MinigameMenu_IsOpened()
  71                 || (QuickMenu_TimeOut && time > QuickMenu_TimeOut));
  72 }
  73
  74 // returns true if succeded, false otherwise
  75 bool QuickMenu_Open(string mode, string submenu, string file)
  76 {
  77         QuickMenu_TimeOut = 0;
  78         if (HUD_QuickMenu_Forbidden())
  79                 return false;
  80
  81         int fh = -1;
  82         string s;
  83
  84         if(mode == "")
  85         {
  86                 if(file == "" || file == "0")
  87                         mode = "default";
  88                 else
  89                         mode = "file";
  90         }
  91
  92         if(mode == "file")
  93         {
  94                 if(file == "" || file == "0")
  95                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu");
  96                 else
  97                 {
  98                         fh = fopen(file, FILE_READ);
  99                         if(fh < 0)
 100                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu", file);
 101                 }
 102                 if(fh < 0)
 103                         mode = "default";
 104         }
 105
 106         if(mode == "default")
 107         {
 108                 QuickMenu_Buffer = buf_create();
 109                 if(QuickMenu_Buffer < 0)
 110                         return false;
 111
 112                 QuickMenu_Default(submenu);
 113         }
 114         else if(mode == "file")
 115         {
 116                 QuickMenu_Buffer = buf_create();
 117                 if(QuickMenu_Buffer < 0)
 118                 {
 119                         fclose(fh);
 120                         return false;
 121                 }
 122
 123                 QuickMenu_Buffer_Size = 0;
 124                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 125                 {
 126                         // first skip invalid entries, so we don't check them anymore
 127                         int argc;
 128                         argc = tokenize_console(s);
 129                         if(argc == 0 || argv(0) == "")
 130                                 continue;
 131                         if(argc == 1)
 132                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 133                         else if(argc == 2)
 134                         {
 135                                 if(argv(1) == "")
 136                                         continue;
 137                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 138                                 ++QuickMenu_Buffer_Size;
 139                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 140                         }
 141                         else if(argc == 3)
 142                         {
 143                                 // check for special keywords
 144                                 float teamplayers = 0, without_me = 0;
 145                                 switch(argv(2))
 146                                 {
 147                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 148                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 149                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 150                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 151                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 152                                         default: continue;
 153                                 }
 154
 155                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 156                                 {
 157                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 158                                         ++QuickMenu_Buffer_Size;
 159                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 160                                         ++QuickMenu_Buffer_Size;
 161                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 162                                         ++QuickMenu_Buffer_Size;
 163                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 164                                 }
 165                         }
 166                         ++QuickMenu_Buffer_Size;
 167                 }
 168                 fclose(fh);
 169         }
 170         else
 171         {
 172                 LOG_WARNF("Unrecognized mode %s", mode);
 173                 return false;
 174         }
 175
 176         if (QuickMenu_Buffer_Size <= 0)
 177         {
 178                 buf_del(QuickMenu_Buffer);
 179                 QuickMenu_Buffer = -1;
 180                 return false;
 181         }
 182
 183         if(mode == "file")
 184                 QuickMenu_Page_Load(submenu, 0);
 185         else
 186                 QuickMenu_Page_Load("", 0);
 187
 188         hudShiftState = 0;
 189
 190         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 191         return true;
 192 }
 193
 194 void QuickMenu_Buffer_Close()
 195 {
 196         if (QuickMenu_Buffer >= 0)
 197         {
 198                 buf_del(QuickMenu_Buffer);
 199                 QuickMenu_Buffer = -1;
 200                 QuickMenu_Buffer_Size = 0;
 201         }
 202 }
 203
 204 void QuickMenu_Close()
 205 {
 206         strfree(QuickMenu_CurrentSubMenu);
 207         int i;
 208         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 209                 QuickMenu_Page_ClearEntry(i);
 210         QuickMenu_Page_Entries = 0;
 211         mouseClicked = 0;
 212         prevMouseClicked = 0;
 213         QuickMenu_Buffer_Close();
 214 }
 215
 216 // It assumes submenu open tag is already detected
 217 void QuickMenu_skip_submenu(string submenu)
 218 {
 219         string z_submenu = string_null; strcpy(z_submenu, submenu);
 220         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 221         {
 222                 string s = QuickMenu_Buffer_Get();
 223                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 224                         continue;
 225                 if(substring(s, 1, -1) == z_submenu) // submenu end
 226                         break;
 227                 QuickMenu_skip_submenu(substring(s, 1, -1));
 228         }
 229         strfree(z_submenu);
 230 }
 231
 232 bool QuickMenu_IsOpened()
 233 {
 234         return (QuickMenu_Page_Entries > 0);
 235 }
 236
 237 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 238 {
 239         TC(int, teamplayers); TC(bool, without_me);
 240         int i;
 241         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 242                 QuickMenu_Page_ClearEntry(i);
 243         QuickMenu_Buffer_Close();
 244
 245         QuickMenu_Buffer = buf_create();
 246         if(QuickMenu_Buffer < 0)
 247                 return false;
 248
 249         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 250
 251         if(QuickMenu_Buffer_Size <= 0)
 252         {
 253                 buf_del(QuickMenu_Buffer);
 254                 QuickMenu_Buffer = -1;
 255                 return false;
 256         }
 257         return true;
 258 }
 259
 260 // new_page 0 means page 0, new_page != 0 means next page
 261 int QuickMenu_Buffer_Index_Prev;
 262 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 263 {
 264         TC(bool, new_page);
 265         string s = string_null, cmd = string_null, z_submenu;
 266
 267         QuickMenu_Page_ActivatedEntry = -1;
 268         if (new_page == 0)
 269                 QuickMenu_Page = 0;
 270         else
 271                 ++QuickMenu_Page;
 272
 273         z_submenu = strzone(target_submenu);
 274         strcpy(QuickMenu_CurrentSubMenu, z_submenu);
 275
 276         QuickMenu_IsLastPage = true;
 277         QuickMenu_Page_Entries = 0;
 278
 279         QuickMenu_Buffer_Index = 0;
 280         if (z_submenu != "")
 281         {
 282                 // skip everything until the submenu open tag is found
 283                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 284                 {
 285                         s = QuickMenu_Buffer_Get();
 286                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 287                         {
 288                                 //LOG_INFOF("^3 beginning of %s\n", z_submenu);
 289                                 ++QuickMenu_Buffer_Index;
 290                                 break; // target_submenu found!
 291                         }
 292                         //LOG_INFOF("^1 skipping %s\n", s);
 293                 }
 294                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 295                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 296         }
 297
 298         // only the last page can contain up to QUICKMENU_MAXLINES entries
 299         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 300         // so that the panel can show an empty row and "Continue..."
 301         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 302         int entry_num = 0; // counts entries in target_submenu
 303         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 304         {
 305                 s = QuickMenu_Buffer_Get();
 306
 307                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 308                 {
 309                         //LOG_INFOF("^3 end of %s\n", z_submenu);
 310                         break;
 311                 }
 312
 313                 if(entry_num >= first_entry)
 314                 {
 315                         ++QuickMenu_Page_Entries;
 316                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 317                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 318                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 319                         {
 320                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 321                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 322                                 QuickMenu_IsLastPage = false;
 323                                 break;
 324                         }
 325                 }
 326
 327                 // NOTE: entries are loaded starting from 1, not from 0
 328                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 329                 {
 330                         if(entry_num >= first_entry)
 331                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 332                         QuickMenu_skip_submenu(substring(s, 1, -1));
 333                 }
 334                 else if(substring(s, 0, 1) == QM_TAG_TITLE)
 335                 {
 336                         ++QuickMenu_Buffer_Index;
 337                         if(entry_num >= first_entry)
 338                         {
 339                                 cmd = QuickMenu_Buffer_Get();
 340                                 string command_code = substring(cmd, 0, 1);
 341                                 if(command_code == QM_TAG_COMMAND)
 342                                         cmd = substring(cmd, 1, -1);
 343                                 else if(command_code == QM_TAG_PLCOMMAND)
 344                                 {
 345                                         // throw away the current quickmenu buffer and load a new one
 346                                         cmd = substring(cmd, 1, -1);
 347                                         strunzone(z_submenu);
 348                                         if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 349                                                 return QuickMenu_Page_Load("", 0);
 350                                         QuickMenu_Close();
 351                                         return false;
 352                                 }
 353
 354                                 tokenize_console(cmd);
 355                                 QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 356
 357                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 358                         }
 359
 360                 }
 361
 362                 ++entry_num;
 363         }
 364         strunzone(z_submenu);
 365         if (QuickMenu_Page_Entries == 0)
 366         {
 367                 QuickMenu_Close();
 368                 return false;
 369         }
 370         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 371         return true;
 372 }
 373
 374 bool QuickMenu_ActionForNumber(int num)
 375 {
 376         TC(int, num);
 377         if (!QuickMenu_IsLastPage)
 378         {
 379                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 380                         return false;
 381                 if (num == QUICKMENU_MAXLINES - 1)
 382                         return false;
 383                 if (num == 0)
 384                 {
 385                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 386                         return false;
 387                 }
 388         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 389                 return false;
 390
 391         if (QuickMenu_Page_Command[num] != "")
 392         {
 393                 QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 394                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 395                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 396                 return true;
 397         }
 398         if (QuickMenu_Page_Description[num] != "")
 399                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 400         return false;
 401 }
 402
 403 void QuickMenu_Page_ActiveEntry(int entry_num)
 404 {
 405         TC(int, entry_num);
 406         QuickMenu_Page_ActivatedEntry = entry_num;
 407         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 408         {
 409                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 410                 // toggle commands don't close the quickmenu
 411                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 412                         QuickMenu_Page_ActivatedEntry_Close = false;
 413                 else
 414                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 415         }
 416         else
 417                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 418 }
 419
 420 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 421 {
 422         TC(int, bInputType);
 423         // we only care for keyboard events
 424         if(bInputType == 2)
 425                 return false;
 426
 427         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 428                 return false;
 429
 430         if(bInputType == 3)
 431         {
 432                 mousepos.x = nPrimary;
 433                 mousepos.y = nSecondary;
 434                 return true;
 435         }
 436
 437         // allow console bind to work
 438         string con_keys = findkeysforcommand("toggleconsole", 0);
 439         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 440         bool hit_con_bind = false;
 441         int i;
 442         for (i = 0; i < keys; ++i)
 443         {
 444                 if(nPrimary == stof(argv(i)))
 445                         hit_con_bind = true;
 446         }
 447
 448         if(bInputType == 0) {
 449                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 450                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 451                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 452         }
 453         else if(bInputType == 1) {
 454                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 455                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 456                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 457         }
 458
 459         if(nPrimary == K_ESCAPE)
 460         {
 461                 if (bInputType == 1)
 462                         return true;
 463                 QuickMenu_Close();
 464         }
 465         else if(nPrimary >= '0' && nPrimary <= '9')
 466         {
 467                 if (bInputType == 1)
 468                         return true;
 469                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 470         }
 471         if(nPrimary == K_MOUSE1)
 472         {
 473                 if(bInputType == 0) // key pressed
 474                         mouseClicked |= S_MOUSE1;
 475                 else if(bInputType == 1) // key released
 476                         mouseClicked -= (mouseClicked & S_MOUSE1);
 477         }
 478         else if(nPrimary == K_MOUSE2)
 479         {
 480                 if(bInputType == 0) // key pressed
 481                         mouseClicked |= S_MOUSE2;
 482                 else if(bInputType == 1) // key released
 483                         mouseClicked -= (mouseClicked & S_MOUSE2);
 484         }
 485         else if(hit_con_bind)
 486                 return false;
 487
 488         return true;
 489 }
 490
 491 void QuickMenu_Mouse()
 492 {
 493         if(mv_active) return;
 494
 495         if(!mouseClicked)
 496         if(prevMouseClicked & S_MOUSE2)
 497         {
 498                 QuickMenu_Close();
 499                 return;
 500         }
 501
 502         panel = HUD_PANEL(QUICKMENU);
 503         HUD_Panel_LoadCvars();
 504
 505         if(panel_bg_padding)
 506         {
 507                 panel_pos += '1 1 0' * panel_bg_padding;
 508                 panel_size -= '2 2 0' * panel_bg_padding;
 509         }
 510
 511         float first_entry_pos, entries_height;
 512         vector fontsize;
 513         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 514         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 515         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 516
 517         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 518         {
 519                 int entry_num = min(QuickMenu_Page_Entries - 1, floor((mousepos.y - first_entry_pos) / fontsize.y));
 520                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 521                 {
 522                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 523                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 524
 525                         if (time > QuickMenu_Page_ActivatedEntry_Time)
 526                         {
 527                                 vector entry_pos = panel_pos;
 528                                 entry_pos.y = first_entry_pos + entry_num * fontsize.y;
 529                                 vector color;
 530                                 if (mouseClicked & S_MOUSE1)
 531                                         color = '0.5 1 0.5';
 532                                 else if (hudShiftState & S_CTRL)
 533                                         color = '1 1 0.3';
 534                                 else
 535                                         color = '1 1 1';
 536                                 drawfill(entry_pos, vec2(panel_size.x, fontsize.y), color, .2, DRAWFLAG_NORMAL);
 537                         }
 538                 }
 539         }
 540 }
 541
 542 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 543 {
 544         string entry;
 545         float offset;
 546         float desc_width = panel_size.x;
 547         if(option)
 548         {
 549                 string pic = strcat(hud_skin_path, "/", option);
 550                 if(precache_pic(pic) == "")
 551                         pic = strcat("gfx/hud/default/", option);
 552                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 553                 desc_width -= option_size.x;
 554                 drawpic(pos + vec2(desc_width, (fontsize.y - option_size.y) / 2), pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 555                 desc_width -= fontsize.x / 4;
 556         }
 557         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 558         if (autocvar_hud_panel_quickmenu_align > 0)
 559         {
 560                 float real_desc_width = stringwidth_colors(entry, fontsize);
 561                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 562
 563                 if(option)
 564                 {
 565                         // when there's enough room align description regardless the checkbox
 566                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 567                         if(offset + real_desc_width + extra_offset < desc_width)
 568                                 offset += extra_offset;
 569                         else
 570                                 offset = max(0, desc_width - real_desc_width);
 571                 }
 572                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 573         }
 574         else
 575                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 576 }
 577
 578 void HUD_QuickMenu()
 579 {
 580         if(!autocvar__hud_configure)
 581         {
 582                 if (!hud_draw_maximized || !QuickMenu_IsOpened())
 583                         return;
 584
 585                 if (HUD_QuickMenu_Forbidden())
 586                 {
 587                         QuickMenu_Close();
 588                         return;
 589                 }
 590         }
 591         else
 592         {
 593                 if(!QuickMenu_IsOpened())
 594                 {
 595                         QuickMenu_Page_Entries = 1;
 596                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 597                         ++QuickMenu_Page_Entries;
 598                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 599                         ++QuickMenu_Page_Entries;
 600                         // although real command doesn't matter here, it must not be empty
 601                         // otherwise the entry is displayed like a submenu
 602                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 603                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 604                         ++QuickMenu_Page_Entries;
 605                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 606                         QuickMenu_IsLastPage = false;
 607                 }
 608         }
 609
 610         HUD_Panel_LoadCvars();
 611
 612         HUD_Scale_Disable();
 613         HUD_Panel_DrawBg();
 614
 615         if(panel_bg_padding)
 616         {
 617                 panel_pos += '1 1 0' * panel_bg_padding;
 618                 panel_size -= '2 2 0' * panel_bg_padding;
 619         }
 620
 621         int i;
 622         vector fontsize;
 623         string color;
 624         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 625
 626         if (!QuickMenu_IsLastPage)
 627         {
 628                 color = "^5";
 629                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 630         }
 631         else
 632                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 633
 634         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 635                 if (QuickMenu_Page_Description[i] == "")
 636                         break;
 637                 string option = string_null;
 638                 if (QuickMenu_Page_Command[i] == "")
 639                         color = "^4";
 640                 else
 641                 {
 642                         color = "^3";
 643                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 644                         {
 645                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 646                                 if(end < 0)
 647                                         tokenize_console(QuickMenu_Page_Command[i]);
 648                                 else
 649                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 650
 651                                 if(argv(1) && argv(0) == "toggle")
 652                                 {
 653                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 654                                         // "disable feature xxx" "toggle xxx 0 1"
 655                                         float ON_value = 1, OFF_value = 0;
 656                                         if(argv(2))
 657                                                 ON_value = stof(argv(2));
 658
 659                                         if(argv(3))
 660                                                 OFF_value = stof(argv(3));
 661                                         else
 662                                                 OFF_value = !ON_value;
 663
 664                                         float value = cvar(argv(1));
 665                                         if(value == ON_value)
 666                                                 option = "checkbox_checked";
 667                                         else if(value == OFF_value)
 668                                                 option = "checkbox_empty";
 669                                         else
 670                                                 option = "checkbox_undefined";
 671                                 }
 672                         }
 673                 }
 674                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 675
 676                 if (time < QuickMenu_Page_ActivatedEntry_Time && QuickMenu_Page_ActivatedEntry == i)
 677                         drawfill(panel_pos, vec2(panel_size.x, fontsize.y), '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 678
 679                 panel_pos.y += fontsize.y;
 680         }
 681
 682         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 683         {
 684                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 685                 {
 686                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 687                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 688                                 QuickMenu_Close();
 689                 }
 690                 else if(QuickMenu_Page_ActivatedEntry_Close)
 691                         QuickMenu_Close();
 692                 QuickMenu_Page_ActivatedEntry = -1;
 693                 QuickMenu_Page_ActivatedEntry_Time = 0;
 694         }
 695 }
 696
 697
 698 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 699         if(target_submenu == eng_submenu && target_submenu_found) \
 700                 return; /* target_submenu entries are now loaded, exit */ \
 701         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 702                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 703         ++QuickMenu_Buffer_Size; \
 704         if(target_submenu == eng_submenu && !target_submenu_found) { \
 705                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 706                 target_submenu_found = true; \
 707         } \
 708 }
 709
 710 #define QUICKMENU_ENTRY(title,command) { \
 711         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 712         { \
 713                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 714                 ++QuickMenu_Buffer_Size; \
 715                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 716         } \
 717         ++QuickMenu_Buffer_Size; \
 718 }
 719
 720 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 721         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 722                 QUICKMENU_SMENU(submenu,eng_submenu) \
 723                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 724                 ++QuickMenu_Buffer_Size; \
 725                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 726                 ++QuickMenu_Buffer_Size; \
 727                 QUICKMENU_SMENU(submenu,eng_submenu) \
 728         } \
 729 }
 730
 731
 732
 733 // useful to Translate a string inside the Command
 734 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 735         if(prvm_language == "en") { \
 736                 tc_title = title; \
 737                 tc_cmd = sprintf(command, text); \
 738         } \
 739         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) { \
 740                 tc_title = strcat("(en)", title); \
 741                 tc_cmd = sprintf(command, text); \
 742         } \
 743         else { \
 744                 tc_title = strcat("(", prvm_language, ")", title); \
 745                 tc_cmd = sprintf(command, translated_text); \
 746         } \
 747         QUICKMENU_ENTRY(tc_title, tc_cmd) \
 748 }
 749
 750 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 751 {
 752         TC(int, teamplayers); TC(bool, without_me);
 753         entity pl;
 754         if(teamplayers && !team_count)
 755                 return;
 756
 757         for(pl = players.sort_next; pl; pl = pl.sort_next)
 758         {
 759                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 760                         continue;
 761                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 762                         continue;
 763                 if(without_me && pl.sv_entnum == player_localnum)
 764                         continue;
 765                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 766         }
 767
 768         return;
 769 }
 770
 771
 772 // Specifying target_submenu, this function only loads entries inside target_submenu
 773 // NOTE: alternatively we could have loaded the whole default quickmenu and
 774 // then called QuickMenu_Page_Load(target_submenu, 0);
 775 // but this sytem is more reliable since we can always refer to target_submenu
 776 // with the English title even if a translation is active
 777 void QuickMenu_Default(string target_submenu)
 778 {
 779         bool target_submenu_found = false;
 780         if(target_submenu != "")
 781                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 782
 783         string tc_title;
 784         string tc_cmd;
 785
 786         QUICKMENU_SMENU(_("Chat"), "Chat")
 787                 QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send public message to")), "Send public message to", "commandmode say %s:^7", 0, 1)
 788                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 789                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 790                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 791                 if(prvm_language != "en")
 792                 QUICKMENU_ENTRY(CTX(_("QMCMD^Send in English")), "toggle hud_panel_quickmenu_translatecommands 0 1; quickmenu; wait; quickmenu default Chat")
 793         QUICKMENU_SMENU(_("Chat"), "Chat")
 794
 795         if(teamplay)
 796         {
 797         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 798                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^strength soon")), "say_team %s", "strength soon", CTX(_("QMCMD^strength soon")))
 799                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 800                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 801                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flagcarrier, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop weapon, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped weapon %w^7 (l:%l^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 813         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 814         }
 815
 816         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 817
 818         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 819                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 820                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 821                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 822                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 823                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 824                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 826                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 827
 828                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 830                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 831                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 832
 833                 if(spectatee_status > 0)
 834                 {
 835                 QUICKMENU_ENTRY(CTX(_("QMCMD^Change spectator camera")), "dropweapon")
 836                 }
 837
 838                 if(spectatee_status == -1)
 839                 {
 840                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 841                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 842                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 843                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision")), "toggle cl_clippedspectating")
 844                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 845                 }
 846
 847                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 848         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 849
 850         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 851                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 852                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 853                 if(STAT(TIMELIMIT) > 0)
 854                 {
 855                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 856                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 857                 }
 858                 if(teamplay)
 859                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 860         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 861
 862         if(spectatee_status != 0)
 863         {
 864         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Spectate a player")), "Spectate a player", "spectate \"%s^7\"", 0, 1)
 865         }
 866
 867         if(target_submenu != "" && !target_submenu_found)
 868         {
 869                 LOG_INFOF("Couldn't find submenu \"%s\"", target_submenu);
 870                 if(prvm_language != "en")
 871                         LOG_INFO("^3Warning: submenu title must be in English");
 872                 QuickMenu_Buffer_Size = 0;
 873         }
 874 }
 875 #undef QUICKMENU_SMENU
 876 #undef QUICKMENU_ENTRY
 877 #undef QUICKMENU_ENTRY_TC