qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         ReplicateVars_Send_All();
  61
  62         // needs to be done so early because of the constants they create
  63         static_init();
  64         static_init_late();
  65         static_init_precache();
  66
  67         binddb = db_create();
  68         tempdb = db_create();
  69         ClientProgsDB = db_load("client.db");
  70
  71         draw_endBoldFont();
  72
  73         //registercommand("hud_configure");
  74         //registercommand("hud_save");
  75         //registercommand("menu_action");
  76
  77         ConsoleCommand_macro_init();
  78
  79         registercvar("hud_usecsqc", "1");
  80         registercvar("scoreboard_columns", "default");
  81
  82         registercvar("cl_nade_type", "3");
  83         registercvar("cl_pokenade_type", "zombie");
  84
  85         registercvar("cl_jumpspeedcap_min", "");
  86         registercvar("cl_jumpspeedcap_max", "");
  87
  88         registercvar("cl_shootfromfixedorigin", "");
  89
  90         registercvar("cl_multijump", "-1");
  91
  92         registercvar("cl_dodging", "0");
  93
  94         registercvar("cl_spawn_near_teammate", "1");
  95
  96         registercvar("cl_weapon_switch_reload", "1");
  97         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  98
  99         registercvar("cl_allow_uidranking", "1");
 100
 101         if(autocvar_cl_lockview)
 102                 cvar_set("cl_lockview", "0");
 103
 104         gametype = NULL;
 105
 106         postinit = false;
 107
 108         calledhooks = 0;
 109
 110         teams = Sort_Spawn();
 111         players = Sort_Spawn();
 112
 113         GetTeam(NUM_SPECTATOR, true); // add specs first
 114
 115         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 116                 weapon_accuracy[w] = -1;
 117
 118         // precaches
 119
 120         if(autocvar_cl_reticle)
 121         {
 122                 precache_pic("gfx/reticle_normal");
 123                 // weapon reticles are precached in weapon files
 124         }
 125
 126         {
 127                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 128                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 129                 shortmapname = mi_shortname;
 130
 131                 if (precache_pic(minimapname) == "")
 132                 {
 133                         // but maybe we have a non-clever minimap
 134                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 135                         if (precache_pic(minimapname) == "")
 136                                 minimapname = ""; // FAIL
 137                         else
 138                                 get_mi_min_max_texcoords(0); // load new texcoords
 139                 }
 140
 141                 mi_center = (mi_min + mi_max) * 0.5;
 142                 mi_scale = mi_max - mi_min;
 143                 minimapname = strzone(minimapname);
 144         }
 145
 146         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 147         LoadMenuSkinValues();
 148 }
 149
 150 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 151 void Shutdown()
 152 {
 153         WarpZone_Shutdown();
 154
 155         delete(teams);
 156         delete(players);
 157         db_close(binddb);
 158         db_close(tempdb);
 159         if(autocvar_cl_db_saveasdump)
 160                 db_dump(ClientProgsDB, "client.db");
 161         else
 162                 db_save(ClientProgsDB, "client.db");
 163         db_close(ClientProgsDB);
 164
 165         if(camera_active)
 166                 cvar_set("chase_active",ftos(chase_active_backup));
 167
 168         // unset the event chasecam's chase_active
 169         if(autocvar_chase_active < 0)
 170                 cvar_set("chase_active", "0");
 171
 172         if (autocvar_r_drawviewmodel < 0)
 173                 cvar_set("r_drawviewmodel", "0");
 174
 175         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 176
 177         if (!isdemo())
 178         {
 179                 if (!(calledhooks & HOOK_START))
 180                         localcmd("\n_cl_hook_gamestart nop\n");
 181                 if (!(calledhooks & HOOK_END))
 182                         localcmd("\ncl_hook_gameend\n");
 183         }
 184
 185         localcmd("\ncl_hook_shutdown\n");
 186
 187         localcmd("\n-button12\n");
 188
 189         deactivate_minigame();
 190         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 191
 192         ReplicateVars_Destroy();
 193 }
 194
 195 void AuditLists()
 196 {
 197         entity e;
 198         entity prev;
 199
 200         prev = players;
 201         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 202         {
 203                 if(prev != e.sort_prev)
 204                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 205         }
 206
 207         prev = teams;
 208         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 209         {
 210                 if(prev != e.sort_prev)
 211                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 212         }
 213 }
 214
 215 float RegisterPlayer(entity player)
 216 {
 217         entity pl;
 218         AuditLists();
 219         for(pl = players.sort_next; pl; pl = pl.sort_next)
 220                 if(pl == player)
 221                         error("Player already registered!");
 222         player.sort_next = players.sort_next;
 223         player.sort_prev = players;
 224         if(players.sort_next)
 225                 players.sort_next.sort_prev = player;
 226         players.sort_next = player;
 227         AuditLists();
 228         return true;
 229 }
 230
 231 void RemovePlayer(entity player)
 232 {
 233         entity pl, parent;
 234         AuditLists();
 235         parent = players;
 236         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 237                 parent = pl;
 238
 239         if(!pl)
 240         {
 241                 error("Trying to remove a player which is not in the playerlist!");
 242                 return;
 243         }
 244         parent.sort_next = player.sort_next;
 245         if(player.sort_next)
 246                 player.sort_next.sort_prev = parent;
 247         AuditLists();
 248 }
 249
 250 void MoveToLast(entity e)
 251 {
 252         AuditLists();
 253         entity ent = e.sort_next;
 254         while(ent)
 255         {
 256                 SORT_SWAP(ent, e);
 257                 ent = e.sort_next;
 258         }
 259         AuditLists();
 260 }
 261
 262 float RegisterTeam(entity Team)
 263 {
 264         assert_once(Team.team, eprint(Team));
 265         entity tm;
 266         AuditLists();
 267         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 268                 if(tm == Team)
 269                         error("Team already registered!");
 270         Team.sort_next = teams.sort_next;
 271         Team.sort_prev = teams;
 272         if(teams.sort_next)
 273                 teams.sort_next.sort_prev = Team;
 274         teams.sort_next = Team;
 275         if(Team.team && Team.team != NUM_SPECTATOR)
 276                 ++team_count;
 277         AuditLists();
 278         return true;
 279 }
 280
 281 void RemoveTeam(entity Team)
 282 {
 283         entity tm, parent;
 284         AuditLists();
 285         parent = teams;
 286         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 287                 parent = tm;
 288
 289         if(!tm)
 290         {
 291                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 292                 return;
 293         }
 294         parent.sort_next = Team.sort_next;
 295         if(Team.sort_next)
 296                 Team.sort_next.sort_prev = parent;
 297         if(Team.team && Team.team != NUM_SPECTATOR)
 298                 --team_count;
 299         AuditLists();
 300 }
 301
 302 entity GetTeam(int Team, bool add)
 303 {
 304         TC(int, Team); TC(bool, add);
 305         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 306         if(teamslots[num])
 307                 return teamslots[num];
 308         if (!add)
 309                 return NULL;
 310         entity tm = new_pure(team);
 311         tm.team = Team;
 312         teamslots[num] = tm;
 313         RegisterTeam(tm);
 314         return tm;
 315 }
 316
 317 .float has_team;
 318 bool SetTeam(entity o, int Team)
 319 {
 320         TC(int, Team);
 321         //devassert_once(Team);
 322         entity tm;
 323         if(teamplay)
 324         {
 325                 switch(Team)
 326                 {
 327                         case -1:
 328                         case NUM_TEAM_1:
 329                         case NUM_TEAM_2:
 330                         case NUM_TEAM_3:
 331                         case NUM_TEAM_4:
 332                                 break;
 333                         default:
 334                                 if(GetTeam(Team, false) == NULL)
 335                                 {
 336                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 337                                         Team = NUM_SPECTATOR;
 338                                 }
 339                                 break;
 340                 }
 341         }
 342         else
 343         {
 344                 switch(Team)
 345                 {
 346                         case -1:
 347                         case 0:
 348                                 break;
 349                         default:
 350                                 if(GetTeam(Team, false) == NULL)
 351                                 {
 352                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 353                                         Team = NUM_SPECTATOR;
 354                                 }
 355                                 break;
 356                 }
 357         }
 358         if(Team == -1) // leave
 359         {
 360                 if(o.has_team)
 361                 {
 362                         tm = GetTeam(o.team, false);
 363                         tm.team_size -= 1;
 364                         o.has_team = 0;
 365                         return true;
 366                 }
 367         }
 368         else
 369         {
 370                 if (!o.has_team)
 371                 {
 372                         o.team = Team;
 373                         tm = GetTeam(Team, true);
 374                         tm.team_size += 1;
 375                         o.has_team = 1;
 376                         return true;
 377                 }
 378                 else if(Team != o.team)
 379                 {
 380                         tm = GetTeam(o.team, false);
 381                         tm.team_size -= 1;
 382                         o.team = Team;
 383                         tm = GetTeam(Team, true);
 384                         tm.team_size += 1;
 385                         return true;
 386                 }
 387         }
 388         return false;
 389 }
 390
 391 void Playerchecker_Think(entity this)
 392 {
 393         int i;
 394         entity e;
 395         for(i = 0; i < maxclients; ++i)
 396         {
 397                 e = playerslots[i];
 398                 if(entcs_GetName(i) == "")
 399                 {
 400                         if(e.sort_prev)
 401                         {
 402                                 // player disconnected
 403                                 SetTeam(e, -1);
 404                                 RemovePlayer(e);
 405                                 e.sort_prev = NULL;
 406                                 //e.gotscores = 0;
 407                         }
 408                 }
 409                 else
 410                 {
 411                         if (!e.sort_prev)
 412                         {
 413                                 // player connected
 414                                 if (!e)
 415                                 {
 416                                         playerslots[i] = e = new_pure(playerslot);
 417                                 }
 418                                 e.sv_entnum = i;
 419                                 e.ping = 0;
 420                                 e.ping_packetloss = 0;
 421                                 e.ping_movementloss = 0;
 422                                 //e.gotscores = 0; // we might already have the scores...
 423                                 int t = entcs_GetScoreTeam(i);
 424                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 425                                 RegisterPlayer(e);
 426                                 Scoreboard_UpdatePlayerPos(e);
 427                         }
 428                 }
 429         }
 430         this.nextthink = time + 0.2;
 431 }
 432
 433 void PostInit()
 434 {
 435         entity playerchecker = new_pure(playerchecker);
 436         setthink(playerchecker, Playerchecker_Think);
 437         playerchecker.nextthink = time + 0.2;
 438
 439         TrueAim_Init();
 440
 441         postinit = true;
 442 }
 443
 444 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 445 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 446 // All keys are in ascii.
 447 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 448 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 449 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 450 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 451 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 452 {
 453         TC(int, bInputType);
 454         bool override = false;
 455         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 456         if (override)
 457                 return true;
 458
 459         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 460
 461         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 466
 467         if(override)
 468                 return true;
 469
 470         return false;
 471 }
 472
 473 // END REQUIRED CSQC FUNCTIONS
 474 // --------------------------------------------------------------------------
 475
 476 // --------------------------------------------------------------------------
 477 // BEGIN OPTIONAL CSQC FUNCTIONS
 478
 479 void Ent_RemovePlayerScore(entity this)
 480 {
 481         if(this.owner) {
 482                 SetTeam(this.owner, -1);
 483                 this.owner.gotscores = 0;
 484                 FOREACH(Scores, true, {
 485                         this.owner.(scores(it)) = 0; // clear all scores
 486                 });
 487         }
 488 }
 489
 490 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 491 {
 492         make_pure(this);
 493         entity o;
 494
 495         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 496         // (no I've never heard of M-x replace-string, sed, or anything like that)
 497         bool isNew = !this.owner; // workaround for DP bug
 498         int n = ReadByte()-1;
 499
 500 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 501         if(!isNew && n != this.sv_entnum)
 502         {
 503                 //print("A CSQC entity changed its owner!\n");
 504                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 505                 isNew = true;
 506                 Ent_Remove(this);
 507         }
 508 #endif
 509
 510         this.sv_entnum = n;
 511
 512         o = playerslots[this.sv_entnum];
 513         if (!o)
 514         {
 515                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 516         }
 517         this.owner = o;
 518         o.sv_entnum = this.sv_entnum;
 519         o.gotscores = 1;
 520
 521         //if (!o.sort_prev)
 522         //      RegisterPlayer(o);
 523         //playerchecker will do this for us later, if it has not already done so
 524
 525         int sf = ReadShort();
 526         int lf = ReadShort();
 527         FOREACH(Scores, true, {
 528                 int p = 1 << (i % 16);
 529                 if (sf & p)
 530                 {
 531                         if (lf & p)
 532                                 o.(scores(it)) = ReadInt24_t();
 533                         else
 534                                 o.(scores(it)) = ReadChar();
 535                 }
 536         });
 537
 538         return = true;
 539
 540         if(o.sort_prev)
 541                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 542
 543         this.entremove = Ent_RemovePlayerScore;
 544 }
 545
 546 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 547 {
 548         make_pure(this);
 549         int i;
 550
 551         this.team = ReadByte();
 552         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 553
 554 #if MAX_TEAMSCORE <= 8
 555         int sf = ReadByte();
 556         int lf = ReadByte();
 557 #else
 558         int sf = ReadShort();
 559         int lf = ReadShort();
 560 #endif
 561         for(i = 0; i < MAX_TEAMSCORE; ++i)
 562                 if(sf & BIT(i))
 563                 {
 564                         if(lf & BIT(i))
 565                                 o.(teamscores(i)) = ReadInt24_t();
 566                         else
 567                                 o.(teamscores(i)) = ReadChar();
 568                 }
 569
 570         return = true;
 571
 572         Scoreboard_UpdateTeamPos(o);
 573 }
 574
 575 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 576 {
 577         make_pure(this);
 578         float newspectatee_status;
 579
 580         int f = ReadByte();
 581
 582         scoreboard_showscores_force = (f & BIT(0));
 583
 584         if(f & BIT(1))
 585         {
 586                 newspectatee_status = ReadByte();
 587                 if(newspectatee_status == player_localnum + 1)
 588                         newspectatee_status = -1; // observing
 589         }
 590         else
 591                 newspectatee_status = 0;
 592
 593         spectatorbutton_zoom = (f & BIT(2));
 594
 595         if(f & BIT(4))
 596         {
 597                 num_spectators = ReadByte();
 598
 599                 float i, slot;
 600
 601                 for(i = 0; i < MAX_SPECTATORS; ++i)
 602                         spectatorlist[i] = 0; // reset list first
 603
 604                 int limit = min(num_spectators, MAX_SPECTATORS);
 605                 for(i = 0; i < limit; ++i)
 606                 {
 607                         slot = ReadByte();
 608                         spectatorlist[i] = slot - 1;
 609                 }
 610         }
 611         else
 612         {
 613                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 614                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 615                 num_spectators = 0;
 616         }
 617
 618         return = true;
 619
 620         if(newspectatee_status != spectatee_status)
 621         {
 622                 // clear race stuff
 623                 race_laptime = 0;
 624                 race_checkpointtime = 0;
 625                 hud_dynamic_shake_factor = -1;
 626                 spectatee_status_changed_time = time;
 627         }
 628         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 629         {
 630                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 631                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 632                 )
 633                         prev_p_health = -1;
 634                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 635                         prev_health = -1;
 636         }
 637         spectatee_status = newspectatee_status;
 638
 639         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 640 }
 641
 642 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 643 {
 644         make_pure(this);
 645         int i, j, b, f;
 646
 647         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 648
 649         if(!(nags & BIT(2)))
 650         {
 651                 strfree(vote_called_vote);
 652                 vote_active = 0;
 653         }
 654         else
 655         {
 656                 vote_active = 1;
 657         }
 658
 659         if(nags & BIT(6))
 660         {
 661                 vote_yescount = ReadByte();
 662                 vote_nocount = ReadByte();
 663                 vote_needed = ReadByte();
 664                 vote_highlighted = ReadChar();
 665         }
 666
 667         if(nags & BIT(7))
 668         {
 669                 strcpy(vote_called_vote, ReadString());
 670         }
 671
 672         if(nags & 1)
 673         {
 674                 for(j = 0; j < maxclients; ++j)
 675                         if(playerslots[j])
 676                                 playerslots[j].ready = true;
 677                 for(i = 1; i <= maxclients; i += 8)
 678                 {
 679                         f = ReadByte();
 680                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 681                                 if (!(f & b))
 682                                         if(playerslots[j])
 683                                                 playerslots[j].ready = false;
 684                 }
 685         }
 686
 687         return = true;
 688
 689         ready_waiting = (nags & BIT(0));
 690         ready_waiting_for_me = (nags & BIT(1));
 691         vote_waiting = (nags & BIT(2));
 692         vote_waiting_for_me = (nags & BIT(3));
 693         warmup_stage = (nags & BIT(4));
 694 }
 695
 696 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 697 {
 698         make_pure(this);
 699         int sf = 0;
 700         serialize(byte, 0, sf);
 701         if (sf & 1) {
 702                 for (int j = 0; j < maxclients; ++j) {
 703                         if (playerslots[j]) {
 704                                 playerslots[j].eliminated = true;
 705                         }
 706                 }
 707                 for (int i = 1; i <= maxclients; i += 8) {
 708                         int f = 0;
 709                         serialize(byte, 0, f);
 710                         for (int b = 0; b < 8; ++b) {
 711                                 if (f & BIT(b)) continue;
 712                                 int j = i - 1 + b;
 713                                 if (playerslots[j]) {
 714                                         playerslots[j].eliminated = false;
 715                                 }
 716                         }
 717                 }
 718         }
 719         return true;
 720 }
 721
 722 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 723 {
 724         make_pure(this);
 725         prandom_debug();
 726         float s = ReadShort();
 727         psrandom(s);
 728         return true;
 729 }
 730
 731 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 732 {
 733         make_pure(this);
 734         int sf = ReadInt24_t();
 735         if (sf == 0) {
 736                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 737                         weapon_accuracy[w] = -1;
 738                 return true;
 739         }
 740
 741         int f = 1;
 742         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 743                 if (sf & f) {
 744                         int b = ReadByte();
 745                         if (b == 0)
 746                                 weapon_accuracy[w] = -1;
 747                         else if (b == 255)
 748                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 749                         else
 750                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 751                 }
 752                 f = (f == 0x800000) ? 1 : f * 2;
 753         }
 754         return true;
 755 }
 756
 757 void Spawn_Draw(entity this)
 758 {
 759         bool dodraw = autocvar_cl_spawn_point_particles;
 760         if(dodraw && autocvar_cl_spawn_point_dist_max)
 761         {
 762                 vector org = getpropertyvec(VF_ORIGIN);
 763                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 764         }
 765
 766         if(dodraw)
 767                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 768 }
 769
 770 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 771 {
 772         float teamnum = (ReadByte() - 1);
 773         vector spn_origin = ReadVector();
 774
 775         this.team = (teamnum + 1);
 776
 777         //if(is_new)
 778         //{
 779                 this.origin = spn_origin;
 780                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 781                 //droptofloor();
 782
 783                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 784                 {
 785                         this.mdl = "models/spawnpoint.md3";
 786                         this.colormod = Team_ColorRGB(teamnum);
 787                         precache_model(this.mdl);
 788                         setmodel(this, this.mdl);
 789                         this.drawmask = MASK_NORMAL;
 790                         //this.move_movetype = MOVETYPE_NOCLIP;
 791                         //this.draw = Spawn_Draw;
 792                         IL_PUSH(g_drawables, this);
 793                 }*/
 794                 this.draw = Spawn_Draw;
 795                 if (is_new) IL_PUSH(g_drawables, this);
 796         //}
 797
 798         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 799         return true;
 800 }
 801
 802 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 803 {
 804         // If entnum is 0, ONLY do the local spawn actions
 805         // this way the server can disable the sending of
 806         // spawn origin or such to clients if wanted.
 807         float entnum = ReadByte();
 808
 809         if(entnum)
 810         {
 811                 this.origin = ReadVector();
 812
 813                 if(is_new)
 814                 {
 815                         float teamnum = entcs_GetTeam(entnum - 1);
 816
 817                         if(autocvar_cl_spawn_event_particles)
 818                         {
 819                                 switch(teamnum)
 820                                 {
 821                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 822                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 823                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 824                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 825                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 826                                 }
 827                         }
 828                         if(autocvar_cl_spawn_event_sound)
 829                         {
 830                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 831                         }
 832                 }
 833         }
 834         return = true;
 835
 836         // local spawn actions
 837         if(is_new && (!entnum || (entnum == player_localentnum)))
 838         {
 839                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 840                 {
 841                         zoomin_effect = 1;
 842                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 843                 }
 844
 845                 if(autocvar_cl_unpress_zoom_on_spawn)
 846                 {
 847                         localcmd("-zoom\n");
 848                         button_zoom = false;
 849                 }
 850                 HUD_Radar_Hide_Maximized();
 851         }
 852         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 853 }
 854
 855 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 856 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 857 void CSQC_Ent_Update(entity this, bool isnew)
 858 {
 859         this.sourceLoc = __FILE__":"STR(__LINE__);
 860         int t = ReadByte();
 861
 862         // set up the "time" global for received entities to be correct for interpolation purposes
 863         float savetime = time;
 864         if(servertime)
 865         {
 866                 time = servertime;
 867         }
 868         else
 869         {
 870                 serverprevtime = time;
 871                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 872                 time = serverprevtime + serverdeltatime;
 873         }
 874
 875 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 876         if (this.enttype)
 877         {
 878                 if (t != this.enttype || isnew)
 879                 {
 880                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 881                         Ent_Remove(this);
 882                         ONREMOVE(this);
 883                         clearentity(this);
 884                         isnew = true;
 885                 }
 886         }
 887         else
 888         {
 889                 if (!isnew)
 890                 {
 891                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 892                         isnew = true;
 893                 }
 894         }
 895 #endif
 896         this.enttype = t;
 897         bool done = false;
 898         FOREACH(LinkedEntities, it.m_id == t, {
 899                 if (isnew) this.classname = it.netname;
 900                 if (autocvar_developer_csqcentities)
 901                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 902                 done = it.m_read(this, NULL, isnew);
 903                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 904                 break;
 905         });
 906         time = savetime;
 907         if (!done)
 908         {
 909                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 910         }
 911 }
 912
 913 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 914 // used when an entity changes its type. For an entity that someone interacts
 915 // with others, make sure it can no longer do so.
 916 void Ent_Remove(entity this)
 917 {
 918         if(this.entremove) this.entremove(this);
 919
 920         if(this.skeletonindex)
 921         {
 922                 skel_delete(this.skeletonindex);
 923                 this.skeletonindex = 0;
 924         }
 925
 926         if(this.snd_looping > 0)
 927         {
 928                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 929                 this.snd_looping = 0;
 930         }
 931
 932         this.enttype = 0;
 933         this.classname = "";
 934         this.draw = func_null;
 935         this.entremove = func_null;
 936         // TODO possibly set more stuff to defaults
 937 }
 938 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 939 void CSQC_Ent_Remove(entity this)
 940 {
 941         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 942         if (wasfreed(this))
 943         {
 944                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 945                 return;
 946         }
 947         if (this.enttype) Ent_Remove(this);
 948         delete(this);
 949 }
 950
 951 void Gamemode_Init()
 952 {
 953         if (!isdemo())
 954         {
 955                 if(!(calledhooks & HOOK_START))
 956                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 957                 calledhooks |= HOOK_START;
 958         }
 959 }
 960 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 961 void CSQC_Parse_StuffCmd(string strMessage)
 962 {
 963         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 964         localcmd(strMessage);
 965 }
 966 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 967 void CSQC_Parse_Print(string strMessage)
 968 {
 969         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 970         print(ColorTranslateRGB(strMessage));
 971 }
 972
 973 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 974 void CSQC_Parse_CenterPrint(string strMessage)
 975 {
 976         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 977         centerprint_AddStandard(strMessage);
 978 }
 979
 980 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 981 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 982 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 983 bool CSQC_Parse_TempEntity()
 984 {
 985         // Acquire TE ID
 986         int nTEID = ReadByte();
 987
 988         FOREACH(TempEntities, it.m_id == nTEID, {
 989                 if (autocvar_developer_csqcentities)
 990                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 991                 return it.m_read(NULL, NULL, true);
 992         });
 993
 994         if (autocvar_developer_csqcentities)
 995                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 996
 997         // No special logic for this temporary entity; return 0 so the engine can handle it
 998         return false;
 999 }
1000
1001 string forcefog;
1002 void Fog_Force()
1003 {
1004         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1005                 localcmd("\nr_drawfog 0\n");
1006         else if (forcefog != "")
1007                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1008 }
1009
1010 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1011 {
1012         make_pure(this);
1013         gametype = ReadRegistered(Gametypes);
1014         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1015         HUD_ModIcons_SetFunc();
1016         FOREACH(Scores, true, {
1017                 strcpy(scores_label(it), ReadString());
1018                 scores_flags(it) = ReadByte();
1019         });
1020         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1021         {
1022                 strcpy(teamscores_label(i), ReadString());
1023                 teamscores_flags(i) = ReadByte();
1024         }
1025         return = true;
1026         Scoreboard_InitScores();
1027         Gamemode_Init();
1028 }
1029
1030 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1031 {
1032         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1033
1034         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042
1043         strcpy(forcefog, ReadString());
1044
1045         armorblockpercent = ReadByte() / 255.0;
1046         damagepush_speedfactor = ReadByte() / 255.0;
1047
1048         serverflags = ReadByte();
1049
1050         g_trueaim_minrange = ReadCoord();
1051
1052         return = true;
1053
1054         MUTATOR_CALLHOOK(Ent_Init);
1055
1056         if (!postinit) PostInit();
1057 }
1058
1059 float GetSpeedUnitFactor(int speed_unit)
1060 {
1061         switch(speed_unit)
1062         {
1063                 default:
1064                 case 1: return 1.0;
1065                 case 2: return 0.0254;
1066                 case 3: return 0.0254 * 3.6;
1067                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1068                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1069         }
1070 }
1071
1072 string GetSpeedUnit(int speed_unit)
1073 {
1074         switch(speed_unit)
1075         {
1076                 // translator-friendly strings without the initial space
1077                 default:
1078                 case 1: return strcat(" ", _("qu/s"));
1079                 case 2: return strcat(" ", _("m/s"));
1080                 case 3: return strcat(" ", _("km/h"));
1081                 case 4: return strcat(" ", _("mph"));
1082                 case 5: return strcat(" ", _("knots"));
1083         }
1084 }
1085
1086 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1087 {
1088         int b = ReadByte();
1089
1090         switch (b)
1091         {
1092                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1093                         race_checkpoint = ReadByte();
1094                         race_time = ReadInt24_t();
1095                         race_previousbesttime = ReadInt24_t();
1096                         race_mypreviousbesttime = ReadInt24_t();
1097                         string pbestname = ReadString();
1098                         if(autocvar_cl_race_cptimes_onlyself)
1099                         {
1100                                 race_previousbesttime = race_mypreviousbesttime;
1101                                 race_mypreviousbesttime = 0;
1102                                 strcpy(race_previousbestname, "");
1103                         }
1104                         else
1105                                 strcpy(race_previousbestname, pbestname);
1106
1107                         race_checkpointtime = time;
1108
1109                         if(race_checkpoint == 0 || race_checkpoint == 254)
1110                         {
1111                                 race_penaltyaccumulator = 0;
1112                                 race_laptime = time; // valid
1113                         }
1114                         break;
1115
1116                 case RACE_NET_CHECKPOINT_CLEAR:
1117                         race_laptime = 0;
1118                         race_checkpointtime = 0;
1119                         break;
1120
1121                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1122                         race_laptime = ReadCoord();
1123                         race_checkpointtime = -99999;
1124                         // fall through
1125                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1126                         race_nextcheckpoint = ReadByte();
1127
1128                         race_nextbesttime = ReadInt24_t();
1129                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1130                                 race_mybesttime = ReadInt24_t();
1131                         string newname = ReadString();
1132                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1133                         {
1134                                 race_nextbesttime = race_mybesttime;
1135                                 race_mybesttime = 0;
1136                                 strcpy(race_nextbestname, "");
1137                         }
1138                         else
1139                                 strcpy(race_nextbestname, newname);
1140                         break;
1141
1142                 case RACE_NET_CHECKPOINT_HIT_RACE:
1143                         race_mycheckpoint = ReadByte();
1144                         race_mycheckpointtime = time;
1145                         race_mycheckpointdelta = ReadInt24_t();
1146                         race_mycheckpointlapsdelta = ReadByte();
1147                         if(race_mycheckpointlapsdelta >= 128)
1148                                 race_mycheckpointlapsdelta -= 256;
1149                         int who = ReadByte();
1150                         if(who)
1151                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1152                         else
1153                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1154                         break;
1155
1156                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1157                         race_othercheckpoint = ReadByte();
1158                         race_othercheckpointtime = time;
1159                         race_othercheckpointdelta = ReadInt24_t();
1160                         race_othercheckpointlapsdelta = ReadByte();
1161                         if(race_othercheckpointlapsdelta >= 128)
1162                                 race_othercheckpointlapsdelta -= 256;
1163                         int what = ReadByte();
1164                         if(what)
1165                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1166                         else
1167                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1168                         break;
1169
1170                 case RACE_NET_PENALTY_RACE:
1171                 case RACE_NET_PENALTY_QUALIFYING:
1172                         race_penaltyeventtime = time;
1173                         race_penaltytime = ReadShort();
1174                         string reason = ReadString();
1175                         if (reason == "missing a checkpoint")
1176                                 reason = _("missing a checkpoint");
1177                         strcpy(race_penaltyreason, reason);
1178                         if (b == RACE_NET_PENALTY_QUALIFYING)
1179                                 race_penaltyaccumulator += race_penaltytime;
1180                         break;
1181
1182                 case RACE_NET_SERVER_RECORD:
1183                         race_server_record = ReadInt24_t();
1184                         break;
1185                 case RACE_NET_SPEED_AWARD:
1186                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1187                         strcpy(race_speedaward_holder, ReadString());
1188                         break;
1189                 case RACE_NET_SPEED_AWARD_BEST:
1190                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1191                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1192                         break;
1193                 case RACE_NET_RANKINGS_CNT:
1194                         RANKINGS_DISPLAY_CNT = ReadByte();
1195                         break;
1196                 case RACE_NET_SERVER_RANKINGS:
1197                         float prevpos, del;
1198                         int pos = ReadShort();
1199                         prevpos = ReadShort();
1200                         del = ReadShort();
1201
1202                         // move other rankings out of the way
1203                         int i;
1204                         if (prevpos) {
1205                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1206                                 for (i=m-1; i>pos-1; --i) {
1207                                         grecordtime[i] = grecordtime[i-1];
1208                                         strcpy(grecordholder[i], grecordholder[i-1]);
1209                                 }
1210                         } else if (del) { // a record has been deleted by the admin
1211                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1212                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1213                                                 grecordtime[i] = 0;
1214                                                 strfree(grecordholder[i]);
1215                                         }
1216                                         else {
1217                                                 grecordtime[i] = grecordtime[i+1];
1218                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1219                                         }
1220                                 }
1221                         } else { // player has no ranked record yet
1222                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1223                                         grecordtime[i] = grecordtime[i-1];
1224                                         strcpy(grecordholder[i], grecordholder[i-1]);
1225                                 }
1226                         }
1227
1228                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1229                                 // kick off the player who fell from the last displayed position
1230                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1231                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1232                         }
1233
1234                         // store new ranking
1235                         strcpy(grecordholder[pos-1], ReadString());
1236                         grecordtime[pos-1] = ReadInt24_t();
1237                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1238                                 race_myrank = pos;
1239                         break;
1240                 case RACE_NET_SERVER_STATUS:
1241                         race_status = ReadShort();
1242                         strcpy(race_status_name, ReadString());
1243         }
1244         return true;
1245 }
1246
1247 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1248 {
1249         teamnagger = 1;
1250         return true;
1251 }
1252
1253 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1254 {
1255         int i = ReadByte();
1256         int pi = ReadShort();
1257         int pl = ReadByte();
1258         int ml = ReadByte();
1259         return = true;
1260         entity e = playerslots[i];
1261         if (!e) return;
1262         e.ping = pi;
1263         e.ping_packetloss = pl / 255.0;
1264         e.ping_movementloss = ml / 255.0;
1265 }
1266
1267 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1268 {
1269         int weapon_id = ReadByte();
1270         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1271         complain_weapon_type = ReadByte();
1272         return = true;
1273
1274         complain_weapon_time = time;
1275         weapontime = time; // ping the weapon panel
1276
1277         switch(complain_weapon_type)
1278         {
1279                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1280                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1281                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1282         }
1283 }
1284
1285 string _getcommandkey(string cmd_name, string command, bool forcename)
1286 {
1287         string keys;
1288         float n, j, k, l = 0;
1289
1290         if (!autocvar_hud_showbinds)
1291                 return cmd_name;
1292
1293         keys = db_get(binddb, command);
1294         if (keys == "")
1295         {
1296                 bool joy_active = cvar("joy_active");
1297                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1298                 for(j = 0; j < n; ++j)
1299                 {
1300                         k = stof(argv(j));
1301                         if(k != -1)
1302                         {
1303                                 string key = keynumtostring(k);
1304                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1305                                         continue;
1306
1307                                 key = translate_key(key);
1308
1309                                 if (keys == "")
1310                                         keys = key;
1311                                 else
1312                                         keys = strcat(keys, ", ", key);
1313
1314                                 ++l;
1315                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1316                                         break;
1317                         }
1318
1319                 }
1320                 if (keys == "")
1321                         keys = "NO_KEY";
1322                 db_put(binddb, command, keys);
1323         }
1324
1325         if (keys == "NO_KEY") {
1326                 if (autocvar_hud_showbinds > 1)
1327                         return sprintf(_("%s (not bound)"), cmd_name);
1328                 else
1329                         return cmd_name;
1330         }
1331         else if (autocvar_hud_showbinds > 1 || forcename)
1332                 return sprintf("%s (%s)", cmd_name, keys);
1333         else
1334                 return keys;
1335 }
1336
1337 /** engine callback */
1338 void URI_Get_Callback(int id, int status, string data)
1339 {
1340         TC(int, id); TC(int, status);
1341         if(url_URI_Get_Callback(id, status, data))
1342         {
1343                 // handled
1344         }
1345         else if (id == URI_GET_DISCARD)
1346         {
1347                 // discard
1348         }
1349         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1350         {
1351                 // sv_cmd curl
1352                 Curl_URI_Get_Callback(id, status, data);
1353         }
1354         else
1355         {
1356                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1357         }
1358 }