qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         gametype = NULL;
 104
 105         postinit = false;
 106
 107         calledhooks = 0;
 108
 109         teams = Sort_Spawn();
 110         players = Sort_Spawn();
 111
 112         GetTeam(NUM_SPECTATOR, true); // add specs first
 113
 114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 115                 weapon_accuracy[w] = -1;
 116
 117         // precaches
 118
 119         if(autocvar_cl_reticle)
 120         {
 121                 precache_pic("gfx/reticle_normal");
 122                 // weapon reticles are precached in weapon files
 123         }
 124
 125         {
 126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 128                 shortmapname = mi_shortname;
 129
 130                 if (precache_pic(minimapname) == "")
 131                 {
 132                         // but maybe we have a non-clever minimap
 133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 134                         if (precache_pic(minimapname) == "")
 135                                 minimapname = ""; // FAIL
 136                         else
 137                                 get_mi_min_max_texcoords(0); // load new texcoords
 138                 }
 139
 140                 mi_center = (mi_min + mi_max) * 0.5;
 141                 mi_scale = mi_max - mi_min;
 142                 minimapname = strzone(minimapname);
 143         }
 144
 145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 146         LoadMenuSkinValues();
 147 }
 148
 149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 150 void Shutdown()
 151 {
 152         WarpZone_Shutdown();
 153
 154         delete(teams);
 155         delete(players);
 156         db_close(binddb);
 157         db_close(tempdb);
 158         if(autocvar_cl_db_saveasdump)
 159                 db_dump(ClientProgsDB, "client.db");
 160         else
 161                 db_save(ClientProgsDB, "client.db");
 162         db_close(ClientProgsDB);
 163
 164         if(camera_active)
 165                 cvar_set("chase_active",ftos(chase_active_backup));
 166
 167         // unset the event chasecam's chase_active
 168         if(autocvar_chase_active < 0)
 169                 cvar_set("chase_active", "0");
 170
 171         if (autocvar_r_drawviewmodel < 0)
 172                 cvar_set("r_drawviewmodel", "0");
 173
 174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 175
 176         if (!isdemo())
 177         {
 178                 if (!(calledhooks & HOOK_START))
 179                         localcmd("\n_cl_hook_gamestart nop\n");
 180                 if (!(calledhooks & HOOK_END))
 181                         localcmd("\ncl_hook_gameend\n");
 182         }
 183
 184         localcmd("\ncl_hook_shutdown\n");
 185
 186         localcmd("\n-button12\n");
 187
 188         deactivate_minigame();
 189         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 190
 191         ReplicateVars(REPLICATEVARS_DESTROY);
 192 }
 193
 194 void AuditLists()
 195 {
 196         entity e;
 197         entity prev;
 198
 199         prev = players;
 200         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 201         {
 202                 if(prev != e.sort_prev)
 203                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 204         }
 205
 206         prev = teams;
 207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 208         {
 209                 if(prev != e.sort_prev)
 210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 211         }
 212 }
 213
 214 float RegisterPlayer(entity player)
 215 {
 216         entity pl;
 217         AuditLists();
 218         for(pl = players.sort_next; pl; pl = pl.sort_next)
 219                 if(pl == player)
 220                         error("Player already registered!");
 221         player.sort_next = players.sort_next;
 222         player.sort_prev = players;
 223         if(players.sort_next)
 224                 players.sort_next.sort_prev = player;
 225         players.sort_next = player;
 226         AuditLists();
 227         return true;
 228 }
 229
 230 void RemovePlayer(entity player)
 231 {
 232         entity pl, parent;
 233         AuditLists();
 234         parent = players;
 235         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 236                 parent = pl;
 237
 238         if(!pl)
 239         {
 240                 error("Trying to remove a player which is not in the playerlist!");
 241                 return;
 242         }
 243         parent.sort_next = player.sort_next;
 244         if(player.sort_next)
 245                 player.sort_next.sort_prev = parent;
 246         AuditLists();
 247 }
 248
 249 void MoveToLast(entity e)
 250 {
 251         AuditLists();
 252         entity ent = e.sort_next;
 253         while(ent)
 254         {
 255                 SORT_SWAP(ent, e);
 256                 ent = e.sort_next;
 257         }
 258         AuditLists();
 259 }
 260
 261 float RegisterTeam(entity Team)
 262 {
 263         assert_once(Team.team, eprint(Team));
 264         entity tm;
 265         AuditLists();
 266         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 267                 if(tm == Team)
 268                         error("Team already registered!");
 269         Team.sort_next = teams.sort_next;
 270         Team.sort_prev = teams;
 271         if(teams.sort_next)
 272                 teams.sort_next.sort_prev = Team;
 273         teams.sort_next = Team;
 274         if(Team.team && Team.team != NUM_SPECTATOR)
 275                 ++team_count;
 276         AuditLists();
 277         return true;
 278 }
 279
 280 void RemoveTeam(entity Team)
 281 {
 282         entity tm, parent;
 283         AuditLists();
 284         parent = teams;
 285         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 286                 parent = tm;
 287
 288         if(!tm)
 289         {
 290                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 291                 return;
 292         }
 293         parent.sort_next = Team.sort_next;
 294         if(Team.sort_next)
 295                 Team.sort_next.sort_prev = parent;
 296         if(Team.team && Team.team != NUM_SPECTATOR)
 297                 --team_count;
 298         AuditLists();
 299 }
 300
 301 entity GetTeam(int Team, bool add)
 302 {
 303         TC(int, Team); TC(bool, add);
 304         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 305         if(teamslots[num])
 306                 return teamslots[num];
 307         if (!add)
 308                 return NULL;
 309         entity tm = new_pure(team);
 310         tm.team = Team;
 311         teamslots[num] = tm;
 312         RegisterTeam(tm);
 313         return tm;
 314 }
 315
 316 .float has_team;
 317 bool SetTeam(entity o, int Team)
 318 {
 319         TC(int, Team);
 320         //devassert_once(Team);
 321         entity tm;
 322         if(teamplay)
 323         {
 324                 switch(Team)
 325                 {
 326                         case -1:
 327                         case NUM_TEAM_1:
 328                         case NUM_TEAM_2:
 329                         case NUM_TEAM_3:
 330                         case NUM_TEAM_4:
 331                                 break;
 332                         default:
 333                                 if(GetTeam(Team, false) == NULL)
 334                                 {
 335                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 336                                         Team = NUM_SPECTATOR;
 337                                 }
 338                                 break;
 339                 }
 340         }
 341         else
 342         {
 343                 switch(Team)
 344                 {
 345                         case -1:
 346                         case 0:
 347                                 break;
 348                         default:
 349                                 if(GetTeam(Team, false) == NULL)
 350                                 {
 351                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 352                                         Team = NUM_SPECTATOR;
 353                                 }
 354                                 break;
 355                 }
 356         }
 357         if(Team == -1) // leave
 358         {
 359                 if(o.has_team)
 360                 {
 361                         tm = GetTeam(o.team, false);
 362                         tm.team_size -= 1;
 363                         o.has_team = 0;
 364                         return true;
 365                 }
 366         }
 367         else
 368         {
 369                 if (!o.has_team)
 370                 {
 371                         o.team = Team;
 372                         tm = GetTeam(Team, true);
 373                         tm.team_size += 1;
 374                         o.has_team = 1;
 375                         return true;
 376                 }
 377                 else if(Team != o.team)
 378                 {
 379                         tm = GetTeam(o.team, false);
 380                         tm.team_size -= 1;
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         return true;
 385                 }
 386         }
 387         return false;
 388 }
 389
 390 void Playerchecker_Think(entity this)
 391 {
 392         int i;
 393         entity e;
 394         for(i = 0; i < maxclients; ++i)
 395         {
 396                 e = playerslots[i];
 397                 if(entcs_GetName(i) == "")
 398                 {
 399                         if(e.sort_prev)
 400                         {
 401                                 // player disconnected
 402                                 SetTeam(e, -1);
 403                                 RemovePlayer(e);
 404                                 e.sort_prev = NULL;
 405                                 //e.gotscores = 0;
 406                         }
 407                 }
 408                 else
 409                 {
 410                         if (!e.sort_prev)
 411                         {
 412                                 // player connected
 413                                 if (!e)
 414                                 {
 415                                         playerslots[i] = e = new_pure(playerslot);
 416                                 }
 417                                 e.sv_entnum = i;
 418                                 e.ping = 0;
 419                                 e.ping_packetloss = 0;
 420                                 e.ping_movementloss = 0;
 421                                 //e.gotscores = 0; // we might already have the scores...
 422                                 int t = entcs_GetScoreTeam(i);
 423                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 424                                 RegisterPlayer(e);
 425                                 Scoreboard_UpdatePlayerPos(e);
 426                         }
 427                 }
 428         }
 429         this.nextthink = time + 0.2;
 430 }
 431
 432 void PostInit()
 433 {
 434         entity playerchecker = new_pure(playerchecker);
 435         setthink(playerchecker, Playerchecker_Think);
 436         playerchecker.nextthink = time + 0.2;
 437
 438         TrueAim_Init();
 439
 440         // this can't be called in CSQC_Init as it'd send cvars too early
 441         ReplicateVars_Start();
 442
 443         postinit = true;
 444 }
 445
 446 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 447 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 448 // All keys are in ascii.
 449 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 450 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 451 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 452 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 453 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 454 {
 455         TC(int, bInputType);
 456         bool override = false;
 457
 458         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
 459         if (override)
 460                 return true;
 461
 462         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 463         if (override)
 464                 return true;
 465
 466         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 467
 468         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 469
 470         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 471
 472         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 473
 474         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 475
 476         if(override)
 477                 return true;
 478
 479         if(bInputType == 3 || bInputType == 2)
 480                 return false;
 481
 482         // at this point bInputType can only be 0 or 1 (key pressed or released)
 483         bool key_pressed = (bInputType == 0);
 484
 485         if(key_pressed) {
 486                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 487                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 488                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 489                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
 490         }
 491         else {
 492                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 493                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 494                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 495                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
 496         }
 497
 498         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
 499         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 500         {
 501                 if (hudShiftState & S_TAB)
 502                 {
 503                         Scoreboard_UI_Enable(0);
 504                         return true;
 505                 }
 506                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 507                 {
 508                         localcmd("\nmenu_showgamemenudialog\n");
 509                         return true;
 510                 }
 511         }
 512
 513         return false;
 514 }
 515
 516 // END REQUIRED CSQC FUNCTIONS
 517 // --------------------------------------------------------------------------
 518
 519 // --------------------------------------------------------------------------
 520 // BEGIN OPTIONAL CSQC FUNCTIONS
 521
 522 void Ent_RemovePlayerScore(entity this)
 523 {
 524         if(this.owner) {
 525                 SetTeam(this.owner, -1);
 526                 this.owner.gotscores = 0;
 527                 FOREACH(Scores, true, {
 528                         this.owner.(scores(it)) = 0; // clear all scores
 529                 });
 530         }
 531 }
 532
 533 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 534 {
 535         make_pure(this);
 536         entity o;
 537
 538         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 539         // (no I've never heard of M-x replace-string, sed, or anything like that)
 540         bool isNew = !this.owner; // workaround for DP bug
 541         int n = ReadByte()-1;
 542
 543 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 544         if(!isNew && n != this.sv_entnum)
 545         {
 546                 //print("A CSQC entity changed its owner!\n");
 547                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 548                 isNew = true;
 549                 Ent_Remove(this);
 550         }
 551 #endif
 552
 553         this.sv_entnum = n;
 554
 555         o = playerslots[this.sv_entnum];
 556         if (!o)
 557         {
 558                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 559         }
 560         this.owner = o;
 561         o.sv_entnum = this.sv_entnum;
 562         o.gotscores = 1;
 563
 564         //if (!o.sort_prev)
 565         //      RegisterPlayer(o);
 566         //playerchecker will do this for us later, if it has not already done so
 567
 568         int sf = ReadShort();
 569         int lf = ReadShort();
 570         FOREACH(Scores, true, {
 571                 int p = 1 << (i % 16);
 572                 if (sf & p)
 573                 {
 574                         if (lf & p)
 575                                 o.(scores(it)) = ReadInt24_t();
 576                         else
 577                                 o.(scores(it)) = ReadChar();
 578                 }
 579         });
 580
 581         return = true;
 582
 583         if(o.sort_prev)
 584                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 585
 586         this.entremove = Ent_RemovePlayerScore;
 587 }
 588
 589 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 590 {
 591         make_pure(this);
 592         int i;
 593
 594         this.team = ReadByte();
 595         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 596
 597 #if MAX_TEAMSCORE <= 8
 598         int sf = ReadByte();
 599         int lf = ReadByte();
 600 #else
 601         int sf = ReadShort();
 602         int lf = ReadShort();
 603 #endif
 604         for(i = 0; i < MAX_TEAMSCORE; ++i)
 605                 if(sf & BIT(i))
 606                 {
 607                         if(lf & BIT(i))
 608                                 o.(teamscores(i)) = ReadInt24_t();
 609                         else
 610                                 o.(teamscores(i)) = ReadChar();
 611                 }
 612
 613         return = true;
 614
 615         Scoreboard_UpdateTeamPos(o);
 616 }
 617
 618 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 619 {
 620         make_pure(this);
 621         float newspectatee_status;
 622
 623         int f = ReadByte();
 624
 625         scoreboard_showscores_force = (f & BIT(0));
 626
 627         if(f & BIT(1))
 628         {
 629                 newspectatee_status = ReadByte();
 630                 if(newspectatee_status == player_localnum + 1)
 631                         newspectatee_status = -1; // observing
 632         }
 633         else
 634                 newspectatee_status = 0;
 635
 636         spectatorbutton_zoom = (f & BIT(2));
 637
 638         if(f & BIT(4))
 639         {
 640                 num_spectators = ReadByte();
 641
 642                 float i, slot;
 643
 644                 for(i = 0; i < MAX_SPECTATORS; ++i)
 645                         spectatorlist[i] = 0; // reset list first
 646
 647                 int limit = min(num_spectators, MAX_SPECTATORS);
 648                 for(i = 0; i < limit; ++i)
 649                 {
 650                         slot = ReadByte();
 651                         spectatorlist[i] = slot - 1;
 652                 }
 653         }
 654         else
 655         {
 656                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 657                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 658                 num_spectators = 0;
 659         }
 660
 661         return = true;
 662
 663         if(newspectatee_status != spectatee_status)
 664         {
 665                 // clear race stuff
 666                 race_laptime = 0;
 667                 race_checkpointtime = 0;
 668                 hud_dynamic_shake_factor = -1;
 669                 spectatee_status_changed_time = time;
 670         }
 671         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 672         {
 673                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 674                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 675                 )
 676                         prev_p_health = -1;
 677                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 678                         prev_health = -1;
 679         }
 680         spectatee_status = newspectatee_status;
 681
 682         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 683 }
 684
 685 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 686 {
 687         make_pure(this);
 688         int i, j, b, f;
 689
 690         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 691
 692         if(!(nags & BIT(2)))
 693         {
 694                 strfree(vote_called_vote);
 695                 vote_active = 0;
 696         }
 697         else
 698         {
 699                 vote_active = 1;
 700         }
 701
 702         if(nags & BIT(6))
 703         {
 704                 vote_yescount = ReadByte();
 705                 vote_nocount = ReadByte();
 706                 vote_needed = ReadByte();
 707                 vote_highlighted = ReadChar();
 708         }
 709
 710         if(nags & BIT(7))
 711         {
 712                 strcpy(vote_called_vote, ReadString());
 713         }
 714
 715         if(nags & 1)
 716         {
 717                 for(j = 0; j < maxclients; ++j)
 718                         if(playerslots[j])
 719                                 playerslots[j].ready = true;
 720                 for(i = 1; i <= maxclients; i += 8)
 721                 {
 722                         f = ReadByte();
 723                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 724                                 if (!(f & b))
 725                                         if(playerslots[j])
 726                                                 playerslots[j].ready = false;
 727                 }
 728         }
 729
 730         return = true;
 731
 732         ready_waiting = (nags & BIT(0));
 733         ready_waiting_for_me = (nags & BIT(1));
 734         vote_waiting = (nags & BIT(2));
 735         vote_waiting_for_me = (nags & BIT(3));
 736         warmup_stage = (nags & BIT(4));
 737 }
 738
 739 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 740 {
 741         make_pure(this);
 742         int sf = 0;
 743         serialize(byte, 0, sf);
 744         if (sf & 1) {
 745                 for (int j = 0; j < maxclients; ++j) {
 746                         if (playerslots[j]) {
 747                                 playerslots[j].eliminated = true;
 748                         }
 749                 }
 750                 for (int i = 1; i <= maxclients; i += 8) {
 751                         int f = 0;
 752                         serialize(byte, 0, f);
 753                         for (int b = 0; b < 8; ++b) {
 754                                 if (f & BIT(b)) continue;
 755                                 int j = i - 1 + b;
 756                                 if (playerslots[j]) {
 757                                         playerslots[j].eliminated = false;
 758                                 }
 759                         }
 760                 }
 761         }
 762         return true;
 763 }
 764
 765 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 766 {
 767         make_pure(this);
 768         prandom_debug();
 769         float s = ReadShort();
 770         psrandom(s);
 771         return true;
 772 }
 773
 774 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 775 {
 776         make_pure(this);
 777         int sf = ReadInt24_t();
 778         if (sf == 0) {
 779                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 780                         weapon_accuracy[w] = -1;
 781                 return true;
 782         }
 783
 784         int f = 1;
 785         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 786                 if (sf & f) {
 787                         int b = ReadByte();
 788                         if (b == 0)
 789                                 weapon_accuracy[w] = -1;
 790                         else if (b == 255)
 791                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 792                         else
 793                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 794                 }
 795                 f = (f == 0x800000) ? 1 : f * 2;
 796         }
 797         return true;
 798 }
 799
 800 void Spawn_Draw(entity this)
 801 {
 802         bool dodraw = autocvar_cl_spawn_point_particles;
 803         if(dodraw && autocvar_cl_spawn_point_dist_max)
 804         {
 805                 vector org = getpropertyvec(VF_ORIGIN);
 806                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 807         }
 808
 809         if(dodraw)
 810                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 811 }
 812
 813 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 814 {
 815         float teamnum = (ReadByte() - 1);
 816         vector spn_origin = ReadVector();
 817
 818         this.team = (teamnum + 1);
 819
 820         //if(is_new)
 821         //{
 822                 this.origin = spn_origin;
 823                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 824                 //droptofloor();
 825
 826                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 827                 {
 828                         this.mdl = "models/spawnpoint.md3";
 829                         this.colormod = Team_ColorRGB(teamnum);
 830                         precache_model(this.mdl);
 831                         setmodel(this, this.mdl);
 832                         this.drawmask = MASK_NORMAL;
 833                         //this.move_movetype = MOVETYPE_NOCLIP;
 834                         //this.draw = Spawn_Draw;
 835                         IL_PUSH(g_drawables, this);
 836                 }*/
 837                 this.draw = Spawn_Draw;
 838                 if (is_new) IL_PUSH(g_drawables, this);
 839         //}
 840
 841         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 842         return true;
 843 }
 844
 845 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 846 {
 847         // If entnum is 0, ONLY do the local spawn actions
 848         // this way the server can disable the sending of
 849         // spawn origin or such to clients if wanted.
 850         float entnum = ReadByte();
 851
 852         if(entnum)
 853         {
 854                 this.origin = ReadVector();
 855
 856                 if(is_new)
 857                 {
 858                         float teamnum = entcs_GetTeam(entnum - 1);
 859
 860                         if(autocvar_cl_spawn_event_particles)
 861                         {
 862                                 switch(teamnum)
 863                                 {
 864                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 865                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 866                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 867                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 868                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 869                                 }
 870                         }
 871                         if(autocvar_cl_spawn_event_sound)
 872                         {
 873                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 874                         }
 875                 }
 876         }
 877         return = true;
 878
 879         // local spawn actions
 880         if(is_new && (!entnum || (entnum == player_localentnum)))
 881         {
 882                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 883                 {
 884                         zoomin_effect = 1;
 885                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 886                 }
 887
 888                 if(autocvar_cl_unpress_zoom_on_spawn)
 889                 {
 890                         localcmd("-zoom\n");
 891                         button_zoom = false;
 892                 }
 893                 HUD_Radar_Hide_Maximized();
 894         }
 895         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 896 }
 897
 898 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 899 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 900 void CSQC_Ent_Update(entity this, bool isnew)
 901 {
 902         this.sourceLoc = __FILE__":"STR(__LINE__);
 903         int t = ReadByte();
 904
 905         // set up the "time" global for received entities to be correct for interpolation purposes
 906         float savetime = time;
 907         if(servertime)
 908         {
 909                 time = servertime;
 910         }
 911         else
 912         {
 913                 serverprevtime = time;
 914                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 915                 time = serverprevtime + serverdeltatime;
 916         }
 917
 918 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 919         if (this.enttype)
 920         {
 921                 if (t != this.enttype || isnew)
 922                 {
 923                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 924                         Ent_Remove(this);
 925                         ONREMOVE(this);
 926                         clearentity(this);
 927                         isnew = true;
 928                 }
 929         }
 930         else
 931         {
 932                 if (!isnew)
 933                 {
 934                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 935                         isnew = true;
 936                 }
 937         }
 938 #endif
 939         this.enttype = t;
 940         bool done = false;
 941         FOREACH(LinkedEntities, it.m_id == t, {
 942                 if (isnew) this.classname = it.netname;
 943                 if (autocvar_developer_csqcentities)
 944                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 945                 done = it.m_read(this, NULL, isnew);
 946                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 947                 break;
 948         });
 949         time = savetime;
 950         if (!done)
 951         {
 952                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 953         }
 954 }
 955
 956 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 957 // used when an entity changes its type. For an entity that someone interacts
 958 // with others, make sure it can no longer do so.
 959 void Ent_Remove(entity this)
 960 {
 961         if(this.entremove) this.entremove(this);
 962
 963         if(this.skeletonindex)
 964         {
 965                 skel_delete(this.skeletonindex);
 966                 this.skeletonindex = 0;
 967         }
 968
 969         if(this.snd_looping > 0)
 970         {
 971                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 972                 this.snd_looping = 0;
 973         }
 974
 975         this.enttype = 0;
 976         this.classname = "";
 977         this.draw = func_null;
 978         this.entremove = func_null;
 979         // TODO possibly set more stuff to defaults
 980 }
 981 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 982 void CSQC_Ent_Remove(entity this)
 983 {
 984         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 985         if (wasfreed(this))
 986         {
 987                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 988                 return;
 989         }
 990         if (this.enttype) Ent_Remove(this);
 991         delete(this);
 992 }
 993
 994 void Gamemode_Init()
 995 {
 996         if (!isdemo())
 997         {
 998                 if(!(calledhooks & HOOK_START))
 999                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1000                 calledhooks |= HOOK_START;
1001         }
1002 }
1003 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1004 void CSQC_Parse_StuffCmd(string strMessage)
1005 {
1006         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1007         localcmd(strMessage);
1008 }
1009 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1010 void CSQC_Parse_Print(string strMessage)
1011 {
1012         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1013         print(ColorTranslateRGB(strMessage));
1014 }
1015
1016 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1017 void CSQC_Parse_CenterPrint(string strMessage)
1018 {
1019         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1020         centerprint_AddStandard(strMessage);
1021 }
1022
1023 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1024 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1025 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1026 bool CSQC_Parse_TempEntity()
1027 {
1028         // Acquire TE ID
1029         int nTEID = ReadByte();
1030
1031         FOREACH(TempEntities, it.m_id == nTEID, {
1032                 if (autocvar_developer_csqcentities)
1033                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1034                 return it.m_read(NULL, NULL, true);
1035         });
1036
1037         if (autocvar_developer_csqcentities)
1038                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1039
1040         // No special logic for this temporary entity; return 0 so the engine can handle it
1041         return false;
1042 }
1043
1044 string forcefog;
1045 void Fog_Force()
1046 {
1047         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1048                 localcmd("\nr_drawfog 0\n");
1049         else if (forcefog != "")
1050                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1051 }
1052
1053 bool net_handle_ServerWelcome();
1054 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1055 {
1056         make_pure(this);
1057         gametype = ReadRegistered(Gametypes);
1058         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1059         HUD_ModIcons_SetFunc();
1060         FOREACH(Scores, true, {
1061                 strcpy(scores_label(it), ReadString());
1062                 scores_flags(it) = ReadByte();
1063         });
1064         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1065         {
1066                 strcpy(teamscores_label(i), ReadString());
1067                 teamscores_flags(i) = ReadByte();
1068         }
1069         bool welcome_msg_too = ReadByte();
1070         if (welcome_msg_too)
1071                 net_handle_ServerWelcome();
1072         return = true;
1073         Scoreboard_InitScores();
1074         Gamemode_Init();
1075 }
1076
1077 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1078 {
1079         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1080
1081         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1082         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1083         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1084         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1085         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1086         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1087         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1088         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1089
1090         strcpy(forcefog, ReadString());
1091
1092         armorblockpercent = ReadByte() / 255.0;
1093         damagepush_speedfactor = ReadByte() / 255.0;
1094
1095         serverflags = ReadByte();
1096
1097         g_trueaim_minrange = ReadCoord();
1098
1099         return = true;
1100
1101         MUTATOR_CALLHOOK(Ent_Init);
1102
1103         if (!postinit) PostInit();
1104 }
1105
1106 float GetSpeedUnitFactor(int speed_unit)
1107 {
1108         switch(speed_unit)
1109         {
1110                 default:
1111                 case 1: return 1.0;
1112                 case 2: return 0.0254;
1113                 case 3: return 0.0254 * 3.6;
1114                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1115                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1116         }
1117 }
1118
1119 string GetSpeedUnit(int speed_unit)
1120 {
1121         switch(speed_unit)
1122         {
1123                 // translator-friendly strings without the initial space
1124                 default:
1125                 case 1: return strcat(" ", _("qu/s"));
1126                 case 2: return strcat(" ", _("m/s"));
1127                 case 3: return strcat(" ", _("km/h"));
1128                 case 4: return strcat(" ", _("mph"));
1129                 case 5: return strcat(" ", _("knots"));
1130         }
1131 }
1132
1133 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1134 {
1135         int b = ReadByte();
1136
1137         switch (b)
1138         {
1139                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1140                         race_checkpoint = ReadByte();
1141                         race_time = ReadInt24_t();
1142                         race_previousbesttime = ReadInt24_t();
1143                         race_mypreviousbesttime = ReadInt24_t();
1144                         string pbestname = ReadString();
1145                         if(autocvar_cl_race_cptimes_onlyself)
1146                         {
1147                                 race_previousbesttime = race_mypreviousbesttime;
1148                                 race_mypreviousbesttime = 0;
1149                                 strcpy(race_previousbestname, "");
1150                         }
1151                         else
1152                                 strcpy(race_previousbestname, pbestname);
1153
1154                         race_checkpointtime = time;
1155
1156                         if(race_checkpoint == 0 || race_checkpoint == 254)
1157                         {
1158                                 race_penaltyaccumulator = 0;
1159                                 race_laptime = time; // valid
1160                         }
1161                         break;
1162
1163                 case RACE_NET_CHECKPOINT_CLEAR:
1164                         race_laptime = 0;
1165                         race_checkpointtime = 0;
1166                         break;
1167
1168                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1169                         race_laptime = ReadCoord();
1170                         race_checkpointtime = -99999;
1171                         // fall through
1172                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1173                         race_nextcheckpoint = ReadByte();
1174
1175                         race_nextbesttime = ReadInt24_t();
1176                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1177                                 race_mybesttime = ReadInt24_t();
1178                         string newname = ReadString();
1179                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1180                         {
1181                                 race_nextbesttime = race_mybesttime;
1182                                 race_mybesttime = 0;
1183                                 strcpy(race_nextbestname, "");
1184                         }
1185                         else
1186                                 strcpy(race_nextbestname, newname);
1187                         break;
1188
1189                 case RACE_NET_CHECKPOINT_HIT_RACE:
1190                         race_mycheckpoint = ReadByte();
1191                         race_mycheckpointtime = time;
1192                         race_mycheckpointdelta = ReadInt24_t();
1193                         race_mycheckpointlapsdelta = ReadByte();
1194                         if(race_mycheckpointlapsdelta >= 128)
1195                                 race_mycheckpointlapsdelta -= 256;
1196                         int who = ReadByte();
1197                         if(who)
1198                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1199                         else
1200                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1201                         break;
1202
1203                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1204                         race_othercheckpoint = ReadByte();
1205                         race_othercheckpointtime = time;
1206                         race_othercheckpointdelta = ReadInt24_t();
1207                         race_othercheckpointlapsdelta = ReadByte();
1208                         if(race_othercheckpointlapsdelta >= 128)
1209                                 race_othercheckpointlapsdelta -= 256;
1210                         int what = ReadByte();
1211                         if(what)
1212                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1213                         else
1214                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1215                         break;
1216
1217                 case RACE_NET_PENALTY_RACE:
1218                 case RACE_NET_PENALTY_QUALIFYING:
1219                         race_penaltyeventtime = time;
1220                         race_penaltytime = ReadShort();
1221                         string reason = ReadString();
1222                         if (reason == "missing a checkpoint")
1223                                 reason = _("missing a checkpoint");
1224                         strcpy(race_penaltyreason, reason);
1225                         if (b == RACE_NET_PENALTY_QUALIFYING)
1226                                 race_penaltyaccumulator += race_penaltytime;
1227                         break;
1228
1229                 case RACE_NET_SERVER_RECORD:
1230                         race_server_record = ReadInt24_t();
1231                         break;
1232                 case RACE_NET_SPEED_AWARD:
1233                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1234                         strcpy(race_speedaward_holder, ReadString());
1235                         break;
1236                 case RACE_NET_SPEED_AWARD_BEST:
1237                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1238                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1239                         break;
1240                 case RACE_NET_RANKINGS_CNT:
1241                         RANKINGS_DISPLAY_CNT = ReadByte();
1242                         break;
1243                 case RACE_NET_SERVER_RANKINGS:
1244                         float prevpos, del;
1245                         int pos = ReadShort();
1246                         prevpos = ReadShort();
1247                         del = ReadShort();
1248
1249                         // move other rankings out of the way
1250                         int i;
1251                         if (prevpos) {
1252                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1253                                 for (i=m-1; i>pos-1; --i) {
1254                                         grecordtime[i] = grecordtime[i-1];
1255                                         strcpy(grecordholder[i], grecordholder[i-1]);
1256                                 }
1257                         } else if (del) { // a record has been deleted by the admin
1258                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1259                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1260                                                 grecordtime[i] = 0;
1261                                                 strfree(grecordholder[i]);
1262                                         }
1263                                         else {
1264                                                 grecordtime[i] = grecordtime[i+1];
1265                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1266                                         }
1267                                 }
1268                         } else { // player has no ranked record yet
1269                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1270                                         grecordtime[i] = grecordtime[i-1];
1271                                         strcpy(grecordholder[i], grecordholder[i-1]);
1272                                 }
1273                         }
1274
1275                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1276                                 // kick off the player who fell from the last displayed position
1277                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1278                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1279                         }
1280
1281                         // store new ranking
1282                         strcpy(grecordholder[pos-1], ReadString());
1283                         grecordtime[pos-1] = ReadInt24_t();
1284                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1285                                 race_myrank = pos;
1286                         break;
1287                 case RACE_NET_SERVER_STATUS:
1288                         race_status = ReadShort();
1289                         strcpy(race_status_name, ReadString());
1290         }
1291         return true;
1292 }
1293
1294 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1295 {
1296         teamnagger = 1;
1297         return true;
1298 }
1299
1300 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1301 {
1302         int i = ReadByte();
1303         int pi = ReadShort();
1304         int pl = ReadByte();
1305         int ml = ReadByte();
1306         return = true;
1307         entity e = playerslots[i];
1308         if (!e) return;
1309         e.ping = pi;
1310         e.ping_packetloss = pl / 255.0;
1311         e.ping_movementloss = ml / 255.0;
1312 }
1313
1314 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1315 {
1316         int weapon_id = ReadByte();
1317         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1318         complain_weapon_type = ReadByte();
1319         return = true;
1320
1321         complain_weapon_time = time;
1322         weapontime = time; // ping the weapon panel
1323
1324         switch(complain_weapon_type)
1325         {
1326                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1327                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1328                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1329         }
1330 }
1331
1332 string translate_modifications(string s)
1333 {
1334         return build_mutator_list(s);
1335 }
1336
1337 string translate_weaponarena(string s)
1338 {
1339         if (s == "") return s;
1340         if (s == "All Weapons Arena") return _("All Weapons Arena");
1341         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1342         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1343         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1344         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1345         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1346         if (s == "No Weapons Arena") return _("No Weapons Arena");
1347
1348         int n = tokenizebyseparator(s, " & ");
1349         string wpn_list = "";
1350         for (int i = 0; i < n; i++)
1351         {
1352                 Weapon wep = Weapon_from_name(argv(i));
1353                 if (wep == WEP_Null)
1354                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1355                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1356         }
1357         if (wpn_list != "")
1358                 return sprintf(_("%s Arena"), wpn_list);
1359         else
1360                 return _("No Weapons Arena");
1361 }
1362
1363 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1364 {
1365         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1366         if (version_mismatch)
1367         {
1368                 if(!version_check)
1369                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1370                                 _("Your client version is outdated."), "\n\n\n",
1371                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1372                                 _("Please update!"));
1373                 else
1374                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1375                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1376                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1377         }
1378         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1379 }
1380
1381 bool net_handle_ServerWelcome()
1382 {
1383         bool campaign = ReadByte();
1384         if (campaign)
1385         {
1386                 string campaign_title = ReadString();
1387                 int campaign_level = ReadByte();
1388                 string campaign_msg = ReadString();
1389                 string welcomedialog_args;
1390                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1391                 string key = getcommandkey(_("jump"), "+jump");
1392                 string msg = strcat(
1393                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1394                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1395                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1396                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1397                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1398                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1399                 return true;
1400         }
1401
1402         welcome_msg_force_centerprint = ReadByte();
1403         strcpy(hostname, ReadString());
1404
1405         string hostversion = ReadString();
1406         bool version_mismatch = ReadByte();
1407         bool version_check = ReadByte();
1408         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1409
1410         string modifications = translate_modifications(ReadString());
1411         string weaponarena_list = translate_weaponarena(ReadString());
1412         string cache_mutatormsg = ReadString();
1413         string motd = ReadString();
1414
1415         string msg = "";
1416         msg = strcat(msg, ver);
1417         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1418
1419         modifications = cons_mid(modifications, ", ", weaponarena_list);
1420         if(modifications != "")
1421                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1422
1423         if (cache_mutatormsg != "")
1424                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1425         string mutator_msg = "";
1426         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1427         mutator_msg = M_ARGV(0, string);
1428         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1429
1430         if (motd != "")
1431                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1432
1433         strcpy(welcome_msg, msg);
1434         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1435         return true;
1436 }
1437
1438 void Welcome_Message_Show_Try()
1439 {
1440         if (!welcome_msg_menu_check_maxtime)
1441                 return;
1442
1443         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1444         // if want dialog check if menu is initialized but for a short time
1445         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1446         {
1447                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1448                 {
1449                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1450                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1451                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1452                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1453                 }
1454                 else
1455                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1456
1457                 strfree(welcome_msg);
1458                 welcome_msg_menu_check_maxtime = 0;
1459         }
1460 }
1461
1462 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1463 {
1464         return net_handle_ServerWelcome();
1465 }
1466
1467 string _getcommandkey(string cmd_name, string command, bool forcename)
1468 {
1469         string keys;
1470         float n, j, k, l = 0;
1471
1472         if (!autocvar_hud_showbinds)
1473                 return cmd_name;
1474
1475         keys = db_get(binddb, command);
1476         if (keys == "")
1477         {
1478                 bool joy_active = cvar("joy_active");
1479                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1480                 for(j = 0; j < n; ++j)
1481                 {
1482                         k = stof(argv(j));
1483                         if(k != -1)
1484                         {
1485                                 string key = keynumtostring(k);
1486                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1487                                         continue;
1488
1489                                 key = translate_key(key);
1490
1491                                 if (keys == "")
1492                                         keys = key;
1493                                 else
1494                                         keys = strcat(keys, ", ", key);
1495
1496                                 ++l;
1497                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1498                                         break;
1499                         }
1500
1501                 }
1502                 if (keys == "")
1503                         keys = "NO_KEY";
1504                 db_put(binddb, command, keys);
1505         }
1506
1507         if (keys == "NO_KEY") {
1508                 if (autocvar_hud_showbinds > 1)
1509                         return sprintf(_("%s (not bound)"), cmd_name);
1510                 else
1511                         return cmd_name;
1512         }
1513         else if (autocvar_hud_showbinds > 1 || forcename)
1514                 return sprintf("%s (%s)", cmd_name, keys);
1515         else
1516                 return keys;
1517 }
1518
1519 /** engine callback */
1520 void URI_Get_Callback(int id, int status, string data)
1521 {
1522         TC(int, id); TC(int, status);
1523         if(url_URI_Get_Callback(id, status, data))
1524         {
1525                 // handled
1526         }
1527         else if (id == URI_GET_DISCARD)
1528         {
1529                 // discard
1530         }
1531         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1532         {
1533                 // sv_cmd curl
1534                 Curl_URI_Get_Callback(id, status, data);
1535         }
1536         else
1537         {
1538                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1539         }
1540 }