qcsrc/client/hud/panel/quickmenu.qc

   1 #include "quickmenu.qh"
   2
   3 #include "scoreboard.qh"
   4 #include <common/ent_cs.qh>
   5 #include <client/hud/all.qh>
   6 #include <client/mapvoting.qh>
   7
   8 // QuickMenu (#23)
   9
  10 // QUICKMENU_MAXLINES must be <= 10
  11 const int QUICKMENU_MAXLINES = 10;
  12 // visible entries are loaded from QuickMenu_Buffer into QuickMenu_Page_* arrays
  13 string QuickMenu_Page_Command[QUICKMENU_MAXLINES];
  14 string QuickMenu_Page_Description[QUICKMENU_MAXLINES];
  15 int QuickMenu_Page_Command_Type[QUICKMENU_MAXLINES];
  16 int QuickMenu_Page_Entries;
  17 int QuickMenu_Page;
  18 int QuickMenu_Page_ActivatedEntry = -1;
  19 bool QuickMenu_Page_ActivatedEntry_Close;
  20 float QuickMenu_Page_ActivatedEntry_Time;
  21 bool QuickMenu_IsLastPage;
  22 // all the entries are loaded into QuickMenu_Buffer
  23 // each entry (submenu or command) is composed of 2 entries
  24 const int QUICKMENU_MAXENTRIES = 256;
  25 const int QUICKMENU_BUFFER_MAXENTRIES = 2 * QUICKMENU_MAXENTRIES;
  26 int QuickMenu_Buffer = -1;
  27 int QuickMenu_Buffer_Size;
  28 int QuickMenu_Buffer_Index;
  29 string QuickMenu_CurrentSubMenu;
  30 float QuickMenu_TimeOut;
  31
  32 // QuickMenu_Buffer are labeled with these tags
  33 #define QM_TAG_TITLE "T"
  34 #define QM_TAG_SUBMENU "S"
  35 #define QM_TAG_COMMAND "C"
  36 #define QM_TAG_PLCOMMAND "P"
  37
  38 #define QuickMenu_Buffer_Set(tag, string) bufstr_set(QuickMenu_Buffer, QuickMenu_Buffer_Size, strcat(tag, string))
  39 #define QuickMenu_Buffer_Get() bufstr_get(QuickMenu_Buffer, QuickMenu_Buffer_Index)
  40
  41 // if s1 is not empty s will be displayed as command otherwise as submenu
  42 void QuickMenu_Page_LoadEntry(int i, string s, string s1)
  43 {
  44     TC(int, i);
  45         //printf("^xc80 entry %d: %s, %s\n", i, s, s1);
  46         if (QuickMenu_Page_Description[i])
  47                 strunzone(QuickMenu_Page_Description[i]);
  48         QuickMenu_Page_Description[i] = strzone(s);
  49         if (QuickMenu_Page_Command[i])
  50                 strunzone(QuickMenu_Page_Command[i]);
  51         QuickMenu_Page_Command[i] = strzone(s1);
  52 }
  53
  54 void QuickMenu_Page_ClearEntry(int i)
  55 {
  56     TC(int, i);
  57         if (QuickMenu_Page_Description[i])
  58                 strunzone(QuickMenu_Page_Description[i]);
  59         QuickMenu_Page_Description[i] = string_null;
  60         if (QuickMenu_Page_Command[i])
  61                 strunzone(QuickMenu_Page_Command[i]);
  62         QuickMenu_Page_Command[i] = string_null;
  63         QuickMenu_Page_Command_Type[i] = 0;
  64 }
  65
  66 float QuickMenu_Page_Load(string target_submenu, float new_page);
  67 void QuickMenu_Default(string submenu);
  68 bool QuickMenu_Open(string mode, string submenu)
  69 {
  70         int fh = -1;
  71         string s;
  72
  73         if(mode == "")
  74         {
  75                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  76                         mode = "default";
  77                 else
  78                         mode = "file";
  79         }
  80
  81         if(mode == "file")
  82         {
  83                 if(autocvar_hud_panel_quickmenu_file == "" || autocvar_hud_panel_quickmenu_file == "0")
  84                         LOG_INFO("No file name is set in hud_panel_quickmenu_file, loading default quickmenu\n");
  85                 else
  86                 {
  87                         fh = fopen(autocvar_hud_panel_quickmenu_file, FILE_READ);
  88                         if(fh < 0)
  89                                 LOG_INFOF("Couldn't open file \"%s\", loading default quickmenu\n", autocvar_hud_panel_quickmenu_file);
  90                 }
  91                 if(fh < 0)
  92                         mode = "default";
  93         }
  94
  95         if(mode == "default")
  96         {
  97                 QuickMenu_Buffer = buf_create();
  98                 if(QuickMenu_Buffer < 0)
  99                         return false;
 100
 101                 QuickMenu_Default(submenu);
 102         }
 103         else if(mode == "file")
 104         {
 105                 QuickMenu_Buffer = buf_create();
 106                 if(QuickMenu_Buffer < 0)
 107                 {
 108                         fclose(fh);
 109                         return false;
 110                 }
 111
 112                 QuickMenu_Buffer_Size = 0;
 113                 while((s = fgets(fh)) && QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES)
 114                 {
 115                         // first skip invalid entries, so we don't check them anymore
 116                         float argc;
 117                         argc = tokenize_console(s);
 118                         if(argc == 0 || argv(0) == "")
 119                                 continue;
 120                         if(argc == 1)
 121                                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 122                         else if(argc == 2)
 123                         {
 124                                 if(argv(1) == "")
 125                                         continue;
 126                                 QuickMenu_Buffer_Set(QM_TAG_TITLE, argv(0));
 127                                 ++QuickMenu_Buffer_Size;
 128                                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, argv(1));
 129                         }
 130                         else if(argc == 3)
 131                         {
 132                                 // check for special keywords
 133                                 float teamplayers = 0, without_me = 0;
 134                                 switch(argv(2))
 135                                 {
 136                                         case "ALLPLAYERS_BUT_ME":               without_me = 1; // fall through
 137                                         case "ALLPLAYERS":                              teamplayers = 0; break;
 138                                         case "OWNTEAMPLAYERS_BUT_ME":   without_me = 1; // fall through
 139                                         case "OWNTEAMPLAYERS":                  teamplayers = 1; break;
 140                                         case "ENEMYTEAMPLAYERS":                teamplayers = 2; break;
 141                                         default: continue;
 142                                 }
 143
 144                                 if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES)
 145                                 {
 146                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 147                                         ++QuickMenu_Buffer_Size;
 148                                         QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); // put PLCOMMAND arguments in the title string
 149                                         ++QuickMenu_Buffer_Size;
 150                                         QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, argv(1));
 151                                         ++QuickMenu_Buffer_Size;
 152                                         QuickMenu_Buffer_Set(QM_TAG_SUBMENU, argv(0));
 153                                 }
 154                         }
 155                         ++QuickMenu_Buffer_Size;
 156                 }
 157                 fclose(fh);
 158         }
 159         else
 160         {
 161                 LOG_WARNF("Unrecognized mode %s", mode);
 162                 return false;
 163         }
 164
 165         if (QuickMenu_Buffer_Size <= 0)
 166         {
 167                 buf_del(QuickMenu_Buffer);
 168                 QuickMenu_Buffer = -1;
 169                 return false;
 170         }
 171
 172         if(mode == "file")
 173                 QuickMenu_Page_Load(submenu, 0);
 174         else
 175                 QuickMenu_Page_Load("", 0);
 176
 177         hud_panel_quickmenu = 1;
 178         if(autocvar_hud_cursormode)
 179                 setcursormode(1);
 180         hudShiftState = 0;
 181
 182         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 183         return true;
 184 }
 185
 186 void QuickMenu_Buffer_Close()
 187 {
 188         if (QuickMenu_Buffer >= 0)
 189         {
 190                 buf_del(QuickMenu_Buffer);
 191                 QuickMenu_Buffer = -1;
 192                 QuickMenu_Buffer_Size = 0;
 193         }
 194 }
 195
 196 void QuickMenu_Close()
 197 {
 198         if (QuickMenu_CurrentSubMenu)
 199                 strunzone(QuickMenu_CurrentSubMenu);
 200         QuickMenu_CurrentSubMenu = string_null;
 201         int i;
 202         for (i = 0; i < QUICKMENU_MAXLINES; ++i)
 203                 QuickMenu_Page_ClearEntry(i);
 204         QuickMenu_Page_Entries = 0;
 205         hud_panel_quickmenu = 0;
 206         mouseClicked = 0;
 207         prevMouseClicked = 0;
 208         QuickMenu_Buffer_Close();
 209
 210         if(autocvar_hud_cursormode)
 211         if(!mv_active)
 212                 setcursormode(0);
 213 }
 214
 215 // It assumes submenu open tag is already detected
 216 void QuickMenu_skip_submenu(string submenu)
 217 {
 218         string s, z_submenu;
 219         z_submenu = strzone(submenu);
 220         for(++QuickMenu_Buffer_Index ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 221         {
 222                 s = QuickMenu_Buffer_Get();
 223                 if(substring(s, 0, 1) != QM_TAG_SUBMENU)
 224                         continue;
 225                 if(substring(s, 1, -1) == z_submenu) // submenu end
 226                         break;
 227                 QuickMenu_skip_submenu(substring(s, 1, -1));
 228         }
 229         strunzone(z_submenu);
 230 }
 231
 232 bool QuickMenu_IsOpened()
 233 {
 234         return (QuickMenu_Page_Entries > 0);
 235 }
 236
 237 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me);
 238 bool HUD_Quickmenu_PlayerListEntries_Create(string cmd, int teamplayers, bool without_me)
 239 {
 240     TC(int, teamplayers); TC(bool, without_me);
 241         int i;
 242         for(i = 0; i < QUICKMENU_MAXLINES; ++i)
 243                 QuickMenu_Page_ClearEntry(i);
 244         QuickMenu_Buffer_Close();
 245
 246         QuickMenu_Buffer = buf_create();
 247         if(QuickMenu_Buffer < 0)
 248                 return false;
 249
 250         HUD_Quickmenu_PlayerListEntries(cmd, teamplayers, without_me);
 251
 252         if(QuickMenu_Buffer_Size <= 0)
 253         {
 254                 buf_del(QuickMenu_Buffer);
 255                 QuickMenu_Buffer = -1;
 256                 return false;
 257         }
 258         return true;
 259 }
 260
 261 // new_page 0 means page 0, new_page != 0 means next page
 262 int QuickMenu_Buffer_Index_Prev;
 263 bool QuickMenu_Page_Load(string target_submenu, bool new_page)
 264 {
 265     TC(bool, new_page);
 266         string s = string_null, cmd = string_null, z_submenu;
 267
 268         if (new_page == 0)
 269                 QuickMenu_Page = 0;
 270         else
 271                 ++QuickMenu_Page;
 272
 273         z_submenu = strzone(target_submenu);
 274         if (QuickMenu_CurrentSubMenu)
 275                 strunzone(QuickMenu_CurrentSubMenu);
 276         QuickMenu_CurrentSubMenu = strzone(z_submenu);
 277
 278         QuickMenu_IsLastPage = true;
 279         QuickMenu_Page_Entries = 0;
 280
 281         QuickMenu_Buffer_Index = 0;
 282         if (z_submenu != "")
 283         {
 284                 // skip everything until the submenu open tag is found
 285                 for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 286                 {
 287                         s = QuickMenu_Buffer_Get();
 288                         if(substring(s, 0, 1) == QM_TAG_SUBMENU && substring(s, 1, -1) == z_submenu)
 289                         {
 290                                 // printf("^3 beginning of %s\n", z_submenu);
 291                                 ++QuickMenu_Buffer_Index;
 292                                 break; // target_submenu found!
 293                         }
 294                         // printf("^1 skipping %s\n", s);
 295                 }
 296                 if(QuickMenu_Buffer_Index == QuickMenu_Buffer_Size)
 297                         LOG_WARNF("Couldn't find submenu \"%s\"", z_submenu);
 298         }
 299
 300         // only the last page can contain up to QUICKMENU_MAXLINES entries
 301         // the other ones contain only (QUICKMENU_MAXLINES - 2) entries
 302         // so that the panel can show an empty row and "Continue..."
 303         float first_entry = QuickMenu_Page * (QUICKMENU_MAXLINES - 2);
 304         int entry_num = 0; // counts entries in target_submenu
 305         for( ; QuickMenu_Buffer_Index < QuickMenu_Buffer_Size; ++QuickMenu_Buffer_Index)
 306         {
 307                 s = QuickMenu_Buffer_Get();
 308
 309                 if(z_submenu != "" && substring(s, 1, -1) == z_submenu)
 310                 {
 311                         // printf("^3 end of %s\n", z_submenu);
 312                         break;
 313                 }
 314
 315                 if(entry_num >= first_entry)
 316                 {
 317                         ++QuickMenu_Page_Entries;
 318                         if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES - 2)
 319                                 QuickMenu_Buffer_Index_Prev = QuickMenu_Buffer_Index;
 320                         else if(QuickMenu_Page_Entries == QUICKMENU_MAXLINES)
 321                         {
 322                                 QuickMenu_Page_ClearEntry(QUICKMENU_MAXLINES - 1);
 323                                 QuickMenu_Buffer_Index = QuickMenu_Buffer_Index_Prev;
 324                                 QuickMenu_IsLastPage = false;
 325                                 break;
 326                         }
 327                 }
 328
 329                 // NOTE: entries are loaded starting from 1, not from 0
 330                 if(substring(s, 0, 1) == QM_TAG_SUBMENU)
 331                 {
 332                         if(entry_num >= first_entry)
 333                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), "");
 334                         QuickMenu_skip_submenu(substring(s, 1, -1));
 335                 }
 336                 else if(entry_num >= first_entry && substring(s, 0, 1) == QM_TAG_TITLE)
 337                 {
 338                         ++QuickMenu_Buffer_Index;
 339                         cmd = QuickMenu_Buffer_Get();
 340                         string command_code = substring(cmd, 0, 1);
 341                         if(command_code == QM_TAG_COMMAND)
 342                                 cmd = substring(cmd, 1, -1);
 343                         else if(command_code == QM_TAG_PLCOMMAND)
 344                         {
 345                                 // throw away the current quickmenu buffer and load a new one
 346                                 cmd = substring(cmd, 1, -1);
 347                                 strunzone(z_submenu);
 348                                 if(HUD_Quickmenu_PlayerListEntries_Create(cmd, stof(substring(s, 1, 1)), stof(substring(s, 2, 1))))
 349                                         return QuickMenu_Page_Load("", 0);
 350                                 QuickMenu_Close();
 351                                 return false;
 352                         }
 353
 354                         tokenize_console(cmd);
 355                         QuickMenu_Page_Command_Type[QuickMenu_Page_Entries] = (argv(1) && argv(0) == "toggle");
 356
 357                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, substring(s, 1, -1), cmd);
 358                 }
 359
 360                 ++entry_num;
 361         }
 362         strunzone(z_submenu);
 363         if (QuickMenu_Page_Entries == 0)
 364         {
 365                 QuickMenu_Close();
 366                 return false;
 367         }
 368         QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 369         return true;
 370 }
 371
 372 bool QuickMenu_ActionForNumber(int num)
 373 {
 374     TC(int, num);
 375         if (!QuickMenu_IsLastPage)
 376         {
 377                 if (num < 0 || num >= QUICKMENU_MAXLINES)
 378                         return false;
 379                 if (num == QUICKMENU_MAXLINES - 1)
 380                         return false;
 381                 if (num == 0)
 382                 {
 383                         QuickMenu_Page_Load(QuickMenu_CurrentSubMenu, +1);
 384                         return false;
 385                 }
 386         } else if (num <= 0 || num > QuickMenu_Page_Entries)
 387                 return false;
 388
 389         if (QuickMenu_Page_Command[num] != "")
 390         {
 391                 localcmd(strcat("\n", QuickMenu_Page_Command[num], "\n"));
 392                 QuickMenu_TimeOut = ((autocvar_hud_panel_quickmenu_time > 0) ? time + autocvar_hud_panel_quickmenu_time : 0);
 393                 return true;
 394         }
 395         if (QuickMenu_Page_Description[num] != "")
 396                 QuickMenu_Page_Load(QuickMenu_Page_Description[num], 0);
 397         return false;
 398 }
 399
 400 void QuickMenu_Page_ActiveEntry(int entry_num)
 401 {
 402     TC(int, entry_num);
 403         QuickMenu_Page_ActivatedEntry = entry_num;
 404         QuickMenu_Page_ActivatedEntry_Time = time + 0.1;
 405         if(QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 406         {
 407                 bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 408                 // toggle commands don't close the quickmenu
 409                 if(QuickMenu_Page_Command_Type[QuickMenu_Page_ActivatedEntry] == 1)
 410                         QuickMenu_Page_ActivatedEntry_Close = false;
 411                 else
 412                         QuickMenu_Page_ActivatedEntry_Close = (f && !(hudShiftState & S_CTRL));
 413         }
 414         else
 415                 QuickMenu_Page_ActivatedEntry_Close = (!(hudShiftState & S_CTRL));
 416 }
 417
 418 bool QuickMenu_InputEvent(int bInputType, float nPrimary, float nSecondary)
 419 {
 420     TC(int, bInputType);
 421         // we only care for keyboard events
 422         if(bInputType == 2)
 423                 return false;
 424
 425         if(!QuickMenu_IsOpened() || autocvar__hud_configure || mv_active)
 426                 return false;
 427
 428         if(bInputType == 3)
 429         {
 430                 mousepos.x = nPrimary;
 431                 mousepos.y = nSecondary;
 432                 return true;
 433         }
 434
 435         // allow console bind to work
 436         string con_keys = findkeysforcommand("toggleconsole", 0);
 437         int keys = tokenize(con_keys); // findkeysforcommand returns data for this
 438         bool hit_con_bind = false;
 439         int i;
 440         for (i = 0; i < keys; ++i)
 441         {
 442                 if(nPrimary == stof(argv(i)))
 443                         hit_con_bind = true;
 444         }
 445
 446         if(bInputType == 0) {
 447                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 448                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 449                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 450         }
 451         else if(bInputType == 1) {
 452                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 453                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 454                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 455         }
 456
 457         if(nPrimary == K_ESCAPE)
 458         {
 459                 if (bInputType == 1)
 460                         return true;
 461                 QuickMenu_Close();
 462         }
 463         else if(nPrimary >= '0' && nPrimary <= '9')
 464         {
 465                 if (bInputType == 1)
 466                         return true;
 467                 QuickMenu_Page_ActiveEntry(stof(chr2str(nPrimary)));
 468         }
 469         if(nPrimary == K_MOUSE1)
 470         {
 471                 if(bInputType == 0) // key pressed
 472                         mouseClicked |= S_MOUSE1;
 473                 else if(bInputType == 1) // key released
 474                         mouseClicked -= (mouseClicked & S_MOUSE1);
 475         }
 476         else if(nPrimary == K_MOUSE2)
 477         {
 478                 if(bInputType == 0) // key pressed
 479                         mouseClicked |= S_MOUSE2;
 480                 else if(bInputType == 1) // key released
 481                         mouseClicked -= (mouseClicked & S_MOUSE2);
 482         }
 483         else if(hit_con_bind)
 484                 return false;
 485
 486         return true;
 487 }
 488
 489 void QuickMenu_Mouse()
 490 {
 491         if(mv_active) return;
 492
 493         if(!mouseClicked)
 494         if(prevMouseClicked & S_MOUSE2)
 495         {
 496                 QuickMenu_Close();
 497                 return;
 498         }
 499
 500         if(!autocvar_hud_cursormode)
 501         {
 502                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 503
 504                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
 505                 mousepos.y = bound(0, mousepos.y, vid_conheight);
 506         }
 507
 508         if(1 - scoreboard_fade_alpha <= 0)
 509                 return;
 510         HUD_Panel_UpdateCvars(1 - scoreboard_fade_alpha);
 511
 512         if(panel_bg_padding)
 513         {
 514                 panel_pos += '1 1 0' * panel_bg_padding;
 515                 panel_size -= '2 2 0' * panel_bg_padding;
 516         }
 517
 518         float first_entry_pos, entries_height;
 519         vector fontsize;
 520         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 521         first_entry_pos = panel_pos.y + ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 522         entries_height = panel_size.y - ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y);
 523
 524         if (mousepos.x >= panel_pos.x && mousepos.y >= first_entry_pos && mousepos.x <= panel_pos.x + panel_size.x && mousepos.y <= first_entry_pos + entries_height)
 525         {
 526                 float entry_num;
 527                 entry_num = floor((mousepos.y - first_entry_pos) / fontsize.y);
 528                 if (QuickMenu_IsLastPage || entry_num != QUICKMENU_MAXLINES - 2)
 529                 {
 530                         panel_pos.y = first_entry_pos + entry_num * fontsize.y;
 531                         vector color;
 532                         if(mouseClicked & S_MOUSE1)
 533                                 color = '0.5 1 0.5';
 534                         else if(hudShiftState & S_CTRL)
 535                                 color = '1 1 0.3';
 536                         else
 537                                 color = '1 1 1';
 538                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, color, .2, DRAWFLAG_NORMAL);
 539
 540                         if(!mouseClicked && (prevMouseClicked & S_MOUSE1))
 541                                 QuickMenu_Page_ActiveEntry((entry_num < QUICKMENU_MAXLINES - 1) ? entry_num + 1 : 0);
 542                 }
 543         }
 544
 545         draw_cursor_normal(mousepos, '1 1 1', 0.8);
 546
 547         prevMouseClicked = mouseClicked;
 548 }
 549
 550 void HUD_Quickmenu_DrawEntry(vector pos, string desc, string option, vector fontsize)
 551 {
 552         string entry;
 553         float offset;
 554         float desc_width = panel_size.x;
 555         if(option)
 556         {
 557                 string pic = strcat(hud_skin_path, "/", option);
 558                 if(precache_pic(pic) == "")
 559                         pic = strcat("gfx/hud/default/", option);
 560                 vector option_size = '1 1 0' * fontsize.y * 0.8;
 561                 desc_width -= option_size.x;
 562                 drawpic(pos + eX * desc_width + eY * (fontsize.y - option_size.y) / 2, pic, option_size, '1 1 1', panel_fg_alpha, DRAWFLAG_ADDITIVE);
 563                 desc_width -= fontsize.x / 4;
 564         }
 565         entry = textShortenToWidth(desc, desc_width, fontsize, stringwidth_colors);
 566         if (autocvar_hud_panel_quickmenu_align > 0)
 567         {
 568                 float real_desc_width = stringwidth_colors(entry, fontsize);
 569                 offset = (desc_width - real_desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 570
 571                 if(option)
 572                 {
 573                         // when there's enough room align description regardless the checkbox
 574                         float extra_offset = (panel_size.x - desc_width) * min(autocvar_hud_panel_quickmenu_align, 1);
 575                         if(offset + real_desc_width + extra_offset < desc_width)
 576                                 offset += extra_offset;
 577                         else
 578                                 offset = max(0, desc_width - real_desc_width);
 579                 }
 580                 drawcolorcodedstring(pos + eX * offset, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 581         }
 582         else
 583                 drawcolorcodedstring(pos, entry, fontsize, panel_fg_alpha, DRAWFLAG_ADDITIVE);
 584 }
 585
 586 void HUD_QuickMenu()
 587 {
 588         if(!autocvar__hud_configure)
 589         {
 590                 if (hud_configure_prev && hud_configure_prev != -1)
 591                         QuickMenu_Close();
 592
 593                 if(!hud_draw_maximized) return;
 594                 if(mv_active) return;
 595                 //if(!autocvar_hud_panel_quickmenu) return;
 596                 if(!hud_panel_quickmenu) return;
 597
 598                 if(QuickMenu_TimeOut)
 599                 if(time > QuickMenu_TimeOut)
 600                 {
 601                         QuickMenu_Close();
 602                         return;
 603                 }
 604         }
 605         else
 606         {
 607                 if(!QuickMenu_IsOpened())
 608                 {
 609                         QuickMenu_Page_Entries = 1;
 610                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 611                         ++QuickMenu_Page_Entries;
 612                         QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Submenu%d"), QuickMenu_Page_Entries), "");
 613                         ++QuickMenu_Page_Entries;
 614                         // although real command doesn't matter here, it must not be empty
 615                         // otherwise the entry is displayed like a submenu
 616                         for (; QuickMenu_Page_Entries < QUICKMENU_MAXLINES - 1; ++QuickMenu_Page_Entries)
 617                                 QuickMenu_Page_LoadEntry(QuickMenu_Page_Entries, sprintf(_("Command%d"), QuickMenu_Page_Entries), "-");
 618                         ++QuickMenu_Page_Entries;
 619                         QuickMenu_Page_ClearEntry(QuickMenu_Page_Entries);
 620                         QuickMenu_IsLastPage = false;
 621                 }
 622         }
 623
 624         if(1 - scoreboard_fade_alpha <= 0)
 625                 return;
 626         HUD_Panel_UpdateCvars(1 - scoreboard_fade_alpha);
 627
 628         HUD_Scale_Disable();
 629         HUD_Panel_DrawBg();
 630
 631         if(panel_bg_padding)
 632         {
 633                 panel_pos += '1 1 0' * panel_bg_padding;
 634                 panel_size -= '2 2 0' * panel_bg_padding;
 635         }
 636
 637         int i;
 638         vector fontsize;
 639         string color;
 640         fontsize = '1 1 0' * (panel_size.y / QUICKMENU_MAXLINES);
 641
 642         if (!QuickMenu_IsLastPage)
 643         {
 644                 color = "^5";
 645                 HUD_Quickmenu_DrawEntry(panel_pos + eY * (panel_size.y - fontsize.y), sprintf("%d: %s%s", 0, color, _("Continue...")), string_null, fontsize);
 646         }
 647         else
 648                 panel_pos.y += ((QUICKMENU_MAXLINES - QuickMenu_Page_Entries) * fontsize.y) / 2;
 649
 650         for (i = 1; i <= QuickMenu_Page_Entries; ++i) {
 651                 if (QuickMenu_Page_Description[i] == "")
 652                         break;
 653                 string option = string_null;
 654                 if (QuickMenu_Page_Command[i] == "")
 655                         color = "^4";
 656                 else
 657                 {
 658                         color = "^3";
 659                         if(QuickMenu_Page_Command_Type[i] == 1) // toggle command
 660                         {
 661                                 int end = strstrofs(QuickMenu_Page_Command[i], ";", 0);
 662                                 if(end < 0)
 663                                         tokenize_console(QuickMenu_Page_Command[i]);
 664                                 else
 665                                         tokenize_console(substring(QuickMenu_Page_Command[i], 0, end));
 666
 667                                 if(argv(1) && argv(0) == "toggle")
 668                                 {
 669                                         // "enable feature xxx" "toggle xxx" (or "toggle xxx 1 0")
 670                                         // "disable feature xxx" "toggle xxx 0 1"
 671                                         float ON_value = 1, OFF_value = 0;
 672                                         if(argv(2))
 673                                                 ON_value = stof(argv(2));
 674
 675                                         if(argv(3))
 676                                                 OFF_value = stof(argv(3));
 677                                         else
 678                                                 OFF_value = !ON_value;
 679
 680                                         float value = cvar(argv(1));
 681                                         if(value == ON_value)
 682                                                 option = "checkbox_checked";
 683                                         else if(value == OFF_value)
 684                                                 option = "checkbox_empty";
 685                                         else
 686                                                 option = "checkbox_undefined";
 687                                 }
 688                         }
 689                 }
 690                 HUD_Quickmenu_DrawEntry(panel_pos, sprintf("%d: %s%s", i, color, QuickMenu_Page_Description[i]), option, fontsize);
 691
 692                 if(QuickMenu_Page_ActivatedEntry_Time && time < QuickMenu_Page_ActivatedEntry_Time
 693                         && QuickMenu_Page_ActivatedEntry == i)
 694                         drawfill(panel_pos, eX * panel_size.x + eY * fontsize.y, '0.5 1 0.5', .2, DRAWFLAG_NORMAL);
 695
 696                 panel_pos.y += fontsize.y;
 697         }
 698
 699         if(QuickMenu_Page_ActivatedEntry >= 0 && time >= QuickMenu_Page_ActivatedEntry_Time)
 700         {
 701                 if(!QuickMenu_Page_Command[QuickMenu_Page_ActivatedEntry])
 702                 {
 703                         bool f = QuickMenu_ActionForNumber(QuickMenu_Page_ActivatedEntry);
 704                         if(f && QuickMenu_Page_ActivatedEntry_Close)
 705                                 QuickMenu_Close();
 706                 }
 707                 else if(QuickMenu_Page_ActivatedEntry_Close)
 708                         QuickMenu_Close();
 709                 QuickMenu_Page_ActivatedEntry = -1;
 710                 QuickMenu_Page_ActivatedEntry_Time = 0;
 711         }
 712 }
 713
 714
 715 #define QUICKMENU_SMENU(submenu,eng_submenu) { \
 716         if(target_submenu == eng_submenu && target_submenu_found) \
 717                 return; /* target_submenu entries are now loaded, exit */ \
 718         if(QuickMenu_Buffer_Size < QUICKMENU_BUFFER_MAXENTRIES) \
 719                 QuickMenu_Buffer_Set(QM_TAG_SUBMENU, submenu); \
 720         ++QuickMenu_Buffer_Size; \
 721         if(target_submenu == eng_submenu && !target_submenu_found) { \
 722                 QuickMenu_Buffer_Size = 0; /* enable load of next entries */ \
 723                 target_submenu_found = true; \
 724         } \
 725 }
 726
 727 #define QUICKMENU_ENTRY(title,command) { \
 728         if(QuickMenu_Buffer_Size + 1 < QUICKMENU_BUFFER_MAXENTRIES) \
 729         { \
 730                 QuickMenu_Buffer_Set(QM_TAG_TITLE, title); \
 731                 ++QuickMenu_Buffer_Size; \
 732                 QuickMenu_Buffer_Set(QM_TAG_COMMAND, command); \
 733         } \
 734         ++QuickMenu_Buffer_Size; \
 735 }
 736
 737 #define QUICKMENU_SMENU_PL(submenu,eng_submenu,command,teamplayers,without_me) { \
 738         if(QuickMenu_Buffer_Size + 3 < QUICKMENU_BUFFER_MAXENTRIES) {\
 739                 QUICKMENU_SMENU(submenu,eng_submenu) \
 740                 QuickMenu_Buffer_Set(QM_TAG_TITLE, strcat(ftos(teamplayers), ftos(without_me))); \
 741                 ++QuickMenu_Buffer_Size; \
 742                 QuickMenu_Buffer_Set(QM_TAG_PLCOMMAND, command); \
 743                 ++QuickMenu_Buffer_Size; \
 744                 QUICKMENU_SMENU(submenu,eng_submenu) \
 745         } \
 746 }
 747
 748
 749
 750 // useful to Translate a string inside the Command
 751 #define QUICKMENU_ENTRY_TC(title,command,text,translated_text) {\
 752         if(prvm_language == "en") \
 753                 QUICKMENU_ENTRY(title, sprintf(command, text)) \
 754         else if(!autocvar_hud_panel_quickmenu_translatecommands || translated_text == text) \
 755                 QUICKMENU_ENTRY(strcat("(en)", title), sprintf(command, text)) \
 756         else \
 757                 QUICKMENU_ENTRY(strcat("(", prvm_language, ")", title), sprintf(command, translated_text)) \
 758 }
 759
 760 void HUD_Quickmenu_PlayerListEntries(string cmd, int teamplayers, bool without_me)
 761 {
 762     TC(int, teamplayers); TC(bool, without_me);
 763         entity pl;
 764         if(teamplayers && !team_count)
 765                 return;
 766
 767         for(pl = players.sort_next; pl; pl = pl.sort_next)
 768         {
 769                 if(teamplayers == 1 && (pl.team != myteam || pl.team == NUM_SPECTATOR)) // only own team players
 770                         continue;
 771                 if(teamplayers == 2 && (pl.team == myteam || pl.team == NUM_SPECTATOR)) // only enemy team players
 772                         continue;
 773                 if(without_me && pl.sv_entnum == player_localnum)
 774                         continue;
 775                 QUICKMENU_ENTRY(entcs_GetName(pl.sv_entnum), sprintf(cmd, entcs_GetName(pl.sv_entnum)))
 776         }
 777
 778         return;
 779 }
 780
 781
 782 // Specifying target_submenu, this function only loads entries inside target_submenu
 783 // NOTE: alternatively we could have loaded the whole default quickmenu and
 784 // then called QuickMenu_Page_Load(target_submenu, 0);
 785 // but this sytem is more reliable since we can always refer to target_submenu
 786 // with the English title even if a translation is active
 787 void QuickMenu_Default(string target_submenu)
 788 {
 789         bool target_submenu_found = false;
 790         if(target_submenu != "")
 791                 QuickMenu_Buffer_Size = QUICKMENU_BUFFER_MAXENTRIES; // forbids load of next entries until target_submenu
 792
 793         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 794                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^nice one")), "say %s", ":-) / nice one", CTX(_("QMCMD^:-) / nice one")))
 795                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^good game")), "say %s", "good game", CTX(_("QMCMD^good game")))
 796                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^hi / good luck")), "say %s", "hi / good luck and have fun", CTX(_("QMCMD^hi / good luck and have fun")))
 797         QUICKMENU_SMENU(CTX(_("QMCMD^Chat")), "Chat")
 798
 799         if(teamplay)
 800         {
 801         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 802                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^quad soon")), "say_team %s", "quad soon", CTX(_("QMCMD^quad soon")))
 803                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^free item, icon")), "say_team %s; g_waypointsprite_team_here_p", "free item %x^7 (l:%y^7)", CTX(_("QMCMD^free item %x^7 (l:%y^7)")))
 804                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^took item, icon")), "say_team %s; g_waypointsprite_team_here", "took item (l:%l^7)", CTX(_("QMCMD^took item (l:%l^7)")))
 805                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^negative")), "say_team %s", "negative", CTX(_("QMCMD^negative")))
 806                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^positive")), "say_team %s", "positive", CTX(_("QMCMD^positive")))
 807                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^need help, icon")), "say_team %s; g_waypointsprite_team_helpme; cmd voice needhelp", "need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^need help (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 808                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^enemy seen, icon")), "say_team %s; g_waypointsprite_team_danger_p; cmd voice incoming", "enemy seen (l:%y^7)", CTX(_("QMCMD^enemy seen (l:%y^7)")))
 809                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^flag seen, icon")), "say_team %s; g_waypointsprite_team_here_p; cmd voice seenflag", "flag seen (l:%y^7)", CTX(_("QMCMD^flag seen (l:%y^7)")))
 810                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^defending, icon")), "say_team %s; g_waypointsprite_team_here", "defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^defending (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 811                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^roaming, icon")), "say_team %s; g_waypointsprite_team_here", "roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^roaming (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 812                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^attacking, icon")), "say_team %s; g_waypointsprite_team_here", "attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)", CTX(_("QMCMD^attacking (l:%l^7) (h:%h^7 a:%a^7 w:%w^7)")))
 813                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^killed flag, icon")), "say_team %s; g_waypointsprite_team_here_p", "killed flagcarrier (l:%y^7)", CTX(_("QMCMD^killed flagcarrier (l:%y^7)")))
 814                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^dropped flag, icon")), "say_team %s; g_waypointsprite_team_here_d", "dropped flag (l:%d^7)", CTX(_("QMCMD^dropped flag (l:%d^7)")))
 815                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop gun, icon")), "say_team %s; g_waypointsprite_team_here; wait; dropweapon", "dropped gun %w^7 (l:%l^7)", CTX(_("QMCMD^dropped gun %w^7 (l:%l^7)")))
 816                 QUICKMENU_ENTRY_TC(CTX(_("QMCMD^drop flag/key, icon")), "say_team %s; g_waypointsprite_team_here; wait; use", "dropped flag/key %w^7 (l:%l^7)", CTX(_("QMCMD^dropped flag/key %w^7 (l:%l^7)")))
 817         QUICKMENU_SMENU(CTX(_("QMCMD^Team chat")), "Team chat")
 818         }
 819
 820         QUICKMENU_SMENU_PL(CTX(_("QMCMD^Send private message to")), "Send private message to", "commandmode tell \"%s^7\"", 0, 1)
 821
 822         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 823                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 824                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person view")), "toggle chase_active")
 825                         QUICKMENU_ENTRY(CTX(_("QMCMD^Player models like mine")), "toggle cl_forceplayermodels")
 826                         QUICKMENU_ENTRY(CTX(_("QMCMD^Names above players")), "toggle hud_shownames")
 827                         QUICKMENU_ENTRY(CTX(_("QMCMD^Crosshair per weapon")), "toggle crosshair_per_weapon")
 828                         QUICKMENU_ENTRY(CTX(_("QMCMD^FPS")), "toggle hud_panel_engineinfo")
 829                         QUICKMENU_ENTRY(CTX(_("QMCMD^Net graph")), "toggle shownetgraph")
 830                 QUICKMENU_SMENU(CTX(_("QMCMD^View/HUD settings")), "View/HUD settings")
 831
 832                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 833                         QUICKMENU_ENTRY(CTX(_("QMCMD^Hit sound")), "toggle cl_hitsound")
 834                         QUICKMENU_ENTRY(CTX(_("QMCMD^Chat sound")), "toggle con_chatsound")
 835                 QUICKMENU_SMENU(CTX(_("QMCMD^Sound settings")), "Sound settings")
 836
 837                 if(spectatee_status > 0)
 838                 {
 839                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 840                         QUICKMENU_ENTRY(CTX(_("QMCMD^1st person")), "chase_active 0; -use")
 841                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person around player")), "chase_active 1; +use")
 842                         QUICKMENU_ENTRY(CTX(_("QMCMD^3rd person behind")), "chase_active 1; -use")
 843                 QUICKMENU_SMENU(CTX(_("QMCMD^Spectator camera")), "Spectator camera")
 844                 }
 845
 846                 if(spectatee_status == -1)
 847                 {
 848                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 849                         QUICKMENU_ENTRY(CTX(_("QMCMD^Increase speed")), "weapnext")
 850                         QUICKMENU_ENTRY(CTX(_("QMCMD^Decrease speed")), "weapprev")
 851                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision off")), "+use")
 852                         QUICKMENU_ENTRY(CTX(_("QMCMD^Wall collision on")), "-use")
 853                 QUICKMENU_SMENU(CTX(_("QMCMD^Observer camera")), "Observer camera")
 854                 }
 855
 856                 QUICKMENU_ENTRY(CTX(_("QMCMD^Fullscreen")), "toggle vid_fullscreen; vid_restart")
 857                 if(prvm_language != "en")
 858                 QUICKMENU_ENTRY(CTX(_("QMCMD^Translate chat messages")), "toggle hud_panel_quickmenu_translatecommands")
 859         QUICKMENU_SMENU(CTX(_("QMCMD^Settings")), "Settings")
 860
 861         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 862                 QUICKMENU_ENTRY(CTX(_("QMCMD^Restart the map")), "vcall restart")
 863                 QUICKMENU_ENTRY(CTX(_("QMCMD^End match")), "vcall endmatch")
 864                 if(STAT(TIMELIMIT) > 0)
 865                 {
 866                 QUICKMENU_ENTRY(CTX(_("QMCMD^Reduce match time")), "vcall reducematchtime")
 867                 QUICKMENU_ENTRY(CTX(_("QMCMD^Extend match time")), "vcall extendmatchtime")
 868                 }
 869                 if(teamplay)
 870                 QUICKMENU_ENTRY(CTX(_("QMCMD^Shuffle teams")), "vcall shuffleteams")
 871         QUICKMENU_SMENU(CTX(_("QMCMD^Call a vote")), "Call a vote")
 872
 873         if(target_submenu != "" && !target_submenu_found)
 874         {
 875                 LOG_WARNF("Couldn't find submenu \"%s\"", target_submenu);
 876                 if(prvm_language != "en")
 877                         LOG_WARNF("^3Warning: submenu must be in English", target_submenu);
 878                 QuickMenu_Buffer_Size = 0;
 879         }
 880 }
 881 #undef QUICKMENU_SMENU
 882 #undef QUICKMENU_ENTRY
 883 #undef QUICKMENU_ENTRY_TC