qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         ReplicateVars(REPLICATEVARS_SEND_ALL);
  62
  63         // needs to be done so early because of the constants they create
  64         static_init();
  65         static_init_late();
  66         static_init_precache();
  67
  68         binddb = db_create();
  69         tempdb = db_create();
  70         ClientProgsDB = db_load("client.db");
  71
  72         draw_endBoldFont();
  73
  74         //registercommand("hud_configure");
  75         //registercommand("hud_save");
  76         //registercommand("menu_action");
  77
  78         ConsoleCommand_macro_init();
  79
  80         registercvar("hud_usecsqc", "1");
  81         registercvar("scoreboard_columns", "default");
  82
  83         registercvar("cl_nade_type", "3");
  84         registercvar("cl_pokenade_type", "zombie");
  85
  86         registercvar("cl_jumpspeedcap_min", "");
  87         registercvar("cl_jumpspeedcap_max", "");
  88
  89         registercvar("cl_shootfromfixedorigin", "");
  90
  91         registercvar("cl_multijump", "-1");
  92
  93         registercvar("cl_dodging", "0");
  94
  95         registercvar("cl_spawn_near_teammate", "1");
  96
  97         registercvar("cl_weapon_switch_reload", "1");
  98         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  99
 100         registercvar("cl_allow_uidranking", "1");
 101
 102         if(autocvar_cl_lockview)
 103                 cvar_set("cl_lockview", "0");
 104
 105         gametype = NULL;
 106
 107         postinit = false;
 108
 109         calledhooks = 0;
 110
 111         teams = Sort_Spawn();
 112         players = Sort_Spawn();
 113
 114         GetTeam(NUM_SPECTATOR, true); // add specs first
 115
 116         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 117                 weapon_accuracy[w] = -1;
 118
 119         // precaches
 120
 121         if(autocvar_cl_reticle)
 122         {
 123                 precache_pic("gfx/reticle_normal");
 124                 // weapon reticles are precached in weapon files
 125         }
 126
 127         {
 128                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 129                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 130                 shortmapname = mi_shortname;
 131
 132                 if (precache_pic(minimapname) == "")
 133                 {
 134                         // but maybe we have a non-clever minimap
 135                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 136                         if (precache_pic(minimapname) == "")
 137                                 minimapname = ""; // FAIL
 138                         else
 139                                 get_mi_min_max_texcoords(0); // load new texcoords
 140                 }
 141
 142                 mi_center = (mi_min + mi_max) * 0.5;
 143                 mi_scale = mi_max - mi_min;
 144                 minimapname = strzone(minimapname);
 145         }
 146
 147         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 148         LoadMenuSkinValues();
 149 }
 150
 151 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 152 void Shutdown()
 153 {
 154         WarpZone_Shutdown();
 155
 156         delete(teams);
 157         delete(players);
 158         db_close(binddb);
 159         db_close(tempdb);
 160         if(autocvar_cl_db_saveasdump)
 161                 db_dump(ClientProgsDB, "client.db");
 162         else
 163                 db_save(ClientProgsDB, "client.db");
 164         db_close(ClientProgsDB);
 165
 166         if(camera_active)
 167                 cvar_set("chase_active",ftos(chase_active_backup));
 168
 169         // unset the event chasecam's chase_active
 170         if(autocvar_chase_active < 0)
 171                 cvar_set("chase_active", "0");
 172
 173         if (autocvar_r_drawviewmodel < 0)
 174                 cvar_set("r_drawviewmodel", "0");
 175
 176         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 177
 178         if (!isdemo())
 179         {
 180                 if (!(calledhooks & HOOK_START))
 181                         localcmd("\n_cl_hook_gamestart nop\n");
 182                 if (!(calledhooks & HOOK_END))
 183                         localcmd("\ncl_hook_gameend\n");
 184         }
 185
 186         localcmd("\ncl_hook_shutdown\n");
 187
 188         localcmd("\n-button12\n");
 189
 190         deactivate_minigame();
 191         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 192
 193         ReplicateVars(REPLICATEVARS_DESTROY);
 194 }
 195
 196 void AuditLists()
 197 {
 198         entity e;
 199         entity prev;
 200
 201         prev = players;
 202         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 203         {
 204                 if(prev != e.sort_prev)
 205                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 206         }
 207
 208         prev = teams;
 209         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 210         {
 211                 if(prev != e.sort_prev)
 212                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 213         }
 214 }
 215
 216 float RegisterPlayer(entity player)
 217 {
 218         entity pl;
 219         AuditLists();
 220         for(pl = players.sort_next; pl; pl = pl.sort_next)
 221                 if(pl == player)
 222                         error("Player already registered!");
 223         player.sort_next = players.sort_next;
 224         player.sort_prev = players;
 225         if(players.sort_next)
 226                 players.sort_next.sort_prev = player;
 227         players.sort_next = player;
 228         AuditLists();
 229         return true;
 230 }
 231
 232 void RemovePlayer(entity player)
 233 {
 234         entity pl, parent;
 235         AuditLists();
 236         parent = players;
 237         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 238                 parent = pl;
 239
 240         if(!pl)
 241         {
 242                 error("Trying to remove a player which is not in the playerlist!");
 243                 return;
 244         }
 245         parent.sort_next = player.sort_next;
 246         if(player.sort_next)
 247                 player.sort_next.sort_prev = parent;
 248         AuditLists();
 249 }
 250
 251 void MoveToLast(entity e)
 252 {
 253         AuditLists();
 254         entity ent = e.sort_next;
 255         while(ent)
 256         {
 257                 SORT_SWAP(ent, e);
 258                 ent = e.sort_next;
 259         }
 260         AuditLists();
 261 }
 262
 263 float RegisterTeam(entity Team)
 264 {
 265         assert_once(Team.team, eprint(Team));
 266         entity tm;
 267         AuditLists();
 268         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 269                 if(tm == Team)
 270                         error("Team already registered!");
 271         Team.sort_next = teams.sort_next;
 272         Team.sort_prev = teams;
 273         if(teams.sort_next)
 274                 teams.sort_next.sort_prev = Team;
 275         teams.sort_next = Team;
 276         if(Team.team && Team.team != NUM_SPECTATOR)
 277                 ++team_count;
 278         AuditLists();
 279         return true;
 280 }
 281
 282 void RemoveTeam(entity Team)
 283 {
 284         entity tm, parent;
 285         AuditLists();
 286         parent = teams;
 287         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 288                 parent = tm;
 289
 290         if(!tm)
 291         {
 292                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 293                 return;
 294         }
 295         parent.sort_next = Team.sort_next;
 296         if(Team.sort_next)
 297                 Team.sort_next.sort_prev = parent;
 298         if(Team.team && Team.team != NUM_SPECTATOR)
 299                 --team_count;
 300         AuditLists();
 301 }
 302
 303 entity GetTeam(int Team, bool add)
 304 {
 305         TC(int, Team); TC(bool, add);
 306         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 307         if(teamslots[num])
 308                 return teamslots[num];
 309         if (!add)
 310                 return NULL;
 311         entity tm = new_pure(team);
 312         tm.team = Team;
 313         teamslots[num] = tm;
 314         RegisterTeam(tm);
 315         return tm;
 316 }
 317
 318 .float has_team;
 319 bool SetTeam(entity o, int Team)
 320 {
 321         TC(int, Team);
 322         //devassert_once(Team);
 323         entity tm;
 324         if(teamplay)
 325         {
 326                 switch(Team)
 327                 {
 328                         case -1:
 329                         case NUM_TEAM_1:
 330                         case NUM_TEAM_2:
 331                         case NUM_TEAM_3:
 332                         case NUM_TEAM_4:
 333                                 break;
 334                         default:
 335                                 if(GetTeam(Team, false) == NULL)
 336                                 {
 337                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 338                                         Team = NUM_SPECTATOR;
 339                                 }
 340                                 break;
 341                 }
 342         }
 343         else
 344         {
 345                 switch(Team)
 346                 {
 347                         case -1:
 348                         case 0:
 349                                 break;
 350                         default:
 351                                 if(GetTeam(Team, false) == NULL)
 352                                 {
 353                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 354                                         Team = NUM_SPECTATOR;
 355                                 }
 356                                 break;
 357                 }
 358         }
 359         if(Team == -1) // leave
 360         {
 361                 if(o.has_team)
 362                 {
 363                         tm = GetTeam(o.team, false);
 364                         tm.team_size -= 1;
 365                         o.has_team = 0;
 366                         return true;
 367                 }
 368         }
 369         else
 370         {
 371                 if (!o.has_team)
 372                 {
 373                         o.team = Team;
 374                         tm = GetTeam(Team, true);
 375                         tm.team_size += 1;
 376                         o.has_team = 1;
 377                         return true;
 378                 }
 379                 else if(Team != o.team)
 380                 {
 381                         tm = GetTeam(o.team, false);
 382                         tm.team_size -= 1;
 383                         o.team = Team;
 384                         tm = GetTeam(Team, true);
 385                         tm.team_size += 1;
 386                         return true;
 387                 }
 388         }
 389         return false;
 390 }
 391
 392 void Playerchecker_Think(entity this)
 393 {
 394         int i;
 395         entity e;
 396         for(i = 0; i < maxclients; ++i)
 397         {
 398                 e = playerslots[i];
 399                 if(entcs_GetName(i) == "")
 400                 {
 401                         if(e.sort_prev)
 402                         {
 403                                 // player disconnected
 404                                 SetTeam(e, -1);
 405                                 RemovePlayer(e);
 406                                 e.sort_prev = NULL;
 407                                 //e.gotscores = 0;
 408                         }
 409                 }
 410                 else
 411                 {
 412                         if (!e.sort_prev)
 413                         {
 414                                 // player connected
 415                                 if (!e)
 416                                 {
 417                                         playerslots[i] = e = new_pure(playerslot);
 418                                 }
 419                                 e.sv_entnum = i;
 420                                 e.ping = 0;
 421                                 e.ping_packetloss = 0;
 422                                 e.ping_movementloss = 0;
 423                                 //e.gotscores = 0; // we might already have the scores...
 424                                 int t = entcs_GetScoreTeam(i);
 425                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 426                                 RegisterPlayer(e);
 427                                 Scoreboard_UpdatePlayerPos(e);
 428                         }
 429                 }
 430         }
 431         this.nextthink = time + 0.2;
 432 }
 433
 434 void PostInit()
 435 {
 436         entity playerchecker = new_pure(playerchecker);
 437         setthink(playerchecker, Playerchecker_Think);
 438         playerchecker.nextthink = time + 0.2;
 439
 440         TrueAim_Init();
 441
 442         postinit = true;
 443 }
 444
 445 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 446 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 447 // All keys are in ascii.
 448 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 449 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 450 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 451 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 452 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 453 {
 454         TC(int, bInputType);
 455         bool override = false;
 456
 457         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 458         if (override)
 459                 return true;
 460
 461         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 466
 467         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 468
 469         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 470
 471         if(override)
 472                 return true;
 473
 474         if(bInputType == 3 || bInputType == 2)
 475                 return false;
 476
 477         // at this point bInputType can only be 0 or 1 (key pressed or released)
 478         bool key_pressed = (bInputType == 0);
 479
 480         if(key_pressed) {
 481                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 482                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 483                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 484         }
 485         else {
 486                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 487                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 488                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 489         }
 490
 491         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 492         {
 493                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 494                 {
 495                         localcmd("\nmenu_showgamemenudialog\n");
 496                         return true;
 497                 }
 498         }
 499
 500         return false;
 501 }
 502
 503 // END REQUIRED CSQC FUNCTIONS
 504 // --------------------------------------------------------------------------
 505
 506 // --------------------------------------------------------------------------
 507 // BEGIN OPTIONAL CSQC FUNCTIONS
 508
 509 void Ent_RemovePlayerScore(entity this)
 510 {
 511         if(this.owner) {
 512                 SetTeam(this.owner, -1);
 513                 this.owner.gotscores = 0;
 514                 FOREACH(Scores, true, {
 515                         this.owner.(scores(it)) = 0; // clear all scores
 516                 });
 517         }
 518 }
 519
 520 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 521 {
 522         make_pure(this);
 523         entity o;
 524
 525         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 526         // (no I've never heard of M-x replace-string, sed, or anything like that)
 527         bool isNew = !this.owner; // workaround for DP bug
 528         int n = ReadByte()-1;
 529
 530 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 531         if(!isNew && n != this.sv_entnum)
 532         {
 533                 //print("A CSQC entity changed its owner!\n");
 534                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 535                 isNew = true;
 536                 Ent_Remove(this);
 537         }
 538 #endif
 539
 540         this.sv_entnum = n;
 541
 542         o = playerslots[this.sv_entnum];
 543         if (!o)
 544         {
 545                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 546         }
 547         this.owner = o;
 548         o.sv_entnum = this.sv_entnum;
 549         o.gotscores = 1;
 550
 551         //if (!o.sort_prev)
 552         //      RegisterPlayer(o);
 553         //playerchecker will do this for us later, if it has not already done so
 554
 555         int sf = ReadShort();
 556         int lf = ReadShort();
 557         FOREACH(Scores, true, {
 558                 int p = 1 << (i % 16);
 559                 if (sf & p)
 560                 {
 561                         if (lf & p)
 562                                 o.(scores(it)) = ReadInt24_t();
 563                         else
 564                                 o.(scores(it)) = ReadChar();
 565                 }
 566         });
 567
 568         return = true;
 569
 570         if(o.sort_prev)
 571                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 572
 573         this.entremove = Ent_RemovePlayerScore;
 574 }
 575
 576 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 577 {
 578         make_pure(this);
 579         int i;
 580
 581         this.team = ReadByte();
 582         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 583
 584 #if MAX_TEAMSCORE <= 8
 585         int sf = ReadByte();
 586         int lf = ReadByte();
 587 #else
 588         int sf = ReadShort();
 589         int lf = ReadShort();
 590 #endif
 591         for(i = 0; i < MAX_TEAMSCORE; ++i)
 592                 if(sf & BIT(i))
 593                 {
 594                         if(lf & BIT(i))
 595                                 o.(teamscores(i)) = ReadInt24_t();
 596                         else
 597                                 o.(teamscores(i)) = ReadChar();
 598                 }
 599
 600         return = true;
 601
 602         Scoreboard_UpdateTeamPos(o);
 603 }
 604
 605 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 606 {
 607         make_pure(this);
 608         float newspectatee_status;
 609
 610         int f = ReadByte();
 611
 612         scoreboard_showscores_force = (f & BIT(0));
 613
 614         if(f & BIT(1))
 615         {
 616                 newspectatee_status = ReadByte();
 617                 if(newspectatee_status == player_localnum + 1)
 618                         newspectatee_status = -1; // observing
 619         }
 620         else
 621                 newspectatee_status = 0;
 622
 623         spectatorbutton_zoom = (f & BIT(2));
 624
 625         if(f & BIT(4))
 626         {
 627                 num_spectators = ReadByte();
 628
 629                 float i, slot;
 630
 631                 for(i = 0; i < MAX_SPECTATORS; ++i)
 632                         spectatorlist[i] = 0; // reset list first
 633
 634                 int limit = min(num_spectators, MAX_SPECTATORS);
 635                 for(i = 0; i < limit; ++i)
 636                 {
 637                         slot = ReadByte();
 638                         spectatorlist[i] = slot - 1;
 639                 }
 640         }
 641         else
 642         {
 643                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 644                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 645                 num_spectators = 0;
 646         }
 647
 648         return = true;
 649
 650         if(newspectatee_status != spectatee_status)
 651         {
 652                 // clear race stuff
 653                 race_laptime = 0;
 654                 race_checkpointtime = 0;
 655                 hud_dynamic_shake_factor = -1;
 656                 spectatee_status_changed_time = time;
 657         }
 658         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 659         {
 660                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 661                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 662                 )
 663                         prev_p_health = -1;
 664                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 665                         prev_health = -1;
 666         }
 667         spectatee_status = newspectatee_status;
 668
 669         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 670 }
 671
 672 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 673 {
 674         make_pure(this);
 675         int i, j, b, f;
 676
 677         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 678
 679         if(!(nags & BIT(2)))
 680         {
 681                 strfree(vote_called_vote);
 682                 vote_active = 0;
 683         }
 684         else
 685         {
 686                 vote_active = 1;
 687         }
 688
 689         if(nags & BIT(6))
 690         {
 691                 vote_yescount = ReadByte();
 692                 vote_nocount = ReadByte();
 693                 vote_needed = ReadByte();
 694                 vote_highlighted = ReadChar();
 695         }
 696
 697         if(nags & BIT(7))
 698         {
 699                 strcpy(vote_called_vote, ReadString());
 700         }
 701
 702         if(nags & 1)
 703         {
 704                 for(j = 0; j < maxclients; ++j)
 705                         if(playerslots[j])
 706                                 playerslots[j].ready = true;
 707                 for(i = 1; i <= maxclients; i += 8)
 708                 {
 709                         f = ReadByte();
 710                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 711                                 if (!(f & b))
 712                                         if(playerslots[j])
 713                                                 playerslots[j].ready = false;
 714                 }
 715         }
 716
 717         return = true;
 718
 719         ready_waiting = (nags & BIT(0));
 720         ready_waiting_for_me = (nags & BIT(1));
 721         vote_waiting = (nags & BIT(2));
 722         vote_waiting_for_me = (nags & BIT(3));
 723         warmup_stage = (nags & BIT(4));
 724 }
 725
 726 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 727 {
 728         make_pure(this);
 729         int sf = 0;
 730         serialize(byte, 0, sf);
 731         if (sf & 1) {
 732                 for (int j = 0; j < maxclients; ++j) {
 733                         if (playerslots[j]) {
 734                                 playerslots[j].eliminated = true;
 735                         }
 736                 }
 737                 for (int i = 1; i <= maxclients; i += 8) {
 738                         int f = 0;
 739                         serialize(byte, 0, f);
 740                         for (int b = 0; b < 8; ++b) {
 741                                 if (f & BIT(b)) continue;
 742                                 int j = i - 1 + b;
 743                                 if (playerslots[j]) {
 744                                         playerslots[j].eliminated = false;
 745                                 }
 746                         }
 747                 }
 748         }
 749         return true;
 750 }
 751
 752 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 753 {
 754         make_pure(this);
 755         prandom_debug();
 756         float s = ReadShort();
 757         psrandom(s);
 758         return true;
 759 }
 760
 761 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 762 {
 763         make_pure(this);
 764         int sf = ReadInt24_t();
 765         if (sf == 0) {
 766                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 767                         weapon_accuracy[w] = -1;
 768                 return true;
 769         }
 770
 771         int f = 1;
 772         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 773                 if (sf & f) {
 774                         int b = ReadByte();
 775                         if (b == 0)
 776                                 weapon_accuracy[w] = -1;
 777                         else if (b == 255)
 778                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 779                         else
 780                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 781                 }
 782                 f = (f == 0x800000) ? 1 : f * 2;
 783         }
 784         return true;
 785 }
 786
 787 void Spawn_Draw(entity this)
 788 {
 789         bool dodraw = autocvar_cl_spawn_point_particles;
 790         if(dodraw && autocvar_cl_spawn_point_dist_max)
 791         {
 792                 vector org = getpropertyvec(VF_ORIGIN);
 793                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 794         }
 795
 796         if(dodraw)
 797                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 798 }
 799
 800 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 801 {
 802         float teamnum = (ReadByte() - 1);
 803         vector spn_origin = ReadVector();
 804
 805         this.team = (teamnum + 1);
 806
 807         //if(is_new)
 808         //{
 809                 this.origin = spn_origin;
 810                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 811                 //droptofloor();
 812
 813                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 814                 {
 815                         this.mdl = "models/spawnpoint.md3";
 816                         this.colormod = Team_ColorRGB(teamnum);
 817                         precache_model(this.mdl);
 818                         setmodel(this, this.mdl);
 819                         this.drawmask = MASK_NORMAL;
 820                         //this.move_movetype = MOVETYPE_NOCLIP;
 821                         //this.draw = Spawn_Draw;
 822                         IL_PUSH(g_drawables, this);
 823                 }*/
 824                 this.draw = Spawn_Draw;
 825                 if (is_new) IL_PUSH(g_drawables, this);
 826         //}
 827
 828         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 829         return true;
 830 }
 831
 832 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 833 {
 834         // If entnum is 0, ONLY do the local spawn actions
 835         // this way the server can disable the sending of
 836         // spawn origin or such to clients if wanted.
 837         float entnum = ReadByte();
 838
 839         if(entnum)
 840         {
 841                 this.origin = ReadVector();
 842
 843                 if(is_new)
 844                 {
 845                         float teamnum = entcs_GetTeam(entnum - 1);
 846
 847                         if(autocvar_cl_spawn_event_particles)
 848                         {
 849                                 switch(teamnum)
 850                                 {
 851                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 852                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 853                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 854                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 855                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 856                                 }
 857                         }
 858                         if(autocvar_cl_spawn_event_sound)
 859                         {
 860                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 861                         }
 862                 }
 863         }
 864         return = true;
 865
 866         // local spawn actions
 867         if(is_new && (!entnum || (entnum == player_localentnum)))
 868         {
 869                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 870                 {
 871                         zoomin_effect = 1;
 872                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 873                 }
 874
 875                 if(autocvar_cl_unpress_zoom_on_spawn)
 876                 {
 877                         localcmd("-zoom\n");
 878                         button_zoom = false;
 879                 }
 880                 HUD_Radar_Hide_Maximized();
 881         }
 882         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 883 }
 884
 885 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 886 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 887 void CSQC_Ent_Update(entity this, bool isnew)
 888 {
 889         this.sourceLoc = __FILE__":"STR(__LINE__);
 890         int t = ReadByte();
 891
 892         // set up the "time" global for received entities to be correct for interpolation purposes
 893         float savetime = time;
 894         if(servertime)
 895         {
 896                 time = servertime;
 897         }
 898         else
 899         {
 900                 serverprevtime = time;
 901                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 902                 time = serverprevtime + serverdeltatime;
 903         }
 904
 905 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 906         if (this.enttype)
 907         {
 908                 if (t != this.enttype || isnew)
 909                 {
 910                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 911                         Ent_Remove(this);
 912                         ONREMOVE(this);
 913                         clearentity(this);
 914                         isnew = true;
 915                 }
 916         }
 917         else
 918         {
 919                 if (!isnew)
 920                 {
 921                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 922                         isnew = true;
 923                 }
 924         }
 925 #endif
 926         this.enttype = t;
 927         bool done = false;
 928         FOREACH(LinkedEntities, it.m_id == t, {
 929                 if (isnew) this.classname = it.netname;
 930                 if (autocvar_developer_csqcentities)
 931                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 932                 done = it.m_read(this, NULL, isnew);
 933                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 934                 break;
 935         });
 936         time = savetime;
 937         if (!done)
 938         {
 939                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 940         }
 941 }
 942
 943 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 944 // used when an entity changes its type. For an entity that someone interacts
 945 // with others, make sure it can no longer do so.
 946 void Ent_Remove(entity this)
 947 {
 948         if(this.entremove) this.entremove(this);
 949
 950         if(this.skeletonindex)
 951         {
 952                 skel_delete(this.skeletonindex);
 953                 this.skeletonindex = 0;
 954         }
 955
 956         if(this.snd_looping > 0)
 957         {
 958                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 959                 this.snd_looping = 0;
 960         }
 961
 962         this.enttype = 0;
 963         this.classname = "";
 964         this.draw = func_null;
 965         this.entremove = func_null;
 966         // TODO possibly set more stuff to defaults
 967 }
 968 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 969 void CSQC_Ent_Remove(entity this)
 970 {
 971         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 972         if (wasfreed(this))
 973         {
 974                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 975                 return;
 976         }
 977         if (this.enttype) Ent_Remove(this);
 978         delete(this);
 979 }
 980
 981 void Gamemode_Init()
 982 {
 983         if (!isdemo())
 984         {
 985                 if(!(calledhooks & HOOK_START))
 986                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 987                 calledhooks |= HOOK_START;
 988         }
 989 }
 990 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 991 void CSQC_Parse_StuffCmd(string strMessage)
 992 {
 993         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 994         localcmd(strMessage);
 995 }
 996 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 997 void CSQC_Parse_Print(string strMessage)
 998 {
 999         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1000         print(ColorTranslateRGB(strMessage));
1001 }
1002
1003 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1004 void CSQC_Parse_CenterPrint(string strMessage)
1005 {
1006         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1007         centerprint_AddStandard(strMessage);
1008 }
1009
1010 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1011 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1012 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1013 bool CSQC_Parse_TempEntity()
1014 {
1015         // Acquire TE ID
1016         int nTEID = ReadByte();
1017
1018         FOREACH(TempEntities, it.m_id == nTEID, {
1019                 if (autocvar_developer_csqcentities)
1020                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1021                 return it.m_read(NULL, NULL, true);
1022         });
1023
1024         if (autocvar_developer_csqcentities)
1025                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1026
1027         // No special logic for this temporary entity; return 0 so the engine can handle it
1028         return false;
1029 }
1030
1031 string forcefog;
1032 void Fog_Force()
1033 {
1034         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1035                 localcmd("\nr_drawfog 0\n");
1036         else if (forcefog != "")
1037                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1038 }
1039
1040 bool net_handle_ServerWelcome();
1041 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1042 {
1043         make_pure(this);
1044         gametype = ReadRegistered(Gametypes);
1045         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1046         HUD_ModIcons_SetFunc();
1047         FOREACH(Scores, true, {
1048                 strcpy(scores_label(it), ReadString());
1049                 scores_flags(it) = ReadByte();
1050         });
1051         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1052         {
1053                 strcpy(teamscores_label(i), ReadString());
1054                 teamscores_flags(i) = ReadByte();
1055         }
1056         bool welcome_msg_too = ReadByte();
1057         if (welcome_msg_too)
1058                 net_handle_ServerWelcome();
1059         return = true;
1060         Scoreboard_InitScores();
1061         Gamemode_Init();
1062 }
1063
1064 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1065 {
1066         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1067
1068         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1069         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1070         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1071         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1072         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1073         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1074         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1075         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1076
1077         strcpy(forcefog, ReadString());
1078
1079         armorblockpercent = ReadByte() / 255.0;
1080         damagepush_speedfactor = ReadByte() / 255.0;
1081
1082         serverflags = ReadByte();
1083
1084         g_trueaim_minrange = ReadCoord();
1085
1086         return = true;
1087
1088         MUTATOR_CALLHOOK(Ent_Init);
1089
1090         if (!postinit) PostInit();
1091 }
1092
1093 float GetSpeedUnitFactor(int speed_unit)
1094 {
1095         switch(speed_unit)
1096         {
1097                 default:
1098                 case 1: return 1.0;
1099                 case 2: return 0.0254;
1100                 case 3: return 0.0254 * 3.6;
1101                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1102                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1103         }
1104 }
1105
1106 string GetSpeedUnit(int speed_unit)
1107 {
1108         switch(speed_unit)
1109         {
1110                 // translator-friendly strings without the initial space
1111                 default:
1112                 case 1: return strcat(" ", _("qu/s"));
1113                 case 2: return strcat(" ", _("m/s"));
1114                 case 3: return strcat(" ", _("km/h"));
1115                 case 4: return strcat(" ", _("mph"));
1116                 case 5: return strcat(" ", _("knots"));
1117         }
1118 }
1119
1120 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1121 {
1122         int b = ReadByte();
1123
1124         switch (b)
1125         {
1126                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1127                         race_checkpoint = ReadByte();
1128                         race_time = ReadInt24_t();
1129                         race_previousbesttime = ReadInt24_t();
1130                         race_mypreviousbesttime = ReadInt24_t();
1131                         string pbestname = ReadString();
1132                         if(autocvar_cl_race_cptimes_onlyself)
1133                         {
1134                                 race_previousbesttime = race_mypreviousbesttime;
1135                                 race_mypreviousbesttime = 0;
1136                                 strcpy(race_previousbestname, "");
1137                         }
1138                         else
1139                                 strcpy(race_previousbestname, pbestname);
1140
1141                         race_checkpointtime = time;
1142
1143                         if(race_checkpoint == 0 || race_checkpoint == 254)
1144                         {
1145                                 race_penaltyaccumulator = 0;
1146                                 race_laptime = time; // valid
1147                         }
1148                         break;
1149
1150                 case RACE_NET_CHECKPOINT_CLEAR:
1151                         race_laptime = 0;
1152                         race_checkpointtime = 0;
1153                         break;
1154
1155                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1156                         race_laptime = ReadCoord();
1157                         race_checkpointtime = -99999;
1158                         // fall through
1159                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1160                         race_nextcheckpoint = ReadByte();
1161
1162                         race_nextbesttime = ReadInt24_t();
1163                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1164                                 race_mybesttime = ReadInt24_t();
1165                         string newname = ReadString();
1166                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1167                         {
1168                                 race_nextbesttime = race_mybesttime;
1169                                 race_mybesttime = 0;
1170                                 strcpy(race_nextbestname, "");
1171                         }
1172                         else
1173                                 strcpy(race_nextbestname, newname);
1174                         break;
1175
1176                 case RACE_NET_CHECKPOINT_HIT_RACE:
1177                         race_mycheckpoint = ReadByte();
1178                         race_mycheckpointtime = time;
1179                         race_mycheckpointdelta = ReadInt24_t();
1180                         race_mycheckpointlapsdelta = ReadByte();
1181                         if(race_mycheckpointlapsdelta >= 128)
1182                                 race_mycheckpointlapsdelta -= 256;
1183                         int who = ReadByte();
1184                         if(who)
1185                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1186                         else
1187                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1188                         break;
1189
1190                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1191                         race_othercheckpoint = ReadByte();
1192                         race_othercheckpointtime = time;
1193                         race_othercheckpointdelta = ReadInt24_t();
1194                         race_othercheckpointlapsdelta = ReadByte();
1195                         if(race_othercheckpointlapsdelta >= 128)
1196                                 race_othercheckpointlapsdelta -= 256;
1197                         int what = ReadByte();
1198                         if(what)
1199                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1200                         else
1201                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1202                         break;
1203
1204                 case RACE_NET_PENALTY_RACE:
1205                 case RACE_NET_PENALTY_QUALIFYING:
1206                         race_penaltyeventtime = time;
1207                         race_penaltytime = ReadShort();
1208                         string reason = ReadString();
1209                         if (reason == "missing a checkpoint")
1210                                 reason = _("missing a checkpoint");
1211                         strcpy(race_penaltyreason, reason);
1212                         if (b == RACE_NET_PENALTY_QUALIFYING)
1213                                 race_penaltyaccumulator += race_penaltytime;
1214                         break;
1215
1216                 case RACE_NET_SERVER_RECORD:
1217                         race_server_record = ReadInt24_t();
1218                         break;
1219                 case RACE_NET_SPEED_AWARD:
1220                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1221                         strcpy(race_speedaward_holder, ReadString());
1222                         break;
1223                 case RACE_NET_SPEED_AWARD_BEST:
1224                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1225                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1226                         break;
1227                 case RACE_NET_RANKINGS_CNT:
1228                         RANKINGS_DISPLAY_CNT = ReadByte();
1229                         break;
1230                 case RACE_NET_SERVER_RANKINGS:
1231                         float prevpos, del;
1232                         int pos = ReadShort();
1233                         prevpos = ReadShort();
1234                         del = ReadShort();
1235
1236                         // move other rankings out of the way
1237                         int i;
1238                         if (prevpos) {
1239                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1240                                 for (i=m-1; i>pos-1; --i) {
1241                                         grecordtime[i] = grecordtime[i-1];
1242                                         strcpy(grecordholder[i], grecordholder[i-1]);
1243                                 }
1244                         } else if (del) { // a record has been deleted by the admin
1245                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1246                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1247                                                 grecordtime[i] = 0;
1248                                                 strfree(grecordholder[i]);
1249                                         }
1250                                         else {
1251                                                 grecordtime[i] = grecordtime[i+1];
1252                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1253                                         }
1254                                 }
1255                         } else { // player has no ranked record yet
1256                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1257                                         grecordtime[i] = grecordtime[i-1];
1258                                         strcpy(grecordholder[i], grecordholder[i-1]);
1259                                 }
1260                         }
1261
1262                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1263                                 // kick off the player who fell from the last displayed position
1264                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1265                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1266                         }
1267
1268                         // store new ranking
1269                         strcpy(grecordholder[pos-1], ReadString());
1270                         grecordtime[pos-1] = ReadInt24_t();
1271                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1272                                 race_myrank = pos;
1273                         break;
1274                 case RACE_NET_SERVER_STATUS:
1275                         race_status = ReadShort();
1276                         strcpy(race_status_name, ReadString());
1277         }
1278         return true;
1279 }
1280
1281 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1282 {
1283         teamnagger = 1;
1284         return true;
1285 }
1286
1287 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1288 {
1289         int i = ReadByte();
1290         int pi = ReadShort();
1291         int pl = ReadByte();
1292         int ml = ReadByte();
1293         return = true;
1294         entity e = playerslots[i];
1295         if (!e) return;
1296         e.ping = pi;
1297         e.ping_packetloss = pl / 255.0;
1298         e.ping_movementloss = ml / 255.0;
1299 }
1300
1301 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1302 {
1303         int weapon_id = ReadByte();
1304         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1305         complain_weapon_type = ReadByte();
1306         return = true;
1307
1308         complain_weapon_time = time;
1309         weapontime = time; // ping the weapon panel
1310
1311         switch(complain_weapon_type)
1312         {
1313                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1314                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1315                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1316         }
1317 }
1318
1319 string translate_modifications(string s)
1320 {
1321         return build_mutator_list(s);
1322 }
1323
1324 string translate_weaponarena(string s)
1325 {
1326         if (s == "") return s;
1327         if (s == "All Weapons Arena") return _("All Weapons Arena");
1328         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1329         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1330         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1331         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1332         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1333         if (s == "No Weapons Arena") return _("No Weapons Arena");
1334
1335         int n = tokenizebyseparator(s, " & ");
1336         string wpn_list = "";
1337         for (int i = 0; i < n; i++)
1338         {
1339                 Weapon wep = Weapon_from_name(argv(i));
1340                 if (wep == WEP_Null)
1341                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1342                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1343         }
1344         if (wpn_list != "")
1345                 return sprintf(_("%s Arena"), wpn_list);
1346         else
1347                 return _("No Weapons Arena");
1348 }
1349
1350 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1351 {
1352         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1353         if (version_mismatch)
1354         {
1355                 if(!version_check)
1356                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1357                                 _("Your client version is outdated."), "\n\n\n",
1358                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1359                                 _("Please update!"));
1360                 else
1361                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1362                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1363                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1364         }
1365         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1366 }
1367
1368 bool net_handle_ServerWelcome()
1369 {
1370         bool campaign = ReadByte();
1371         if (campaign)
1372         {
1373                 string campaign_title = ReadString();
1374                 int campaign_level = ReadByte();
1375                 string campaign_msg = ReadString();
1376                 string welcomedialog_args;
1377                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1378                 string key = getcommandkey(_("jump"), "+jump");
1379                 string msg = strcat(
1380                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1381                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1382                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1383                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1384                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1385                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1386                 return true;
1387         }
1388
1389         welcome_msg_force_centerprint = ReadByte();
1390         strcpy(hostname, ReadString());
1391
1392         string hostversion = ReadString();
1393         bool version_mismatch = ReadByte();
1394         bool version_check = ReadByte();
1395         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1396
1397         string modifications = translate_modifications(ReadString());
1398         string weaponarena_list = translate_weaponarena(ReadString());
1399         string cache_mutatormsg = ReadString();
1400         string motd = ReadString();
1401
1402         string msg = "";
1403         msg = strcat(msg, ver);
1404         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1405
1406         modifications = cons_mid(modifications, ", ", weaponarena_list);
1407         if(modifications != "")
1408                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1409
1410         if (cache_mutatormsg != "")
1411                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1412         string mutator_msg = "";
1413         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1414         mutator_msg = M_ARGV(0, string);
1415         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1416
1417         if (motd != "")
1418                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1419
1420         strcpy(welcome_msg, msg);
1421         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1422         return true;
1423 }
1424
1425 void Welcome_Message_Show_Try()
1426 {
1427         if (!welcome_msg_menu_check_maxtime)
1428                 return;
1429
1430         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1431         // if want dialog check if menu is initialized but for a short time
1432         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1433         {
1434                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1435                 {
1436                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1437                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1438                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1439                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1440                 }
1441                 else
1442                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1443
1444                 strfree(welcome_msg);
1445                 welcome_msg_menu_check_maxtime = 0;
1446         }
1447 }
1448
1449 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1450 {
1451         return net_handle_ServerWelcome();
1452 }
1453
1454 string _getcommandkey(string cmd_name, string command, bool forcename)
1455 {
1456         string keys;
1457         float n, j, k, l = 0;
1458
1459         if (!autocvar_hud_showbinds)
1460                 return cmd_name;
1461
1462         keys = db_get(binddb, command);
1463         if (keys == "")
1464         {
1465                 bool joy_active = cvar("joy_active");
1466                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1467                 for(j = 0; j < n; ++j)
1468                 {
1469                         k = stof(argv(j));
1470                         if(k != -1)
1471                         {
1472                                 string key = keynumtostring(k);
1473                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1474                                         continue;
1475
1476                                 key = translate_key(key);
1477
1478                                 if (keys == "")
1479                                         keys = key;
1480                                 else
1481                                         keys = strcat(keys, ", ", key);
1482
1483                                 ++l;
1484                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1485                                         break;
1486                         }
1487
1488                 }
1489                 if (keys == "")
1490                         keys = "NO_KEY";
1491                 db_put(binddb, command, keys);
1492         }
1493
1494         if (keys == "NO_KEY") {
1495                 if (autocvar_hud_showbinds > 1)
1496                         return sprintf(_("%s (not bound)"), cmd_name);
1497                 else
1498                         return cmd_name;
1499         }
1500         else if (autocvar_hud_showbinds > 1 || forcename)
1501                 return sprintf("%s (%s)", cmd_name, keys);
1502         else
1503                 return keys;
1504 }
1505
1506 /** engine callback */
1507 void URI_Get_Callback(int id, int status, string data)
1508 {
1509         TC(int, id); TC(int, status);
1510         if(url_URI_Get_Callback(id, status, data))
1511         {
1512                 // handled
1513         }
1514         else if (id == URI_GET_DISCARD)
1515         {
1516                 // discard
1517         }
1518         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1519         {
1520                 // sv_cmd curl
1521                 Curl_URI_Get_Callback(id, status, data);
1522         }
1523         else
1524         {
1525                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1526         }
1527 }