qcsrc/client/hud_config.qc

   1 #include "hud_config.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5
   6 #include "../common/constants.qh"
   7
   8 #include "../dpdefs/keycodes.qh"
   9
  10
  11 #define HUD_Write(s) fputs(fh, s)
  12 // q: quoted, n: not quoted
  13 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
  14 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
  15 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
  16 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
  17 // Save the config
  18 void HUD_Panel_ExportCfg(string cfgname)
  19 {
  20         float fh;
  21         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  22         fh = fopen(filename, FILE_WRITE);
  23         if(fh >= 0)
  24         {
  25                 HUD_Write_Cvar_q("hud_skin");
  26                 HUD_Write_Cvar_q("hud_panel_bg");
  27                 HUD_Write_Cvar_q("hud_panel_bg_color");
  28                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  29                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  30                 HUD_Write_Cvar_q("hud_panel_bg_border");
  31                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  32                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  33                 HUD_Write("\n");
  34
  35                 HUD_Write_Cvar_q("hud_dock");
  36                 HUD_Write_Cvar_q("hud_dock_color");
  37                 HUD_Write_Cvar_q("hud_dock_color_team");
  38                 HUD_Write_Cvar_q("hud_dock_alpha");
  39                 HUD_Write("\n");
  40
  41                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  42                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  43                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  44                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  45                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  46                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  47                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  48                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  49                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  50                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  51                 HUD_Write("\n");
  52
  53                 HUD_Write_Cvar_q("_hud_panelorder");
  54                 HUD_Write("\n");
  55
  56                 HUD_Write_Cvar_q("hud_configure_grid");
  57                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  58                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  59                 HUD_Write("\n");
  60
  61                 // common cvars for all panels
  62                 int i;
  63                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  64                 {
  65                         panel = hud_panel[i];
  66
  67                         HUD_Write_PanelCvar_n("");
  68                         HUD_Write_PanelCvar_q("_pos");
  69                         HUD_Write_PanelCvar_q("_size");
  70                         HUD_Write_PanelCvar_q("_bg");
  71                         HUD_Write_PanelCvar_q("_bg_color");
  72                         HUD_Write_PanelCvar_q("_bg_color_team");
  73                         HUD_Write_PanelCvar_q("_bg_alpha");
  74                         HUD_Write_PanelCvar_q("_bg_border");
  75                         HUD_Write_PanelCvar_q("_bg_padding");
  76                         switch(i) {
  77                                 case HUD_PANEL_WEAPONS:
  78                                         HUD_Write_PanelCvar_q("_accuracy");
  79                                         HUD_Write_PanelCvar_q("_label");
  80                                         HUD_Write_PanelCvar_q("_label_scale");
  81                                         HUD_Write_PanelCvar_q("_complainbubble");
  82                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  83                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  84                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  85                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  86                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  87                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  88                                         HUD_Write_PanelCvar_q("_ammo");
  89                                         HUD_Write_PanelCvar_q("_ammo_color");
  90                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  91                                         HUD_Write_PanelCvar_q("_aspect");
  92                                         HUD_Write_PanelCvar_q("_timeout");
  93                                         HUD_Write_PanelCvar_q("_timeout_effect");
  94                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  95                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  96                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  97                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  98                                         HUD_Write_PanelCvar_q("_onlyowned");
  99                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 100                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 101                                         break;
 102                                 case HUD_PANEL_AMMO:
 103                                         HUD_Write_PanelCvar_q("_onlycurrent");
 104                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 105                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 106                                         HUD_Write_PanelCvar_q("_iconalign");
 107                                         HUD_Write_PanelCvar_q("_progressbar");
 108                                         HUD_Write_PanelCvar_q("_progressbar_name");
 109                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 110                                         HUD_Write_PanelCvar_q("_text");
 111                                         break;
 112                                 case HUD_PANEL_POWERUPS:
 113                                         HUD_Write_PanelCvar_q("_iconalign");
 114                                         HUD_Write_PanelCvar_q("_baralign");
 115                                         HUD_Write_PanelCvar_q("_progressbar");
 116                                         HUD_Write_PanelCvar_q("_text");
 117                                         break;
 118                                 case HUD_PANEL_HEALTHARMOR:
 119                                         HUD_Write_PanelCvar_q("_flip");
 120                                         HUD_Write_PanelCvar_q("_iconalign");
 121                                         HUD_Write_PanelCvar_q("_baralign");
 122                                         HUD_Write_PanelCvar_q("_progressbar");
 123                                         HUD_Write_PanelCvar_q("_progressbar_health");
 124                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 125                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 126                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 127                                         HUD_Write_PanelCvar_q("_text");
 128                                         break;
 129                                 case HUD_PANEL_NOTIFY:
 130                                         HUD_Write_PanelCvar_q("_flip");
 131                                         HUD_Write_PanelCvar_q("_fontsize");
 132                                         HUD_Write_PanelCvar_q("_time");
 133                                         HUD_Write_PanelCvar_q("_fadetime");
 134                                         HUD_Write_PanelCvar_q("_icon_aspect");
 135                                         break;
 136                                 case HUD_PANEL_TIMER:
 137                                         HUD_Write_PanelCvar_q("_increment");
 138                                         break;
 139                                 case HUD_PANEL_RADAR:
 140                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 141                                         HUD_Write_PanelCvar_q("_rotation");
 142                                         HUD_Write_PanelCvar_q("_zoommode");
 143                                         HUD_Write_PanelCvar_q("_scale");
 144                                         HUD_Write_PanelCvar_q("_maximized_scale");
 145                                         HUD_Write_PanelCvar_q("_maximized_size");
 146                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 147                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 148                                         break;
 149                                 case HUD_PANEL_SCORE:
 150                                         HUD_Write_PanelCvar_q("_rankings");
 151                                         break;
 152                                 case HUD_PANEL_VOTE:
 153                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 154                                         break;
 155                                 case HUD_PANEL_MODICONS:
 156                                         HUD_Write_PanelCvar_q("_ca_layout");
 157                                         HUD_Write_PanelCvar_q("_dom_layout");
 158                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 159                                         break;
 160                                 case HUD_PANEL_PRESSEDKEYS:
 161                                         HUD_Write_PanelCvar_q("_aspect");
 162                                         HUD_Write_PanelCvar_q("_attack");
 163                                         break;
 164                                 case HUD_PANEL_ENGINEINFO:
 165                                         HUD_Write_PanelCvar_q("_framecounter_time");
 166                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 167                                         break;
 168                                 case HUD_PANEL_INFOMESSAGES:
 169                                         HUD_Write_PanelCvar_q("_flip");
 170                                         break;
 171                                 case HUD_PANEL_PHYSICS:
 172                                         HUD_Write_PanelCvar_q("_speed_unit");
 173                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 174                                         HUD_Write_PanelCvar_q("_speed_max");
 175                                         HUD_Write_PanelCvar_q("_speed_vertical");
 176                                         HUD_Write_PanelCvar_q("_topspeed");
 177                                         HUD_Write_PanelCvar_q("_topspeed_time");
 178                                         HUD_Write_PanelCvar_q("_acceleration_max");
 179                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 180                                         HUD_Write_PanelCvar_q("_flip");
 181                                         HUD_Write_PanelCvar_q("_baralign");
 182                                         HUD_Write_PanelCvar_q("_progressbar");
 183                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 184                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 185                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 186                                         HUD_Write_PanelCvar_q("_text");
 187                                         HUD_Write_PanelCvar_q("_text_scale");
 188                                         break;
 189                                 case HUD_PANEL_CENTERPRINT:
 190                                         HUD_Write_PanelCvar_q("_align");
 191                                         HUD_Write_PanelCvar_q("_flip");
 192                                         HUD_Write_PanelCvar_q("_fontscale");
 193                                         HUD_Write_PanelCvar_q("_time");
 194                                         HUD_Write_PanelCvar_q("_fade_in");
 195                                         HUD_Write_PanelCvar_q("_fade_out");
 196                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 197                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 198                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 199                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 200                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 201                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 202                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 203                                         break;
 204                                 case HUD_PANEL_ITEMSTIME:
 205                                         HUD_Write_PanelCvar_q("_iconalign");
 206                                         HUD_Write_PanelCvar_q("_progressbar");
 207                                         HUD_Write_PanelCvar_q("_progressbar_name");
 208                                         HUD_Write_PanelCvar_q("_progressbar_reduced");
 209                                         HUD_Write_PanelCvar_q("_text");
 210                                         HUD_Write_PanelCvar_q("_ratio");
 211                                         HUD_Write_PanelCvar_q("_dynamicsize");
 212                                         break;
 213                         }
 214                         HUD_Write("\n");
 215                 }
 216                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 217
 218                 LOG_INFOF(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 219                 fclose(fh);
 220         }
 221         else
 222                 LOG_INFOF(_("^1Couldn't write to %s\n"), filename);
 223 }
 224
 225 void HUD_Configure_Exit_Force()
 226 {
 227         if (menu_enabled)
 228         {
 229                 menu_enabled = 0;
 230                 localcmd("togglemenu\n");
 231         }
 232         cvar_set("_hud_configure", "0");
 233 }
 234
 235 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 236 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 237 {
 238         vector myCenter, targCenter;
 239         vector myTarget = myPos;
 240         int i;
 241         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 242                 panel = hud_panel[i];
 243                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 244                 if(panel == highlightedPanel) continue;
 245                 HUD_Panel_UpdatePosSize();
 246                 if(!panel_enabled) continue;
 247
 248                 panel_pos -= '1 1 0' * panel_bg_border;
 249                 panel_size += '2 2 0' * panel_bg_border;
 250
 251                 if(myPos.y + mySize.y < panel_pos.y)
 252                         continue;
 253                 if(myPos.y > panel_pos.y + panel_size.y)
 254                         continue;
 255
 256                 if(myPos.x + mySize.x < panel_pos.x)
 257                         continue;
 258                 if(myPos.x > panel_pos.x + panel_size.x)
 259                         continue;
 260
 261                 // OK, there IS a collision.
 262
 263                 myCenter.x = myPos.x + 0.5 * mySize.x;
 264                 myCenter.y = myPos.y + 0.5 * mySize.y;
 265
 266                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 267                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 268
 269                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 270                 {
 271                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 272                                 myTarget.x = panel_pos.x - mySize.x;
 273                         else // push it upwards
 274                                 myTarget.y = panel_pos.y - mySize.y;
 275                 }
 276                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 277                 {
 278                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 279                                 myTarget.x = panel_pos.x + panel_size.x;
 280                         else // push it upwards
 281                                 myTarget.y = panel_pos.y - mySize.y;
 282                 }
 283                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 284                 {
 285                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 286                                 myTarget.x = panel_pos.x - mySize.x;
 287                         else // push it downwards
 288                                 myTarget.y = panel_pos.y + panel_size.y;
 289                 }
 290                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 291                 {
 292                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 293                                 myTarget.x = panel_pos.x + panel_size.x;
 294                         else // push it downwards
 295                                 myTarget.y = panel_pos.y + panel_size.y;
 296                 }
 297                 //if(cvar("hud_configure_checkcollisions_debug"))
 298                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 299         }
 300
 301         return myTarget;
 302 }
 303
 304 void HUD_Panel_SetPos(vector pos)
 305 {
 306         panel = highlightedPanel;
 307         HUD_Panel_UpdatePosSize();
 308         vector mySize;
 309         mySize = panel_size;
 310
 311         //if(cvar("hud_configure_checkcollisions_debug"))
 312                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 313
 314         if(autocvar_hud_configure_grid)
 315         {
 316                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 317                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 318         }
 319
 320         if(hud_configure_checkcollisions)
 321                 pos = HUD_Panel_CheckMove(pos, mySize);
 322
 323         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 324         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 325
 326         string s;
 327         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 328
 329         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 330 }
 331
 332 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 333 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 334         vector targEndPos;
 335         vector dist;
 336         float ratio = mySize.x/mySize.y;
 337         int i;
 338         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 339                 panel = hud_panel[i];
 340                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 341                 if(panel == highlightedPanel) continue;
 342                 HUD_Panel_UpdatePosSize();
 343                 if(!panel_enabled) continue;
 344
 345                 panel_pos -= '1 1 0' * panel_bg_border;
 346                 panel_size += '2 2 0' * panel_bg_border;
 347
 348                 targEndPos = panel_pos + panel_size;
 349
 350                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 351                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 352                         continue;
 353
 354                 if (resizeCorner == 1)
 355                 {
 356                         // check if this panel is on our way
 357                         if (resizeorigin.x <= panel_pos.x)
 358                                 continue;
 359                         if (resizeorigin.y <= panel_pos.y)
 360                                 continue;
 361                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 362                                 continue;
 363                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 364                                 continue;
 365
 366                         // there is a collision:
 367                         // detect which side of the panel we are facing is actually limiting the resizing
 368                         // (which side the resize direction finds for first) and reduce the size up to there
 369                         //
 370                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 371                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 372                         dist.x = resizeorigin.x - targEndPos.x;
 373                         dist.y = resizeorigin.y - targEndPos.y;
 374                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 375                                 mySize.x = min(mySize.x, dist.x);
 376                         else
 377                                 mySize.y = min(mySize.y, dist.y);
 378                 }
 379                 else if (resizeCorner == 2)
 380                 {
 381                         if (resizeorigin.x >= targEndPos.x)
 382                                 continue;
 383                         if (resizeorigin.y <= panel_pos.y)
 384                                 continue;
 385                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 386                                 continue;
 387                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 388                                 continue;
 389
 390                         dist.x = panel_pos.x - resizeorigin.x;
 391                         dist.y = resizeorigin.y - targEndPos.y;
 392                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 393                                 mySize.x = min(mySize.x, dist.x);
 394                         else
 395                                 mySize.y = min(mySize.y, dist.y);
 396                 }
 397                 else if (resizeCorner == 3)
 398                 {
 399                         if (resizeorigin.x <= panel_pos.x)
 400                                 continue;
 401                         if (resizeorigin.y >= targEndPos.y)
 402                                 continue;
 403                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 404                                 continue;
 405                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 406                                 continue;
 407
 408                         dist.x = resizeorigin.x - targEndPos.x;
 409                         dist.y = panel_pos.y - resizeorigin.y;
 410                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 411                                 mySize.x = min(mySize.x, dist.x);
 412                         else
 413                                 mySize.y = min(mySize.y, dist.y);
 414                 }
 415                 else if (resizeCorner == 4)
 416                 {
 417                         if (resizeorigin.x >= targEndPos.x)
 418                                 continue;
 419                         if (resizeorigin.y >= targEndPos.y)
 420                                 continue;
 421                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 422                                 continue;
 423                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 424                                 continue;
 425
 426                         dist.x = panel_pos.x - resizeorigin.x;
 427                         dist.y = panel_pos.y - resizeorigin.y;
 428                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 429                                 mySize.x = min(mySize.x, dist.x);
 430                         else
 431                                 mySize.y = min(mySize.y, dist.y);
 432                 }
 433                 //if(cvar("hud_configure_checkcollisions_debug"))
 434                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 435         }
 436
 437         return mySize;
 438 }
 439
 440 void HUD_Panel_SetPosSize(vector mySize)
 441 {
 442         panel = highlightedPanel;
 443         HUD_Panel_UpdatePosSize();
 444         vector resizeorigin = panel_click_resizeorigin;
 445         vector myPos;
 446
 447         // minimum panel size cap
 448         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 449         mySize.y = max(0.025 * vid_conheight, mySize.y);
 450
 451         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 452         {
 453                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 454                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 455         }
 456
 457         // collision testing|
 458         // -----------------+
 459
 460         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 461         if(resizeCorner == 1) {
 462                 myPos.x = resizeorigin.x - mySize.x;
 463                 myPos.y = resizeorigin.y - mySize.y;
 464         } else if(resizeCorner == 2) {
 465                 myPos.x = resizeorigin.x;
 466                 myPos.y = resizeorigin.y - mySize.y;
 467         } else if(resizeCorner == 3) {
 468                 myPos.x = resizeorigin.x - mySize.x;
 469                 myPos.y = resizeorigin.y;
 470         } else { // resizeCorner == 4
 471                 myPos.x = resizeorigin.x;
 472                 myPos.y = resizeorigin.y;
 473         }
 474
 475         // left/top screen edges
 476         if(myPos.x < 0)
 477                 mySize.x = mySize.x + myPos.x;
 478         if(myPos.y < 0)
 479                 mySize.y = mySize.y + myPos.y;
 480
 481         // bottom/right screen edges
 482         if(myPos.x + mySize.x > vid_conwidth)
 483                 mySize.x = vid_conwidth - myPos.x;
 484         if(myPos.y + mySize.y > vid_conheight)
 485                 mySize.y = vid_conheight - myPos.y;
 486
 487         //if(cvar("hud_configure_checkcollisions_debug"))
 488                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 489
 490         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 491         if(autocvar_hud_configure_grid)
 492         {
 493                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 494                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 495         }
 496
 497         if(hud_configure_checkcollisions)
 498                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 499
 500         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 501         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 502         mySize.y = max(0.025 * vid_conheight, mySize.y);
 503
 504         // do another pos check, as size might have changed by now
 505         if(resizeCorner == 1) {
 506                 myPos.x = resizeorigin.x - mySize.x;
 507                 myPos.y = resizeorigin.y - mySize.y;
 508         } else if(resizeCorner == 2) {
 509                 myPos.x = resizeorigin.x;
 510                 myPos.y = resizeorigin.y - mySize.y;
 511         } else if(resizeCorner == 3) {
 512                 myPos.x = resizeorigin.x - mySize.x;
 513                 myPos.y = resizeorigin.y;
 514         } else { // resizeCorner == 4
 515                 myPos.x = resizeorigin.x;
 516                 myPos.y = resizeorigin.y;
 517         }
 518
 519         //if(cvar("hud_configure_checkcollisions_debug"))
 520                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 521
 522         string s;
 523         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 524         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 525
 526         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 527         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 528 }
 529
 530 float pressed_key_time;
 531 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 532 void HUD_Panel_Arrow_Action(float nPrimary)
 533 {
 534         if(!highlightedPanel)
 535                 return;
 536
 537         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 538
 539         float step;
 540         if(autocvar_hud_configure_grid)
 541         {
 542                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 543                 {
 544                         if (hudShiftState & S_SHIFT)
 545                                 step = hud_configure_realGridSize.y;
 546                         else
 547                                 step = 2 * hud_configure_realGridSize.y;
 548                 }
 549                 else
 550                 {
 551                         if (hudShiftState & S_SHIFT)
 552                                 step = hud_configure_realGridSize.x;
 553                         else
 554                                 step = 2 * hud_configure_realGridSize.x;
 555                 }
 556         }
 557         else
 558         {
 559                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 560                         step = vid_conheight;
 561                 else
 562                         step = vid_conwidth;
 563                 if (hudShiftState & S_SHIFT)
 564                         step = (step / 256); // more precision
 565                 else
 566                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 567         }
 568
 569         panel = highlightedPanel;
 570         HUD_Panel_UpdatePosSize();
 571
 572         highlightedPanel_initial_pos = panel_pos;
 573         highlightedPanel_initial_size = panel_size;
 574
 575         if (hudShiftState & S_ALT) // resize
 576         {
 577                 if(nPrimary == K_UPARROW)
 578                         resizeCorner = 1;
 579                 else if(nPrimary == K_RIGHTARROW)
 580                         resizeCorner = 2;
 581                 else if(nPrimary == K_LEFTARROW)
 582                         resizeCorner = 3;
 583                 else // if(nPrimary == K_DOWNARROW)
 584                         resizeCorner = 4;
 585
 586                 // ctrl+arrow reduces the size, instead of increasing it
 587                 // Note that ctrl disables collisions check too, but it's fine
 588                 // since we don't collide with anything reducing the size
 589                 if (hudShiftState & S_CTRL) {
 590                         step = -step;
 591                         resizeCorner = 5 - resizeCorner;
 592                 }
 593
 594                 vector mySize;
 595                 mySize = panel_size;
 596                 panel_click_resizeorigin = panel_pos;
 597                 if(resizeCorner == 1) {
 598                         panel_click_resizeorigin += mySize;
 599                         mySize.y += step;
 600                 } else if(resizeCorner == 2) {
 601                         panel_click_resizeorigin.y += mySize.y;
 602                         mySize.x += step;
 603                 } else if(resizeCorner == 3) {
 604                         panel_click_resizeorigin.x += mySize.x;
 605                         mySize.x += step;
 606                 } else { // resizeCorner == 4
 607                         mySize.y += step;
 608                 }
 609                 HUD_Panel_SetPosSize(mySize);
 610         }
 611         else // move
 612         {
 613                 vector pos;
 614                 pos = panel_pos;
 615                 if(nPrimary == K_UPARROW)
 616                         pos.y -= step;
 617                 else if(nPrimary == K_DOWNARROW)
 618                         pos.y += step;
 619                 else if(nPrimary == K_LEFTARROW)
 620                         pos.x -= step;
 621                 else // if(nPrimary == K_RIGHTARROW)
 622                         pos.x += step;
 623
 624                 HUD_Panel_SetPos(pos);
 625         }
 626
 627         panel = highlightedPanel;
 628         HUD_Panel_UpdatePosSize();
 629
 630         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 631         {
 632                 // backup!
 633                 panel_pos_backup = highlightedPanel_initial_pos;
 634                 panel_size_backup = highlightedPanel_initial_size;
 635                 highlightedPanel_backup = highlightedPanel;
 636         }
 637 }
 638
 639 void HUD_Panel_EnableMenu();
 640 entity tab_panels[HUD_PANEL_MAX];
 641 entity tab_panel;
 642 vector tab_panel_pos;
 643 float tab_backward;
 644 void HUD_Panel_FirstInDrawQ(float id);
 645 void reset_tab_panels()
 646 {
 647         int i;
 648         for(i = 0; i < HUD_PANEL_NUM; ++i)
 649                 tab_panels[i] = world;
 650 }
 651 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 652 {
 653         string s;
 654
 655         if(bInputType == 2)
 656                 return false;
 657
 658         if(!autocvar__hud_configure)
 659                 return false;
 660
 661         if(bInputType == 3)
 662         {
 663                 mousepos.x = nPrimary;
 664                 mousepos.y = nSecondary;
 665                 return true;
 666         }
 667
 668         // block any input while a menu dialog is fading
 669         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 670         if(autocvar__menu_alpha)
 671         {
 672                 hudShiftState = 0;
 673                 mouseClicked = 0;
 674                 return true;
 675         }
 676
 677         // allow console bind to work
 678         string con_keys;
 679         float keys;
 680         con_keys = findkeysforcommand("toggleconsole", 0);
 681         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 682
 683         bool hit_con_bind = false;
 684         int i;
 685         for (i = 0; i < keys; ++i)
 686         {
 687                 if(nPrimary == stof(argv(i)))
 688                         hit_con_bind = true;
 689         }
 690
 691         if(bInputType == 0) {
 692                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 693                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 694                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 695         }
 696         else if(bInputType == 1) {
 697                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 698                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 699                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 700         }
 701
 702         if(nPrimary == K_CTRL)
 703         {
 704                 if (bInputType == 1) //ctrl has been released
 705                 {
 706                         if (tab_panel)
 707                         {
 708                                 //switch to selected panel
 709                                 highlightedPanel = tab_panel;
 710                                 highlightedAction = 0;
 711                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 712                         }
 713                         tab_panel = world;
 714                         reset_tab_panels();
 715                 }
 716         }
 717
 718         if(nPrimary == K_MOUSE1)
 719         {
 720                 if(bInputType == 0) // key pressed
 721                         mouseClicked |= S_MOUSE1;
 722                 else if(bInputType == 1) // key released
 723                         mouseClicked -= (mouseClicked & S_MOUSE1);
 724         }
 725         else if(nPrimary == K_MOUSE2)
 726         {
 727                 if(bInputType == 0) // key pressed
 728                         mouseClicked |= S_MOUSE2;
 729                 else if(bInputType == 1) // key released
 730                         mouseClicked -= (mouseClicked & S_MOUSE2);
 731         }
 732         else if(nPrimary == K_ESCAPE)
 733         {
 734                 if (bInputType == 1)
 735                         return true;
 736                 menu_enabled = 1;
 737                 localcmd("menu_showhudexit\n");
 738         }
 739         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 740         {
 741                 if (bInputType == 1)
 742                         return true;
 743                 if (!menu_enabled)
 744                         cvar_set("_hud_configure", "0");
 745         }
 746         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
 747         {
 748                 if (bInputType == 1 || mouseClicked)
 749                         return true;
 750
 751                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
 752                 // lays in the same level of another panel then the next consecutive
 753                 // CTRL TAB presses will reselect once more the highlighted panel
 754
 755                 entity starting_panel;
 756                 entity old_tab_panel = tab_panel;
 757                 if (!tab_panel) //first press of TAB
 758                 {
 759                         if (highlightedPanel)
 760                         {
 761                                 panel = highlightedPanel;
 762                                 HUD_Panel_UpdatePosSize();
 763                         }
 764                         else
 765                                 panel_pos = '0 0 0';
 766                         starting_panel = highlightedPanel;
 767                         tab_panel_pos = panel_pos; //to compute level
 768                 }
 769                 else
 770                 {
 771                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 772                                 reset_tab_panels();
 773                         starting_panel = tab_panel;
 774                 }
 775                 tab_backward = (hudShiftState & S_SHIFT);
 776
 777                 float k, level = 0, start_posX;
 778                 vector candidate_pos = '0 0 0';
 779                 const float LEVELS_NUM = 4;
 780                 float level_height = vid_conheight / LEVELS_NUM;
 781 :find_tab_panel
 782                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 783                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 784                 start_posX = tab_panel_pos.x;
 785                 tab_panel = world;
 786                 k=0;
 787                 while(++k)
 788                 {
 789                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 790                         {
 791                                 panel = hud_panel[i];
 792                                 if(panel == HUD_PANEL(MAPVOTE))
 793                                         continue;
 794                                 if (panel == tab_panels[i] || panel == starting_panel)
 795                                         continue;
 796                                 HUD_Panel_UpdatePosSize();
 797                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 798                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 799                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 800                                 {
 801                                         tab_panel = panel;
 802                                         tab_panel_pos = candidate_pos = panel_pos;
 803                                 }
 804                         }
 805                         if (tab_panel)
 806                                 break;
 807                         if (k == LEVELS_NUM) //tab_panel not found
 808                         {
 809                                 reset_tab_panels();
 810                                 if (!old_tab_panel)
 811                                 {
 812                                         tab_panel = world;
 813                                         return true;
 814                                 }
 815                                 starting_panel = old_tab_panel;
 816                                 old_tab_panel = world;
 817                                 goto find_tab_panel; //u must find tab_panel!
 818                         }
 819                         if (!tab_backward)
 820                         {
 821                                 level = (level + level_height) % vid_conheight;
 822                                 start_posX = 0;
 823                                 candidate_pos.x = vid_conwidth;
 824                         }
 825                         else
 826                         {
 827                                 level = (level - level_height) % vid_conheight;
 828                                 start_posX = vid_conwidth;
 829                                 candidate_pos.x = 0;
 830                         }
 831                 }
 832
 833                 tab_panels[tab_panel.panel_id] = tab_panel;
 834         }
 835         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 836         {
 837                 if (bInputType == 1 || mouseClicked)
 838                         return true;
 839
 840                 if (highlightedPanel)
 841                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 842                 else
 843                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 844         }
 845         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 846         {
 847                 if (bInputType == 1 || mouseClicked)
 848                         return true;
 849
 850                 if (highlightedPanel)
 851                 {
 852                         panel = highlightedPanel;
 853                         HUD_Panel_UpdatePosSize();
 854                         panel_size_copied = panel_size;
 855                 }
 856         }
 857         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 858         {
 859                 if (bInputType == 1 || mouseClicked)
 860                         return true;
 861
 862                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 863                         return true;
 864
 865                 panel = highlightedPanel;
 866                 HUD_Panel_UpdatePosSize();
 867
 868                 // reduce size if it'd go beyond screen boundaries
 869                 vector tmp_size = panel_size_copied;
 870                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 871                         tmp_size.x = vid_conwidth - panel_pos.x;
 872                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 873                         tmp_size.y = vid_conheight - panel_pos.y;
 874
 875                 if (panel_size == tmp_size)
 876                         return true;
 877
 878                 // backup first!
 879                 panel_pos_backup = panel_pos;
 880                 panel_size_backup = panel_size;
 881                 highlightedPanel_backup = highlightedPanel;
 882
 883                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 884                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 885         }
 886         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 887         {
 888                 if (bInputType == 1 || mouseClicked)
 889                         return true;
 890                 //restore previous values
 891                 if (highlightedPanel_backup)
 892                 {
 893                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 894                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 895                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 896                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 897                         highlightedPanel_backup = world;
 898                 }
 899         }
 900         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
 901         {
 902                 if (bInputType == 1 || mouseClicked)
 903                         return true;
 904                 localcmd("hud save myconfig\n");
 905         }
 906         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 907         {
 908                 if (bInputType == 1)
 909                 {
 910                         pressed_key_time = 0;
 911                         return true;
 912                 }
 913                 else if (pressed_key_time == 0)
 914                         pressed_key_time = time;
 915
 916                 if (!mouseClicked)
 917                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 918         }
 919         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 920         {
 921                 if (bInputType == 1)
 922                         return true;
 923                 if (highlightedPanel)
 924                         HUD_Panel_EnableMenu();
 925         }
 926         else if(hit_con_bind || nPrimary == K_PAUSE)
 927                 return false;
 928
 929         return true;
 930 }
 931
 932 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 933 {
 934         int i, j = 0;
 935         while(j < HUD_PANEL_NUM)
 936         {
 937                 i = panel_order[j];
 938                 j += 1;
 939
 940                 panel = hud_panel[i];
 941                 if(panel == HUD_PANEL(MAPVOTE)) continue;
 942                 HUD_Panel_UpdatePosSize();
 943
 944                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 945
 946                 // move
 947                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 948                 {
 949                         return 1;
 950                 }
 951                 // resize from topleft border
 952                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 953                 {
 954                         return 2;
 955                 }
 956                 // resize from topright border
 957                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 958                 {
 959                         return 3;
 960                 }
 961                 // resize from bottomleft border
 962                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 963                 {
 964                         return 3;
 965                 }
 966                 // resize from bottomright border
 967                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 968                 {
 969                         return 2;
 970                 }
 971         }
 972         return 0;
 973 }
 974
 975 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 976 void HUD_Panel_FirstInDrawQ(float id)
 977 {
 978         int i;
 979         int place = -1;
 980         // find out where in the array our current id is, save into place
 981         for(i = 0; i < HUD_PANEL_NUM; ++i)
 982         {
 983                 if(panel_order[i] == id)
 984                 {
 985                         place = i;
 986                         break;
 987                 }
 988         }
 989         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 990         if(place == -1)
 991                 place = HUD_PANEL_NUM - 1;
 992
 993         // move all ids up by one step in the array until "place"
 994         for(i = place; i > 0; --i)
 995         {
 996                 panel_order[i] = panel_order[i-1];
 997         }
 998         // now save the new top id
 999         panel_order[0] = id;
1000
1001         // let's save them into the cvar by some strcat trickery
1002         string s = "";
1003         for(i = 0; i < HUD_PANEL_NUM; ++i)
1004         {
1005                 s = strcat(s, ftos(panel_order[i]), " ");
1006         }
1007         cvar_set("_hud_panelorder", s);
1008         if(hud_panelorder_prev)
1009                 strunzone(hud_panelorder_prev);
1010         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
1011 }
1012
1013 void HUD_Panel_Highlight(float allow_move)
1014 {
1015         int i, j = 0;
1016
1017         while(j < HUD_PANEL_NUM)
1018         {
1019                 i = panel_order[j];
1020                 j += 1;
1021
1022                 panel = hud_panel[i];
1023                 if(panel == HUD_PANEL(MAPVOTE))
1024                         continue;
1025                 HUD_Panel_UpdatePosSize();
1026
1027                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1028
1029                 // move
1030                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1031                 {
1032                         highlightedPanel = hud_panel[i];
1033                         HUD_Panel_FirstInDrawQ(i);
1034                         highlightedAction = 1;
1035                         panel_click_distance = mousepos - panel_pos;
1036                         return;
1037                 }
1038                 // resize from topleft border
1039                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1040                 {
1041                         highlightedPanel = hud_panel[i];
1042                         HUD_Panel_FirstInDrawQ(i);
1043                         highlightedAction = 2;
1044                         resizeCorner = 1;
1045                         panel_click_distance = mousepos - panel_pos;
1046                         panel_click_resizeorigin = panel_pos + panel_size;
1047                         return;
1048                 }
1049                 // resize from topright border
1050                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1051                 {
1052                         highlightedPanel = hud_panel[i];
1053                         HUD_Panel_FirstInDrawQ(i);
1054                         highlightedAction = 2;
1055                         resizeCorner = 2;
1056                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1057                         panel_click_distance.y = mousepos.y - panel_pos.y;
1058                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1059                         return;
1060                 }
1061                 // resize from bottomleft border
1062                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1063                 {
1064                         highlightedPanel = hud_panel[i];
1065                         HUD_Panel_FirstInDrawQ(i);
1066                         highlightedAction = 2;
1067                         resizeCorner = 3;
1068                         panel_click_distance.x = mousepos.x - panel_pos.x;
1069                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1070                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1071                         return;
1072                 }
1073                 // resize from bottomright border
1074                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1075                 {
1076                         highlightedPanel = hud_panel[i];
1077                         HUD_Panel_FirstInDrawQ(i);
1078                         highlightedAction = 2;
1079                         resizeCorner = 4;
1080                         panel_click_distance = panel_size - mousepos + panel_pos;
1081                         panel_click_resizeorigin = panel_pos;
1082                         return;
1083                 }
1084         }
1085         highlightedPanel = world;
1086         highlightedAction = 0;
1087 }
1088
1089 void HUD_Panel_EnableMenu()
1090 {
1091         menu_enabled = 2;
1092         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1093 }
1094 float mouse_over_panel;
1095 void HUD_Panel_Mouse()
1096 {
1097         if(autocvar__menu_alpha == 1)
1098                 return;
1099
1100         if (!autocvar_hud_cursormode)
1101         {
1102                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1103
1104                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1105                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1106         }
1107
1108         if(mouseClicked)
1109         {
1110                 if(prevMouseClicked == 0)
1111                 {
1112                         if (tab_panel)
1113                         {
1114                                 //stop ctrl-tab selection
1115                                 tab_panel = world;
1116                                 reset_tab_panels();
1117                         }
1118                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1119                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1120                         if (highlightedPanel)
1121                         {
1122                                 highlightedPanel_initial_pos = panel_pos;
1123                                 highlightedPanel_initial_size = panel_size;
1124                         }
1125                         // doubleclick check
1126                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1127                         {
1128                                 mouseClicked = 0; // to prevent spam, I guess.
1129                                 HUD_Panel_EnableMenu();
1130                         }
1131                         else
1132                         {
1133                                 if (mouseClicked & S_MOUSE1)
1134                                 {
1135                                         prevMouseClickedTime = time;
1136                                         prevMouseClickedPos = mousepos;
1137                                 }
1138                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1139                         }
1140                 }
1141                 else
1142                 {
1143                         panel = highlightedPanel;
1144                         HUD_Panel_UpdatePosSize();
1145                 }
1146
1147                 if (highlightedPanel)
1148                 {
1149                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1150                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1151                         {
1152                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1153                                 // backup!
1154                                 panel_pos_backup = highlightedPanel_initial_pos;
1155                                 panel_size_backup = highlightedPanel_initial_size;
1156                                 highlightedPanel_backup = highlightedPanel;
1157                         }
1158                         else
1159                                 // in case the clicked panel is inside another panel and we aren't
1160                                 // moving it, avoid the immediate "fix" of its position/size
1161                                 // (often unwanted and hateful) by disabling collisions check
1162                                 hud_configure_checkcollisions = false;
1163                 }
1164
1165                 if(highlightedAction == 1)
1166                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1167                 else if(highlightedAction == 2)
1168                 {
1169                         vector mySize = '0 0 0';
1170                         if(resizeCorner == 1) {
1171                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1172                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1173                         } else if(resizeCorner == 2) {
1174                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1175                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1176                         } else if(resizeCorner == 3) {
1177                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1178                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1179                         } else { // resizeCorner == 4
1180                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1181                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1182                         }
1183                         HUD_Panel_SetPosSize(mySize);
1184                 }
1185         }
1186         else
1187         {
1188                 if(prevMouseClicked)
1189                         highlightedAction = 0;
1190                 if(menu_enabled == 2)
1191                         mouse_over_panel = 0;
1192                 else
1193                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1194                 if (mouse_over_panel && !tab_panel)
1195                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1196         }
1197         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1198         const vector cursorsize = '32 32 0';
1199         float cursor_alpha = 1 - autocvar__menu_alpha;
1200
1201         if(!mouse_over_panel)
1202                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1203         else if(mouse_over_panel == 1)
1204                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1205         else if(mouse_over_panel == 2)
1206                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1207         else
1208                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1209
1210         prevMouseClicked = mouseClicked;
1211 }
1212 void HUD_Configure_DrawGrid()
1213 {
1214         float i;
1215         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1216         {
1217                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1218                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1219                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1220                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1221                 vector s;
1222                 // x-axis
1223                 s = eX + eY * vid_conheight;
1224                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1225                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1226                 // y-axis
1227                 s = eY + eX * vid_conwidth;
1228                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1229                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1230         }
1231 }
1232
1233 float _menu_alpha_prev;
1234 void HUD_Configure_Frame()
1235 {
1236         int i;
1237         if(autocvar__hud_configure)
1238         {
1239                 if(isdemo() || intermission == 2)
1240                 {
1241                         HUD_Configure_Exit_Force();
1242                         return;
1243                 }
1244
1245                 if(!hud_configure_prev)
1246                 {
1247                         if(autocvar_hud_cursormode)
1248                                 setcursormode(1);
1249                         hudShiftState = 0;
1250                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1251                                 hud_panel[panel_order[i]].update_time = time;
1252                 }
1253
1254                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1255                 if(autocvar__menu_alpha != _menu_alpha_prev)
1256                 {
1257                         if(autocvar__menu_alpha == 0)
1258                                 menu_enabled = 0;
1259                         _menu_alpha_prev = autocvar__menu_alpha;
1260                 }
1261
1262                 HUD_Configure_DrawGrid();
1263         }
1264         else if(hud_configure_prev)
1265         {
1266                 if(menu_enabled)
1267                         menu_enabled = 0;
1268                 if(autocvar_hud_cursormode)
1269                         setcursormode(0);
1270         }
1271 }
1272
1273 const float hlBorderSize = 2;
1274 const string hlBorder = "gfx/hud/default/border_highlighted";
1275 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1276 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1277 {
1278         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1279         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1280         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1281         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1282         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1283 }
1284
1285 void HUD_Configure_PostDraw()
1286 {
1287         if(autocvar__hud_configure)
1288         {
1289                 if(tab_panel)
1290                 {
1291                         panel = tab_panel;
1292                         HUD_Panel_UpdatePosSize();
1293                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1294                 }
1295                 if(highlightedPanel)
1296                 {
1297                         panel = highlightedPanel;
1298                         HUD_Panel_UpdatePosSize();
1299                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1300                 }
1301         }
1302 }