qcsrc/client/hud/panel/timer.qc

   1 #include "timer.qh"
   2 void HUD_Timer()
   3 {
   4         if(!autocvar__hud_configure)
   5         {
   6                 if(!autocvar_hud_panel_timer) return;
   7         }
   8
   9         HUD_Panel_UpdateCvars();
  10
  11         draw_beginBoldFont();
  12
  13         vector pos, mySize;
  14         pos = panel_pos;
  15         mySize = panel_size;
  16
  17         HUD_Scale_Enable();
  18         HUD_Panel_DrawBg(1);
  19         if(panel_bg_padding)
  20         {
  21                 pos += '1 1 0' * panel_bg_padding;
  22                 mySize -= '2 2 0' * panel_bg_padding;
  23         }
  24
  25         string timer;
  26         float timelimit, elapsedTime, timeleft, minutesLeft;
  27
  28         timelimit = STAT(TIMELIMIT);
  29
  30         timeleft = max(0, timelimit * 60 + STAT(GAMESTARTTIME) - time);
  31         timeleft = ceil(timeleft);
  32
  33         minutesLeft = floor(timeleft / 60);
  34
  35         float warmup_timeleft = 0;
  36         if(warmup_stage)
  37         {
  38                 float warmup_timelimit = STAT(WARMUP_TIMELIMIT);
  39                 if(warmup_timelimit > 0)
  40                         warmup_timeleft = max(0, warmup_timelimit - time);
  41                 else if(warmup_timelimit == 0)
  42                         warmup_timeleft = timeleft;
  43                 warmup_timeleft = ceil(warmup_timeleft);
  44         }
  45
  46         vector timer_color;
  47         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
  48                 timer_color = '1 1 1'; //white
  49         else if(minutesLeft >= 1)
  50                 timer_color = '1 1 0'; //yellow
  51         else
  52                 timer_color = '1 0 0'; //red
  53
  54         if (autocvar_hud_panel_timer_increment || (!warmup_stage && timelimit == 0) || (warmup_stage && warmup_timeleft <= 0)) {
  55                 if (time < STAT(GAMESTARTTIME)) {
  56                         //while restart is still active, show 00:00
  57                         timer = seconds_tostring(0);
  58                 } else {
  59                         elapsedTime = floor(time - STAT(GAMESTARTTIME));
  60                         timer = seconds_tostring(elapsedTime);
  61                 }
  62         } else {
  63                 if(warmup_stage)
  64                         timer = seconds_tostring(warmup_timeleft);
  65                 else
  66                         timer = seconds_tostring(timeleft);
  67         }
  68
  69         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
  70
  71         draw_endBoldFont();
  72 }