qcsrc/client/hud_config.qc

   1 #include "hud_config.qh"
   2 #include "_all.qh"
   3
   4 #include "hud.qh"
   5
   6 #include "../common/constants.qh"
   7
   8 #include "../dpdefs/keycodes.qh"
   9
  10
  11 #define HUD_Write(s) fputs(fh, s)
  12 // q: quoted, n: not quoted
  13 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
  14 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
  15 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
  16 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
  17 // Save the config
  18 void HUD_Panel_ExportCfg(string cfgname)
  19 {
  20         float fh;
  21         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  22         fh = fopen(filename, FILE_WRITE);
  23         if(fh >= 0)
  24         {
  25                 HUD_Write_Cvar_q("hud_skin");
  26                 HUD_Write_Cvar_q("hud_panel_bg");
  27                 HUD_Write_Cvar_q("hud_panel_bg_color");
  28                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  29                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  30                 HUD_Write_Cvar_q("hud_panel_bg_border");
  31                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  32                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  33                 HUD_Write("\n");
  34
  35                 HUD_Write_Cvar_q("hud_dock");
  36                 HUD_Write_Cvar_q("hud_dock_color");
  37                 HUD_Write_Cvar_q("hud_dock_color_team");
  38                 HUD_Write_Cvar_q("hud_dock_alpha");
  39                 HUD_Write("\n");
  40
  41                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  42                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  43                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  44                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  45                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  46                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  47                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  48                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  49                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  50                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  51                 HUD_Write("\n");
  52
  53                 HUD_Write_Cvar_q("_hud_panelorder");
  54                 HUD_Write("\n");
  55
  56                 HUD_Write_Cvar_q("hud_configure_grid");
  57                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  58                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  59                 HUD_Write("\n");
  60
  61                 // common cvars for all panels
  62                 int i;
  63                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  64                 {
  65                         panel = hud_panel[i];
  66
  67                         HUD_Write_PanelCvar_n("");
  68                         HUD_Write_PanelCvar_q("_pos");
  69                         HUD_Write_PanelCvar_q("_size");
  70                         HUD_Write_PanelCvar_q("_bg");
  71                         HUD_Write_PanelCvar_q("_bg_color");
  72                         HUD_Write_PanelCvar_q("_bg_color_team");
  73                         HUD_Write_PanelCvar_q("_bg_alpha");
  74                         HUD_Write_PanelCvar_q("_bg_border");
  75                         HUD_Write_PanelCvar_q("_bg_padding");
  76                         switch(i) {
  77                                 case HUD_PANEL_WEAPONS:
  78                                         HUD_Write_PanelCvar_q("_accuracy");
  79                                         HUD_Write_PanelCvar_q("_label");
  80                                         HUD_Write_PanelCvar_q("_label_scale");
  81                                         HUD_Write_PanelCvar_q("_complainbubble");
  82                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  83                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  84                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  85                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  86                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  87                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  88                                         HUD_Write_PanelCvar_q("_ammo");
  89                                         HUD_Write_PanelCvar_q("_ammo_color");
  90                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  91                                         HUD_Write_PanelCvar_q("_aspect");
  92                                         HUD_Write_PanelCvar_q("_timeout");
  93                                         HUD_Write_PanelCvar_q("_timeout_effect");
  94                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  95                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  96                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  97                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  98                                         HUD_Write_PanelCvar_q("_onlyowned");
  99                                         break;
 100                                 case HUD_PANEL_AMMO:
 101                                         HUD_Write_PanelCvar_q("_onlycurrent");
 102                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
 103                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_progressbar");
 106                                         HUD_Write_PanelCvar_q("_progressbar_name");
 107                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
 108                                         HUD_Write_PanelCvar_q("_text");
 109                                         break;
 110                                 case HUD_PANEL_POWERUPS:
 111                                         HUD_Write_PanelCvar_q("_flip");
 112                                         HUD_Write_PanelCvar_q("_iconalign");
 113                                         HUD_Write_PanelCvar_q("_baralign");
 114                                         HUD_Write_PanelCvar_q("_progressbar");
 115                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 116                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 117                                         HUD_Write_PanelCvar_q("_text");
 118                                         break;
 119                                 case HUD_PANEL_HEALTHARMOR:
 120                                         HUD_Write_PanelCvar_q("_flip");
 121                                         HUD_Write_PanelCvar_q("_iconalign");
 122                                         HUD_Write_PanelCvar_q("_baralign");
 123                                         HUD_Write_PanelCvar_q("_progressbar");
 124                                         HUD_Write_PanelCvar_q("_progressbar_health");
 125                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 126                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 127                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 128                                         HUD_Write_PanelCvar_q("_text");
 129                                         break;
 130                                 case HUD_PANEL_NOTIFY:
 131                                         HUD_Write_PanelCvar_q("_flip");
 132                                         HUD_Write_PanelCvar_q("_fontsize");
 133                                         HUD_Write_PanelCvar_q("_time");
 134                                         HUD_Write_PanelCvar_q("_fadetime");
 135                                         HUD_Write_PanelCvar_q("_icon_aspect");
 136                                         break;
 137                                 case HUD_PANEL_TIMER:
 138                                         HUD_Write_PanelCvar_q("_increment");
 139                                         break;
 140                                 case HUD_PANEL_RADAR:
 141                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 142                                         HUD_Write_PanelCvar_q("_rotation");
 143                                         HUD_Write_PanelCvar_q("_zoommode");
 144                                         HUD_Write_PanelCvar_q("_scale");
 145                                         HUD_Write_PanelCvar_q("_maximized_scale");
 146                                         HUD_Write_PanelCvar_q("_maximized_size");
 147                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 148                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 149                                         break;
 150                                 case HUD_PANEL_SCORE:
 151                                         HUD_Write_PanelCvar_q("_rankings");
 152                                         break;
 153                                 case HUD_PANEL_VOTE:
 154                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 155                                         break;
 156                                 case HUD_PANEL_MODICONS:
 157                                         HUD_Write_PanelCvar_q("_ca_layout");
 158                                         HUD_Write_PanelCvar_q("_dom_layout");
 159                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 160                                         break;
 161                                 case HUD_PANEL_PRESSEDKEYS:
 162                                         HUD_Write_PanelCvar_q("_aspect");
 163                                         HUD_Write_PanelCvar_q("_attack");
 164                                         break;
 165                                 case HUD_PANEL_ENGINEINFO:
 166                                         HUD_Write_PanelCvar_q("_framecounter_time");
 167                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 168                                         break;
 169                                 case HUD_PANEL_INFOMESSAGES:
 170                                         HUD_Write_PanelCvar_q("_flip");
 171                                         break;
 172                                 case HUD_PANEL_PHYSICS:
 173                                         HUD_Write_PanelCvar_q("_speed_unit");
 174                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 175                                         HUD_Write_PanelCvar_q("_speed_max");
 176                                         HUD_Write_PanelCvar_q("_speed_vertical");
 177                                         HUD_Write_PanelCvar_q("_topspeed");
 178                                         HUD_Write_PanelCvar_q("_topspeed_time");
 179                                         HUD_Write_PanelCvar_q("_acceleration_max");
 180                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 181                                         HUD_Write_PanelCvar_q("_flip");
 182                                         HUD_Write_PanelCvar_q("_baralign");
 183                                         HUD_Write_PanelCvar_q("_progressbar");
 184                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 185                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 186                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 187                                         HUD_Write_PanelCvar_q("_text");
 188                                         HUD_Write_PanelCvar_q("_text_scale");
 189                                         break;
 190                                 case HUD_PANEL_CENTERPRINT:
 191                                         HUD_Write_PanelCvar_q("_align");
 192                                         HUD_Write_PanelCvar_q("_flip");
 193                                         HUD_Write_PanelCvar_q("_fontscale");
 194                                         HUD_Write_PanelCvar_q("_time");
 195                                         HUD_Write_PanelCvar_q("_fade_in");
 196                                         HUD_Write_PanelCvar_q("_fade_out");
 197                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 198                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 199                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 200                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 201                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 202                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 203                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 204                                         break;
 205                         }
 206                         HUD_Write("\n");
 207                 }
 208                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 209
 210                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 211                 fclose(fh);
 212         }
 213         else
 214                 printf(_("^1Couldn't write to %s\n"), filename);
 215 }
 216
 217 void HUD_Configure_Exit_Force()
 218 {
 219         if (menu_enabled)
 220         {
 221                 menu_enabled = 0;
 222                 localcmd("togglemenu\n");
 223         }
 224         cvar_set("_hud_configure", "0");
 225 }
 226
 227 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 228 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 229 {
 230         vector myCenter, targCenter;
 231         vector myTarget = myPos;
 232         int i;
 233         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 234                 panel = hud_panel[i];
 235                 if(panel == highlightedPanel) continue;
 236                 HUD_Panel_UpdatePosSize();
 237                 if(!panel_enabled) continue;
 238
 239                 panel_pos -= '1 1 0' * panel_bg_border;
 240                 panel_size += '2 2 0' * panel_bg_border;
 241
 242                 if(myPos.y + mySize.y < panel_pos.y)
 243                         continue;
 244                 if(myPos.y > panel_pos.y + panel_size.y)
 245                         continue;
 246
 247                 if(myPos.x + mySize.x < panel_pos.x)
 248                         continue;
 249                 if(myPos.x > panel_pos.x + panel_size.x)
 250                         continue;
 251
 252                 // OK, there IS a collision.
 253
 254                 myCenter.x = myPos.x + 0.5 * mySize.x;
 255                 myCenter.y = myPos.y + 0.5 * mySize.y;
 256
 257                 targCenter.x = panel_pos.x + 0.5 * panel_size.x;
 258                 targCenter.y = panel_pos.y + 0.5 * panel_size.y;
 259
 260                 if(myCenter.x < targCenter.x && myCenter.y < targCenter.y) // top left (of the target panel)
 261                 {
 262                         if(myPos.x + mySize.x - panel_pos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 263                                 myTarget.x = panel_pos.x - mySize.x;
 264                         else // push it upwards
 265                                 myTarget.y = panel_pos.y - mySize.y;
 266                 }
 267                 else if(myCenter.x > targCenter.x && myCenter.y < targCenter.y) // top right
 268                 {
 269                         if(panel_pos.x + panel_size.x - myPos.x < myPos.y + mySize.y - panel_pos.y) // push it to the side
 270                                 myTarget.x = panel_pos.x + panel_size.x;
 271                         else // push it upwards
 272                                 myTarget.y = panel_pos.y - mySize.y;
 273                 }
 274                 else if(myCenter.x < targCenter.x && myCenter.y > targCenter.y) // bottom left
 275                 {
 276                         if(myPos.x + mySize.x - panel_pos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 277                                 myTarget.x = panel_pos.x - mySize.x;
 278                         else // push it downwards
 279                                 myTarget.y = panel_pos.y + panel_size.y;
 280                 }
 281                 else if(myCenter.x > targCenter.x && myCenter.y > targCenter.y) // bottom right
 282                 {
 283                         if(panel_pos.x + panel_size.x - myPos.x < panel_pos.y + panel_size.y - myPos.y) // push it to the side
 284                                 myTarget.x = panel_pos.x + panel_size.x;
 285                         else // push it downwards
 286                                 myTarget.y = panel_pos.y + panel_size.y;
 287                 }
 288                 //if(cvar("hud_configure_checkcollisions_debug"))
 289                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 290         }
 291
 292         return myTarget;
 293 }
 294
 295 void HUD_Panel_SetPos(vector pos)
 296 {
 297         panel = highlightedPanel;
 298         HUD_Panel_UpdatePosSize();
 299         vector mySize;
 300         mySize = panel_size;
 301
 302         //if(cvar("hud_configure_checkcollisions_debug"))
 303                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 304
 305         if(autocvar_hud_configure_grid)
 306         {
 307                 pos.x = floor((pos.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 308                 pos.y = floor((pos.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 309         }
 310
 311         if(hud_configure_checkcollisions)
 312                 pos = HUD_Panel_CheckMove(pos, mySize);
 313
 314         pos.x = bound(0, pos.x, vid_conwidth - mySize.x);
 315         pos.y = bound(0, pos.y, vid_conheight - mySize.y);
 316
 317         string s;
 318         s = strcat(ftos(pos.x/vid_conwidth), " ", ftos(pos.y/vid_conheight));
 319
 320         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 321 }
 322
 323 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 324 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 325         vector targEndPos;
 326         vector dist;
 327         float ratio = mySize.x/mySize.y;
 328         int i;
 329         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 330                 panel = hud_panel[i];
 331                 if(panel == highlightedPanel) continue;
 332                 HUD_Panel_UpdatePosSize();
 333                 if(!panel_enabled) continue;
 334
 335                 panel_pos -= '1 1 0' * panel_bg_border;
 336                 panel_size += '2 2 0' * panel_bg_border;
 337
 338                 targEndPos = panel_pos + panel_size;
 339
 340                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 341                 if(resizeorigin.x > panel_pos.x && resizeorigin.x < targEndPos.x && resizeorigin.y > panel_pos.y && resizeorigin.y < targEndPos.y)
 342                         continue;
 343
 344                 if (resizeCorner == 1)
 345                 {
 346                         // check if this panel is on our way
 347                         if (resizeorigin.x <= panel_pos.x)
 348                                 continue;
 349                         if (resizeorigin.y <= panel_pos.y)
 350                                 continue;
 351                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 352                                 continue;
 353                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 354                                 continue;
 355
 356                         // there is a collision:
 357                         // detect which side of the panel we are facing is actually limiting the resizing
 358                         // (which side the resize direction finds for first) and reduce the size up to there
 359                         //
 360                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 361                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 362                         dist.x = resizeorigin.x - targEndPos.x;
 363                         dist.y = resizeorigin.y - targEndPos.y;
 364                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 365                                 mySize.x = min(mySize.x, dist.x);
 366                         else
 367                                 mySize.y = min(mySize.y, dist.y);
 368                 }
 369                 else if (resizeCorner == 2)
 370                 {
 371                         if (resizeorigin.x >= targEndPos.x)
 372                                 continue;
 373                         if (resizeorigin.y <= panel_pos.y)
 374                                 continue;
 375                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 376                                 continue;
 377                         if (targEndPos.y <= resizeorigin.y - mySize.y)
 378                                 continue;
 379
 380                         dist.x = panel_pos.x - resizeorigin.x;
 381                         dist.y = resizeorigin.y - targEndPos.y;
 382                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 383                                 mySize.x = min(mySize.x, dist.x);
 384                         else
 385                                 mySize.y = min(mySize.y, dist.y);
 386                 }
 387                 else if (resizeCorner == 3)
 388                 {
 389                         if (resizeorigin.x <= panel_pos.x)
 390                                 continue;
 391                         if (resizeorigin.y >= targEndPos.y)
 392                                 continue;
 393                         if (targEndPos.x <= resizeorigin.x - mySize.x)
 394                                 continue;
 395                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 396                                 continue;
 397
 398                         dist.x = resizeorigin.x - targEndPos.x;
 399                         dist.y = panel_pos.y - resizeorigin.y;
 400                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 401                                 mySize.x = min(mySize.x, dist.x);
 402                         else
 403                                 mySize.y = min(mySize.y, dist.y);
 404                 }
 405                 else if (resizeCorner == 4)
 406                 {
 407                         if (resizeorigin.x >= targEndPos.x)
 408                                 continue;
 409                         if (resizeorigin.y >= targEndPos.y)
 410                                 continue;
 411                         if (panel_pos.x >= resizeorigin.x + mySize.x)
 412                                 continue;
 413                         if (panel_pos.y >= resizeorigin.y + mySize.y)
 414                                 continue;
 415
 416                         dist.x = panel_pos.x - resizeorigin.x;
 417                         dist.y = panel_pos.y - resizeorigin.y;
 418                         if (dist.y <= 0 || dist.x / dist.y > ratio)
 419                                 mySize.x = min(mySize.x, dist.x);
 420                         else
 421                                 mySize.y = min(mySize.y, dist.y);
 422                 }
 423                 //if(cvar("hud_configure_checkcollisions_debug"))
 424                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 425         }
 426
 427         return mySize;
 428 }
 429
 430 void HUD_Panel_SetPosSize(vector mySize)
 431 {
 432         panel = highlightedPanel;
 433         HUD_Panel_UpdatePosSize();
 434         vector resizeorigin = panel_click_resizeorigin;
 435         vector myPos;
 436
 437         // minimum panel size cap
 438         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 439         mySize.y = max(0.025 * vid_conheight, mySize.y);
 440
 441         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 442         {
 443                 mySize.x = max(17 * autocvar_con_chatsize, mySize.x);
 444                 mySize.y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize.y);
 445         }
 446
 447         // collision testing|
 448         // -----------------+
 449
 450         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 451         if(resizeCorner == 1) {
 452                 myPos.x = resizeorigin.x - mySize.x;
 453                 myPos.y = resizeorigin.y - mySize.y;
 454         } else if(resizeCorner == 2) {
 455                 myPos.x = resizeorigin.x;
 456                 myPos.y = resizeorigin.y - mySize.y;
 457         } else if(resizeCorner == 3) {
 458                 myPos.x = resizeorigin.x - mySize.x;
 459                 myPos.y = resizeorigin.y;
 460         } else { // resizeCorner == 4
 461                 myPos.x = resizeorigin.x;
 462                 myPos.y = resizeorigin.y;
 463         }
 464
 465         // left/top screen edges
 466         if(myPos.x < 0)
 467                 mySize.x = mySize.x + myPos.x;
 468         if(myPos.y < 0)
 469                 mySize.y = mySize.y + myPos.y;
 470
 471         // bottom/right screen edges
 472         if(myPos.x + mySize.x > vid_conwidth)
 473                 mySize.x = vid_conwidth - myPos.x;
 474         if(myPos.y + mySize.y > vid_conheight)
 475                 mySize.y = vid_conheight - myPos.y;
 476
 477         //if(cvar("hud_configure_checkcollisions_debug"))
 478                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 479
 480         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 481         if(autocvar_hud_configure_grid)
 482         {
 483                 mySize.x = floor((mySize.x/vid_conwidth)/hud_configure_gridSize.x + 0.5) * hud_configure_realGridSize.x;
 484                 mySize.y = floor((mySize.y/vid_conheight)/hud_configure_gridSize.y + 0.5) * hud_configure_realGridSize.y;
 485         }
 486
 487         if(hud_configure_checkcollisions)
 488                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 489
 490         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 491         mySize.x = max(0.025 * vid_conwidth, mySize.x);
 492         mySize.y = max(0.025 * vid_conheight, mySize.y);
 493
 494         // do another pos check, as size might have changed by now
 495         if(resizeCorner == 1) {
 496                 myPos.x = resizeorigin.x - mySize.x;
 497                 myPos.y = resizeorigin.y - mySize.y;
 498         } else if(resizeCorner == 2) {
 499                 myPos.x = resizeorigin.x;
 500                 myPos.y = resizeorigin.y - mySize.y;
 501         } else if(resizeCorner == 3) {
 502                 myPos.x = resizeorigin.x - mySize.x;
 503                 myPos.y = resizeorigin.y;
 504         } else { // resizeCorner == 4
 505                 myPos.x = resizeorigin.x;
 506                 myPos.y = resizeorigin.y;
 507         }
 508
 509         //if(cvar("hud_configure_checkcollisions_debug"))
 510                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 511
 512         string s;
 513         s = strcat(ftos(mySize.x/vid_conwidth), " ", ftos(mySize.y/vid_conheight));
 514         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 515
 516         s = strcat(ftos(myPos.x/vid_conwidth), " ", ftos(myPos.y/vid_conheight));
 517         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 518 }
 519
 520 float pressed_key_time;
 521 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 522 void HUD_Panel_Arrow_Action(float nPrimary)
 523 {
 524         if(!highlightedPanel)
 525                 return;
 526
 527         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 528
 529         float step;
 530         if(autocvar_hud_configure_grid)
 531         {
 532                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 533                 {
 534                         if (hudShiftState & S_SHIFT)
 535                                 step = hud_configure_realGridSize.y;
 536                         else
 537                                 step = 2 * hud_configure_realGridSize.y;
 538                 }
 539                 else
 540                 {
 541                         if (hudShiftState & S_SHIFT)
 542                                 step = hud_configure_realGridSize.x;
 543                         else
 544                                 step = 2 * hud_configure_realGridSize.x;
 545                 }
 546         }
 547         else
 548         {
 549                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 550                         step = vid_conheight;
 551                 else
 552                         step = vid_conwidth;
 553                 if (hudShiftState & S_SHIFT)
 554                         step = (step / 256); // more precision
 555                 else
 556                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 557         }
 558
 559         panel = highlightedPanel;
 560         HUD_Panel_UpdatePosSize();
 561
 562         highlightedPanel_initial_pos = panel_pos;
 563         highlightedPanel_initial_size = panel_size;
 564
 565         if (hudShiftState & S_ALT) // resize
 566         {
 567                 if(nPrimary == K_UPARROW)
 568                         resizeCorner = 1;
 569                 else if(nPrimary == K_RIGHTARROW)
 570                         resizeCorner = 2;
 571                 else if(nPrimary == K_LEFTARROW)
 572                         resizeCorner = 3;
 573                 else // if(nPrimary == K_DOWNARROW)
 574                         resizeCorner = 4;
 575
 576                 // ctrl+arrow reduces the size, instead of increasing it
 577                 // Note that ctrl disables collisions check too, but it's fine
 578                 // since we don't collide with anything reducing the size
 579                 if (hudShiftState & S_CTRL) {
 580                         step = -step;
 581                         resizeCorner = 5 - resizeCorner;
 582                 }
 583
 584                 vector mySize;
 585                 mySize = panel_size;
 586                 panel_click_resizeorigin = panel_pos;
 587                 if(resizeCorner == 1) {
 588                         panel_click_resizeorigin += mySize;
 589                         mySize.y += step;
 590                 } else if(resizeCorner == 2) {
 591                         panel_click_resizeorigin.y += mySize.y;
 592                         mySize.x += step;
 593                 } else if(resizeCorner == 3) {
 594                         panel_click_resizeorigin.x += mySize.x;
 595                         mySize.x += step;
 596                 } else { // resizeCorner == 4
 597                         mySize.y += step;
 598                 }
 599                 HUD_Panel_SetPosSize(mySize);
 600         }
 601         else // move
 602         {
 603                 vector pos;
 604                 pos = panel_pos;
 605                 if(nPrimary == K_UPARROW)
 606                         pos.y -= step;
 607                 else if(nPrimary == K_DOWNARROW)
 608                         pos.y += step;
 609                 else if(nPrimary == K_LEFTARROW)
 610                         pos.x -= step;
 611                 else // if(nPrimary == K_RIGHTARROW)
 612                         pos.x += step;
 613
 614                 HUD_Panel_SetPos(pos);
 615         }
 616
 617         panel = highlightedPanel;
 618         HUD_Panel_UpdatePosSize();
 619
 620         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 621         {
 622                 // backup!
 623                 panel_pos_backup = highlightedPanel_initial_pos;
 624                 panel_size_backup = highlightedPanel_initial_size;
 625                 highlightedPanel_backup = highlightedPanel;
 626         }
 627 }
 628
 629 void HUD_Panel_EnableMenu();
 630 entity tab_panels[HUD_PANEL_MAX];
 631 entity tab_panel;
 632 vector tab_panel_pos;
 633 float tab_backward;
 634 void HUD_Panel_FirstInDrawQ(float id);
 635 void reset_tab_panels()
 636 {
 637         int i;
 638         for(i = 0; i < HUD_PANEL_NUM; ++i)
 639                 tab_panels[i] = world;
 640 }
 641 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 642 {
 643         string s;
 644
 645         if(bInputType == 2)
 646                 return false;
 647
 648         if(!autocvar__hud_configure)
 649                 return false;
 650
 651         if(bInputType == 3)
 652         {
 653                 mousepos.x = nPrimary;
 654                 mousepos.y = nSecondary;
 655                 return true;
 656         }
 657
 658         // block any input while a menu dialog is fading
 659         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 660         if(autocvar__menu_alpha)
 661         {
 662                 hudShiftState = 0;
 663                 mouseClicked = 0;
 664                 return true;
 665         }
 666
 667         // allow console bind to work
 668         string con_keys;
 669         float keys;
 670         con_keys = findkeysforcommand("toggleconsole", 0);
 671         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 672
 673         bool hit_con_bind = false;
 674         int i;
 675         for (i = 0; i < keys; ++i)
 676         {
 677                 if(nPrimary == stof(argv(i)))
 678                         hit_con_bind = true;
 679         }
 680
 681         if(bInputType == 0) {
 682                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 683                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 684                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 685         }
 686         else if(bInputType == 1) {
 687                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 688                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 689                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 690         }
 691
 692         if(nPrimary == K_CTRL)
 693         {
 694                 if (bInputType == 1) //ctrl has been released
 695                 {
 696                         if (tab_panel)
 697                         {
 698                                 //switch to selected panel
 699                                 highlightedPanel = tab_panel;
 700                                 highlightedAction = 0;
 701                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 702                         }
 703                         tab_panel = world;
 704                         reset_tab_panels();
 705                 }
 706         }
 707
 708         if(nPrimary == K_MOUSE1)
 709         {
 710                 if(bInputType == 0) // key pressed
 711                         mouseClicked |= S_MOUSE1;
 712                 else if(bInputType == 1) // key released
 713                         mouseClicked -= (mouseClicked & S_MOUSE1);
 714         }
 715         else if(nPrimary == K_MOUSE2)
 716         {
 717                 if(bInputType == 0) // key pressed
 718                         mouseClicked |= S_MOUSE2;
 719                 else if(bInputType == 1) // key released
 720                         mouseClicked -= (mouseClicked & S_MOUSE2);
 721         }
 722         else if(nPrimary == K_ESCAPE)
 723         {
 724                 if (bInputType == 1)
 725                         return true;
 726                 menu_enabled = 1;
 727                 localcmd("menu_showhudexit\n");
 728         }
 729         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 730         {
 731                 if (bInputType == 1)
 732                         return true;
 733                 if (!menu_enabled)
 734                         cvar_set("_hud_configure", "0");
 735         }
 736         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // switch panel
 737         {
 738                 if (bInputType == 1 || mouseClicked)
 739                         return true;
 740
 741                 // FIXME minor bug: if a panel is highlighted, has the same pos_x and
 742                 // lays in the same level of another panel then the next consecutive
 743                 // CTRL TAB presses will reselect once more the highlighted panel
 744
 745                 entity starting_panel;
 746                 entity old_tab_panel = tab_panel;
 747                 if (!tab_panel) //first press of TAB
 748                 {
 749                         if (highlightedPanel)
 750                         {
 751                                 panel = highlightedPanel;
 752                                 HUD_Panel_UpdatePosSize();
 753                         }
 754                         else
 755                                 panel_pos = '0 0 0';
 756                         starting_panel = highlightedPanel;
 757                         tab_panel_pos = panel_pos; //to compute level
 758                 }
 759                 else
 760                 {
 761                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 762                                 reset_tab_panels();
 763                         starting_panel = tab_panel;
 764                 }
 765                 tab_backward = (hudShiftState & S_SHIFT);
 766
 767                 float k, level = 0, start_posX;
 768                 vector candidate_pos = '0 0 0';
 769                 const float LEVELS_NUM = 4;
 770                 float level_height = vid_conheight / LEVELS_NUM;
 771 :find_tab_panel
 772                 level = floor(tab_panel_pos.y / level_height) * level_height; //starting level
 773                 candidate_pos.x = (!tab_backward) ? vid_conwidth : 0;
 774                 start_posX = tab_panel_pos.x;
 775                 tab_panel = world;
 776                 k=0;
 777                 while(++k)
 778                 {
 779                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 780                         {
 781                                 panel = hud_panel[i];
 782                                 if (panel == tab_panels[i] || panel == starting_panel)
 783                                         continue;
 784                                 HUD_Panel_UpdatePosSize();
 785                                 if (panel_pos.y >= level && (panel_pos.y - level) < level_height)
 786                                 if (  ( !tab_backward && panel_pos.x >= start_posX && (panel_pos.x < candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y <= candidate_pos.y)) )
 787                                         || ( tab_backward && panel_pos.x <= start_posX && (panel_pos.x > candidate_pos.x || (panel_pos.x == candidate_pos.x && panel_pos.y >= candidate_pos.y)) )  )
 788                                 {
 789                                         tab_panel = panel;
 790                                         tab_panel_pos = candidate_pos = panel_pos;
 791                                 }
 792                         }
 793                         if (tab_panel)
 794                                 break;
 795                         if (k == LEVELS_NUM) //tab_panel not found
 796                         {
 797                                 reset_tab_panels();
 798                                 if (!old_tab_panel)
 799                                 {
 800                                         tab_panel = world;
 801                                         return true;
 802                                 }
 803                                 starting_panel = old_tab_panel;
 804                                 old_tab_panel = world;
 805                                 goto find_tab_panel; //u must find tab_panel!
 806                         }
 807                         if (!tab_backward)
 808                         {
 809                                 level = (level + level_height) % vid_conheight;
 810                                 start_posX = 0;
 811                                 candidate_pos.x = vid_conwidth;
 812                         }
 813                         else
 814                         {
 815                                 level = (level - level_height) % vid_conheight;
 816                                 start_posX = vid_conwidth;
 817                                 candidate_pos.x = 0;
 818                         }
 819                 }
 820
 821                 tab_panels[tab_panel.panel_id] = tab_panel;
 822         }
 823         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 824         {
 825                 if (bInputType == 1 || mouseClicked)
 826                         return true;
 827
 828                 if (highlightedPanel)
 829                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 830                 else
 831                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 832         }
 833         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 834         {
 835                 if (bInputType == 1 || mouseClicked)
 836                         return true;
 837
 838                 if (highlightedPanel)
 839                 {
 840                         panel = highlightedPanel;
 841                         HUD_Panel_UpdatePosSize();
 842                         panel_size_copied = panel_size;
 843                 }
 844         }
 845         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 846         {
 847                 if (bInputType == 1 || mouseClicked)
 848                         return true;
 849
 850                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 851                         return true;
 852
 853                 panel = highlightedPanel;
 854                 HUD_Panel_UpdatePosSize();
 855
 856                 // reduce size if it'd go beyond screen boundaries
 857                 vector tmp_size = panel_size_copied;
 858                 if (panel_pos.x + panel_size_copied.x > vid_conwidth)
 859                         tmp_size.x = vid_conwidth - panel_pos.x;
 860                 if (panel_pos.y + panel_size_copied.y > vid_conheight)
 861                         tmp_size.y = vid_conheight - panel_pos.y;
 862
 863                 if (panel_size == tmp_size)
 864                         return true;
 865
 866                 // backup first!
 867                 panel_pos_backup = panel_pos;
 868                 panel_size_backup = panel_size;
 869                 highlightedPanel_backup = highlightedPanel;
 870
 871                 s = strcat(ftos(tmp_size.x/vid_conwidth), " ", ftos(tmp_size.y/vid_conheight));
 872                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 873         }
 874         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 875         {
 876                 if (bInputType == 1 || mouseClicked)
 877                         return true;
 878                 //restore previous values
 879                 if (highlightedPanel_backup)
 880                 {
 881                         s = strcat(ftos(panel_pos_backup.x/vid_conwidth), " ", ftos(panel_pos_backup.y/vid_conheight));
 882                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 883                         s = strcat(ftos(panel_size_backup.x/vid_conwidth), " ", ftos(panel_size_backup.y/vid_conheight));
 884                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 885                         highlightedPanel_backup = world;
 886                 }
 887         }
 888         else if(nPrimary == 's' && hudShiftState & S_CTRL) // save config
 889         {
 890                 if (bInputType == 1 || mouseClicked)
 891                         return true;
 892                 localcmd("hud save myconfig\n");
 893         }
 894         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 895         {
 896                 if (bInputType == 1)
 897                 {
 898                         pressed_key_time = 0;
 899                         return true;
 900                 }
 901                 else if (pressed_key_time == 0)
 902                         pressed_key_time = time;
 903
 904                 if (!mouseClicked)
 905                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 906         }
 907         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 908         {
 909                 if (bInputType == 1)
 910                         return true;
 911                 if (highlightedPanel)
 912                         HUD_Panel_EnableMenu();
 913         }
 914         else if(hit_con_bind || nPrimary == K_PAUSE)
 915                 return false;
 916
 917         return true;
 918 }
 919
 920 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 921 {
 922         int i, j = 0;
 923         while(j < HUD_PANEL_NUM)
 924         {
 925                 i = panel_order[j];
 926                 j += 1;
 927
 928                 panel = hud_panel[i];
 929                 HUD_Panel_UpdatePosSize();
 930
 931                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 932
 933                 // move
 934                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
 935                 {
 936                         return 1;
 937                 }
 938                 // resize from topleft border
 939                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 940                 {
 941                         return 2;
 942                 }
 943                 // resize from topright border
 944                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
 945                 {
 946                         return 3;
 947                 }
 948                 // resize from bottomleft border
 949                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
 950                 {
 951                         return 3;
 952                 }
 953                 // resize from bottomright border
 954                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
 955                 {
 956                         return 2;
 957                 }
 958         }
 959         return 0;
 960 }
 961
 962 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 963 void HUD_Panel_FirstInDrawQ(float id)
 964 {
 965         int i;
 966         int place = -1;
 967         // find out where in the array our current id is, save into place
 968         for(i = 0; i < HUD_PANEL_NUM; ++i)
 969         {
 970                 if(panel_order[i] == id)
 971                 {
 972                         place = i;
 973                         break;
 974                 }
 975         }
 976         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 977         if(place == -1)
 978                 place = HUD_PANEL_NUM - 1;
 979
 980         // move all ids up by one step in the array until "place"
 981         for(i = place; i > 0; --i)
 982         {
 983                 panel_order[i] = panel_order[i-1];
 984         }
 985         // now save the new top id
 986         panel_order[0] = id;
 987
 988         // let's save them into the cvar by some strcat trickery
 989         string s = "";
 990         for(i = 0; i < HUD_PANEL_NUM; ++i)
 991         {
 992                 s = strcat(s, ftos(panel_order[i]), " ");
 993         }
 994         cvar_set("_hud_panelorder", s);
 995         if(hud_panelorder_prev)
 996                 strunzone(hud_panelorder_prev);
 997         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 998 }
 999
1000 void HUD_Panel_Highlight(float allow_move)
1001 {
1002         int i, j = 0;
1003
1004         while(j < HUD_PANEL_NUM)
1005         {
1006                 i = panel_order[j];
1007                 j += 1;
1008
1009                 panel = hud_panel[i];
1010                 HUD_Panel_UpdatePosSize();
1011
1012                 float border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1013
1014                 // move
1015                 if(allow_move && mousepos.x > panel_pos.x && mousepos.y > panel_pos.y && mousepos.x < panel_pos.x + panel_size.x && mousepos.y < panel_pos.y + panel_size.y)
1016                 {
1017                         highlightedPanel = hud_panel[i];
1018                         HUD_Panel_FirstInDrawQ(i);
1019                         highlightedAction = 1;
1020                         panel_click_distance = mousepos - panel_pos;
1021                         return;
1022                 }
1023                 // resize from topleft border
1024                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1025                 {
1026                         highlightedPanel = hud_panel[i];
1027                         HUD_Panel_FirstInDrawQ(i);
1028                         highlightedAction = 2;
1029                         resizeCorner = 1;
1030                         panel_click_distance = mousepos - panel_pos;
1031                         panel_click_resizeorigin = panel_pos + panel_size;
1032                         return;
1033                 }
1034                 // resize from topright border
1035                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y - border && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + 0.5 * panel_size.y)
1036                 {
1037                         highlightedPanel = hud_panel[i];
1038                         HUD_Panel_FirstInDrawQ(i);
1039                         highlightedAction = 2;
1040                         resizeCorner = 2;
1041                         panel_click_distance.x = panel_size.x - mousepos.x + panel_pos.x;
1042                         panel_click_distance.y = mousepos.y - panel_pos.y;
1043                         panel_click_resizeorigin = panel_pos + eY * panel_size.y;
1044                         return;
1045                 }
1046                 // resize from bottomleft border
1047                 else if(mousepos.x >= panel_pos.x - border && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + 0.5 * panel_size.x && mousepos.y <= panel_pos.y + panel_size.y + border)
1048                 {
1049                         highlightedPanel = hud_panel[i];
1050                         HUD_Panel_FirstInDrawQ(i);
1051                         highlightedAction = 2;
1052                         resizeCorner = 3;
1053                         panel_click_distance.x = mousepos.x - panel_pos.x;
1054                         panel_click_distance.y = panel_size.y - mousepos.y + panel_pos.y;
1055                         panel_click_resizeorigin = panel_pos + eX * panel_size.x;
1056                         return;
1057                 }
1058                 // resize from bottomright border
1059                 else if(mousepos.x >= panel_pos.x + 0.5 * panel_size.x && mousepos.y >= panel_pos.y + 0.5 * panel_size.y && mousepos.x <= panel_pos.x + panel_size.x + border && mousepos.y <= panel_pos.y + panel_size.y + border)
1060                 {
1061                         highlightedPanel = hud_panel[i];
1062                         HUD_Panel_FirstInDrawQ(i);
1063                         highlightedAction = 2;
1064                         resizeCorner = 4;
1065                         panel_click_distance = panel_size - mousepos + panel_pos;
1066                         panel_click_resizeorigin = panel_pos;
1067                         return;
1068                 }
1069         }
1070         highlightedPanel = world;
1071         highlightedAction = 0;
1072 }
1073
1074 void HUD_Panel_EnableMenu()
1075 {
1076         menu_enabled = 2;
1077         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1078 }
1079 float mouse_over_panel;
1080 void HUD_Panel_Mouse()
1081 {
1082         if(autocvar__menu_alpha == 1)
1083                 return;
1084
1085         if (!autocvar_hud_cursormode)
1086         {
1087                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1088
1089                 mousepos.x = bound(0, mousepos.x, vid_conwidth);
1090                 mousepos.y = bound(0, mousepos.y, vid_conheight);
1091         }
1092
1093         if(mouseClicked)
1094         {
1095                 if(prevMouseClicked == 0)
1096                 {
1097                         if (tab_panel)
1098                         {
1099                                 //stop ctrl-tab selection
1100                                 tab_panel = world;
1101                                 reset_tab_panels();
1102                         }
1103                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1104                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1105                         if (highlightedPanel)
1106                         {
1107                                 highlightedPanel_initial_pos = panel_pos;
1108                                 highlightedPanel_initial_size = panel_size;
1109                         }
1110                         // doubleclick check
1111                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1112                         {
1113                                 mouseClicked = 0; // to prevent spam, I guess.
1114                                 HUD_Panel_EnableMenu();
1115                         }
1116                         else
1117                         {
1118                                 if (mouseClicked & S_MOUSE1)
1119                                 {
1120                                         prevMouseClickedTime = time;
1121                                         prevMouseClickedPos = mousepos;
1122                                 }
1123                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1124                         }
1125                 }
1126                 else
1127                 {
1128                         panel = highlightedPanel;
1129                         HUD_Panel_UpdatePosSize();
1130                 }
1131
1132                 if (highlightedPanel)
1133                 {
1134                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1135                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1136                         {
1137                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1138                                 // backup!
1139                                 panel_pos_backup = highlightedPanel_initial_pos;
1140                                 panel_size_backup = highlightedPanel_initial_size;
1141                                 highlightedPanel_backup = highlightedPanel;
1142                         }
1143                         else
1144                                 // in case the clicked panel is inside another panel and we aren't
1145                                 // moving it, avoid the immediate "fix" of its position/size
1146                                 // (often unwanted and hateful) by disabling collisions check
1147                                 hud_configure_checkcollisions = false;
1148                 }
1149
1150                 if(highlightedAction == 1)
1151                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1152                 else if(highlightedAction == 2)
1153                 {
1154                         vector mySize = '0 0 0';
1155                         if(resizeCorner == 1) {
1156                                 mySize.x = panel_click_resizeorigin.x - (mousepos.x - panel_click_distance.x);
1157                                 mySize.y = panel_click_resizeorigin.y - (mousepos.y - panel_click_distance.y);
1158                         } else if(resizeCorner == 2) {
1159                                 mySize.x = mousepos.x + panel_click_distance.x - panel_click_resizeorigin.x;
1160                                 mySize.y = panel_click_distance.y + panel_click_resizeorigin.y - mousepos.y;
1161                         } else if(resizeCorner == 3) {
1162                                 mySize.x = panel_click_resizeorigin.x + panel_click_distance.x - mousepos.x;
1163                                 mySize.y = mousepos.y + panel_click_distance.y - panel_click_resizeorigin.y;
1164                         } else { // resizeCorner == 4
1165                                 mySize.x = mousepos.x - (panel_click_resizeorigin.x - panel_click_distance.x);
1166                                 mySize.y = mousepos.y - (panel_click_resizeorigin.y - panel_click_distance.y);
1167                         }
1168                         HUD_Panel_SetPosSize(mySize);
1169                 }
1170         }
1171         else
1172         {
1173                 if(prevMouseClicked)
1174                         highlightedAction = 0;
1175                 if(menu_enabled == 2)
1176                         mouse_over_panel = 0;
1177                 else
1178                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(true);
1179                 if (mouse_over_panel && !tab_panel)
1180                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1181         }
1182         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1183         const vector cursorsize = '32 32 0';
1184         float cursor_alpha = 1 - autocvar__menu_alpha;
1185
1186         if(!mouse_over_panel)
1187                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1188         else if(mouse_over_panel == 1)
1189                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1190         else if(mouse_over_panel == 2)
1191                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1192         else
1193                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1194
1195         prevMouseClicked = mouseClicked;
1196 }
1197 void HUD_Configure_DrawGrid()
1198 {
1199         float i;
1200         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1201         {
1202                 hud_configure_gridSize.x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1203                 hud_configure_gridSize.y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1204                 hud_configure_realGridSize.x = hud_configure_gridSize.x * vid_conwidth;
1205                 hud_configure_realGridSize.y = hud_configure_gridSize.y * vid_conheight;
1206                 vector s;
1207                 // x-axis
1208                 s = eX + eY * vid_conheight;
1209                 for(i = 1; i < 1/hud_configure_gridSize.x; ++i)
1210                         drawfill(eX * i * hud_configure_realGridSize.x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1211                 // y-axis
1212                 s = eY + eX * vid_conwidth;
1213                 for(i = 1; i < 1/hud_configure_gridSize.y; ++i)
1214                         drawfill(eY * i * hud_configure_realGridSize.y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1215         }
1216 }
1217
1218 float _menu_alpha_prev;
1219 void HUD_Configure_Frame()
1220 {
1221         int i;
1222         if(autocvar__hud_configure)
1223         {
1224                 if(isdemo() || intermission == 2)
1225                 {
1226                         HUD_Configure_Exit_Force();
1227                         return;
1228                 }
1229
1230                 if(!hud_configure_prev)
1231                 {
1232                         if(autocvar_hud_cursormode)
1233                                 setcursormode(1);
1234                         hudShiftState = 0;
1235                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1236                                 hud_panel[panel_order[i]].update_time = time;
1237                 }
1238
1239                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1240                 if(autocvar__menu_alpha != _menu_alpha_prev)
1241                 {
1242                         if(autocvar__menu_alpha == 0)
1243                                 menu_enabled = 0;
1244                         _menu_alpha_prev = autocvar__menu_alpha;
1245                 }
1246
1247                 HUD_Configure_DrawGrid();
1248         }
1249         else if(hud_configure_prev)
1250         {
1251                 if(menu_enabled)
1252                         menu_enabled = 0;
1253                 if(autocvar_hud_cursormode)
1254                         setcursormode(0);
1255         }
1256 }
1257
1258 const float hlBorderSize = 2;
1259 const string hlBorder = "gfx/hud/default/border_highlighted";
1260 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1261 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1262 {
1263         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1264         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1265         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size.y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size.x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1266         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1267         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size.x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size.y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1268 }
1269
1270 void HUD_Configure_PostDraw()
1271 {
1272         if(autocvar__hud_configure)
1273         {
1274                 if(tab_panel)
1275                 {
1276                         panel = tab_panel;
1277                         HUD_Panel_UpdatePosSize();
1278                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1279                 }
1280                 if(highlightedPanel)
1281                 {
1282                         panel = highlightedPanel;
1283                         HUD_Panel_UpdatePosSize();
1284                         HUD_Panel_HlBorder(panel_bg_border * hlBorderSize, '0 0.5 1', 0.4 * (1 - autocvar__menu_alpha));
1285                 }
1286         }
1287 }