qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/centerprint.qh"
  15 #include "hud/panel/scoreboard.qh"
  16 #include "hud/panel/quickmenu.qh"
  17 #include "shownames.qh"
  18 #include "view.qh"
  19 #include <common/t_items.qh>
  20 #include "weapons/projectile.qh"
  21 #include <common/deathtypes/all.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/minigames/cl_minigames.qh>
  25 #include <common/minigames/cl_minigames_hud.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/scores.qh>
  29 #include <common/mapobjects/_mod.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  42 {
  43         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  44         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  45 }
  46
  47 void draw_cursor_normal(vector pos, vector col, float a)
  48 {
  49         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  50 }
  51
  52 void LoadMenuSkinValues()
  53 {
  54         int fh = -1;
  55         if(cvar_string("menu_skin") != "")
  56         {
  57                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  58                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  59         }
  60         if(fh < 0 && cvar_defstring("menu_skin") != "")
  61         {
  62                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  63                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  64                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  65         }
  66         if(fh < 0)
  67         {
  68                 draw_currentSkin = "gfx/menu/default";
  69                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  70         }
  71
  72         draw_currentSkin = strzone(draw_currentSkin);
  73
  74         if(fh >= 0)
  75         {
  76                 string s;
  77                 while((s = fgets(fh)))
  78                 {
  79                         int n = tokenize_console(s);
  80                         if (n < 2)
  81                                 continue;
  82                         if(substring(argv(0), 0, 2) == "//")
  83                                 continue;
  84                         if(argv(0) == "SIZE_CURSOR")
  85                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                         else if(argv(0) == "OFFSET_CURSOR")
  87                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  88                 }
  89                 fclose(fh);
  90         }
  91 }
  92
  93 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  94 // Useful for precaching things
  95
  96 void CSQC_Init()
  97 {
  98         prvm_language = strzone(cvar_string("prvm_language"));
  99
 100 #ifdef WATERMARK
 101         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 102 #endif
 103
 104         {
 105                 int i = 0;
 106                 for ( ; i < 255; ++i)
 107                         if (getplayerkeyvalue(i, "viewentity") == "")
 108                                 break;
 109                 maxclients = i;
 110         }
 111
 112         // needs to be done so early because of the constants they create
 113         static_init();
 114         static_init_late();
 115         static_init_precache();
 116
 117         binddb = db_create();
 118         tempdb = db_create();
 119         ClientProgsDB = db_load("client.db");
 120
 121         draw_endBoldFont();
 122
 123         //registercommand("hud_configure");
 124         //registercommand("hud_save");
 125         //registercommand("menu_action");
 126
 127         ConsoleCommand_macro_init();
 128
 129         registercvar("hud_usecsqc", "1");
 130         registercvar("scoreboard_columns", "default");
 131
 132         registercvar("cl_nade_type", "3");
 133         registercvar("cl_pokenade_type", "zombie");
 134
 135         registercvar("cl_jumpspeedcap_min", "");
 136         registercvar("cl_jumpspeedcap_max", "");
 137
 138         registercvar("cl_shootfromfixedorigin", "");
 139
 140         registercvar("cl_multijump", "-1");
 141
 142         registercvar("cl_dodging", "0");
 143
 144         registercvar("cl_spawn_near_teammate", "1");
 145
 146         registercvar("cl_weapon_switch_reload", "1");
 147         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 148
 149         registercvar("cl_allow_uidranking", "1");
 150
 151         if(autocvar_cl_lockview)
 152                 cvar_set("cl_lockview", "0");
 153
 154         gametype = NULL;
 155
 156         postinit = false;
 157
 158         calledhooks = 0;
 159
 160         teams = Sort_Spawn();
 161         players = Sort_Spawn();
 162
 163         GetTeam(NUM_SPECTATOR, true); // add specs first
 164
 165         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 166                 weapon_accuracy[w] = -1;
 167
 168         // precaches
 169
 170         if(autocvar_cl_reticle)
 171         {
 172                 precache_pic("gfx/reticle_normal");
 173                 // weapon reticles are precached in weapon files
 174         }
 175
 176         {
 177                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 178                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179                 shortmapname = mi_shortname;
 180
 181                 if (precache_pic(minimapname) == "")
 182                 {
 183                         // but maybe we have a non-clever minimap
 184                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                         if (precache_pic(minimapname) == "")
 186                                 minimapname = ""; // FAIL
 187                         else
 188                                 get_mi_min_max_texcoords(0); // load new texcoords
 189                 }
 190
 191                 mi_center = (mi_min + mi_max) * 0.5;
 192                 mi_scale = mi_max - mi_min;
 193                 minimapname = strzone(minimapname);
 194         }
 195
 196         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 197         LoadMenuSkinValues();
 198 }
 199
 200 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 201 void Shutdown()
 202 {
 203         WarpZone_Shutdown();
 204
 205         delete(teams);
 206         delete(players);
 207         db_close(binddb);
 208         db_close(tempdb);
 209         if(autocvar_cl_db_saveasdump)
 210                 db_dump(ClientProgsDB, "client.db");
 211         else
 212                 db_save(ClientProgsDB, "client.db");
 213         db_close(ClientProgsDB);
 214
 215         if(camera_active)
 216                 cvar_set("chase_active",ftos(chase_active_backup));
 217
 218         // unset the event chasecam's chase_active
 219         if(autocvar_chase_active < 0)
 220                 cvar_set("chase_active", "0");
 221
 222         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 223
 224         if (!isdemo())
 225         {
 226                 if (!(calledhooks & HOOK_START))
 227                         localcmd("\n_cl_hook_gamestart nop\n");
 228                 if (!(calledhooks & HOOK_END))
 229                         localcmd("\ncl_hook_gameend\n");
 230         }
 231
 232         localcmd("\ncl_hook_shutdown\n");
 233
 234         localcmd("\n-button12\n");
 235
 236         deactivate_minigame();
 237         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 238
 239         ReplicateVars(true); // destroy
 240 }
 241
 242 .float has_team;
 243 bool SetTeam(entity o, int Team)
 244 {
 245         TC(int, Team);
 246         //devassert_once(Team);
 247         entity tm;
 248         if(teamplay)
 249         {
 250                 switch(Team)
 251                 {
 252                         case -1:
 253                         case NUM_TEAM_1:
 254                         case NUM_TEAM_2:
 255                         case NUM_TEAM_3:
 256                         case NUM_TEAM_4:
 257                                 break;
 258                         default:
 259                                 if(GetTeam(Team, false) == NULL)
 260                                 {
 261                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 262                                         Team = NUM_SPECTATOR;
 263                                 }
 264                                 break;
 265                 }
 266         }
 267         else
 268         {
 269                 switch(Team)
 270                 {
 271                         case -1:
 272                         case 0:
 273                                 break;
 274                         default:
 275                                 if(GetTeam(Team, false) == NULL)
 276                                 {
 277                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 278                                         Team = NUM_SPECTATOR;
 279                                 }
 280                                 break;
 281                 }
 282         }
 283         if(Team == -1) // leave
 284         {
 285                 if(o.has_team)
 286                 {
 287                         tm = GetTeam(o.team, false);
 288                         tm.team_size -= 1;
 289                         o.has_team = 0;
 290                         return true;
 291                 }
 292         }
 293         else
 294         {
 295                 if (!o.has_team)
 296                 {
 297                         o.team = Team;
 298                         tm = GetTeam(Team, true);
 299                         tm.team_size += 1;
 300                         o.has_team = 1;
 301                         return true;
 302                 }
 303                 else if(Team != o.team)
 304                 {
 305                         tm = GetTeam(o.team, false);
 306                         tm.team_size -= 1;
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         return true;
 311                 }
 312         }
 313         return false;
 314 }
 315
 316 void Playerchecker_Think(entity this)
 317 {
 318         int i;
 319         entity e;
 320         for(i = 0; i < maxclients; ++i)
 321         {
 322                 e = playerslots[i];
 323                 if(entcs_GetName(i) == "")
 324                 {
 325                         if(e.sort_prev)
 326                         {
 327                                 // player disconnected
 328                                 SetTeam(e, -1);
 329                                 RemovePlayer(e);
 330                                 e.sort_prev = NULL;
 331                                 //e.gotscores = 0;
 332                         }
 333                 }
 334                 else
 335                 {
 336                         if (!e.sort_prev)
 337                         {
 338                                 // player connected
 339                                 if (!e)
 340                                 {
 341                                         playerslots[i] = e = new_pure(playerslot);
 342                                 }
 343                                 e.sv_entnum = i;
 344                                 e.ping = 0;
 345                                 e.ping_packetloss = 0;
 346                                 e.ping_movementloss = 0;
 347                                 //e.gotscores = 0; // we might already have the scores...
 348                                 int t = entcs_GetScoreTeam(i);
 349                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 350                                 RegisterPlayer(e);
 351                                 Scoreboard_UpdatePlayerPos(e);
 352                         }
 353                 }
 354         }
 355         this.nextthink = time + 0.2;
 356 }
 357
 358 void PostInit()
 359 {
 360         entity playerchecker = new_pure(playerchecker);
 361         setthink(playerchecker, Playerchecker_Think);
 362         playerchecker.nextthink = time + 0.2;
 363
 364         TrueAim_Init();
 365
 366         postinit = true;
 367 }
 368
 369 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 370 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 371 // All keys are in ascii.
 372 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 373 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 374 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 375 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 376 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 377 {
 378         TC(int, bInputType);
 379         bool override = false;
 380         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 381         if (override)
 382                 return true;
 383
 384         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 385
 386         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 387
 388         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 389
 390         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 391
 392         if(override)
 393                 return true;
 394
 395         return false;
 396 }
 397
 398 // END REQUIRED CSQC FUNCTIONS
 399 // --------------------------------------------------------------------------
 400
 401 // --------------------------------------------------------------------------
 402 // BEGIN OPTIONAL CSQC FUNCTIONS
 403
 404 void Ent_RemovePlayerScore(entity this)
 405 {
 406         if(this.owner) {
 407                 SetTeam(this.owner, -1);
 408                 this.owner.gotscores = 0;
 409                 FOREACH(Scores, true, {
 410                         this.owner.(scores(it)) = 0; // clear all scores
 411                 });
 412         }
 413 }
 414
 415 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 416 {
 417         make_pure(this);
 418         entity o;
 419
 420         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 421         // (no I've never heard of M-x replace-string, sed, or anything like that)
 422         bool isNew = !this.owner; // workaround for DP bug
 423         int n = ReadByte()-1;
 424
 425 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 426         if(!isNew && n != this.sv_entnum)
 427         {
 428                 //print("A CSQC entity changed its owner!\n");
 429                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 430                 isNew = true;
 431                 Ent_Remove(this);
 432         }
 433 #endif
 434
 435         this.sv_entnum = n;
 436
 437         o = playerslots[this.sv_entnum];
 438         if (!o)
 439         {
 440                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 441         }
 442         this.owner = o;
 443         o.sv_entnum = this.sv_entnum;
 444         o.gotscores = 1;
 445
 446         //if (!o.sort_prev)
 447         //      RegisterPlayer(o);
 448         //playerchecker will do this for us later, if it has not already done so
 449
 450         int sf = ReadShort();
 451         int lf = ReadShort();
 452         FOREACH(Scores, true, {
 453                 int p = 1 << (i % 16);
 454                 if (sf & p)
 455                 {
 456                         if (lf & p)
 457                                 o.(scores(it)) = ReadInt24_t();
 458                         else
 459                                 o.(scores(it)) = ReadChar();
 460                 }
 461         });
 462
 463         return = true;
 464
 465         if(o.sort_prev)
 466                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 467
 468         this.entremove = Ent_RemovePlayerScore;
 469 }
 470
 471 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 472 {
 473         make_pure(this);
 474         int i;
 475
 476         this.team = ReadByte();
 477         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 478
 479 #if MAX_TEAMSCORE <= 8
 480         int sf = ReadByte();
 481         int lf = ReadByte();
 482 #else
 483         int sf = ReadShort();
 484         int lf = ReadShort();
 485 #endif
 486         for(i = 0; i < MAX_TEAMSCORE; ++i)
 487                 if(sf & BIT(i))
 488                 {
 489                         if(lf & BIT(i))
 490                                 o.(teamscores(i)) = ReadInt24_t();
 491                         else
 492                                 o.(teamscores(i)) = ReadChar();
 493                 }
 494
 495         return = true;
 496
 497         Scoreboard_UpdateTeamPos(o);
 498 }
 499
 500 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 501 {
 502         make_pure(this);
 503         float newspectatee_status;
 504
 505         int f = ReadByte();
 506
 507         scoreboard_showscores_force = (f & BIT(0));
 508
 509         if(f & BIT(1))
 510         {
 511                 newspectatee_status = ReadByte();
 512                 if(newspectatee_status == player_localnum + 1)
 513                         newspectatee_status = -1; // observing
 514         }
 515         else
 516                 newspectatee_status = 0;
 517
 518         spectatorbutton_zoom = (f & BIT(2));
 519
 520         if(f & BIT(4))
 521         {
 522                 num_spectators = ReadByte();
 523
 524                 float i, slot;
 525
 526                 for(i = 0; i < MAX_SPECTATORS; ++i)
 527                         spectatorlist[i] = 0; // reset list first
 528
 529                 for(i = 0; i < num_spectators; ++i)
 530                 {
 531                         slot = ReadByte();
 532                         spectatorlist[i] = slot - 1;
 533                 }
 534         }
 535
 536         return = true;
 537
 538         if(newspectatee_status != spectatee_status)
 539         {
 540                 // clear race stuff
 541                 race_laptime = 0;
 542                 race_checkpointtime = 0;
 543                 hud_dynamic_shake_factor = -1;
 544                 spectatee_status_changed_time = time;
 545         }
 546         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 547         {
 548                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 549                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 550                 )
 551                         prev_p_health = -1;
 552                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 553                         prev_health = -1;
 554         }
 555         spectatee_status = newspectatee_status;
 556
 557         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 558 }
 559
 560 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 561 {
 562         make_pure(this);
 563         int i, j, b, f;
 564
 565         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 566
 567         if(!(nags & BIT(2)))
 568         {
 569                 strfree(vote_called_vote);
 570                 vote_active = 0;
 571         }
 572         else
 573         {
 574                 vote_active = 1;
 575         }
 576
 577         if(nags & BIT(6))
 578         {
 579                 vote_yescount = ReadByte();
 580                 vote_nocount = ReadByte();
 581                 vote_needed = ReadByte();
 582                 vote_highlighted = ReadChar();
 583         }
 584
 585         if(nags & BIT(7))
 586         {
 587                 strcpy(vote_called_vote, ReadString());
 588         }
 589
 590         if(nags & 1)
 591         {
 592                 for(j = 0; j < maxclients; ++j)
 593                         if(playerslots[j])
 594                                 playerslots[j].ready = true;
 595                 for(i = 1; i <= maxclients; i += 8)
 596                 {
 597                         f = ReadByte();
 598                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 599                                 if (!(f & b))
 600                                         if(playerslots[j])
 601                                                 playerslots[j].ready = false;
 602                 }
 603         }
 604
 605         return = true;
 606
 607         ready_waiting = (nags & BIT(0));
 608         ready_waiting_for_me = (nags & BIT(1));
 609         vote_waiting = (nags & BIT(2));
 610         vote_waiting_for_me = (nags & BIT(3));
 611         warmup_stage = (nags & BIT(4));
 612 }
 613
 614 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 615 {
 616         make_pure(this);
 617         int sf = 0;
 618         serialize(byte, 0, sf);
 619         if (sf & 1) {
 620                 for (int j = 0; j < maxclients; ++j) {
 621                         if (playerslots[j]) {
 622                                 playerslots[j].eliminated = true;
 623                         }
 624                 }
 625                 for (int i = 1; i <= maxclients; i += 8) {
 626                         int f = 0;
 627                         serialize(byte, 0, f);
 628                         for (int b = 0; b < 8; ++b) {
 629                                 if (f & BIT(b)) continue;
 630                                 int j = i - 1 + b;
 631                                 if (playerslots[j]) {
 632                                         playerslots[j].eliminated = false;
 633                                 }
 634                         }
 635                 }
 636         }
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 641 {
 642         make_pure(this);
 643         prandom_debug();
 644         float s = ReadShort();
 645         psrandom(s);
 646         return true;
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 650 {
 651         make_pure(this);
 652         int sf = ReadInt24_t();
 653         if (sf == 0) {
 654                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 655                         weapon_accuracy[w] = -1;
 656                 return true;
 657         }
 658
 659         int f = 1;
 660         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 661                 if (sf & f) {
 662                         int b = ReadByte();
 663                         if (b == 0)
 664                                 weapon_accuracy[w] = -1;
 665                         else if (b == 255)
 666                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 667                         else
 668                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 669                 }
 670                 f = (f == 0x800000) ? 1 : f * 2;
 671         }
 672         return true;
 673 }
 674
 675 void Spawn_Draw(entity this)
 676 {
 677         bool dodraw = true;
 678         if(autocvar_cl_spawn_point_dist_max)
 679         {
 680                 vector org = getpropertyvec(VF_ORIGIN);
 681                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 682         }
 683
 684         if(dodraw)
 685                 __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 686 }
 687
 688 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 689 {
 690         float teamnum = (ReadByte() - 1);
 691         vector spn_origin = ReadVector();
 692
 693         this.team = (teamnum + 1);
 694
 695         //if(is_new)
 696         //{
 697                 this.origin = spn_origin;
 698                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 699                 //droptofloor();
 700
 701                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 702                 {
 703                         this.mdl = "models/spawnpoint.md3";
 704                         this.colormod = Team_ColorRGB(teamnum);
 705                         precache_model(this.mdl);
 706                         setmodel(this, this.mdl);
 707                         this.drawmask = MASK_NORMAL;
 708                         //this.move_movetype = MOVETYPE_NOCLIP;
 709                         //this.draw = Spawn_Draw;
 710                         IL_PUSH(g_drawables, this);
 711                 }*/
 712                 if(autocvar_cl_spawn_point_particles)
 713                 {
 714                         if(teamplay)
 715                         {
 716                                 switch(teamnum)
 717                                 {
 718                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 719                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 720                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 721                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 722                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 723                                 }
 724                         }
 725                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 726
 727                         this.draw = Spawn_Draw;
 728                         if (is_new) IL_PUSH(g_drawables, this);
 729                 }
 730         //}
 731
 732         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 733         return true;
 734 }
 735
 736 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 737 {
 738         // If entnum is 0, ONLY do the local spawn actions
 739         // this way the server can disable the sending of
 740         // spawn origin or such to clients if wanted.
 741         float entnum = ReadByte();
 742
 743         if(entnum)
 744         {
 745                 this.origin = ReadVector();
 746
 747                 if(is_new)
 748                 {
 749                         float teamnum = entcs_GetTeam(entnum - 1);
 750
 751                         if(autocvar_cl_spawn_event_particles)
 752                         {
 753                                 switch(teamnum)
 754                                 {
 755                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 756                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 757                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 758                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 759                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 760                                 }
 761                         }
 762                         if(autocvar_cl_spawn_event_sound)
 763                         {
 764                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 765                         }
 766                 }
 767         }
 768         return = true;
 769
 770         // local spawn actions
 771         if(is_new && (!entnum || (entnum == player_localentnum)))
 772         {
 773                 zoomin_effect = 1;
 774                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 775
 776                 if(autocvar_cl_unpress_zoom_on_spawn)
 777                 {
 778                         localcmd("-zoom\n");
 779                         button_zoom = false;
 780                 }
 781                 HUD_Radar_Hide_Maximized();
 782         }
 783         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 784 }
 785
 786 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 787 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 788 void CSQC_Ent_Update(entity this, bool isnew)
 789 {
 790         this.sourceLoc = __FILE__":"STR(__LINE__);
 791         int t = ReadByte();
 792
 793         // set up the "time" global for received entities to be correct for interpolation purposes
 794         float savetime = time;
 795         if(servertime)
 796         {
 797                 time = servertime;
 798         }
 799         else
 800         {
 801                 serverprevtime = time;
 802                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 803                 time = serverprevtime + serverdeltatime;
 804         }
 805
 806 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 807         if (this.enttype)
 808         {
 809                 if (t != this.enttype || isnew)
 810                 {
 811                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 812                         Ent_Remove(this);
 813                         clearentity(this);
 814                         isnew = true;
 815                 }
 816         }
 817         else
 818         {
 819                 if (!isnew)
 820                 {
 821                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 822                         isnew = true;
 823                 }
 824         }
 825 #endif
 826         this.enttype = t;
 827         bool done = false;
 828         FOREACH(LinkedEntities, it.m_id == t, {
 829                 if (isnew) this.classname = it.netname;
 830                 if (autocvar_developer_csqcentities)
 831             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 832                 done = it.m_read(this, NULL, isnew);
 833                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 834                 break;
 835         });
 836         time = savetime;
 837         if (!done)
 838         {
 839                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 840         }
 841 }
 842
 843 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 844 // used when an entity changes its type. For an entity that someone interacts
 845 // with others, make sure it can no longer do so.
 846 void Ent_Remove(entity this)
 847 {
 848         if(this.entremove) this.entremove(this);
 849
 850         if(this.skeletonindex)
 851         {
 852                 skel_delete(this.skeletonindex);
 853                 this.skeletonindex = 0;
 854         }
 855
 856         if(this.snd_looping > 0)
 857         {
 858                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 859                 this.snd_looping = 0;
 860         }
 861
 862         this.enttype = 0;
 863         this.classname = "";
 864         this.draw = func_null;
 865         this.entremove = func_null;
 866         // TODO possibly set more stuff to defaults
 867 }
 868 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 869 void CSQC_Ent_Remove(entity this)
 870 {
 871         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 872         if (wasfreed(this))
 873         {
 874                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 875                 return;
 876         }
 877         if (this.enttype) Ent_Remove(this);
 878         delete(this);
 879 }
 880
 881 void Gamemode_Init()
 882 {
 883         if (!isdemo())
 884         {
 885                 if(!(calledhooks & HOOK_START))
 886                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 887                 calledhooks |= HOOK_START;
 888         }
 889 }
 890 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 891 void CSQC_Parse_StuffCmd(string strMessage)
 892 {
 893         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 894         localcmd(strMessage);
 895 }
 896 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 897 void CSQC_Parse_Print(string strMessage)
 898 {
 899         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 900         print(ColorTranslateRGB(strMessage));
 901 }
 902
 903 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 904 void CSQC_Parse_CenterPrint(string strMessage)
 905 {
 906         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 907         centerprint_AddStandard(strMessage);
 908 }
 909
 910 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 911 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 912 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 913 bool CSQC_Parse_TempEntity()
 914 {
 915         // Acquire TE ID
 916         int nTEID = ReadByte();
 917
 918         FOREACH(TempEntities, it.m_id == nTEID, {
 919                 if (autocvar_developer_csqcentities)
 920                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 921                 return it.m_read(NULL, NULL, true);
 922         });
 923
 924         if (autocvar_developer_csqcentities)
 925                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 926
 927         // No special logic for this temporary entity; return 0 so the engine can handle it
 928         return false;
 929 }
 930
 931 string forcefog;
 932 void Fog_Force()
 933 {
 934         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 935                 localcmd("\nr_drawfog 0\n");
 936         else if (forcefog != "")
 937                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 938 }
 939
 940 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 941 {
 942         make_pure(this);
 943         gametype = ReadRegistered(Gametypes);
 944         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 945         HUD_ModIcons_SetFunc();
 946         FOREACH(Scores, true, {
 947                 strcpy(scores_label(it), ReadString());
 948                 scores_flags(it) = ReadByte();
 949         });
 950         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 951         {
 952                 strcpy(teamscores_label(i), ReadString());
 953                 teamscores_flags(i) = ReadByte();
 954         }
 955         return = true;
 956         Scoreboard_InitScores();
 957         Gamemode_Init();
 958 }
 959
 960 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 961 {
 962         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 963
 964         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 965         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 966         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 967         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 969         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 970         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 971         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 972
 973         strcpy(forcefog, ReadString());
 974
 975         armorblockpercent = ReadByte() / 255.0;
 976         damagepush_speedfactor = ReadByte() / 255.0;
 977
 978         serverflags = ReadByte();
 979
 980         g_trueaim_minrange = ReadCoord();
 981
 982         return = true;
 983
 984         MUTATOR_CALLHOOK(Ent_Init);
 985
 986         if (!postinit) PostInit();
 987 }
 988
 989 float GetSpeedUnitFactor(int speed_unit)
 990 {
 991         switch(speed_unit)
 992         {
 993                 default:
 994                 case 1:
 995                         return 1.0;
 996                 case 2:
 997                         return 0.0254;
 998                 case 3:
 999                         return 0.0254 * 3.6;
1000                 case 4:
1001                         return 0.0254 * 3.6 * 0.6213711922;
1002                 case 5:
1003                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1004         }
1005 }
1006
1007 string GetSpeedUnit(int speed_unit)
1008 {
1009         switch(speed_unit)
1010         {
1011                 default:
1012                 case 1:
1013                         return _(" qu/s");
1014                 case 2:
1015                         return _(" m/s");
1016                 case 3:
1017                         return _(" km/h");
1018                 case 4:
1019                         return _(" mph");
1020                 case 5:
1021                         return _(" knots");
1022         }
1023 }
1024
1025 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1026 {
1027         int b = ReadByte();
1028
1029         switch (b)
1030         {
1031                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1032                         race_checkpoint = ReadByte();
1033                         race_time = ReadInt24_t();
1034                         race_previousbesttime = ReadInt24_t();
1035                         race_mypreviousbesttime = ReadInt24_t();
1036                         string pbestname = ReadString();
1037                         if(autocvar_cl_race_cptimes_onlyself)
1038                         {
1039                                 race_previousbesttime = race_mypreviousbesttime;
1040                                 race_mypreviousbesttime = 0;
1041                                 strcpy(race_previousbestname, "");
1042                         }
1043                         else
1044                                 strcpy(race_previousbestname, pbestname);
1045
1046                         race_checkpointtime = time;
1047
1048                         if(race_checkpoint == 0 || race_checkpoint == 254)
1049                         {
1050                                 race_penaltyaccumulator = 0;
1051                                 race_laptime = time; // valid
1052                         }
1053                         break;
1054
1055                 case RACE_NET_CHECKPOINT_CLEAR:
1056                         race_laptime = 0;
1057                         race_checkpointtime = 0;
1058                         break;
1059
1060                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1061                         race_laptime = ReadCoord();
1062                         race_checkpointtime = -99999;
1063                         // fall through
1064                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1065                         race_nextcheckpoint = ReadByte();
1066
1067                         race_nextbesttime = ReadInt24_t();
1068                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1069                                 race_mybesttime = ReadInt24_t();
1070                         string newname = ReadString();
1071                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1072                         {
1073                                 race_nextbesttime = race_mybesttime;
1074                                 race_mybesttime = 0;
1075                                 strcpy(race_nextbestname, "");
1076                         }
1077                         else
1078                                 strcpy(race_nextbestname, newname);
1079                         break;
1080
1081                 case RACE_NET_CHECKPOINT_HIT_RACE:
1082                         race_mycheckpoint = ReadByte();
1083                         race_mycheckpointtime = time;
1084                         race_mycheckpointdelta = ReadInt24_t();
1085                         race_mycheckpointlapsdelta = ReadByte();
1086                         if(race_mycheckpointlapsdelta >= 128)
1087                                 race_mycheckpointlapsdelta -= 256;
1088                         int who = ReadByte();
1089                         if(who)
1090                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1091                         else
1092                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1093                         break;
1094
1095                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1096                         race_othercheckpoint = ReadByte();
1097                         race_othercheckpointtime = time;
1098                         race_othercheckpointdelta = ReadInt24_t();
1099                         race_othercheckpointlapsdelta = ReadByte();
1100                         if(race_othercheckpointlapsdelta >= 128)
1101                                 race_othercheckpointlapsdelta -= 256;
1102                         int what = ReadByte();
1103                         if(what)
1104                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1105                         else
1106                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1107                         break;
1108
1109                 case RACE_NET_PENALTY_RACE:
1110                 case RACE_NET_PENALTY_QUALIFYING:
1111                         race_penaltyeventtime = time;
1112                         race_penaltytime = ReadShort();
1113                         string reason = ReadString();
1114                         if (reason == "missing a checkpoint")
1115                                 reason = _("missing a checkpoint");
1116                         strcpy(race_penaltyreason, reason);
1117                         if (b == RACE_NET_PENALTY_QUALIFYING)
1118                                 race_penaltyaccumulator += race_penaltytime;
1119                         break;
1120
1121                 case RACE_NET_SERVER_RECORD:
1122                         race_server_record = ReadInt24_t();
1123                         break;
1124                 case RACE_NET_SPEED_AWARD:
1125                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1126                         strcpy(race_speedaward_holder, ReadString());
1127                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1128                         break;
1129                 case RACE_NET_SPEED_AWARD_BEST:
1130                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1131                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1132                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1133                         break;
1134                 case RACE_NET_RANKINGS_CNT:
1135                         RANKINGS_DISPLAY_CNT = ReadByte();
1136                         break;
1137                 case RACE_NET_SERVER_RANKINGS:
1138                         float prevpos, del;
1139                         int pos = ReadShort();
1140                         prevpos = ReadShort();
1141                         del = ReadShort();
1142
1143                         // move other rankings out of the way
1144                         int i;
1145                         if (prevpos) {
1146                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1147                                 for (i=m-1; i>pos-1; --i) {
1148                                         grecordtime[i] = grecordtime[i-1];
1149                                         strcpy(grecordholder[i], grecordholder[i-1]);
1150                                 }
1151                         } else if (del) { // a record has been deleted by the admin
1152                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1153                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1154                                                 grecordtime[i] = 0;
1155                                                 strfree(grecordholder[i]);
1156                                         }
1157                                         else {
1158                                                 grecordtime[i] = grecordtime[i+1];
1159                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1160                                         }
1161                                 }
1162                         } else { // player has no ranked record yet
1163                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1164                                         grecordtime[i] = grecordtime[i-1];
1165                                         strcpy(grecordholder[i], grecordholder[i-1]);
1166                                 }
1167                         }
1168
1169                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1170                                 // kick off the player who fell from the last displayed position
1171                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1172                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1173                         }
1174
1175                         // store new ranking
1176                         strcpy(grecordholder[pos-1], ReadString());
1177                         grecordtime[pos-1] = ReadInt24_t();
1178                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1179                                 race_myrank = pos;
1180                         break;
1181                 case RACE_NET_SERVER_STATUS:
1182                         race_status = ReadShort();
1183                         strcpy(race_status_name, ReadString());
1184         }
1185         return true;
1186 }
1187
1188 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1189 {
1190         teamnagger = 1;
1191         return true;
1192 }
1193
1194 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1195 {
1196         int i = ReadByte();
1197         int pi = ReadShort();
1198         int pl = ReadByte();
1199         int ml = ReadByte();
1200         return = true;
1201         entity e = playerslots[i];
1202         if (!e) return;
1203         e.ping = pi;
1204         e.ping_packetloss = pl / 255.0;
1205         e.ping_movementloss = ml / 255.0;
1206 }
1207
1208 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1209 {
1210         int weapon_id = ReadByte();
1211         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1212         complain_weapon_type = ReadByte();
1213         return = true;
1214
1215         complain_weapon_time = time;
1216         weapontime = time; // ping the weapon panel
1217
1218         switch(complain_weapon_type)
1219         {
1220                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1221                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1222                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1223         }
1224 }
1225
1226 string _getcommandkey(string cmd_name, string command, bool forcename)
1227 {
1228         string keys;
1229         float n, j, k, l = 0;
1230
1231         if (!autocvar_hud_showbinds)
1232                 return cmd_name;
1233
1234         keys = db_get(binddb, command);
1235         if (keys == "")
1236         {
1237                 bool joy_active = cvar("joy_active");
1238                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1239                 for(j = 0; j < n; ++j)
1240                 {
1241                         k = stof(argv(j));
1242                         if(k != -1)
1243                         {
1244                                 string key = keynumtostring(k);
1245                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1246                                         continue;
1247
1248                                 key = translate_key(key);
1249
1250                                 if (keys == "")
1251                                         keys = key;
1252                                 else
1253                                         keys = strcat(keys, ", ", key);
1254
1255                                 ++l;
1256                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1257                                         break;
1258                         }
1259
1260                 }
1261                 if (keys == "")
1262                         keys = "NO_KEY";
1263                 db_put(binddb, command, keys);
1264         }
1265
1266         if (keys == "NO_KEY") {
1267                 if (autocvar_hud_showbinds > 1)
1268                         return sprintf(_("%s (not bound)"), cmd_name);
1269                 else
1270                         return cmd_name;
1271         }
1272         else if (autocvar_hud_showbinds > 1 || forcename)
1273                 return sprintf("%s (%s)", cmd_name, keys);
1274         else
1275                 return keys;
1276 }