qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/scoreboard.qh"
  15 #include "hud/panel/quickmenu.qh"
  16 #include "shownames.qh"
  17 #include "view.qh"
  18 #include <common/t_items.qh>
  19 #include "weapons/projectile.qh"
  20 #include <common/deathtypes/all.qh>
  21 #include <common/items/_mod.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/minigames/cl_minigames.qh>
  24 #include <common/minigames/cl_minigames_hud.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/net_notice.qh>
  27 #include <common/scores.qh>
  28 #include <common/mapobjects/_mod.qh>
  29 #include <common/vehicles/all.qh>
  30 #include <lib/csqcmodel/cl_model.qh>
  31 #include <lib/csqcmodel/interpolate.qh>
  32 #include <lib/warpzone/client.qh>
  33
  34 // --------------------------------------------------------------------------
  35 // BEGIN REQUIRED CSQC FUNCTIONS
  36 //include "main.qh"
  37
  38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  39
  40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  41 {
  42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  44 }
  45
  46 void draw_cursor_normal(vector pos, vector col, float a)
  47 {
  48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  49 }
  50
  51 void LoadMenuSkinValues()
  52 {
  53         int fh = -1;
  54         if(cvar_string("menu_skin") != "")
  55         {
  56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  58         }
  59         if(fh < 0 && cvar_defstring("menu_skin") != "")
  60         {
  61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  64         }
  65         if(fh < 0)
  66         {
  67                 draw_currentSkin = "gfx/menu/default";
  68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  69         }
  70
  71         draw_currentSkin = strzone(draw_currentSkin);
  72
  73         if(fh >= 0)
  74         {
  75                 string s;
  76                 while((s = fgets(fh)))
  77                 {
  78                         int n = tokenize_console(s);
  79                         if (n < 2)
  80                                 continue;
  81                         if(substring(argv(0), 0, 2) == "//")
  82                                 continue;
  83                         if(argv(0) == "SIZE_CURSOR")
  84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  85                         else if(argv(0) == "OFFSET_CURSOR")
  86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  87                 }
  88                 fclose(fh);
  89         }
  90 }
  91
  92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  93 // Useful for precaching things
  94
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_shootfromfixedorigin", "");
 138
 139         registercvar("cl_multijump", "1");
 140
 141         registercvar("cl_spawn_near_teammate", "1");
 142
 143         if(autocvar_cl_lockview)
 144                 cvar_set("cl_lockview", "0");
 145
 146         gametype = NULL;
 147
 148         postinit = false;
 149
 150         calledhooks = 0;
 151
 152         teams = Sort_Spawn();
 153         players = Sort_Spawn();
 154
 155         GetTeam(NUM_SPECTATOR, true); // add specs first
 156
 157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 158                 weapon_accuracy[w] = -1;
 159
 160         // precaches
 161
 162         if(autocvar_cl_reticle)
 163         {
 164                 precache_pic("gfx/reticle_normal");
 165                 // weapon reticles are precached in weapon files
 166         }
 167
 168         {
 169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 171                 shortmapname = mi_shortname;
 172
 173                 if (precache_pic(minimapname) == "")
 174                 {
 175                         // but maybe we have a non-clever minimap
 176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 177                         if (precache_pic(minimapname) == "")
 178                                 minimapname = ""; // FAIL
 179                         else
 180                                 get_mi_min_max_texcoords(0); // load new texcoords
 181                 }
 182
 183                 mi_center = (mi_min + mi_max) * 0.5;
 184                 mi_scale = mi_max - mi_min;
 185                 minimapname = strzone(minimapname);
 186         }
 187
 188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 189         LoadMenuSkinValues();
 190 }
 191
 192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 193 void Shutdown()
 194 {
 195         WarpZone_Shutdown();
 196
 197         delete(teams);
 198         delete(players);
 199         db_close(binddb);
 200         db_close(tempdb);
 201         if(autocvar_cl_db_saveasdump)
 202                 db_dump(ClientProgsDB, "client.db");
 203         else
 204                 db_save(ClientProgsDB, "client.db");
 205         db_close(ClientProgsDB);
 206
 207         if(camera_active)
 208                 cvar_set("chase_active",ftos(chase_active_backup));
 209
 210         // unset the event chasecam's chase_active
 211         if(autocvar_chase_active < 0)
 212                 cvar_set("chase_active", "0");
 213
 214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 215
 216         if (!isdemo())
 217         {
 218                 if (!(calledhooks & HOOK_START))
 219                         localcmd("\n_cl_hook_gamestart nop\n");
 220                 if (!(calledhooks & HOOK_END))
 221                         localcmd("\ncl_hook_gameend\n");
 222         }
 223
 224         localcmd("\ncl_hook_shutdown\n");
 225
 226         deactivate_minigame();
 227         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 228 }
 229
 230 .float has_team;
 231 float SetTeam(entity o, int Team)
 232 {
 233     TC(int, Team);
 234         devassert_once(Team);
 235         entity tm;
 236         if(teamplay)
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case NUM_TEAM_1:
 242                         case NUM_TEAM_2:
 243                         case NUM_TEAM_3:
 244                         case NUM_TEAM_4:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == NULL)
 248                                 {
 249                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         else
 256         {
 257                 switch(Team)
 258                 {
 259                         case -1:
 260                         case 0:
 261                                 break;
 262                         default:
 263                                 if(GetTeam(Team, false) == NULL)
 264                                 {
 265                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 266                                         Team = NUM_SPECTATOR;
 267                                 }
 268                                 break;
 269                 }
 270         }
 271         if(Team == -1) // leave
 272         {
 273                 if(o.has_team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.has_team = 0;
 278                         return true;
 279                 }
 280         }
 281         else
 282         {
 283                 if (!o.has_team)
 284                 {
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         o.has_team = 1;
 289                         return true;
 290                 }
 291                 else if(Team != o.team)
 292                 {
 293                         tm = GetTeam(o.team, false);
 294                         tm.team_size -= 1;
 295                         o.team = Team;
 296                         tm = GetTeam(Team, true);
 297                         tm.team_size += 1;
 298                         return true;
 299                 }
 300         }
 301         return false;
 302 }
 303
 304 void Playerchecker_Think(entity this)
 305 {
 306     int i;
 307         entity e;
 308         for(i = 0; i < maxclients; ++i)
 309         {
 310                 e = playerslots[i];
 311                 if(entcs_GetName(i) == "")
 312                 {
 313                         if(e.sort_prev)
 314                         {
 315                                 // player disconnected
 316                                 SetTeam(e, -1);
 317                                 RemovePlayer(e);
 318                                 e.sort_prev = NULL;
 319                                 //e.gotscores = 0;
 320                         }
 321                 }
 322                 else
 323                 {
 324                         if (!e.sort_prev)
 325                         {
 326                                 // player connected
 327                                 if (!e)
 328                                 {
 329                                         playerslots[i] = e = new_pure(playerslot);
 330                                 }
 331                                 e.sv_entnum = i;
 332                                 e.ping = 0;
 333                                 e.ping_packetloss = 0;
 334                                 e.ping_movementloss = 0;
 335                                 //e.gotscores = 0; // we might already have the scores...
 336                                 int t = entcs_GetScoreTeam(i);
 337                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 338                                 RegisterPlayer(e);
 339                                 Scoreboard_UpdatePlayerPos(e);
 340                         }
 341                 }
 342         }
 343         this.nextthink = time + 0.2;
 344 }
 345
 346 void PostInit()
 347 {
 348         entity playerchecker = new_pure(playerchecker);
 349         setthink(playerchecker, Playerchecker_Think);
 350         playerchecker.nextthink = time + 0.2;
 351
 352         TrueAim_Init();
 353
 354         postinit = true;
 355 }
 356
 357 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 358 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 359 // All keys are in ascii.
 360 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 361 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 362 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 363 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 364 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 365 {
 366     TC(int, bInputType);
 367     bool override = false;
 368         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 369
 370         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 371
 372         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 373
 374         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 375
 376         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 377
 378         if(override)
 379                 return true;
 380
 381         return false;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_RemovePlayerScore(entity this)
 391 {
 392         if(this.owner) {
 393                 SetTeam(this.owner, -1);
 394                 this.owner.gotscores = 0;
 395                 FOREACH(Scores, true, {
 396                         this.owner.(scores(it)) = 0; // clear all scores
 397                 });
 398         }
 399 }
 400
 401 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 402 {
 403         make_pure(this);
 404         entity o;
 405
 406         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 407         // (no I've never heard of M-x replace-string, sed, or anything like that)
 408         bool isNew = !this.owner; // workaround for DP bug
 409         int n = ReadByte()-1;
 410
 411 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 412         if(!isNew && n != this.sv_entnum)
 413         {
 414                 //print("A CSQC entity changed its owner!\n");
 415                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 416                 isNew = true;
 417                 Ent_Remove(this);
 418         }
 419 #endif
 420
 421         this.sv_entnum = n;
 422
 423         o = playerslots[this.sv_entnum];
 424         if (!o)
 425         {
 426                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 427         }
 428         this.owner = o;
 429         o.sv_entnum = this.sv_entnum;
 430         o.gotscores = 1;
 431
 432         //if (!o.sort_prev)
 433         //      RegisterPlayer(o);
 434         //playerchecker will do this for us later, if it has not already done so
 435
 436         int sf = ReadShort();
 437         int lf = ReadShort();
 438         FOREACH(Scores, true, {
 439                 int p = 1 << (i % 16);
 440                 if (sf & p)
 441                 {
 442                         if (lf & p)
 443                                 o.(scores(it)) = ReadInt24_t();
 444                         else
 445                                 o.(scores(it)) = ReadChar();
 446                 }
 447         });
 448
 449         return = true;
 450
 451         if(o.sort_prev)
 452                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 453
 454         this.entremove = Ent_RemovePlayerScore;
 455 }
 456
 457 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 458 {
 459         make_pure(this);
 460         int i;
 461
 462         this.team = ReadByte();
 463         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 464
 465 #if MAX_TEAMSCORE <= 8
 466         int sf = ReadByte();
 467         int lf = ReadByte();
 468 #else
 469         int sf = ReadShort();
 470         int lf = ReadShort();
 471 #endif
 472         for(i = 0; i < MAX_TEAMSCORE; ++i)
 473                 if(sf & BIT(i))
 474                 {
 475                         if(lf & BIT(i))
 476                                 o.(teamscores(i)) = ReadInt24_t();
 477                         else
 478                                 o.(teamscores(i)) = ReadChar();
 479                 }
 480
 481         return = true;
 482
 483         Scoreboard_UpdateTeamPos(o);
 484 }
 485
 486 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 487 {
 488         make_pure(this);
 489         float newspectatee_status;
 490
 491         int f = ReadByte();
 492
 493         scoreboard_showscores_force = (f & BIT(0));
 494
 495         if(f & BIT(1))
 496         {
 497                 newspectatee_status = ReadByte();
 498                 if(newspectatee_status == player_localnum + 1)
 499                         newspectatee_status = -1; // observing
 500         }
 501         else
 502                 newspectatee_status = 0;
 503
 504         spectatorbutton_zoom = (f & BIT(2));
 505
 506         if(f & BIT(4))
 507         {
 508                 num_spectators = ReadByte();
 509
 510                 float i, slot;
 511
 512                 for(i = 0; i < MAX_SPECTATORS; ++i)
 513                         spectatorlist[i] = 0; // reset list first
 514
 515                 for(i = 0; i < num_spectators; ++i)
 516                 {
 517                         slot = ReadByte();
 518                         spectatorlist[i] = slot - 1;
 519                 }
 520         }
 521
 522         return = true;
 523
 524         if(newspectatee_status != spectatee_status)
 525         {
 526                 // clear race stuff
 527                 race_laptime = 0;
 528                 race_checkpointtime = 0;
 529                 hud_dynamic_shake_factor = -1;
 530         }
 531         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 532         {
 533                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 534                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 535                 )
 536                         prev_p_health = -1;
 537                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 538                         prev_health = -1;
 539         }
 540         spectatee_status = newspectatee_status;
 541
 542         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 543 }
 544
 545 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 546 {
 547         make_pure(this);
 548         int i, j, b, f;
 549
 550         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 551
 552         if(!(nags & BIT(2)))
 553         {
 554                 strfree(vote_called_vote);
 555                 vote_active = 0;
 556         }
 557         else
 558         {
 559                 vote_active = 1;
 560         }
 561
 562         if(nags & BIT(6))
 563         {
 564                 vote_yescount = ReadByte();
 565                 vote_nocount = ReadByte();
 566                 vote_needed = ReadByte();
 567                 vote_highlighted = ReadChar();
 568         }
 569
 570         if(nags & BIT(7))
 571         {
 572                 strcpy(vote_called_vote, ReadString());
 573         }
 574
 575         if(nags & 1)
 576         {
 577                 for(j = 0; j < maxclients; ++j)
 578                         if(playerslots[j])
 579                                 playerslots[j].ready = 1;
 580                 for(i = 1; i <= maxclients; i += 8)
 581                 {
 582                         f = ReadByte();
 583                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 584                                 if (!(f & b))
 585                                         if(playerslots[j])
 586                                                 playerslots[j].ready = 0;
 587                 }
 588         }
 589
 590         return = true;
 591
 592         ready_waiting = (nags & BIT(0));
 593         ready_waiting_for_me = (nags & BIT(1));
 594         vote_waiting = (nags & BIT(2));
 595         vote_waiting_for_me = (nags & BIT(3));
 596         warmup_stage = (nags & BIT(4));
 597 }
 598
 599 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 600 {
 601         make_pure(this);
 602         int sf = 0;
 603         serialize(byte, 0, sf);
 604         if (sf & 1) {
 605                 for (int j = 0; j < maxclients; ++j) {
 606                         if (playerslots[j]) {
 607                                 playerslots[j].eliminated = 1;
 608                         }
 609                 }
 610                 for (int i = 1; i <= maxclients; i += 8) {
 611                         int f = 0;
 612                         serialize(byte, 0, f);
 613                         for (int b = 0; b < 8; ++b) {
 614                                 if (f & BIT(b)) continue;
 615                                 int j = i - 1 + b;
 616                                 if (playerslots[j]) {
 617                                         playerslots[j].eliminated = 0;
 618                                 }
 619                         }
 620                 }
 621         }
 622         return true;
 623 }
 624
 625 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 626 {
 627         make_pure(this);
 628         prandom_debug();
 629         float s = ReadShort();
 630         psrandom(s);
 631         return true;
 632 }
 633
 634 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 635 {
 636         make_pure(this);
 637         int sf = ReadInt24_t();
 638         if (sf == 0) {
 639                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 640                         weapon_accuracy[w] = -1;
 641                 return true;
 642         }
 643
 644         int f = 1;
 645         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 646                 if (sf & f) {
 647                         int b = ReadByte();
 648                         if (b == 0)
 649                                 weapon_accuracy[w] = -1;
 650                         else if (b == 255)
 651                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 652                         else
 653                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 654                 }
 655                 f = (f == 0x800000) ? 1 : f * 2;
 656         }
 657         return true;
 658 }
 659
 660 void Spawn_Draw(entity this)
 661 {
 662         if(this.alpha <= 0)
 663                 return;
 664
 665         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 666 }
 667
 668 void Spawn_PreDraw(entity this)
 669 {
 670         float alph;
 671         vector org = getpropertyvec(VF_ORIGIN);
 672         if(this.fade_start)
 673         {
 674                 if(vdist(org - this.origin, >, this.fade_end))
 675                         alph = 0; // save on some processing
 676                 else if(vdist(org - this.origin, <, this.fade_start))
 677                         alph = 1; // more processing saved
 678                 else
 679                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 680         }
 681         else
 682                 alph = 1;
 683         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 684         this.alpha = alph;
 685         if(alph <= 0)
 686                 this.drawmask = 0;
 687         else
 688                 this.drawmask = MASK_NORMAL;
 689 }
 690
 691 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 692 {
 693         float teamnum = (ReadByte() - 1);
 694         vector spn_origin = ReadVector();
 695
 696         this.team = (teamnum + 1);
 697
 698         //if(is_new)
 699         //{
 700                 this.origin = spn_origin;
 701                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 702                 //droptofloor();
 703
 704                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 705                 {
 706                         this.mdl = "models/spawnpoint.md3";
 707                         this.colormod = Team_ColorRGB(teamnum);
 708                         precache_model(this.mdl);
 709                         setmodel(this, this.mdl);
 710                         this.drawmask = MASK_NORMAL;
 711                         //this.move_movetype = MOVETYPE_NOCLIP;
 712                         //this.draw = Spawn_Draw;
 713                         IL_PUSH(g_drawables, this);
 714                 }*/
 715                 if(autocvar_cl_spawn_point_particles)
 716                 {
 717                         if(teamplay)
 718                         {
 719                                 switch(teamnum)
 720                                 {
 721                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 722                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 723                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 724                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 725                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 726                                 }
 727                         }
 728                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 729
 730                         this.draw = Spawn_Draw;
 731                         if (is_new) IL_PUSH(g_drawables, this);
 732                         setpredraw(this, Spawn_PreDraw);
 733                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 734                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 735                 }
 736         //}
 737
 738         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 739         return true;
 740 }
 741
 742 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 743 {
 744         // If entnum is 0, ONLY do the local spawn actions
 745         // this way the server can disable the sending of
 746         // spawn origin or such to clients if wanted.
 747         float entnum = ReadByte();
 748
 749         if(entnum)
 750         {
 751                 this.origin = ReadVector();
 752
 753                 if(is_new)
 754                 {
 755                         float teamnum = entcs_GetTeam(entnum - 1);
 756
 757                         if(autocvar_cl_spawn_event_particles)
 758                         {
 759                                 switch(teamnum)
 760                                 {
 761                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 765                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 766                                 }
 767                         }
 768                         if(autocvar_cl_spawn_event_sound)
 769                         {
 770                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 771                         }
 772                 }
 773         }
 774         return = true;
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787                 HUD_Radar_Hide_Maximized();
 788         }
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void CSQC_Ent_Update(entity this, bool isnew)
 795 {
 796         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 797         int t = ReadByte();
 798
 799         // set up the "time" global for received entities to be correct for interpolation purposes
 800         float savetime = time;
 801         if(servertime)
 802         {
 803                 time = servertime;
 804         }
 805         else
 806         {
 807                 serverprevtime = time;
 808                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 809                 time = serverprevtime + serverdeltatime;
 810         }
 811
 812 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 813         if (this.enttype)
 814         {
 815                 if (t != this.enttype || isnew)
 816                 {
 817                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 818                         Ent_Remove(this);
 819                         clearentity(this);
 820                         isnew = true;
 821                 }
 822         }
 823         else
 824         {
 825                 if (!isnew)
 826                 {
 827                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 828                         isnew = true;
 829                 }
 830         }
 831 #endif
 832         this.enttype = t;
 833         bool done = false;
 834         FOREACH(LinkedEntities, it.m_id == t, {
 835                 if (isnew) this.classname = it.netname;
 836                 if (autocvar_developer_csqcentities)
 837             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 838                 done = it.m_read(this, NULL, isnew);
 839                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 840                 break;
 841         });
 842         time = savetime;
 843         if (!done)
 844         {
 845                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 846         }
 847 }
 848
 849 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 850 // used when an entity changes its type. For an entity that someone interacts
 851 // with others, make sure it can no longer do so.
 852 void Ent_Remove(entity this)
 853 {
 854         if(this.entremove) this.entremove(this);
 855
 856         if(this.skeletonindex)
 857         {
 858                 skel_delete(this.skeletonindex);
 859                 this.skeletonindex = 0;
 860         }
 861
 862         if(this.snd_looping > 0)
 863         {
 864                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 865                 this.snd_looping = 0;
 866         }
 867
 868         this.enttype = 0;
 869         this.classname = "";
 870         this.draw = func_null;
 871         this.entremove = func_null;
 872         // TODO possibly set more stuff to defaults
 873 }
 874 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 875 void CSQC_Ent_Remove(entity this)
 876 {
 877         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 878         if (wasfreed(this))
 879         {
 880                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 881                 return;
 882         }
 883         if (this.enttype) Ent_Remove(this);
 884         delete(this);
 885 }
 886
 887 void Gamemode_Init()
 888 {
 889         if (!isdemo())
 890         {
 891                 if(!(calledhooks & HOOK_START))
 892                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 893                 calledhooks |= HOOK_START;
 894         }
 895 }
 896 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 897 void CSQC_Parse_StuffCmd(string strMessage)
 898 {
 899         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 900         localcmd(strMessage);
 901 }
 902 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 903 void CSQC_Parse_Print(string strMessage)
 904 {
 905         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 906         print(ColorTranslateRGB(strMessage));
 907 }
 908
 909 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 910 void CSQC_Parse_CenterPrint(string strMessage)
 911 {
 912         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 913         centerprint_hud(strMessage);
 914 }
 915
 916 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 917 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 918 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 919 bool CSQC_Parse_TempEntity()
 920 {
 921         // Acquire TE ID
 922         int nTEID = ReadByte();
 923
 924         FOREACH(TempEntities, it.m_id == nTEID, {
 925                 if (autocvar_developer_csqcentities)
 926                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 927                 return it.m_read(NULL, NULL, true);
 928         });
 929
 930         if (autocvar_developer_csqcentities)
 931                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 932
 933         // No special logic for this temporary entity; return 0 so the engine can handle it
 934         return false;
 935 }
 936
 937 string forcefog;
 938 void Fog_Force()
 939 {
 940         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 941                 localcmd("\nr_drawfog 0\n");
 942         else if (forcefog != "")
 943                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 944 }
 945
 946 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 947 {
 948         make_pure(this);
 949         gametype = ReadRegistered(Gametypes);
 950         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 951         HUD_ModIcons_SetFunc();
 952         FOREACH(Scores, true, {
 953                 strcpy(scores_label(it), ReadString());
 954                 scores_flags(it) = ReadByte();
 955         });
 956         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 957         {
 958                 strcpy(teamscores_label(i), ReadString());
 959                 teamscores_flags(i) = ReadByte();
 960         }
 961         return = true;
 962         Scoreboard_InitScores();
 963         Gamemode_Init();
 964 }
 965
 966 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 967 {
 968         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 969
 970         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 971         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 972         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 973         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 974         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 975         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 976         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 977         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 978
 979         strcpy(forcefog, ReadString());
 980
 981         armorblockpercent = ReadByte() / 255.0;
 982         damagepush_speedfactor = ReadByte() / 255.0;
 983
 984         serverflags = ReadByte();
 985
 986         g_trueaim_minrange = ReadCoord();
 987
 988         return = true;
 989
 990         MUTATOR_CALLHOOK(Ent_Init);
 991
 992         if (!postinit) PostInit();
 993 }
 994
 995 float GetSpeedUnitFactor(int speed_unit)
 996 {
 997         switch(speed_unit)
 998         {
 999                 default:
1000                 case 1:
1001                         return 1.0;
1002                 case 2:
1003                         return 0.0254;
1004                 case 3:
1005                         return 0.0254 * 3.6;
1006                 case 4:
1007                         return 0.0254 * 3.6 * 0.6213711922;
1008                 case 5:
1009                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1010         }
1011 }
1012
1013 string GetSpeedUnit(int speed_unit)
1014 {
1015         switch(speed_unit)
1016         {
1017                 default:
1018                 case 1:
1019                         return _(" qu/s");
1020                 case 2:
1021                         return _(" m/s");
1022                 case 3:
1023                         return _(" km/h");
1024                 case 4:
1025                         return _(" mph");
1026                 case 5:
1027                         return _(" knots");
1028         }
1029 }
1030
1031 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1032 {
1033         int b = ReadByte();
1034
1035         switch (b)
1036         {
1037                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1038                         race_checkpoint = ReadByte();
1039                         race_time = ReadInt24_t();
1040                         race_previousbesttime = ReadInt24_t();
1041                         race_mypreviousbesttime = ReadInt24_t();
1042                         string pbestname = ReadString();
1043                         if(autocvar_cl_race_cptimes_onlyself)
1044                         {
1045                                 race_previousbesttime = race_mypreviousbesttime;
1046                                 race_mypreviousbesttime = 0;
1047                                 strcpy(race_previousbestname, "");
1048                         }
1049                         else
1050                                 strcpy(race_previousbestname, pbestname);
1051
1052                         race_checkpointtime = time;
1053
1054                         if(race_checkpoint == 0 || race_checkpoint == 254)
1055                         {
1056                                 race_penaltyaccumulator = 0;
1057                                 race_laptime = time; // valid
1058                         }
1059                         break;
1060
1061                 case RACE_NET_CHECKPOINT_CLEAR:
1062                         race_laptime = 0;
1063                         race_checkpointtime = 0;
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1067                         race_laptime = ReadCoord();
1068                         race_checkpointtime = -99999;
1069                         // fall through
1070                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1071                         race_nextcheckpoint = ReadByte();
1072
1073                         race_nextbesttime = ReadInt24_t();
1074                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1075                                 race_mybesttime = ReadInt24_t();
1076                         string newname = ReadString();
1077                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1078                         {
1079                                 race_nextbesttime = race_mybesttime;
1080                                 race_mybesttime = 0;
1081                                 strcpy(race_nextbestname, "");
1082                         }
1083                         else
1084                                 strcpy(race_nextbestname, newname);
1085                         break;
1086
1087                 case RACE_NET_CHECKPOINT_HIT_RACE:
1088                         race_mycheckpoint = ReadByte();
1089                         race_mycheckpointtime = time;
1090                         race_mycheckpointdelta = ReadInt24_t();
1091                         race_mycheckpointlapsdelta = ReadByte();
1092                         if(race_mycheckpointlapsdelta >= 128)
1093                                 race_mycheckpointlapsdelta -= 256;
1094                         int who = ReadByte();
1095                         if(who)
1096                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1097                         else
1098                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1102                         race_othercheckpoint = ReadByte();
1103                         race_othercheckpointtime = time;
1104                         race_othercheckpointdelta = ReadInt24_t();
1105                         race_othercheckpointlapsdelta = ReadByte();
1106                         if(race_othercheckpointlapsdelta >= 128)
1107                                 race_othercheckpointlapsdelta -= 256;
1108                         int what = ReadByte();
1109                         if(what)
1110                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1111                         else
1112                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1113                         break;
1114
1115                 case RACE_NET_PENALTY_RACE:
1116                         race_penaltyeventtime = time;
1117                         race_penaltytime = ReadShort();
1118                         //race_penaltyaccumulator += race_penaltytime;
1119                         strcpy(race_penaltyreason, ReadString());
1120                         break;
1121
1122                 case RACE_NET_PENALTY_QUALIFYING:
1123                         race_penaltyeventtime = time;
1124                         race_penaltytime = ReadShort();
1125                         race_penaltyaccumulator += race_penaltytime;
1126                         strcpy(race_penaltyreason, ReadString());
1127                         break;
1128
1129                 case RACE_NET_SERVER_RECORD:
1130                         race_server_record = ReadInt24_t();
1131                         break;
1132                 case RACE_NET_SPEED_AWARD:
1133                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1134                         strcpy(race_speedaward_holder, ReadString());
1135                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1136                         break;
1137                 case RACE_NET_SPEED_AWARD_BEST:
1138                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1139                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1140                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1141                         break;
1142                 case RACE_NET_RANKINGS_CNT:
1143                         RANKINGS_DISPLAY_CNT = ReadByte();
1144                         break;
1145                 case RACE_NET_SERVER_RANKINGS:
1146                         float prevpos, del;
1147             int pos = ReadShort();
1148                         prevpos = ReadShort();
1149                         del = ReadShort();
1150
1151                         // move other rankings out of the way
1152             int i;
1153                         if (prevpos) {
1154                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1155                                 for (i=m-1; i>pos-1; --i) {
1156                                         grecordtime[i] = grecordtime[i-1];
1157                                         strcpy(grecordholder[i], grecordholder[i-1]);
1158                                 }
1159                         } else if (del) { // a record has been deleted by the admin
1160                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1161                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1162                                                 grecordtime[i] = 0;
1163                                                 strfree(grecordholder[i]);
1164                                         }
1165                                         else {
1166                                                 grecordtime[i] = grecordtime[i+1];
1167                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1168                                         }
1169                                 }
1170                         } else { // player has no ranked record yet
1171                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1172                                         grecordtime[i] = grecordtime[i-1];
1173                                         strcpy(grecordholder[i], grecordholder[i-1]);
1174                                 }
1175                         }
1176
1177                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1178                                 // kick off the player who fell from the last displayed position
1179                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1180                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1181                         }
1182
1183                         // store new ranking
1184                         strcpy(grecordholder[pos-1], ReadString());
1185                         grecordtime[pos-1] = ReadInt24_t();
1186                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1187                                 race_myrank = pos;
1188                         break;
1189                 case RACE_NET_SERVER_STATUS:
1190                         race_status = ReadShort();
1191                         strcpy(race_status_name, ReadString());
1192         }
1193         return true;
1194 }
1195
1196 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1197 {
1198         teamnagger = 1;
1199         return true;
1200 }
1201
1202 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1203 {
1204         int i = ReadByte();
1205         int pi = ReadShort();
1206         int pl = ReadByte();
1207         int ml = ReadByte();
1208         return = true;
1209         entity e = playerslots[i];
1210         if (!e) return;
1211         e.ping = pi;
1212         e.ping_packetloss = pl / 255.0;
1213         e.ping_movementloss = ml / 255.0;
1214 }
1215
1216 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1217 {
1218         int weapon_id = ReadByte();
1219         complain_weapon = Weapons_from(weapon_id);
1220         complain_weapon_type = ReadByte();
1221         return = true;
1222
1223         complain_weapon_time = time;
1224         weapontime = time; // ping the weapon panel
1225
1226         switch(complain_weapon_type)
1227         {
1228                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1229                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1230                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1231         }
1232 }
1233
1234 string _getcommandkey(string cmd_name, string command, bool forcename)
1235 {
1236         string keys;
1237         float n, j, k, l = 0;
1238
1239         if (!autocvar_hud_showbinds)
1240                 return cmd_name;
1241
1242         keys = db_get(binddb, command);
1243         if (keys == "")
1244         {
1245                 bool joy_active = cvar("joy_active");
1246                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1247                 for(j = 0; j < n; ++j)
1248                 {
1249                         k = stof(argv(j));
1250                         if(k != -1)
1251                         {
1252                                 string key = keynumtostring(k);
1253                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1254                                         continue;
1255
1256                                 if (keys == "")
1257                                         keys = key;
1258                                 else
1259                                         keys = strcat(keys, ", ", key);
1260
1261                                 ++l;
1262                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1263                                         break;
1264                         }
1265
1266                 }
1267                 if (keys == "")
1268                         keys = "NO_KEY";
1269                 db_put(binddb, command, keys);
1270         }
1271
1272         if (keys == "NO_KEY") {
1273                 if (autocvar_hud_showbinds > 1)
1274                         return sprintf(_("%s (not bound)"), cmd_name);
1275                 else
1276                         return cmd_name;
1277         }
1278         else if (autocvar_hud_showbinds > 1 || forcename)
1279                 return sprintf("%s (%s)", cmd_name, keys);
1280         else
1281                 return keys;
1282 }