qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_iconalign");
  92                                         HUD_Write_PanelCvar_q("_progressbar");
  93                                         HUD_Write_PanelCvar_q("_progressbar_name");
  94                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  95                                         HUD_Write_PanelCvar_q("_text");
  96                                         break;
  97                                 case HUD_PANEL_POWERUPS:
  98                                         HUD_Write_PanelCvar_q("_flip");
  99                                         HUD_Write_PanelCvar_q("_iconalign");
 100                                         HUD_Write_PanelCvar_q("_baralign");
 101                                         HUD_Write_PanelCvar_q("_progressbar");
 102                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 103                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 104                                         HUD_Write_PanelCvar_q("_text");
 105                                         break;
 106                                 case HUD_PANEL_HEALTHARMOR:
 107                                         HUD_Write_PanelCvar_q("_flip");
 108                                         HUD_Write_PanelCvar_q("_iconalign");
 109                                         HUD_Write_PanelCvar_q("_baralign");
 110                                         HUD_Write_PanelCvar_q("_progressbar");
 111                                         HUD_Write_PanelCvar_q("_progressbar_health");
 112                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 113                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 114                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 115                                         HUD_Write_PanelCvar_q("_text");
 116                                         break;
 117                                 case HUD_PANEL_NOTIFY:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         HUD_Write_PanelCvar_q("_fontsize");
 120                                         HUD_Write_PanelCvar_q("_time");
 121                                         HUD_Write_PanelCvar_q("_fadetime");
 122                                         break;
 123                                 case HUD_PANEL_TIMER:
 124                                         HUD_Write_PanelCvar_q("_increment");
 125                                         break;
 126                                 case HUD_PANEL_RADAR:
 127                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 128                                         HUD_Write_PanelCvar_q("_rotation");
 129                                         HUD_Write_PanelCvar_q("_zoommode");
 130                                         HUD_Write_PanelCvar_q("_scale");
 131                                         HUD_Write_PanelCvar_q("_maximized_scale");
 132                                         HUD_Write_PanelCvar_q("_maximized_size");
 133                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 134                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 135                                         break;
 136                                 case HUD_PANEL_SCORE:
 137                                         HUD_Write_PanelCvar_q("_rankings");
 138                                         break;
 139                                 case HUD_PANEL_VOTE:
 140                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 141                                         break;
 142                                 case HUD_PANEL_MODICONS:
 143                                         HUD_Write_PanelCvar_q("_dom_layout");
 144                                         break;
 145                                 case HUD_PANEL_PRESSEDKEYS:
 146                                         HUD_Write_PanelCvar_q("_aspect");
 147                                         HUD_Write_PanelCvar_q("_attack");
 148                                         break;
 149                                 case HUD_PANEL_ENGINEINFO:
 150                                         HUD_Write_PanelCvar_q("_framecounter_time");
 151                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 152                                         break;
 153                                 case HUD_PANEL_INFOMESSAGES:
 154                                         HUD_Write_PanelCvar_q("_flip");
 155                                         break;
 156                                 case HUD_PANEL_PHYSICS:
 157                                         HUD_Write_PanelCvar_q("_speed_unit");
 158                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 159                                         HUD_Write_PanelCvar_q("_speed_max");
 160                                         HUD_Write_PanelCvar_q("_speed_vertical");
 161                                         HUD_Write_PanelCvar_q("_topspeed");
 162                                         HUD_Write_PanelCvar_q("_topspeed_time");
 163                                         HUD_Write_PanelCvar_q("_acceleration_max");
 164                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 165                                         HUD_Write_PanelCvar_q("_flip");
 166                                         HUD_Write_PanelCvar_q("_baralign");
 167                                         HUD_Write_PanelCvar_q("_progressbar");
 168                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 169                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 170                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 171                                         HUD_Write_PanelCvar_q("_text");
 172                                         HUD_Write_PanelCvar_q("_text_scale");
 173                                         break;
 174                                 case HUD_PANEL_CENTERPRINT:
 175                                         HUD_Write_PanelCvar_q("_align");
 176                                         HUD_Write_PanelCvar_q("_flip");
 177                                         HUD_Write_PanelCvar_q("_fontscale");
 178                                         HUD_Write_PanelCvar_q("_time");
 179                                         HUD_Write_PanelCvar_q("_fade_in");
 180                                         HUD_Write_PanelCvar_q("_fade_out");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 184                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 185                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 187                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 188                                         break;
 189                         }
 190                         HUD_Write("\n");
 191                 }
 192                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 193
 194                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 195                 fclose(fh);
 196         }
 197         else
 198                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 199 }
 200
 201 void HUD_Configure_Exit_Force()
 202 {
 203         if (menu_enabled)
 204         {
 205                 menu_enabled = 0;
 206                 localcmd("togglemenu\n");
 207         }
 208         cvar_set("_hud_configure", "0");
 209 }
 210
 211 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 212 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 213 {
 214         float i;
 215         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 216         vector myTarget;
 217         myTarget = myPos;
 218
 219         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 220                 if(i == highlightedPanel || !panel_enabled)
 221                         continue;
 222
 223                 HUD_Panel_UpdatePosSizeForId(i);
 224
 225                 panel_pos -= '1 1 0' * panel_bg_border;
 226                 panel_size += '2 2 0' * panel_bg_border;
 227
 228                 if(myPos_y + mySize_y < panel_pos_y)
 229                         continue;
 230                 if(myPos_y > panel_pos_y + panel_size_y)
 231                         continue;
 232
 233                 if(myPos_x + mySize_x < panel_pos_x)
 234                         continue;
 235                 if(myPos_x > panel_pos_x + panel_size_x)
 236                         continue;
 237
 238                 // OK, there IS a collision.
 239
 240                 myCenter_x = myPos_x + 0.5 * mySize_x;
 241                 myCenter_y = myPos_y + 0.5 * mySize_y;
 242
 243                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 244                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 245
 246                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 247                 {
 248                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 249                                 myTarget_x = panel_pos_x - mySize_x;
 250                         else // push it upwards
 251                                 myTarget_y = panel_pos_y - mySize_y;
 252                 }
 253                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 254                 {
 255                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 256                                 myTarget_x = panel_pos_x + panel_size_x;
 257                         else // push it upwards
 258                                 myTarget_y = panel_pos_y - mySize_y;
 259                 }
 260                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 261                 {
 262                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 263                                 myTarget_x = panel_pos_x - mySize_x;
 264                         else // push it downwards
 265                                 myTarget_y = panel_pos_y + panel_size_y;
 266                 }
 267                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 268                 {
 269                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 270                                 myTarget_x = panel_pos_x + panel_size_x;
 271                         else // push it downwards
 272                                 myTarget_y = panel_pos_y + panel_size_y;
 273                 }
 274                 //if(cvar("hud_configure_checkcollisions_debug"))
 275                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 276         }
 277
 278         return myTarget;
 279 }
 280
 281 void HUD_Panel_SetPos(vector pos)
 282 {
 283         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 284         vector mySize;
 285         mySize = panel_size;
 286
 287         //if(cvar("hud_configure_checkcollisions_debug"))
 288                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 289
 290         if(autocvar_hud_configure_grid)
 291         {
 292                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 293                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 294         }
 295
 296         if(hud_configure_checkcollisions)
 297                 pos = HUD_Panel_CheckMove(pos, mySize);
 298
 299         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 300         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 301
 302         string s;
 303         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 304
 305         HUD_Panel_GetName(highlightedPanel);
 306         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 307 }
 308
 309 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 310 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 311         float i;
 312
 313         vector targEndPos;
 314
 315         float dist_x, dist_y;
 316         float ratio;
 317         ratio = mySize_x/mySize_y;
 318
 319         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 320                 if(i == highlightedPanel || !panel_enabled)
 321                         continue;
 322
 323                 HUD_Panel_UpdatePosSizeForId(i);
 324
 325                 panel_pos -= '1 1 0' * panel_bg_border;
 326                 panel_size += '2 2 0' * panel_bg_border;
 327
 328                 targEndPos = panel_pos + panel_size;
 329
 330                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 331                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 332                         continue;
 333
 334                 if (resizeCorner == 1)
 335                 {
 336                         // check if this panel is on our way
 337                         if (resizeorigin_x <= panel_pos_x)
 338                                 continue;
 339                         if (resizeorigin_y <= panel_pos_y)
 340                                 continue;
 341                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 342                                 continue;
 343                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 344                                 continue;
 345
 346                         // there is a collision:
 347                         // detect which side of the panel we are facing is actually limiting the resizing
 348                         // (which side the resize direction finds for first) and reduce the size up to there
 349                         //
 350                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 351                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 352                         dist_x = resizeorigin_x - targEndPos_x;
 353                         dist_y = resizeorigin_y - targEndPos_y;
 354                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 355                                 mySize_x = min(mySize_x, dist_x);
 356                         else
 357                                 mySize_y = min(mySize_y, dist_y);
 358                 }
 359                 else if (resizeCorner == 2)
 360                 {
 361                         if (resizeorigin_x >= targEndPos_x)
 362                                 continue;
 363                         if (resizeorigin_y <= panel_pos_y)
 364                                 continue;
 365                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 366                                 continue;
 367                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 368                                 continue;
 369
 370                         dist_x = panel_pos_x - resizeorigin_x;
 371                         dist_y = resizeorigin_y - targEndPos_y;
 372                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 373                                 mySize_x = min(mySize_x, dist_x);
 374                         else
 375                                 mySize_y = min(mySize_y, dist_y);
 376                 }
 377                 else if (resizeCorner == 3)
 378                 {
 379                         if (resizeorigin_x <= panel_pos_x)
 380                                 continue;
 381                         if (resizeorigin_y >= targEndPos_y)
 382                                 continue;
 383                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 384                                 continue;
 385                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 386                                 continue;
 387
 388                         dist_x = resizeorigin_x - targEndPos_x;
 389                         dist_y = panel_pos_y - resizeorigin_y;
 390                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 391                                 mySize_x = min(mySize_x, dist_x);
 392                         else
 393                                 mySize_y = min(mySize_y, dist_y);
 394                 }
 395                 else if (resizeCorner == 4)
 396                 {
 397                         if (resizeorigin_x >= targEndPos_x)
 398                                 continue;
 399                         if (resizeorigin_y >= targEndPos_y)
 400                                 continue;
 401                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 402                                 continue;
 403                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 404                                 continue;
 405
 406                         dist_x = panel_pos_x - resizeorigin_x;
 407                         dist_y = panel_pos_y - resizeorigin_y;
 408                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 409                                 mySize_x = min(mySize_x, dist_x);
 410                         else
 411                                 mySize_y = min(mySize_y, dist_y);
 412                 }
 413                 //if(cvar("hud_configure_checkcollisions_debug"))
 414                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 415         }
 416
 417         return mySize;
 418 }
 419
 420 void HUD_Panel_SetPosSize(vector mySize)
 421 {
 422         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 423         vector resizeorigin;
 424         resizeorigin = panel_click_resizeorigin;
 425         local noref vector myPos; // fteqcc sucks
 426
 427         // minimum panel size cap
 428         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 429         mySize_y = max(0.025 * vid_conheight, mySize_y);
 430
 431         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 432         {
 433                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 434                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 435         }
 436
 437         // collision testing|
 438         // -----------------+
 439
 440         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 441         if(resizeCorner == 1) {
 442                 myPos_x = resizeorigin_x - mySize_x;
 443                 myPos_y = resizeorigin_y - mySize_y;
 444         } else if(resizeCorner == 2) {
 445                 myPos_x = resizeorigin_x;
 446                 myPos_y = resizeorigin_y - mySize_y;
 447         } else if(resizeCorner == 3) {
 448                 myPos_x = resizeorigin_x - mySize_x;
 449                 myPos_y = resizeorigin_y;
 450         } else { // resizeCorner == 4
 451                 myPos_x = resizeorigin_x;
 452                 myPos_y = resizeorigin_y;
 453         }
 454
 455         // left/top screen edges
 456         if(myPos_x < 0)
 457                 mySize_x = mySize_x + myPos_x;
 458         if(myPos_y < 0)
 459                 mySize_y = mySize_y + myPos_y;
 460
 461         // bottom/right screen edges
 462         if(myPos_x + mySize_x > vid_conwidth)
 463                 mySize_x = vid_conwidth - myPos_x;
 464         if(myPos_y + mySize_y > vid_conheight)
 465                 mySize_y = vid_conheight - myPos_y;
 466
 467         //if(cvar("hud_configure_checkcollisions_debug"))
 468                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 469
 470         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 471         if(autocvar_hud_configure_grid)
 472         {
 473                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 474                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 475         }
 476
 477         if(hud_configure_checkcollisions)
 478                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 479
 480         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 481         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 482         mySize_y = max(0.025 * vid_conheight, mySize_y);
 483
 484         // do another pos check, as size might have changed by now
 485         if(resizeCorner == 1) {
 486                 myPos_x = resizeorigin_x - mySize_x;
 487                 myPos_y = resizeorigin_y - mySize_y;
 488         } else if(resizeCorner == 2) {
 489                 myPos_x = resizeorigin_x;
 490                 myPos_y = resizeorigin_y - mySize_y;
 491         } else if(resizeCorner == 3) {
 492                 myPos_x = resizeorigin_x - mySize_x;
 493                 myPos_y = resizeorigin_y;
 494         } else { // resizeCorner == 4
 495                 myPos_x = resizeorigin_x;
 496                 myPos_y = resizeorigin_y;
 497         }
 498
 499         //if(cvar("hud_configure_checkcollisions_debug"))
 500                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 501
 502         HUD_Panel_GetName(highlightedPanel);
 503         string s;
 504         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 505         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 506
 507         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 508         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 509 }
 510
 511 float pressed_key_time;
 512 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 513 void HUD_Panel_Arrow_Action(float nPrimary)
 514 {
 515         if (highlightedPanel == -1)
 516                 return;
 517
 518         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 519
 520         float step;
 521         if(autocvar_hud_configure_grid)
 522         {
 523                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 524                 {
 525                         if (hudShiftState & S_SHIFT)
 526                                 step = hud_configure_realGridSize_y;
 527                         else
 528                                 step = 2 * hud_configure_realGridSize_y;
 529                 }
 530                 else
 531                 {
 532                         if (hudShiftState & S_SHIFT)
 533                                 step = hud_configure_realGridSize_x;
 534                         else
 535                                 step = 2 * hud_configure_realGridSize_x;
 536                 }
 537         }
 538         else
 539         {
 540                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 541                         step = vid_conheight;
 542                 else
 543                         step = vid_conwidth;
 544                 if (hudShiftState & S_SHIFT)
 545                         step = (step / 256); // more precision
 546                 else
 547                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 548         }
 549
 550         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 551
 552         highlightedPanel_initial_pos = panel_pos;
 553         highlightedPanel_initial_size = panel_size;
 554
 555         if (hudShiftState & S_ALT) // resize
 556         {
 557                 highlightedAction = 1;
 558                 if(nPrimary == K_UPARROW)
 559                         resizeCorner = 1;
 560                 else if(nPrimary == K_RIGHTARROW)
 561                         resizeCorner = 2;
 562                 else if(nPrimary == K_LEFTARROW)
 563                         resizeCorner = 3;
 564                 else // if(nPrimary == K_DOWNARROW)
 565                         resizeCorner = 4;
 566
 567                 // ctrl+arrow reduces the size, instead of increasing it
 568                 // Note that ctrl disables collisions check too, but it's fine
 569                 // since we don't collide with anything reducing the size
 570                 if (hudShiftState & S_CTRL) {
 571                         step = -step;
 572                         resizeCorner = 5 - resizeCorner;
 573                 }
 574
 575                 vector mySize;
 576                 mySize = panel_size;
 577                 panel_click_resizeorigin = panel_pos;
 578                 if(resizeCorner == 1) {
 579                         panel_click_resizeorigin += mySize;
 580                         mySize_y += step;
 581                 } else if(resizeCorner == 2) {
 582                         panel_click_resizeorigin_y += mySize_y;
 583                         mySize_x += step;
 584                 } else if(resizeCorner == 3) {
 585                         panel_click_resizeorigin_x += mySize_x;
 586                         mySize_x += step;
 587                 } else { // resizeCorner == 4
 588                         mySize_y += step;
 589                 }
 590                 HUD_Panel_SetPosSize(mySize);
 591         }
 592         else // move
 593         {
 594                 highlightedAction = 2;
 595                 vector pos;
 596                 pos = panel_pos;
 597                 if(nPrimary == K_UPARROW)
 598                         pos_y -= step;
 599                 else if(nPrimary == K_DOWNARROW)
 600                         pos_y += step;
 601                 else if(nPrimary == K_LEFTARROW)
 602                         pos_x -= step;
 603                 else // if(nPrimary == K_RIGHTARROW)
 604                         pos_x += step;
 605
 606                 HUD_Panel_SetPos(pos);
 607         }
 608
 609         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 610
 611         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 612         {
 613                 // backup!
 614                 panel_pos_backup = highlightedPanel_initial_pos;
 615                 panel_size_backup = highlightedPanel_initial_size;
 616                 highlightedPanel_backup = highlightedPanel;
 617         }
 618 }
 619
 620 const float S_MOUSE1 = 1;
 621 const float S_MOUSE2 = 2;
 622 const float S_MOUSE3 = 4;
 623 float mouseClicked;
 624 float prevMouseClicked; // previous state
 625 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 626 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 627
 628 void HUD_Panel_EnableMenu();
 629 float tab_panels[HUD_PANEL_NUM];
 630 float tab_panel, tab_backward;
 631 vector tab_panel_pos;
 632 void HUD_Panel_FirstInDrawQ(float id);
 633 void reset_tab_panels()
 634 {
 635         int i;
 636         for(i = 0; i < HUD_PANEL_NUM; ++i)
 637                 tab_panels[i] = -1;
 638 }
 639 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 640 {
 641         string s;
 642
 643         if(bInputType == 2)
 644                 return false;
 645
 646         if(!autocvar__hud_configure)
 647                 return false;
 648
 649         // block any input while a menu dialog is fading
 650         if(autocvar__menu_alpha)
 651                 return true;
 652
 653         if(bInputType == 3)
 654         {
 655                 mousepos_x = nPrimary;
 656                 mousepos_y = nSecondary;
 657                 return true;
 658         }
 659
 660         // allow console bind to work
 661         string con_keys;
 662         float keys;
 663         con_keys = findkeysforcommand("toggleconsole", 0);
 664         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 665
 666         float hit_con_bind = 0, i;
 667         for (i = 0; i < keys; ++i)
 668         {
 669                 if(nPrimary == stof(argv(i)))
 670                         hit_con_bind = 1;
 671         }
 672
 673         if(bInputType == 0) {
 674                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 675                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 676                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 677         }
 678         else if(bInputType == 1) {
 679                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 680                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 681                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 682         }
 683
 684         if(nPrimary == K_CTRL)
 685         {
 686                 if (bInputType == 1) //ctrl has been released
 687                 {
 688                         if (tab_panel != -1)
 689                         {
 690                                 //switch to selected panel
 691                                 highlightedPanel = tab_panel;
 692                                 highlightedAction = 0;
 693                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 694                         }
 695                         tab_panel = -1;
 696                         reset_tab_panels();
 697                 }
 698         }
 699
 700         if(nPrimary == K_MOUSE1)
 701         {
 702                 if(bInputType == 0) // key pressed
 703                         mouseClicked |= S_MOUSE1;
 704                 else if(bInputType == 1) // key released
 705                         mouseClicked -= (mouseClicked & S_MOUSE1);
 706         }
 707         else if(nPrimary == K_MOUSE2)
 708         {
 709                 if(bInputType == 0) // key pressed
 710                         mouseClicked |= S_MOUSE2;
 711                 else if(bInputType == 1) // key released
 712                         mouseClicked -= (mouseClicked & S_MOUSE2);
 713         }
 714         else if(nPrimary == K_ESCAPE)
 715         {
 716                 if (bInputType == 1)
 717                         return true;
 718                 menu_enabled = 1;
 719                 menu_enabled_time = time;
 720                 localcmd("menu_showhudexit\n");
 721         }
 722         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 723         {
 724                 if (bInputType == 1)
 725                         return true;
 726                 if (!menu_enabled)
 727                         cvar_set("_hud_configure", "0");
 728         }
 729         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 730         {
 731                 if (bInputType == 1 || mouseClicked)
 732                         return true;
 733
 734                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 735                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 736                 //(it should only after every other panel of the hud)
 737                 //It's a minor bug anyway, we can live with it
 738
 739                 float starting_panel;
 740                 float old_tab_panel = tab_panel;
 741                 if (tab_panel == -1) //first press of TAB
 742                 {
 743                         if (highlightedPanel != -1)
 744                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 745                         else
 746                                 panel_pos = '0 0 0';
 747                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 748                         tab_panel_pos = panel_pos; //to compute level
 749                 }
 750                 else
 751                 {
 752                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 753                                 reset_tab_panels();
 754                         starting_panel = tab_panel;
 755                 }
 756                 tab_backward = (hudShiftState & S_SHIFT);
 757
 758                 float k, level = 0, start_pos_x;
 759                 vector candidate_pos = '0 0 0';
 760                 const float LEVELS_NUM = 4;
 761                 float level_height = vid_conheight / LEVELS_NUM;
 762 :find_tab_panel
 763                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 764                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 765                 start_pos_x = tab_panel_pos_x;
 766                 tab_panel = -1;
 767                 k=0;
 768                 while(++k)
 769                 {
 770                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 771                         {
 772                                 if (i == tab_panels[i] || i == starting_panel)
 773                                         continue;
 774                                 HUD_Panel_UpdatePosSizeForId(i)
 775                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 776                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 777                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 778                                 {
 779                                         tab_panel = i;
 780                                         tab_panel_pos = candidate_pos = panel_pos;
 781                                 }
 782                         }
 783                         if (tab_panel != -1)
 784                                 break;
 785                         if (k == LEVELS_NUM) //tab_panel not found
 786                         {
 787                                 reset_tab_panels();
 788                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 789                                 {
 790                                         tab_panel = -1;
 791                                         return true;
 792                                 }
 793                                 starting_panel = old_tab_panel;
 794                                 old_tab_panel = -2;
 795                                 goto find_tab_panel; //u must find tab_panel!
 796                         }
 797                         if (!tab_backward)
 798                         {
 799                                 level = mod(level + level_height, vid_conheight);
 800                                 start_pos_x = 0;
 801                                 candidate_pos_x = vid_conwidth;
 802                         }
 803                         else
 804                         {
 805                                 level = mod(level - level_height, vid_conheight);
 806                                 start_pos_x = vid_conwidth;
 807                                 candidate_pos_x = 0;
 808                         }
 809                 }
 810
 811                 tab_panels[tab_panel] = tab_panel;
 812         }
 813         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 814         {
 815                 if (bInputType == 1 || mouseClicked)
 816                         return true;
 817
 818                 if (highlightedPanel != -1)
 819                 {
 820                         HUD_Panel_GetName(highlightedPanel);
 821                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 822                 }
 823                 else
 824                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 825         }
 826         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 827         {
 828                 if (bInputType == 1 || mouseClicked)
 829                         return true;
 830
 831                 if (highlightedPanel != -1)
 832                 {
 833                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 834                         panel_size_copied = panel_size;
 835                         highlightedPanel_copied = highlightedPanel;
 836                 }
 837         }
 838         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 839         {
 840                 if (bInputType == 1 || mouseClicked)
 841                         return true;
 842
 843                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 844                         return true;
 845
 846                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 847
 848                 // reduce size if it'd go beyond screen boundaries
 849                 vector tmp_size = panel_size_copied;
 850                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 851                         tmp_size_x = vid_conwidth - panel_pos_x;
 852                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 853                         tmp_size_y = vid_conheight - panel_pos_y;
 854
 855                 if (panel_size == tmp_size)
 856                         return true;
 857
 858                 // backup first!
 859                 panel_pos_backup = panel_pos;
 860                 panel_size_backup = panel_size;
 861                 highlightedPanel_backup = highlightedPanel;
 862
 863                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 864                 HUD_Panel_GetName(highlightedPanel);
 865                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 866         }
 867         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 868         {
 869                 if (bInputType == 1 || mouseClicked)
 870                         return true;
 871                 //restore previous values
 872                 if (highlightedPanel_backup != -1)
 873                 {
 874                         HUD_Panel_GetName(highlightedPanel_backup);
 875                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 876                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 877                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 878                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 879                         highlightedPanel_backup = -1;
 880                 }
 881         }
 882         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 883         {
 884                 if (bInputType == 1)
 885                 {
 886                         pressed_key_time = 0;
 887                         return true;
 888                 }
 889                 else if (pressed_key_time == 0)
 890                         pressed_key_time = time;
 891
 892                 if (!mouseClicked)
 893                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 894         }
 895         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 896         {
 897                 if (bInputType == 1)
 898                         return true;
 899                 if (highlightedPanel != -1)
 900                         HUD_Panel_EnableMenu();
 901         }
 902         else if(hit_con_bind)
 903                 return false;
 904
 905         return true;
 906 }
 907
 908 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 909 {
 910         float i, j = 0, border;
 911
 912         while(j < HUD_PANEL_NUM)
 913         {
 914                 i = panel_order[j];
 915                 j += 1;
 916
 917                 HUD_Panel_UpdatePosSizeForId(i);
 918
 919                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 920
 921                 // move
 922                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 923                 {
 924                         return 1;
 925                 }
 926                 // resize from topleft border
 927                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 928                 {
 929                         return 2;
 930                 }
 931                 // resize from topright border
 932                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 933                 {
 934                         return 3;
 935                 }
 936                 // resize from bottomleft border
 937                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 938                 {
 939                         return 3;
 940                 }
 941                 // resize from bottomright border
 942                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 943                 {
 944                         return 2;
 945                 }
 946         }
 947         return 0;
 948 }
 949
 950 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 951 void HUD_Panel_FirstInDrawQ(float id)
 952 {
 953         float i;
 954         var float place = -1;
 955         // find out where in the array our current id is, save into place
 956         for(i = 0; i < HUD_PANEL_NUM; ++i)
 957         {
 958                 if(panel_order[i] == id)
 959                 {
 960                         place = i;
 961                         break;
 962                 }
 963         }
 964         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 965         if(place == -1)
 966                 place = HUD_PANEL_NUM - 1;
 967
 968         // move all ids up by one step in the array until "place"
 969         for(i = place; i > 0; --i)
 970         {
 971                 panel_order[i] = panel_order[i-1];
 972         }
 973         // now save the new top id
 974         panel_order[0] = id;
 975
 976         // let's save them into the cvar by some strcat trickery
 977         string s = "";
 978         for(i = 0; i < HUD_PANEL_NUM; ++i)
 979         {
 980                 s = strcat(s, ftos(panel_order[i]), " ");
 981         }
 982         cvar_set("_hud_panelorder", s);
 983         if(hud_panelorder_prev)
 984                 strunzone(hud_panelorder_prev);
 985         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 986 }
 987
 988 void HUD_Panel_Highlight(float allow_move)
 989 {
 990         float i, j = 0, border;
 991
 992         while(j < HUD_PANEL_NUM)
 993         {
 994                 i = panel_order[j];
 995                 j += 1;
 996
 997                 HUD_Panel_UpdatePosSizeForId(i);
 998
 999                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1000
1001                 // move
1002                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1003                 {
1004                         highlightedPanel = i;
1005                         HUD_Panel_FirstInDrawQ(i);
1006                         highlightedAction = 1;
1007                         panel_click_distance = mousepos - panel_pos;
1008                         return;
1009                 }
1010                 // resize from topleft border
1011                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1012                 {
1013                         highlightedPanel = i;
1014                         HUD_Panel_FirstInDrawQ(i);
1015                         highlightedAction = 2;
1016                         resizeCorner = 1;
1017                         panel_click_distance = mousepos - panel_pos;
1018                         panel_click_resizeorigin = panel_pos + panel_size;
1019                         return;
1020                 }
1021                 // resize from topright border
1022                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1023                 {
1024                         highlightedPanel = i;
1025                         HUD_Panel_FirstInDrawQ(i);
1026                         highlightedAction = 2;
1027                         resizeCorner = 2;
1028                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1029                         panel_click_distance_y = mousepos_y - panel_pos_y;
1030                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1031                         return;
1032                 }
1033                 // resize from bottomleft border
1034                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1035                 {
1036                         highlightedPanel = i;
1037                         HUD_Panel_FirstInDrawQ(i);
1038                         highlightedAction = 2;
1039                         resizeCorner = 3;
1040                         panel_click_distance_x = mousepos_x - panel_pos_x;
1041                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1042                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1043                         return;
1044                 }
1045                 // resize from bottomright border
1046                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1047                 {
1048                         highlightedPanel = i;
1049                         HUD_Panel_FirstInDrawQ(i);
1050                         highlightedAction = 2;
1051                         resizeCorner = 4;
1052                         panel_click_distance = panel_size - mousepos + panel_pos;
1053                         panel_click_resizeorigin = panel_pos;
1054                         return;
1055                 }
1056         }
1057         highlightedPanel = -1;
1058         highlightedAction = 0;
1059 }
1060
1061 void HUD_Panel_EnableMenu()
1062 {
1063         menu_enabled = 2;
1064         menu_enabled_time = time;
1065         HUD_Panel_GetName(highlightedPanel);
1066         localcmd("menu_showhudoptions ", panel_name, "\n");
1067 }
1068 float mouse_over_panel;
1069 void HUD_Panel_Mouse()
1070 {
1071         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1072         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1073                 menu_enabled = 0;
1074
1075         /*
1076         print("menu_enabled: ", ftos(menu_enabled), "\n");
1077         print("Highlighted: ", ftos(highlightedPanel), "\n");
1078         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1079         */
1080
1081         if(autocvar__menu_alpha == 1)
1082                 return;
1083
1084         if not(autocvar_hud_cursormode)
1085         {
1086                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1087
1088                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1089                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1090         }
1091
1092         if(mouseClicked)
1093         {
1094                 if(prevMouseClicked == 0)
1095                 {
1096                         if (tab_panel != -1)
1097                         {
1098                                 //stop ctrl-tab selection
1099                                 tab_panel = -1;
1100                                 reset_tab_panels();
1101                         }
1102                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1103                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1104                         if (highlightedPanel != -1)
1105                         {
1106                                 highlightedPanel_initial_pos = panel_pos;
1107                                 highlightedPanel_initial_size = panel_size;
1108                         }
1109                         // doubleclick check
1110                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1111                         {
1112                                 mouseClicked = 0; // to prevent spam, I guess.
1113                                 HUD_Panel_EnableMenu();
1114                         }
1115                         else
1116                         {
1117                                 if (mouseClicked & S_MOUSE1)
1118                                 {
1119                                         prevMouseClickedTime = time;
1120                                         prevMouseClickedPos = mousepos;
1121                                 }
1122                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1123                         }
1124                 }
1125                 else
1126                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1127
1128                 if (highlightedPanel != -1)
1129                 {
1130                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1131                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1132                         {
1133                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1134                                 // backup!
1135                                 panel_pos_backup = highlightedPanel_initial_pos;
1136                                 panel_size_backup = highlightedPanel_initial_size;
1137                                 highlightedPanel_backup = highlightedPanel;
1138                         }
1139                         else
1140                                 // in case the clicked panel is inside another panel and we aren't
1141                                 // moving it, avoid the immediate "fix" of its position/size
1142                                 // (often unwanted and hateful) by disabling collisions check
1143                                 hud_configure_checkcollisions = false;
1144                 }
1145
1146                 if(highlightedAction == 1)
1147                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1148                 else if(highlightedAction == 2)
1149                 {
1150                         vector mySize = '0 0 0';
1151                         if(resizeCorner == 1) {
1152                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1153                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1154                         } else if(resizeCorner == 2) {
1155                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1156                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1157                         } else if(resizeCorner == 3) {
1158                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1159                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1160                         } else { // resizeCorner == 4
1161                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1162                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1163                         }
1164                         HUD_Panel_SetPosSize(mySize);
1165                 }
1166         }
1167         else
1168         {
1169                 if(menu_enabled == 2)
1170                         mouse_over_panel = 0;
1171                 else
1172                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1173                 if (mouse_over_panel && tab_panel == -1)
1174                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1175         }
1176         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1177         const vector cursorsize = '32 32 0';
1178         float cursor_alpha = 1 - autocvar__menu_alpha;
1179
1180         if(!mouse_over_panel)
1181                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1182         else if(mouse_over_panel == 1)
1183                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1184         else if(mouse_over_panel == 2)
1185                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1186         else
1187                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1188
1189         prevMouseClicked = mouseClicked;
1190 }
1191
1192 const float hlBorderSize = 4;
1193 const string hlBorder = "gfx/hud/default/border_highlighted";
1194 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1195 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1196 {
1197         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1198         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1199         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1200         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1201         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1202 }