qcsrc/client/hud_config.qc

   1 #include "hud_config.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5
   6 #include "../common/constants.qh"
   7
   8 #include "../dpdefs/keycodes.qh"
   9
  10
  11 #define HUD_Write(s) fputs(fh, s)
  12 // q: quoted, n: not quoted
  13 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
  14 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
  15 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
  16 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
  17 // Save the config
  18 void HUD_Panel_ExportCfg(string cfgname)
  19 {
  20         float fh;
  21         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  22         fh = fopen(filename, FILE_WRITE);
  23         if(fh >= 0)
  24         {
  25                 HUD_Write_Cvar_q("hud_skin");
  26                 HUD_Write_Cvar_q("hud_panel_bg");
  27                 HUD_Write_Cvar_q("hud_panel_bg_color");
  28                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  29                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  30                 HUD_Write_Cvar_q("hud_panel_bg_border");
  31                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  32                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  33                 HUD_Write("\n");
  34
  35                 HUD_Write_Cvar_q("hud_dock");
  36                 HUD_Write_Cvar_q("hud_dock_color");
  37                 HUD_Write_Cvar_q("hud_dock_color_team");
  38                 HUD_Write_Cvar_q("hud_dock_alpha");
  39                 HUD_Write("\n");
  40
  41                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  42                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  43                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  44                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  45                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  46                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  47                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  48                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  49                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  50                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  51                 HUD_Write("\n");
  52
  53                 HUD_Write_Cvar_q("_hud_panelorder");
  54                 HUD_Write("\n");
  55
  56                 HUD_Write_Cvar_q("hud_configure_grid");
  57                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  58                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  59                 HUD_Write("\n");
  60
  61                 // common cvars for all panels
  62                 int i;
  63                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  64                 {
  65                         panel = hud_panel[i];
  66
  67                         HUD_Write_PanelCvar_n("");
  68                         HUD_Write_PanelCvar_q("_pos");
  69                         HUD_Write_PanelCvar_q("_size");
  70                         HUD_Write_PanelCvar_q("_bg");
  71                         HUD_Write_PanelCvar_q("_bg_color");
  72                         HUD_Write_PanelCvar_q("_bg_color_team");
  73                         HUD_Write_PanelCvar_q("_bg_alpha");
  74                         HUD_Write_PanelCvar_q("_bg_border");
  75                         HUD_Write_PanelCvar_q("_bg_padding");
  76                         switch(i) {
  77                                 case HUD_PANEL_WEAPONS:
  78                                         HUD_Write_PanelCvar_q("_accuracy");
  79                                         HUD_Write_PanelCvar_q("_label");
  80                                         HUD_Write_PanelCvar_q("_label_scale");
  81                                         HUD_Write_PanelCvar_q("_complainbubble");
  82                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  83                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  84                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  85                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  86                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  87                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  88                                         HUD_Write_PanelCvar_q("_ammo");
  89                                         HUD_Write_PanelCvar_q("_ammo_color");
  90                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  91                                         HUD_Write_PanelCvar_q("_aspect");
  92                                         HUD_Write_PanelCvar_q("_timeout");
  93                                         HUD_Write_PanelCvar_q("_timeout_effect");
  94                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  95                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  96                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  97                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  98                                         HUD_Write_PanelCvar_q("_onlyowned");
  99                                         break;
 100                                 case HUD_PANEL_AMMO:
 101                                         HUD_Write_PanelCvar_q("_onlycurrent");
 102                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 103                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_progressbar");
 106                                         HUD_Write_PanelCvar_q("_progressbar_name");
 107                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 108                                         HUD_Write_PanelCvar_q("_text");
 109                                         break;
 110                                 case HUD_PANEL_POWERUPS:
 111                                         HUD_Write_PanelCvar_q("_flip");
 112                                         HUD_Write_PanelCvar_q("_iconalign");
 113                                         HUD_Write_PanelCvar_q("_baralign");
 114                                         HUD_Write_PanelCvar_q("_progressbar");
 115                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 116                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 117                                         HUD_Write_PanelCvar_q("_text");
 118                                         break;
 119                                 case HUD_PANEL_HEALTHARMOR:
 120                                         HUD_Write_PanelCvar_q("_flip");
 121                                         HUD_Write_PanelCvar_q("_iconalign");
 122                                         HUD_Write_PanelCvar_q("_baralign");
 123                                         HUD_Write_PanelCvar_q("_progressbar");
 124                                         HUD_Write_PanelCvar_q("_progressbar_health");
 125                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 126                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 127                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 128                                         HUD_Write_PanelCvar_q("_text");
 129                                         break;
 130                                 case HUD_PANEL_NOTIFY:
 131                                         HUD_Write_PanelCvar_q("_flip");
 132                                         HUD_Write_PanelCvar_q("_fontsize");
 133                                         HUD_Write_PanelCvar_q("_time");
 134                                         HUD_Write_PanelCvar_q("_fadetime");
 135                                         HUD_Write_PanelCvar_q("_icon_aspect");
 136                                         break;
 137                                 case HUD_PANEL_TIMER:
 138                                         HUD_Write_PanelCvar_q("_increment");
 139                                         break;
 140                                 case HUD_PANEL_RADAR:
 141                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 142                                         HUD_Write_PanelCvar_q("_rotation");
 143                                         HUD_Write_PanelCvar_q("_zoommode");
 144                                         HUD_Write_PanelCvar_q("_scale");
 145                                         HUD_Write_PanelCvar_q("_maximized_scale");
 146                                         HUD_Write_PanelCvar_q("_maximized_size");
 147                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 148                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 149                                         break;
 150                                 case HUD_PANEL_SCORE:
 151                                         HUD_Write_PanelCvar_q("_rankings");
 152                                         break;
 153                                 case HUD_PANEL_VOTE:
 154                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 155                                         break;
 156                                 case HUD_PANEL_MODICONS:
 157                                         HUD_Write_PanelCvar_q("_ca_layout");
 158                                         HUD_Write_PanelCvar_q("_dom_layout");
 159                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 160                                         break;
 161                                 case HUD_PANEL_PRESSEDKEYS:
 162                                         HUD_Write_PanelCvar_q("_aspect");
 163                                         HUD_Write_PanelCvar_q("_attack");
 164                                         break;
 165                                 case HUD_PANEL_ENGINEINFO:
 166                                         HUD_Write_PanelCvar_q("_framecounter_time");
 167                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 168                                         break;
 169                                 case HUD_PANEL_INFOMESSAGES:
 170                                         HUD_Write_PanelCvar_q("_flip");
 171                                         break;
 172                                 case HUD_PANEL_PHYSICS:
 173                                         HUD_Write_PanelCvar_q("_speed_unit");
 174                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 175                                         HUD_Write_PanelCvar_q("_speed_max");
 176                                         HUD_Write_PanelCvar_q("_speed_vertical");
 177                                         HUD_Write_PanelCvar_q("_topspeed");
 178                                         HUD_Write_PanelCvar_q("_topspeed_time");
 179                                         HUD_Write_PanelCvar_q("_acceleration_max");
 180                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 181                                         HUD_Write_PanelCvar_q("_flip");
 182                                         HUD_Write_PanelCvar_q("_baralign");
 183                                         HUD_Write_PanelCvar_q("_progressbar");
 184                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 185                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 186                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 187                                         HUD_Write_PanelCvar_q("_text");
 188                                         HUD_Write_PanelCvar_q("_text_scale");
 189                                         break;
 190                                 case HUD_PANEL_CENTERPRINT:
 191                                         HUD_Write_PanelCvar_q("_align");
 192                                         HUD_Write_PanelCvar_q("_flip");
 193                                         HUD_Write_PanelCvar_q("_fontscale");
 194                                         HUD_Write_PanelCvar_q("_time");
 195                                         HUD_Write_PanelCvar_q("_fade_in");
 196                                         HUD_Write_PanelCvar_q("_fade_out");
 197                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 198                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 199                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 200                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 201                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 202                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 203                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 204                                         break;
 205                         }
 206                         HUD_Write("\n");
 207                 }
 208                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 209
 210                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 211                 fclose(fh);
 212         }
 213         else
 214                 printf(_("^1Couldn't write to %s\n"), filename);
 215 }
 216
 217 void HUD_Configure_Exit_Force()
 218 {
 219         if (menu_enabled)
 220         {
 221                 menu_enabled = 0;
 222                 localcmd("togglemenu\n");
 223         }
 224         cvar_set("_hud_configure", "0");
 225 }
 226
 227 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 228 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 229 {
 230         vector myCenter, targCenter;
 231         vector myTarget = myPos;
 232         int i;
 233         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 234                 panel = hud_panel[i];
 235                 if(panel == highlightedPanel) continue;
 236                 HUD_Panel_UpdatePosSize();
 237                 if(!panel_enabled) continue;
 238
 239                 panel_pos -= '1 1 0' * panel_bg_border;
 240                 panel_size += '2 2 0' * panel_bg_border;
 241
 242                 if(myPos.y + mySize.y < panel_pos.y)
 243                         continue;
 244                 if(myPos.y > panel_pos.y + panel_size.y)
 245                         continue;
 246
 247                 if(myPos.x + mySize.x < panel_pos.x)
 248                         continue;
 249                 if(myPos.x > panel_pos.x + panel_size.x)
 250                         continue;
 251
 252                 // OK, there IS a collision.
 253
 254                 myCenter.x = myPos.x + 0.5 * mySize.x;
 255                 myCenter.y = myPos.y + 0.5 * mySize.y;
 256
 257                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 258                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 259
 260                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 261                 {
 262                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 263                                 myTarget.x = panel_pos.x - mySize.x;
 264                         else // push it upwards
 265                                 myTarget.y = panel_pos.y - mySize.y;
 266                 }
 267                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 268                 {
 269                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 270                                 myTarget.x = panel_pos.x + panel_size.x;
 271                         else // push it upwards
 272                                 myTarget.y = panel_pos.y - mySize.y;
 273                 }
 274                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 275                 {
 276                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 277                                 myTarget.x = panel_pos.x - mySize.x;
 278                         else // push it downwards
 279                                 myTarget.y = panel_pos.y + panel_size.y;
 280                 }
 281                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 282                 {
 283                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 284                                 myTarget.x = panel_pos.x + panel_size.x;
 285                         else // push it downwards
 286                                 myTarget.y = panel_pos.y + panel_size.y;
 287                 }
 288                 //if(cvar("hud_configure_checkcollisions_debug"))
 289                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 290         }
 291
 292         return myTarget;
 293 }
 294
 295 void HUD_Panel_SetPos(vector pos)
 296 {
 297         panel = highlightedPanel;
 298         HUD_Panel_UpdatePosSize();
 299         vector mySize;
 300         mySize = panel_size;
 301
 302         //if(cvar("hud_configure_checkcollisions_debug"))
 303                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 304
 305         if(autocvar_hud_configure_grid)
 306         {
 307                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 308                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 309         }
 310
 311         if(hud_configure_checkcollisions)
 312                 pos = HUD_Panel_CheckMove(pos, mySize);
 313
 314         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 315         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 316
 317         string s;
 318         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 319
 320         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 321 }
 322
 323 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 324 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 325         vector targEndPos;
 326         vector dist;
 327         float ratio = mySize.x/mySize.y;
 328         int i;
 329         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 330                 panel = hud_panel[i];
 331                 if(panel == highlightedPanel) continue;
 332                 HUD_Panel_UpdatePosSize();
 333                 if(!panel_enabled) continue;
 334
 335                 panel_pos -= '1 1 0' * panel_bg_border;
 336                 panel_size += '2 2 0' * panel_bg_border;
 337
 338                 targEndPos = panel_pos + panel_size;
 339
 340                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 341                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 342                         continue;
 343
 344                 if (resizeCorner == 1)
 345                 {
 346                         // check if this panel is on our way
 347                         if (resizeorigin.x <= panel_pos.x)
 348                                 continue;
 349                         if (resizeorigin.y <= panel_pos.y)
 350                                 continue;
 351                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 352                                 continue;
 353                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 354                                 continue;
 355
 356                         // there is a collision:
 357                         // detect which side of the panel we are facing is actually limiting the resizing
 358                         // (which side the resize direction finds for first) and reduce the size up to there
 359                         //
 360                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 361                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 362                         dist.x = resizeorigin.x - targEndPos.x;
 363                         dist.y = resizeorigin.y - targEndPos.y;
 364                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 365                                 mySize.x = min(mySize.x, dist.x);
 366                         else
 367                                 mySize.y = min(mySize.y, dist.y);
 368                 }
 369                 else if (resizeCorner == 2)
 370                 {
 371                         if (resizeorigin.x >= targEndPos.x)
 372                                 continue;
 373                         if (resizeorigin.y <= panel_pos.y)
 374                                 continue;
 375                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 376                                 continue;
 377                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 378                                 continue;
 379
 380                         dist.x = panel_pos.x - resizeorigin.x;
 381                         dist.y = resizeorigin.y - targEndPos.y;
 382                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 383                                 mySize.x = min(mySize.x, dist.x);
 384                         else
 385                                 mySize.y = min(mySize.y, dist.y);
 386                 }
 387                 else if (resizeCorner == 3)
 388                 {
 389                         if (resizeorigin.x <= panel_pos.x)
 390                                 continue;
 391                         if (resizeorigin.y >= targEndPos.y)
 392                                 continue;
 393                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 394                                 continue;
 395                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 396                                 continue;
 397
 398                         dist.x = resizeorigin.x - targEndPos.x;
 399                         dist.y = panel_pos.y - resizeorigin.y;
 400                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 401                                 mySize.x = min(mySize.x, dist.x);
 402                         else
 403                                 mySize.y = min(mySize.y, dist.y);
 404                 }
 405                 else if (resizeCorner == 4)
 406                 {
 407                         if (resizeorigin.x >= targEndPos.x)
 408                                 continue;
 409                         if (resizeorigin.y >= targEndPos.y)
 410                                 continue;
 411                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 412                                 continue;
 413                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 414                                 continue;
 415
 416                         dist.x = panel_pos.x - resizeorigin.x;
 417                         dist.y = panel_pos.y - resizeorigin.y;
 418                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 419                                 mySize.x = min(mySize.x, dist.x);
 420                         else
 421                                 mySize.y = min(mySize.y, dist.y);
 422                 }
 423                 //if(cvar("hud_configure_checkcollisions_debug"))
 424                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 425         }
 426
 427         return mySize;
 428 }
 429
 430 void HUD_Panel_SetPosSize(vector mySize)
 431 {
 432         panel = highlightedPanel;
 433         HUD_Panel_UpdatePosSize();
 434         vector resizeorigin;
 435         resizeorigin = panel_click_resizeorigin;
 436         vector myPos;
 437
 438         // minimum panel size cap
 439         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 440         mySize.y = max(0.025 * vid_conheight, mySize.y);
 441
 442         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 443         {
 444                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 445                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 446         }
 447
 448         // collision testing|
 449         // -----------------+
 450
 451         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 452         if(resizeCorner == 1) {
 453                 myPos.x = resizeorigin.x - mySize.x;
 454                 myPos.y = resizeorigin.y - mySize.y;
 455         } else if(resizeCorner == 2) {
 456                 myPos.x = resizeorigin.x;
 457                 myPos.y = resizeorigin.y - mySize.y;
 458         } else if(resizeCorner == 3) {
 459                 myPos.x = resizeorigin.x - mySize.x;
 460                 myPos.y = resizeorigin.y;
 461         } else { // resizeCorner == 4
 462                 myPos.x = resizeorigin.x;
 463                 myPos.y = resizeorigin.y;
 464         }
 465
 466         // left/top screen edges
 467         if(myPos.x < 0)
 468                 mySize.x = mySize.x + myPos.x;
 469         if(myPos.y < 0)
 470                 mySize.y = mySize.y + myPos.y;
 471
 472         // bottom/right screen edges
 473         if(myPos.x + mySize.x > vid_conwidth)
 474                 mySize.x = vid_conwidth - myPos.x;
 475         if(myPos.y + mySize.y > vid_conheight)
 476                 mySize.y = vid_conheight - myPos.y;
 477
 478         //if(cvar("hud_configure_checkcollisions_debug"))
 479                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 480
 481         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 482         if(autocvar_hud_configure_grid)
 483         {
 484                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 485                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 486         }
 487
 488         if(hud_configure_checkcollisions)
 489                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 490
 491         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 492         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 493         mySize.y = max(0.025 * vid_conheight, mySize.y);
 494
 495         // do another pos check, as size might have changed by now
 496         if(resizeCorner == 1) {
 497                 myPos.x = resizeorigin.x - mySize.x;
 498                 myPos.y = resizeorigin.y - mySize.y;
 499         } else if(resizeCorner == 2) {
 500                 myPos.x = resizeorigin.x;
 501                 myPos.y = resizeorigin.y - mySize.y;
 502         } else if(resizeCorner == 3) {
 503                 myPos.x = resizeorigin.x - mySize.x;
 504                 myPos.y = resizeorigin.y;
 505         } else { // resizeCorner == 4
 506                 myPos.x = resizeorigin.x;
 507                 myPos.y = resizeorigin.y;
 508         }
 509
 510         //if(cvar("hud_configure_checkcollisions_debug"))
 511                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 512
 513         string s;
 514         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 515         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 516
 517         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 518         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 519 }
 520
 521 float pressed_key_time;
 522 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 523 void HUD_Panel_Arrow_Action(float nPrimary)
 524 {
 525         if(!highlightedPanel)
 526                 return;
 527
 528         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 529
 530         float step;
 531         if(autocvar_hud_configure_grid)
 532         {
 533                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 534                 {
 535                         if (hudShiftState & S_SHIFT)
 536                                 step = hud_configure_realGridSize.y;
 537                         else
 538                                 step = 2 * hud_configure_realGridSize.y;
 539                 }
 540                 else
 541                 {
 542                         if (hudShiftState & S_SHIFT)
 543                                 step = hud_configure_realGridSize.x;
 544                         else
 545                                 step = 2 * hud_configure_realGridSize.x;
 546                 }
 547         }
 548         else
 549         {
 550                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 551                         step = vid_conheight;
 552                 else
 553                         step = vid_conwidth;
 554                 if (hudShiftState & S_SHIFT)
 555                         step = (step / 256); // more precision
 556                 else
 557                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 558         }
 559
 560         panel = highlightedPanel;
 561         HUD_Panel_UpdatePosSize();
 562
 563         highlightedPanel_initial_pos = panel_pos;
 564         highlightedPanel_initial_size = panel_size;
 565
 566         if (hudShiftState & S_ALT) // resize
 567         {
 568                 highlightedAction = 1;
 569                 if(nPrimary == K_UPARROW)
 570                         resizeCorner = 1;
 571                 else if(nPrimary == K_RIGHTARROW)
 572                         resizeCorner = 2;
 573                 else if(nPrimary == K_LEFTARROW)
 574                         resizeCorner = 3;
 575                 else // if(nPrimary == K_DOWNARROW)
 576                         resizeCorner = 4;
 577
 578                 // ctrl+arrow reduces the size, instead of increasing it
 579                 // Note that ctrl disables collisions check too, but it's fine
 580                 // since we don't collide with anything reducing the size
 581                 if (hudShiftState & S_CTRL) {
 582                         step = -step;
 583                         resizeCorner = 5 - resizeCorner;
 584                 }
 585
 586                 vector mySize;
 587                 mySize = panel_size;
 588                 panel_click_resizeorigin = panel_pos;
 589                 if(resizeCorner == 1) {
 590                         panel_click_resizeorigin += mySize;
 591                         mySize.y += step;
 592                 } else if(resizeCorner == 2) {
 593                         panel_click_resizeorigin.y += mySize.y;
 594                         mySize.x += step;
 595                 } else if(resizeCorner == 3) {
 596                         panel_click_resizeorigin.x += mySize.x;
 597                         mySize.x += step;
 598                 } else { // resizeCorner == 4
 599                         mySize.y += step;
 600                 }
 601                 HUD_Panel_SetPosSize(mySize);
 602         }
 603         else // move
 604         {
 605                 highlightedAction = 2;
 606                 vector pos;
 607                 pos = panel_pos;
 608                 if(nPrimary == K_UPARROW)
 609                         pos.y -= step;
 610                 else if(nPrimary == K_DOWNARROW)
 611                         pos.y += step;
 612                 else if(nPrimary == K_LEFTARROW)
 613                         pos.x -= step;
 614                 else // if(nPrimary == K_RIGHTARROW)
 615                         pos.x += step;
 616
 617                 HUD_Panel_SetPos(pos);
 618         }
 619
 620         panel = highlightedPanel;
 621         HUD_Panel_UpdatePosSize();
 622
 623         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 624         {
 625                 // backup!
 626                 panel_pos_backup = highlightedPanel_initial_pos;
 627                 panel_size_backup = highlightedPanel_initial_size;
 628                 highlightedPanel_backup = highlightedPanel;
 629         }
 630 }
 631
 632 const int S_MOUSE1 = 1;
 633 const int S_MOUSE2 = 2;
 634 const int S_MOUSE3 = 4;
 635 int mouseClicked;
 636 int prevMouseClicked; // previous state
 637 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 638 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 639
 640 void HUD_Panel_EnableMenu();
 641 entity tab_panels[HUD_PANEL_MAX];
 642 entity tab_panel;
 643 vector tab_panel_pos;
 644 float tab_backward;
 645 void HUD_Panel_FirstInDrawQ(float id);
 646 void reset_tab_panels()
 647 {
 648         int i;
 649         for(i = 0; i < HUD_PANEL_NUM; ++i)
 650                 tab_panels[i] = world;
 651 }
 652 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 653 {
 654         string s;
 655
 656         if(bInputType == 2)
 657                 return false;
 658
 659         if(!autocvar__hud_configure)
 660                 return false;
 661
 662         if(bInputType == 3)
 663         {
 664                 mousepos.x = nPrimary;
 665                 mousepos.y = nSecondary;
 666                 return true;
 667         }
 668
 669         // block any input while a menu dialog is fading
 670         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 671         if(autocvar__menu_alpha)
 672         {
 673                 hudShiftState = 0;
 674                 mouseClicked = 0;
 675                 return true;
 676         }
 677
 678         // allow console bind to work
 679         string con_keys;
 680         float keys;
 681         con_keys = findkeysforcommand("toggleconsole", 0);
 682         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 683
 684         bool hit_con_bind = false;
 685         int i;
 686         for (i = 0; i < keys; ++i)
 687         {
 688                 if(nPrimary == stof(argv(i)))
 689                         hit_con_bind = true;
 690         }
 691
 692         if(bInputType == 0) {
 693                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 694                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 695                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 696         }
 697         else if(bInputType == 1) {
 698                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 699                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 700                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 701         }
 702
 703         if(nPrimary == K_CTRL)
 704         {
 705                 if (bInputType == 1) //ctrl has been released
 706                 {
 707                         if (tab_panel)
 708                         {
 709                                 //switch to selected panel
 710                                 highlightedPanel = tab_panel;
 711                                 highlightedAction = 0;
 712                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 713                         }
 714                         tab_panel = world;
 715                         reset_tab_panels();
 716                 }
 717         }
 718
 719         if(nPrimary == K_MOUSE1)
 720         {
 721                 if(bInputType == 0) // key pressed
 722                         mouseClicked |= S_MOUSE1;
 723                 else if(bInputType == 1) // key released
 724                         mouseClicked -= (mouseClicked & S_MOUSE1);
 725         }
 726         else if(nPrimary == K_MOUSE2)
 727         {
 728                 if(bInputType == 0) // key pressed
 729                         mouseClicked |= S_MOUSE2;
 730                 else if(bInputType == 1) // key released
 731                         mouseClicked -= (mouseClicked & S_MOUSE2);
 732         }
 733         else if(nPrimary == K_ESCAPE)
 734         {
 735                 if (bInputType == 1)
 736                         return true;
 737                 menu_enabled = 1;
 738                 localcmd("menu_showhudexit\n");
 739         }
 740         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 741         {
 742                 if (bInputType == 1)
 743                         return true;
 744                 if (!menu_enabled)
 745                         cvar_set("_hud_configure", "0");
 746         }
 747         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 748         {
 749                 if (bInputType == 1 || mouseClicked)
 750                         return true;
 751
 752                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 753                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 754                 //(it should only after every other panel of the hud)
 755                 //It's a minor bug anyway, we can live with it
 756
 757                 entity starting_panel;
 758                 entity old_tab_panel = tab_panel;
 759                 if (!tab_panel) //first press of TAB
 760                 {
 761                         if (highlightedPanel)
 762                         {
 763                                 panel = highlightedPanel;
 764                                 HUD_Panel_UpdatePosSize();
 765                         }
 766                         else
 767                                 panel_pos = '0 0 0';
 768                         starting_panel = highlightedPanel;
 769                         tab_panel_pos = panel_pos; //to compute level
 770                 }
 771                 else
 772                 {
 773                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 774                                 reset_tab_panels();
 775                         starting_panel = tab_panel;
 776                 }
 777                 tab_backward = (hudShiftState & S_SHIFT);
 778
 779                 float k, level = 0, start_posX;
 780                 vector candidate_pos = '0 0 0';
 781                 const float LEVELS_NUM = 4;
 782                 float level_height = vid_conheight / LEVELS_NUM;
 783 :find_tab_panel
 784                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 785                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 786                 start_posX = tab_panel_pos.x;
 787                 tab_panel = world;
 788                 k=0;
 789                 while(++k)
 790                 {
 791                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 792                         {
 793                                 panel = hud_panel[i];
 794                                 if (panel == tab_panels[i] || panel == starting_panel)
 795                                         continue;
 796                                 HUD_Panel_UpdatePosSize();
 797                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 798                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 799                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 800                                 {
 801                                         tab_panel = panel;
 802                                         tab_panel_pos = candidate_pos = panel_pos;
 803                                 }
 804                         }
 805                         if (tab_panel)
 806                                 break;
 807                         if (k == LEVELS_NUM) //tab_panel not found
 808                         {
 809                                 reset_tab_panels();
 810                                 if (!old_tab_panel)
 811                                 {
 812                                         tab_panel = world;
 813                                         return true;
 814                                 }
 815                                 starting_panel = old_tab_panel;
 816                                 old_tab_panel = world;
 817                                 goto find_tab_panel; //u must find tab_panel!
 818                         }
 819                         if (!tab_backward)
 820                         {
 821                                 level = (level + level_height) % vid_conheight;
 822                                 start_posX = 0;
 823                                 candidate_pos.x = vid_conwidth;
 824                         }
 825                         else
 826                         {
 827                                 level = (level - level_height) % vid_conheight;
 828                                 start_posX = vid_conwidth;
 829                                 candidate_pos.x = 0;
 830                         }
 831                 }
 832
 833                 tab_panels[tab_panel.panel_id] = tab_panel;
 834         }
 835         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 836         {
 837                 if (bInputType == 1 || mouseClicked)
 838                         return true;
 839
 840                 if (highlightedPanel)
 841                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 842                 else
 843                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 844         }
 845         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 846         {
 847                 if (bInputType == 1 || mouseClicked)
 848                         return true;
 849
 850                 if (highlightedPanel)
 851                 {
 852                         panel = highlightedPanel;
 853                         HUD_Panel_UpdatePosSize();
 854                         panel_size_copied = panel_size;
 855                 }
 856         }
 857         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 858         {
 859                 if (bInputType == 1 || mouseClicked)
 860                         return true;
 861
 862                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 863                         return true;
 864
 865                 panel = highlightedPanel;
 866                 HUD_Panel_UpdatePosSize();
 867
 868                 // reduce size if it'd go beyond screen boundaries
 869                 vector tmp_size = panel_size_copied;
 870                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 871                         tmp_size.x = vid_conwidth - panel_pos.x;
 872                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 873                         tmp_size.y = vid_conheight - panel_pos.y;
 874
 875                 if (panel_size == tmp_size)
 876                         return true;
 877
 878                 // backup first!
 879                 panel_pos_backup = panel_pos;
 880                 panel_size_backup = panel_size;
 881                 highlightedPanel_backup = highlightedPanel;
 882
 883                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 884                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 885         }
 886         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 887         {
 888                 if (bInputType == 1 || mouseClicked)
 889                         return true;
 890                 //restore previous values
 891                 if (highlightedPanel_backup)
 892                 {
 893                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 894                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 895                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 896                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 897                         highlightedPanel_backup = world;
 898                 }
 899         }
 900         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 901         {
 902                 if (bInputType == 1)
 903                 {
 904                         pressed_key_time = 0;
 905                         return true;
 906                 }
 907                 else if (pressed_key_time == 0)
 908                         pressed_key_time = time;
 909
 910                 if (!mouseClicked)
 911                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 912         }
 913         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 914         {
 915                 if (bInputType == 1)
 916                         return true;
 917                 if (highlightedPanel)
 918                         HUD_Panel_EnableMenu();
 919         }
 920         else if(hit_con_bind)
 921                 return false;
 922
 923         return true;
 924 }
 925
 926 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 927 {
 928         int i, j = 0;
 929         while(j < HUD_PANEL_NUM)
 930         {
 931                 i = panel_order[j];
 932                 j += 1;
 933
 934                 panel = hud_panel[i];
 935                 HUD_Panel_UpdatePosSize();
 936
 937                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 938
 939                 // move
 940                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 941                 {
 942                         return 1;
 943                 }
 944                 // resize from topleft border
 945                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 946                 {
 947                         return 2;
 948                 }
 949                 // resize from topright border
 950                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 951                 {
 952                         return 3;
 953                 }
 954                 // resize from bottomleft border
 955                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 956                 {
 957                         return 3;
 958                 }
 959                 // resize from bottomright border
 960                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 961                 {
 962                         return 2;
 963                 }
 964         }
 965         return 0;
 966 }
 967
 968 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 969 void HUD_Panel_FirstInDrawQ(float id)
 970 {
 971         int i;
 972         int place = -1;
 973         // find out where in the array our current id is, save into place
 974         for(i = 0; i < HUD_PANEL_NUM; ++i)
 975         {
 976                 if(panel_order[i] == id)
 977                 {
 978                         place = i;
 979                         break;
 980                 }
 981         }
 982         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 983         if(place == -1)
 984                 place = HUD_PANEL_NUM - 1;
 985
 986         // move all ids up by one step in the array until "place"
 987         for(i = place; i > 0; --i)
 988         {
 989                 panel_order[i] = panel_order[i-1];
 990         }
 991         // now save the new top id
 992         panel_order[0] = id;
 993
 994         // let's save them into the cvar by some strcat trickery
 995         string s = "";
 996         for(i = 0; i < HUD_PANEL_NUM; ++i)
 997         {
 998                 s = strcat(s, ftos(panel_order[i]), " ");
 999         }
1000         cvar_set("_hud_panelorder", s);
1001         if(hud_panelorder_prev)
1002                 strunzone(hud_panelorder_prev);
1003         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1004 }
1005
1006 void HUD_Panel_Highlight(float allow_move)
1007 {
1008         int i, j = 0;
1009
1010         while(j < HUD_PANEL_NUM)
1011         {
1012                 i = panel_order[j];
1013                 j += 1;
1014
1015                 panel = hud_panel[i];
1016                 HUD_Panel_UpdatePosSize();
1017
1018                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1019
1020                 // move
1021                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1022                 {
1023                         highlightedPanel = hud_panel[i];
1024                         HUD_Panel_FirstInDrawQ(i);
1025                         highlightedAction = 1;
1026                         panel_click_distance = mousepos - panel_pos;
1027                         return;
1028                 }
1029                 // resize from topleft border
1030                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1031                 {
1032                         highlightedPanel = hud_panel[i];
1033                         HUD_Panel_FirstInDrawQ(i);
1034                         highlightedAction = 2;
1035                         resizeCorner = 1;
1036                         panel_click_distance = mousepos - panel_pos;
1037                         panel_click_resizeorigin = panel_pos + panel_size;
1038                         return;
1039                 }
1040                 // resize from topright border
1041                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1042                 {
1043                         highlightedPanel = hud_panel[i];
1044                         HUD_Panel_FirstInDrawQ(i);
1045                         highlightedAction = 2;
1046                         resizeCorner = 2;
1047                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1048                         panel_click_distance.y = mousepos.y - panel_pos.y;
1049                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1050                         return;
1051                 }
1052                 // resize from bottomleft border
1053                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1054                 {
1055                         highlightedPanel = hud_panel[i];
1056                         HUD_Panel_FirstInDrawQ(i);
1057                         highlightedAction = 2;
1058                         resizeCorner = 3;
1059                         panel_click_distance.x = mousepos.x - panel_pos.x;
1060                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1061                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1062                         return;
1063                 }
1064                 // resize from bottomright border
1065                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1066                 {
1067                         highlightedPanel = hud_panel[i];
1068                         HUD_Panel_FirstInDrawQ(i);
1069                         highlightedAction = 2;
1070                         resizeCorner = 4;
1071                         panel_click_distance = panel_size - mousepos + panel_pos;
1072                         panel_click_resizeorigin = panel_pos;
1073                         return;
1074                 }
1075         }
1076         highlightedPanel = world;
1077         highlightedAction = 0;
1078 }
1079
1080 void HUD_Panel_EnableMenu()
1081 {
1082         menu_enabled = 2;
1083         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1084 }
1085 float mouse_over_panel;
1086 void HUD_Panel_Mouse()
1087 {
1088         if(autocvar__menu_alpha == 1)
1089                 return;
1090
1091         if (!autocvar_hud_cursormode)
1092         {
1093                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1094
1095                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1096                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1097         }
1098
1099         if(mouseClicked)
1100         {
1101                 if(prevMouseClicked == 0)
1102                 {
1103                         if (tab_panel)
1104                         {
1105                                 //stop ctrl-tab selection
1106                                 tab_panel = world;
1107                                 reset_tab_panels();
1108                         }
1109                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1110                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1111                         if (highlightedPanel)
1112                         {
1113                                 highlightedPanel_initial_pos = panel_pos;
1114                                 highlightedPanel_initial_size = panel_size;
1115                         }
1116                         // doubleclick check
1117                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1118                         {
1119                                 mouseClicked = 0; // to prevent spam, I guess.
1120                                 HUD_Panel_EnableMenu();
1121                         }
1122                         else
1123                         {
1124                                 if (mouseClicked & S_MOUSE1)
1125                                 {
1126                                         prevMouseClickedTime = time;
1127                                         prevMouseClickedPos = mousepos;
1128                                 }
1129                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1130                         }
1131                 }
1132                 else
1133                 {
1134                         panel = highlightedPanel;
1135                         HUD_Panel_UpdatePosSize();
1136                 }
1137
1138                 if (highlightedPanel)
1139                 {
1140                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1141                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1142                         {
1143                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1144                                 // backup!
1145                                 panel_pos_backup = highlightedPanel_initial_pos;
1146                                 panel_size_backup = highlightedPanel_initial_size;
1147                                 highlightedPanel_backup = highlightedPanel;
1148                         }
1149                         else
1150                                 // in case the clicked panel is inside another panel and we aren't
1151                                 // moving it, avoid the immediate "fix" of its position/size
1152                                 // (often unwanted and hateful) by disabling collisions check
1153                                 hud_configure_checkcollisions = false;
1154                 }
1155
1156                 if(highlightedAction == 1)
1157                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1158                 else if(highlightedAction == 2)
1159                 {
1160                         vector mySize = '0 0 0';
1161                         if(resizeCorner == 1) {
1162                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1163                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1164                         } else if(resizeCorner == 2) {
1165                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1166                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1167                         } else if(resizeCorner == 3) {
1168                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1169                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1170                         } else { // resizeCorner == 4
1171                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1172                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1173                         }
1174                         HUD_Panel_SetPosSize(mySize);
1175                 }
1176         }
1177         else
1178         {
1179                 if(menu_enabled == 2)
1180                         mouse_over_panel = 0;
1181                 else
1182                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1183                 if (mouse_over_panel && !tab_panel)
1184                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1185         }
1186         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1187         const vector cursorsize = '32 32 0';
1188         float cursor_alpha = 1 - autocvar__menu_alpha;
1189
1190         if(!mouse_over_panel)
1191                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1192         else if(mouse_over_panel == 1)
1193                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1194         else if(mouse_over_panel == 2)
1195                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1196         else
1197                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1198
1199         prevMouseClicked = mouseClicked;
1200 }
1201 void HUD_Configure_DrawGrid()
1202 {
1203         float i;
1204         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1205         {
1206                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1207                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1208                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1209                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1210                 vector s;
1211                 // x-axis
1212                 s = eX + eY * vid_conheight;
1213                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1214                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1215                 // y-axis
1216                 s = eY + eX * vid_conwidth;
1217                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1218                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1219         }
1220 }
1221
1222 float _menu_alpha_prev;
1223 void HUD_Configure_Frame()
1224 {
1225         int i;
1226         if(autocvar__hud_configure)
1227         {
1228                 if(isdemo() || intermission == 2)
1229                 {
1230                         HUD_Configure_Exit_Force();
1231                         return;
1232                 }
1233
1234                 if(!hud_configure_prev)
1235                 {
1236                         if(autocvar_hud_cursormode)
1237                                 setcursormode(1);
1238                         hudShiftState = 0;
1239                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1240                                 hud_panel[panel_order[i]].update_time = time;
1241                 }
1242
1243                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1244                 if(autocvar__menu_alpha != _menu_alpha_prev)
1245                 {
1246                         if(autocvar__menu_alpha == 0)
1247                                 menu_enabled = 0;
1248                         _menu_alpha_prev = autocvar__menu_alpha;
1249                 }
1250
1251                 HUD_Configure_DrawGrid();
1252         }
1253         else if(hud_configure_prev)
1254         {
1255                 if(menu_enabled)
1256                         menu_enabled = 0;
1257                 if(autocvar_hud_cursormode)
1258                         setcursormode(0);
1259         }
1260 }
1261
1262 const float hlBorderSize = 2;
1263 const string hlBorder = "gfx/hud/default/border_highlighted";
1264 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1265 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1266 {
1267         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1268         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1269         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1270         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1271         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1272 }
1273
1274 void HUD_Configure_PostDraw()
1275 {
1276         if(autocvar__hud_configure)
1277         {
1278                 if(tab_panel)
1279                 {
1280                         panel = tab_panel;
1281                         HUD_Panel_UpdatePosSize();
1282                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1283                 }
1284                 if(highlightedPanel)
1285                 {
1286                         panel = highlightedPanel;
1287                         HUD_Panel_UpdatePosSize();
1288                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1289                 }
1290         }
1291 }