qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         if (autocvar_r_drawviewmodel < 0)
 171                 cvar_set("r_drawviewmodel", "0");
 172
 173         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 174
 175         if (!isdemo())
 176         {
 177                 if (!(calledhooks & HOOK_START))
 178                         localcmd("\n_cl_hook_gamestart nop\n");
 179                 if (!(calledhooks & HOOK_END))
 180                 {
 181                         int gamecount = cvar("cl_matchcount");
 182                         localcmd("\ncl_hook_gameend\n");
 183                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
 184                         // earlier versions of the game abuse the hook to set this cvar
 185                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
 186                         //cvar_set("cl_matchcount", itos(gamecount + 1));
 187                 }
 188         }
 189
 190         localcmd("\ncl_hook_shutdown\n");
 191
 192         localcmd("\n-button12\n");
 193
 194         deactivate_minigame();
 195         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 196
 197         ReplicateVars(true); // destroy
 198 }
 199
 200 void AuditLists()
 201 {
 202         entity e;
 203         entity prev;
 204
 205         prev = players;
 206         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 207         {
 208                 if(prev != e.sort_prev)
 209                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 210         }
 211
 212         prev = teams;
 213         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 214         {
 215                 if(prev != e.sort_prev)
 216                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 217         }
 218 }
 219
 220 float RegisterPlayer(entity player)
 221 {
 222         entity pl;
 223         AuditLists();
 224         for(pl = players.sort_next; pl; pl = pl.sort_next)
 225                 if(pl == player)
 226                         error("Player already registered!");
 227         player.sort_next = players.sort_next;
 228         player.sort_prev = players;
 229         if(players.sort_next)
 230                 players.sort_next.sort_prev = player;
 231         players.sort_next = player;
 232         AuditLists();
 233         return true;
 234 }
 235
 236 void RemovePlayer(entity player)
 237 {
 238         entity pl, parent;
 239         AuditLists();
 240         parent = players;
 241         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 242                 parent = pl;
 243
 244         if(!pl)
 245         {
 246                 error("Trying to remove a player which is not in the playerlist!");
 247                 return;
 248         }
 249         parent.sort_next = player.sort_next;
 250         if(player.sort_next)
 251                 player.sort_next.sort_prev = parent;
 252         AuditLists();
 253 }
 254
 255 void MoveToLast(entity e)
 256 {
 257         AuditLists();
 258         entity ent = e.sort_next;
 259         while(ent)
 260         {
 261                 SORT_SWAP(ent, e);
 262                 ent = e.sort_next;
 263         }
 264         AuditLists();
 265 }
 266
 267 float RegisterTeam(entity Team)
 268 {
 269         assert_once(Team.team, eprint(Team));
 270         entity tm;
 271         AuditLists();
 272         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 273                 if(tm == Team)
 274                         error("Team already registered!");
 275         Team.sort_next = teams.sort_next;
 276         Team.sort_prev = teams;
 277         if(teams.sort_next)
 278                 teams.sort_next.sort_prev = Team;
 279         teams.sort_next = Team;
 280         if(Team.team && Team.team != NUM_SPECTATOR)
 281                 ++team_count;
 282         AuditLists();
 283         return true;
 284 }
 285
 286 void RemoveTeam(entity Team)
 287 {
 288         entity tm, parent;
 289         AuditLists();
 290         parent = teams;
 291         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 292                 parent = tm;
 293
 294         if(!tm)
 295         {
 296                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 297                 return;
 298         }
 299         parent.sort_next = Team.sort_next;
 300         if(Team.sort_next)
 301                 Team.sort_next.sort_prev = parent;
 302         if(Team.team && Team.team != NUM_SPECTATOR)
 303                 --team_count;
 304         AuditLists();
 305 }
 306
 307 entity GetTeam(int Team, bool add)
 308 {
 309         TC(int, Team); TC(bool, add);
 310         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 311         if(teamslots[num])
 312                 return teamslots[num];
 313         if (!add)
 314                 return NULL;
 315         entity tm = new_pure(team);
 316         tm.team = Team;
 317         teamslots[num] = tm;
 318         RegisterTeam(tm);
 319         return tm;
 320 }
 321
 322 .float has_team;
 323 bool SetTeam(entity o, int Team)
 324 {
 325         TC(int, Team);
 326         //devassert_once(Team);
 327         entity tm;
 328         if(teamplay)
 329         {
 330                 switch(Team)
 331                 {
 332                         case -1:
 333                         case NUM_TEAM_1:
 334                         case NUM_TEAM_2:
 335                         case NUM_TEAM_3:
 336                         case NUM_TEAM_4:
 337                                 break;
 338                         default:
 339                                 if(GetTeam(Team, false) == NULL)
 340                                 {
 341                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 342                                         Team = NUM_SPECTATOR;
 343                                 }
 344                                 break;
 345                 }
 346         }
 347         else
 348         {
 349                 switch(Team)
 350                 {
 351                         case -1:
 352                         case 0:
 353                                 break;
 354                         default:
 355                                 if(GetTeam(Team, false) == NULL)
 356                                 {
 357                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 358                                         Team = NUM_SPECTATOR;
 359                                 }
 360                                 break;
 361                 }
 362         }
 363         if(Team == -1) // leave
 364         {
 365                 if(o.has_team)
 366                 {
 367                         tm = GetTeam(o.team, false);
 368                         tm.team_size -= 1;
 369                         o.has_team = 0;
 370                         return true;
 371                 }
 372         }
 373         else
 374         {
 375                 if (!o.has_team)
 376                 {
 377                         o.team = Team;
 378                         tm = GetTeam(Team, true);
 379                         tm.team_size += 1;
 380                         o.has_team = 1;
 381                         return true;
 382                 }
 383                 else if(Team != o.team)
 384                 {
 385                         tm = GetTeam(o.team, false);
 386                         tm.team_size -= 1;
 387                         o.team = Team;
 388                         tm = GetTeam(Team, true);
 389                         tm.team_size += 1;
 390                         return true;
 391                 }
 392         }
 393         return false;
 394 }
 395
 396 void Playerchecker_Think(entity this)
 397 {
 398         int i;
 399         entity e;
 400         for(i = 0; i < maxclients; ++i)
 401         {
 402                 e = playerslots[i];
 403                 if(entcs_GetName(i) == "")
 404                 {
 405                         if(e.sort_prev)
 406                         {
 407                                 // player disconnected
 408                                 SetTeam(e, -1);
 409                                 RemovePlayer(e);
 410                                 e.sort_prev = NULL;
 411                                 //e.gotscores = 0;
 412                         }
 413                 }
 414                 else
 415                 {
 416                         if (!e.sort_prev)
 417                         {
 418                                 // player connected
 419                                 if (!e)
 420                                 {
 421                                         playerslots[i] = e = new_pure(playerslot);
 422                                 }
 423                                 e.sv_entnum = i;
 424                                 e.ping = 0;
 425                                 e.ping_packetloss = 0;
 426                                 e.ping_movementloss = 0;
 427                                 //e.gotscores = 0; // we might already have the scores...
 428                                 int t = entcs_GetScoreTeam(i);
 429                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 430                                 RegisterPlayer(e);
 431                                 Scoreboard_UpdatePlayerPos(e);
 432                         }
 433                 }
 434         }
 435         this.nextthink = time + 0.2;
 436 }
 437
 438 void PostInit()
 439 {
 440         entity playerchecker = new_pure(playerchecker);
 441         setthink(playerchecker, Playerchecker_Think);
 442         playerchecker.nextthink = time + 0.2;
 443
 444         TrueAim_Init();
 445
 446         postinit = true;
 447 }
 448
 449 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 450 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 451 // All keys are in ascii.
 452 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 453 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 454 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 455 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 456 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 457 {
 458         TC(int, bInputType);
 459         bool override = false;
 460         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 461         if (override)
 462                 return true;
 463
 464         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 465
 466         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 467
 468         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 469
 470         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 471
 472         if(override)
 473                 return true;
 474
 475         return false;
 476 }
 477
 478 // END REQUIRED CSQC FUNCTIONS
 479 // --------------------------------------------------------------------------
 480
 481 // --------------------------------------------------------------------------
 482 // BEGIN OPTIONAL CSQC FUNCTIONS
 483
 484 void Ent_RemovePlayerScore(entity this)
 485 {
 486         if(this.owner) {
 487                 SetTeam(this.owner, -1);
 488                 this.owner.gotscores = 0;
 489                 FOREACH(Scores, true, {
 490                         this.owner.(scores(it)) = 0; // clear all scores
 491                 });
 492         }
 493 }
 494
 495 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 496 {
 497         make_pure(this);
 498         entity o;
 499
 500         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 501         // (no I've never heard of M-x replace-string, sed, or anything like that)
 502         bool isNew = !this.owner; // workaround for DP bug
 503         int n = ReadByte()-1;
 504
 505 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 506         if(!isNew && n != this.sv_entnum)
 507         {
 508                 //print("A CSQC entity changed its owner!\n");
 509                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 510                 isNew = true;
 511                 Ent_Remove(this);
 512         }
 513 #endif
 514
 515         this.sv_entnum = n;
 516
 517         o = playerslots[this.sv_entnum];
 518         if (!o)
 519         {
 520                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 521         }
 522         this.owner = o;
 523         o.sv_entnum = this.sv_entnum;
 524         o.gotscores = 1;
 525
 526         //if (!o.sort_prev)
 527         //      RegisterPlayer(o);
 528         //playerchecker will do this for us later, if it has not already done so
 529
 530         int sf = ReadShort();
 531         int lf = ReadShort();
 532         FOREACH(Scores, true, {
 533                 int p = 1 << (i % 16);
 534                 if (sf & p)
 535                 {
 536                         if (lf & p)
 537                                 o.(scores(it)) = ReadInt24_t();
 538                         else
 539                                 o.(scores(it)) = ReadChar();
 540                 }
 541         });
 542
 543         return = true;
 544
 545         if(o.sort_prev)
 546                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 547
 548         this.entremove = Ent_RemovePlayerScore;
 549 }
 550
 551 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 552 {
 553         make_pure(this);
 554         int i;
 555
 556         this.team = ReadByte();
 557         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 558
 559 #if MAX_TEAMSCORE <= 8
 560         int sf = ReadByte();
 561         int lf = ReadByte();
 562 #else
 563         int sf = ReadShort();
 564         int lf = ReadShort();
 565 #endif
 566         for(i = 0; i < MAX_TEAMSCORE; ++i)
 567                 if(sf & BIT(i))
 568                 {
 569                         if(lf & BIT(i))
 570                                 o.(teamscores(i)) = ReadInt24_t();
 571                         else
 572                                 o.(teamscores(i)) = ReadChar();
 573                 }
 574
 575         return = true;
 576
 577         Scoreboard_UpdateTeamPos(o);
 578 }
 579
 580 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 581 {
 582         make_pure(this);
 583         float newspectatee_status;
 584
 585         int f = ReadByte();
 586
 587         scoreboard_showscores_force = (f & BIT(0));
 588
 589         if(f & BIT(1))
 590         {
 591                 newspectatee_status = ReadByte();
 592                 if(newspectatee_status == player_localnum + 1)
 593                         newspectatee_status = -1; // observing
 594         }
 595         else
 596                 newspectatee_status = 0;
 597
 598         spectatorbutton_zoom = (f & BIT(2));
 599
 600         if(f & BIT(4))
 601         {
 602                 num_spectators = ReadByte();
 603
 604                 float i, slot;
 605
 606                 for(i = 0; i < MAX_SPECTATORS; ++i)
 607                         spectatorlist[i] = 0; // reset list first
 608
 609                 int limit = min(num_spectators, MAX_SPECTATORS);
 610                 for(i = 0; i < limit; ++i)
 611                 {
 612                         slot = ReadByte();
 613                         spectatorlist[i] = slot - 1;
 614                 }
 615         }
 616         else
 617         {
 618                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 619                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 620                 num_spectators = 0;
 621         }
 622
 623         return = true;
 624
 625         if(newspectatee_status != spectatee_status)
 626         {
 627                 // clear race stuff
 628                 race_laptime = 0;
 629                 race_checkpointtime = 0;
 630                 hud_dynamic_shake_factor = -1;
 631                 spectatee_status_changed_time = time;
 632         }
 633         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 634         {
 635                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 636                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 637                 )
 638                         prev_p_health = -1;
 639                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 640                         prev_health = -1;
 641         }
 642         spectatee_status = newspectatee_status;
 643
 644         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 645 }
 646
 647 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 648 {
 649         make_pure(this);
 650         int i, j, b, f;
 651
 652         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 653
 654         if(!(nags & BIT(2)))
 655         {
 656                 strfree(vote_called_vote);
 657                 vote_active = 0;
 658         }
 659         else
 660         {
 661                 vote_active = 1;
 662         }
 663
 664         if(nags & BIT(6))
 665         {
 666                 vote_yescount = ReadByte();
 667                 vote_nocount = ReadByte();
 668                 vote_needed = ReadByte();
 669                 vote_highlighted = ReadChar();
 670         }
 671
 672         if(nags & BIT(7))
 673         {
 674                 strcpy(vote_called_vote, ReadString());
 675         }
 676
 677         if(nags & 1)
 678         {
 679                 for(j = 0; j < maxclients; ++j)
 680                         if(playerslots[j])
 681                                 playerslots[j].ready = true;
 682                 for(i = 1; i <= maxclients; i += 8)
 683                 {
 684                         f = ReadByte();
 685                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 686                                 if (!(f & b))
 687                                         if(playerslots[j])
 688                                                 playerslots[j].ready = false;
 689                 }
 690         }
 691
 692         return = true;
 693
 694         ready_waiting = (nags & BIT(0));
 695         ready_waiting_for_me = (nags & BIT(1));
 696         vote_waiting = (nags & BIT(2));
 697         vote_waiting_for_me = (nags & BIT(3));
 698         warmup_stage = (nags & BIT(4));
 699 }
 700
 701 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 702 {
 703         make_pure(this);
 704         int sf = 0;
 705         serialize(byte, 0, sf);
 706         if (sf & 1) {
 707                 for (int j = 0; j < maxclients; ++j) {
 708                         if (playerslots[j]) {
 709                                 playerslots[j].eliminated = true;
 710                         }
 711                 }
 712                 for (int i = 1; i <= maxclients; i += 8) {
 713                         int f = 0;
 714                         serialize(byte, 0, f);
 715                         for (int b = 0; b < 8; ++b) {
 716                                 if (f & BIT(b)) continue;
 717                                 int j = i - 1 + b;
 718                                 if (playerslots[j]) {
 719                                         playerslots[j].eliminated = false;
 720                                 }
 721                         }
 722                 }
 723         }
 724         return true;
 725 }
 726
 727 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 728 {
 729         make_pure(this);
 730         prandom_debug();
 731         float s = ReadShort();
 732         psrandom(s);
 733         return true;
 734 }
 735
 736 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 737 {
 738         make_pure(this);
 739         int sf = ReadInt24_t();
 740         if (sf == 0) {
 741                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 742                         weapon_accuracy[w] = -1;
 743                 return true;
 744         }
 745
 746         int f = 1;
 747         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 748                 if (sf & f) {
 749                         int b = ReadByte();
 750                         if (b == 0)
 751                                 weapon_accuracy[w] = -1;
 752                         else if (b == 255)
 753                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 754                         else
 755                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 756                 }
 757                 f = (f == 0x800000) ? 1 : f * 2;
 758         }
 759         return true;
 760 }
 761
 762 void Spawn_Draw(entity this)
 763 {
 764         bool dodraw = autocvar_cl_spawn_point_particles;
 765         if(dodraw && autocvar_cl_spawn_point_dist_max)
 766         {
 767                 vector org = getpropertyvec(VF_ORIGIN);
 768                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 769         }
 770
 771         if(dodraw)
 772                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 773 }
 774
 775 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 776 {
 777         float teamnum = (ReadByte() - 1);
 778         vector spn_origin = ReadVector();
 779
 780         this.team = (teamnum + 1);
 781
 782         //if(is_new)
 783         //{
 784                 this.origin = spn_origin;
 785                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 786                 //droptofloor();
 787
 788                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 789                 {
 790                         this.mdl = "models/spawnpoint.md3";
 791                         this.colormod = Team_ColorRGB(teamnum);
 792                         precache_model(this.mdl);
 793                         setmodel(this, this.mdl);
 794                         this.drawmask = MASK_NORMAL;
 795                         //this.move_movetype = MOVETYPE_NOCLIP;
 796                         //this.draw = Spawn_Draw;
 797                         IL_PUSH(g_drawables, this);
 798                 }*/
 799                 this.draw = Spawn_Draw;
 800                 if (is_new) IL_PUSH(g_drawables, this);
 801         //}
 802
 803         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 804         return true;
 805 }
 806
 807 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 808 {
 809         // If entnum is 0, ONLY do the local spawn actions
 810         // this way the server can disable the sending of
 811         // spawn origin or such to clients if wanted.
 812         float entnum = ReadByte();
 813
 814         if(entnum)
 815         {
 816                 this.origin = ReadVector();
 817
 818                 if(is_new)
 819                 {
 820                         float teamnum = entcs_GetTeam(entnum - 1);
 821
 822                         if(autocvar_cl_spawn_event_particles)
 823                         {
 824                                 switch(teamnum)
 825                                 {
 826                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 827                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 828                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 829                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 830                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 831                                 }
 832                         }
 833                         if(autocvar_cl_spawn_event_sound)
 834                         {
 835                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 836                         }
 837                 }
 838         }
 839         return = true;
 840
 841         // local spawn actions
 842         if(is_new && (!entnum || (entnum == player_localentnum)))
 843         {
 844                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 845                 {
 846                         zoomin_effect = 1;
 847                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 848                 }
 849
 850                 if(autocvar_cl_unpress_zoom_on_spawn)
 851                 {
 852                         localcmd("-zoom\n");
 853                         button_zoom = false;
 854                 }
 855                 HUD_Radar_Hide_Maximized();
 856         }
 857         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 858 }
 859
 860 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 861 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 862 void CSQC_Ent_Update(entity this, bool isnew)
 863 {
 864         this.sourceLoc = __FILE__":"STR(__LINE__);
 865         int t = ReadByte();
 866
 867         // set up the "time" global for received entities to be correct for interpolation purposes
 868         float savetime = time;
 869         if(servertime)
 870         {
 871                 time = servertime;
 872         }
 873         else
 874         {
 875                 serverprevtime = time;
 876                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 877                 time = serverprevtime + serverdeltatime;
 878         }
 879
 880 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 881         if (this.enttype)
 882         {
 883                 if (t != this.enttype || isnew)
 884                 {
 885                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 886                         Ent_Remove(this);
 887                         clearentity(this);
 888                         isnew = true;
 889                 }
 890         }
 891         else
 892         {
 893                 if (!isnew)
 894                 {
 895                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 896                         isnew = true;
 897                 }
 898         }
 899 #endif
 900         this.enttype = t;
 901         bool done = false;
 902         FOREACH(LinkedEntities, it.m_id == t, {
 903                 if (isnew) this.classname = it.netname;
 904                 if (autocvar_developer_csqcentities)
 905                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 906                 done = it.m_read(this, NULL, isnew);
 907                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 908                 break;
 909         });
 910         time = savetime;
 911         if (!done)
 912         {
 913                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 914         }
 915 }
 916
 917 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 918 // used when an entity changes its type. For an entity that someone interacts
 919 // with others, make sure it can no longer do so.
 920 void Ent_Remove(entity this)
 921 {
 922         if(this.entremove) this.entremove(this);
 923
 924         if(this.skeletonindex)
 925         {
 926                 skel_delete(this.skeletonindex);
 927                 this.skeletonindex = 0;
 928         }
 929
 930         if(this.snd_looping > 0)
 931         {
 932                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 933                 this.snd_looping = 0;
 934         }
 935
 936         this.enttype = 0;
 937         this.classname = "";
 938         this.draw = func_null;
 939         this.entremove = func_null;
 940         // TODO possibly set more stuff to defaults
 941 }
 942 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 943 void CSQC_Ent_Remove(entity this)
 944 {
 945         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 946         if (wasfreed(this))
 947         {
 948                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 949                 return;
 950         }
 951         if (this.enttype) Ent_Remove(this);
 952         delete(this);
 953 }
 954
 955 void Gamemode_Init()
 956 {
 957         if (!isdemo())
 958         {
 959                 if(!(calledhooks & HOOK_START))
 960                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 961                 calledhooks |= HOOK_START;
 962         }
 963 }
 964 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 965 void CSQC_Parse_StuffCmd(string strMessage)
 966 {
 967         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 968         localcmd(strMessage);
 969 }
 970 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 971 void CSQC_Parse_Print(string strMessage)
 972 {
 973         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 974         print(ColorTranslateRGB(strMessage));
 975 }
 976
 977 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 978 void CSQC_Parse_CenterPrint(string strMessage)
 979 {
 980         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 981         centerprint_AddStandard(strMessage);
 982 }
 983
 984 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 985 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 986 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 987 bool CSQC_Parse_TempEntity()
 988 {
 989         // Acquire TE ID
 990         int nTEID = ReadByte();
 991
 992         FOREACH(TempEntities, it.m_id == nTEID, {
 993                 if (autocvar_developer_csqcentities)
 994                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 995                 return it.m_read(NULL, NULL, true);
 996         });
 997
 998         if (autocvar_developer_csqcentities)
 999                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1000
1001         // No special logic for this temporary entity; return 0 so the engine can handle it
1002         return false;
1003 }
1004
1005 string forcefog;
1006 void Fog_Force()
1007 {
1008         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1009                 localcmd("\nr_drawfog 0\n");
1010         else if (forcefog != "")
1011                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1012 }
1013
1014 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1015 {
1016         make_pure(this);
1017         gametype = ReadRegistered(Gametypes);
1018         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1019         HUD_ModIcons_SetFunc();
1020         FOREACH(Scores, true, {
1021                 strcpy(scores_label(it), ReadString());
1022                 scores_flags(it) = ReadByte();
1023         });
1024         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1025         {
1026                 strcpy(teamscores_label(i), ReadString());
1027                 teamscores_flags(i) = ReadByte();
1028         }
1029         return = true;
1030         Scoreboard_InitScores();
1031         Gamemode_Init();
1032 }
1033
1034 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1035 {
1036         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1037
1038         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1044         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1045         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1046
1047         strcpy(forcefog, ReadString());
1048
1049         armorblockpercent = ReadByte() / 255.0;
1050         damagepush_speedfactor = ReadByte() / 255.0;
1051
1052         serverflags = ReadByte();
1053
1054         g_trueaim_minrange = ReadCoord();
1055
1056         return = true;
1057
1058         MUTATOR_CALLHOOK(Ent_Init);
1059
1060         if (!postinit) PostInit();
1061 }
1062
1063 float GetSpeedUnitFactor(int speed_unit)
1064 {
1065         switch(speed_unit)
1066         {
1067                 default:
1068                 case 1: return 1.0;
1069                 case 2: return 0.0254;
1070                 case 3: return 0.0254 * 3.6;
1071                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1072                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1073         }
1074 }
1075
1076 string GetSpeedUnit(int speed_unit)
1077 {
1078         switch(speed_unit)
1079         {
1080                 // translator-friendly strings without the initial space
1081                 default:
1082                 case 1: return strcat(" ", _("qu/s"));
1083                 case 2: return strcat(" ", _("m/s"));
1084                 case 3: return strcat(" ", _("km/h"));
1085                 case 4: return strcat(" ", _("mph"));
1086                 case 5: return strcat(" ", _("knots"));
1087         }
1088 }
1089
1090 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1091 {
1092         int b = ReadByte();
1093
1094         switch (b)
1095         {
1096                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1097                         race_checkpoint = ReadByte();
1098                         race_time = ReadInt24_t();
1099                         race_previousbesttime = ReadInt24_t();
1100                         race_mypreviousbesttime = ReadInt24_t();
1101                         string pbestname = ReadString();
1102                         if(autocvar_cl_race_cptimes_onlyself)
1103                         {
1104                                 race_previousbesttime = race_mypreviousbesttime;
1105                                 race_mypreviousbesttime = 0;
1106                                 strcpy(race_previousbestname, "");
1107                         }
1108                         else
1109                                 strcpy(race_previousbestname, pbestname);
1110
1111                         race_checkpointtime = time;
1112
1113                         if(race_checkpoint == 0 || race_checkpoint == 254)
1114                         {
1115                                 race_penaltyaccumulator = 0;
1116                                 race_laptime = time; // valid
1117                         }
1118                         break;
1119
1120                 case RACE_NET_CHECKPOINT_CLEAR:
1121                         race_laptime = 0;
1122                         race_checkpointtime = 0;
1123                         break;
1124
1125                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1126                         race_laptime = ReadCoord();
1127                         race_checkpointtime = -99999;
1128                         // fall through
1129                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1130                         race_nextcheckpoint = ReadByte();
1131
1132                         race_nextbesttime = ReadInt24_t();
1133                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1134                                 race_mybesttime = ReadInt24_t();
1135                         string newname = ReadString();
1136                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1137                         {
1138                                 race_nextbesttime = race_mybesttime;
1139                                 race_mybesttime = 0;
1140                                 strcpy(race_nextbestname, "");
1141                         }
1142                         else
1143                                 strcpy(race_nextbestname, newname);
1144                         break;
1145
1146                 case RACE_NET_CHECKPOINT_HIT_RACE:
1147                         race_mycheckpoint = ReadByte();
1148                         race_mycheckpointtime = time;
1149                         race_mycheckpointdelta = ReadInt24_t();
1150                         race_mycheckpointlapsdelta = ReadByte();
1151                         if(race_mycheckpointlapsdelta >= 128)
1152                                 race_mycheckpointlapsdelta -= 256;
1153                         int who = ReadByte();
1154                         if(who)
1155                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1156                         else
1157                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1158                         break;
1159
1160                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1161                         race_othercheckpoint = ReadByte();
1162                         race_othercheckpointtime = time;
1163                         race_othercheckpointdelta = ReadInt24_t();
1164                         race_othercheckpointlapsdelta = ReadByte();
1165                         if(race_othercheckpointlapsdelta >= 128)
1166                                 race_othercheckpointlapsdelta -= 256;
1167                         int what = ReadByte();
1168                         if(what)
1169                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1170                         else
1171                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1172                         break;
1173
1174                 case RACE_NET_PENALTY_RACE:
1175                 case RACE_NET_PENALTY_QUALIFYING:
1176                         race_penaltyeventtime = time;
1177                         race_penaltytime = ReadShort();
1178                         string reason = ReadString();
1179                         if (reason == "missing a checkpoint")
1180                                 reason = _("missing a checkpoint");
1181                         strcpy(race_penaltyreason, reason);
1182                         if (b == RACE_NET_PENALTY_QUALIFYING)
1183                                 race_penaltyaccumulator += race_penaltytime;
1184                         break;
1185
1186                 case RACE_NET_SERVER_RECORD:
1187                         race_server_record = ReadInt24_t();
1188                         break;
1189                 case RACE_NET_SPEED_AWARD:
1190                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1191                         strcpy(race_speedaward_holder, ReadString());
1192                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1193                         break;
1194                 case RACE_NET_SPEED_AWARD_BEST:
1195                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1196                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1197                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1198                         break;
1199                 case RACE_NET_RANKINGS_CNT:
1200                         RANKINGS_DISPLAY_CNT = ReadByte();
1201                         break;
1202                 case RACE_NET_SERVER_RANKINGS:
1203                         float prevpos, del;
1204                         int pos = ReadShort();
1205                         prevpos = ReadShort();
1206                         del = ReadShort();
1207
1208                         // move other rankings out of the way
1209                         int i;
1210                         if (prevpos) {
1211                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1212                                 for (i=m-1; i>pos-1; --i) {
1213                                         grecordtime[i] = grecordtime[i-1];
1214                                         strcpy(grecordholder[i], grecordholder[i-1]);
1215                                 }
1216                         } else if (del) { // a record has been deleted by the admin
1217                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1218                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1219                                                 grecordtime[i] = 0;
1220                                                 strfree(grecordholder[i]);
1221                                         }
1222                                         else {
1223                                                 grecordtime[i] = grecordtime[i+1];
1224                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1225                                         }
1226                                 }
1227                         } else { // player has no ranked record yet
1228                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1229                                         grecordtime[i] = grecordtime[i-1];
1230                                         strcpy(grecordholder[i], grecordholder[i-1]);
1231                                 }
1232                         }
1233
1234                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1235                                 // kick off the player who fell from the last displayed position
1236                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1237                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1238                         }
1239
1240                         // store new ranking
1241                         strcpy(grecordholder[pos-1], ReadString());
1242                         grecordtime[pos-1] = ReadInt24_t();
1243                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1244                                 race_myrank = pos;
1245                         break;
1246                 case RACE_NET_SERVER_STATUS:
1247                         race_status = ReadShort();
1248                         strcpy(race_status_name, ReadString());
1249         }
1250         return true;
1251 }
1252
1253 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1254 {
1255         teamnagger = 1;
1256         return true;
1257 }
1258
1259 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1260 {
1261         int i = ReadByte();
1262         int pi = ReadShort();
1263         int pl = ReadByte();
1264         int ml = ReadByte();
1265         return = true;
1266         entity e = playerslots[i];
1267         if (!e) return;
1268         e.ping = pi;
1269         e.ping_packetloss = pl / 255.0;
1270         e.ping_movementloss = ml / 255.0;
1271 }
1272
1273 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1274 {
1275         int weapon_id = ReadByte();
1276         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1277         complain_weapon_type = ReadByte();
1278         return = true;
1279
1280         complain_weapon_time = time;
1281         weapontime = time; // ping the weapon panel
1282
1283         switch(complain_weapon_type)
1284         {
1285                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1286                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1287                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1288         }
1289 }
1290
1291 string _getcommandkey(string cmd_name, string command, bool forcename)
1292 {
1293         string keys;
1294         float n, j, k, l = 0;
1295
1296         if (!autocvar_hud_showbinds)
1297                 return cmd_name;
1298
1299         keys = db_get(binddb, command);
1300         if (keys == "")
1301         {
1302                 bool joy_active = cvar("joy_active");
1303                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1304                 for(j = 0; j < n; ++j)
1305                 {
1306                         k = stof(argv(j));
1307                         if(k != -1)
1308                         {
1309                                 string key = keynumtostring(k);
1310                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1311                                         continue;
1312
1313                                 key = translate_key(key);
1314
1315                                 if (keys == "")
1316                                         keys = key;
1317                                 else
1318                                         keys = strcat(keys, ", ", key);
1319
1320                                 ++l;
1321                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1322                                         break;
1323                         }
1324
1325                 }
1326                 if (keys == "")
1327                         keys = "NO_KEY";
1328                 db_put(binddb, command, keys);
1329         }
1330
1331         if (keys == "NO_KEY") {
1332                 if (autocvar_hud_showbinds > 1)
1333                         return sprintf(_("%s (not bound)"), cmd_name);
1334                 else
1335                         return cmd_name;
1336         }
1337         else if (autocvar_hud_showbinds > 1 || forcename)
1338                 return sprintf("%s (%s)", cmd_name, keys);
1339         else
1340                 return keys;
1341 }
1342
1343 /** engine callback */
1344 void URI_Get_Callback(int id, int status, string data)
1345 {
1346         TC(int, id); TC(int, status);
1347         if(url_URI_Get_Callback(id, status, data))
1348         {
1349                 // handled
1350         }
1351         else if (id == URI_GET_DISCARD)
1352         {
1353                 // discard
1354         }
1355         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1356         {
1357                 // sv_cmd curl
1358                 Curl_URI_Get_Callback(id, status, data);
1359         }
1360         else
1361         {
1362                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1363         }
1364 }