Fix ESC key not closing team selection if automatically opened by the server, scorebo...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include <client/command/cl_cmd.qh>
4 #include <client/draw.qh>
5 #include <client/hud/_mod.qh>
6 #include <client/hud/panel/centerprint.qh>
7 #include <client/hud/panel/chat.qh>
8 #include <client/hud/panel/quickmenu.qh>
9 #include <client/hud/panel/scoreboard.qh>
10 #include <client/items/items.qh>
11 #include <client/mapvoting.qh>
12 #include <client/mutators/_mod.qh>
13 #include <client/shownames.qh>
14 #include <client/view.qh>
15 #include <client/weapons/projectile.qh>
16 #include <common/deathtypes/all.qh>
17 #include <common/effects/all.inc>
18 #include <common/effects/all.qh>
19 #include <common/effects/effect.qh>
20 #include <common/effects/qc/_mod.qh>
21 #include <common/ent_cs.qh>
22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
23 #include <common/items/_mod.qh>
24 #include <common/mapinfo.qh>
25 #include <common/mapobjects/_mod.qh>
26 #include <common/minigames/cl_minigames.qh>
27 #include <common/minigames/cl_minigames_hud.qh>
28 #include <common/net_linked.qh>
29 #include <common/net_notice.qh>
30 #include <common/scores.qh>
31 #include <common/vehicles/all.qh>
32 #include <lib/csqcmodel/cl_model.qh>
33 #include <lib/csqcmodel/interpolate.qh>
34 #include <lib/warpzone/client.qh>
35
36 // --------------------------------------------------------------------------
37 // BEGIN REQUIRED CSQC FUNCTIONS
38 //include "main.qh"
39
40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
41
42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
43 // Useful for precaching things
44
45 void CSQC_Init()
46 {
47         prvm_language = strzone(cvar_string("prvm_language"));
48
49 #ifdef WATERMARK
50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
51 #endif
52
53         {
54                 int i = 0;
55                 for ( ; i < 255; ++i)
56                         if (getplayerkeyvalue(i, "viewentity") == "")
57                                 break;
58                 maxclients = i;
59         }
60
61         // needs to be done so early because of the constants they create
62         static_init();
63         static_init_late();
64         static_init_precache();
65
66         binddb = db_create();
67         tempdb = db_create();
68         ClientProgsDB = db_load("client.db");
69
70         draw_endBoldFont();
71
72         //registercommand("hud_configure");
73         //registercommand("hud_save");
74         //registercommand("menu_action");
75
76         ConsoleCommand_macro_init();
77
78         registercvar("hud_usecsqc", "1");
79         registercvar("scoreboard_columns", "default");
80
81         registercvar("cl_nade_type", "3");
82         registercvar("cl_pokenade_type", "zombie");
83
84         registercvar("cl_jumpspeedcap_min", "");
85         registercvar("cl_jumpspeedcap_max", "");
86
87         registercvar("cl_shootfromfixedorigin", "");
88
89         registercvar("cl_multijump", "-1");
90
91         registercvar("cl_dodging", "0");
92
93         registercvar("cl_spawn_near_teammate", "1");
94
95         registercvar("cl_weapon_switch_reload", "1");
96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
97
98         registercvar("cl_allow_uidranking", "1");
99
100         if(autocvar_cl_lockview)
101                 cvar_set("cl_lockview", "0");
102
103         gametype = NULL;
104
105         postinit = false;
106
107         calledhooks = 0;
108
109         teams = Sort_Spawn();
110         players = Sort_Spawn();
111
112         GetTeam(NUM_SPECTATOR, true); // add specs first
113
114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
115                 weapon_accuracy[w] = -1;
116
117         // precaches
118
119         if(autocvar_cl_reticle)
120         {
121                 precache_pic("gfx/reticle_normal");
122                 // weapon reticles are precached in weapon files
123         }
124
125         {
126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
128                 shortmapname = mi_shortname;
129
130                 if (precache_pic(minimapname) == "")
131                 {
132                         // but maybe we have a non-clever minimap
133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
134                         if (precache_pic(minimapname) == "")
135                                 minimapname = ""; // FAIL
136                         else
137                                 get_mi_min_max_texcoords(0); // load new texcoords
138                 }
139
140                 mi_center = (mi_min + mi_max) * 0.5;
141                 mi_scale = mi_max - mi_min;
142                 minimapname = strzone(minimapname);
143         }
144
145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
146         LoadMenuSkinValues();
147 }
148
149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
150 void Shutdown()
151 {
152         WarpZone_Shutdown();
153
154         delete(teams);
155         delete(players);
156         db_close(binddb);
157         db_close(tempdb);
158         if(autocvar_cl_db_saveasdump)
159                 db_dump(ClientProgsDB, "client.db");
160         else
161                 db_save(ClientProgsDB, "client.db");
162         db_close(ClientProgsDB);
163
164         if(camera_active)
165                 cvar_set("chase_active",ftos(chase_active_backup));
166
167         // unset the event chasecam's chase_active
168         if(autocvar_chase_active < 0)
169                 cvar_set("chase_active", "0");
170
171         if (autocvar_r_drawviewmodel < 0)
172                 cvar_set("r_drawviewmodel", "0");
173
174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
175
176         if (!isdemo())
177         {
178                 if (!(calledhooks & HOOK_START))
179                         localcmd("\n_cl_hook_gamestart nop\n");
180                 if (!(calledhooks & HOOK_END))
181                         localcmd("\ncl_hook_gameend\n");
182         }
183
184         localcmd("\ncl_hook_shutdown\n");
185
186         localcmd("\n-button12\n");
187
188         deactivate_minigame();
189         HUD_MinigameMenu_Close(NULL, NULL, NULL);
190
191         ReplicateVars(REPLICATEVARS_DESTROY);
192 }
193
194 void AuditLists()
195 {
196         entity e;
197         entity prev;
198
199         prev = players;
200         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
201         {
202                 if(prev != e.sort_prev)
203                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
204         }
205
206         prev = teams;
207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
208         {
209                 if(prev != e.sort_prev)
210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
211         }
212 }
213
214 float RegisterPlayer(entity player)
215 {
216         entity pl;
217         AuditLists();
218         for(pl = players.sort_next; pl; pl = pl.sort_next)
219                 if(pl == player)
220                         error("Player already registered!");
221         player.sort_next = players.sort_next;
222         player.sort_prev = players;
223         if(players.sort_next)
224                 players.sort_next.sort_prev = player;
225         players.sort_next = player;
226         AuditLists();
227         return true;
228 }
229
230 void RemovePlayer(entity player)
231 {
232         entity pl, parent;
233         AuditLists();
234         parent = players;
235         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
236                 parent = pl;
237
238         if(!pl)
239         {
240                 error("Trying to remove a player which is not in the playerlist!");
241                 return;
242         }
243         parent.sort_next = player.sort_next;
244         if(player.sort_next)
245                 player.sort_next.sort_prev = parent;
246         AuditLists();
247 }
248
249 void MoveToLast(entity e)
250 {
251         AuditLists();
252         entity ent = e.sort_next;
253         while(ent)
254         {
255                 SORT_SWAP(ent, e);
256                 ent = e.sort_next;
257         }
258         AuditLists();
259 }
260
261 float RegisterTeam(entity Team)
262 {
263         assert_once(Team.team, eprint(Team));
264         entity tm;
265         AuditLists();
266         for(tm = teams.sort_next; tm; tm = tm.sort_next)
267                 if(tm == Team)
268                         error("Team already registered!");
269         Team.sort_next = teams.sort_next;
270         Team.sort_prev = teams;
271         if(teams.sort_next)
272                 teams.sort_next.sort_prev = Team;
273         teams.sort_next = Team;
274         if(Team.team && Team.team != NUM_SPECTATOR)
275                 ++team_count;
276         AuditLists();
277         return true;
278 }
279
280 void RemoveTeam(entity Team)
281 {
282         entity tm, parent;
283         AuditLists();
284         parent = teams;
285         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
286                 parent = tm;
287
288         if(!tm)
289         {
290                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
291                 return;
292         }
293         parent.sort_next = Team.sort_next;
294         if(Team.sort_next)
295                 Team.sort_next.sort_prev = parent;
296         if(Team.team && Team.team != NUM_SPECTATOR)
297                 --team_count;
298         AuditLists();
299 }
300
301 entity GetTeam(int Team, bool add)
302 {
303         TC(int, Team); TC(bool, add);
304         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
305         if(teamslots[num])
306                 return teamslots[num];
307         if (!add)
308                 return NULL;
309         entity tm = new_pure(team);
310         tm.team = Team;
311         teamslots[num] = tm;
312         RegisterTeam(tm);
313         return tm;
314 }
315
316 .float has_team;
317 bool SetTeam(entity o, int Team)
318 {
319         TC(int, Team);
320         //devassert_once(Team);
321         entity tm;
322         if(teamplay)
323         {
324                 switch(Team)
325                 {
326                         case -1:
327                         case NUM_TEAM_1:
328                         case NUM_TEAM_2:
329                         case NUM_TEAM_3:
330                         case NUM_TEAM_4:
331                                 break;
332                         default:
333                                 if(GetTeam(Team, false) == NULL)
334                                 {
335                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
336                                         Team = NUM_SPECTATOR;
337                                 }
338                                 break;
339                 }
340         }
341         else
342         {
343                 switch(Team)
344                 {
345                         case -1:
346                         case 0:
347                                 break;
348                         default:
349                                 if(GetTeam(Team, false) == NULL)
350                                 {
351                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
352                                         Team = NUM_SPECTATOR;
353                                 }
354                                 break;
355                 }
356         }
357         if(Team == -1) // leave
358         {
359                 if(o.has_team)
360                 {
361                         tm = GetTeam(o.team, false);
362                         tm.team_size -= 1;
363                         o.has_team = 0;
364                         return true;
365                 }
366         }
367         else
368         {
369                 if (!o.has_team)
370                 {
371                         o.team = Team;
372                         tm = GetTeam(Team, true);
373                         tm.team_size += 1;
374                         o.has_team = 1;
375                         return true;
376                 }
377                 else if(Team != o.team)
378                 {
379                         tm = GetTeam(o.team, false);
380                         tm.team_size -= 1;
381                         o.team = Team;
382                         tm = GetTeam(Team, true);
383                         tm.team_size += 1;
384                         return true;
385                 }
386         }
387         return false;
388 }
389
390 void Playerchecker_Think(entity this)
391 {
392         int i;
393         entity e;
394         for(i = 0; i < maxclients; ++i)
395         {
396                 e = playerslots[i];
397                 if(entcs_GetName(i) == "")
398                 {
399                         if(e.sort_prev)
400                         {
401                                 // player disconnected
402                                 SetTeam(e, -1);
403                                 RemovePlayer(e);
404                                 e.sort_prev = NULL;
405                                 //e.gotscores = 0;
406                         }
407                 }
408                 else
409                 {
410                         if (!e.sort_prev)
411                         {
412                                 // player connected
413                                 if (!e)
414                                 {
415                                         playerslots[i] = e = new_pure(playerslot);
416                                 }
417                                 e.sv_entnum = i;
418                                 e.ping = 0;
419                                 e.ping_packetloss = 0;
420                                 e.ping_movementloss = 0;
421                                 //e.gotscores = 0; // we might already have the scores...
422                                 int t = entcs_GetScoreTeam(i);
423                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
424                                 RegisterPlayer(e);
425                                 Scoreboard_UpdatePlayerPos(e);
426                         }
427                 }
428         }
429         this.nextthink = time + 0.2;
430 }
431
432 void PostInit()
433 {
434         entity playerchecker = new_pure(playerchecker);
435         setthink(playerchecker, Playerchecker_Think);
436         playerchecker.nextthink = time + 0.2;
437
438         TrueAim_Init();
439
440         // this can't be called in CSQC_Init as it'd send cvars too early
441         ReplicateVars_Start();
442
443         postinit = true;
444 }
445
446 void Release_Common_Keys()
447 {
448         localcmd("-fire\n");
449         localcmd("-fire2\n");
450         localcmd("-use\n");
451         localcmd("-hook\n");
452         localcmd("-jump\n");
453 }
454
455 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
456 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
457 // All keys are in ascii.
458 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
459 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
460 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
461 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
462 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
463 {
464         TC(int, bInputType);
465         bool override = false;
466
467         override |= HUD_Scoreboard_InputEvent(bInputType, nPrimary, nSecondary);
468         if (override)
469                 return true;
470
471         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
472         if (override)
473                 return true;
474
475         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
476
477         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
478
479         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
480
481         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
482
483         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
484
485         if(override)
486                 return true;
487
488         if(bInputType == 3 || bInputType == 2)
489                 return false;
490
491         // at this point bInputType can only be 0 or 1 (key pressed or released)
492         bool key_pressed = (bInputType == 0);
493
494         if(key_pressed) {
495                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
496                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
497                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
498                 if(nPrimary == K_TAB) hudShiftState |= S_TAB;
499         }
500         else {
501                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
502                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
503                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
504                 if(nPrimary == K_TAB) hudShiftState -= (hudShiftState & S_TAB);
505         }
506
507         // NOTE: Shift-Escape must be filtered out because it's the hardcoded console shortcut
508         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
509         {
510                 if (hudShiftState & S_TAB)
511                 {
512                         Scoreboard_UI_Enable(0);
513                         return true;
514                 }
515                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
516                 {
517                         localcmd("\nmenu_showgamemenudialog\n");
518                         return true;
519                 }
520         }
521
522         return false;
523 }
524
525 // END REQUIRED CSQC FUNCTIONS
526 // --------------------------------------------------------------------------
527
528 // --------------------------------------------------------------------------
529 // BEGIN OPTIONAL CSQC FUNCTIONS
530
531 void Ent_RemovePlayerScore(entity this)
532 {
533         if(this.owner) {
534                 SetTeam(this.owner, -1);
535                 this.owner.gotscores = 0;
536                 FOREACH(Scores, true, {
537                         this.owner.(scores(it)) = 0; // clear all scores
538                 });
539         }
540 }
541
542 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
543 {
544         make_pure(this);
545         entity o;
546
547         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
548         // (no I've never heard of M-x replace-string, sed, or anything like that)
549         bool isNew = !this.owner; // workaround for DP bug
550         int n = ReadByte()-1;
551
552 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
553         if(!isNew && n != this.sv_entnum)
554         {
555                 //print("A CSQC entity changed its owner!\n");
556                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
557                 isNew = true;
558                 Ent_Remove(this);
559         }
560 #endif
561
562         this.sv_entnum = n;
563
564         o = playerslots[this.sv_entnum];
565         if (!o)
566         {
567                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
568         }
569         this.owner = o;
570         o.sv_entnum = this.sv_entnum;
571         o.gotscores = 1;
572
573         //if (!o.sort_prev)
574         //      RegisterPlayer(o);
575         //playerchecker will do this for us later, if it has not already done so
576
577         int sf = ReadShort();
578         int lf = ReadShort();
579         FOREACH(Scores, true, {
580                 int p = 1 << (i % 16);
581                 if (sf & p)
582                 {
583                         if (lf & p)
584                                 o.(scores(it)) = ReadInt24_t();
585                         else
586                                 o.(scores(it)) = ReadChar();
587                 }
588         });
589
590         return = true;
591
592         if(o.sort_prev)
593                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
594
595         this.entremove = Ent_RemovePlayerScore;
596 }
597
598 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
599 {
600         make_pure(this);
601         int i;
602
603         this.team = ReadByte();
604         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
605
606 #if MAX_TEAMSCORE <= 8
607         int sf = ReadByte();
608         int lf = ReadByte();
609 #else
610         int sf = ReadShort();
611         int lf = ReadShort();
612 #endif
613         for(i = 0; i < MAX_TEAMSCORE; ++i)
614                 if(sf & BIT(i))
615                 {
616                         if(lf & BIT(i))
617                                 o.(teamscores(i)) = ReadInt24_t();
618                         else
619                                 o.(teamscores(i)) = ReadChar();
620                 }
621
622         return = true;
623
624         Scoreboard_UpdateTeamPos(o);
625 }
626
627 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
628 {
629         make_pure(this);
630         float newspectatee_status;
631
632         int f = ReadByte();
633
634         scoreboard_showscores_force = (f & BIT(0));
635
636         if(f & BIT(1))
637         {
638                 newspectatee_status = ReadByte();
639                 if(newspectatee_status == player_localnum + 1)
640                         newspectatee_status = -1; // observing
641         }
642         else
643                 newspectatee_status = 0;
644
645         spectatorbutton_zoom = (f & BIT(2));
646
647         if(f & BIT(4))
648         {
649                 num_spectators = ReadByte();
650
651                 float i, slot;
652
653                 for(i = 0; i < MAX_SPECTATORS; ++i)
654                         spectatorlist[i] = 0; // reset list first
655
656                 int limit = min(num_spectators, MAX_SPECTATORS);
657                 for(i = 0; i < limit; ++i)
658                 {
659                         slot = ReadByte();
660                         spectatorlist[i] = slot - 1;
661                 }
662         }
663         else
664         {
665                 for(int j = 0; j < MAX_SPECTATORS; ++j)
666                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
667                 num_spectators = 0;
668         }
669
670         return = true;
671
672         if(newspectatee_status != spectatee_status)
673         {
674                 // clear race stuff
675                 race_laptime = 0;
676                 race_checkpointtime = 0;
677                 hud_dynamic_shake_factor = -1;
678                 spectatee_status_changed_time = time;
679         }
680         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
681         {
682                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
683                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
684                 )
685                         prev_p_health = -1;
686                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
687                         prev_health = -1;
688         }
689         spectatee_status = newspectatee_status;
690
691         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
692 }
693
694 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
695 {
696         make_pure(this);
697         int i, j, b, f;
698
699         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
700
701         if(!(nags & BIT(2)))
702         {
703                 strfree(vote_called_vote);
704                 vote_active = 0;
705         }
706         else
707         {
708                 vote_active = 1;
709         }
710
711         if(nags & BIT(6))
712         {
713                 vote_yescount = ReadByte();
714                 vote_nocount = ReadByte();
715                 vote_needed = ReadByte();
716                 vote_highlighted = ReadChar();
717         }
718
719         if(nags & BIT(7))
720         {
721                 strcpy(vote_called_vote, ReadString());
722         }
723
724         if(nags & 1)
725         {
726                 for(j = 0; j < maxclients; ++j)
727                         if(playerslots[j])
728                                 playerslots[j].ready = true;
729                 for(i = 1; i <= maxclients; i += 8)
730                 {
731                         f = ReadByte();
732                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
733                                 if (!(f & b))
734                                         if(playerslots[j])
735                                                 playerslots[j].ready = false;
736                 }
737         }
738
739         return = true;
740
741         ready_waiting = (nags & BIT(0));
742         ready_waiting_for_me = (nags & BIT(1));
743         vote_waiting = (nags & BIT(2));
744         vote_waiting_for_me = (nags & BIT(3));
745         warmup_stage = (nags & BIT(4));
746 }
747
748 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
749 {
750         make_pure(this);
751         int sf = 0;
752         serialize(byte, 0, sf);
753         if (sf & 1) {
754                 for (int j = 0; j < maxclients; ++j) {
755                         if (playerslots[j]) {
756                                 playerslots[j].eliminated = true;
757                         }
758                 }
759                 for (int i = 1; i <= maxclients; i += 8) {
760                         int f = 0;
761                         serialize(byte, 0, f);
762                         for (int b = 0; b < 8; ++b) {
763                                 if (f & BIT(b)) continue;
764                                 int j = i - 1 + b;
765                                 if (playerslots[j]) {
766                                         playerslots[j].eliminated = false;
767                                 }
768                         }
769                 }
770         }
771         return true;
772 }
773
774 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
775 {
776         make_pure(this);
777         prandom_debug();
778         float s = ReadShort();
779         psrandom(s);
780         return true;
781 }
782
783 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
784 {
785         make_pure(this);
786         int sf = ReadInt24_t();
787         if (sf == 0) {
788                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
789                         weapon_accuracy[w] = -1;
790                 return true;
791         }
792
793         int f = 1;
794         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
795                 if (sf & f) {
796                         int b = ReadByte();
797                         if (b == 0)
798                                 weapon_accuracy[w] = -1;
799                         else if (b == 255)
800                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
801                         else
802                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
803                 }
804                 f = (f == 0x800000) ? 1 : f * 2;
805         }
806         return true;
807 }
808
809 void Spawn_Draw(entity this)
810 {
811         bool dodraw = autocvar_cl_spawn_point_particles;
812         if(dodraw && autocvar_cl_spawn_point_dist_max)
813         {
814                 vector org = getpropertyvec(VF_ORIGIN);
815                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
816         }
817
818         if(dodraw)
819                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
820 }
821
822 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
823 {
824         float teamnum = (ReadByte() - 1);
825         vector spn_origin = ReadVector();
826
827         this.team = (teamnum + 1);
828
829         //if(is_new)
830         //{
831                 this.origin = spn_origin;
832                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
833                 //droptofloor();
834
835                 /*if(autocvar_cl_spawn_point_model) // needs a model first
836                 {
837                         this.mdl = "models/spawnpoint.md3";
838                         this.colormod = Team_ColorRGB(teamnum);
839                         precache_model(this.mdl);
840                         setmodel(this, this.mdl);
841                         this.drawmask = MASK_NORMAL;
842                         //this.move_movetype = MOVETYPE_NOCLIP;
843                         //this.draw = Spawn_Draw;
844                         IL_PUSH(g_drawables, this);
845                 }*/
846                 this.draw = Spawn_Draw;
847                 if (is_new) IL_PUSH(g_drawables, this);
848         //}
849
850         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
851         return true;
852 }
853
854 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
855 {
856         // If entnum is 0, ONLY do the local spawn actions
857         // this way the server can disable the sending of
858         // spawn origin or such to clients if wanted.
859         float entnum = ReadByte();
860
861         if(entnum)
862         {
863                 this.origin = ReadVector();
864
865                 if(is_new)
866                 {
867                         float teamnum = entcs_GetTeam(entnum - 1);
868
869                         if(autocvar_cl_spawn_event_particles)
870                         {
871                                 switch(teamnum)
872                                 {
873                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
874                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
875                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
876                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
877                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
878                                 }
879                         }
880                         if(autocvar_cl_spawn_event_sound)
881                         {
882                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
883                         }
884                 }
885         }
886         return = true;
887
888         // local spawn actions
889         if(is_new && (!entnum || (entnum == player_localentnum)))
890         {
891                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
892                 {
893                         zoomin_effect = 1;
894                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
895                 }
896
897                 if(autocvar_cl_unpress_zoom_on_spawn)
898                 {
899                         localcmd("-zoom\n");
900                         button_zoom = false;
901                 }
902                 HUD_Radar_Hide_Maximized();
903         }
904         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
905 }
906
907 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
908 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
909 void CSQC_Ent_Update(entity this, bool isnew)
910 {
911         this.sourceLoc = __FILE__":"STR(__LINE__);
912         int t = ReadByte();
913
914         // set up the "time" global for received entities to be correct for interpolation purposes
915         float savetime = time;
916         if(servertime)
917         {
918                 time = servertime;
919         }
920         else
921         {
922                 serverprevtime = time;
923                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
924                 time = serverprevtime + serverdeltatime;
925         }
926
927 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
928         if (this.enttype)
929         {
930                 if (t != this.enttype || isnew)
931                 {
932                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
933                         Ent_Remove(this);
934                         ONREMOVE(this);
935                         clearentity(this);
936                         isnew = true;
937                 }
938         }
939         else
940         {
941                 if (!isnew)
942                 {
943                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
944                         isnew = true;
945                 }
946         }
947 #endif
948         this.enttype = t;
949         bool done = false;
950         FOREACH(LinkedEntities, it.m_id == t, {
951                 if (isnew) this.classname = it.netname;
952                 if (autocvar_developer_csqcentities)
953                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
954                 done = it.m_read(this, NULL, isnew);
955                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
956                 break;
957         });
958         time = savetime;
959         if (!done)
960         {
961                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
962         }
963 }
964
965 // Destructor, but does NOT deallocate the entity by calling remove(). Also
966 // used when an entity changes its type. For an entity that someone interacts
967 // with others, make sure it can no longer do so.
968 void Ent_Remove(entity this)
969 {
970         if(this.entremove) this.entremove(this);
971
972         if(this.skeletonindex)
973         {
974                 skel_delete(this.skeletonindex);
975                 this.skeletonindex = 0;
976         }
977
978         if(this.snd_looping > 0)
979         {
980                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
981                 this.snd_looping = 0;
982         }
983
984         this.enttype = 0;
985         this.classname = "";
986         this.draw = func_null;
987         this.entremove = func_null;
988         // TODO possibly set more stuff to defaults
989 }
990 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
991 void CSQC_Ent_Remove(entity this)
992 {
993         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
994         if (wasfreed(this))
995         {
996                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
997                 return;
998         }
999         if (this.enttype) Ent_Remove(this);
1000         delete(this);
1001 }
1002
1003 void Gamemode_Init()
1004 {
1005         if (!isdemo())
1006         {
1007                 if(!(calledhooks & HOOK_START))
1008                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
1009                 calledhooks |= HOOK_START;
1010         }
1011 }
1012 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1013 void CSQC_Parse_StuffCmd(string strMessage)
1014 {
1015         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1016         localcmd(strMessage);
1017 }
1018 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1019 void CSQC_Parse_Print(string strMessage)
1020 {
1021         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1022         print(ColorTranslateRGB(strMessage));
1023 }
1024
1025 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1026 void CSQC_Parse_CenterPrint(string strMessage)
1027 {
1028         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1029         centerprint_AddStandard(strMessage);
1030 }
1031
1032 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1033 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1034 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1035 bool CSQC_Parse_TempEntity()
1036 {
1037         // Acquire TE ID
1038         int nTEID = ReadByte();
1039
1040         FOREACH(TempEntities, it.m_id == nTEID, {
1041                 if (autocvar_developer_csqcentities)
1042                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1043                 return it.m_read(NULL, NULL, true);
1044         });
1045
1046         if (autocvar_developer_csqcentities)
1047                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1048
1049         // No special logic for this temporary entity; return 0 so the engine can handle it
1050         return false;
1051 }
1052
1053 string forcefog;
1054 void Fog_Force()
1055 {
1056         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1057                 localcmd("\nr_drawfog 0\n");
1058         else if (forcefog != "")
1059                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1060 }
1061
1062 bool net_handle_ServerWelcome();
1063 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1064 {
1065         make_pure(this);
1066         gametype = ReadRegistered(Gametypes);
1067         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1068         HUD_ModIcons_SetFunc();
1069         FOREACH(Scores, true, {
1070                 strcpy(scores_label(it), ReadString());
1071                 scores_flags(it) = ReadByte();
1072         });
1073         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1074         {
1075                 strcpy(teamscores_label(i), ReadString());
1076                 teamscores_flags(i) = ReadByte();
1077         }
1078         bool welcome_msg_too = ReadByte();
1079         if (welcome_msg_too)
1080                 net_handle_ServerWelcome();
1081         return = true;
1082         Scoreboard_InitScores();
1083         Gamemode_Init();
1084 }
1085
1086 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1087 {
1088         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1089
1090         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1091         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1092         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1093         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1094         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1095         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1096         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1097         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1098
1099         strcpy(forcefog, ReadString());
1100
1101         armorblockpercent = ReadByte() / 255.0;
1102         damagepush_speedfactor = ReadByte() / 255.0;
1103
1104         serverflags = ReadByte();
1105
1106         g_trueaim_minrange = ReadCoord();
1107
1108         return = true;
1109
1110         MUTATOR_CALLHOOK(Ent_Init);
1111
1112         if (!postinit) PostInit();
1113 }
1114
1115 float GetSpeedUnitFactor(int speed_unit)
1116 {
1117         switch(speed_unit)
1118         {
1119                 default:
1120                 case 1: return 1.0;
1121                 case 2: return 0.0254;
1122                 case 3: return 0.0254 * 3.6;
1123                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1124                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1125         }
1126 }
1127
1128 string GetSpeedUnit(int speed_unit)
1129 {
1130         switch(speed_unit)
1131         {
1132                 // translator-friendly strings without the initial space
1133                 default:
1134                 case 1: return strcat(" ", _("qu/s"));
1135                 case 2: return strcat(" ", _("m/s"));
1136                 case 3: return strcat(" ", _("km/h"));
1137                 case 4: return strcat(" ", _("mph"));
1138                 case 5: return strcat(" ", _("knots"));
1139         }
1140 }
1141
1142 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1143 {
1144         int b = ReadByte();
1145
1146         switch (b)
1147         {
1148                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1149                         race_checkpoint = ReadByte();
1150                         race_time = ReadInt24_t();
1151                         race_previousbesttime = ReadInt24_t();
1152                         race_mypreviousbesttime = ReadInt24_t();
1153                         string pbestname = ReadString();
1154                         if(autocvar_cl_race_cptimes_onlyself)
1155                         {
1156                                 race_previousbesttime = race_mypreviousbesttime;
1157                                 race_mypreviousbesttime = 0;
1158                                 strcpy(race_previousbestname, "");
1159                         }
1160                         else
1161                                 strcpy(race_previousbestname, pbestname);
1162
1163                         race_checkpointtime = time;
1164
1165                         if(race_checkpoint == 0 || race_checkpoint == 254)
1166                         {
1167                                 race_penaltyaccumulator = 0;
1168                                 race_laptime = time; // valid
1169                         }
1170                         break;
1171
1172                 case RACE_NET_CHECKPOINT_CLEAR:
1173                         race_laptime = 0;
1174                         race_checkpointtime = 0;
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1178                         race_laptime = ReadCoord();
1179                         race_checkpointtime = -99999;
1180                         // fall through
1181                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1182                         race_nextcheckpoint = ReadByte();
1183
1184                         race_nextbesttime = ReadInt24_t();
1185                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1186                                 race_mybesttime = ReadInt24_t();
1187                         string newname = ReadString();
1188                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1189                         {
1190                                 race_nextbesttime = race_mybesttime;
1191                                 race_mybesttime = 0;
1192                                 strcpy(race_nextbestname, "");
1193                         }
1194                         else
1195                                 strcpy(race_nextbestname, newname);
1196                         break;
1197
1198                 case RACE_NET_CHECKPOINT_HIT_RACE:
1199                         race_mycheckpoint = ReadByte();
1200                         race_mycheckpointtime = time;
1201                         race_mycheckpointdelta = ReadInt24_t();
1202                         race_mycheckpointlapsdelta = ReadByte();
1203                         if(race_mycheckpointlapsdelta >= 128)
1204                                 race_mycheckpointlapsdelta -= 256;
1205                         int who = ReadByte();
1206                         if(who)
1207                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1208                         else
1209                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1210                         break;
1211
1212                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1213                         race_othercheckpoint = ReadByte();
1214                         race_othercheckpointtime = time;
1215                         race_othercheckpointdelta = ReadInt24_t();
1216                         race_othercheckpointlapsdelta = ReadByte();
1217                         if(race_othercheckpointlapsdelta >= 128)
1218                                 race_othercheckpointlapsdelta -= 256;
1219                         int what = ReadByte();
1220                         if(what)
1221                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1222                         else
1223                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1224                         break;
1225
1226                 case RACE_NET_PENALTY_RACE:
1227                 case RACE_NET_PENALTY_QUALIFYING:
1228                         race_penaltyeventtime = time;
1229                         race_penaltytime = ReadShort();
1230                         string reason = ReadString();
1231                         if (reason == "missing a checkpoint")
1232                                 reason = _("missing a checkpoint");
1233                         strcpy(race_penaltyreason, reason);
1234                         if (b == RACE_NET_PENALTY_QUALIFYING)
1235                                 race_penaltyaccumulator += race_penaltytime;
1236                         break;
1237
1238                 case RACE_NET_SERVER_RECORD:
1239                         race_server_record = ReadInt24_t();
1240                         break;
1241                 case RACE_NET_SPEED_AWARD:
1242                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1243                         strcpy(race_speedaward_holder, ReadString());
1244                         break;
1245                 case RACE_NET_SPEED_AWARD_BEST:
1246                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1247                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1248                         break;
1249                 case RACE_NET_RANKINGS_CNT:
1250                         RANKINGS_DISPLAY_CNT = ReadByte();
1251                         break;
1252                 case RACE_NET_SERVER_RANKINGS:
1253                         float prevpos, del;
1254                         int pos = ReadShort();
1255                         prevpos = ReadShort();
1256                         del = ReadShort();
1257
1258                         // move other rankings out of the way
1259                         int i;
1260                         if (prevpos) {
1261                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1262                                 for (i=m-1; i>pos-1; --i) {
1263                                         grecordtime[i] = grecordtime[i-1];
1264                                         strcpy(grecordholder[i], grecordholder[i-1]);
1265                                 }
1266                         } else if (del) { // a record has been deleted by the admin
1267                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1268                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1269                                                 grecordtime[i] = 0;
1270                                                 strfree(grecordholder[i]);
1271                                         }
1272                                         else {
1273                                                 grecordtime[i] = grecordtime[i+1];
1274                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1275                                         }
1276                                 }
1277                         } else { // player has no ranked record yet
1278                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1279                                         grecordtime[i] = grecordtime[i-1];
1280                                         strcpy(grecordholder[i], grecordholder[i-1]);
1281                                 }
1282                         }
1283
1284                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1285                                 // kick off the player who fell from the last displayed position
1286                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1287                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1288                         }
1289
1290                         // store new ranking
1291                         strcpy(grecordholder[pos-1], ReadString());
1292                         grecordtime[pos-1] = ReadInt24_t();
1293                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1294                                 race_myrank = pos;
1295                         break;
1296                 case RACE_NET_SERVER_STATUS:
1297                         race_status = ReadShort();
1298                         strcpy(race_status_name, ReadString());
1299         }
1300         return true;
1301 }
1302
1303 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1304 {
1305         teamnagger = 1;
1306         return true;
1307 }
1308
1309 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1310 {
1311         int i = ReadByte();
1312         int pi = ReadShort();
1313         int pl = ReadByte();
1314         int ml = ReadByte();
1315         return = true;
1316         entity e = playerslots[i];
1317         if (!e) return;
1318         e.ping = pi;
1319         e.ping_packetloss = pl / 255.0;
1320         e.ping_movementloss = ml / 255.0;
1321 }
1322
1323 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1324 {
1325         int weapon_id = ReadByte();
1326         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1327         complain_weapon_type = ReadByte();
1328         return = true;
1329
1330         complain_weapon_time = time;
1331         weapontime = time; // ping the weapon panel
1332
1333         switch(complain_weapon_type)
1334         {
1335                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1336                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1337                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1338         }
1339 }
1340
1341 string translate_modifications(string s)
1342 {
1343         return build_mutator_list(s);
1344 }
1345
1346 string translate_weaponarena(string s)
1347 {
1348         if (s == "") return s;
1349         if (s == "All Weapons Arena") return _("All Weapons Arena");
1350         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1351         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1352         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1353         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1354         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1355         if (s == "No Weapons Arena") return _("No Weapons Arena");
1356
1357         int n = tokenizebyseparator(s, " & ");
1358         string wpn_list = "";
1359         for (int i = 0; i < n; i++)
1360         {
1361                 Weapon wep = Weapon_from_name(argv(i));
1362                 if (wep == WEP_Null)
1363                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1364                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1365         }
1366         if (wpn_list != "")
1367                 return sprintf(_("%s Arena"), wpn_list);
1368         else
1369                 return _("No Weapons Arena");
1370 }
1371
1372 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1373 {
1374         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1375         if (version_mismatch)
1376         {
1377                 if(!version_check)
1378                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1379                                 _("Your client version is outdated."), "\n\n\n",
1380                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1381                                 _("Please update!"));
1382                 else
1383                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1384                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1385                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1386         }
1387         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1388 }
1389
1390 bool net_handle_ServerWelcome()
1391 {
1392         bool campaign = ReadByte();
1393         if (campaign)
1394         {
1395                 string campaign_title = ReadString();
1396                 int campaign_level = ReadByte();
1397                 string campaign_msg = ReadString();
1398                 string welcomedialog_args;
1399                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1400                 string key = getcommandkey(_("jump"), "+jump");
1401                 string msg = strcat(
1402                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1403                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1404                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1405                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1406                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1407                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1408                 return true;
1409         }
1410
1411         welcome_msg_force_centerprint = ReadByte();
1412         strcpy(hostname, ReadString());
1413
1414         string hostversion = ReadString();
1415         bool version_mismatch = ReadByte();
1416         bool version_check = ReadByte();
1417         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1418
1419         string modifications = translate_modifications(ReadString());
1420         string weaponarena_list = translate_weaponarena(ReadString());
1421         string cache_mutatormsg = ReadString();
1422         string motd = ReadString();
1423
1424         string msg = "";
1425         msg = strcat(msg, ver);
1426         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1427
1428         modifications = cons_mid(modifications, ", ", weaponarena_list);
1429         if(modifications != "")
1430                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1431
1432         if (cache_mutatormsg != "")
1433                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1434         string mutator_msg = "";
1435         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1436         mutator_msg = M_ARGV(0, string);
1437         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1438
1439         if (motd != "")
1440                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1441
1442         strcpy(welcome_msg, msg);
1443         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1444         return true;
1445 }
1446
1447 void Welcome_Message_Show_Try()
1448 {
1449         if (!welcome_msg_menu_check_maxtime)
1450                 return;
1451
1452         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1453         // if want dialog check if menu is initialized but for a short time
1454         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1455         {
1456                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1457                 {
1458                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1459                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1460                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1461                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1462                 }
1463                 else
1464                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1465
1466                 strfree(welcome_msg);
1467                 welcome_msg_menu_check_maxtime = 0;
1468         }
1469 }
1470
1471 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1472 {
1473         return net_handle_ServerWelcome();
1474 }
1475
1476 string _getcommandkey(string cmd_name, string command, bool forcename)
1477 {
1478         string keys;
1479         float n, j, k, l = 0;
1480
1481         if (!autocvar_hud_showbinds)
1482                 return cmd_name;
1483
1484         keys = db_get(binddb, command);
1485         if (keys == "")
1486         {
1487                 bool joy_active = cvar("joy_active");
1488                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1489                 for(j = 0; j < n; ++j)
1490                 {
1491                         k = stof(argv(j));
1492                         if(k != -1)
1493                         {
1494                                 string key = keynumtostring(k);
1495                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1496                                         continue;
1497
1498                                 key = translate_key(key);
1499
1500                                 if (keys == "")
1501                                         keys = key;
1502                                 else
1503                                         keys = strcat(keys, ", ", key);
1504
1505                                 ++l;
1506                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1507                                         break;
1508                         }
1509
1510                 }
1511                 if (keys == "")
1512                         keys = "NO_KEY";
1513                 db_put(binddb, command, keys);
1514         }
1515
1516         if (keys == "NO_KEY") {
1517                 if (autocvar_hud_showbinds > 1)
1518                         return sprintf(_("%s (not bound)"), cmd_name);
1519                 else
1520                         return cmd_name;
1521         }
1522         else if (autocvar_hud_showbinds > 1 || forcename)
1523                 return sprintf("%s (%s)", cmd_name, keys);
1524         else
1525                 return keys;
1526 }
1527
1528 /** engine callback */
1529 void URI_Get_Callback(int id, int status, string data)
1530 {
1531         TC(int, id); TC(int, status);
1532         if(url_URI_Get_Callback(id, status, data))
1533         {
1534                 // handled
1535         }
1536         else if (id == URI_GET_DISCARD)
1537         {
1538                 // discard
1539         }
1540         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1541         {
1542                 // sv_cmd curl
1543                 Curl_URI_Get_Callback(id, status, data);
1544         }
1545         else
1546         {
1547                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1548         }
1549 }