qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == world)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think(entity this)
 294 {
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         setthink(playerchecker, Playerchecker_Think);
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 355 {
 356     TC(int, bInputType);
 357         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         return false;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380
 381 void Ent_Remove(entity this);
 382
 383 void Ent_RemovePlayerScore(entity this)
 384 {
 385         if(this.owner) {
 386                 SetTeam(this.owner, -1);
 387                 this.owner.gotscores = 0;
 388                 for(int i = 0; i < MAX_SCORE; ++i) {
 389                         this.owner.(scores[i]) = 0; // clear all scores
 390                 }
 391         }
 392 }
 393
 394 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 395 {
 396         make_pure(this);
 397         int i, n;
 398         bool isNew;
 399         entity o;
 400
 401         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 402         // (no I've never heard of M-x replace-string, sed, or anything like that)
 403         isNew = !this.owner; // workaround for DP bug
 404         n = ReadByte()-1;
 405
 406 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 407         if(!isNew && n != this.sv_entnum)
 408         {
 409                 //print("A CSQC entity changed its owner!\n");
 410                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 411                 isNew = true;
 412                 Ent_Remove(this);
 413         }
 414 #endif
 415
 416         this.sv_entnum = n;
 417
 418         o = playerslots[this.sv_entnum];
 419         if (!o)
 420         {
 421                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 422         }
 423         this.owner = o;
 424         o.sv_entnum = this.sv_entnum;
 425         o.gotscores = 1;
 426
 427         //if (!o.sort_prev)
 428         //      RegisterPlayer(o);
 429         //playerchecker will do this for us later, if it has not already done so
 430
 431     int sf, lf;
 432 #if MAX_SCORE <= 8
 433         sf = ReadByte();
 434         lf = ReadByte();
 435 #else
 436         sf = ReadShort();
 437         lf = ReadShort();
 438 #endif
 439     int p;
 440         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 441                 if(sf & p)
 442                 {
 443                         if(lf & p)
 444                                 o.(scores[i]) = ReadInt24_t();
 445                         else
 446                                 o.(scores[i]) = ReadChar();
 447                 }
 448
 449         return = true;
 450
 451         if(o.sort_prev)
 452                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 453
 454         this.entremove = Ent_RemovePlayerScore;
 455 }
 456
 457 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 458 {
 459         make_pure(this);
 460         int i;
 461         entity o;
 462
 463         this.team = ReadByte();
 464         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 465
 466     int sf, lf;
 467 #if MAX_TEAMSCORE <= 8
 468         sf = ReadByte();
 469         lf = ReadByte();
 470 #else
 471         sf = ReadShort();
 472         lf = ReadShort();
 473 #endif
 474         int p;
 475         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 476                 if(sf & p)
 477                 {
 478                         if(lf & p)
 479                                 o.(teamscores[i]) = ReadInt24_t();
 480                         else
 481                                 o.(teamscores[i]) = ReadChar();
 482                 }
 483
 484         return = true;
 485
 486         HUD_UpdateTeamPos(o);
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 490 {
 491         make_pure(this);
 492         float newspectatee_status;
 493
 494     int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & 1);
 497
 498         if(f & 2)
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & 4);
 508
 509         if(f & 8)
 510         {
 511                 angles_held_status = 1;
 512                 angles_held.x = ReadAngle();
 513                 angles_held.y = ReadAngle();
 514                 angles_held.z = 0;
 515         }
 516         else
 517                 angles_held_status = 0;
 518
 519         return = true;
 520
 521         if(newspectatee_status != spectatee_status)
 522         {
 523                 // clear race stuff
 524                 race_laptime = 0;
 525                 race_checkpointtime = 0;
 526                 hud_dynamic_shake_factor = -1;
 527         }
 528         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 529         {
 530                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 531                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 532                 )
 533                         prev_p_health = -1;
 534                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 535                         prev_health = -1;
 536         }
 537         spectatee_status = newspectatee_status;
 538
 539         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 540 }
 541
 542 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 543 {
 544         make_pure(this);
 545     int i, j, b, f;
 546
 547     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 548
 549         if(!(nags & BIT(2)))
 550         {
 551                 if(vote_called_vote)
 552                         strunzone(vote_called_vote);
 553                 vote_called_vote = string_null;
 554                 vote_active = 0;
 555         }
 556         else
 557         {
 558                 vote_active = 1;
 559         }
 560
 561         if(nags & BIT(6))
 562         {
 563                 vote_yescount = ReadByte();
 564                 vote_nocount = ReadByte();
 565                 vote_needed = ReadByte();
 566                 vote_highlighted = ReadChar();
 567         }
 568
 569         if(nags & BIT(7))
 570         {
 571                 if(vote_called_vote)
 572                         strunzone(vote_called_vote);
 573                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 574         }
 575
 576         if(nags & 1)
 577         {
 578                 for(j = 0; j < maxclients; ++j)
 579                         if(playerslots[j])
 580                                 playerslots[j].ready = 1;
 581                 for(i = 1; i <= maxclients; i += 8)
 582                 {
 583                         f = ReadByte();
 584                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 585                                 if (!(f & b))
 586                                         if(playerslots[j])
 587                                                 playerslots[j].ready = 0;
 588                 }
 589         }
 590
 591         return = true;
 592
 593         ready_waiting = (nags & BIT(0));
 594         ready_waiting_for_me = (nags & BIT(1));
 595         vote_waiting = (nags & BIT(2));
 596         vote_waiting_for_me = (nags & BIT(3));
 597         warmup_stage = (nags & BIT(4));
 598 }
 599
 600 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 601 {
 602         make_pure(this);
 603     int i, j, b, f;
 604
 605     int sf = ReadByte();
 606         if(sf & 1)
 607         {
 608                 for(j = 0; j < maxclients; ++j)
 609                         if(playerslots[j])
 610                                 playerslots[j].eliminated = 1;
 611                 for(i = 1; i <= maxclients; i += 8)
 612                 {
 613                         f = ReadByte();
 614                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 615                                 if (!(f & b))
 616                                         if(playerslots[j])
 617                                                 playerslots[j].eliminated = 0;
 618                 }
 619         }
 620         return true;
 621 }
 622
 623 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 624 {
 625         make_pure(this);
 626         prandom_debug();
 627         float s = ReadShort();
 628         psrandom(s);
 629         return true;
 630 }
 631
 632 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 633 {
 634         make_pure(this);
 635     int sf = ReadInt24_t();
 636         if (sf == 0) {
 637                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 638                         weapon_accuracy[w] = -1;
 639                 return true;
 640         }
 641
 642         int f = 1;
 643         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 644                 if (sf & f) {
 645             int b = ReadByte();
 646                         if (b == 0)
 647                                 weapon_accuracy[w] = -1;
 648                         else if (b == 255)
 649                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 650                         else
 651                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 652                 }
 653                 f = (f == 0x800000) ? 1 : f * 2;
 654         }
 655         return true;
 656 }
 657
 658 void Spawn_Draw(entity this)
 659 {
 660         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 661 }
 662
 663 void Spawn_PreDraw(entity this)
 664 {
 665         float alph;
 666         vector org = getpropertyvec(VF_ORIGIN);
 667         if(this.fade_start)
 668                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 669         else
 670                 alph = 1;
 671         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 672         this.alpha = alph;
 673         if(alph <= 0)
 674                 this.drawmask = 0;
 675         else
 676                 this.drawmask = MASK_NORMAL;
 677 }
 678
 679 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 680 {
 681         float teamnum = (ReadByte() - 1);
 682         vector spn_origin;
 683         spn_origin.x = ReadCoord();
 684         spn_origin.y = ReadCoord();
 685         spn_origin.z = ReadCoord();
 686
 687         //if(is_new)
 688         //{
 689                 this.origin = spn_origin;
 690                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 691                 //droptofloor();
 692
 693                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 694                 {
 695                         this.mdl = "models/spawnpoint.md3";
 696                         this.colormod = Team_ColorRGB(teamnum);
 697                         precache_model(this.mdl);
 698                         setmodel(this, this.mdl);
 699                         this.drawmask = MASK_NORMAL;
 700                         //this.movetype = MOVETYPE_NOCLIP;
 701                         //this.draw = Spawn_Draw;
 702                 }*/
 703                 if(autocvar_cl_spawn_point_particles)
 704                 {
 705                         if((serverflags & SERVERFLAG_TEAMPLAY))
 706                         {
 707                                 switch(teamnum)
 708                                 {
 709                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 710                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 711                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 712                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 713                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 714                                 }
 715                         }
 716                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 717
 718                         this.draw = Spawn_Draw;
 719                         setpredraw(this, Spawn_PreDraw);
 720                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 721                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 722                 }
 723         //}
 724
 725         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 726         return true;
 727 }
 728
 729 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 730 {
 731         // If entnum is 0, ONLY do the local spawn actions
 732         // this way the server can disable the sending of
 733         // spawn origin or such to clients if wanted.
 734         float entnum = ReadByte();
 735
 736         if(entnum)
 737         {
 738                 this.origin_x = ReadCoord();
 739                 this.origin_y = ReadCoord();
 740                 this.origin_z = ReadCoord();
 741
 742                 if(is_new)
 743                 {
 744                         float teamnum = entcs_GetTeam(entnum - 1);
 745
 746                         if(autocvar_cl_spawn_event_particles)
 747                         {
 748                                 switch(teamnum)
 749                                 {
 750                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 751                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 752                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 753                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 754                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 755                                 }
 756                         }
 757                         if(autocvar_cl_spawn_event_sound)
 758                         {
 759                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 760                         }
 761                 }
 762         }
 763         return = true;
 764
 765         // local spawn actions
 766         if(is_new && (!entnum || (entnum == player_localentnum)))
 767         {
 768                 zoomin_effect = 1;
 769                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 770
 771                 if(autocvar_cl_unpress_zoom_on_spawn)
 772                 {
 773                         localcmd("-zoom\n");
 774                         button_zoom = false;
 775                 }
 776         }
 777         HUD_Radar_Hide_Maximized();
 778         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 779 }
 780
 781 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 782 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 783 void CSQC_Ent_Update(bool isnew)
 784 {
 785         SELFPARAM();
 786         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 787         int t = ReadByte();
 788
 789         // set up the "time" global for received entities to be correct for interpolation purposes
 790         float savetime = time;
 791         if(servertime)
 792         {
 793                 time = servertime;
 794         }
 795         else
 796         {
 797                 serverprevtime = time;
 798                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 799                 time = serverprevtime + serverdeltatime;
 800         }
 801
 802 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 803         if (this.enttype)
 804         {
 805                 if (t != this.enttype || isnew)
 806                 {
 807                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 808                         Ent_Remove(this);
 809                         clearentity(this);
 810                         isnew = true;
 811                 }
 812         }
 813         else
 814         {
 815                 if (!isnew)
 816                 {
 817                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 818                         isnew = true;
 819                 }
 820         }
 821 #endif
 822         this.enttype = t;
 823         bool done = false;
 824         FOREACH(LinkedEntities, it.m_id == t, {
 825                 if (isnew) this.classname = it.netname;
 826                 if (autocvar_developer_csqcentities)
 827             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 828                 done = it.m_read(this, NULL, isnew);
 829                 break;
 830         });
 831         time = savetime;
 832         if (!done)
 833         {
 834                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 835         }
 836 }
 837
 838 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 839 // used when an entity changes its type. For an entity that someone interacts
 840 // with others, make sure it can no longer do so.
 841 void Ent_Remove(entity this)
 842 {
 843         if(this.entremove) this.entremove(this);
 844
 845         if(this.skeletonindex)
 846         {
 847                 skel_delete(this.skeletonindex);
 848                 this.skeletonindex = 0;
 849         }
 850
 851         if(this.snd_looping > 0)
 852         {
 853                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 854                 this.snd_looping = 0;
 855         }
 856
 857         this.enttype = 0;
 858         this.classname = "";
 859         this.draw = func_null;
 860         this.entremove = func_null;
 861         // TODO possibly set more stuff to defaults
 862 }
 863 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 864 void CSQC_Ent_Remove()
 865 {
 866         SELFPARAM();
 867         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 868         if (wasfreed(this))
 869         {
 870                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 871                 return;
 872         }
 873         if (this.enttype) Ent_Remove(this);
 874         remove(this);
 875 }
 876
 877 void Gamemode_Init()
 878 {
 879         if (!isdemo())
 880         {
 881                 if(!(calledhooks & HOOK_START))
 882                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 883                 calledhooks |= HOOK_START;
 884         }
 885 }
 886 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 887 void CSQC_Parse_StuffCmd(string strMessage)
 888 {
 889         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 890         localcmd(strMessage);
 891 }
 892 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 893 void CSQC_Parse_Print(string strMessage)
 894 {
 895         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 896         print(ColorTranslateRGB(strMessage));
 897 }
 898
 899 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 900 void CSQC_Parse_CenterPrint(string strMessage)
 901 {
 902         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 903         centerprint_hud(strMessage);
 904 }
 905
 906 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 907 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 908 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 909 bool CSQC_Parse_TempEntity()
 910 {
 911         // Acquire TE ID
 912         int nTEID = ReadByte();
 913
 914         FOREACH(TempEntities, it.m_id == nTEID, {
 915                 if (autocvar_developer_csqcentities)
 916                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 917                 return it.m_read(NULL, NULL, true);
 918         });
 919
 920         if (autocvar_developer_csqcentities)
 921                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 922
 923         // No special logic for this temporary entity; return 0 so the engine can handle it
 924         return false;
 925 }
 926
 927 string forcefog;
 928 void Fog_Force()
 929 {
 930         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 931                 localcmd("\nr_drawfog 0\n");
 932         else if (forcefog != "")
 933                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 934 }
 935
 936 void Gamemode_Init();
 937 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 938 {
 939         make_pure(this);
 940         gametype = ReadInt24_t();
 941         HUD_ModIcons_SetFunc();
 942         for (int i = 0; i < MAX_SCORE; ++i)
 943         {
 944                 if (scores_label[i]) strunzone(scores_label[i]);
 945                 scores_label[i] = strzone(ReadString());
 946                 scores_flags[i] = ReadByte();
 947         }
 948         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 949         {
 950                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 951                 teamscores_label[i] = strzone(ReadString());
 952                 teamscores_flags[i] = ReadByte();
 953         }
 954         return = true;
 955         HUD_InitScores();
 956         Gamemode_Init();
 957 }
 958
 959 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 960 {
 961         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 962
 963         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 966         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 967         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 971
 972         if (forcefog) strunzone(forcefog);
 973         forcefog = strzone(ReadString());
 974
 975         armorblockpercent = ReadByte() / 255.0;
 976
 977         serverflags = ReadByte();
 978
 979         g_trueaim_minrange = ReadCoord();
 980
 981         return = true;
 982
 983         MUTATOR_CALLHOOK(Ent_Init);
 984
 985         if (!postinit) PostInit();
 986 }
 987
 988 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 989 {
 990         int b = ReadByte();
 991
 992         switch (b)
 993         {
 994                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 995                         race_checkpoint = ReadByte();
 996                         race_time = ReadInt24_t();
 997                         race_previousbesttime = ReadInt24_t();
 998                         if(race_previousbestname)
 999                                 strunzone(race_previousbestname);
1000                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1001
1002                         race_checkpointtime = time;
1003
1004                         if(race_checkpoint == 0 || race_checkpoint == 254)
1005                         {
1006                                 race_penaltyaccumulator = 0;
1007                                 race_laptime = time; // valid
1008                         }
1009
1010                         break;
1011
1012                 case RACE_NET_CHECKPOINT_CLEAR:
1013                         race_laptime = 0;
1014                         race_checkpointtime = 0;
1015                         break;
1016
1017                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1018                         race_laptime = ReadCoord();
1019                         race_checkpointtime = -99999;
1020                         // fall through
1021                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1022                         race_nextcheckpoint = ReadByte();
1023
1024                         race_nextbesttime = ReadInt24_t();
1025                         if(race_nextbestname)
1026                                 strunzone(race_nextbestname);
1027                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1028                         break;
1029
1030                 case RACE_NET_CHECKPOINT_HIT_RACE:
1031                         race_mycheckpoint = ReadByte();
1032                         race_mycheckpointtime = time;
1033                         race_mycheckpointdelta = ReadInt24_t();
1034                         race_mycheckpointlapsdelta = ReadByte();
1035                         if(race_mycheckpointlapsdelta >= 128)
1036                                 race_mycheckpointlapsdelta -= 256;
1037                         if(race_mycheckpointenemy)
1038                                 strunzone(race_mycheckpointenemy);
1039                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1040                         break;
1041
1042                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1043                         race_othercheckpoint = ReadByte();
1044                         race_othercheckpointtime = time;
1045                         race_othercheckpointdelta = ReadInt24_t();
1046                         race_othercheckpointlapsdelta = ReadByte();
1047                         if(race_othercheckpointlapsdelta >= 128)
1048                                 race_othercheckpointlapsdelta -= 256;
1049                         if(race_othercheckpointenemy)
1050                                 strunzone(race_othercheckpointenemy);
1051                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1052                         break;
1053
1054                 case RACE_NET_PENALTY_RACE:
1055                         race_penaltyeventtime = time;
1056                         race_penaltytime = ReadShort();
1057                         //race_penaltyaccumulator += race_penaltytime;
1058                         if(race_penaltyreason)
1059                                 strunzone(race_penaltyreason);
1060                         race_penaltyreason = strzone(ReadString());
1061                         break;
1062
1063                 case RACE_NET_PENALTY_QUALIFYING:
1064                         race_penaltyeventtime = time;
1065                         race_penaltytime = ReadShort();
1066                         race_penaltyaccumulator += race_penaltytime;
1067                         if(race_penaltyreason)
1068                                 strunzone(race_penaltyreason);
1069                         race_penaltyreason = strzone(ReadString());
1070                         break;
1071
1072                 case RACE_NET_SERVER_RECORD:
1073                         race_server_record = ReadInt24_t();
1074                         break;
1075                 case RACE_NET_SPEED_AWARD:
1076                         race_speedaward = ReadInt24_t();
1077                         if(race_speedaward_holder)
1078                                 strunzone(race_speedaward_holder);
1079                         race_speedaward_holder = strzone(ReadString());
1080                         break;
1081                 case RACE_NET_SPEED_AWARD_BEST:
1082                         race_speedaward_alltimebest = ReadInt24_t();
1083                         if(race_speedaward_alltimebest_holder)
1084                                 strunzone(race_speedaward_alltimebest_holder);
1085                         race_speedaward_alltimebest_holder = strzone(ReadString());
1086                         break;
1087                 case RACE_NET_SERVER_RANKINGS:
1088                         float prevpos, del;
1089             int pos = ReadShort();
1090                         prevpos = ReadShort();
1091                         del = ReadShort();
1092
1093                         // move other rankings out of the way
1094             int i;
1095                         if (prevpos) {
1096                                 for (i=prevpos-1;i>pos-1;--i) {
1097                                         grecordtime[i] = grecordtime[i-1];
1098                                         if(grecordholder[i])
1099                                                 strunzone(grecordholder[i]);
1100                                         grecordholder[i] = strzone(grecordholder[i-1]);
1101                                 }
1102                         } else if (del) { // a record has been deleted by the admin
1103                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1104                                         if (i == RANKINGS_CNT-1) { // clear out last record
1105                                                 grecordtime[i] = 0;
1106                                                 if (grecordholder[i])
1107                                                         strunzone(grecordholder[i]);
1108                                                 grecordholder[i] = string_null;
1109                                         }
1110                                         else {
1111                                                 grecordtime[i] = grecordtime[i+1];
1112                                                 if (grecordholder[i])
1113                                                         strunzone(grecordholder[i]);
1114                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1115                                         }
1116                                 }
1117                         } else { // player has no ranked record yet
1118                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1119                                         grecordtime[i] = grecordtime[i-1];
1120                                         if(grecordholder[i])
1121                                                 strunzone(grecordholder[i]);
1122                                         grecordholder[i] = strzone(grecordholder[i-1]);
1123                                 }
1124                         }
1125
1126                         // store new ranking
1127                         if(grecordholder[pos-1] != "")
1128                                 strunzone(grecordholder[pos-1]);
1129                         grecordholder[pos-1] = strzone(ReadString());
1130                         grecordtime[pos-1] = ReadInt24_t();
1131                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1132                                 race_myrank = pos;
1133                         break;
1134                 case RACE_NET_SERVER_STATUS:
1135                         race_status = ReadShort();
1136                         if(race_status_name)
1137                                 strunzone(race_status_name);
1138                         race_status_name = strzone(ReadString());
1139         }
1140         return true;
1141 }
1142
1143 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1144 {
1145         teamnagger = 1;
1146         return true;
1147 }
1148
1149 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1150 {
1151         int i = ReadByte();
1152         int pi = ReadShort();
1153         int pl = ReadByte();
1154         int ml = ReadByte();
1155         return = true;
1156         entity e = playerslots[i];
1157         if (!e) return;
1158         e.ping = pi;
1159         e.ping_packetloss = pl / 255.0;
1160         e.ping_movementloss = ml / 255.0;
1161 }
1162
1163 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1164 {
1165         complain_weapon = ReadByte();
1166         complain_weapon_type = ReadByte();
1167         return = true;
1168
1169         complain_weapon_time = time;
1170         weapontime = time; // ping the weapon panel
1171
1172         switch(complain_weapon_type)
1173         {
1174                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1175                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1176                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1177         }
1178 }
1179
1180 string getcommandkey(string text, string command)
1181 {
1182         string keys;
1183         float n, j, k, l = 0;
1184
1185         if (!autocvar_hud_showbinds)
1186                 return text;
1187
1188         keys = db_get(binddb, command);
1189         if (keys == "")
1190         {
1191                 bool joy_detected = cvar("joy_detected");
1192                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1193                 for(j = 0; j < n; ++j)
1194                 {
1195                         k = stof(argv(j));
1196                         if(k != -1)
1197                         {
1198                                 string key = keynumtostring(k);
1199                                 if(!joy_detected && substring(key, 0, 3) == "JOY")
1200                                         continue;
1201
1202                                 if (keys == "")
1203                                         keys = key;
1204                                 else
1205                                         keys = strcat(keys, ", ", key);
1206
1207                                 ++l;
1208                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1209                                         break;
1210                         }
1211
1212                 }
1213                 if (keys == "")
1214                         keys = "NO_KEY";
1215                 db_put(binddb, command, keys);
1216         }
1217
1218         if (keys == "NO_KEY") {
1219                 if (autocvar_hud_showbinds > 1)
1220                         return sprintf(_("%s (not bound)"), text);
1221                 else
1222                         return text;
1223         }
1224         else if (autocvar_hud_showbinds > 1)
1225                 return sprintf("%s (%s)", text, keys);
1226         else
1227                 return keys;
1228 }