Make scoreboard team selection on spacebar press work for old clients. While at it...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include <client/command/cl_cmd.qh>
4 #include <client/draw.qh>
5 #include <client/hud/_mod.qh>
6 #include <client/hud/panel/centerprint.qh>
7 #include <client/hud/panel/chat.qh>
8 #include <client/hud/panel/quickmenu.qh>
9 #include <client/hud/panel/scoreboard.qh>
10 #include <client/items/items.qh>
11 #include <client/mapvoting.qh>
12 #include <client/mutators/_mod.qh>
13 #include <client/shownames.qh>
14 #include <client/view.qh>
15 #include <client/weapons/projectile.qh>
16 #include <common/deathtypes/all.qh>
17 #include <common/effects/all.inc>
18 #include <common/effects/all.qh>
19 #include <common/effects/effect.qh>
20 #include <common/effects/qc/_mod.qh>
21 #include <common/ent_cs.qh>
22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
23 #include <common/items/_mod.qh>
24 #include <common/mapinfo.qh>
25 #include <common/mapobjects/_mod.qh>
26 #include <common/minigames/cl_minigames.qh>
27 #include <common/minigames/cl_minigames_hud.qh>
28 #include <common/net_linked.qh>
29 #include <common/net_notice.qh>
30 #include <common/scores.qh>
31 #include <common/vehicles/all.qh>
32 #include <lib/csqcmodel/cl_model.qh>
33 #include <lib/csqcmodel/interpolate.qh>
34 #include <lib/warpzone/client.qh>
35
36 // --------------------------------------------------------------------------
37 // BEGIN REQUIRED CSQC FUNCTIONS
38 //include "main.qh"
39
40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
41
42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
43 // Useful for precaching things
44
45 void CSQC_Init()
46 {
47         prvm_language = strzone(cvar_string("prvm_language"));
48
49 #ifdef WATERMARK
50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
51 #endif
52
53         {
54                 int i = 0;
55                 for ( ; i < 255; ++i)
56                         if (getplayerkeyvalue(i, "viewentity") == "")
57                                 break;
58                 maxclients = i;
59         }
60
61         // needs to be done so early because of the constants they create
62         static_init();
63         static_init_late();
64         static_init_precache();
65
66         binddb = db_create();
67         tempdb = db_create();
68         ClientProgsDB = db_load("client.db");
69
70         draw_endBoldFont();
71
72         //registercommand("hud_configure");
73         //registercommand("hud_save");
74         //registercommand("menu_action");
75
76         ConsoleCommand_macro_init();
77
78         registercvar("hud_usecsqc", "1");
79         registercvar("scoreboard_columns", "default");
80
81         registercvar("cl_nade_type", "3");
82         registercvar("cl_pokenade_type", "zombie");
83
84         registercvar("cl_jumpspeedcap_min", "");
85         registercvar("cl_jumpspeedcap_max", "");
86
87         registercvar("cl_shootfromfixedorigin", "");
88
89         registercvar("cl_multijump", "-1");
90
91         registercvar("cl_dodging", "0");
92
93         registercvar("cl_spawn_near_teammate", "1");
94
95         registercvar("cl_weapon_switch_reload", "1");
96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
97
98         registercvar("cl_allow_uidranking", "1");
99
100         if(autocvar_cl_lockview)
101                 cvar_set("cl_lockview", "0");
102
103         if (cvar_type("_scoreboard_team_selection_available") & CVAR_TYPEFLAG_EXISTS)
104                 cvar_settemp("_scoreboard_team_selection_available", "1");
105         cvar_set("_scoreboard_team_selection", "0"); // in case it has been left set to 1
106
107         gametype = NULL;
108
109         postinit = false;
110
111         calledhooks = 0;
112
113         teams = Sort_Spawn();
114         players = Sort_Spawn();
115
116         GetTeam(NUM_SPECTATOR, true); // add specs first
117
118         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
119                 weapon_accuracy[w] = -1;
120
121         // precaches
122
123         if(autocvar_cl_reticle)
124         {
125                 precache_pic("gfx/reticle_normal");
126                 // weapon reticles are precached in weapon files
127         }
128
129         {
130                 get_mi_min_max_texcoords(1); // try the CLEVER way first
131                 minimapname = strcat("gfx/", mi_shortname, "_radar");
132                 shortmapname = mi_shortname;
133
134                 if (precache_pic(minimapname) == "")
135                 {
136                         // but maybe we have a non-clever minimap
137                         minimapname = strcat("gfx/", mi_shortname, "_mini");
138                         if (precache_pic(minimapname) == "")
139                                 minimapname = ""; // FAIL
140                         else
141                                 get_mi_min_max_texcoords(0); // load new texcoords
142                 }
143
144                 mi_center = (mi_min + mi_max) * 0.5;
145                 mi_scale = mi_max - mi_min;
146                 minimapname = strzone(minimapname);
147         }
148
149         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
150         LoadMenuSkinValues();
151 }
152
153 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
154 void Shutdown()
155 {
156         WarpZone_Shutdown();
157
158         delete(teams);
159         delete(players);
160         db_close(binddb);
161         db_close(tempdb);
162         if(autocvar_cl_db_saveasdump)
163                 db_dump(ClientProgsDB, "client.db");
164         else
165                 db_save(ClientProgsDB, "client.db");
166         db_close(ClientProgsDB);
167
168         if(camera_active)
169                 cvar_set("chase_active",ftos(chase_active_backup));
170
171         // unset the event chasecam's chase_active
172         if(autocvar_chase_active < 0)
173                 cvar_set("chase_active", "0");
174
175         if (autocvar_r_drawviewmodel < 0)
176                 cvar_set("r_drawviewmodel", "0");
177
178         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
179
180         if (!isdemo())
181         {
182                 if (!(calledhooks & HOOK_START))
183                         localcmd("\n_cl_hook_gamestart nop\n");
184                 if (!(calledhooks & HOOK_END))
185                 {
186                         int gamecount = cvar("cl_matchcount");
187                         localcmd("\ncl_hook_gameend\n");
188                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
189                         // earlier versions of the game abuse the hook to set this cvar
190                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
191                         //cvar_set("cl_matchcount", itos(gamecount + 1));
192                 }
193         }
194
195         localcmd("\ncl_hook_shutdown\n");
196
197         localcmd("\n-button12\n");
198
199         deactivate_minigame();
200         HUD_MinigameMenu_Close(NULL, NULL, NULL);
201
202         ReplicateVars(REPLICATEVARS_DESTROY);
203 }
204
205 void AuditLists()
206 {
207         entity e;
208         entity prev;
209
210         prev = players;
211         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
212         {
213                 if(prev != e.sort_prev)
214                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
215         }
216
217         prev = teams;
218         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
219         {
220                 if(prev != e.sort_prev)
221                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
222         }
223 }
224
225 float RegisterPlayer(entity player)
226 {
227         entity pl;
228         AuditLists();
229         for(pl = players.sort_next; pl; pl = pl.sort_next)
230                 if(pl == player)
231                         error("Player already registered!");
232         player.sort_next = players.sort_next;
233         player.sort_prev = players;
234         if(players.sort_next)
235                 players.sort_next.sort_prev = player;
236         players.sort_next = player;
237         AuditLists();
238         return true;
239 }
240
241 void RemovePlayer(entity player)
242 {
243         entity pl, parent;
244         AuditLists();
245         parent = players;
246         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
247                 parent = pl;
248
249         if(!pl)
250         {
251                 error("Trying to remove a player which is not in the playerlist!");
252                 return;
253         }
254         parent.sort_next = player.sort_next;
255         if(player.sort_next)
256                 player.sort_next.sort_prev = parent;
257         AuditLists();
258 }
259
260 void MoveToLast(entity e)
261 {
262         AuditLists();
263         entity ent = e.sort_next;
264         while(ent)
265         {
266                 SORT_SWAP(ent, e);
267                 ent = e.sort_next;
268         }
269         AuditLists();
270 }
271
272 float RegisterTeam(entity Team)
273 {
274         assert_once(Team.team, eprint(Team));
275         entity tm;
276         AuditLists();
277         for(tm = teams.sort_next; tm; tm = tm.sort_next)
278                 if(tm == Team)
279                         error("Team already registered!");
280         Team.sort_next = teams.sort_next;
281         Team.sort_prev = teams;
282         if(teams.sort_next)
283                 teams.sort_next.sort_prev = Team;
284         teams.sort_next = Team;
285         if(Team.team && Team.team != NUM_SPECTATOR)
286                 ++team_count;
287         AuditLists();
288         return true;
289 }
290
291 void RemoveTeam(entity Team)
292 {
293         entity tm, parent;
294         AuditLists();
295         parent = teams;
296         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
297                 parent = tm;
298
299         if(!tm)
300         {
301                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
302                 return;
303         }
304         parent.sort_next = Team.sort_next;
305         if(Team.sort_next)
306                 Team.sort_next.sort_prev = parent;
307         if(Team.team && Team.team != NUM_SPECTATOR)
308                 --team_count;
309         AuditLists();
310 }
311
312 entity GetTeam(int Team, bool add)
313 {
314         TC(int, Team); TC(bool, add);
315         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
316         if(teamslots[num])
317                 return teamslots[num];
318         if (!add)
319                 return NULL;
320         entity tm = new_pure(team);
321         tm.team = Team;
322         teamslots[num] = tm;
323         RegisterTeam(tm);
324         return tm;
325 }
326
327 .float has_team;
328 bool SetTeam(entity o, int Team)
329 {
330         TC(int, Team);
331         //devassert_once(Team);
332         entity tm;
333         if(teamplay)
334         {
335                 switch(Team)
336                 {
337                         case -1:
338                         case NUM_TEAM_1:
339                         case NUM_TEAM_2:
340                         case NUM_TEAM_3:
341                         case NUM_TEAM_4:
342                                 break;
343                         default:
344                                 if(GetTeam(Team, false) == NULL)
345                                 {
346                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
347                                         Team = NUM_SPECTATOR;
348                                 }
349                                 break;
350                 }
351         }
352         else
353         {
354                 switch(Team)
355                 {
356                         case -1:
357                         case 0:
358                                 break;
359                         default:
360                                 if(GetTeam(Team, false) == NULL)
361                                 {
362                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
363                                         Team = NUM_SPECTATOR;
364                                 }
365                                 break;
366                 }
367         }
368         if(Team == -1) // leave
369         {
370                 if(o.has_team)
371                 {
372                         tm = GetTeam(o.team, false);
373                         tm.team_size -= 1;
374                         o.has_team = 0;
375                         return true;
376                 }
377         }
378         else
379         {
380                 if (!o.has_team)
381                 {
382                         o.team = Team;
383                         tm = GetTeam(Team, true);
384                         tm.team_size += 1;
385                         o.has_team = 1;
386                         return true;
387                 }
388                 else if(Team != o.team)
389                 {
390                         tm = GetTeam(o.team, false);
391                         tm.team_size -= 1;
392                         o.team = Team;
393                         tm = GetTeam(Team, true);
394                         tm.team_size += 1;
395                         return true;
396                 }
397         }
398         return false;
399 }
400
401 void Playerchecker_Think(entity this)
402 {
403         int i;
404         entity e;
405         for(i = 0; i < maxclients; ++i)
406         {
407                 e = playerslots[i];
408                 if(entcs_GetName(i) == "")
409                 {
410                         if(e.sort_prev)
411                         {
412                                 // player disconnected
413                                 SetTeam(e, -1);
414                                 RemovePlayer(e);
415                                 e.sort_prev = NULL;
416                                 //e.gotscores = 0;
417                         }
418                 }
419                 else
420                 {
421                         if (!e.sort_prev)
422                         {
423                                 // player connected
424                                 if (!e)
425                                 {
426                                         playerslots[i] = e = new_pure(playerslot);
427                                 }
428                                 e.sv_entnum = i;
429                                 e.ping = 0;
430                                 e.ping_packetloss = 0;
431                                 e.ping_movementloss = 0;
432                                 //e.gotscores = 0; // we might already have the scores...
433                                 int t = entcs_GetScoreTeam(i);
434                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
435                                 RegisterPlayer(e);
436                                 Scoreboard_UpdatePlayerPos(e);
437                         }
438                 }
439         }
440         this.nextthink = time + 0.2;
441 }
442
443 void PostInit()
444 {
445         entity playerchecker = new_pure(playerchecker);
446         setthink(playerchecker, Playerchecker_Think);
447         playerchecker.nextthink = time + 0.2;
448
449         TrueAim_Init();
450
451         // this can't be called in CSQC_Init as it'd send cvars too early
452         ReplicateVars_Start();
453
454         postinit = true;
455 }
456
457 void Release_Common_Keys()
458 {
459         localcmd("-fire\n");
460         localcmd("-fire2\n");
461         localcmd("-use\n");
462         localcmd("-hook\n");
463         localcmd("-jump\n");
464 }
465
466 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
467 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
468 // All keys are in ascii.
469 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
470 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
471 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
472 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
473 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
474 {
475         TC(int, bInputType);
476         bool override = false;
477
478         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
479         if (override)
480                 return true;
481
482         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
483         if (override)
484                 return true;
485
486         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
487
488         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
489
490         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
491
492         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
493
494         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
495
496         if(override)
497                 return true;
498
499         if(bInputType == 3 || bInputType == 2)
500                 return false;
501
502         // at this point bInputType can only be 0 or 1 (key pressed or released)
503         bool key_pressed = (bInputType == 0);
504
505         if(key_pressed) {
506                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
507                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
508                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
509                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
510         }
511         else {
512                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
513                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
514                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
515                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
516         }
517
518         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
519         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
520         {
521                 if (hudShiftState & S_TAB)
522                 {
523                         Scoreboard_UI_Enable(0);
524                         return true;
525                 }
526                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
527                 {
528                         localcmd("\nmenu_showgamemenudialog\n");
529                         return true;
530                 }
531         }
532
533         return false;
534 }
535
536 // END REQUIRED CSQC FUNCTIONS
537 // --------------------------------------------------------------------------
538
539 // --------------------------------------------------------------------------
540 // BEGIN OPTIONAL CSQC FUNCTIONS
541
542 void Ent_RemovePlayerScore(entity this)
543 {
544         if(this.owner) {
545                 SetTeam(this.owner, -1);
546                 this.owner.gotscores = 0;
547                 FOREACH(Scores, true, {
548                         this.owner.(scores(it)) = 0; // clear all scores
549                 });
550         }
551 }
552
553 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
554 {
555         make_pure(this);
556         entity o;
557
558         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
559         // (no I've never heard of M-x replace-string, sed, or anything like that)
560         bool isNew = !this.owner; // workaround for DP bug
561         int n = ReadByte()-1;
562
563 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
564         if(!isNew && n != this.sv_entnum)
565         {
566                 //print("A CSQC entity changed its owner!\n");
567                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
568                 isNew = true;
569                 Ent_Remove(this);
570         }
571 #endif
572
573         this.sv_entnum = n;
574
575         o = playerslots[this.sv_entnum];
576         if (!o)
577         {
578                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
579         }
580         this.owner = o;
581         o.sv_entnum = this.sv_entnum;
582         o.gotscores = 1;
583
584         //if (!o.sort_prev)
585         //      RegisterPlayer(o);
586         //playerchecker will do this for us later, if it has not already done so
587
588         int sf = ReadShort();
589         int lf = ReadShort();
590         FOREACH(Scores, true, {
591                 int p = 1 << (i % 16);
592                 if (sf & p)
593                 {
594                         if (lf & p)
595                                 o.(scores(it)) = ReadInt24_t();
596                         else
597                                 o.(scores(it)) = ReadChar();
598                 }
599         });
600
601         return = true;
602
603         if(o.sort_prev)
604                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
605
606         this.entremove = Ent_RemovePlayerScore;
607 }
608
609 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
610 {
611         make_pure(this);
612         int i;
613
614         this.team = ReadByte();
615         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
616
617 #if MAX_TEAMSCORE <= 8
618         int sf = ReadByte();
619         int lf = ReadByte();
620 #else
621         int sf = ReadShort();
622         int lf = ReadShort();
623 #endif
624         for(i = 0; i < MAX_TEAMSCORE; ++i)
625                 if(sf & BIT(i))
626                 {
627                         if(lf & BIT(i))
628                                 o.(teamscores(i)) = ReadInt24_t();
629                         else
630                                 o.(teamscores(i)) = ReadChar();
631                 }
632
633         return = true;
634
635         Scoreboard_UpdateTeamPos(o);
636 }
637
638 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
639 {
640         make_pure(this);
641         float newspectatee_status;
642
643         int f = ReadByte();
644
645         scoreboard_showscores_force = (f & BIT(0));
646
647         if(f & BIT(1))
648         {
649                 newspectatee_status = ReadByte();
650                 if(newspectatee_status == player_localnum + 1)
651                         newspectatee_status = -1; // observing
652         }
653         else
654                 newspectatee_status = 0;
655
656         spectatorbutton_zoom = (f & BIT(2));
657
658         if(f & BIT(4))
659         {
660                 num_spectators = ReadByte();
661
662                 float i, slot;
663
664                 for(i = 0; i < MAX_SPECTATORS; ++i)
665                         spectatorlist[i] = 0; // reset list first
666
667                 int limit = min(num_spectators, MAX_SPECTATORS);
668                 for(i = 0; i < limit; ++i)
669                 {
670                         slot = ReadByte();
671                         spectatorlist[i] = slot - 1;
672                 }
673         }
674         else
675         {
676                 for(int j = 0; j < MAX_SPECTATORS; ++j)
677                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
678                 num_spectators = 0;
679         }
680
681         return = true;
682
683         if(newspectatee_status != spectatee_status)
684         {
685                 // clear race stuff
686                 race_laptime = 0;
687                 race_checkpointtime = 0;
688                 hud_dynamic_shake_factor = -1;
689                 spectatee_status_changed_time = time;
690         }
691         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
692         {
693                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
694                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
695                 )
696                         prev_p_health = -1;
697                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
698                         prev_health = -1;
699         }
700         spectatee_status = newspectatee_status;
701
702         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
703 }
704
705 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
706 {
707         make_pure(this);
708         int i, j, b, f;
709
710         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
711
712         if(!(nags & BIT(2)))
713         {
714                 strfree(vote_called_vote);
715                 vote_active = 0;
716         }
717         else
718         {
719                 vote_active = 1;
720         }
721
722         if(nags & BIT(6))
723         {
724                 vote_yescount = ReadByte();
725                 vote_nocount = ReadByte();
726                 vote_needed = ReadByte();
727                 vote_highlighted = ReadChar();
728         }
729
730         if(nags & BIT(7))
731         {
732                 strcpy(vote_called_vote, ReadString());
733         }
734
735         if(nags & 1)
736         {
737                 for(j = 0; j < maxclients; ++j)
738                         if(playerslots[j])
739                                 playerslots[j].ready = true;
740                 for(i = 1; i <= maxclients; i += 8)
741                 {
742                         f = ReadByte();
743                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
744                                 if (!(f & b))
745                                         if(playerslots[j])
746                                                 playerslots[j].ready = false;
747                 }
748         }
749
750         return = true;
751
752         ready_waiting = (nags & BIT(0));
753         ready_waiting_for_me = (nags & BIT(1));
754         vote_waiting = (nags & BIT(2));
755         vote_waiting_for_me = (nags & BIT(3));
756         warmup_stage = (nags & BIT(4));
757 }
758
759 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
760 {
761         make_pure(this);
762         int sf = 0;
763         serialize(byte, 0, sf);
764         if (sf & 1) {
765                 for (int j = 0; j < maxclients; ++j) {
766                         if (playerslots[j]) {
767                                 playerslots[j].eliminated = true;
768                         }
769                 }
770                 for (int i = 1; i <= maxclients; i += 8) {
771                         int f = 0;
772                         serialize(byte, 0, f);
773                         for (int b = 0; b < 8; ++b) {
774                                 if (f & BIT(b)) continue;
775                                 int j = i - 1 + b;
776                                 if (playerslots[j]) {
777                                         playerslots[j].eliminated = false;
778                                 }
779                         }
780                 }
781         }
782         return true;
783 }
784
785 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
786 {
787         make_pure(this);
788         prandom_debug();
789         float s = ReadShort();
790         psrandom(s);
791         return true;
792 }
793
794 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
795 {
796         make_pure(this);
797         int sf = ReadInt24_t();
798         if (sf == 0) {
799                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
800                         weapon_accuracy[w] = -1;
801                 return true;
802         }
803
804         int f = 1;
805         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
806                 if (sf & f) {
807                         int b = ReadByte();
808                         if (b == 0)
809                                 weapon_accuracy[w] = -1;
810                         else if (b == 255)
811                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
812                         else
813                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
814                 }
815                 f = (f == 0x800000) ? 1 : f * 2;
816         }
817         return true;
818 }
819
820 void Spawn_Draw(entity this)
821 {
822         bool dodraw = autocvar_cl_spawn_point_particles;
823         if(dodraw && autocvar_cl_spawn_point_dist_max)
824         {
825                 vector org = getpropertyvec(VF_ORIGIN);
826                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
827         }
828
829         if(dodraw)
830                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
831 }
832
833 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
834 {
835         float teamnum = (ReadByte() - 1);
836         vector spn_origin = ReadVector();
837
838         this.team = (teamnum + 1);
839
840         //if(is_new)
841         //{
842                 this.origin = spn_origin;
843                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
844                 //droptofloor();
845
846                 /*if(autocvar_cl_spawn_point_model) // needs a model first
847                 {
848                         this.mdl = "models/spawnpoint.md3";
849                         this.colormod = Team_ColorRGB(teamnum);
850                         precache_model(this.mdl);
851                         setmodel(this, this.mdl);
852                         this.drawmask = MASK_NORMAL;
853                         //this.move_movetype = MOVETYPE_NOCLIP;
854                         //this.draw = Spawn_Draw;
855                         IL_PUSH(g_drawables, this);
856                 }*/
857                 this.draw = Spawn_Draw;
858                 if (is_new) IL_PUSH(g_drawables, this);
859         //}
860
861         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
862         return true;
863 }
864
865 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
866 {
867         // If entnum is 0, ONLY do the local spawn actions
868         // this way the server can disable the sending of
869         // spawn origin or such to clients if wanted.
870         float entnum = ReadByte();
871
872         if(entnum)
873         {
874                 this.origin = ReadVector();
875
876                 if(is_new)
877                 {
878                         float teamnum = entcs_GetTeam(entnum - 1);
879
880                         if(autocvar_cl_spawn_event_particles)
881                         {
882                                 switch(teamnum)
883                                 {
884                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
885                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
886                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
887                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
888                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
889                                 }
890                         }
891                         if(autocvar_cl_spawn_event_sound)
892                         {
893                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
894                         }
895                 }
896         }
897         return = true;
898
899         // local spawn actions
900         if(is_new && (!entnum || (entnum == player_localentnum)))
901         {
902                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
903                 {
904                         zoomin_effect = 1;
905                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
906                 }
907
908                 if(autocvar_cl_unpress_zoom_on_spawn)
909                 {
910                         localcmd("-zoom\n");
911                         button_zoom = false;
912                 }
913                 HUD_Radar_Hide_Maximized();
914         }
915         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
916 }
917
918 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
919 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
920 void CSQC_Ent_Update(entity this, bool isnew)
921 {
922         this.sourceLoc = __FILE__":"STR(__LINE__);
923         int t = ReadByte();
924
925         // set up the "time" global for received entities to be correct for interpolation purposes
926         float savetime = time;
927         if(servertime)
928         {
929                 time = servertime;
930         }
931         else
932         {
933                 serverprevtime = time;
934                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
935                 time = serverprevtime + serverdeltatime;
936         }
937
938 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
939         if (this.enttype)
940         {
941                 if (t != this.enttype || isnew)
942                 {
943                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
944                         Ent_Remove(this);
945                         ONREMOVE(this);
946                         clearentity(this);
947                         isnew = true;
948                 }
949         }
950         else
951         {
952                 if (!isnew)
953                 {
954                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
955                         isnew = true;
956                 }
957         }
958 #endif
959         this.enttype = t;
960         bool done = false;
961         FOREACH(LinkedEntities, it.m_id == t, {
962                 if (isnew) this.classname = it.netname;
963                 if (autocvar_developer_csqcentities)
964                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
965                 done = it.m_read(this, NULL, isnew);
966                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
967                 break;
968         });
969         time = savetime;
970         if (!done)
971         {
972                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
973         }
974 }
975
976 // Destructor, but does NOT deallocate the entity by calling remove(). Also
977 // used when an entity changes its type. For an entity that someone interacts
978 // with others, make sure it can no longer do so.
979 void Ent_Remove(entity this)
980 {
981         if(this.entremove) this.entremove(this);
982
983         if(this.skeletonindex)
984         {
985                 skel_delete(this.skeletonindex);
986                 this.skeletonindex = 0;
987         }
988
989         if(this.snd_looping > 0)
990         {
991                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
992                 this.snd_looping = 0;
993         }
994
995         this.enttype = 0;
996         this.classname = "";
997         this.draw = func_null;
998         this.entremove = func_null;
999         // TODO possibly set more stuff to defaults
1000 }
1001 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
1002 void CSQC_Ent_Remove(entity this)
1003 {
1004         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
1005         if (wasfreed(this))
1006         {
1007                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
1008                 return;
1009         }
1010         if (this.enttype) Ent_Remove(this);
1011         delete(this);
1012 }
1013
1014 void Gamemode_Init()
1015 {
1016         if (!isdemo())
1017         {
1018                 if(!(calledhooks & HOOK_START))
1019                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1020                 calledhooks |= HOOK_START;
1021         }
1022 }
1023 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1024 void CSQC_Parse_StuffCmd(string strMessage)
1025 {
1026         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1027         localcmd(strMessage);
1028 }
1029 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1030 void CSQC_Parse_Print(string strMessage)
1031 {
1032         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1033         print(ColorTranslateRGB(strMessage));
1034 }
1035
1036 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1037 void CSQC_Parse_CenterPrint(string strMessage)
1038 {
1039         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1040         centerprint_AddStandard(strMessage);
1041 }
1042
1043 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1044 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1045 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1046 bool CSQC_Parse_TempEntity()
1047 {
1048         // Acquire TE ID
1049         int nTEID = ReadByte();
1050
1051         FOREACH(TempEntities, it.m_id == nTEID, {
1052                 if (autocvar_developer_csqcentities)
1053                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1054                 return it.m_read(NULL, NULL, true);
1055         });
1056
1057         if (autocvar_developer_csqcentities)
1058                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1059
1060         // No special logic for this temporary entity; return 0 so the engine can handle it
1061         return false;
1062 }
1063
1064 string forcefog;
1065 void Fog_Force()
1066 {
1067         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1068                 localcmd("\nr_drawfog 0\n");
1069         else if (forcefog != "")
1070                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1071 }
1072
1073 bool net_handle_ServerWelcome();
1074 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1075 {
1076         make_pure(this);
1077         gametype = ReadRegistered(Gametypes);
1078         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1079         HUD_ModIcons_SetFunc();
1080         FOREACH(Scores, true, {
1081                 strcpy(scores_label(it), ReadString());
1082                 scores_flags(it) = ReadByte();
1083         });
1084         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1085         {
1086                 strcpy(teamscores_label(i), ReadString());
1087                 teamscores_flags(i) = ReadByte();
1088         }
1089         bool welcome_msg_too = ReadByte();
1090         if (welcome_msg_too)
1091                 net_handle_ServerWelcome();
1092         return = true;
1093         Scoreboard_InitScores();
1094         Gamemode_Init();
1095 }
1096
1097 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1098 {
1099         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1100
1101         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1102         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1103         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1104         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1105         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1106         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1107         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1108         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1109
1110         strcpy(forcefog, ReadString());
1111
1112         armorblockpercent = ReadByte() / 255.0;
1113         damagepush_speedfactor = ReadByte() / 255.0;
1114
1115         serverflags = ReadByte();
1116
1117         g_trueaim_minrange = ReadCoord();
1118
1119         return = true;
1120
1121         MUTATOR_CALLHOOK(Ent_Init);
1122
1123         if (!postinit) PostInit();
1124 }
1125
1126 float GetSpeedUnitFactor(int speed_unit)
1127 {
1128         switch(speed_unit)
1129         {
1130                 default:
1131                 case 1: return 1.0;
1132                 case 2: return 0.0254;
1133                 case 3: return 0.0254 * 3.6;
1134                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1135                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1136         }
1137 }
1138
1139 string GetSpeedUnit(int speed_unit)
1140 {
1141         switch(speed_unit)
1142         {
1143                 // translator-friendly strings without the initial space
1144                 default:
1145                 case 1: return strcat(" ", _("qu/s"));
1146                 case 2: return strcat(" ", _("m/s"));
1147                 case 3: return strcat(" ", _("km/h"));
1148                 case 4: return strcat(" ", _("mph"));
1149                 case 5: return strcat(" ", _("knots"));
1150         }
1151 }
1152
1153 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1154 {
1155         int b = ReadByte();
1156
1157         switch (b)
1158         {
1159                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1160                         race_checkpoint = ReadByte();
1161                         race_time = ReadInt24_t();
1162                         race_previousbesttime = ReadInt24_t();
1163                         race_mypreviousbesttime = ReadInt24_t();
1164                         string pbestname = ReadString();
1165                         if(autocvar_cl_race_cptimes_onlyself)
1166                         {
1167                                 race_previousbesttime = race_mypreviousbesttime;
1168                                 race_mypreviousbesttime = 0;
1169                                 strcpy(race_previousbestname, "");
1170                         }
1171                         else
1172                                 strcpy(race_previousbestname, pbestname);
1173
1174                         race_checkpointtime = time;
1175
1176                         if(race_checkpoint == 0 || race_checkpoint == 254)
1177                         {
1178                                 race_penaltyaccumulator = 0;
1179                                 race_laptime = time; // valid
1180                         }
1181                         break;
1182
1183                 case RACE_NET_CHECKPOINT_CLEAR:
1184                         race_laptime = 0;
1185                         race_checkpointtime = 0;
1186                         break;
1187
1188                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1189                         race_laptime = ReadCoord();
1190                         race_checkpointtime = -99999;
1191                         // fall through
1192                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1193                         race_nextcheckpoint = ReadByte();
1194
1195                         race_nextbesttime = ReadInt24_t();
1196                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1197                                 race_mybesttime = ReadInt24_t();
1198                         string newname = ReadString();
1199                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1200                         {
1201                                 race_nextbesttime = race_mybesttime;
1202                                 race_mybesttime = 0;
1203                                 strcpy(race_nextbestname, "");
1204                         }
1205                         else
1206                                 strcpy(race_nextbestname, newname);
1207                         break;
1208
1209                 case RACE_NET_CHECKPOINT_HIT_RACE:
1210                         race_mycheckpoint = ReadByte();
1211                         race_mycheckpointtime = time;
1212                         race_mycheckpointdelta = ReadInt24_t();
1213                         race_mycheckpointlapsdelta = ReadByte();
1214                         if(race_mycheckpointlapsdelta >= 128)
1215                                 race_mycheckpointlapsdelta -= 256;
1216                         int who = ReadByte();
1217                         if(who)
1218                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1219                         else
1220                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1221                         break;
1222
1223                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1224                         race_othercheckpoint = ReadByte();
1225                         race_othercheckpointtime = time;
1226                         race_othercheckpointdelta = ReadInt24_t();
1227                         race_othercheckpointlapsdelta = ReadByte();
1228                         if(race_othercheckpointlapsdelta >= 128)
1229                                 race_othercheckpointlapsdelta -= 256;
1230                         int what = ReadByte();
1231                         if(what)
1232                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1233                         else
1234                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1235                         break;
1236
1237                 case RACE_NET_PENALTY_RACE:
1238                 case RACE_NET_PENALTY_QUALIFYING:
1239                         race_penaltyeventtime = time;
1240                         race_penaltytime = ReadShort();
1241                         string reason = ReadString();
1242                         if (reason == "missing a checkpoint")
1243                                 reason = _("missing a checkpoint");
1244                         strcpy(race_penaltyreason, reason);
1245                         if (b == RACE_NET_PENALTY_QUALIFYING)
1246                                 race_penaltyaccumulator += race_penaltytime;
1247                         break;
1248
1249                 case RACE_NET_SERVER_RECORD:
1250                         race_server_record = ReadInt24_t();
1251                         break;
1252                 case RACE_NET_SPEED_AWARD:
1253                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1254                         strcpy(race_speedaward_holder, ReadString());
1255                         break;
1256                 case RACE_NET_SPEED_AWARD_BEST:
1257                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1258                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1259                         break;
1260                 case RACE_NET_RANKINGS_CNT:
1261                         RANKINGS_DISPLAY_CNT = ReadByte();
1262                         break;
1263                 case RACE_NET_SERVER_RANKINGS:
1264                         float prevpos, del;
1265                         int pos = ReadShort();
1266                         prevpos = ReadShort();
1267                         del = ReadShort();
1268
1269                         // move other rankings out of the way
1270                         int i;
1271                         if (prevpos) {
1272                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1273                                 for (i=m-1; i>pos-1; --i) {
1274                                         grecordtime[i] = grecordtime[i-1];
1275                                         strcpy(grecordholder[i], grecordholder[i-1]);
1276                                 }
1277                         } else if (del) { // a record has been deleted by the admin
1278                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1279                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1280                                                 grecordtime[i] = 0;
1281                                                 strfree(grecordholder[i]);
1282                                         }
1283                                         else {
1284                                                 grecordtime[i] = grecordtime[i+1];
1285                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1286                                         }
1287                                 }
1288                         } else { // player has no ranked record yet
1289                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1290                                         grecordtime[i] = grecordtime[i-1];
1291                                         strcpy(grecordholder[i], grecordholder[i-1]);
1292                                 }
1293                         }
1294
1295                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1296                                 // kick off the player who fell from the last displayed position
1297                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1298                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1299                         }
1300
1301                         // store new ranking
1302                         strcpy(grecordholder[pos-1], ReadString());
1303                         grecordtime[pos-1] = ReadInt24_t();
1304                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1305                                 race_myrank = pos;
1306                         break;
1307                 case RACE_NET_SERVER_STATUS:
1308                         race_status = ReadShort();
1309                         strcpy(race_status_name, ReadString());
1310         }
1311         return true;
1312 }
1313
1314 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1315 {
1316         teamnagger = 1;
1317         return true;
1318 }
1319
1320 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1321 {
1322         int i = ReadByte();
1323         int pi = ReadShort();
1324         int pl = ReadByte();
1325         int ml = ReadByte();
1326         return = true;
1327         entity e = playerslots[i];
1328         if (!e) return;
1329         e.ping = pi;
1330         e.ping_packetloss = pl / 255.0;
1331         e.ping_movementloss = ml / 255.0;
1332 }
1333
1334 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1335 {
1336         int weapon_id = ReadByte();
1337         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1338         complain_weapon_type = ReadByte();
1339         return = true;
1340
1341         complain_weapon_time = time;
1342         weapontime = time; // ping the weapon panel
1343
1344         switch(complain_weapon_type)
1345         {
1346                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1347                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1348                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1349         }
1350 }
1351
1352 string translate_modifications(string s)
1353 {
1354         return build_mutator_list(s);
1355 }
1356
1357 string translate_weaponarena(string s)
1358 {
1359         if (s == "") return s;
1360         if (s == "All Weapons Arena") return _("All Weapons Arena");
1361         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1362         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1363         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1364         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1365         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1366         if (s == "No Weapons Arena") return _("No Weapons Arena");
1367
1368         int n = tokenizebyseparator(s, " & ");
1369         string wpn_list = "";
1370         for (int i = 0; i < n; i++)
1371         {
1372                 Weapon wep = Weapon_from_name(argv(i));
1373                 if (wep == WEP_Null)
1374                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1375                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1376         }
1377         if (wpn_list != "")
1378                 return sprintf(_("%s Arena"), wpn_list);
1379         else
1380                 return _("No Weapons Arena");
1381 }
1382
1383 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1384 {
1385         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1386         if (version_mismatch)
1387         {
1388                 if(!version_check)
1389                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1390                                 _("Your client version is outdated."), "\n\n\n",
1391                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1392                                 _("Please update!"));
1393                 else
1394                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1395                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1396                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1397         }
1398         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1399 }
1400
1401 bool net_handle_ServerWelcome()
1402 {
1403         bool campaign = ReadByte();
1404         if (campaign)
1405         {
1406                 string campaign_title = ReadString();
1407                 int campaign_level = ReadByte();
1408                 string campaign_msg = ReadString();
1409                 string welcomedialog_args;
1410                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1411                 string key = getcommandkey(_("jump"), "+jump");
1412                 string msg = strcat(
1413                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1414                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1415                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1416                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1417                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1418                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1419                 return true;
1420         }
1421
1422         strcpy(hostname, ReadString());
1423
1424         string hostversion = ReadString();
1425         bool version_mismatch = ReadByte();
1426         bool version_check = ReadByte();
1427         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1428
1429         string modifications = translate_modifications(ReadString());
1430         string weaponarena_list = translate_weaponarena(ReadString());
1431         string cache_mutatormsg = ReadString();
1432         string motd = ReadString();
1433
1434         string msg = "";
1435         msg = strcat(msg, ver);
1436         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1437
1438         modifications = cons_mid(modifications, ", ", weaponarena_list);
1439         if(modifications != "")
1440                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1441
1442         if (cache_mutatormsg != "")
1443                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1444         string mutator_msg = "";
1445         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1446         mutator_msg = M_ARGV(0, string);
1447         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1448
1449         if (motd != "")
1450                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1451
1452         strcpy(welcome_msg, msg);
1453         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1454         return true;
1455 }
1456
1457 void Welcome_Message_Show_Try()
1458 {
1459         if (!welcome_msg_menu_check_maxtime)
1460                 return;
1461
1462         // if want dialog check if menu is initialized but for a short time
1463         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1464         {
1465                 if (cvar("_menu_welcome_dialog_available"))
1466                 {
1467                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1468                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1469                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1470                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1471                         if (intermission || isdemo() || !autocvar_cl_welcome)
1472                                 // close it after it's been initialized so it can still be opened manually
1473                                 localcmd("\ntogglemenu 0\n");
1474                 }
1475
1476                 strfree(welcome_msg);
1477                 welcome_msg_menu_check_maxtime = 0;
1478         }
1479 }
1480
1481 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1482 {
1483         return net_handle_ServerWelcome();
1484 }
1485
1486 string _getcommandkey(string cmd_name, string command, bool forcename)
1487 {
1488         string keys;
1489         float n, j, k, l = 0;
1490
1491         if (!autocvar_hud_showbinds)
1492                 return cmd_name;
1493
1494         keys = db_get(binddb, command);
1495         if (keys == "")
1496         {
1497                 bool joy_active = cvar("joy_active");
1498                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1499                 for(j = 0; j < n; ++j)
1500                 {
1501                         k = stof(argv(j));
1502                         if(k != -1)
1503                         {
1504                                 string key = keynumtostring(k);
1505                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1506                                         continue;
1507
1508                                 key = translate_key(key);
1509
1510                                 if (keys == "")
1511                                         keys = key;
1512                                 else
1513                                         keys = strcat(keys, ", ", key);
1514
1515                                 ++l;
1516                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1517                                         break;
1518                         }
1519
1520                 }
1521                 if (keys == "")
1522                         keys = "NO_KEY";
1523                 db_put(binddb, command, keys);
1524         }
1525
1526         if (keys == "NO_KEY") {
1527                 if (autocvar_hud_showbinds > 1)
1528                         return sprintf(_("%s (not bound)"), cmd_name);
1529                 else
1530                         return cmd_name;
1531         }
1532         else if (autocvar_hud_showbinds > 1 || forcename)
1533                 return sprintf("%s (%s)", cmd_name, keys);
1534         else
1535                 return keys;
1536 }
1537
1538 /** engine callback */
1539 void URI_Get_Callback(int id, int status, string data)
1540 {
1541         TC(int, id); TC(int, status);
1542         if(url_URI_Get_Callback(id, status, data))
1543         {
1544                 // handled
1545         }
1546         else if (id == URI_GET_DISCARD)
1547         {
1548                 // discard
1549         }
1550         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1551         {
1552                 // sv_cmd curl
1553                 Curl_URI_Get_Callback(id, status, data);
1554         }
1555         else
1556         {
1557                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1558         }
1559 }