qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         gametype = NULL;
 104
 105         postinit = false;
 106
 107         calledhooks = 0;
 108
 109         teams = Sort_Spawn();
 110         players = Sort_Spawn();
 111
 112         GetTeam(NUM_SPECTATOR, true); // add specs first
 113
 114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 115                 weapon_accuracy[w] = -1;
 116
 117         // precaches
 118
 119         if(autocvar_cl_reticle)
 120         {
 121                 precache_pic("gfx/reticle_normal");
 122                 // weapon reticles are precached in weapon files
 123         }
 124
 125         {
 126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 128                 shortmapname = mi_shortname;
 129
 130                 if (precache_pic(minimapname) == "")
 131                 {
 132                         // but maybe we have a non-clever minimap
 133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 134                         if (precache_pic(minimapname) == "")
 135                                 minimapname = ""; // FAIL
 136                         else
 137                                 get_mi_min_max_texcoords(0); // load new texcoords
 138                 }
 139
 140                 mi_center = (mi_min + mi_max) * 0.5;
 141                 mi_scale = mi_max - mi_min;
 142                 minimapname = strzone(minimapname);
 143         }
 144
 145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 146         LoadMenuSkinValues();
 147 }
 148
 149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 150 void Shutdown()
 151 {
 152         WarpZone_Shutdown();
 153
 154         delete(teams);
 155         delete(players);
 156         db_close(binddb);
 157         db_close(tempdb);
 158         if(autocvar_cl_db_saveasdump)
 159                 db_dump(ClientProgsDB, "client.db");
 160         else
 161                 db_save(ClientProgsDB, "client.db");
 162         db_close(ClientProgsDB);
 163
 164         if(camera_active)
 165                 cvar_set("chase_active",ftos(chase_active_backup));
 166
 167         // unset the event chasecam's chase_active
 168         if(autocvar_chase_active < 0)
 169                 cvar_set("chase_active", "0");
 170
 171         if (autocvar_r_drawviewmodel < 0)
 172                 cvar_set("r_drawviewmodel", "0");
 173
 174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 175
 176         if (!isdemo())
 177         {
 178                 if (!(calledhooks & HOOK_START))
 179                         localcmd("\n_cl_hook_gamestart nop\n");
 180                 if (!(calledhooks & HOOK_END))
 181                 {
 182                         int gamecount = cvar("cl_matchcount");
 183                         localcmd("\ncl_hook_gameend\n");
 184                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 185                         // earlier versions of the game abuse the hook to set this cvar
 186                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 187                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 188                 }
 189         }
 190
 191         localcmd("\ncl_hook_shutdown\n");
 192
 193         localcmd("\n-button12\n");
 194
 195         deactivate_minigame();
 196         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 197
 198         ReplicateVars(REPLICATEVARS_DESTROY);
 199 }
 200
 201 void AuditLists()
 202 {
 203         entity e;
 204         entity prev;
 205
 206         prev = players;
 207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 208         {
 209                 if(prev != e.sort_prev)
 210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 211         }
 212
 213         prev = teams;
 214         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 215         {
 216                 if(prev != e.sort_prev)
 217                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 218         }
 219 }
 220
 221 float RegisterPlayer(entity player)
 222 {
 223         entity pl;
 224         AuditLists();
 225         for(pl = players.sort_next; pl; pl = pl.sort_next)
 226                 if(pl == player)
 227                         error("Player already registered!");
 228         player.sort_next = players.sort_next;
 229         player.sort_prev = players;
 230         if(players.sort_next)
 231                 players.sort_next.sort_prev = player;
 232         players.sort_next = player;
 233         AuditLists();
 234         return true;
 235 }
 236
 237 void RemovePlayer(entity player)
 238 {
 239         entity pl, parent;
 240         AuditLists();
 241         parent = players;
 242         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 243                 parent = pl;
 244
 245         if(!pl)
 246         {
 247                 error("Trying to remove a player which is not in the playerlist!");
 248                 return;
 249         }
 250         parent.sort_next = player.sort_next;
 251         if(player.sort_next)
 252                 player.sort_next.sort_prev = parent;
 253         AuditLists();
 254 }
 255
 256 void MoveToLast(entity e)
 257 {
 258         AuditLists();
 259         entity ent = e.sort_next;
 260         while(ent)
 261         {
 262                 SORT_SWAP(ent, e);
 263                 ent = e.sort_next;
 264         }
 265         AuditLists();
 266 }
 267
 268 float RegisterTeam(entity Team)
 269 {
 270         assert_once(Team.team, eprint(Team));
 271         entity tm;
 272         AuditLists();
 273         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 274                 if(tm == Team)
 275                         error("Team already registered!");
 276         Team.sort_next = teams.sort_next;
 277         Team.sort_prev = teams;
 278         if(teams.sort_next)
 279                 teams.sort_next.sort_prev = Team;
 280         teams.sort_next = Team;
 281         if(Team.team && Team.team != NUM_SPECTATOR)
 282                 ++team_count;
 283         AuditLists();
 284         return true;
 285 }
 286
 287 void RemoveTeam(entity Team)
 288 {
 289         entity tm, parent;
 290         AuditLists();
 291         parent = teams;
 292         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 293                 parent = tm;
 294
 295         if(!tm)
 296         {
 297                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 298                 return;
 299         }
 300         parent.sort_next = Team.sort_next;
 301         if(Team.sort_next)
 302                 Team.sort_next.sort_prev = parent;
 303         if(Team.team && Team.team != NUM_SPECTATOR)
 304                 --team_count;
 305         AuditLists();
 306 }
 307
 308 entity GetTeam(int Team, bool add)
 309 {
 310         TC(int, Team); TC(bool, add);
 311         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 312         if(teamslots[num])
 313                 return teamslots[num];
 314         if (!add)
 315                 return NULL;
 316         entity tm = new_pure(team);
 317         tm.team = Team;
 318         teamslots[num] = tm;
 319         RegisterTeam(tm);
 320         return tm;
 321 }
 322
 323 .float has_team;
 324 bool SetTeam(entity o, int Team)
 325 {
 326         TC(int, Team);
 327         //devassert_once(Team);
 328         entity tm;
 329         if(teamplay)
 330         {
 331                 switch(Team)
 332                 {
 333                         case -1:
 334                         case NUM_TEAM_1:
 335                         case NUM_TEAM_2:
 336                         case NUM_TEAM_3:
 337                         case NUM_TEAM_4:
 338                                 break;
 339                         default:
 340                                 if(GetTeam(Team, false) == NULL)
 341                                 {
 342                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 343                                         Team = NUM_SPECTATOR;
 344                                 }
 345                                 break;
 346                 }
 347         }
 348         else
 349         {
 350                 switch(Team)
 351                 {
 352                         case -1:
 353                         case 0:
 354                                 break;
 355                         default:
 356                                 if(GetTeam(Team, false) == NULL)
 357                                 {
 358                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 359                                         Team = NUM_SPECTATOR;
 360                                 }
 361                                 break;
 362                 }
 363         }
 364         if(Team == -1) // leave
 365         {
 366                 if(o.has_team)
 367                 {
 368                         tm = GetTeam(o.team, false);
 369                         tm.team_size -= 1;
 370                         o.has_team = 0;
 371                         return true;
 372                 }
 373         }
 374         else
 375         {
 376                 if (!o.has_team)
 377                 {
 378                         o.team = Team;
 379                         tm = GetTeam(Team, true);
 380                         tm.team_size += 1;
 381                         o.has_team = 1;
 382                         return true;
 383                 }
 384                 else if(Team != o.team)
 385                 {
 386                         tm = GetTeam(o.team, false);
 387                         tm.team_size -= 1;
 388                         o.team = Team;
 389                         tm = GetTeam(Team, true);
 390                         tm.team_size += 1;
 391                         return true;
 392                 }
 393         }
 394         return false;
 395 }
 396
 397 void Playerchecker_Think(entity this)
 398 {
 399         int i;
 400         entity e;
 401         for(i = 0; i < maxclients; ++i)
 402         {
 403                 e = playerslots[i];
 404                 if(entcs_GetName(i) == "")
 405                 {
 406                         if(e.sort_prev)
 407                         {
 408                                 // player disconnected
 409                                 SetTeam(e, -1);
 410                                 RemovePlayer(e);
 411                                 e.sort_prev = NULL;
 412                                 //e.gotscores = 0;
 413                         }
 414                 }
 415                 else
 416                 {
 417                         if (!e.sort_prev)
 418                         {
 419                                 // player connected
 420                                 if (!e)
 421                                 {
 422                                         playerslots[i] = e = new_pure(playerslot);
 423                                 }
 424                                 e.sv_entnum = i;
 425                                 e.ping = 0;
 426                                 e.ping_packetloss = 0;
 427                                 e.ping_movementloss = 0;
 428                                 //e.gotscores = 0; // we might already have the scores...
 429                                 int t = entcs_GetScoreTeam(i);
 430                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 431                                 RegisterPlayer(e);
 432                                 Scoreboard_UpdatePlayerPos(e);
 433                         }
 434                 }
 435         }
 436         this.nextthink = time + 0.2;
 437 }
 438
 439 void PostInit()
 440 {
 441         entity playerchecker = new_pure(playerchecker);
 442         setthink(playerchecker, Playerchecker_Think);
 443         playerchecker.nextthink = time + 0.2;
 444
 445         TrueAim_Init();
 446
 447         // this can't be called in CSQC_Init as it'd send cvars too early
 448         ReplicateVars_Start();
 449
 450         postinit = true;
 451 }
 452
 453 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 454 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 455 // All keys are in ascii.
 456 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 457 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 458 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 459 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 460 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 461 {
 462         TC(int, bInputType);
 463         bool override = false;
 464
 465         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 466         if (override)
 467                 return true;
 468
 469         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 470
 471         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 472
 473         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 474
 475         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 476
 477         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 478
 479         if(override)
 480                 return true;
 481
 482         if(bInputType == 3 || bInputType == 2)
 483                 return false;
 484
 485         // at this point bInputType can only be 0 or 1 (key pressed or released)
 486         bool key_pressed = (bInputType == 0);
 487
 488         if(key_pressed) {
 489                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 490                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 491                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 492         }
 493         else {
 494                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 495                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 496                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 497         }
 498
 499         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 500         {
 501                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 502                 {
 503                         localcmd("\nmenu_showgamemenudialog\n");
 504                         return true;
 505                 }
 506         }
 507
 508         return false;
 509 }
 510
 511 // END REQUIRED CSQC FUNCTIONS
 512 // --------------------------------------------------------------------------
 513
 514 // --------------------------------------------------------------------------
 515 // BEGIN OPTIONAL CSQC FUNCTIONS
 516
 517 void Ent_RemovePlayerScore(entity this)
 518 {
 519         if(this.owner) {
 520                 SetTeam(this.owner, -1);
 521                 this.owner.gotscores = 0;
 522                 FOREACH(Scores, true, {
 523                         this.owner.(scores(it)) = 0; // clear all scores
 524                 });
 525         }
 526 }
 527
 528 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 529 {
 530         make_pure(this);
 531         entity o;
 532
 533         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 534         // (no I've never heard of M-x replace-string, sed, or anything like that)
 535         bool isNew = !this.owner; // workaround for DP bug
 536         int n = ReadByte()-1;
 537
 538 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 539         if(!isNew && n != this.sv_entnum)
 540         {
 541                 //print("A CSQC entity changed its owner!\n");
 542                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 543                 isNew = true;
 544                 Ent_Remove(this);
 545         }
 546 #endif
 547
 548         this.sv_entnum = n;
 549
 550         o = playerslots[this.sv_entnum];
 551         if (!o)
 552         {
 553                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 554         }
 555         this.owner = o;
 556         o.sv_entnum = this.sv_entnum;
 557         o.gotscores = 1;
 558
 559         //if (!o.sort_prev)
 560         //      RegisterPlayer(o);
 561         //playerchecker will do this for us later, if it has not already done so
 562
 563         int sf = ReadShort();
 564         int lf = ReadShort();
 565         FOREACH(Scores, true, {
 566                 int p = 1 << (i % 16);
 567                 if (sf & p)
 568                 {
 569                         if (lf & p)
 570                                 o.(scores(it)) = ReadInt24_t();
 571                         else
 572                                 o.(scores(it)) = ReadChar();
 573                 }
 574         });
 575
 576         return = true;
 577
 578         if(o.sort_prev)
 579                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 580
 581         this.entremove = Ent_RemovePlayerScore;
 582 }
 583
 584 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 585 {
 586         make_pure(this);
 587         int i;
 588
 589         this.team = ReadByte();
 590         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 591
 592 #if MAX_TEAMSCORE <= 8
 593         int sf = ReadByte();
 594         int lf = ReadByte();
 595 #else
 596         int sf = ReadShort();
 597         int lf = ReadShort();
 598 #endif
 599         for(i = 0; i < MAX_TEAMSCORE; ++i)
 600                 if(sf & BIT(i))
 601                 {
 602                         if(lf & BIT(i))
 603                                 o.(teamscores(i)) = ReadInt24_t();
 604                         else
 605                                 o.(teamscores(i)) = ReadChar();
 606                 }
 607
 608         return = true;
 609
 610         Scoreboard_UpdateTeamPos(o);
 611 }
 612
 613 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 614 {
 615         make_pure(this);
 616         float newspectatee_status;
 617
 618         int f = ReadByte();
 619
 620         scoreboard_showscores_force = (f & BIT(0));
 621
 622         if(f & BIT(1))
 623         {
 624                 newspectatee_status = ReadByte();
 625                 if(newspectatee_status == player_localnum + 1)
 626                         newspectatee_status = -1; // observing
 627         }
 628         else
 629                 newspectatee_status = 0;
 630
 631         spectatorbutton_zoom = (f & BIT(2));
 632
 633         if(f & BIT(4))
 634         {
 635                 num_spectators = ReadByte();
 636
 637                 float i, slot;
 638
 639                 for(i = 0; i < MAX_SPECTATORS; ++i)
 640                         spectatorlist[i] = 0; // reset list first
 641
 642                 int limit = min(num_spectators, MAX_SPECTATORS);
 643                 for(i = 0; i < limit; ++i)
 644                 {
 645                         slot = ReadByte();
 646                         spectatorlist[i] = slot - 1;
 647                 }
 648         }
 649         else
 650         {
 651                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 652                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 653                 num_spectators = 0;
 654         }
 655
 656         return = true;
 657
 658         if(newspectatee_status != spectatee_status)
 659         {
 660                 // clear race stuff
 661                 race_laptime = 0;
 662                 race_checkpointtime = 0;
 663                 hud_dynamic_shake_factor = -1;
 664                 spectatee_status_changed_time = time;
 665         }
 666         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 667         {
 668                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 669                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 670                 )
 671                         prev_p_health = -1;
 672                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 673                         prev_health = -1;
 674         }
 675         spectatee_status = newspectatee_status;
 676
 677         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 678 }
 679
 680 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 681 {
 682         make_pure(this);
 683         int i, j, b, f;
 684
 685         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 686
 687         if(!(nags & BIT(2)))
 688         {
 689                 strfree(vote_called_vote);
 690                 vote_active = 0;
 691         }
 692         else
 693         {
 694                 vote_active = 1;
 695         }
 696
 697         if(nags & BIT(6))
 698         {
 699                 vote_yescount = ReadByte();
 700                 vote_nocount = ReadByte();
 701                 vote_needed = ReadByte();
 702                 vote_highlighted = ReadChar();
 703         }
 704
 705         if(nags & BIT(7))
 706         {
 707                 strcpy(vote_called_vote, ReadString());
 708         }
 709
 710         if(nags & 1)
 711         {
 712                 for(j = 0; j < maxclients; ++j)
 713                         if(playerslots[j])
 714                                 playerslots[j].ready = true;
 715                 for(i = 1; i <= maxclients; i += 8)
 716                 {
 717                         f = ReadByte();
 718                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 719                                 if (!(f & b))
 720                                         if(playerslots[j])
 721                                                 playerslots[j].ready = false;
 722                 }
 723         }
 724
 725         return = true;
 726
 727         ready_waiting = (nags & BIT(0));
 728         ready_waiting_for_me = (nags & BIT(1));
 729         vote_waiting = (nags & BIT(2));
 730         vote_waiting_for_me = (nags & BIT(3));
 731         warmup_stage = (nags & BIT(4));
 732 }
 733
 734 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 735 {
 736         make_pure(this);
 737         int sf = 0;
 738         serialize(byte, 0, sf);
 739         if (sf & 1) {
 740                 for (int j = 0; j < maxclients; ++j) {
 741                         if (playerslots[j]) {
 742                                 playerslots[j].eliminated = true;
 743                         }
 744                 }
 745                 for (int i = 1; i <= maxclients; i += 8) {
 746                         int f = 0;
 747                         serialize(byte, 0, f);
 748                         for (int b = 0; b < 8; ++b) {
 749                                 if (f & BIT(b)) continue;
 750                                 int j = i - 1 + b;
 751                                 if (playerslots[j]) {
 752                                         playerslots[j].eliminated = false;
 753                                 }
 754                         }
 755                 }
 756         }
 757         return true;
 758 }
 759
 760 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 761 {
 762         make_pure(this);
 763         prandom_debug();
 764         float s = ReadShort();
 765         psrandom(s);
 766         return true;
 767 }
 768
 769 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 770 {
 771         make_pure(this);
 772         int sf = ReadInt24_t();
 773         if (sf == 0) {
 774                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 775                         weapon_accuracy[w] = -1;
 776                 return true;
 777         }
 778
 779         int f = 1;
 780         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 781                 if (sf & f) {
 782                         int b = ReadByte();
 783                         if (b == 0)
 784                                 weapon_accuracy[w] = -1;
 785                         else if (b == 255)
 786                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 787                         else
 788                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 789                 }
 790                 f = (f == 0x800000) ? 1 : f * 2;
 791         }
 792         return true;
 793 }
 794
 795 void Spawn_Draw(entity this)
 796 {
 797         bool dodraw = autocvar_cl_spawn_point_particles;
 798         if(dodraw && autocvar_cl_spawn_point_dist_max)
 799         {
 800                 vector org = getpropertyvec(VF_ORIGIN);
 801                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 802         }
 803
 804         if(dodraw)
 805                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 806 }
 807
 808 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 809 {
 810         float teamnum = (ReadByte() - 1);
 811         vector spn_origin = ReadVector();
 812
 813         this.team = (teamnum + 1);
 814
 815         //if(is_new)
 816         //{
 817                 this.origin = spn_origin;
 818                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 819                 //droptofloor();
 820
 821                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 822                 {
 823                         this.mdl = "models/spawnpoint.md3";
 824                         this.colormod = Team_ColorRGB(teamnum);
 825                         precache_model(this.mdl);
 826                         setmodel(this, this.mdl);
 827                         this.drawmask = MASK_NORMAL;
 828                         //this.move_movetype = MOVETYPE_NOCLIP;
 829                         //this.draw = Spawn_Draw;
 830                         IL_PUSH(g_drawables, this);
 831                 }*/
 832                 this.draw = Spawn_Draw;
 833                 if (is_new) IL_PUSH(g_drawables, this);
 834         //}
 835
 836         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 837         return true;
 838 }
 839
 840 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 841 {
 842         // If entnum is 0, ONLY do the local spawn actions
 843         // this way the server can disable the sending of
 844         // spawn origin or such to clients if wanted.
 845         float entnum = ReadByte();
 846
 847         if(entnum)
 848         {
 849                 this.origin = ReadVector();
 850
 851                 if(is_new)
 852                 {
 853                         float teamnum = entcs_GetTeam(entnum - 1);
 854
 855                         if(autocvar_cl_spawn_event_particles)
 856                         {
 857                                 switch(teamnum)
 858                                 {
 859                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 860                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 861                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 862                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 863                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 864                                 }
 865                         }
 866                         if(autocvar_cl_spawn_event_sound)
 867                         {
 868                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 869                         }
 870                 }
 871         }
 872         return = true;
 873
 874         // local spawn actions
 875         if(is_new && (!entnum || (entnum == player_localentnum)))
 876         {
 877                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 878                 {
 879                         zoomin_effect = 1;
 880                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 881                 }
 882
 883                 if(autocvar_cl_unpress_zoom_on_spawn)
 884                 {
 885                         localcmd("-zoom\n");
 886                         button_zoom = false;
 887                 }
 888                 HUD_Radar_Hide_Maximized();
 889         }
 890         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 891 }
 892
 893 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 894 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 895 void CSQC_Ent_Update(entity this, bool isnew)
 896 {
 897         this.sourceLoc = __FILE__":"STR(__LINE__);
 898         int t = ReadByte();
 899
 900         // set up the "time" global for received entities to be correct for interpolation purposes
 901         float savetime = time;
 902         if(servertime)
 903         {
 904                 time = servertime;
 905         }
 906         else
 907         {
 908                 serverprevtime = time;
 909                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 910                 time = serverprevtime + serverdeltatime;
 911         }
 912
 913 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 914         if (this.enttype)
 915         {
 916                 if (t != this.enttype || isnew)
 917                 {
 918                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 919                         Ent_Remove(this);
 920                         ONREMOVE(this);
 921                         clearentity(this);
 922                         isnew = true;
 923                 }
 924         }
 925         else
 926         {
 927                 if (!isnew)
 928                 {
 929                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 930                         isnew = true;
 931                 }
 932         }
 933 #endif
 934         this.enttype = t;
 935         bool done = false;
 936         FOREACH(LinkedEntities, it.m_id == t, {
 937                 if (isnew) this.classname = it.netname;
 938                 if (autocvar_developer_csqcentities)
 939                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 940                 done = it.m_read(this, NULL, isnew);
 941                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 942                 break;
 943         });
 944         time = savetime;
 945         if (!done)
 946         {
 947                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 948         }
 949 }
 950
 951 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 952 // used when an entity changes its type. For an entity that someone interacts
 953 // with others, make sure it can no longer do so.
 954 void Ent_Remove(entity this)
 955 {
 956         if(this.entremove) this.entremove(this);
 957
 958         if(this.skeletonindex)
 959         {
 960                 skel_delete(this.skeletonindex);
 961                 this.skeletonindex = 0;
 962         }
 963
 964         if(this.snd_looping > 0)
 965         {
 966                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 967                 this.snd_looping = 0;
 968         }
 969
 970         this.enttype = 0;
 971         this.classname = "";
 972         this.draw = func_null;
 973         this.entremove = func_null;
 974         // TODO possibly set more stuff to defaults
 975 }
 976 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 977 void CSQC_Ent_Remove(entity this)
 978 {
 979         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 980         if (wasfreed(this))
 981         {
 982                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 983                 return;
 984         }
 985         if (this.enttype) Ent_Remove(this);
 986         delete(this);
 987 }
 988
 989 void Gamemode_Init()
 990 {
 991         if (!isdemo())
 992         {
 993                 if(!(calledhooks & HOOK_START))
 994                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 995                 calledhooks |= HOOK_START;
 996         }
 997 }
 998 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 999 void CSQC_Parse_StuffCmd(string strMessage)
1000 {
1001         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
1002         localcmd(strMessage);
1003 }
1004 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1005 void CSQC_Parse_Print(string strMessage)
1006 {
1007         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1008         print(ColorTranslateRGB(strMessage));
1009 }
1010
1011 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1012 void CSQC_Parse_CenterPrint(string strMessage)
1013 {
1014         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1015         centerprint_AddStandard(strMessage);
1016 }
1017
1018 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1019 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1020 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1021 bool CSQC_Parse_TempEntity()
1022 {
1023         // Acquire TE ID
1024         int nTEID = ReadByte();
1025
1026         FOREACH(TempEntities, it.m_id == nTEID, {
1027                 if (autocvar_developer_csqcentities)
1028                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1029                 return it.m_read(NULL, NULL, true);
1030         });
1031
1032         if (autocvar_developer_csqcentities)
1033                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1034
1035         // No special logic for this temporary entity; return 0 so the engine can handle it
1036         return false;
1037 }
1038
1039 string forcefog;
1040 void Fog_Force()
1041 {
1042         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1043                 localcmd("\nr_drawfog 0\n");
1044         else if (forcefog != "")
1045                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1046 }
1047
1048 bool net_handle_ServerWelcome();
1049 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1050 {
1051         make_pure(this);
1052         gametype = ReadRegistered(Gametypes);
1053         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1054         HUD_ModIcons_SetFunc();
1055         FOREACH(Scores, true, {
1056                 strcpy(scores_label(it), ReadString());
1057                 scores_flags(it) = ReadByte();
1058         });
1059         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1060         {
1061                 strcpy(teamscores_label(i), ReadString());
1062                 teamscores_flags(i) = ReadByte();
1063         }
1064         bool welcome_msg_too = ReadByte();
1065         if (welcome_msg_too)
1066                 net_handle_ServerWelcome();
1067         return = true;
1068         Scoreboard_InitScores();
1069         Gamemode_Init();
1070 }
1071
1072 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1073 {
1074         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1075
1076         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1077         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1078         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1079         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1080         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1081         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1082         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1083         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1084
1085         strcpy(forcefog, ReadString());
1086
1087         armorblockpercent = ReadByte() / 255.0;
1088         damagepush_speedfactor = ReadByte() / 255.0;
1089
1090         serverflags = ReadByte();
1091
1092         g_trueaim_minrange = ReadCoord();
1093
1094         return = true;
1095
1096         MUTATOR_CALLHOOK(Ent_Init);
1097
1098         if (!postinit) PostInit();
1099 }
1100
1101 float GetSpeedUnitFactor(int speed_unit)
1102 {
1103         switch(speed_unit)
1104         {
1105                 default:
1106                 case 1: return 1.0;
1107                 case 2: return 0.0254;
1108                 case 3: return 0.0254 * 3.6;
1109                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1110                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1111         }
1112 }
1113
1114 string GetSpeedUnit(int speed_unit)
1115 {
1116         switch(speed_unit)
1117         {
1118                 // translator-friendly strings without the initial space
1119                 default:
1120                 case 1: return strcat(" ", _("qu/s"));
1121                 case 2: return strcat(" ", _("m/s"));
1122                 case 3: return strcat(" ", _("km/h"));
1123                 case 4: return strcat(" ", _("mph"));
1124                 case 5: return strcat(" ", _("knots"));
1125         }
1126 }
1127
1128 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1129 {
1130         int b = ReadByte();
1131
1132         switch (b)
1133         {
1134                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1135                         race_checkpoint = ReadByte();
1136                         race_time = ReadInt24_t();
1137                         race_previousbesttime = ReadInt24_t();
1138                         race_mypreviousbesttime = ReadInt24_t();
1139                         string pbestname = ReadString();
1140                         if(autocvar_cl_race_cptimes_onlyself)
1141                         {
1142                                 race_previousbesttime = race_mypreviousbesttime;
1143                                 race_mypreviousbesttime = 0;
1144                                 strcpy(race_previousbestname, "");
1145                         }
1146                         else
1147                                 strcpy(race_previousbestname, pbestname);
1148
1149                         race_checkpointtime = time;
1150
1151                         if(race_checkpoint == 0 || race_checkpoint == 254)
1152                         {
1153                                 race_penaltyaccumulator = 0;
1154                                 race_laptime = time; // valid
1155                         }
1156                         break;
1157
1158                 case RACE_NET_CHECKPOINT_CLEAR:
1159                         race_laptime = 0;
1160                         race_checkpointtime = 0;
1161                         break;
1162
1163                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1164                         race_laptime = ReadCoord();
1165                         race_checkpointtime = -99999;
1166                         // fall through
1167                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1168                         race_nextcheckpoint = ReadByte();
1169
1170                         race_nextbesttime = ReadInt24_t();
1171                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1172                                 race_mybesttime = ReadInt24_t();
1173                         string newname = ReadString();
1174                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1175                         {
1176                                 race_nextbesttime = race_mybesttime;
1177                                 race_mybesttime = 0;
1178                                 strcpy(race_nextbestname, "");
1179                         }
1180                         else
1181                                 strcpy(race_nextbestname, newname);
1182                         break;
1183
1184                 case RACE_NET_CHECKPOINT_HIT_RACE:
1185                         race_mycheckpoint = ReadByte();
1186                         race_mycheckpointtime = time;
1187                         race_mycheckpointdelta = ReadInt24_t();
1188                         race_mycheckpointlapsdelta = ReadByte();
1189                         if(race_mycheckpointlapsdelta >= 128)
1190                                 race_mycheckpointlapsdelta -= 256;
1191                         int who = ReadByte();
1192                         if(who)
1193                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1194                         else
1195                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1196                         break;
1197
1198                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1199                         race_othercheckpoint = ReadByte();
1200                         race_othercheckpointtime = time;
1201                         race_othercheckpointdelta = ReadInt24_t();
1202                         race_othercheckpointlapsdelta = ReadByte();
1203                         if(race_othercheckpointlapsdelta >= 128)
1204                                 race_othercheckpointlapsdelta -= 256;
1205                         int what = ReadByte();
1206                         if(what)
1207                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1208                         else
1209                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1210                         break;
1211
1212                 case RACE_NET_PENALTY_RACE:
1213                 case RACE_NET_PENALTY_QUALIFYING:
1214                         race_penaltyeventtime = time;
1215                         race_penaltytime = ReadShort();
1216                         string reason = ReadString();
1217                         if (reason == "missing a checkpoint")
1218                                 reason = _("missing a checkpoint");
1219                         strcpy(race_penaltyreason, reason);
1220                         if (b == RACE_NET_PENALTY_QUALIFYING)
1221                                 race_penaltyaccumulator += race_penaltytime;
1222                         break;
1223
1224                 case RACE_NET_SERVER_RECORD:
1225                         race_server_record = ReadInt24_t();
1226                         break;
1227                 case RACE_NET_SPEED_AWARD:
1228                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1229                         strcpy(race_speedaward_holder, ReadString());
1230                         break;
1231                 case RACE_NET_SPEED_AWARD_BEST:
1232                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1233                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1234                         break;
1235                 case RACE_NET_RANKINGS_CNT:
1236                         RANKINGS_DISPLAY_CNT = ReadByte();
1237                         break;
1238                 case RACE_NET_SERVER_RANKINGS:
1239                         float prevpos, del;
1240                         int pos = ReadShort();
1241                         prevpos = ReadShort();
1242                         del = ReadShort();
1243
1244                         // move other rankings out of the way
1245                         int i;
1246                         if (prevpos) {
1247                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1248                                 for (i=m-1; i>pos-1; --i) {
1249                                         grecordtime[i] = grecordtime[i-1];
1250                                         strcpy(grecordholder[i], grecordholder[i-1]);
1251                                 }
1252                         } else if (del) { // a record has been deleted by the admin
1253                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1254                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1255                                                 grecordtime[i] = 0;
1256                                                 strfree(grecordholder[i]);
1257                                         }
1258                                         else {
1259                                                 grecordtime[i] = grecordtime[i+1];
1260                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1261                                         }
1262                                 }
1263                         } else { // player has no ranked record yet
1264                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1265                                         grecordtime[i] = grecordtime[i-1];
1266                                         strcpy(grecordholder[i], grecordholder[i-1]);
1267                                 }
1268                         }
1269
1270                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1271                                 // kick off the player who fell from the last displayed position
1272                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1273                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1274                         }
1275
1276                         // store new ranking
1277                         strcpy(grecordholder[pos-1], ReadString());
1278                         grecordtime[pos-1] = ReadInt24_t();
1279                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1280                                 race_myrank = pos;
1281                         break;
1282                 case RACE_NET_SERVER_STATUS:
1283                         race_status = ReadShort();
1284                         strcpy(race_status_name, ReadString());
1285         }
1286         return true;
1287 }
1288
1289 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1290 {
1291         teamnagger = 1;
1292         return true;
1293 }
1294
1295 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1296 {
1297         int i = ReadByte();
1298         int pi = ReadShort();
1299         int pl = ReadByte();
1300         int ml = ReadByte();
1301         return = true;
1302         entity e = playerslots[i];
1303         if (!e) return;
1304         e.ping = pi;
1305         e.ping_packetloss = pl / 255.0;
1306         e.ping_movementloss = ml / 255.0;
1307 }
1308
1309 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1310 {
1311         int weapon_id = ReadByte();
1312         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1313         complain_weapon_type = ReadByte();
1314         return = true;
1315
1316         complain_weapon_time = time;
1317         weapontime = time; // ping the weapon panel
1318
1319         switch(complain_weapon_type)
1320         {
1321                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1322                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1323                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1324         }
1325 }
1326
1327 string translate_modifications(string s)
1328 {
1329         return build_mutator_list(s);
1330 }
1331
1332 string translate_weaponarena(string s)
1333 {
1334         if (s == "") return s;
1335         if (s == "All Weapons Arena") return _("All Weapons Arena");
1336         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1337         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1338         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1339         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1340         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1341         if (s == "No Weapons Arena") return _("No Weapons Arena");
1342
1343         int n = tokenizebyseparator(s, " & ");
1344         string wpn_list = "";
1345         for (int i = 0; i < n; i++)
1346         {
1347                 Weapon wep = Weapon_from_name(argv(i));
1348                 if (wep == WEP_Null)
1349                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1350                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1351         }
1352         if (wpn_list != "")
1353                 return sprintf(_("%s Arena"), wpn_list);
1354         else
1355                 return _("No Weapons Arena");
1356 }
1357
1358 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1359 {
1360         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1361         if (version_mismatch)
1362         {
1363                 if(!version_check)
1364                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1365                                 _("Your client version is outdated."), "\n\n\n",
1366                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1367                                 _("Please update!"));
1368                 else
1369                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1370                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1371                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1372         }
1373         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1374 }
1375
1376 bool net_handle_ServerWelcome()
1377 {
1378         bool campaign = ReadByte();
1379         if (campaign)
1380         {
1381                 string campaign_title = ReadString();
1382                 int campaign_level = ReadByte();
1383                 string campaign_msg = ReadString();
1384                 string welcomedialog_args;
1385                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1386                 string key = getcommandkey(_("jump"), "+jump");
1387                 string msg = strcat(
1388                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1389                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1390                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1391                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1392                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1393                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1394                 return true;
1395         }
1396
1397         strcpy(hostname, ReadString());
1398
1399         string hostversion = ReadString();
1400         bool version_mismatch = ReadByte();
1401         bool version_check = ReadByte();
1402         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1403
1404         string modifications = translate_modifications(ReadString());
1405         string weaponarena_list = translate_weaponarena(ReadString());
1406         string cache_mutatormsg = ReadString();
1407         string motd = ReadString();
1408
1409         string msg = "";
1410         msg = strcat(msg, ver);
1411         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1412
1413         modifications = cons_mid(modifications, ", ", weaponarena_list);
1414         if(modifications != "")
1415                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1416
1417         if (cache_mutatormsg != "")
1418                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1419         string mutator_msg = "";
1420         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1421         mutator_msg = M_ARGV(0, string);
1422         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1423
1424         if (motd != "")
1425                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1426
1427         strcpy(welcome_msg, msg);
1428         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1429         return true;
1430 }
1431
1432 void Welcome_Message_Show_Try()
1433 {
1434         if (!welcome_msg_menu_check_maxtime)
1435                 return;
1436
1437         // if want dialog check if menu is initialized but for a short time
1438         if (cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1439         {
1440                 if (cvar("_menu_welcome_dialog_available"))
1441                 {
1442                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1443                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1444                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1445                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1446                         if (intermission || isdemo()) // close it after it's been initialized so it can still be opened manually
1447                                 localcmd("\ntogglemenu 0\n");
1448                 }
1449
1450                 strfree(welcome_msg);
1451                 welcome_msg_menu_check_maxtime = 0;
1452         }
1453 }
1454
1455 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1456 {
1457         return net_handle_ServerWelcome();
1458 }
1459
1460 string _getcommandkey(string cmd_name, string command, bool forcename)
1461 {
1462         string keys;
1463         float n, j, k, l = 0;
1464
1465         if (!autocvar_hud_showbinds)
1466                 return cmd_name;
1467
1468         keys = db_get(binddb, command);
1469         if (keys == "")
1470         {
1471                 bool joy_active = cvar("joy_active");
1472                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1473                 for(j = 0; j < n; ++j)
1474                 {
1475                         k = stof(argv(j));
1476                         if(k != -1)
1477                         {
1478                                 string key = keynumtostring(k);
1479                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1480                                         continue;
1481
1482                                 key = translate_key(key);
1483
1484                                 if (keys == "")
1485                                         keys = key;
1486                                 else
1487                                         keys = strcat(keys, ", ", key);
1488
1489                                 ++l;
1490                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1491                                         break;
1492                         }
1493
1494                 }
1495                 if (keys == "")
1496                         keys = "NO_KEY";
1497                 db_put(binddb, command, keys);
1498         }
1499
1500         if (keys == "NO_KEY") {
1501                 if (autocvar_hud_showbinds > 1)
1502                         return sprintf(_("%s (not bound)"), cmd_name);
1503                 else
1504                         return cmd_name;
1505         }
1506         else if (autocvar_hud_showbinds > 1 || forcename)
1507                 return sprintf("%s (%s)", cmd_name, keys);
1508         else
1509                 return keys;
1510 }
1511
1512 /** engine callback */
1513 void URI_Get_Callback(int id, int status, string data)
1514 {
1515         TC(int, id); TC(int, status);
1516         if(url_URI_Get_Callback(id, status, data))
1517         {
1518                 // handled
1519         }
1520         else if (id == URI_GET_DISCARD)
1521         {
1522                 // discard
1523         }
1524         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1525         {
1526                 // sv_cmd curl
1527                 Curl_URI_Get_Callback(id, status, data);
1528         }
1529         else
1530         {
1531                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1532         }
1533 }