qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "../common/effects/qc/all.qh"
   4 #include "hook.qh"
   5 #include "hud/all.qh"
   6 #include "mapvoting.qh"
   7 #include "mutators/events.qh"
   8 #include "quickmenu.qh"
   9 #include "scoreboard.qh"
  10 #include "shownames.qh"
  11 #include "tuba.qh"
  12 #include "t_items.qh"
  13 #include "wall.qh"
  14 #include "weapons/projectile.qh"
  15 #include "../common/deathtypes/all.qh"
  16 #include "../common/items/all.qh"
  17 #include "../common/mapinfo.qh"
  18 #include "../common/minigames/cl_minigames.qh"
  19 #include "../common/minigames/cl_minigames_hud.qh"
  20 #include "../common/net_notice.qh"
  21 #include "../common/triggers/include.qh"
  22 #include "../common/vehicles/all.qh"
  23 #include "../lib/csqcmodel/cl_model.qh"
  24 #include "../lib/csqcmodel/interpolate.qh"
  25 #include "../lib/warpzone/client.qh"
  26
  27 // --------------------------------------------------------------------------
  28 // BEGIN REQUIRED CSQC FUNCTIONS
  29 //include "main.qh"
  30
  31 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void ConsoleCommand_macro_init();
  37 void CSQC_Init()
  38 {
  39         prvm_language = strzone(cvar_string("prvm_language"));
  40
  41 #ifdef WATERMARK
  42         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  43 #endif
  44
  45         binddb = db_create();
  46         tempdb = db_create();
  47         ClientProgsDB = db_load("client.db");
  48         compressShortVector_init();
  49
  50         draw_endBoldFont();
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         //registercommand("hud_configure");
  61         //registercommand("hud_save");
  62         //registercommand("menu_action");
  63
  64         ConsoleCommand_macro_init();
  65
  66         registercvar("hud_usecsqc", "1");
  67         registercvar("scoreboard_columns", "default");
  68
  69         registercvar("cl_nade_type", "3");
  70         registercvar("cl_pokenade_type", "zombie");
  71
  72         registercvar("cl_jumpspeedcap_min", "");
  73         registercvar("cl_jumpspeedcap_max", "");
  74
  75         registercvar("cl_multijump", "0");
  76
  77         registercvar("cl_spawn_near_teammate", "1");
  78
  79         gametype = 0;
  80
  81         // hud_fields uses strunzone on the titles!
  82         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
  83                 hud_title[i] = strzone("(null)");
  84
  85         Cmd_HUD_SetFields(0);
  86
  87         postinit = false;
  88
  89         calledhooks = 0;
  90
  91         teams = Sort_Spawn();
  92         players = Sort_Spawn();
  93
  94         GetTeam(NUM_SPECTATOR, true); // add specs first
  95
  96         // needs to be done so early because of the constants they create
  97         static_init();
  98         static_init_late();
  99         static_init_precache();
 100
 101         // precaches
 102
 103         if(autocvar_cl_reticle)
 104         {
 105                 precache_pic("gfx/reticle_normal");
 106                 // weapon reticles are precached in weapon files
 107         }
 108
 109         {
 110                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 111                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 112                 shortmapname = mi_shortname;
 113
 114                 if (precache_pic(minimapname) == "")
 115                 {
 116                         // but maybe we have a non-clever minimap
 117                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 118                         if (precache_pic(minimapname) == "")
 119                                 minimapname = ""; // FAIL
 120                         else
 121                                 get_mi_min_max_texcoords(0); // load new texcoords
 122                 }
 123
 124                 mi_center = (mi_min + mi_max) * 0.5;
 125                 mi_scale = mi_max - mi_min;
 126                 minimapname = strzone(minimapname);
 127         }
 128
 129         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 130         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 131 }
 132
 133 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 134 void Shutdown()
 135 {
 136         WarpZone_Shutdown();
 137
 138         remove(teams);
 139         remove(players);
 140         db_close(binddb);
 141         db_close(tempdb);
 142         if(autocvar_cl_db_saveasdump)
 143                 db_dump(ClientProgsDB, "client.db");
 144         else
 145                 db_save(ClientProgsDB, "client.db");
 146         db_close(ClientProgsDB);
 147
 148         if(camera_active)
 149                 cvar_set("chase_active",ftos(chase_active_backup));
 150
 151         // unset the event chasecam's chase_active
 152         if(autocvar_chase_active < 0)
 153                 cvar_set("chase_active", "0");
 154
 155         if (!isdemo())
 156         {
 157                 if (!(calledhooks & HOOK_START))
 158                         localcmd("\n_cl_hook_gamestart nop\n");
 159                 if (!(calledhooks & HOOK_END))
 160                         localcmd("\ncl_hook_gameend\n");
 161         }
 162
 163         deactivate_minigame();
 164         HUD_MinigameMenu_Close();
 165 }
 166
 167 .float has_team;
 168 float SetTeam(entity o, int Team)
 169 {
 170         entity tm;
 171         if(teamplay)
 172         {
 173                 switch(Team)
 174                 {
 175                         case -1:
 176                         case NUM_TEAM_1:
 177                         case NUM_TEAM_2:
 178                         case NUM_TEAM_3:
 179                         case NUM_TEAM_4:
 180                                 break;
 181                         default:
 182                                 if(GetTeam(Team, false) == world)
 183                                 {
 184                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 185                                         Team = NUM_SPECTATOR;
 186                                 }
 187                                 break;
 188                 }
 189         }
 190         else
 191         {
 192                 switch(Team)
 193                 {
 194                         case -1:
 195                         case 0:
 196                                 break;
 197                         default:
 198                                 if(GetTeam(Team, false) == world)
 199                                 {
 200                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 201                                         Team = NUM_SPECTATOR;
 202                                 }
 203                                 break;
 204                 }
 205         }
 206         if(Team == -1) // leave
 207         {
 208                 if(o.has_team)
 209                 {
 210                         tm = GetTeam(o.team, false);
 211                         tm.team_size -= 1;
 212                         o.has_team = 0;
 213                         return true;
 214                 }
 215         }
 216         else
 217         {
 218                 if (!o.has_team)
 219                 {
 220                         o.team = Team;
 221                         tm = GetTeam(Team, true);
 222                         tm.team_size += 1;
 223                         o.has_team = 1;
 224                         return true;
 225                 }
 226                 else if(Team != o.team)
 227                 {
 228                         tm = GetTeam(o.team, false);
 229                         tm.team_size -= 1;
 230                         o.team = Team;
 231                         tm = GetTeam(Team, true);
 232                         tm.team_size += 1;
 233                         return true;
 234                 }
 235         }
 236         return false;
 237 }
 238
 239 void Playerchecker_Think()
 240 {
 241         SELFPARAM();
 242     int i;
 243         entity e;
 244         for(i = 0; i < maxclients; ++i)
 245         {
 246                 e = playerslots[i];
 247                 if(entcs_GetName(i) == "")
 248                 {
 249                         if(e.sort_prev)
 250                         {
 251                                 // player disconnected
 252                                 SetTeam(e, -1);
 253                                 RemovePlayer(e);
 254                                 e.sort_prev = world;
 255                                 //e.gotscores = 0;
 256                         }
 257                 }
 258                 else
 259                 {
 260                         if (!e.sort_prev)
 261                         {
 262                                 // player connected
 263                                 if (!e)
 264                                 {
 265                                         playerslots[i] = e = new(playerslot);
 266                                         make_pure(e);
 267                                 }
 268                                 e.sv_entnum = i;
 269                                 e.ping = 0;
 270                                 e.ping_packetloss = 0;
 271                                 e.ping_movementloss = 0;
 272                                 //e.gotscores = 0; // we might already have the scores...
 273                                 SetTeam(e, entcs_GetTeam(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 274                                 RegisterPlayer(e);
 275                                 HUD_UpdatePlayerPos(e);
 276                         }
 277                 }
 278         }
 279         this.nextthink = time + 0.2;
 280 }
 281
 282 void Porto_Init();
 283 void TrueAim_Init();
 284 void PostInit()
 285 {
 286         entity playerchecker = new(playerchecker);
 287         make_pure(playerchecker);
 288         playerchecker.think = Playerchecker_Think;
 289         playerchecker.nextthink = time + 0.2;
 290
 291         Porto_Init();
 292         TrueAim_Init();
 293
 294         postinit = true;
 295 }
 296
 297 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 298 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 299 // All keys are in ascii.
 300 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 301 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 302 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 303 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 304 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 305 {
 306         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 307                 return true;
 308
 309         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 310                 return true;
 311
 312         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 313                 return true;
 314
 315         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 316                 return true;
 317
 318         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 319                 return true;
 320
 321         return false;
 322 }
 323
 324 // END REQUIRED CSQC FUNCTIONS
 325 // --------------------------------------------------------------------------
 326
 327 // --------------------------------------------------------------------------
 328 // BEGIN OPTIONAL CSQC FUNCTIONS
 329
 330 void Ent_Remove();
 331
 332 void Ent_RemovePlayerScore()
 333 {
 334         SELFPARAM();
 335         if(this.owner) {
 336                 SetTeam(this.owner, -1);
 337                 this.owner.gotscores = 0;
 338                 for(int i = 0; i < MAX_SCORE; ++i) {
 339                         this.owner.(scores[i]) = 0; // clear all scores
 340                 }
 341         }
 342 }
 343
 344 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 345 {
 346         make_pure(this);
 347         int i, n;
 348         bool isNew;
 349         entity o;
 350
 351         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 352         // (no I've never heard of M-x replace-string, sed, or anything like that)
 353         isNew = !this.owner; // workaround for DP bug
 354         n = ReadByte()-1;
 355
 356 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 357         if(!isNew && n != this.sv_entnum)
 358         {
 359                 //print("A CSQC entity changed its owner!\n");
 360                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(this), this.classname);
 361                 isNew = true;
 362                 Ent_Remove();
 363         }
 364 #endif
 365
 366         this.sv_entnum = n;
 367
 368         o = playerslots[this.sv_entnum];
 369         if (!o)
 370         {
 371                 o = playerslots[this.sv_entnum] = new(playerslot);
 372                 make_pure(o);
 373         }
 374         this.owner = o;
 375         o.sv_entnum = this.sv_entnum;
 376         o.gotscores = 1;
 377
 378         //if (!o.sort_prev)
 379         //      RegisterPlayer(o);
 380         //playerchecker will do this for us later, if it has not already done so
 381
 382     int sf, lf;
 383 #if MAX_SCORE <= 8
 384         sf = ReadByte();
 385         lf = ReadByte();
 386 #else
 387         sf = ReadShort();
 388         lf = ReadShort();
 389 #endif
 390     int p;
 391         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 392                 if(sf & p)
 393                 {
 394                         if(lf & p)
 395                                 o.(scores[i]) = ReadInt24_t();
 396                         else
 397                                 o.(scores[i]) = ReadChar();
 398                 }
 399
 400         return = true;
 401
 402         if(o.sort_prev)
 403                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 404
 405         this.entremove = Ent_RemovePlayerScore;
 406 }
 407
 408 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 409 {
 410         make_pure(this);
 411         int i;
 412         entity o;
 413
 414         this.team = ReadByte();
 415         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 416
 417     int sf, lf;
 418 #if MAX_TEAMSCORE <= 8
 419         sf = ReadByte();
 420         lf = ReadByte();
 421 #else
 422         sf = ReadShort();
 423         lf = ReadShort();
 424 #endif
 425         int p;
 426         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 427                 if(sf & p)
 428                 {
 429                         if(lf & p)
 430                                 o.(teamscores[i]) = ReadInt24_t();
 431                         else
 432                                 o.(teamscores[i]) = ReadChar();
 433                 }
 434
 435         return = true;
 436
 437         HUD_UpdateTeamPos(o);
 438 }
 439
 440 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 441 {
 442         make_pure(this);
 443         float newspectatee_status;
 444
 445     int f = ReadByte();
 446
 447         scoreboard_showscores_force = (f & 1);
 448
 449         if(f & 2)
 450         {
 451                 newspectatee_status = ReadByte();
 452                 if(newspectatee_status == player_localnum + 1)
 453                         newspectatee_status = -1; // observing
 454         }
 455         else
 456                 newspectatee_status = 0;
 457
 458         spectatorbutton_zoom = (f & 4);
 459
 460         if(f & 8)
 461         {
 462                 angles_held_status = 1;
 463                 angles_held.x = ReadAngle();
 464                 angles_held.y = ReadAngle();
 465                 angles_held.z = 0;
 466         }
 467         else
 468                 angles_held_status = 0;
 469
 470         return = true;
 471
 472         if(newspectatee_status != spectatee_status)
 473         {
 474                 // clear race stuff
 475                 race_laptime = 0;
 476                 race_checkpointtime = 0;
 477         }
 478         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 479         {
 480                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 481                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 482                 )
 483                         prev_p_health = -1;
 484                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 485                         prev_health = -1;
 486         }
 487         spectatee_status = newspectatee_status;
 488
 489         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 490 }
 491
 492 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 493 {
 494         make_pure(this);
 495     int i, j, b, f;
 496
 497     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 498
 499         if(!(nags & BIT(2)))
 500         {
 501                 if(vote_called_vote)
 502                         strunzone(vote_called_vote);
 503                 vote_called_vote = string_null;
 504                 vote_active = 0;
 505         }
 506         else
 507         {
 508                 vote_active = 1;
 509         }
 510
 511         if(nags & BIT(6))
 512         {
 513                 vote_yescount = ReadByte();
 514                 vote_nocount = ReadByte();
 515                 vote_needed = ReadByte();
 516                 vote_highlighted = ReadChar();
 517         }
 518
 519         if(nags & BIT(7))
 520         {
 521                 if(vote_called_vote)
 522                         strunzone(vote_called_vote);
 523                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 524         }
 525
 526         if(nags & 1)
 527         {
 528                 for(j = 0; j < maxclients; ++j)
 529                         if(playerslots[j])
 530                                 playerslots[j].ready = 1;
 531                 for(i = 1; i <= maxclients; i += 8)
 532                 {
 533                         f = ReadByte();
 534                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 535                                 if (!(f & b))
 536                                         if(playerslots[j])
 537                                                 playerslots[j].ready = 0;
 538                 }
 539         }
 540
 541         return = true;
 542
 543         ready_waiting = (nags & BIT(0));
 544         ready_waiting_for_me = (nags & BIT(1));
 545         vote_waiting = (nags & BIT(2));
 546         vote_waiting_for_me = (nags & BIT(3));
 547         warmup_stage = (nags & BIT(4));
 548 }
 549
 550 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 551 {
 552         make_pure(this);
 553     int i, j, b, f;
 554
 555     int sf = ReadByte();
 556         if(sf & 1)
 557         {
 558                 for(j = 0; j < maxclients; ++j)
 559                         if(playerslots[j])
 560                                 playerslots[j].eliminated = 1;
 561                 for(i = 1; i <= maxclients; i += 8)
 562                 {
 563                         f = ReadByte();
 564                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 565                                 if (!(f & b))
 566                                         if(playerslots[j])
 567                                                 playerslots[j].eliminated = 0;
 568                 }
 569         }
 570         return true;
 571 }
 572
 573 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 574 {
 575         make_pure(this);
 576         prandom_debug();
 577         float s = ReadShort();
 578         psrandom(s);
 579         return true;
 580 }
 581
 582 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 583 {
 584         make_pure(this);
 585     int sf = ReadInt24_t();
 586         if (sf == 0) {
 587                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 588                         weapon_accuracy[w] = -1;
 589                 return true;
 590         }
 591
 592         int f = 1;
 593         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 594                 if (sf & f) {
 595             int b = ReadByte();
 596                         if (b == 0)
 597                                 weapon_accuracy[w] = -1;
 598                         else if (b == 255)
 599                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 600                         else
 601                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 602                 }
 603                 f = (f == 0x800000) ? 1 : f * 2;
 604         }
 605         return true;
 606 }
 607
 608 void Spawn_Draw(entity this)
 609 {
 610         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 611 }
 612
 613 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 614 {
 615         float teamnum = (ReadByte() - 1);
 616         vector spn_origin;
 617         spn_origin.x = ReadShort();
 618         spn_origin.y = ReadShort();
 619         spn_origin.z = ReadShort();
 620
 621         //if(is_new)
 622         //{
 623                 this.origin = spn_origin;
 624                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 625                 //droptofloor();
 626
 627                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 628                 {
 629                         this.mdl = "models/spawnpoint.md3";
 630                         this.colormod = Team_ColorRGB(teamnum);
 631                         precache_model(this.mdl);
 632                         setmodel(this, this.mdl);
 633                         this.drawmask = MASK_NORMAL;
 634                         //this.movetype = MOVETYPE_NOCLIP;
 635                         //this.draw = Spawn_Draw;
 636                 }*/
 637                 if(autocvar_cl_spawn_point_particles)
 638                 {
 639                         if((serverflags & SERVERFLAG_TEAMPLAY))
 640                         {
 641                                 switch(teamnum)
 642                                 {
 643                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 644                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 645                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 646                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 647                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 648                                 }
 649                         }
 650                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 651
 652                         this.draw = Spawn_Draw;
 653                 }
 654         //}
 655
 656         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 657         return true;
 658 }
 659
 660 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 661 {
 662         // If entnum is 0, ONLY do the local spawn actions
 663         // this way the server can disable the sending of
 664         // spawn origin or such to clients if wanted.
 665         float entnum = ReadByte();
 666
 667         if(entnum)
 668         {
 669                 this.origin_x = ReadShort();
 670                 this.origin_y = ReadShort();
 671                 this.origin_z = ReadShort();
 672
 673                 if(is_new)
 674                 {
 675                         float teamnum = entcs_GetTeam(entnum - 1);
 676
 677                         if(autocvar_cl_spawn_event_particles)
 678                         {
 679                                 switch(teamnum)
 680                                 {
 681                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 682                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 683                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 684                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 685                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 686                                 }
 687                         }
 688                         if(autocvar_cl_spawn_event_sound)
 689                         {
 690                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 691                         }
 692                 }
 693         }
 694         return = true;
 695
 696         // local spawn actions
 697         if(is_new && (!entnum || (entnum == player_localentnum)))
 698         {
 699                 zoomin_effect = 1;
 700                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 701
 702                 if(autocvar_cl_unpress_zoom_on_spawn)
 703                 {
 704                         localcmd("-zoom\n");
 705                         button_zoom = false;
 706                 }
 707         }
 708         HUD_Radar_Hide_Maximized();
 709         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 710 }
 711
 712 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 713 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 714 void CSQC_Ent_Update(bool isnew)
 715 {
 716         SELFPARAM();
 717         this.sourceLocLine = __LINE__;
 718         this.sourceLocFile = __FILE__;
 719         int t = ReadByte();
 720
 721         // set up the "time" global for received entities to be correct for interpolation purposes
 722         float savetime = time;
 723         if(servertime)
 724         {
 725                 time = servertime;
 726         }
 727         else
 728         {
 729                 serverprevtime = time;
 730                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 731                 time = serverprevtime + serverdeltatime;
 732         }
 733
 734 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 735         if (this.enttype)
 736         {
 737                 if (t != this.enttype || isnew)
 738                 {
 739                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(this), this.entnum, this.enttype, t);
 740                         Ent_Remove();
 741                         clearentity(this);
 742                         isnew = true;
 743                 }
 744         }
 745         else
 746         {
 747                 if (!isnew)
 748                 {
 749                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(this), this.entnum, t);
 750                         isnew = true;
 751                 }
 752         }
 753 #endif
 754         this.enttype = t;
 755         bool done = false;
 756         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 757                 if (isnew) this.classname = it.netname;
 758                 if (autocvar_developer_csqcentities)
 759             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 760                 done = it.m_read(this, isnew);
 761                 break;
 762         ));
 763         time = savetime;
 764         if (!done)
 765         {
 766                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 767         }
 768 }
 769
 770 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 771 // used when an entity changes its type. For an entity that someone interacts
 772 // with others, make sure it can no longer do so.
 773 void Ent_Remove()
 774 {
 775         SELFPARAM();
 776         if(this.entremove) this.entremove();
 777
 778         if(this.skeletonindex)
 779         {
 780                 skel_delete(this.skeletonindex);
 781                 this.skeletonindex = 0;
 782         }
 783
 784         if(this.snd_looping > 0)
 785         {
 786                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 787                 this.snd_looping = 0;
 788         }
 789
 790         this.enttype = 0;
 791         this.classname = "";
 792         this.draw = func_null;
 793         this.entremove = func_null;
 794         // TODO possibly set more stuff to defaults
 795 }
 796 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 797 void CSQC_Ent_Remove()
 798 {
 799         SELFPARAM();
 800         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 801         if (wasfreed(this))
 802         {
 803                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 804                 return;
 805         }
 806         if (this.enttype) Ent_Remove();
 807         remove(this);
 808 }
 809
 810 void Gamemode_Init()
 811 {
 812         if (!isdemo())
 813         {
 814                 if(!(calledhooks & HOOK_START))
 815                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 816                 calledhooks |= HOOK_START;
 817         }
 818 }
 819 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 820 void CSQC_Parse_StuffCmd(string strMessage)
 821 {
 822         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 823         localcmd(strMessage);
 824 }
 825 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 826 void CSQC_Parse_Print(string strMessage)
 827 {
 828         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 829         print(ColorTranslateRGB(strMessage));
 830 }
 831
 832 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 833 void CSQC_Parse_CenterPrint(string strMessage)
 834 {
 835         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 836         centerprint_hud(strMessage);
 837 }
 838
 839 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 840 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 841 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 842 bool CSQC_Parse_TempEntity()
 843 {
 844         // Acquire TE ID
 845         int nTEID = ReadByte();
 846
 847         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
 848                 if (autocvar_developer_csqcentities)
 849                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 850                 return it.m_read(NULL, true);
 851         ));
 852
 853         if (autocvar_developer_csqcentities)
 854                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 855
 856         // No special logic for this temporary entity; return 0 so the engine can handle it
 857         return false;
 858 }
 859
 860 /** TODO somehow thwart prvm_globalset client ... */
 861 string forcefog;
 862 void Fog_Force()
 863 {
 864         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 865                 localcmd("\nr_drawfog 0\n");
 866         else if (forcefog != "")
 867                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 868 }
 869
 870 void Gamemode_Init();
 871 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 872 {
 873         make_pure(this);
 874         gametype = ReadInt24_t();
 875         HUD_ModIcons_SetFunc();
 876         for (int i = 0; i < MAX_SCORE; ++i)
 877         {
 878                 if (scores_label[i]) strunzone(scores_label[i]);
 879                 scores_label[i] = strzone(ReadString());
 880                 scores_flags[i] = ReadByte();
 881         }
 882         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 883         {
 884                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 885                 teamscores_label[i] = strzone(ReadString());
 886                 teamscores_flags[i] = ReadByte();
 887         }
 888         return = true;
 889         HUD_InitScores();
 890         Gamemode_Init();
 891 }
 892
 893 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 894 {
 895         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 896
 897         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 898         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 899         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 900         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 901         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 902         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 903         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 904         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 905
 906         if (forcefog) strunzone(forcefog);
 907         forcefog = strzone(ReadString());
 908
 909         armorblockpercent = ReadByte() / 255.0;
 910
 911         g_balance_mortar_bouncefactor = ReadCoord();
 912         g_balance_mortar_bouncestop = ReadCoord();
 913         g_balance_electro_secondary_bouncefactor = ReadCoord();
 914         g_balance_electro_secondary_bouncestop = ReadCoord();
 915
 916         vortex_scope = !ReadByte();
 917         rifle_scope = !ReadByte();
 918
 919         serverflags = ReadByte();
 920
 921         minelayer_maxmines = ReadByte();
 922
 923         hagar_maxrockets = ReadByte();
 924
 925         g_trueaim_minrange = ReadCoord();
 926         g_balance_porto_secondary = ReadByte();
 927         return = true;
 928
 929         MUTATOR_CALLHOOK(Ent_Init);
 930
 931         if (!postinit) PostInit();
 932 }
 933
 934 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 935 {
 936         int b = ReadByte();
 937
 938         switch (b)
 939         {
 940                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 941                         race_checkpoint = ReadByte();
 942                         race_time = ReadInt24_t();
 943                         race_previousbesttime = ReadInt24_t();
 944                         if(race_previousbestname)
 945                                 strunzone(race_previousbestname);
 946                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 947
 948                         race_checkpointtime = time;
 949
 950                         if(race_checkpoint == 0 || race_checkpoint == 254)
 951                         {
 952                                 race_penaltyaccumulator = 0;
 953                                 race_laptime = time; // valid
 954                         }
 955
 956                         break;
 957
 958                 case RACE_NET_CHECKPOINT_CLEAR:
 959                         race_laptime = 0;
 960                         race_checkpointtime = 0;
 961                         break;
 962
 963                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 964                         race_laptime = ReadCoord();
 965                         race_checkpointtime = -99999;
 966                         // fall through
 967                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 968                         race_nextcheckpoint = ReadByte();
 969
 970                         race_nextbesttime = ReadInt24_t();
 971                         if(race_nextbestname)
 972                                 strunzone(race_nextbestname);
 973                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 974                         break;
 975
 976                 case RACE_NET_CHECKPOINT_HIT_RACE:
 977                         race_mycheckpoint = ReadByte();
 978                         race_mycheckpointtime = time;
 979                         race_mycheckpointdelta = ReadInt24_t();
 980                         race_mycheckpointlapsdelta = ReadByte();
 981                         if(race_mycheckpointlapsdelta >= 128)
 982                                 race_mycheckpointlapsdelta -= 256;
 983                         if(race_mycheckpointenemy)
 984                                 strunzone(race_mycheckpointenemy);
 985                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 986                         break;
 987
 988                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 989                         race_othercheckpoint = ReadByte();
 990                         race_othercheckpointtime = time;
 991                         race_othercheckpointdelta = ReadInt24_t();
 992                         race_othercheckpointlapsdelta = ReadByte();
 993                         if(race_othercheckpointlapsdelta >= 128)
 994                                 race_othercheckpointlapsdelta -= 256;
 995                         if(race_othercheckpointenemy)
 996                                 strunzone(race_othercheckpointenemy);
 997                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 998                         break;
 999
1000                 case RACE_NET_PENALTY_RACE:
1001                         race_penaltyeventtime = time;
1002                         race_penaltytime = ReadShort();
1003                         //race_penaltyaccumulator += race_penaltytime;
1004                         if(race_penaltyreason)
1005                                 strunzone(race_penaltyreason);
1006                         race_penaltyreason = strzone(ReadString());
1007                         break;
1008
1009                 case RACE_NET_PENALTY_QUALIFYING:
1010                         race_penaltyeventtime = time;
1011                         race_penaltytime = ReadShort();
1012                         race_penaltyaccumulator += race_penaltytime;
1013                         if(race_penaltyreason)
1014                                 strunzone(race_penaltyreason);
1015                         race_penaltyreason = strzone(ReadString());
1016                         break;
1017
1018                 case RACE_NET_SERVER_RECORD:
1019                         race_server_record = ReadInt24_t();
1020                         break;
1021                 case RACE_NET_SPEED_AWARD:
1022                         race_speedaward = ReadInt24_t();
1023                         if(race_speedaward_holder)
1024                                 strunzone(race_speedaward_holder);
1025                         race_speedaward_holder = strzone(ReadString());
1026                         break;
1027                 case RACE_NET_SPEED_AWARD_BEST:
1028                         race_speedaward_alltimebest = ReadInt24_t();
1029                         if(race_speedaward_alltimebest_holder)
1030                                 strunzone(race_speedaward_alltimebest_holder);
1031                         race_speedaward_alltimebest_holder = strzone(ReadString());
1032                         break;
1033                 case RACE_NET_SERVER_RANKINGS:
1034                         float prevpos, del;
1035             int pos = ReadShort();
1036                         prevpos = ReadShort();
1037                         del = ReadShort();
1038
1039                         // move other rankings out of the way
1040             int i;
1041                         if (prevpos) {
1042                                 for (i=prevpos-1;i>pos-1;--i) {
1043                                         grecordtime[i] = grecordtime[i-1];
1044                                         if(grecordholder[i])
1045                                                 strunzone(grecordholder[i]);
1046                                         grecordholder[i] = strzone(grecordholder[i-1]);
1047                                 }
1048                         } else if (del) { // a record has been deleted by the admin
1049                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1050                                         if (i == RANKINGS_CNT-1) { // clear out last record
1051                                                 grecordtime[i] = 0;
1052                                                 if (grecordholder[i])
1053                                                         strunzone(grecordholder[i]);
1054                                                 grecordholder[i] = string_null;
1055                                         }
1056                                         else {
1057                                                 grecordtime[i] = grecordtime[i+1];
1058                                                 if (grecordholder[i])
1059                                                         strunzone(grecordholder[i]);
1060                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1061                                         }
1062                                 }
1063                         } else { // player has no ranked record yet
1064                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1065                                         grecordtime[i] = grecordtime[i-1];
1066                                         if(grecordholder[i])
1067                                                 strunzone(grecordholder[i]);
1068                                         grecordholder[i] = strzone(grecordholder[i-1]);
1069                                 }
1070                         }
1071
1072                         // store new ranking
1073                         if(grecordholder[pos-1] != "")
1074                                 strunzone(grecordholder[pos-1]);
1075                         grecordholder[pos-1] = strzone(ReadString());
1076                         grecordtime[pos-1] = ReadInt24_t();
1077                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1078                                 race_myrank = pos;
1079                         break;
1080                 case RACE_NET_SERVER_STATUS:
1081                         race_status = ReadShort();
1082                         if(race_status_name)
1083                                 strunzone(race_status_name);
1084                         race_status_name = strzone(ReadString());
1085         }
1086         return true;
1087 }
1088
1089 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1090 {
1091         teamnagger = 1;
1092         return true;
1093 }
1094
1095 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1096 {
1097         int i = ReadByte();
1098         int pi = ReadShort();
1099         int pl = ReadByte();
1100         int ml = ReadByte();
1101         return = true;
1102         entity e = playerslots[i];
1103         if (!e) return;
1104         e.ping = pi;
1105         e.ping_packetloss = pl / 255.0;
1106         e.ping_movementloss = ml / 255.0;
1107 }
1108
1109 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1110 {
1111         complain_weapon = ReadByte();
1112         if (complain_weapon_name) strunzone(complain_weapon_name);
1113         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1114         complain_weapon_type = ReadByte();
1115         return = true;
1116
1117         complain_weapon_time = time;
1118         weapontime = time; // ping the weapon panel
1119
1120         switch(complain_weapon_type)
1121         {
1122                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1123                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1124                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1125         }
1126 }
1127
1128 string getcommandkey(string text, string command)
1129 {
1130         string keys;
1131         float n, j, k, l = 0;
1132
1133         if (!autocvar_hud_showbinds)
1134                 return text;
1135
1136         keys = db_get(binddb, command);
1137         if (keys == "")
1138         {
1139                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1140                 for(j = 0; j < n; ++j)
1141                 {
1142                         k = stof(argv(j));
1143                         if(k != -1)
1144                         {
1145                                 if ("" == keys)
1146                                         keys = keynumtostring(k);
1147                                 else
1148                                         keys = strcat(keys, ", ", keynumtostring(k));
1149
1150                                 ++l;
1151                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1152                                         break;
1153                         }
1154
1155                 }
1156                 if (keys == "")
1157                         keys = "NO_KEY";
1158                 db_put(binddb, command, keys);
1159         }
1160
1161         if (keys == "NO_KEY") {
1162                 if (autocvar_hud_showbinds > 1)
1163                         return sprintf(_("%s (not bound)"), text);
1164                 else
1165                         return text;
1166         }
1167         else if (autocvar_hud_showbinds > 1)
1168                 return sprintf("%s (%s)", text, keys);
1169         else
1170                 return keys;
1171 }