ed50dda37878b5b7dc20e67a08f09708875215e6
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2 #include "_all.qh"
3
4 #include "controlpoint.qh"
5 #include "csqcmodel_hooks.qh"
6 #include "damage.qh"
7 #include "effects.qh"
8 #include "generator.qh"
9 #include "gibs.qh"
10 #include "hook.qh"
11 #include "hud.qh"
12 #include "hud_config.qh"
13 #include "laser.qh"
14 #include "mapvoting.qh"
15 #include "modeleffects.qh"
16 #include "particles.qh"
17 #include "scoreboard.qh"
18 #include "shownames.qh"
19 #include "tuba.qh"
20 #include "t_items.qh"
21 #include "wall.qh"
22
23 #include "../common/vehicles/all.qh"
24
25 #include "mutators/events.qh"
26
27 #include "weapons/projectile.qh"
28
29 #include "../common/buffs.qh"
30 #include "../common/deathtypes.qh"
31 #include "../common/effects.qh"
32 #include "../common/mapinfo.qh"
33 #include "../common/monsters/all.qh"
34 #include "../common/nades.qh"
35 #include "../common/net_notice.qh"
36 #include "../common/notifications.qh"
37 #include "../common/stats.qh"
38 #include "../common/teams.qh"
39
40 #include "../common/items/all.qh"
41
42 #include "../common/mutators/base.qh"
43
44 #include "../common/weapons/all.qh"
45
46 #include "../csqcmodellib/cl_model.qh"
47 #include "../csqcmodellib/interpolate.qh"
48
49 #include "../common/triggers/include.qh"
50
51 #include "../common/turrets/cl_turrets.qh"
52 #include "../common/turrets/turrets.qh"
53
54 #include "../warpzonelib/client.qh"
55
56 // --------------------------------------------------------------------------
57 // BEGIN REQUIRED CSQC FUNCTIONS
58 //include "main.qh"
59
60 entity clearentity_ent;
61 void clearentity(entity e)
62 {
63         if (!clearentity_ent)
64         {
65                 clearentity_ent = spawn();
66                 clearentity_ent.classname = "clearentity";
67         }
68         int n = e.entnum;
69         copyentity(clearentity_ent, e);
70         e.entnum = n;
71 }
72
73 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
74 void menu_show_error()
75 {
76         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
77 }
78
79 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
80 // Useful for precaching things
81
82 void menu_sub_null()
83 {
84 }
85
86 string forcefog;
87 void ConsoleCommand_macro_init();
88 void CSQC_Init(void)
89 {
90         prvm_language = cvar_string("prvm_language");
91
92 #ifdef WATERMARK
93         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
94 #endif
95
96         int i;
97
98         binddb = db_create();
99         tempdb = db_create();
100         ClientProgsDB = db_load("client.db");
101         compressShortVector_init();
102
103         draw_endBoldFont();
104         menu_visible = false;
105         menu_show = menu_show_error;
106         menu_action = func_null;
107
108         for(i = 0; i < 255; ++i)
109                 if(getplayerkeyvalue(i, "viewentity") == "")
110                         break;
111         maxclients = i;
112
113         //registercommand("hud_configure");
114         //registercommand("hud_save");
115         //registercommand("menu_action");
116
117         ConsoleCommand_macro_init();
118
119         registercvar("hud_usecsqc", "1");
120         registercvar("scoreboard_columns", "default");
121
122         registercvar("cl_nade_type", "3");
123         registercvar("cl_pokenade_type", "zombie");
124
125         registercvar("cl_jumpspeedcap_min", "");
126         registercvar("cl_jumpspeedcap_max", "");
127
128         gametype = 0;
129
130         // hud_fields uses strunzone on the titles!
131         for(i = 0; i < MAX_HUD_FIELDS; ++i)
132                 hud_title[i] = strzone("(null)");
133
134         Cmd_HUD_SetFields(0);
135
136         postinit = false;
137
138         calledhooks = 0;
139
140         teams = Sort_Spawn();
141         players = Sort_Spawn();
142
143         GetTeam(NUM_SPECTATOR, true); // add specs first
144
145         // needs to be done so early because of the constants they create
146         static_init();
147         CALL_ACCUMULATED_FUNCTION(RegisterTurrets);
148         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
149         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
150         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
151         CALL_ACCUMULATED_FUNCTION(RegisterEffects);
152
153         initialize_minigames();
154
155         // precaches
156         precache_model("null");
157         precache_sound("misc/hit.wav");
158         precache_sound("misc/typehit.wav");
159
160         generator_precache();
161         Projectile_Precache();
162         Hook_Precache();
163         GibSplash_Precache();
164         Tuba_Precache();
165         CSQCPlayer_Precache();
166
167         if(autocvar_cl_reticle)
168         {
169                 precache_pic("gfx/reticle_normal");
170                 // weapon reticles are precached in weapon files
171         }
172
173         get_mi_min_max_texcoords(1); // try the CLEVER way first
174         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
175         shortmapname = mi_shortname;
176
177         if(precache_pic(minimapname) == "")
178         {
179                 // but maybe we have a non-clever minimap
180                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
181                 if(precache_pic(minimapname) == "")
182                         minimapname = ""; // FAIL
183                 else
184                         get_mi_min_max_texcoords(0); // load new texcoords
185         }
186
187         mi_center = (mi_min + mi_max) * 0.5;
188         mi_scale = mi_max - mi_min;
189         minimapname = strzone(minimapname);
190
191         WarpZone_Init();
192
193         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
194         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
195 }
196
197 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
198 void Shutdown(void)
199 {
200         WarpZone_Shutdown();
201
202         remove(teams);
203         remove(players);
204         db_close(binddb);
205         db_close(tempdb);
206         if(autocvar_cl_db_saveasdump)
207                 db_dump(ClientProgsDB, "client.db");
208         else
209                 db_save(ClientProgsDB, "client.db");
210         db_close(ClientProgsDB);
211
212         if(camera_active)
213                 cvar_set("chase_active",ftos(chase_active_backup));
214
215         // unset the event chasecam's chase_active
216         if(autocvar_chase_active < 0)
217                 cvar_set("chase_active", "0");
218
219         if (!isdemo())
220         {
221                 if (!(calledhooks & HOOK_START))
222                         localcmd("\n_cl_hook_gamestart nop\n");
223                 if (!(calledhooks & HOOK_END))
224                         localcmd("\ncl_hook_gameend\n");
225         }
226
227         deactivate_minigame();
228         HUD_MinigameMenu_Close();
229 }
230
231 .float has_team;
232 float SetTeam(entity o, int Team)
233 {
234         entity tm;
235         if(teamplay)
236         {
237                 switch(Team)
238                 {
239                         case -1:
240                         case NUM_TEAM_1:
241                         case NUM_TEAM_2:
242                         case NUM_TEAM_3:
243                         case NUM_TEAM_4:
244                                 break;
245                         default:
246                                 if(GetTeam(Team, false) == world)
247                                 {
248                                         dprintf("trying to switch to unsupported team %d\n", Team);
249                                         Team = NUM_SPECTATOR;
250                                 }
251                                 break;
252                 }
253         }
254         else
255         {
256                 switch(Team)
257                 {
258                         case -1:
259                         case 0:
260                                 break;
261                         default:
262                                 if(GetTeam(Team, false) == world)
263                                 {
264                                         dprintf("trying to switch to unsupported team %d\n", Team);
265                                         Team = NUM_SPECTATOR;
266                                 }
267                                 break;
268                 }
269         }
270         if(Team == -1) // leave
271         {
272                 if(o.has_team)
273                 {
274                         tm = GetTeam(o.team, false);
275                         tm.team_size -= 1;
276                         o.has_team = 0;
277                         return true;
278                 }
279         }
280         else
281         {
282                 if (!o.has_team)
283                 {
284                         o.team = Team;
285                         tm = GetTeam(Team, true);
286                         tm.team_size += 1;
287                         o.has_team = 1;
288                         return true;
289                 }
290                 else if(Team != o.team)
291                 {
292                         tm = GetTeam(o.team, false);
293                         tm.team_size -= 1;
294                         o.team = Team;
295                         tm = GetTeam(Team, true);
296                         tm.team_size += 1;
297                         return true;
298                 }
299         }
300         return false;
301 }
302
303 void Playerchecker_Think()
304 {
305     int i;
306         entity e;
307         for(i = 0; i < maxclients; ++i)
308         {
309                 e = playerslots[i];
310                 if(GetPlayerName(i) == "")
311                 {
312                         if(e.sort_prev)
313                         {
314                                 // player disconnected
315                                 SetTeam(e, -1);
316                                 RemovePlayer(e);
317                                 e.sort_prev = world;
318                                 //e.gotscores = 0;
319                         }
320                 }
321                 else
322                 {
323                         if (!e.sort_prev)
324                         {
325                                 // player connected
326                                 if (!e)
327                                         playerslots[i] = e = spawn();
328                                 e.sv_entnum = i;
329                                 e.ping = 0;
330                                 e.ping_packetloss = 0;
331                                 e.ping_movementloss = 0;
332                                 //e.gotscores = 0; // we might already have the scores...
333                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
334                                 RegisterPlayer(e);
335                                 HUD_UpdatePlayerPos(e);
336                         }
337                 }
338         }
339         self.nextthink = time + 0.2;
340 }
341
342 void Porto_Init();
343 void TrueAim_Init();
344 void PostInit(void)
345 {
346         entity playerchecker;
347         playerchecker = spawn();
348         playerchecker.think = Playerchecker_Think;
349         playerchecker.nextthink = time + 0.2;
350
351         Porto_Init();
352         TrueAim_Init();
353
354         postinit = true;
355 }
356
357 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
358 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
359 // All keys are in ascii.
360 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
361 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
362 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
363 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
364 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
365 {
366         float bSkipKey;
367         bSkipKey = false;
368
369         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
370                 return true;
371
372         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
373                 return true;
374
375         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
376                 return true;
377
378         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
379                 return true;
380
381         if(menu_visible && menu_action)
382                 if(menu_action(bInputType, nPrimary, nSecondary))
383                         return true;
384
385         return bSkipKey;
386 }
387
388 // END REQUIRED CSQC FUNCTIONS
389 // --------------------------------------------------------------------------
390
391 // --------------------------------------------------------------------------
392 // BEGIN OPTIONAL CSQC FUNCTIONS
393
394 void Ent_RemoveEntCS()
395 {
396         entcs_receiver[self.sv_entnum] = world;
397 }
398 void Ent_ReadEntCS()
399 {
400     int sf;
401         InterpolateOrigin_Undo();
402
403         self.classname = "entcs_receiver";
404         sf = ReadByte();
405
406         if(sf & 1)
407                 self.sv_entnum = ReadByte();
408         if(sf & 2)
409         {
410                 self.origin_x = ReadShort();
411                 self.origin_y = ReadShort();
412                 self.origin_z = ReadShort();
413                 setorigin(self, self.origin);
414         }
415         if(sf & 4)
416         {
417                 self.angles_y = ReadByte() * 360.0 / 256;
418                 self.angles_x = self.angles_z = 0;
419         }
420         if(sf & 8)
421                 self.healthvalue = ReadByte() * 10;
422         if(sf & 16)
423                 self.armorvalue = ReadByte() * 10;
424
425         entcs_receiver[self.sv_entnum] = self;
426         self.entremove = Ent_RemoveEntCS;
427         self.iflags |= IFLAG_ORIGIN;
428
429         InterpolateOrigin_Note();
430 }
431
432 void Ent_Remove();
433
434 void Ent_RemovePlayerScore()
435 {
436         if(self.owner) {
437                 SetTeam(self.owner, -1);
438                 self.owner.gotscores = 0;
439                 for(int i = 0; i < MAX_SCORE; ++i) {
440                         self.owner.(scores[i]) = 0; // clear all scores
441                 }
442         }
443 }
444
445 void Ent_ReadPlayerScore()
446 {
447         int i, n;
448         bool isNew;
449         entity o;
450
451         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
452         // (no I've never heard of M-x replace-string, sed, or anything like that)
453         isNew = !self.owner; // workaround for DP bug
454         n = ReadByte()-1;
455
456 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
457         if(!isNew && n != self.sv_entnum)
458         {
459                 //print("A CSQC entity changed its owner!\n");
460                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
461                 isNew = true;
462                 Ent_Remove();
463                 self.enttype = ENT_CLIENT_SCORES;
464         }
465 #endif
466
467         self.sv_entnum = n;
468
469         if (!(playerslots[self.sv_entnum]))
470                 playerslots[self.sv_entnum] = spawn();
471         o = self.owner = playerslots[self.sv_entnum];
472         o.sv_entnum = self.sv_entnum;
473         o.gotscores = 1;
474
475         //if (!o.sort_prev)
476         //      RegisterPlayer(o);
477         //playerchecker will do this for us later, if it has not already done so
478
479     int sf, lf;
480 #if MAX_SCORE <= 8
481         sf = ReadByte();
482         lf = ReadByte();
483 #else
484         sf = ReadShort();
485         lf = ReadShort();
486 #endif
487     int p;
488         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
489                 if(sf & p)
490                 {
491                         if(lf & p)
492                                 o.(scores[i]) = ReadInt24_t();
493                         else
494                                 o.(scores[i]) = ReadChar();
495                 }
496
497         if(o.sort_prev)
498                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
499
500         self.entremove = Ent_RemovePlayerScore;
501 }
502
503 void Ent_ReadTeamScore()
504 {
505         int i;
506         entity o;
507
508         self.team = ReadByte();
509         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
510
511     int sf, lf;
512 #if MAX_TEAMSCORE <= 8
513         sf = ReadByte();
514         lf = ReadByte();
515 #else
516         sf = ReadShort();
517         lf = ReadShort();
518 #endif
519         int p;
520         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
521                 if(sf & p)
522                 {
523                         if(lf & p)
524                                 o.(teamscores[i]) = ReadInt24_t();
525                         else
526                                 o.(teamscores[i]) = ReadChar();
527                 }
528
529         HUD_UpdateTeamPos(o);
530 }
531
532 void Ent_ClientData()
533 {
534         float newspectatee_status;
535
536     int f = ReadByte();
537
538         scoreboard_showscores_force = (f & 1);
539
540         if(f & 2)
541         {
542                 newspectatee_status = ReadByte();
543                 if(newspectatee_status == player_localnum + 1)
544                         newspectatee_status = -1; // observing
545         }
546         else
547                 newspectatee_status = 0;
548
549         spectatorbutton_zoom = (f & 4);
550
551         if(f & 8)
552         {
553                 angles_held_status = 1;
554                 angles_held.x = ReadAngle();
555                 angles_held.y = ReadAngle();
556                 angles_held.z = 0;
557         }
558         else
559                 angles_held_status = 0;
560
561         if(newspectatee_status != spectatee_status)
562         {
563                 // clear race stuff
564                 race_laptime = 0;
565                 race_checkpointtime = 0;
566         }
567         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
568         {
569                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
570                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
571                 )
572                         prev_p_health = -1;
573                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
574                         prev_health = -1;
575         }
576         spectatee_status = newspectatee_status;
577
578         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
579 }
580
581 void Ent_Nagger()
582 {
583     int i, j, b, f;
584
585     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
586
587         if(!(nags & 4))
588         {
589                 if(vote_called_vote)
590                         strunzone(vote_called_vote);
591                 vote_called_vote = string_null;
592                 vote_active = 0;
593         }
594         else
595         {
596                 vote_active = 1;
597         }
598
599         if(nags & 64)
600         {
601                 vote_yescount = ReadByte();
602                 vote_nocount = ReadByte();
603                 vote_needed = ReadByte();
604                 vote_highlighted = ReadChar();
605         }
606
607         if(nags & 128)
608         {
609                 if(vote_called_vote)
610                         strunzone(vote_called_vote);
611                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
612         }
613
614         if(nags & 1)
615         {
616                 for(j = 0; j < maxclients; ++j)
617                         if(playerslots[j])
618                                 playerslots[j].ready = 1;
619                 for(i = 1; i <= maxclients; i += 8)
620                 {
621                         f = ReadByte();
622                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
623                                 if (!(f & b))
624                                         if(playerslots[j])
625                                                 playerslots[j].ready = 0;
626                 }
627         }
628
629         ready_waiting = (nags & 1);
630         ready_waiting_for_me = (nags & 2);
631         vote_waiting = (nags & 4);
632         vote_waiting_for_me = (nags & 8);
633         warmup_stage = (nags & 16);
634 }
635
636 void Ent_EliminatedPlayers()
637 {
638     int i, j, b, f;
639
640     int sf = ReadByte();
641         if(sf & 1)
642         {
643                 for(j = 0; j < maxclients; ++j)
644                         if(playerslots[j])
645                                 playerslots[j].eliminated = 1;
646                 for(i = 1; i <= maxclients; i += 8)
647                 {
648                         f = ReadByte();
649                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
650                                 if (!(f & b))
651                                         if(playerslots[j])
652                                                 playerslots[j].eliminated = 0;
653                 }
654         }
655 }
656
657 void Ent_RandomSeed()
658 {
659         float s;
660         prandom_debug();
661         s = ReadShort();
662         psrandom(s);
663 }
664
665 void Ent_ReadAccuracy(void)
666 {
667     int f, w;
668     int sf = ReadInt24_t();
669         if(sf == 0)
670         {
671                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
672                         weapon_accuracy[w] = -1;
673                 return;
674         }
675
676         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
677         {
678                 if(sf & f)
679                 {
680             int b = ReadByte();
681                         if(b == 0)
682                                 weapon_accuracy[w] = -1;
683                         else if(b == 255)
684                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
685                         else
686                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
687                 }
688                 if(f == 0x800000)
689                         f = 1;
690                 else
691                         f *= 2;
692         }
693 }
694
695 void Spawn_Draw(void)
696 {
697         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
698 }
699
700 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
701 {
702         float teamnum = (ReadByte() - 1);
703         vector spn_origin;
704         spn_origin.x = ReadShort();
705         spn_origin.y = ReadShort();
706         spn_origin.z = ReadShort();
707
708         if(is_new)
709         {
710                 self.origin = spn_origin;
711                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
712                 droptofloor();
713
714                 /*if(autocvar_cl_spawn_point_model) // needs a model first
715                 {
716                         self.mdl = "models/spawnpoint.md3";
717                         self.colormod = Team_ColorRGB(teamnum);
718                         precache_model(self.mdl);
719                         setmodel(self, self.mdl);
720                         self.drawmask = MASK_NORMAL;
721                         //self.movetype = MOVETYPE_NOCLIP;
722                         //self.draw = Spawn_Draw;
723                 }*/
724                 if(autocvar_cl_spawn_point_particles)
725                 {
726                         if((serverflags & SERVERFLAG_TEAMPLAY))
727                         {
728                                 switch(teamnum)
729                                 {
730                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
731                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
732                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
733                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
734                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
735                                 }
736                         }
737                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
738
739                         self.draw = Spawn_Draw;
740                 }
741         }
742
743         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
744 }
745
746 void Ent_ReadSpawnEvent(float is_new)
747 {
748         // If entnum is 0, ONLY do the local spawn actions
749         // this way the server can disable the sending of
750         // spawn origin or such to clients if wanted.
751         float entnum = ReadByte();
752
753         if(entnum)
754         {
755                 self.origin_x = ReadShort();
756                 self.origin_y = ReadShort();
757                 self.origin_z = ReadShort();
758
759                 if(is_new)
760                 {
761                         float teamnum = GetPlayerColor(entnum - 1);
762
763                         if(autocvar_cl_spawn_event_particles)
764                         {
765                                 switch(teamnum)
766                                 {
767                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
768                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
769                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
770                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
771                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
772                                 }
773                         }
774                         if(autocvar_cl_spawn_event_sound)
775                         {
776                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
777                         }
778                 }
779         }
780
781         // local spawn actions
782         if(is_new && (!entnum || (entnum == player_localentnum)))
783         {
784                 zoomin_effect = 1;
785                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
786
787                 if(autocvar_cl_unpress_zoom_on_spawn)
788                 {
789                         localcmd("-zoom\n");
790                         button_zoom = false;
791                 }
792         }
793         HUD_Radar_Hide_Maximized();
794         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
795 }
796
797 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
798 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
799 void Ent_RadarLink();
800 void Ent_Init();
801 void Ent_ScoresInfo();
802 void CSQC_Ent_Update(float bIsNewEntity)
803 {
804         float t;
805         float savetime;
806         t = ReadByte();
807
808         if(autocvar_developer_csqcentities)
809                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
810
811         // set up the "time" global for received entities to be correct for interpolation purposes
812         savetime = time;
813         if(servertime)
814         {
815                 time = servertime;
816         }
817         else
818         {
819                 serverprevtime = time;
820                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
821                 time = serverprevtime + serverdeltatime;
822         }
823
824 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
825         if(self.enttype)
826         {
827                 if(t != self.enttype || bIsNewEntity)
828                 {
829                         //print("A CSQC entity changed its type!\n");
830                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
831                         Ent_Remove();
832                         clearentity(self);
833                         bIsNewEntity = 1;
834                 }
835         }
836         else
837         {
838                 if(!bIsNewEntity)
839                 {
840                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
841                         bIsNewEntity = 1;
842                 }
843         }
844 #endif
845         self.enttype = t;
846         switch(t)
847         {
848                 case ENT_CLIENT_MUTATOR: {
849                         int mutID = ReadMutator();
850                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
851                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
852                         break;
853                 }
854                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
855                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
856                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
857                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
858                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
859                 case ENT_CLIENT_LASER: Ent_Laser(); break;
860                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
861                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
862                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
863                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
864                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
865                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
866                 case ENT_CLIENT_INIT: Ent_Init(); break;
867                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
868                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
869                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
870                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
871                 case ENT_CLIENT_WALL: Ent_Wall(); break;
872                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
873                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
874                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
875                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
876                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
877                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
878                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
879                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
880                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
881                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
882                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
883                 case ENT_CLIENT_TURRET: ent_turret(); break;
884                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
885                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(); break;
886                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
887                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
888                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
889                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
890                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
891                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
892                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
893                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
894                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
895                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
896                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
897                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
898                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
899                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
900                 case ENT_CLIENT_DOOR: ent_door(); break;
901                 case ENT_CLIENT_PLAT: ent_plat(); break;
902                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
903                 case ENT_CLIENT_CORNER: ent_corner(); break;
904                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
905                 case ENT_CLIENT_TRAIN: ent_train(); break;
906                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
907                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
908
909                 default:
910                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
911                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
912                         break;
913         }
914
915         time = savetime;
916 }
917 // Destructor, but does NOT deallocate the entity by calling remove(). Also
918 // used when an entity changes its type. For an entity that someone interacts
919 // with others, make sure it can no longer do so.
920 void Ent_Remove()
921 {
922         if(self.entremove)
923                 self.entremove();
924
925         if(self.skeletonindex)
926         {
927                 skel_delete(self.skeletonindex);
928                 self.skeletonindex = 0;
929         }
930
931         if(self.snd_looping > 0)
932         {
933                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
934                 self.snd_looping = 0;
935         }
936
937         self.enttype = 0;
938         self.classname = "";
939         self.draw = menu_sub_null;
940         self.entremove = menu_sub_null;
941         // TODO possibly set more stuff to defaults
942 }
943 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
944 void CSQC_Ent_Remove()
945 {
946         if(autocvar_developer_csqcentities)
947                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
948
949         if(wasfreed(self))
950         {
951                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
952                 return;
953         }
954         if(self.enttype)
955                 Ent_Remove();
956         remove(self);
957 }
958
959 void Gamemode_Init()
960 {
961         if (!isdemo())
962         {
963                 if(!(calledhooks & HOOK_START))
964                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
965                 calledhooks |= HOOK_START;
966         }
967 }
968 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
969 void CSQC_Parse_StuffCmd(string strMessage)
970 {
971         if(autocvar_developer_csqcentities)
972                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
973
974         localcmd(strMessage);
975 }
976 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
977 void CSQC_Parse_Print(string strMessage)
978 {
979         if(autocvar_developer_csqcentities)
980                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
981
982         print(ColorTranslateRGB(strMessage));
983 }
984
985 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
986 void CSQC_Parse_CenterPrint(string strMessage)
987 {
988         if(autocvar_developer_csqcentities)
989                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
990
991         centerprint_hud(strMessage);
992 }
993
994 string notranslate_fogcmd1 = "\nfog ";
995 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
996 void Fog_Force()
997 {
998         // TODO somehow thwart prvm_globalset client ...
999
1000         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1001                 { localcmd("\nr_drawfog 0\n"); }
1002         else if(forcefog != "")
1003                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1004 }
1005
1006 void Gamemode_Init();
1007 void Ent_ScoresInfo()
1008 {
1009     int i;
1010         self.classname = "ent_client_scores_info";
1011         gametype = ReadInt24_t();
1012         HUD_ModIcons_SetFunc();
1013         for(i = 0; i < MAX_SCORE; ++i)
1014         {
1015                 if(scores_label[i])
1016                         strunzone(scores_label[i]);
1017                 scores_label[i] = strzone(ReadString());
1018                 scores_flags[i] = ReadByte();
1019         }
1020         for(i = 0; i < MAX_TEAMSCORE; ++i)
1021         {
1022                 if(teamscores_label[i])
1023                         strunzone(teamscores_label[i]);
1024                 teamscores_label[i] = strzone(ReadString());
1025                 teamscores_flags[i] = ReadByte();
1026         }
1027         HUD_InitScores();
1028         Gamemode_Init();
1029 }
1030
1031 void Ent_Init()
1032 {
1033         self.classname = "ent_client_init";
1034
1035         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1036
1037         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1038         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1040         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1044         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1045
1046         if(forcefog)
1047                 strunzone(forcefog);
1048         forcefog = strzone(ReadString());
1049
1050         armorblockpercent = ReadByte() / 255.0;
1051
1052         g_balance_mortar_bouncefactor = ReadCoord();
1053         g_balance_mortar_bouncestop = ReadCoord();
1054         g_balance_electro_secondary_bouncefactor = ReadCoord();
1055         g_balance_electro_secondary_bouncestop = ReadCoord();
1056
1057         vortex_scope = !ReadByte();
1058         rifle_scope = !ReadByte();
1059
1060         serverflags = ReadByte();
1061
1062         minelayer_maxmines = ReadByte();
1063
1064         hagar_maxrockets = ReadByte();
1065
1066         g_trueaim_minrange = ReadCoord();
1067         g_balance_porto_secondary = ReadByte();
1068
1069         if(!postinit)
1070                 PostInit();
1071 }
1072
1073 void Net_ReadRace()
1074 {
1075         float b;
1076
1077         b = ReadByte();
1078
1079         switch(b)
1080         {
1081                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1082                         race_checkpoint = ReadByte();
1083                         race_time = ReadInt24_t();
1084                         race_previousbesttime = ReadInt24_t();
1085                         if(race_previousbestname)
1086                                 strunzone(race_previousbestname);
1087                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1088
1089                         race_checkpointtime = time;
1090
1091                         if(race_checkpoint == 0 || race_checkpoint == 254)
1092                         {
1093                                 race_penaltyaccumulator = 0;
1094                                 race_laptime = time; // valid
1095                         }
1096
1097                         break;
1098
1099                 case RACE_NET_CHECKPOINT_CLEAR:
1100                         race_laptime = 0;
1101                         race_checkpointtime = 0;
1102                         break;
1103
1104                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1105                         race_laptime = ReadCoord();
1106                         race_checkpointtime = -99999;
1107                         // fall through
1108                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1109                         race_nextcheckpoint = ReadByte();
1110
1111                         race_nextbesttime = ReadInt24_t();
1112                         if(race_nextbestname)
1113                                 strunzone(race_nextbestname);
1114                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1115                         break;
1116
1117                 case RACE_NET_CHECKPOINT_HIT_RACE:
1118                         race_mycheckpoint = ReadByte();
1119                         race_mycheckpointtime = time;
1120                         race_mycheckpointdelta = ReadInt24_t();
1121                         race_mycheckpointlapsdelta = ReadByte();
1122                         if(race_mycheckpointlapsdelta >= 128)
1123                                 race_mycheckpointlapsdelta -= 256;
1124                         if(race_mycheckpointenemy)
1125                                 strunzone(race_mycheckpointenemy);
1126                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1127                         break;
1128
1129                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1130                         race_othercheckpoint = ReadByte();
1131                         race_othercheckpointtime = time;
1132                         race_othercheckpointdelta = ReadInt24_t();
1133                         race_othercheckpointlapsdelta = ReadByte();
1134                         if(race_othercheckpointlapsdelta >= 128)
1135                                 race_othercheckpointlapsdelta -= 256;
1136                         if(race_othercheckpointenemy)
1137                                 strunzone(race_othercheckpointenemy);
1138                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1139                         break;
1140
1141                 case RACE_NET_PENALTY_RACE:
1142                         race_penaltyeventtime = time;
1143                         race_penaltytime = ReadShort();
1144                         //race_penaltyaccumulator += race_penaltytime;
1145                         if(race_penaltyreason)
1146                                 strunzone(race_penaltyreason);
1147                         race_penaltyreason = strzone(ReadString());
1148                         break;
1149
1150                 case RACE_NET_PENALTY_QUALIFYING:
1151                         race_penaltyeventtime = time;
1152                         race_penaltytime = ReadShort();
1153                         race_penaltyaccumulator += race_penaltytime;
1154                         if(race_penaltyreason)
1155                                 strunzone(race_penaltyreason);
1156                         race_penaltyreason = strzone(ReadString());
1157                         break;
1158
1159                 case RACE_NET_SERVER_RECORD:
1160                         race_server_record = ReadInt24_t();
1161                         break;
1162                 case RACE_NET_SPEED_AWARD:
1163                         race_speedaward = ReadInt24_t();
1164                         if(race_speedaward_holder)
1165                                 strunzone(race_speedaward_holder);
1166                         race_speedaward_holder = strzone(ReadString());
1167                         break;
1168                 case RACE_NET_SPEED_AWARD_BEST:
1169                         race_speedaward_alltimebest = ReadInt24_t();
1170                         if(race_speedaward_alltimebest_holder)
1171                                 strunzone(race_speedaward_alltimebest_holder);
1172                         race_speedaward_alltimebest_holder = strzone(ReadString());
1173                         break;
1174                 case RACE_NET_SERVER_RANKINGS:
1175                         float prevpos, del;
1176             int pos = ReadShort();
1177                         prevpos = ReadShort();
1178                         del = ReadShort();
1179
1180                         // move other rankings out of the way
1181             int i;
1182                         if (prevpos) {
1183                                 for (i=prevpos-1;i>pos-1;--i) {
1184                                         grecordtime[i] = grecordtime[i-1];
1185                                         if(grecordholder[i])
1186                                                 strunzone(grecordholder[i]);
1187                                         grecordholder[i] = strzone(grecordholder[i-1]);
1188                                 }
1189                         } else if (del) { // a record has been deleted by the admin
1190                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1191                                         if (i == RANKINGS_CNT-1) { // clear out last record
1192                                                 grecordtime[i] = 0;
1193                                                 if (grecordholder[i])
1194                                                         strunzone(grecordholder[i]);
1195                                                 grecordholder[i] = string_null;
1196                                         }
1197                                         else {
1198                                                 grecordtime[i] = grecordtime[i+1];
1199                                                 if (grecordholder[i])
1200                                                         strunzone(grecordholder[i]);
1201                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1202                                         }
1203                                 }
1204                         } else { // player has no ranked record yet
1205                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1206                                         grecordtime[i] = grecordtime[i-1];
1207                                         if(grecordholder[i])
1208                                                 strunzone(grecordholder[i]);
1209                                         grecordholder[i] = strzone(grecordholder[i-1]);
1210                                 }
1211                         }
1212
1213                         // store new ranking
1214                         if(grecordholder[pos-1] != "")
1215                                 strunzone(grecordholder[pos-1]);
1216                         grecordholder[pos-1] = strzone(ReadString());
1217                         grecordtime[pos-1] = ReadInt24_t();
1218                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1219                                 race_myrank = pos;
1220                         break;
1221                 case RACE_NET_SERVER_STATUS:
1222                         race_status = ReadShort();
1223                         if(race_status_name)
1224                                 strunzone(race_status_name);
1225                         race_status_name = strzone(ReadString());
1226         }
1227 }
1228
1229 void Net_TeamNagger()
1230 {
1231         teamnagger = 1;
1232 }
1233
1234 void Net_ReadPingPLReport()
1235 {
1236         int e, pi, pl, ml;
1237         e = ReadByte();
1238         pi = ReadShort();
1239         pl = ReadByte();
1240         ml = ReadByte();
1241         if (!(playerslots[e]))
1242                 return;
1243         playerslots[e].ping = pi;
1244         playerslots[e].ping_packetloss = pl / 255.0;
1245         playerslots[e].ping_movementloss = ml / 255.0;
1246 }
1247
1248 void Net_WeaponComplain()
1249 {
1250         complain_weapon = ReadByte();
1251
1252         if(complain_weapon_name)
1253                 strunzone(complain_weapon_name);
1254         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1255
1256         complain_weapon_type = ReadByte();
1257
1258         complain_weapon_time = time;
1259         weapontime = time; // ping the weapon panel
1260
1261         switch(complain_weapon_type)
1262         {
1263                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1264                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1265                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1266         }
1267 }
1268
1269 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1270 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1271 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1272 float CSQC_Parse_TempEntity()
1273 {
1274         // Acquire TE ID
1275         int nTEID = ReadByte();
1276
1277         if (autocvar_developer_csqcentities)
1278                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1279
1280         switch (nTEID)
1281         {
1282                 case TE_CSQC_MUTATOR:
1283                         int mutID = ReadMutator();
1284                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1285                         return true;
1286                 case TE_CSQC_TARGET_MUSIC:
1287                         Net_TargetMusic();
1288                         return true;
1289                 case TE_CSQC_PICTURE:
1290                         Net_MapVote_Picture();
1291                         return true;
1292                 case TE_CSQC_RACE:
1293                         Net_ReadRace();
1294                         return true;
1295                 case TE_CSQC_VORTEXBEAMPARTICLE:
1296                         Net_ReadVortexBeamParticle();
1297                         return true;
1298                 case TE_CSQC_TEAMNAGGER:
1299                         Net_TeamNagger();
1300                         return true;
1301                 case TE_CSQC_ARC:
1302                         Net_ReadArc();
1303                         return true;
1304                 case TE_CSQC_PINGPLREPORT:
1305                         Net_ReadPingPLReport();
1306                         return true;
1307                 case TE_CSQC_WEAPONCOMPLAIN:
1308                         Net_WeaponComplain();
1309                         return true;
1310                 case TE_CSQC_VEHICLESETUP:
1311                         Net_VehicleSetup();
1312                         return true;
1313                 case TE_CSQC_SVNOTICE:
1314                         cl_notice_read();
1315                         return true;
1316                 case TE_CSQC_SHOCKWAVEPARTICLE:
1317                         Net_ReadShockwaveParticle();
1318                         return true;
1319                 default:
1320                         // No special logic for this temporary entity; return 0 so the engine can handle it
1321                         return false;
1322         }
1323 }
1324
1325 string getcommandkey(string text, string command)
1326 {
1327         string keys;
1328         float n, j, k, l = 0;
1329
1330         if (!autocvar_hud_showbinds)
1331                 return text;
1332
1333         keys = db_get(binddb, command);
1334         if (keys == "")
1335         {
1336                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1337                 for(j = 0; j < n; ++j)
1338                 {
1339                         k = stof(argv(j));
1340                         if(k != -1)
1341                         {
1342                                 if ("" == keys)
1343                                         keys = keynumtostring(k);
1344                                 else
1345                                         keys = strcat(keys, ", ", keynumtostring(k));
1346
1347                                 ++l;
1348                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1349                                         break;
1350                         }
1351
1352                 }
1353                 if (keys == "")
1354                         keys = "NO_KEY";
1355                 db_put(binddb, command, keys);
1356         }
1357
1358         if (keys == "NO_KEY") {
1359                 if (autocvar_hud_showbinds > 1)
1360                         return sprintf(_("%s (not bound)"), text);
1361                 else
1362                         return text;
1363         }
1364         else if (autocvar_hud_showbinds > 1)
1365                 return sprintf("%s (%s)", text, keys);
1366         else
1367                 return keys;
1368 }