qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "controlpoint.qh"
   4 #include "damage.qh"
   5 #include "effects.qh"
   6 #include "generator.qh"
   7 #include "gibs.qh"
   8 #include "hook.qh"
   9 #include "hud.qh"
  10 #include "hud_config.qh"
  11 #include "laser.qh"
  12 #include "mapvoting.qh"
  13 #include "modeleffects.qh"
  14 #include "mutators/events.qh"
  15 #include "particles.qh"
  16 #include "quickmenu.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22 #include "weapons/projectile.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/items/all.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/minigames/cl_minigames.qh"
  27 #include "../common/minigames/cl_minigames_hud.qh"
  28 #include "../common/net_notice.qh"
  29 #include "../common/triggers/include.qh"
  30 #include "../common/turrets/cl_turrets.qh"
  31 #include "../common/vehicles/all.qh"
  32 #include "../lib/csqcmodel/cl_model.qh"
  33 #include "../lib/csqcmodel/interpolate.qh"
  34 #include "../lib/warpzone/client.qh"
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 entity clearentity_ent;
  41 void clearentity(entity e)
  42 {
  43         if (!clearentity_ent)
  44         {
  45                 clearentity_ent = spawn();
  46                 clearentity_ent.classname = "clearentity";
  47         }
  48         int n = e.entnum;
  49         copyentity(clearentity_ent, e);
  50         e.entnum = n;
  51 }
  52
  53 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  54 void menu_show_error()
  55 {
  56         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  57 }
  58
  59 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  60 // Useful for precaching things
  61
  62 void menu_sub_null()
  63 {
  64 }
  65
  66 void draw_null(entity this) { }
  67
  68 string forcefog;
  69 void ConsoleCommand_macro_init();
  70 void CSQC_Init(void)
  71 {
  72         prvm_language = strzone(cvar_string("prvm_language"));
  73
  74 #ifdef WATERMARK
  75         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  76 #endif
  77
  78         int i;
  79
  80         binddb = db_create();
  81         tempdb = db_create();
  82         ClientProgsDB = db_load("client.db");
  83         compressShortVector_init();
  84
  85         draw_endBoldFont();
  86         menu_visible = false;
  87         menu_show = menu_show_error;
  88         menu_action = func_null;
  89
  90         for(i = 0; i < 255; ++i)
  91                 if(getplayerkeyvalue(i, "viewentity") == "")
  92                         break;
  93         maxclients = i;
  94
  95         //registercommand("hud_configure");
  96         //registercommand("hud_save");
  97         //registercommand("menu_action");
  98
  99         ConsoleCommand_macro_init();
 100
 101         registercvar("hud_usecsqc", "1");
 102         registercvar("scoreboard_columns", "default");
 103
 104         registercvar("cl_nade_type", "3");
 105         registercvar("cl_pokenade_type", "zombie");
 106
 107         registercvar("cl_jumpspeedcap_min", "");
 108         registercvar("cl_jumpspeedcap_max", "");
 109
 110         registercvar("cl_multijump", "0");
 111
 112         registercvar("cl_spawn_near_teammate", "1");
 113
 114         gametype = 0;
 115
 116         // hud_fields uses strunzone on the titles!
 117         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 118                 hud_title[i] = strzone("(null)");
 119
 120         Cmd_HUD_SetFields(0);
 121
 122         postinit = false;
 123
 124         calledhooks = 0;
 125
 126         teams = Sort_Spawn();
 127         players = Sort_Spawn();
 128
 129         GetTeam(NUM_SPECTATOR, true); // add specs first
 130
 131         // needs to be done so early because of the constants they create
 132         static_init();
 133
 134         // precaches
 135
 136         Projectile_Precache();
 137         Tuba_Precache();
 138
 139         if(autocvar_cl_reticle)
 140         {
 141                 precache_pic("gfx/reticle_normal");
 142                 // weapon reticles are precached in weapon files
 143         }
 144
 145         get_mi_min_max_texcoords(1); // try the CLEVER way first
 146         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 147         shortmapname = mi_shortname;
 148
 149         if(precache_pic(minimapname) == "")
 150         {
 151                 // but maybe we have a non-clever minimap
 152                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 153                 if(precache_pic(minimapname) == "")
 154                         minimapname = ""; // FAIL
 155                 else
 156                         get_mi_min_max_texcoords(0); // load new texcoords
 157         }
 158
 159         mi_center = (mi_min + mi_max) * 0.5;
 160         mi_scale = mi_max - mi_min;
 161         minimapname = strzone(minimapname);
 162
 163         WarpZone_Init();
 164
 165         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 166         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 167 }
 168
 169 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 170 void Shutdown(void)
 171 {
 172         WarpZone_Shutdown();
 173
 174         remove(teams);
 175         remove(players);
 176         db_close(binddb);
 177         db_close(tempdb);
 178         if(autocvar_cl_db_saveasdump)
 179                 db_dump(ClientProgsDB, "client.db");
 180         else
 181                 db_save(ClientProgsDB, "client.db");
 182         db_close(ClientProgsDB);
 183
 184         if(camera_active)
 185                 cvar_set("chase_active",ftos(chase_active_backup));
 186
 187         // unset the event chasecam's chase_active
 188         if(autocvar_chase_active < 0)
 189                 cvar_set("chase_active", "0");
 190
 191         if (!isdemo())
 192         {
 193                 if (!(calledhooks & HOOK_START))
 194                         localcmd("\n_cl_hook_gamestart nop\n");
 195                 if (!(calledhooks & HOOK_END))
 196                         localcmd("\ncl_hook_gameend\n");
 197         }
 198
 199         deactivate_minigame();
 200         HUD_MinigameMenu_Close();
 201 }
 202
 203 .float has_team;
 204 float SetTeam(entity o, int Team)
 205 {
 206         entity tm;
 207         if(teamplay)
 208         {
 209                 switch(Team)
 210                 {
 211                         case -1:
 212                         case NUM_TEAM_1:
 213                         case NUM_TEAM_2:
 214                         case NUM_TEAM_3:
 215                         case NUM_TEAM_4:
 216                                 break;
 217                         default:
 218                                 if(GetTeam(Team, false) == world)
 219                                 {
 220                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 221                                         Team = NUM_SPECTATOR;
 222                                 }
 223                                 break;
 224                 }
 225         }
 226         else
 227         {
 228                 switch(Team)
 229                 {
 230                         case -1:
 231                         case 0:
 232                                 break;
 233                         default:
 234                                 if(GetTeam(Team, false) == world)
 235                                 {
 236                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 237                                         Team = NUM_SPECTATOR;
 238                                 }
 239                                 break;
 240                 }
 241         }
 242         if(Team == -1) // leave
 243         {
 244                 if(o.has_team)
 245                 {
 246                         tm = GetTeam(o.team, false);
 247                         tm.team_size -= 1;
 248                         o.has_team = 0;
 249                         return true;
 250                 }
 251         }
 252         else
 253         {
 254                 if (!o.has_team)
 255                 {
 256                         o.team = Team;
 257                         tm = GetTeam(Team, true);
 258                         tm.team_size += 1;
 259                         o.has_team = 1;
 260                         return true;
 261                 }
 262                 else if(Team != o.team)
 263                 {
 264                         tm = GetTeam(o.team, false);
 265                         tm.team_size -= 1;
 266                         o.team = Team;
 267                         tm = GetTeam(Team, true);
 268                         tm.team_size += 1;
 269                         return true;
 270                 }
 271         }
 272         return false;
 273 }
 274
 275 void Playerchecker_Think()
 276 {SELFPARAM();
 277     int i;
 278         entity e;
 279         for(i = 0; i < maxclients; ++i)
 280         {
 281                 e = playerslots[i];
 282                 if(GetPlayerName(i) == "")
 283                 {
 284                         if(e.sort_prev)
 285                         {
 286                                 // player disconnected
 287                                 SetTeam(e, -1);
 288                                 RemovePlayer(e);
 289                                 e.sort_prev = world;
 290                                 //e.gotscores = 0;
 291                         }
 292                 }
 293                 else
 294                 {
 295                         if (!e.sort_prev)
 296                         {
 297                                 // player connected
 298                                 if (!e)
 299                                         playerslots[i] = e = spawn();
 300                                 e.sv_entnum = i;
 301                                 e.ping = 0;
 302                                 e.ping_packetloss = 0;
 303                                 e.ping_movementloss = 0;
 304                                 //e.gotscores = 0; // we might already have the scores...
 305                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 306                                 RegisterPlayer(e);
 307                                 HUD_UpdatePlayerPos(e);
 308                         }
 309                 }
 310         }
 311         self.nextthink = time + 0.2;
 312 }
 313
 314 void Porto_Init();
 315 void TrueAim_Init();
 316 void PostInit(void)
 317 {
 318         entity playerchecker;
 319         playerchecker = spawn();
 320         playerchecker.think = Playerchecker_Think;
 321         playerchecker.nextthink = time + 0.2;
 322
 323         Porto_Init();
 324         TrueAim_Init();
 325
 326         postinit = true;
 327 }
 328
 329 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 330 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 331 // All keys are in ascii.
 332 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 333 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 334 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 335 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 336 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 337 {
 338         float bSkipKey;
 339         bSkipKey = false;
 340
 341         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 342                 return true;
 343
 344         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 345                 return true;
 346
 347         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 348                 return true;
 349
 350         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 351                 return true;
 352
 353         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 354                 return true;
 355
 356         if(menu_visible && menu_action)
 357                 if(menu_action(bInputType, nPrimary, nSecondary))
 358                         return true;
 359
 360         return bSkipKey;
 361 }
 362
 363 // END REQUIRED CSQC FUNCTIONS
 364 // --------------------------------------------------------------------------
 365
 366 // --------------------------------------------------------------------------
 367 // BEGIN OPTIONAL CSQC FUNCTIONS
 368
 369 void Ent_RemoveEntCS()
 370 {SELFPARAM();
 371         entcs_receiver[self.sv_entnum] = NULL;
 372 }
 373 void Ent_ReadEntCS()
 374 {SELFPARAM();
 375         InterpolateOrigin_Undo();
 376         self.classname = "entcs_receiver";
 377         int sf = ReadByte();
 378
 379         if(sf & BIT(0))
 380                 self.sv_entnum = ReadByte();
 381         if (sf & BIT(1))
 382         {
 383                 self.origin_x = ReadShort();
 384                 self.origin_y = ReadShort();
 385                 self.origin_z = ReadShort();
 386                 setorigin(self, self.origin);
 387         }
 388         if (sf & BIT(2))
 389         {
 390                 self.angles_y = ReadByte() * 360.0 / 256;
 391                 self.angles_x = self.angles_z = 0;
 392         }
 393         if (sf & BIT(3))
 394                 self.healthvalue = ReadByte() * 10;
 395         if (sf & BIT(4))
 396                 self.armorvalue = ReadByte() * 10;
 397
 398         entcs_receiver[self.sv_entnum] = self;
 399         self.entremove = Ent_RemoveEntCS;
 400         self.iflags |= IFLAG_ORIGIN;
 401
 402         InterpolateOrigin_Note();
 403 }
 404
 405 void Ent_Remove();
 406
 407 void Ent_RemovePlayerScore()
 408 {SELFPARAM();
 409         if(self.owner) {
 410                 SetTeam(self.owner, -1);
 411                 self.owner.gotscores = 0;
 412                 for(int i = 0; i < MAX_SCORE; ++i) {
 413                         self.owner.(scores[i]) = 0; // clear all scores
 414                 }
 415         }
 416 }
 417
 418 void Ent_ReadPlayerScore()
 419 {SELFPARAM();
 420         int i, n;
 421         bool isNew;
 422         entity o;
 423
 424         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 425         // (no I've never heard of M-x replace-string, sed, or anything like that)
 426         isNew = !self.owner; // workaround for DP bug
 427         n = ReadByte()-1;
 428
 429 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 430         if(!isNew && n != self.sv_entnum)
 431         {
 432                 //print("A CSQC entity changed its owner!\n");
 433                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 434                 isNew = true;
 435                 Ent_Remove();
 436                 self.enttype = ENT_CLIENT_SCORES;
 437         }
 438 #endif
 439
 440         self.sv_entnum = n;
 441
 442         if (!(playerslots[self.sv_entnum]))
 443                 playerslots[self.sv_entnum] = spawn();
 444         o = self.owner = playerslots[self.sv_entnum];
 445         o.sv_entnum = self.sv_entnum;
 446         o.gotscores = 1;
 447
 448         //if (!o.sort_prev)
 449         //      RegisterPlayer(o);
 450         //playerchecker will do this for us later, if it has not already done so
 451
 452     int sf, lf;
 453 #if MAX_SCORE <= 8
 454         sf = ReadByte();
 455         lf = ReadByte();
 456 #else
 457         sf = ReadShort();
 458         lf = ReadShort();
 459 #endif
 460     int p;
 461         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 462                 if(sf & p)
 463                 {
 464                         if(lf & p)
 465                                 o.(scores[i]) = ReadInt24_t();
 466                         else
 467                                 o.(scores[i]) = ReadChar();
 468                 }
 469
 470         if(o.sort_prev)
 471                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 472
 473         self.entremove = Ent_RemovePlayerScore;
 474 }
 475
 476 void Ent_ReadTeamScore()
 477 {SELFPARAM();
 478         int i;
 479         entity o;
 480
 481         self.team = ReadByte();
 482         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 483
 484     int sf, lf;
 485 #if MAX_TEAMSCORE <= 8
 486         sf = ReadByte();
 487         lf = ReadByte();
 488 #else
 489         sf = ReadShort();
 490         lf = ReadShort();
 491 #endif
 492         int p;
 493         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 494                 if(sf & p)
 495                 {
 496                         if(lf & p)
 497                                 o.(teamscores[i]) = ReadInt24_t();
 498                         else
 499                                 o.(teamscores[i]) = ReadChar();
 500                 }
 501
 502         HUD_UpdateTeamPos(o);
 503 }
 504
 505 void Ent_ClientData()
 506 {
 507         float newspectatee_status;
 508
 509     int f = ReadByte();
 510
 511         scoreboard_showscores_force = (f & 1);
 512
 513         if(f & 2)
 514         {
 515                 newspectatee_status = ReadByte();
 516                 if(newspectatee_status == player_localnum + 1)
 517                         newspectatee_status = -1; // observing
 518         }
 519         else
 520                 newspectatee_status = 0;
 521
 522         spectatorbutton_zoom = (f & 4);
 523
 524         if(f & 8)
 525         {
 526                 angles_held_status = 1;
 527                 angles_held.x = ReadAngle();
 528                 angles_held.y = ReadAngle();
 529                 angles_held.z = 0;
 530         }
 531         else
 532                 angles_held_status = 0;
 533
 534         if(newspectatee_status != spectatee_status)
 535         {
 536                 // clear race stuff
 537                 race_laptime = 0;
 538                 race_checkpointtime = 0;
 539         }
 540         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 541         {
 542                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 543                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 544                 )
 545                         prev_p_health = -1;
 546                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 547                         prev_health = -1;
 548         }
 549         spectatee_status = newspectatee_status;
 550
 551         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 552 }
 553
 554 void Ent_Nagger()
 555 {
 556     int i, j, b, f;
 557
 558     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 559
 560         if(!(nags & 4))
 561         {
 562                 if(vote_called_vote)
 563                         strunzone(vote_called_vote);
 564                 vote_called_vote = string_null;
 565                 vote_active = 0;
 566         }
 567         else
 568         {
 569                 vote_active = 1;
 570         }
 571
 572         if(nags & 64)
 573         {
 574                 vote_yescount = ReadByte();
 575                 vote_nocount = ReadByte();
 576                 vote_needed = ReadByte();
 577                 vote_highlighted = ReadChar();
 578         }
 579
 580         if(nags & 128)
 581         {
 582                 if(vote_called_vote)
 583                         strunzone(vote_called_vote);
 584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 585         }
 586
 587         if(nags & 1)
 588         {
 589                 for(j = 0; j < maxclients; ++j)
 590                         if(playerslots[j])
 591                                 playerslots[j].ready = 1;
 592                 for(i = 1; i <= maxclients; i += 8)
 593                 {
 594                         f = ReadByte();
 595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 596                                 if (!(f & b))
 597                                         if(playerslots[j])
 598                                                 playerslots[j].ready = 0;
 599                 }
 600         }
 601
 602         ready_waiting = (nags & 1);
 603         ready_waiting_for_me = (nags & 2);
 604         vote_waiting = (nags & 4);
 605         vote_waiting_for_me = (nags & 8);
 606         warmup_stage = (nags & 16);
 607 }
 608
 609 void Ent_EliminatedPlayers()
 610 {
 611     int i, j, b, f;
 612
 613     int sf = ReadByte();
 614         if(sf & 1)
 615         {
 616                 for(j = 0; j < maxclients; ++j)
 617                         if(playerslots[j])
 618                                 playerslots[j].eliminated = 1;
 619                 for(i = 1; i <= maxclients; i += 8)
 620                 {
 621                         f = ReadByte();
 622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 623                                 if (!(f & b))
 624                                         if(playerslots[j])
 625                                                 playerslots[j].eliminated = 0;
 626                 }
 627         }
 628 }
 629
 630 void Ent_RandomSeed()
 631 {
 632         float s;
 633         prandom_debug();
 634         s = ReadShort();
 635         psrandom(s);
 636 }
 637
 638 void Ent_ReadAccuracy(void)
 639 {
 640     int f, w;
 641     int sf = ReadInt24_t();
 642         if(sf == 0)
 643         {
 644                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 645                         weapon_accuracy[w] = -1;
 646                 return;
 647         }
 648
 649         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 650         {
 651                 if(sf & f)
 652                 {
 653             int b = ReadByte();
 654                         if(b == 0)
 655                                 weapon_accuracy[w] = -1;
 656                         else if(b == 255)
 657                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 658                         else
 659                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 660                 }
 661                 if(f == 0x800000)
 662                         f = 1;
 663                 else
 664                         f *= 2;
 665         }
 666 }
 667
 668 void Spawn_Draw(entity this)
 669 {
 670         pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 671 }
 672
 673 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 674 {SELFPARAM();
 675         float teamnum = (ReadByte() - 1);
 676         vector spn_origin;
 677         spn_origin.x = ReadShort();
 678         spn_origin.y = ReadShort();
 679         spn_origin.z = ReadShort();
 680
 681         if(is_new)
 682         {
 683                 self.origin = spn_origin;
 684                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 685                 droptofloor();
 686
 687                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 688                 {
 689                         self.mdl = "models/spawnpoint.md3";
 690                         self.colormod = Team_ColorRGB(teamnum);
 691                         precache_model(self.mdl);
 692                         setmodel(self, self.mdl);
 693                         self.drawmask = MASK_NORMAL;
 694                         //self.movetype = MOVETYPE_NOCLIP;
 695                         //self.draw = Spawn_Draw;
 696                 }*/
 697                 if(autocvar_cl_spawn_point_particles)
 698                 {
 699                         if((serverflags & SERVERFLAG_TEAMPLAY))
 700                         {
 701                                 switch(teamnum)
 702                                 {
 703                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 704                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 705                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 706                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 707                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 708                                 }
 709                         }
 710                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 711
 712                         self.draw = Spawn_Draw;
 713                 }
 714         }
 715
 716         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 717 }
 718
 719 void Ent_ReadSpawnEvent(float is_new)
 720 {SELFPARAM();
 721         // If entnum is 0, ONLY do the local spawn actions
 722         // this way the server can disable the sending of
 723         // spawn origin or such to clients if wanted.
 724         float entnum = ReadByte();
 725
 726         if(entnum)
 727         {
 728                 self.origin_x = ReadShort();
 729                 self.origin_y = ReadShort();
 730                 self.origin_z = ReadShort();
 731
 732                 if(is_new)
 733                 {
 734                         float teamnum = GetPlayerColor(entnum - 1);
 735
 736                         if(autocvar_cl_spawn_event_particles)
 737                         {
 738                                 switch(teamnum)
 739                                 {
 740                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 741                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 742                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 743                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 744                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 745                                 }
 746                         }
 747                         if(autocvar_cl_spawn_event_sound)
 748                         {
 749                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 750                         }
 751                 }
 752         }
 753
 754         // local spawn actions
 755         if(is_new && (!entnum || (entnum == player_localentnum)))
 756         {
 757                 zoomin_effect = 1;
 758                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 759
 760                 if(autocvar_cl_unpress_zoom_on_spawn)
 761                 {
 762                         localcmd("-zoom\n");
 763                         button_zoom = false;
 764                 }
 765         }
 766         HUD_Radar_Hide_Maximized();
 767         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 768 }
 769
 770 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 771 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 772 void Ent_RadarLink();
 773 void Ent_Init();
 774 void Ent_ScoresInfo();
 775 void CSQC_Ent_Update(float bIsNewEntity)
 776 {SELFPARAM();
 777         int t = ReadByte();
 778
 779         if(autocvar_developer_csqcentities)
 780                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 781
 782         // set up the "time" global for received entities to be correct for interpolation purposes
 783         float savetime = time;
 784         if(servertime)
 785         {
 786                 time = servertime;
 787         }
 788         else
 789         {
 790                 serverprevtime = time;
 791                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 792                 time = serverprevtime + serverdeltatime;
 793         }
 794
 795 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 796         if(self.enttype)
 797         {
 798                 if(t != self.enttype || bIsNewEntity)
 799                 {
 800                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 801                         Ent_Remove();
 802                         clearentity(self);
 803                         bIsNewEntity = 1;
 804                 }
 805         }
 806         else
 807         {
 808                 if(!bIsNewEntity)
 809                 {
 810                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 811                         bIsNewEntity = 1;
 812                 }
 813         }
 814 #endif
 815         self.enttype = t;
 816         bool done = false;
 817         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 818                 it.m_read(self, bIsNewEntity);
 819                 done = true;
 820                 break;
 821         ));
 822         if (!done)
 823         switch(t)
 824         {
 825                 case ENT_CLIENT_MUTATOR: {
 826                         int mutID = ReadMutator();
 827                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 828                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 829                         break;
 830                 }
 831                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 832                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 833                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 834                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 835                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 836                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 837                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 838                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 839                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 840                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 841                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 842                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 843                 case ENT_CLIENT_INIT: Ent_Init(); break;
 844                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 845                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 846                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 847                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 848                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 849                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 850                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 851                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 852                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 853                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 854                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 855                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 856                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 857                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 858                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 859                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 860                 case ENT_CLIENT_TURRET: ent_turret(); break;
 861                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 862                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
 863                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 864                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 865                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 866                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 867                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 868                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 869                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 870                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 871                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 872                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 873                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 874                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 875                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 876                 case ENT_CLIENT_DOOR: ent_door(); break;
 877                 case ENT_CLIENT_PLAT: ent_plat(); break;
 878                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 879                 case ENT_CLIENT_CORNER: ent_corner(); break;
 880                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 881                 case ENT_CLIENT_TRAIN: ent_train(); break;
 882                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 883                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 884
 885                 default:
 886                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 887                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 888                         break;
 889         }
 890
 891         time = savetime;
 892 }
 893 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 894 // used when an entity changes its type. For an entity that someone interacts
 895 // with others, make sure it can no longer do so.
 896 void Ent_Remove()
 897 {SELFPARAM();
 898         if(self.entremove)
 899                 self.entremove();
 900
 901         if(self.skeletonindex)
 902         {
 903                 skel_delete(self.skeletonindex);
 904                 self.skeletonindex = 0;
 905         }
 906
 907         if(self.snd_looping > 0)
 908         {
 909                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 910                 self.snd_looping = 0;
 911         }
 912
 913         self.enttype = 0;
 914         self.classname = "";
 915         self.draw = draw_null;
 916         self.entremove = menu_sub_null;
 917         // TODO possibly set more stuff to defaults
 918 }
 919 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 920 void CSQC_Ent_Remove()
 921 {SELFPARAM();
 922         if(autocvar_developer_csqcentities)
 923                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 924
 925         if(wasfreed(self))
 926         {
 927                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 928                 return;
 929         }
 930         if(self.enttype)
 931                 Ent_Remove();
 932         remove(self);
 933 }
 934
 935 void Gamemode_Init()
 936 {
 937         if (!isdemo())
 938         {
 939                 if(!(calledhooks & HOOK_START))
 940                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 941                 calledhooks |= HOOK_START;
 942         }
 943 }
 944 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 945 void CSQC_Parse_StuffCmd(string strMessage)
 946 {
 947         if(autocvar_developer_csqcentities)
 948                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 949
 950         localcmd(strMessage);
 951 }
 952 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 953 void CSQC_Parse_Print(string strMessage)
 954 {
 955         if(autocvar_developer_csqcentities)
 956                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 957
 958         print(ColorTranslateRGB(strMessage));
 959 }
 960
 961 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 962 void CSQC_Parse_CenterPrint(string strMessage)
 963 {
 964         if(autocvar_developer_csqcentities)
 965                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 966
 967         centerprint_hud(strMessage);
 968 }
 969
 970 string notranslate_fogcmd1 = "\nfog ";
 971 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 972 void Fog_Force()
 973 {
 974         // TODO somehow thwart prvm_globalset client ...
 975
 976         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 977                 { localcmd("\nr_drawfog 0\n"); }
 978         else if(forcefog != "")
 979                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 980 }
 981
 982 void Gamemode_Init();
 983 void Ent_ScoresInfo()
 984 {SELFPARAM();
 985     int i;
 986         self.classname = "ent_client_scores_info";
 987         gametype = ReadInt24_t();
 988         HUD_ModIcons_SetFunc();
 989         for(i = 0; i < MAX_SCORE; ++i)
 990         {
 991                 if(scores_label[i])
 992                         strunzone(scores_label[i]);
 993                 scores_label[i] = strzone(ReadString());
 994                 scores_flags[i] = ReadByte();
 995         }
 996         for(i = 0; i < MAX_TEAMSCORE; ++i)
 997         {
 998                 if(teamscores_label[i])
 999                         strunzone(teamscores_label[i]);
1000                 teamscores_label[i] = strzone(ReadString());
1001                 teamscores_flags[i] = ReadByte();
1002         }
1003         HUD_InitScores();
1004         Gamemode_Init();
1005 }
1006
1007 void Ent_Init()
1008 {SELFPARAM();
1009         self.classname = "ent_client_init";
1010
1011         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1012
1013         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1014         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1015         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1016         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1017         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1018         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1019         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1020         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1021
1022         if(forcefog)
1023                 strunzone(forcefog);
1024         forcefog = strzone(ReadString());
1025
1026         armorblockpercent = ReadByte() / 255.0;
1027
1028         g_balance_mortar_bouncefactor = ReadCoord();
1029         g_balance_mortar_bouncestop = ReadCoord();
1030         g_balance_electro_secondary_bouncefactor = ReadCoord();
1031         g_balance_electro_secondary_bouncestop = ReadCoord();
1032
1033         vortex_scope = !ReadByte();
1034         rifle_scope = !ReadByte();
1035
1036         serverflags = ReadByte();
1037
1038         minelayer_maxmines = ReadByte();
1039
1040         hagar_maxrockets = ReadByte();
1041
1042         g_trueaim_minrange = ReadCoord();
1043         g_balance_porto_secondary = ReadByte();
1044
1045         if(!postinit)
1046                 PostInit();
1047 }
1048
1049 void Net_ReadRace()
1050 {
1051         float b;
1052
1053         b = ReadByte();
1054
1055         switch(b)
1056         {
1057                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1058                         race_checkpoint = ReadByte();
1059                         race_time = ReadInt24_t();
1060                         race_previousbesttime = ReadInt24_t();
1061                         if(race_previousbestname)
1062                                 strunzone(race_previousbestname);
1063                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1064
1065                         race_checkpointtime = time;
1066
1067                         if(race_checkpoint == 0 || race_checkpoint == 254)
1068                         {
1069                                 race_penaltyaccumulator = 0;
1070                                 race_laptime = time; // valid
1071                         }
1072
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_CLEAR:
1076                         race_laptime = 0;
1077                         race_checkpointtime = 0;
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1081                         race_laptime = ReadCoord();
1082                         race_checkpointtime = -99999;
1083                         // fall through
1084                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1085                         race_nextcheckpoint = ReadByte();
1086
1087                         race_nextbesttime = ReadInt24_t();
1088                         if(race_nextbestname)
1089                                 strunzone(race_nextbestname);
1090                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1091                         break;
1092
1093                 case RACE_NET_CHECKPOINT_HIT_RACE:
1094                         race_mycheckpoint = ReadByte();
1095                         race_mycheckpointtime = time;
1096                         race_mycheckpointdelta = ReadInt24_t();
1097                         race_mycheckpointlapsdelta = ReadByte();
1098                         if(race_mycheckpointlapsdelta >= 128)
1099                                 race_mycheckpointlapsdelta -= 256;
1100                         if(race_mycheckpointenemy)
1101                                 strunzone(race_mycheckpointenemy);
1102                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1106                         race_othercheckpoint = ReadByte();
1107                         race_othercheckpointtime = time;
1108                         race_othercheckpointdelta = ReadInt24_t();
1109                         race_othercheckpointlapsdelta = ReadByte();
1110                         if(race_othercheckpointlapsdelta >= 128)
1111                                 race_othercheckpointlapsdelta -= 256;
1112                         if(race_othercheckpointenemy)
1113                                 strunzone(race_othercheckpointenemy);
1114                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1115                         break;
1116
1117                 case RACE_NET_PENALTY_RACE:
1118                         race_penaltyeventtime = time;
1119                         race_penaltytime = ReadShort();
1120                         //race_penaltyaccumulator += race_penaltytime;
1121                         if(race_penaltyreason)
1122                                 strunzone(race_penaltyreason);
1123                         race_penaltyreason = strzone(ReadString());
1124                         break;
1125
1126                 case RACE_NET_PENALTY_QUALIFYING:
1127                         race_penaltyeventtime = time;
1128                         race_penaltytime = ReadShort();
1129                         race_penaltyaccumulator += race_penaltytime;
1130                         if(race_penaltyreason)
1131                                 strunzone(race_penaltyreason);
1132                         race_penaltyreason = strzone(ReadString());
1133                         break;
1134
1135                 case RACE_NET_SERVER_RECORD:
1136                         race_server_record = ReadInt24_t();
1137                         break;
1138                 case RACE_NET_SPEED_AWARD:
1139                         race_speedaward = ReadInt24_t();
1140                         if(race_speedaward_holder)
1141                                 strunzone(race_speedaward_holder);
1142                         race_speedaward_holder = strzone(ReadString());
1143                         break;
1144                 case RACE_NET_SPEED_AWARD_BEST:
1145                         race_speedaward_alltimebest = ReadInt24_t();
1146                         if(race_speedaward_alltimebest_holder)
1147                                 strunzone(race_speedaward_alltimebest_holder);
1148                         race_speedaward_alltimebest_holder = strzone(ReadString());
1149                         break;
1150                 case RACE_NET_SERVER_RANKINGS:
1151                         float prevpos, del;
1152             int pos = ReadShort();
1153                         prevpos = ReadShort();
1154                         del = ReadShort();
1155
1156                         // move other rankings out of the way
1157             int i;
1158                         if (prevpos) {
1159                                 for (i=prevpos-1;i>pos-1;--i) {
1160                                         grecordtime[i] = grecordtime[i-1];
1161                                         if(grecordholder[i])
1162                                                 strunzone(grecordholder[i]);
1163                                         grecordholder[i] = strzone(grecordholder[i-1]);
1164                                 }
1165                         } else if (del) { // a record has been deleted by the admin
1166                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1167                                         if (i == RANKINGS_CNT-1) { // clear out last record
1168                                                 grecordtime[i] = 0;
1169                                                 if (grecordholder[i])
1170                                                         strunzone(grecordholder[i]);
1171                                                 grecordholder[i] = string_null;
1172                                         }
1173                                         else {
1174                                                 grecordtime[i] = grecordtime[i+1];
1175                                                 if (grecordholder[i])
1176                                                         strunzone(grecordholder[i]);
1177                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1178                                         }
1179                                 }
1180                         } else { // player has no ranked record yet
1181                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1182                                         grecordtime[i] = grecordtime[i-1];
1183                                         if(grecordholder[i])
1184                                                 strunzone(grecordholder[i]);
1185                                         grecordholder[i] = strzone(grecordholder[i-1]);
1186                                 }
1187                         }
1188
1189                         // store new ranking
1190                         if(grecordholder[pos-1] != "")
1191                                 strunzone(grecordholder[pos-1]);
1192                         grecordholder[pos-1] = strzone(ReadString());
1193                         grecordtime[pos-1] = ReadInt24_t();
1194                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1195                                 race_myrank = pos;
1196                         break;
1197                 case RACE_NET_SERVER_STATUS:
1198                         race_status = ReadShort();
1199                         if(race_status_name)
1200                                 strunzone(race_status_name);
1201                         race_status_name = strzone(ReadString());
1202         }
1203 }
1204
1205 void Net_TeamNagger()
1206 {
1207         teamnagger = 1;
1208 }
1209
1210 void Net_ReadPingPLReport()
1211 {
1212         int e, pi, pl, ml;
1213         e = ReadByte();
1214         pi = ReadShort();
1215         pl = ReadByte();
1216         ml = ReadByte();
1217         if (!(playerslots[e]))
1218                 return;
1219         playerslots[e].ping = pi;
1220         playerslots[e].ping_packetloss = pl / 255.0;
1221         playerslots[e].ping_movementloss = ml / 255.0;
1222 }
1223
1224 void Net_WeaponComplain()
1225 {
1226         complain_weapon = ReadByte();
1227
1228         if(complain_weapon_name)
1229                 strunzone(complain_weapon_name);
1230         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1231
1232         complain_weapon_type = ReadByte();
1233
1234         complain_weapon_time = time;
1235         weapontime = time; // ping the weapon panel
1236
1237         switch(complain_weapon_type)
1238         {
1239                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1240                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1241                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1242         }
1243 }
1244
1245 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1246 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1247 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1248 bool CSQC_Parse_TempEntity()
1249 {
1250         // Acquire TE ID
1251         int nTEID = ReadByte();
1252
1253         if (autocvar_developer_csqcentities)
1254                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1255
1256         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1257                 it.m_read(NULL, true);
1258                 return true;
1259         ));
1260         switch (nTEID)
1261         {
1262                 case TE_CSQC_MUTATOR:
1263                         int mutID = ReadMutator();
1264                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1265                         return true;
1266                 case TE_CSQC_TARGET_MUSIC:
1267                         Net_TargetMusic();
1268                         return true;
1269                 case TE_CSQC_PICTURE:
1270                         Net_MapVote_Picture();
1271                         return true;
1272                 case TE_CSQC_RACE:
1273                         Net_ReadRace();
1274                         return true;
1275                 case TE_CSQC_VORTEXBEAMPARTICLE:
1276                         Net_ReadVortexBeamParticle();
1277                         return true;
1278                 case TE_CSQC_TEAMNAGGER:
1279                         Net_TeamNagger();
1280                         return true;
1281                 case TE_CSQC_ARC:
1282                         Net_ReadArc();
1283                         return true;
1284                 case TE_CSQC_PINGPLREPORT:
1285                         Net_ReadPingPLReport();
1286                         return true;
1287                 case TE_CSQC_WEAPONCOMPLAIN:
1288                         Net_WeaponComplain();
1289                         return true;
1290                 case TE_CSQC_VEHICLESETUP:
1291                         Net_VehicleSetup();
1292                         return true;
1293                 case TE_CSQC_SVNOTICE:
1294                         cl_notice_read();
1295                         return true;
1296                 case TE_CSQC_SHOCKWAVEPARTICLE:
1297                         Net_ReadShockwaveParticle();
1298                         return true;
1299                 default:
1300                         // No special logic for this temporary entity; return 0 so the engine can handle it
1301                         return false;
1302         }
1303 }
1304
1305 string getcommandkey(string text, string command)
1306 {
1307         string keys;
1308         float n, j, k, l = 0;
1309
1310         if (!autocvar_hud_showbinds)
1311                 return text;
1312
1313         keys = db_get(binddb, command);
1314         if (keys == "")
1315         {
1316                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1317                 for(j = 0; j < n; ++j)
1318                 {
1319                         k = stof(argv(j));
1320                         if(k != -1)
1321                         {
1322                                 if ("" == keys)
1323                                         keys = keynumtostring(k);
1324                                 else
1325                                         keys = strcat(keys, ", ", keynumtostring(k));
1326
1327                                 ++l;
1328                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1329                                         break;
1330                         }
1331
1332                 }
1333                 if (keys == "")
1334                         keys = "NO_KEY";
1335                 db_put(binddb, command, keys);
1336         }
1337
1338         if (keys == "NO_KEY") {
1339                 if (autocvar_hud_showbinds > 1)
1340                         return sprintf(_("%s (not bound)"), text);
1341                 else
1342                         return text;
1343         }
1344         else if (autocvar_hud_showbinds > 1)
1345                 return sprintf("%s (%s)", text, keys);
1346         else
1347                 return keys;
1348 }