qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "hud/panel/quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222     TC(int, Team);
 223         devassert_once(Team);
 224         entity tm;
 225         if(teamplay)
 226         {
 227                 switch(Team)
 228                 {
 229                         case -1:
 230                         case NUM_TEAM_1:
 231                         case NUM_TEAM_2:
 232                         case NUM_TEAM_3:
 233                         case NUM_TEAM_4:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == NULL)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         else
 245         {
 246                 switch(Team)
 247                 {
 248                         case -1:
 249                         case 0:
 250                                 break;
 251                         default:
 252                                 if(GetTeam(Team, false) == NULL)
 253                                 {
 254                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 255                                         Team = NUM_SPECTATOR;
 256                                 }
 257                                 break;
 258                 }
 259         }
 260         if(Team == -1) // leave
 261         {
 262                 if(o.has_team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.has_team = 0;
 267                         return true;
 268                 }
 269         }
 270         else
 271         {
 272                 if (!o.has_team)
 273                 {
 274                         o.team = Team;
 275                         tm = GetTeam(Team, true);
 276                         tm.team_size += 1;
 277                         o.has_team = 1;
 278                         return true;
 279                 }
 280                 else if(Team != o.team)
 281                 {
 282                         tm = GetTeam(o.team, false);
 283                         tm.team_size -= 1;
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         return true;
 288                 }
 289         }
 290         return false;
 291 }
 292
 293 void Playerchecker_Think(entity this)
 294 {
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = NULL;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         setthink(playerchecker, Playerchecker_Think);
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 355 {
 356     TC(int, bInputType);
 357         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 358                 return true;
 359
 360         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 361                 return true;
 362
 363         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 364                 return true;
 365
 366         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 367                 return true;
 368
 369         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 370                 return true;
 371
 372         return false;
 373 }
 374
 375 // END REQUIRED CSQC FUNCTIONS
 376 // --------------------------------------------------------------------------
 377
 378 // --------------------------------------------------------------------------
 379 // BEGIN OPTIONAL CSQC FUNCTIONS
 380
 381 void Ent_Remove(entity this);
 382
 383 void Ent_RemovePlayerScore(entity this)
 384 {
 385         if(this.owner) {
 386                 SetTeam(this.owner, -1);
 387                 this.owner.gotscores = 0;
 388                 for(int i = 0; i < MAX_SCORE; ++i) {
 389                         this.owner.(scores[i]) = 0; // clear all scores
 390                 }
 391         }
 392 }
 393
 394 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 395 {
 396         make_pure(this);
 397         int i, n;
 398         bool isNew;
 399         entity o;
 400
 401         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 402         // (no I've never heard of M-x replace-string, sed, or anything like that)
 403         isNew = !this.owner; // workaround for DP bug
 404         n = ReadByte()-1;
 405
 406 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 407         if(!isNew && n != this.sv_entnum)
 408         {
 409                 //print("A CSQC entity changed its owner!\n");
 410                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 411                 isNew = true;
 412                 Ent_Remove(this);
 413         }
 414 #endif
 415
 416         this.sv_entnum = n;
 417
 418         o = playerslots[this.sv_entnum];
 419         if (!o)
 420         {
 421                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 422         }
 423         this.owner = o;
 424         o.sv_entnum = this.sv_entnum;
 425         o.gotscores = 1;
 426
 427         //if (!o.sort_prev)
 428         //      RegisterPlayer(o);
 429         //playerchecker will do this for us later, if it has not already done so
 430
 431     int sf, lf;
 432 #if MAX_SCORE <= 8
 433         sf = ReadByte();
 434         lf = ReadByte();
 435 #else
 436         sf = ReadShort();
 437         lf = ReadShort();
 438 #endif
 439     int p;
 440         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 441                 if(sf & p)
 442                 {
 443                         if(lf & p)
 444                                 o.(scores[i]) = ReadInt24_t();
 445                         else
 446                                 o.(scores[i]) = ReadChar();
 447                 }
 448
 449         return = true;
 450
 451         if(o.sort_prev)
 452                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 453
 454         this.entremove = Ent_RemovePlayerScore;
 455 }
 456
 457 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 458 {
 459         make_pure(this);
 460         int i;
 461         entity o;
 462
 463         this.team = ReadByte();
 464         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 465
 466     int sf, lf;
 467 #if MAX_TEAMSCORE <= 8
 468         sf = ReadByte();
 469         lf = ReadByte();
 470 #else
 471         sf = ReadShort();
 472         lf = ReadShort();
 473 #endif
 474         int p;
 475         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 476                 if(sf & p)
 477                 {
 478                         if(lf & p)
 479                                 o.(teamscores[i]) = ReadInt24_t();
 480                         else
 481                                 o.(teamscores[i]) = ReadChar();
 482                 }
 483
 484         return = true;
 485
 486         HUD_UpdateTeamPos(o);
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 490 {
 491         make_pure(this);
 492         float newspectatee_status;
 493
 494     int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & 1);
 497
 498         if(f & 2)
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & 4);
 508
 509         if(f & 8)
 510         {
 511                 angles_held_status = 1;
 512                 angles_held.x = ReadAngle();
 513                 angles_held.y = ReadAngle();
 514                 angles_held.z = 0;
 515         }
 516         else
 517                 angles_held_status = 0;
 518
 519         if(f & 16)
 520         {
 521                 num_spectators = ReadByte();
 522
 523                 float i, slot;
 524
 525                 for(i = 0; i < MAX_SPECTATORS; ++i)
 526                         spectatorlist[i] = 0; // reset list first
 527
 528                 for(i = 0; i < num_spectators; ++i)
 529                 {
 530                         slot = ReadByte();
 531                         spectatorlist[i] = slot - 1;
 532                 }
 533         }
 534
 535         return = true;
 536
 537         if(newspectatee_status != spectatee_status)
 538         {
 539                 // clear race stuff
 540                 race_laptime = 0;
 541                 race_checkpointtime = 0;
 542                 hud_dynamic_shake_factor = -1;
 543         }
 544         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 545         {
 546                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 547                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 548                 )
 549                         prev_p_health = -1;
 550                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 551                         prev_health = -1;
 552         }
 553         spectatee_status = newspectatee_status;
 554
 555         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 556 }
 557
 558 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 559 {
 560         make_pure(this);
 561     int i, j, b, f;
 562
 563     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 564
 565         if(!(nags & BIT(2)))
 566         {
 567                 if(vote_called_vote)
 568                         strunzone(vote_called_vote);
 569                 vote_called_vote = string_null;
 570                 vote_active = 0;
 571         }
 572         else
 573         {
 574                 vote_active = 1;
 575         }
 576
 577         if(nags & BIT(6))
 578         {
 579                 vote_yescount = ReadByte();
 580                 vote_nocount = ReadByte();
 581                 vote_needed = ReadByte();
 582                 vote_highlighted = ReadChar();
 583         }
 584
 585         if(nags & BIT(7))
 586         {
 587                 if(vote_called_vote)
 588                         strunzone(vote_called_vote);
 589                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 590         }
 591
 592         if(nags & 1)
 593         {
 594                 for(j = 0; j < maxclients; ++j)
 595                         if(playerslots[j])
 596                                 playerslots[j].ready = 1;
 597                 for(i = 1; i <= maxclients; i += 8)
 598                 {
 599                         f = ReadByte();
 600                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 601                                 if (!(f & b))
 602                                         if(playerslots[j])
 603                                                 playerslots[j].ready = 0;
 604                 }
 605         }
 606
 607         return = true;
 608
 609         ready_waiting = (nags & BIT(0));
 610         ready_waiting_for_me = (nags & BIT(1));
 611         vote_waiting = (nags & BIT(2));
 612         vote_waiting_for_me = (nags & BIT(3));
 613         warmup_stage = (nags & BIT(4));
 614 }
 615
 616 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 617 {
 618         make_pure(this);
 619     int i, j, b, f;
 620
 621     int sf = ReadByte();
 622         if(sf & 1)
 623         {
 624                 for(j = 0; j < maxclients; ++j)
 625                         if(playerslots[j])
 626                                 playerslots[j].eliminated = 1;
 627                 for(i = 1; i <= maxclients; i += 8)
 628                 {
 629                         f = ReadByte();
 630                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 631                                 if (!(f & b))
 632                                         if(playerslots[j])
 633                                                 playerslots[j].eliminated = 0;
 634                 }
 635         }
 636         return true;
 637 }
 638
 639 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 640 {
 641         make_pure(this);
 642         prandom_debug();
 643         float s = ReadShort();
 644         psrandom(s);
 645         return true;
 646 }
 647
 648 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 649 {
 650         make_pure(this);
 651     int sf = ReadInt24_t();
 652         if (sf == 0) {
 653                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 654                         weapon_accuracy[w] = -1;
 655                 return true;
 656         }
 657
 658         int f = 1;
 659         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 660                 if (sf & f) {
 661             int b = ReadByte();
 662                         if (b == 0)
 663                                 weapon_accuracy[w] = -1;
 664                         else if (b == 255)
 665                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 666                         else
 667                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 668                 }
 669                 f = (f == 0x800000) ? 1 : f * 2;
 670         }
 671         return true;
 672 }
 673
 674 void Spawn_Draw(entity this)
 675 {
 676         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 677 }
 678
 679 void Spawn_PreDraw(entity this)
 680 {
 681         float alph;
 682         vector org = getpropertyvec(VF_ORIGIN);
 683         if(this.fade_start)
 684                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 685         else
 686                 alph = 1;
 687         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 688         this.alpha = alph;
 689         if(alph <= 0)
 690                 this.drawmask = 0;
 691         else
 692                 this.drawmask = MASK_NORMAL;
 693 }
 694
 695 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 696 {
 697         float teamnum = (ReadByte() - 1);
 698         vector spn_origin;
 699         spn_origin.x = ReadCoord();
 700         spn_origin.y = ReadCoord();
 701         spn_origin.z = ReadCoord();
 702
 703         this.team = (teamnum + 1);
 704
 705         //if(is_new)
 706         //{
 707                 this.origin = spn_origin;
 708                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 709                 //droptofloor();
 710
 711                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 712                 {
 713                         this.mdl = "models/spawnpoint.md3";
 714                         this.colormod = Team_ColorRGB(teamnum);
 715                         precache_model(this.mdl);
 716                         setmodel(this, this.mdl);
 717                         this.drawmask = MASK_NORMAL;
 718                         //this.movetype = MOVETYPE_NOCLIP;
 719                         //this.draw = Spawn_Draw;
 720                 }*/
 721                 if(autocvar_cl_spawn_point_particles)
 722                 {
 723                         if((serverflags & SERVERFLAG_TEAMPLAY))
 724                         {
 725                                 switch(teamnum)
 726                                 {
 727                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 728                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 729                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 730                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 731                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 732                                 }
 733                         }
 734                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 735
 736                         this.draw = Spawn_Draw;
 737                         setpredraw(this, Spawn_PreDraw);
 738                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 739                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 740                 }
 741         //}
 742
 743         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 744         return true;
 745 }
 746
 747 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 748 {
 749         // If entnum is 0, ONLY do the local spawn actions
 750         // this way the server can disable the sending of
 751         // spawn origin or such to clients if wanted.
 752         float entnum = ReadByte();
 753
 754         if(entnum)
 755         {
 756                 this.origin_x = ReadCoord();
 757                 this.origin_y = ReadCoord();
 758                 this.origin_z = ReadCoord();
 759
 760                 if(is_new)
 761                 {
 762                         float teamnum = entcs_GetTeam(entnum - 1);
 763
 764                         if(autocvar_cl_spawn_event_particles)
 765                         {
 766                                 switch(teamnum)
 767                                 {
 768                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 769                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 771                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 772                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 773                                 }
 774                         }
 775                         if(autocvar_cl_spawn_event_sound)
 776                         {
 777                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 778                         }
 779                 }
 780         }
 781         return = true;
 782
 783         // local spawn actions
 784         if(is_new && (!entnum || (entnum == player_localentnum)))
 785         {
 786                 zoomin_effect = 1;
 787                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 788
 789                 if(autocvar_cl_unpress_zoom_on_spawn)
 790                 {
 791                         localcmd("-zoom\n");
 792                         button_zoom = false;
 793                 }
 794         }
 795         HUD_Radar_Hide_Maximized();
 796         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 797 }
 798
 799 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 800 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 801 void CSQC_Ent_Update(entity this, bool isnew)
 802 {
 803         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 804         int t = ReadByte();
 805
 806         // set up the "time" global for received entities to be correct for interpolation purposes
 807         float savetime = time;
 808         if(servertime)
 809         {
 810                 time = servertime;
 811         }
 812         else
 813         {
 814                 serverprevtime = time;
 815                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 816                 time = serverprevtime + serverdeltatime;
 817         }
 818
 819 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 820         if (this.enttype)
 821         {
 822                 if (t != this.enttype || isnew)
 823                 {
 824                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 825                         Ent_Remove(this);
 826                         clearentity(this);
 827                         isnew = true;
 828                 }
 829         }
 830         else
 831         {
 832                 if (!isnew)
 833                 {
 834                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 835                         isnew = true;
 836                 }
 837         }
 838 #endif
 839         this.enttype = t;
 840         bool done = false;
 841         FOREACH(LinkedEntities, it.m_id == t, {
 842                 if (isnew) this.classname = it.netname;
 843                 if (autocvar_developer_csqcentities)
 844             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 845                 done = it.m_read(this, NULL, isnew);
 846                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 847                 break;
 848         });
 849         time = savetime;
 850         if (!done)
 851         {
 852                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 853         }
 854 }
 855
 856 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 857 // used when an entity changes its type. For an entity that someone interacts
 858 // with others, make sure it can no longer do so.
 859 void Ent_Remove(entity this)
 860 {
 861         if(this.entremove) this.entremove(this);
 862
 863         if(this.skeletonindex)
 864         {
 865                 skel_delete(this.skeletonindex);
 866                 this.skeletonindex = 0;
 867         }
 868
 869         if(this.snd_looping > 0)
 870         {
 871                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 872                 this.snd_looping = 0;
 873         }
 874
 875         this.enttype = 0;
 876         this.classname = "";
 877         this.draw = func_null;
 878         this.entremove = func_null;
 879         // TODO possibly set more stuff to defaults
 880 }
 881 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 882 void CSQC_Ent_Remove(entity this)
 883 {
 884         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 885         if (wasfreed(this))
 886         {
 887                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 888                 return;
 889         }
 890         if (this.enttype) Ent_Remove(this);
 891         remove(this);
 892 }
 893
 894 void Gamemode_Init()
 895 {
 896         if (!isdemo())
 897         {
 898                 if(!(calledhooks & HOOK_START))
 899                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 900                 calledhooks |= HOOK_START;
 901         }
 902 }
 903 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 904 void CSQC_Parse_StuffCmd(string strMessage)
 905 {
 906         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 907         localcmd(strMessage);
 908 }
 909 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 910 void CSQC_Parse_Print(string strMessage)
 911 {
 912         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 913         print(ColorTranslateRGB(strMessage));
 914 }
 915
 916 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 917 void CSQC_Parse_CenterPrint(string strMessage)
 918 {
 919         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 920         centerprint_hud(strMessage);
 921 }
 922
 923 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 924 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 925 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 926 bool CSQC_Parse_TempEntity()
 927 {
 928         // Acquire TE ID
 929         int nTEID = ReadByte();
 930
 931         FOREACH(TempEntities, it.m_id == nTEID, {
 932                 if (autocvar_developer_csqcentities)
 933                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 934                 return it.m_read(NULL, NULL, true);
 935         });
 936
 937         if (autocvar_developer_csqcentities)
 938                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 939
 940         // No special logic for this temporary entity; return 0 so the engine can handle it
 941         return false;
 942 }
 943
 944 string forcefog;
 945 void Fog_Force()
 946 {
 947         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 948                 localcmd("\nr_drawfog 0\n");
 949         else if (forcefog != "")
 950                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 951 }
 952
 953 void Gamemode_Init();
 954 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 955 {
 956         make_pure(this);
 957         gametype = ReadInt24_t();
 958         HUD_ModIcons_SetFunc();
 959         for (int i = 0; i < MAX_SCORE; ++i)
 960         {
 961                 if (scores_label[i]) strunzone(scores_label[i]);
 962                 scores_label[i] = strzone(ReadString());
 963                 scores_flags[i] = ReadByte();
 964         }
 965         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 966         {
 967                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 968                 teamscores_label[i] = strzone(ReadString());
 969                 teamscores_flags[i] = ReadByte();
 970         }
 971         return = true;
 972         HUD_InitScores();
 973         Gamemode_Init();
 974 }
 975
 976 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 977 {
 978         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 979
 980         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 981         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 982         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 983         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 984         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 985         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 986         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 987         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 988
 989         if (forcefog) strunzone(forcefog);
 990         forcefog = strzone(ReadString());
 991
 992         armorblockpercent = ReadByte() / 255.0;
 993
 994         serverflags = ReadByte();
 995
 996         g_trueaim_minrange = ReadCoord();
 997
 998         return = true;
 999
1000         MUTATOR_CALLHOOK(Ent_Init);
1001
1002         if (!postinit) PostInit();
1003 }
1004
1005 float GetSpeedUnitFactor(int speed_unit)
1006 {
1007         switch(speed_unit)
1008         {
1009                 default:
1010                 case 1:
1011                         return 1.0;
1012                 case 2:
1013                         return 0.0254;
1014                 case 3:
1015                         return 0.0254 * 3.6;
1016                 case 4:
1017                         return 0.0254 * 3.6 * 0.6213711922;
1018                 case 5:
1019                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1020         }
1021 }
1022
1023 string GetSpeedUnit(int speed_unit)
1024 {
1025         switch(speed_unit)
1026         {
1027                 default:
1028                 case 1:
1029                         return _(" qu/s");
1030                 case 2:
1031                         return _(" m/s");
1032                 case 3:
1033                         return _(" km/h");
1034                 case 4:
1035                         return _(" mph");
1036                 case 5:
1037                         return _(" knots");
1038         }
1039 }
1040
1041 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1042 {
1043         int b = ReadByte();
1044
1045         switch (b)
1046         {
1047                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1048                         race_checkpoint = ReadByte();
1049                         race_time = ReadInt24_t();
1050                         race_previousbesttime = ReadInt24_t();
1051                         if(race_previousbestname)
1052                                 strunzone(race_previousbestname);
1053                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1054
1055                         race_checkpointtime = time;
1056
1057                         if(race_checkpoint == 0 || race_checkpoint == 254)
1058                         {
1059                                 race_penaltyaccumulator = 0;
1060                                 race_laptime = time; // valid
1061                         }
1062
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_CLEAR:
1066                         race_laptime = 0;
1067                         race_checkpointtime = 0;
1068                         break;
1069
1070                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1071                         race_laptime = ReadCoord();
1072                         race_checkpointtime = -99999;
1073                         // fall through
1074                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1075                         race_nextcheckpoint = ReadByte();
1076
1077                         race_nextbesttime = ReadInt24_t();
1078                         if(race_nextbestname)
1079                                 strunzone(race_nextbestname);
1080                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1081                         break;
1082
1083                 case RACE_NET_CHECKPOINT_HIT_RACE:
1084                         race_mycheckpoint = ReadByte();
1085                         race_mycheckpointtime = time;
1086                         race_mycheckpointdelta = ReadInt24_t();
1087                         race_mycheckpointlapsdelta = ReadByte();
1088                         if(race_mycheckpointlapsdelta >= 128)
1089                                 race_mycheckpointlapsdelta -= 256;
1090                         if(race_mycheckpointenemy)
1091                                 strunzone(race_mycheckpointenemy);
1092                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1096                         race_othercheckpoint = ReadByte();
1097                         race_othercheckpointtime = time;
1098                         race_othercheckpointdelta = ReadInt24_t();
1099                         race_othercheckpointlapsdelta = ReadByte();
1100                         if(race_othercheckpointlapsdelta >= 128)
1101                                 race_othercheckpointlapsdelta -= 256;
1102                         if(race_othercheckpointenemy)
1103                                 strunzone(race_othercheckpointenemy);
1104                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1105                         break;
1106
1107                 case RACE_NET_PENALTY_RACE:
1108                         race_penaltyeventtime = time;
1109                         race_penaltytime = ReadShort();
1110                         //race_penaltyaccumulator += race_penaltytime;
1111                         if(race_penaltyreason)
1112                                 strunzone(race_penaltyreason);
1113                         race_penaltyreason = strzone(ReadString());
1114                         break;
1115
1116                 case RACE_NET_PENALTY_QUALIFYING:
1117                         race_penaltyeventtime = time;
1118                         race_penaltytime = ReadShort();
1119                         race_penaltyaccumulator += race_penaltytime;
1120                         if(race_penaltyreason)
1121                                 strunzone(race_penaltyreason);
1122                         race_penaltyreason = strzone(ReadString());
1123                         break;
1124
1125                 case RACE_NET_SERVER_RECORD:
1126                         race_server_record = ReadInt24_t();
1127                         break;
1128                 case RACE_NET_SPEED_AWARD:
1129                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1130                         if(race_speedaward_holder)
1131                                 strunzone(race_speedaward_holder);
1132                         race_speedaward_holder = strzone(ReadString());
1133                         if(race_speedaward_unit)
1134                                 strunzone(race_speedaward_unit);
1135                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1136                         break;
1137                 case RACE_NET_SPEED_AWARD_BEST:
1138                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1139                         if(race_speedaward_alltimebest_holder)
1140                                 strunzone(race_speedaward_alltimebest_holder);
1141                         race_speedaward_alltimebest_holder = strzone(ReadString());
1142                         if(race_speedaward_alltimebest_unit)
1143                                 strunzone(race_speedaward_alltimebest_unit);
1144                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1145                         break;
1146                 case RACE_NET_SERVER_RANKINGS:
1147                         float prevpos, del;
1148             int pos = ReadShort();
1149                         prevpos = ReadShort();
1150                         del = ReadShort();
1151
1152                         // move other rankings out of the way
1153             int i;
1154                         if (prevpos) {
1155                                 for (i=prevpos-1;i>pos-1;--i) {
1156                                         grecordtime[i] = grecordtime[i-1];
1157                                         if(grecordholder[i])
1158                                                 strunzone(grecordholder[i]);
1159                                         grecordholder[i] = strzone(grecordholder[i-1]);
1160                                 }
1161                         } else if (del) { // a record has been deleted by the admin
1162                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1163                                         if (i == RANKINGS_CNT-1) { // clear out last record
1164                                                 grecordtime[i] = 0;
1165                                                 if (grecordholder[i])
1166                                                         strunzone(grecordholder[i]);
1167                                                 grecordholder[i] = string_null;
1168                                         }
1169                                         else {
1170                                                 grecordtime[i] = grecordtime[i+1];
1171                                                 if (grecordholder[i])
1172                                                         strunzone(grecordholder[i]);
1173                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1174                                         }
1175                                 }
1176                         } else { // player has no ranked record yet
1177                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1178                                         grecordtime[i] = grecordtime[i-1];
1179                                         if(grecordholder[i])
1180                                                 strunzone(grecordholder[i]);
1181                                         grecordholder[i] = strzone(grecordholder[i-1]);
1182                                 }
1183                         }
1184
1185                         // store new ranking
1186                         if(grecordholder[pos-1] != "")
1187                                 strunzone(grecordholder[pos-1]);
1188                         grecordholder[pos-1] = strzone(ReadString());
1189                         grecordtime[pos-1] = ReadInt24_t();
1190                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1191                                 race_myrank = pos;
1192                         break;
1193                 case RACE_NET_SERVER_STATUS:
1194                         race_status = ReadShort();
1195                         if(race_status_name)
1196                                 strunzone(race_status_name);
1197                         race_status_name = strzone(ReadString());
1198         }
1199         return true;
1200 }
1201
1202 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1203 {
1204         teamnagger = 1;
1205         return true;
1206 }
1207
1208 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1209 {
1210         int i = ReadByte();
1211         int pi = ReadShort();
1212         int pl = ReadByte();
1213         int ml = ReadByte();
1214         return = true;
1215         entity e = playerslots[i];
1216         if (!e) return;
1217         e.ping = pi;
1218         e.ping_packetloss = pl / 255.0;
1219         e.ping_movementloss = ml / 255.0;
1220 }
1221
1222 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1223 {
1224         complain_weapon = ReadByte();
1225         complain_weapon_type = ReadByte();
1226         return = true;
1227
1228         complain_weapon_time = time;
1229         weapontime = time; // ping the weapon panel
1230
1231         switch(complain_weapon_type)
1232         {
1233                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1234                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1235                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1236         }
1237 }
1238
1239 string getcommandkey(string text, string command)
1240 {
1241         string keys;
1242         float n, j, k, l = 0;
1243
1244         if (!autocvar_hud_showbinds)
1245                 return text;
1246
1247         keys = db_get(binddb, command);
1248         if (keys == "")
1249         {
1250                 bool joy_detected = cvar("joy_detected");
1251                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1252                 for(j = 0; j < n; ++j)
1253                 {
1254                         k = stof(argv(j));
1255                         if(k != -1)
1256                         {
1257                                 string key = keynumtostring(k);
1258                                 if(!joy_detected && substring(key, 0, 3) == "JOY")
1259                                         continue;
1260
1261                                 if (keys == "")
1262                                         keys = key;
1263                                 else
1264                                         keys = strcat(keys, ", ", key);
1265
1266                                 ++l;
1267                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1268                                         break;
1269                         }
1270
1271                 }
1272                 if (keys == "")
1273                         keys = "NO_KEY";
1274                 db_put(binddb, command, keys);
1275         }
1276
1277         if (keys == "NO_KEY") {
1278                 if (autocvar_hud_showbinds > 1)
1279                         return sprintf(_("%s (not bound)"), text);
1280                 else
1281                         return text;
1282         }
1283         else if (autocvar_hud_showbinds > 1)
1284                 return sprintf("%s (%s)", text, keys);
1285         else
1286                 return keys;
1287 }