qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include <client/mutators/_mod.qh>
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "weapons/projectile.qh"
  18 #include <common/deathtypes/all.qh>
  19 #include <common/items/_mod.qh>
  20 #include <common/mapinfo.qh>
  21 #include <common/minigames/cl_minigames.qh>
  22 #include <common/minigames/cl_minigames_hud.qh>
  23 #include <common/net_linked.qh>
  24 #include <common/net_notice.qh>
  25 #include <common/scores.qh>
  26 #include <common/mapobjects/_mod.qh>
  27 #include <common/vehicles/all.qh>
  28 #include <lib/csqcmodel/cl_model.qh>
  29 #include <lib/csqcmodel/interpolate.qh>
  30 #include <lib/warpzone/client.qh>
  31
  32 // --------------------------------------------------------------------------
  33 // BEGIN REQUIRED CSQC FUNCTIONS
  34 //include "main.qh"
  35
  36 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  37
  38 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  39 {
  40         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  41         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  42 }
  43
  44 void draw_cursor_normal(vector pos, vector col, float a)
  45 {
  46         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  47 }
  48
  49 void LoadMenuSkinValues()
  50 {
  51         int fh = -1;
  52         if(cvar_string("menu_skin") != "")
  53         {
  54                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  55                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  56         }
  57         if(fh < 0 && cvar_defstring("menu_skin") != "")
  58         {
  59                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  60                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  61                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  62         }
  63         if(fh < 0)
  64         {
  65                 draw_currentSkin = "gfx/menu/default";
  66                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  67         }
  68
  69         draw_currentSkin = strzone(draw_currentSkin);
  70
  71         if(fh >= 0)
  72         {
  73                 string s;
  74                 while((s = fgets(fh)))
  75                 {
  76                         int n = tokenize_console(s);
  77                         if (n < 2)
  78                                 continue;
  79                         if(substring(argv(0), 0, 2) == "//")
  80                                 continue;
  81                         if(argv(0) == "SIZE_CURSOR")
  82                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  83                         else if(argv(0) == "OFFSET_CURSOR")
  84                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  85                 }
  86                 fclose(fh);
  87         }
  88 }
  89
  90 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  91 // Useful for precaching things
  92
  93 void ConsoleCommand_macro_init();
  94 void CSQC_Init()
  95 {
  96         prvm_language = strzone(cvar_string("prvm_language"));
  97
  98 #ifdef WATERMARK
  99         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 100 #endif
 101
 102         {
 103                 int i = 0;
 104                 for ( ; i < 255; ++i)
 105                         if (getplayerkeyvalue(i, "viewentity") == "")
 106                                 break;
 107                 maxclients = i;
 108         }
 109
 110         // needs to be done so early because of the constants they create
 111         static_init();
 112         static_init_late();
 113         static_init_precache();
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118
 119         draw_endBoldFont();
 120
 121         //registercommand("hud_configure");
 122         //registercommand("hud_save");
 123         //registercommand("menu_action");
 124
 125         ConsoleCommand_macro_init();
 126
 127         registercvar("hud_usecsqc", "1");
 128         registercvar("scoreboard_columns", "default");
 129
 130         registercvar("cl_nade_type", "3");
 131         registercvar("cl_pokenade_type", "zombie");
 132
 133         registercvar("cl_jumpspeedcap_min", "");
 134         registercvar("cl_jumpspeedcap_max", "");
 135
 136         registercvar("cl_shootfromfixedorigin", "");
 137
 138         registercvar("cl_multijump", "1");
 139
 140         registercvar("cl_spawn_near_teammate", "1");
 141
 142         if(autocvar_cl_lockview)
 143                 cvar_set("cl_lockview", "0");
 144
 145         gametype = NULL;
 146
 147         postinit = false;
 148
 149         calledhooks = 0;
 150
 151         teams = Sort_Spawn();
 152         players = Sort_Spawn();
 153
 154         GetTeam(NUM_SPECTATOR, true); // add specs first
 155
 156         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 157                 weapon_accuracy[w] = -1;
 158
 159         // precaches
 160
 161         if(autocvar_cl_reticle)
 162         {
 163                 precache_pic("gfx/reticle_normal");
 164                 // weapon reticles are precached in weapon files
 165         }
 166
 167         {
 168                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 169                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 170                 shortmapname = mi_shortname;
 171
 172                 if (precache_pic(minimapname) == "")
 173                 {
 174                         // but maybe we have a non-clever minimap
 175                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 176                         if (precache_pic(minimapname) == "")
 177                                 minimapname = ""; // FAIL
 178                         else
 179                                 get_mi_min_max_texcoords(0); // load new texcoords
 180                 }
 181
 182                 mi_center = (mi_min + mi_max) * 0.5;
 183                 mi_scale = mi_max - mi_min;
 184                 minimapname = strzone(minimapname);
 185         }
 186
 187         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 188         LoadMenuSkinValues();
 189 }
 190
 191 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 192 void Shutdown()
 193 {
 194         WarpZone_Shutdown();
 195
 196         delete(teams);
 197         delete(players);
 198         db_close(binddb);
 199         db_close(tempdb);
 200         if(autocvar_cl_db_saveasdump)
 201                 db_dump(ClientProgsDB, "client.db");
 202         else
 203                 db_save(ClientProgsDB, "client.db");
 204         db_close(ClientProgsDB);
 205
 206         if(camera_active)
 207                 cvar_set("chase_active",ftos(chase_active_backup));
 208
 209         // unset the event chasecam's chase_active
 210         if(autocvar_chase_active < 0)
 211                 cvar_set("chase_active", "0");
 212
 213         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 214
 215         if (!isdemo())
 216         {
 217                 if (!(calledhooks & HOOK_START))
 218                         localcmd("\n_cl_hook_gamestart nop\n");
 219                 if (!(calledhooks & HOOK_END))
 220                         localcmd("\ncl_hook_gameend\n");
 221         }
 222
 223         localcmd("\ncl_hook_shutdown\n");
 224
 225         deactivate_minigame();
 226         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 227 }
 228
 229 .float has_team;
 230 float SetTeam(entity o, int Team)
 231 {
 232     TC(int, Team);
 233         devassert_once(Team);
 234         entity tm;
 235         if(teamplay)
 236         {
 237                 switch(Team)
 238                 {
 239                         case -1:
 240                         case NUM_TEAM_1:
 241                         case NUM_TEAM_2:
 242                         case NUM_TEAM_3:
 243                         case NUM_TEAM_4:
 244                                 break;
 245                         default:
 246                                 if(GetTeam(Team, false) == NULL)
 247                                 {
 248                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 249                                         Team = NUM_SPECTATOR;
 250                                 }
 251                                 break;
 252                 }
 253         }
 254         else
 255         {
 256                 switch(Team)
 257                 {
 258                         case -1:
 259                         case 0:
 260                                 break;
 261                         default:
 262                                 if(GetTeam(Team, false) == NULL)
 263                                 {
 264                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 265                                         Team = NUM_SPECTATOR;
 266                                 }
 267                                 break;
 268                 }
 269         }
 270         if(Team == -1) // leave
 271         {
 272                 if(o.has_team)
 273                 {
 274                         tm = GetTeam(o.team, false);
 275                         tm.team_size -= 1;
 276                         o.has_team = 0;
 277                         return true;
 278                 }
 279         }
 280         else
 281         {
 282                 if (!o.has_team)
 283                 {
 284                         o.team = Team;
 285                         tm = GetTeam(Team, true);
 286                         tm.team_size += 1;
 287                         o.has_team = 1;
 288                         return true;
 289                 }
 290                 else if(Team != o.team)
 291                 {
 292                         tm = GetTeam(o.team, false);
 293                         tm.team_size -= 1;
 294                         o.team = Team;
 295                         tm = GetTeam(Team, true);
 296                         tm.team_size += 1;
 297                         return true;
 298                 }
 299         }
 300         return false;
 301 }
 302
 303 void Playerchecker_Think(entity this)
 304 {
 305     int i;
 306         entity e;
 307         for(i = 0; i < maxclients; ++i)
 308         {
 309                 e = playerslots[i];
 310                 if(entcs_GetName(i) == "")
 311                 {
 312                         if(e.sort_prev)
 313                         {
 314                                 // player disconnected
 315                                 SetTeam(e, -1);
 316                                 RemovePlayer(e);
 317                                 e.sort_prev = NULL;
 318                                 //e.gotscores = 0;
 319                         }
 320                 }
 321                 else
 322                 {
 323                         if (!e.sort_prev)
 324                         {
 325                                 // player connected
 326                                 if (!e)
 327                                 {
 328                                         playerslots[i] = e = new_pure(playerslot);
 329                                 }
 330                                 e.sv_entnum = i;
 331                                 e.ping = 0;
 332                                 e.ping_packetloss = 0;
 333                                 e.ping_movementloss = 0;
 334                                 //e.gotscores = 0; // we might already have the scores...
 335                                 int t = entcs_GetScoreTeam(i);
 336                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 337                                 RegisterPlayer(e);
 338                                 Scoreboard_UpdatePlayerPos(e);
 339                         }
 340                 }
 341         }
 342         this.nextthink = time + 0.2;
 343 }
 344
 345 void TrueAim_Init();
 346 void PostInit()
 347 {
 348         entity playerchecker = new_pure(playerchecker);
 349         setthink(playerchecker, Playerchecker_Think);
 350         playerchecker.nextthink = time + 0.2;
 351
 352         TrueAim_Init();
 353
 354         postinit = true;
 355 }
 356
 357 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 358 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 359 // All keys are in ascii.
 360 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 361 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 362 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 363 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 364 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 365 {
 366     TC(int, bInputType);
 367         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 368                 return true;
 369
 370         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 371                 return true;
 372
 373         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 374                 return true;
 375
 376         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 377                 return true;
 378
 379         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 380                 return true;
 381
 382         return false;
 383 }
 384
 385 // END REQUIRED CSQC FUNCTIONS
 386 // --------------------------------------------------------------------------
 387
 388 // --------------------------------------------------------------------------
 389 // BEGIN OPTIONAL CSQC FUNCTIONS
 390
 391 void Ent_Remove(entity this);
 392
 393 void Ent_RemovePlayerScore(entity this)
 394 {
 395         if(this.owner) {
 396                 SetTeam(this.owner, -1);
 397                 this.owner.gotscores = 0;
 398                 FOREACH(Scores, true, {
 399                         this.owner.(scores(it)) = 0; // clear all scores
 400                 });
 401         }
 402 }
 403
 404 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 405 {
 406         make_pure(this);
 407         entity o;
 408
 409         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 410         // (no I've never heard of M-x replace-string, sed, or anything like that)
 411         bool isNew = !this.owner; // workaround for DP bug
 412         int n = ReadByte()-1;
 413
 414 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 415         if(!isNew && n != this.sv_entnum)
 416         {
 417                 //print("A CSQC entity changed its owner!\n");
 418                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 419                 isNew = true;
 420                 Ent_Remove(this);
 421         }
 422 #endif
 423
 424         this.sv_entnum = n;
 425
 426         o = playerslots[this.sv_entnum];
 427         if (!o)
 428         {
 429                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 430         }
 431         this.owner = o;
 432         o.sv_entnum = this.sv_entnum;
 433         o.gotscores = 1;
 434
 435         //if (!o.sort_prev)
 436         //      RegisterPlayer(o);
 437         //playerchecker will do this for us later, if it has not already done so
 438
 439         int sf = ReadShort();
 440         int lf = ReadShort();
 441         FOREACH(Scores, true, {
 442                 int p = 1 << (i % 16);
 443                 if (sf & p)
 444                 {
 445                         if (lf & p)
 446                                 o.(scores(it)) = ReadInt24_t();
 447                         else
 448                                 o.(scores(it)) = ReadChar();
 449                 }
 450         });
 451
 452         return = true;
 453
 454         if(o.sort_prev)
 455                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 456
 457         this.entremove = Ent_RemovePlayerScore;
 458 }
 459
 460 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 461 {
 462         make_pure(this);
 463         int i;
 464
 465         this.team = ReadByte();
 466         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 467
 468 #if MAX_TEAMSCORE <= 8
 469         int sf = ReadByte();
 470         int lf = ReadByte();
 471 #else
 472         int sf = ReadShort();
 473         int lf = ReadShort();
 474 #endif
 475         for(i = 0; i < MAX_TEAMSCORE; ++i)
 476                 if(sf & BIT(i))
 477                 {
 478                         if(lf & BIT(i))
 479                                 o.(teamscores(i)) = ReadInt24_t();
 480                         else
 481                                 o.(teamscores(i)) = ReadChar();
 482                 }
 483
 484         return = true;
 485
 486         Scoreboard_UpdateTeamPos(o);
 487 }
 488
 489 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 490 {
 491         make_pure(this);
 492         float newspectatee_status;
 493
 494         int f = ReadByte();
 495
 496         scoreboard_showscores_force = (f & BIT(0));
 497
 498         if(f & BIT(1))
 499         {
 500                 newspectatee_status = ReadByte();
 501                 if(newspectatee_status == player_localnum + 1)
 502                         newspectatee_status = -1; // observing
 503         }
 504         else
 505                 newspectatee_status = 0;
 506
 507         spectatorbutton_zoom = (f & BIT(2));
 508
 509         if(f & BIT(4))
 510         {
 511                 num_spectators = ReadByte();
 512
 513                 float i, slot;
 514
 515                 for(i = 0; i < MAX_SPECTATORS; ++i)
 516                         spectatorlist[i] = 0; // reset list first
 517
 518                 for(i = 0; i < num_spectators; ++i)
 519                 {
 520                         slot = ReadByte();
 521                         spectatorlist[i] = slot - 1;
 522                 }
 523         }
 524
 525         return = true;
 526
 527         if(newspectatee_status != spectatee_status)
 528         {
 529                 // clear race stuff
 530                 race_laptime = 0;
 531                 race_checkpointtime = 0;
 532                 hud_dynamic_shake_factor = -1;
 533         }
 534         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 535         {
 536                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 537                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 538                 )
 539                         prev_p_health = -1;
 540                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 541                         prev_health = -1;
 542         }
 543         spectatee_status = newspectatee_status;
 544
 545         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 546 }
 547
 548 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 549 {
 550         make_pure(this);
 551         int i, j, b, f;
 552
 553         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 554
 555         if(!(nags & BIT(2)))
 556         {
 557                 strfree(vote_called_vote);
 558                 vote_active = 0;
 559         }
 560         else
 561         {
 562                 vote_active = 1;
 563         }
 564
 565         if(nags & BIT(6))
 566         {
 567                 vote_yescount = ReadByte();
 568                 vote_nocount = ReadByte();
 569                 vote_needed = ReadByte();
 570                 vote_highlighted = ReadChar();
 571         }
 572
 573         if(nags & BIT(7))
 574         {
 575                 strcpy(vote_called_vote, ReadString());
 576         }
 577
 578         if(nags & 1)
 579         {
 580                 for(j = 0; j < maxclients; ++j)
 581                         if(playerslots[j])
 582                                 playerslots[j].ready = 1;
 583                 for(i = 1; i <= maxclients; i += 8)
 584                 {
 585                         f = ReadByte();
 586                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 587                                 if (!(f & b))
 588                                         if(playerslots[j])
 589                                                 playerslots[j].ready = 0;
 590                 }
 591         }
 592
 593         return = true;
 594
 595         ready_waiting = (nags & BIT(0));
 596         ready_waiting_for_me = (nags & BIT(1));
 597         vote_waiting = (nags & BIT(2));
 598         vote_waiting_for_me = (nags & BIT(3));
 599         warmup_stage = (nags & BIT(4));
 600 }
 601
 602 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 603 {
 604         make_pure(this);
 605         int sf = 0;
 606         serialize(byte, 0, sf);
 607         if (sf & 1) {
 608                 for (int j = 0; j < maxclients; ++j) {
 609                         if (playerslots[j]) {
 610                                 playerslots[j].eliminated = 1;
 611                         }
 612                 }
 613                 for (int i = 1; i <= maxclients; i += 8) {
 614                         int f = 0;
 615                         serialize(byte, 0, f);
 616                         for (int b = 0; b < 8; ++b) {
 617                                 if (f & BIT(b)) continue;
 618                                 int j = i - 1 + b;
 619                                 if (playerslots[j]) {
 620                                         playerslots[j].eliminated = 0;
 621                                 }
 622                         }
 623                 }
 624         }
 625         return true;
 626 }
 627
 628 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 629 {
 630         make_pure(this);
 631         prandom_debug();
 632         float s = ReadShort();
 633         psrandom(s);
 634         return true;
 635 }
 636
 637 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 638 {
 639         make_pure(this);
 640         int sf = ReadInt24_t();
 641         if (sf == 0) {
 642                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 643                         weapon_accuracy[w] = -1;
 644                 return true;
 645         }
 646
 647         int f = 1;
 648         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 649                 if (sf & f) {
 650                         int b = ReadByte();
 651                         if (b == 0)
 652                                 weapon_accuracy[w] = -1;
 653                         else if (b == 255)
 654                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 655                         else
 656                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 657                 }
 658                 f = (f == 0x800000) ? 1 : f * 2;
 659         }
 660         return true;
 661 }
 662
 663 void Spawn_Draw(entity this)
 664 {
 665         if(this.alpha <= 0)
 666                 return;
 667
 668         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 669 }
 670
 671 void Spawn_PreDraw(entity this)
 672 {
 673         float alph;
 674         vector org = getpropertyvec(VF_ORIGIN);
 675         if(this.fade_start)
 676         {
 677                 if(vdist(org - this.origin, >, this.fade_end))
 678                         alph = 0; // save on some processing
 679                 else if(vdist(org - this.origin, <, this.fade_start))
 680                         alph = 1; // more processing saved
 681                 else
 682                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 683         }
 684         else
 685                 alph = 1;
 686         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 687         this.alpha = alph;
 688         if(alph <= 0)
 689                 this.drawmask = 0;
 690         else
 691                 this.drawmask = MASK_NORMAL;
 692 }
 693
 694 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 695 {
 696         float teamnum = (ReadByte() - 1);
 697         vector spn_origin = ReadVector();
 698
 699         this.team = (teamnum + 1);
 700
 701         //if(is_new)
 702         //{
 703                 this.origin = spn_origin;
 704                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 705                 //droptofloor();
 706
 707                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 708                 {
 709                         this.mdl = "models/spawnpoint.md3";
 710                         this.colormod = Team_ColorRGB(teamnum);
 711                         precache_model(this.mdl);
 712                         setmodel(this, this.mdl);
 713                         this.drawmask = MASK_NORMAL;
 714                         //this.move_movetype = MOVETYPE_NOCLIP;
 715                         //this.draw = Spawn_Draw;
 716                         IL_PUSH(g_drawables, this);
 717                 }*/
 718                 if(autocvar_cl_spawn_point_particles)
 719                 {
 720                         if(teamplay)
 721                         {
 722                                 switch(teamnum)
 723                                 {
 724                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 725                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 726                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 727                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 728                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 729                                 }
 730                         }
 731                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 732
 733                         this.draw = Spawn_Draw;
 734                         if (is_new) IL_PUSH(g_drawables, this);
 735                         setpredraw(this, Spawn_PreDraw);
 736                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 737                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 738                 }
 739         //}
 740
 741         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 742         return true;
 743 }
 744
 745 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 746 {
 747         // If entnum is 0, ONLY do the local spawn actions
 748         // this way the server can disable the sending of
 749         // spawn origin or such to clients if wanted.
 750         float entnum = ReadByte();
 751
 752         if(entnum)
 753         {
 754                 this.origin = ReadVector();
 755
 756                 if(is_new)
 757                 {
 758                         float teamnum = entcs_GetTeam(entnum - 1);
 759
 760                         if(autocvar_cl_spawn_event_particles)
 761                         {
 762                                 switch(teamnum)
 763                                 {
 764                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 765                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 766                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 767                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 768                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 769                                 }
 770                         }
 771                         if(autocvar_cl_spawn_event_sound)
 772                         {
 773                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 774                         }
 775                 }
 776         }
 777         return = true;
 778
 779         // local spawn actions
 780         if(is_new && (!entnum || (entnum == player_localentnum)))
 781         {
 782                 zoomin_effect = 1;
 783                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 784
 785                 if(autocvar_cl_unpress_zoom_on_spawn)
 786                 {
 787                         localcmd("-zoom\n");
 788                         button_zoom = false;
 789                 }
 790                 HUD_Radar_Hide_Maximized();
 791         }
 792         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 793 }
 794
 795 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 796 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 797 void CSQC_Ent_Update(entity this, bool isnew)
 798 {
 799         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 800         int t = ReadByte();
 801
 802         // set up the "time" global for received entities to be correct for interpolation purposes
 803         float savetime = time;
 804         if(servertime)
 805         {
 806                 time = servertime;
 807         }
 808         else
 809         {
 810                 serverprevtime = time;
 811                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 812                 time = serverprevtime + serverdeltatime;
 813         }
 814
 815 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 816         if (this.enttype)
 817         {
 818                 if (t != this.enttype || isnew)
 819                 {
 820                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 821                         Ent_Remove(this);
 822                         clearentity(this);
 823                         isnew = true;
 824                 }
 825         }
 826         else
 827         {
 828                 if (!isnew)
 829                 {
 830                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 831                         isnew = true;
 832                 }
 833         }
 834 #endif
 835         this.enttype = t;
 836         bool done = false;
 837         FOREACH(LinkedEntities, it.m_id == t, {
 838                 if (isnew) this.classname = it.netname;
 839                 if (autocvar_developer_csqcentities)
 840             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 841                 done = it.m_read(this, NULL, isnew);
 842                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 843                 break;
 844         });
 845         time = savetime;
 846         if (!done)
 847         {
 848                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 849         }
 850 }
 851
 852 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 853 // used when an entity changes its type. For an entity that someone interacts
 854 // with others, make sure it can no longer do so.
 855 void Ent_Remove(entity this)
 856 {
 857         if(this.entremove) this.entremove(this);
 858
 859         if(this.skeletonindex)
 860         {
 861                 skel_delete(this.skeletonindex);
 862                 this.skeletonindex = 0;
 863         }
 864
 865         if(this.snd_looping > 0)
 866         {
 867                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 868                 this.snd_looping = 0;
 869         }
 870
 871         this.enttype = 0;
 872         this.classname = "";
 873         this.draw = func_null;
 874         this.entremove = func_null;
 875         // TODO possibly set more stuff to defaults
 876 }
 877 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 878 void CSQC_Ent_Remove(entity this)
 879 {
 880         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 881         if (wasfreed(this))
 882         {
 883                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 884                 return;
 885         }
 886         if (this.enttype) Ent_Remove(this);
 887         delete(this);
 888 }
 889
 890 void Gamemode_Init()
 891 {
 892         if (!isdemo())
 893         {
 894                 if(!(calledhooks & HOOK_START))
 895                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 896                 calledhooks |= HOOK_START;
 897         }
 898 }
 899 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 900 void CSQC_Parse_StuffCmd(string strMessage)
 901 {
 902         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 903         localcmd(strMessage);
 904 }
 905 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 906 void CSQC_Parse_Print(string strMessage)
 907 {
 908         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 909         print(ColorTranslateRGB(strMessage));
 910 }
 911
 912 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 913 void CSQC_Parse_CenterPrint(string strMessage)
 914 {
 915         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 916         centerprint_hud(strMessage);
 917 }
 918
 919 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 920 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 921 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 922 bool CSQC_Parse_TempEntity()
 923 {
 924         // Acquire TE ID
 925         int nTEID = ReadByte();
 926
 927         FOREACH(TempEntities, it.m_id == nTEID, {
 928                 if (autocvar_developer_csqcentities)
 929                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 930                 return it.m_read(NULL, NULL, true);
 931         });
 932
 933         if (autocvar_developer_csqcentities)
 934                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 935
 936         // No special logic for this temporary entity; return 0 so the engine can handle it
 937         return false;
 938 }
 939
 940 string forcefog;
 941 void Fog_Force()
 942 {
 943         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 944                 localcmd("\nr_drawfog 0\n");
 945         else if (forcefog != "")
 946                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 947 }
 948
 949 void Gamemode_Init();
 950 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 951 {
 952         make_pure(this);
 953         gametype = ReadRegistered(Gametypes);
 954         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 955         HUD_ModIcons_SetFunc();
 956         FOREACH(Scores, true, {
 957                 strcpy(scores_label(it), ReadString());
 958                 scores_flags(it) = ReadByte();
 959         });
 960         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 961         {
 962                 strcpy(teamscores_label(i), ReadString());
 963                 teamscores_flags(i) = ReadByte();
 964         }
 965         return = true;
 966         Scoreboard_InitScores();
 967         Gamemode_Init();
 968 }
 969
 970 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 971 {
 972         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 973
 974         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 975         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 976         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 977         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 978         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 979         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 980         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 981         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 982
 983         strcpy(forcefog, ReadString());
 984
 985         armorblockpercent = ReadByte() / 255.0;
 986         damagepush_speedfactor = ReadByte() / 255.0;
 987
 988         serverflags = ReadByte();
 989
 990         g_trueaim_minrange = ReadCoord();
 991
 992         return = true;
 993
 994         MUTATOR_CALLHOOK(Ent_Init);
 995
 996         if (!postinit) PostInit();
 997 }
 998
 999 float GetSpeedUnitFactor(int speed_unit)
1000 {
1001         switch(speed_unit)
1002         {
1003                 default:
1004                 case 1:
1005                         return 1.0;
1006                 case 2:
1007                         return 0.0254;
1008                 case 3:
1009                         return 0.0254 * 3.6;
1010                 case 4:
1011                         return 0.0254 * 3.6 * 0.6213711922;
1012                 case 5:
1013                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1014         }
1015 }
1016
1017 string GetSpeedUnit(int speed_unit)
1018 {
1019         switch(speed_unit)
1020         {
1021                 default:
1022                 case 1:
1023                         return _(" qu/s");
1024                 case 2:
1025                         return _(" m/s");
1026                 case 3:
1027                         return _(" km/h");
1028                 case 4:
1029                         return _(" mph");
1030                 case 5:
1031                         return _(" knots");
1032         }
1033 }
1034
1035 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1036 {
1037         int b = ReadByte();
1038
1039         switch (b)
1040         {
1041                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1042                         race_checkpoint = ReadByte();
1043                         race_time = ReadInt24_t();
1044                         race_previousbesttime = ReadInt24_t();
1045                         race_mypreviousbesttime = ReadInt24_t();
1046                         string pbestname = ReadString();
1047                         if(autocvar_cl_race_cptimes_onlyself)
1048                         {
1049                                 race_previousbesttime = race_mypreviousbesttime;
1050                                 race_mypreviousbesttime = 0;
1051                                 strcpy(race_previousbestname, "");
1052                         }
1053                         else
1054                                 strcpy(race_previousbestname, pbestname);
1055
1056                         race_checkpointtime = time;
1057
1058                         if(race_checkpoint == 0 || race_checkpoint == 254)
1059                         {
1060                                 race_penaltyaccumulator = 0;
1061                                 race_laptime = time; // valid
1062                         }
1063                         break;
1064
1065                 case RACE_NET_CHECKPOINT_CLEAR:
1066                         race_laptime = 0;
1067                         race_checkpointtime = 0;
1068                         break;
1069
1070                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1071                         race_laptime = ReadCoord();
1072                         race_checkpointtime = -99999;
1073                         // fall through
1074                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1075                         race_nextcheckpoint = ReadByte();
1076
1077                         race_nextbesttime = ReadInt24_t();
1078                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1079                                 race_mybesttime = ReadInt24_t();
1080                         string newname = ReadString();
1081                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1082                         {
1083                                 race_nextbesttime = race_mybesttime;
1084                                 race_mybesttime = 0;
1085                                 strcpy(race_nextbestname, "");
1086                         }
1087                         else
1088                                 strcpy(race_nextbestname, newname);
1089                         break;
1090
1091                 case RACE_NET_CHECKPOINT_HIT_RACE:
1092                         race_mycheckpoint = ReadByte();
1093                         race_mycheckpointtime = time;
1094                         race_mycheckpointdelta = ReadInt24_t();
1095                         race_mycheckpointlapsdelta = ReadByte();
1096                         if(race_mycheckpointlapsdelta >= 128)
1097                                 race_mycheckpointlapsdelta -= 256;
1098                         int who = ReadByte();
1099                         if(who)
1100                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1101                         else
1102                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1103                         break;
1104
1105                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1106                         race_othercheckpoint = ReadByte();
1107                         race_othercheckpointtime = time;
1108                         race_othercheckpointdelta = ReadInt24_t();
1109                         race_othercheckpointlapsdelta = ReadByte();
1110                         if(race_othercheckpointlapsdelta >= 128)
1111                                 race_othercheckpointlapsdelta -= 256;
1112                         int what = ReadByte();
1113                         if(what)
1114                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1115                         else
1116                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1117                         break;
1118
1119                 case RACE_NET_PENALTY_RACE:
1120                         race_penaltyeventtime = time;
1121                         race_penaltytime = ReadShort();
1122                         //race_penaltyaccumulator += race_penaltytime;
1123                         strcpy(race_penaltyreason, ReadString());
1124                         break;
1125
1126                 case RACE_NET_PENALTY_QUALIFYING:
1127                         race_penaltyeventtime = time;
1128                         race_penaltytime = ReadShort();
1129                         race_penaltyaccumulator += race_penaltytime;
1130                         strcpy(race_penaltyreason, ReadString());
1131                         break;
1132
1133                 case RACE_NET_SERVER_RECORD:
1134                         race_server_record = ReadInt24_t();
1135                         break;
1136                 case RACE_NET_SPEED_AWARD:
1137                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1138                         strcpy(race_speedaward_holder, ReadString());
1139                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1140                         break;
1141                 case RACE_NET_SPEED_AWARD_BEST:
1142                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1143                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1144                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1145                         break;
1146                 case RACE_NET_RANKINGS_CNT:
1147                         RANKINGS_DISPLAY_CNT = ReadByte();
1148                         break;
1149                 case RACE_NET_SERVER_RANKINGS:
1150                         float prevpos, del;
1151             int pos = ReadShort();
1152                         prevpos = ReadShort();
1153                         del = ReadShort();
1154
1155                         // move other rankings out of the way
1156             int i;
1157                         if (prevpos) {
1158                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1159                                 for (i=m-1; i>pos-1; --i) {
1160                                         grecordtime[i] = grecordtime[i-1];
1161                                         strcpy(grecordholder[i], grecordholder[i-1]);
1162                                 }
1163                         } else if (del) { // a record has been deleted by the admin
1164                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1165                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1166                                                 grecordtime[i] = 0;
1167                                                 strfree(grecordholder[i]);
1168                                         }
1169                                         else {
1170                                                 grecordtime[i] = grecordtime[i+1];
1171                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1172                                         }
1173                                 }
1174                         } else { // player has no ranked record yet
1175                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1176                                         grecordtime[i] = grecordtime[i-1];
1177                                         strcpy(grecordholder[i], grecordholder[i-1]);
1178                                 }
1179                         }
1180
1181                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1182                                 // kick off the player who fell from the last displayed position
1183                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1184                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1185                         }
1186
1187                         // store new ranking
1188                         strcpy(grecordholder[pos-1], ReadString());
1189                         grecordtime[pos-1] = ReadInt24_t();
1190                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1191                                 race_myrank = pos;
1192                         break;
1193                 case RACE_NET_SERVER_STATUS:
1194                         race_status = ReadShort();
1195                         strcpy(race_status_name, ReadString());
1196         }
1197         return true;
1198 }
1199
1200 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1201 {
1202         teamnagger = 1;
1203         return true;
1204 }
1205
1206 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1207 {
1208         int i = ReadByte();
1209         int pi = ReadShort();
1210         int pl = ReadByte();
1211         int ml = ReadByte();
1212         return = true;
1213         entity e = playerslots[i];
1214         if (!e) return;
1215         e.ping = pi;
1216         e.ping_packetloss = pl / 255.0;
1217         e.ping_movementloss = ml / 255.0;
1218 }
1219
1220 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1221 {
1222         complain_weapon = ReadByte();
1223         complain_weapon_type = ReadByte();
1224         return = true;
1225
1226         complain_weapon_time = time;
1227         weapontime = time; // ping the weapon panel
1228
1229         switch(complain_weapon_type)
1230         {
1231                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1232                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1233                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1234         }
1235 }
1236
1237 string _getcommandkey(string cmd_name, string command, bool forcename)
1238 {
1239         string keys;
1240         float n, j, k, l = 0;
1241
1242         if (!autocvar_hud_showbinds)
1243                 return cmd_name;
1244
1245         keys = db_get(binddb, command);
1246         if (keys == "")
1247         {
1248                 bool joy_active = cvar("joy_active");
1249                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1250                 for(j = 0; j < n; ++j)
1251                 {
1252                         k = stof(argv(j));
1253                         if(k != -1)
1254                         {
1255                                 string key = keynumtostring(k);
1256                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1257                                         continue;
1258
1259                                 if (keys == "")
1260                                         keys = key;
1261                                 else
1262                                         keys = strcat(keys, ", ", key);
1263
1264                                 ++l;
1265                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1266                                         break;
1267                         }
1268
1269                 }
1270                 if (keys == "")
1271                         keys = "NO_KEY";
1272                 db_put(binddb, command, keys);
1273         }
1274
1275         if (keys == "NO_KEY") {
1276                 if (autocvar_hud_showbinds > 1)
1277                         return sprintf(_("%s (not bound)"), cmd_name);
1278                 else
1279                         return cmd_name;
1280         }
1281         else if (autocvar_hud_showbinds > 1 || forcename)
1282                 return sprintf("%s (%s)", cmd_name, keys);
1283         else
1284                 return keys;
1285 }