qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/centerprint.qh"
  15 #include "hud/panel/scoreboard.qh"
  16 #include "hud/panel/quickmenu.qh"
  17 #include "shownames.qh"
  18 #include "view.qh"
  19 #include <common/t_items.qh>
  20 #include "weapons/projectile.qh"
  21 #include <common/deathtypes/all.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/minigames/cl_minigames.qh>
  25 #include <common/minigames/cl_minigames_hud.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/scores.qh>
  29 #include <common/mapobjects/_mod.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  42 {
  43         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  44         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  45 }
  46
  47 void draw_cursor_normal(vector pos, vector col, float a)
  48 {
  49         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  50 }
  51
  52 void LoadMenuSkinValues()
  53 {
  54         int fh = -1;
  55         if(cvar_string("menu_skin") != "")
  56         {
  57                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  58                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  59         }
  60         if(fh < 0 && cvar_defstring("menu_skin") != "")
  61         {
  62                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  63                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  64                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  65         }
  66         if(fh < 0)
  67         {
  68                 draw_currentSkin = "gfx/menu/default";
  69                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  70         }
  71
  72         draw_currentSkin = strzone(draw_currentSkin);
  73
  74         if(fh >= 0)
  75         {
  76                 string s;
  77                 while((s = fgets(fh)))
  78                 {
  79                         int n = tokenize_console(s);
  80                         if (n < 2)
  81                                 continue;
  82                         if(substring(argv(0), 0, 2) == "//")
  83                                 continue;
  84                         if(argv(0) == "SIZE_CURSOR")
  85                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                         else if(argv(0) == "OFFSET_CURSOR")
  87                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  88                 }
  89                 fclose(fh);
  90         }
  91 }
  92
  93 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  94 // Useful for precaching things
  95
  96 void CSQC_Init()
  97 {
  98         prvm_language = strzone(cvar_string("prvm_language"));
  99
 100 #ifdef WATERMARK
 101         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 102 #endif
 103
 104         {
 105                 int i = 0;
 106                 for ( ; i < 255; ++i)
 107                         if (getplayerkeyvalue(i, "viewentity") == "")
 108                                 break;
 109                 maxclients = i;
 110         }
 111
 112         // needs to be done so early because of the constants they create
 113         static_init();
 114         static_init_late();
 115         static_init_precache();
 116
 117         binddb = db_create();
 118         tempdb = db_create();
 119         ClientProgsDB = db_load("client.db");
 120
 121         draw_endBoldFont();
 122
 123         //registercommand("hud_configure");
 124         //registercommand("hud_save");
 125         //registercommand("menu_action");
 126
 127         ConsoleCommand_macro_init();
 128
 129         registercvar("hud_usecsqc", "1");
 130         registercvar("scoreboard_columns", "default");
 131
 132         registercvar("cl_nade_type", "3");
 133         registercvar("cl_pokenade_type", "zombie");
 134
 135         registercvar("cl_jumpspeedcap_min", "");
 136         registercvar("cl_jumpspeedcap_max", "");
 137
 138         registercvar("cl_shootfromfixedorigin", "");
 139
 140         registercvar("cl_multijump", "-1");
 141
 142         registercvar("cl_dodging", "0");
 143
 144         registercvar("cl_spawn_near_teammate", "1");
 145
 146         registercvar("cl_weapon_switch_reload", "1");
 147         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 148
 149         registercvar("cl_allow_uidranking", "1");
 150
 151         if(autocvar_cl_lockview)
 152                 cvar_set("cl_lockview", "0");
 153
 154         gametype = NULL;
 155
 156         postinit = false;
 157
 158         calledhooks = 0;
 159
 160         teams = Sort_Spawn();
 161         players = Sort_Spawn();
 162
 163         GetTeam(NUM_SPECTATOR, true); // add specs first
 164
 165         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 166                 weapon_accuracy[w] = -1;
 167
 168         // precaches
 169
 170         if(autocvar_cl_reticle)
 171         {
 172                 precache_pic("gfx/reticle_normal");
 173                 // weapon reticles are precached in weapon files
 174         }
 175
 176         {
 177                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 178                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179                 shortmapname = mi_shortname;
 180
 181                 if (precache_pic(minimapname) == "")
 182                 {
 183                         // but maybe we have a non-clever minimap
 184                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                         if (precache_pic(minimapname) == "")
 186                                 minimapname = ""; // FAIL
 187                         else
 188                                 get_mi_min_max_texcoords(0); // load new texcoords
 189                 }
 190
 191                 mi_center = (mi_min + mi_max) * 0.5;
 192                 mi_scale = mi_max - mi_min;
 193                 minimapname = strzone(minimapname);
 194         }
 195
 196         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 197         LoadMenuSkinValues();
 198 }
 199
 200 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 201 void Shutdown()
 202 {
 203         WarpZone_Shutdown();
 204
 205         delete(teams);
 206         delete(players);
 207         db_close(binddb);
 208         db_close(tempdb);
 209         if(autocvar_cl_db_saveasdump)
 210                 db_dump(ClientProgsDB, "client.db");
 211         else
 212                 db_save(ClientProgsDB, "client.db");
 213         db_close(ClientProgsDB);
 214
 215         if(camera_active)
 216                 cvar_set("chase_active",ftos(chase_active_backup));
 217
 218         // unset the event chasecam's chase_active
 219         if(autocvar_chase_active < 0)
 220                 cvar_set("chase_active", "0");
 221
 222         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 223
 224         if (!isdemo())
 225         {
 226                 if (!(calledhooks & HOOK_START))
 227                         localcmd("\n_cl_hook_gamestart nop\n");
 228                 if (!(calledhooks & HOOK_END))
 229                         localcmd("\ncl_hook_gameend\n");
 230         }
 231
 232         localcmd("\ncl_hook_shutdown\n");
 233
 234         localcmd("\n-button12\n");
 235
 236         deactivate_minigame();
 237         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 238
 239         ReplicateVars(true); // destroy
 240 }
 241
 242 .float has_team;
 243 bool SetTeam(entity o, int Team)
 244 {
 245         TC(int, Team);
 246         //devassert_once(Team);
 247         entity tm;
 248         if(teamplay)
 249         {
 250                 switch(Team)
 251                 {
 252                         case -1:
 253                         case NUM_TEAM_1:
 254                         case NUM_TEAM_2:
 255                         case NUM_TEAM_3:
 256                         case NUM_TEAM_4:
 257                                 break;
 258                         default:
 259                                 if(GetTeam(Team, false) == NULL)
 260                                 {
 261                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 262                                         Team = NUM_SPECTATOR;
 263                                 }
 264                                 break;
 265                 }
 266         }
 267         else
 268         {
 269                 switch(Team)
 270                 {
 271                         case -1:
 272                         case 0:
 273                                 break;
 274                         default:
 275                                 if(GetTeam(Team, false) == NULL)
 276                                 {
 277                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 278                                         Team = NUM_SPECTATOR;
 279                                 }
 280                                 break;
 281                 }
 282         }
 283         if(Team == -1) // leave
 284         {
 285                 if(o.has_team)
 286                 {
 287                         tm = GetTeam(o.team, false);
 288                         tm.team_size -= 1;
 289                         o.has_team = 0;
 290                         return true;
 291                 }
 292         }
 293         else
 294         {
 295                 if (!o.has_team)
 296                 {
 297                         o.team = Team;
 298                         tm = GetTeam(Team, true);
 299                         tm.team_size += 1;
 300                         o.has_team = 1;
 301                         return true;
 302                 }
 303                 else if(Team != o.team)
 304                 {
 305                         tm = GetTeam(o.team, false);
 306                         tm.team_size -= 1;
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         return true;
 311                 }
 312         }
 313         return false;
 314 }
 315
 316 void Playerchecker_Think(entity this)
 317 {
 318         int i;
 319         entity e;
 320         for(i = 0; i < maxclients; ++i)
 321         {
 322                 e = playerslots[i];
 323                 if(entcs_GetName(i) == "")
 324                 {
 325                         if(e.sort_prev)
 326                         {
 327                                 // player disconnected
 328                                 SetTeam(e, -1);
 329                                 RemovePlayer(e);
 330                                 e.sort_prev = NULL;
 331                                 //e.gotscores = 0;
 332                         }
 333                 }
 334                 else
 335                 {
 336                         if (!e.sort_prev)
 337                         {
 338                                 // player connected
 339                                 if (!e)
 340                                 {
 341                                         playerslots[i] = e = new_pure(playerslot);
 342                                 }
 343                                 e.sv_entnum = i;
 344                                 e.ping = 0;
 345                                 e.ping_packetloss = 0;
 346                                 e.ping_movementloss = 0;
 347                                 //e.gotscores = 0; // we might already have the scores...
 348                                 int t = entcs_GetScoreTeam(i);
 349                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 350                                 RegisterPlayer(e);
 351                                 Scoreboard_UpdatePlayerPos(e);
 352                         }
 353                 }
 354         }
 355         this.nextthink = time + 0.2;
 356 }
 357
 358 void PostInit()
 359 {
 360         entity playerchecker = new_pure(playerchecker);
 361         setthink(playerchecker, Playerchecker_Think);
 362         playerchecker.nextthink = time + 0.2;
 363
 364         TrueAim_Init();
 365
 366         postinit = true;
 367 }
 368
 369 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 370 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 371 // All keys are in ascii.
 372 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 373 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 374 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 375 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 376 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 377 {
 378         TC(int, bInputType);
 379         bool override = false;
 380         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 381         if (override)
 382                 return true;
 383
 384         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 385
 386         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 387
 388         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 389
 390         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 391
 392         if(override)
 393                 return true;
 394
 395         return false;
 396 }
 397
 398 // END REQUIRED CSQC FUNCTIONS
 399 // --------------------------------------------------------------------------
 400
 401 // --------------------------------------------------------------------------
 402 // BEGIN OPTIONAL CSQC FUNCTIONS
 403
 404 void Ent_RemovePlayerScore(entity this)
 405 {
 406         if(this.owner) {
 407                 SetTeam(this.owner, -1);
 408                 this.owner.gotscores = 0;
 409                 FOREACH(Scores, true, {
 410                         this.owner.(scores(it)) = 0; // clear all scores
 411                 });
 412         }
 413 }
 414
 415 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 416 {
 417         make_pure(this);
 418         entity o;
 419
 420         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 421         // (no I've never heard of M-x replace-string, sed, or anything like that)
 422         bool isNew = !this.owner; // workaround for DP bug
 423         int n = ReadByte()-1;
 424
 425 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 426         if(!isNew && n != this.sv_entnum)
 427         {
 428                 //print("A CSQC entity changed its owner!\n");
 429                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 430                 isNew = true;
 431                 Ent_Remove(this);
 432         }
 433 #endif
 434
 435         this.sv_entnum = n;
 436
 437         o = playerslots[this.sv_entnum];
 438         if (!o)
 439         {
 440                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 441         }
 442         this.owner = o;
 443         o.sv_entnum = this.sv_entnum;
 444         o.gotscores = 1;
 445
 446         //if (!o.sort_prev)
 447         //      RegisterPlayer(o);
 448         //playerchecker will do this for us later, if it has not already done so
 449
 450         int sf = ReadShort();
 451         int lf = ReadShort();
 452         FOREACH(Scores, true, {
 453                 int p = 1 << (i % 16);
 454                 if (sf & p)
 455                 {
 456                         if (lf & p)
 457                                 o.(scores(it)) = ReadInt24_t();
 458                         else
 459                                 o.(scores(it)) = ReadChar();
 460                 }
 461         });
 462
 463         return = true;
 464
 465         if(o.sort_prev)
 466                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 467
 468         this.entremove = Ent_RemovePlayerScore;
 469 }
 470
 471 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 472 {
 473         make_pure(this);
 474         int i;
 475
 476         this.team = ReadByte();
 477         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 478
 479 #if MAX_TEAMSCORE <= 8
 480         int sf = ReadByte();
 481         int lf = ReadByte();
 482 #else
 483         int sf = ReadShort();
 484         int lf = ReadShort();
 485 #endif
 486         for(i = 0; i < MAX_TEAMSCORE; ++i)
 487                 if(sf & BIT(i))
 488                 {
 489                         if(lf & BIT(i))
 490                                 o.(teamscores(i)) = ReadInt24_t();
 491                         else
 492                                 o.(teamscores(i)) = ReadChar();
 493                 }
 494
 495         return = true;
 496
 497         Scoreboard_UpdateTeamPos(o);
 498 }
 499
 500 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 501 {
 502         make_pure(this);
 503         float newspectatee_status;
 504
 505         int f = ReadByte();
 506
 507         scoreboard_showscores_force = (f & BIT(0));
 508
 509         if(f & BIT(1))
 510         {
 511                 newspectatee_status = ReadByte();
 512                 if(newspectatee_status == player_localnum + 1)
 513                         newspectatee_status = -1; // observing
 514         }
 515         else
 516                 newspectatee_status = 0;
 517
 518         spectatorbutton_zoom = (f & BIT(2));
 519
 520         if(f & BIT(4))
 521         {
 522                 num_spectators = ReadByte();
 523
 524                 float i, slot;
 525
 526                 for(i = 0; i < MAX_SPECTATORS; ++i)
 527                         spectatorlist[i] = 0; // reset list first
 528
 529                 for(i = 0; i < num_spectators; ++i)
 530                 {
 531                         slot = ReadByte();
 532                         spectatorlist[i] = slot - 1;
 533                 }
 534         }
 535
 536         return = true;
 537
 538         if(newspectatee_status != spectatee_status)
 539         {
 540                 // clear race stuff
 541                 race_laptime = 0;
 542                 race_checkpointtime = 0;
 543                 hud_dynamic_shake_factor = -1;
 544                 spectatee_status_changed_time = time;
 545         }
 546         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 547         {
 548                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 549                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 550                 )
 551                         prev_p_health = -1;
 552                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 553                         prev_health = -1;
 554         }
 555         spectatee_status = newspectatee_status;
 556
 557         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 558 }
 559
 560 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 561 {
 562         make_pure(this);
 563         int i, j, b, f;
 564
 565         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 566
 567         if(!(nags & BIT(2)))
 568         {
 569                 strfree(vote_called_vote);
 570                 vote_active = 0;
 571         }
 572         else
 573         {
 574                 vote_active = 1;
 575         }
 576
 577         if(nags & BIT(6))
 578         {
 579                 vote_yescount = ReadByte();
 580                 vote_nocount = ReadByte();
 581                 vote_needed = ReadByte();
 582                 vote_highlighted = ReadChar();
 583         }
 584
 585         if(nags & BIT(7))
 586         {
 587                 strcpy(vote_called_vote, ReadString());
 588         }
 589
 590         if(nags & 1)
 591         {
 592                 for(j = 0; j < maxclients; ++j)
 593                         if(playerslots[j])
 594                                 playerslots[j].ready = true;
 595                 for(i = 1; i <= maxclients; i += 8)
 596                 {
 597                         f = ReadByte();
 598                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 599                                 if (!(f & b))
 600                                         if(playerslots[j])
 601                                                 playerslots[j].ready = false;
 602                 }
 603         }
 604
 605         return = true;
 606
 607         ready_waiting = (nags & BIT(0));
 608         ready_waiting_for_me = (nags & BIT(1));
 609         vote_waiting = (nags & BIT(2));
 610         vote_waiting_for_me = (nags & BIT(3));
 611         warmup_stage = (nags & BIT(4));
 612 }
 613
 614 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 615 {
 616         make_pure(this);
 617         int sf = 0;
 618         serialize(byte, 0, sf);
 619         if (sf & 1) {
 620                 for (int j = 0; j < maxclients; ++j) {
 621                         if (playerslots[j]) {
 622                                 playerslots[j].eliminated = true;
 623                         }
 624                 }
 625                 for (int i = 1; i <= maxclients; i += 8) {
 626                         int f = 0;
 627                         serialize(byte, 0, f);
 628                         for (int b = 0; b < 8; ++b) {
 629                                 if (f & BIT(b)) continue;
 630                                 int j = i - 1 + b;
 631                                 if (playerslots[j]) {
 632                                         playerslots[j].eliminated = false;
 633                                 }
 634                         }
 635                 }
 636         }
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 641 {
 642         make_pure(this);
 643         prandom_debug();
 644         float s = ReadShort();
 645         psrandom(s);
 646         return true;
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 650 {
 651         make_pure(this);
 652         int sf = ReadInt24_t();
 653         if (sf == 0) {
 654                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 655                         weapon_accuracy[w] = -1;
 656                 return true;
 657         }
 658
 659         int f = 1;
 660         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 661                 if (sf & f) {
 662                         int b = ReadByte();
 663                         if (b == 0)
 664                                 weapon_accuracy[w] = -1;
 665                         else if (b == 255)
 666                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 667                         else
 668                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 669                 }
 670                 f = (f == 0x800000) ? 1 : f * 2;
 671         }
 672         return true;
 673 }
 674
 675 void Spawn_Draw(entity this)
 676 {
 677         if(this.alpha <= 0)
 678                 return;
 679
 680         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 681 }
 682
 683 void Spawn_PreDraw(entity this)
 684 {
 685         float alph;
 686         vector org = getpropertyvec(VF_ORIGIN);
 687         if(this.fade_start)
 688         {
 689                 if(vdist(org - this.origin, >, this.fade_end))
 690                         alph = 0; // save on some processing
 691                 else if(vdist(org - this.origin, <, this.fade_start))
 692                         alph = 1; // more processing saved
 693                 else
 694                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 695         }
 696         else
 697                 alph = 1;
 698         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 699         this.alpha = alph;
 700         if(alph <= 0)
 701                 this.drawmask = 0;
 702         else
 703                 this.drawmask = MASK_NORMAL;
 704 }
 705
 706 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 707 {
 708         float teamnum = (ReadByte() - 1);
 709         vector spn_origin = ReadVector();
 710
 711         this.team = (teamnum + 1);
 712
 713         //if(is_new)
 714         //{
 715                 this.origin = spn_origin;
 716                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 717                 //droptofloor();
 718
 719                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 720                 {
 721                         this.mdl = "models/spawnpoint.md3";
 722                         this.colormod = Team_ColorRGB(teamnum);
 723                         precache_model(this.mdl);
 724                         setmodel(this, this.mdl);
 725                         this.drawmask = MASK_NORMAL;
 726                         //this.move_movetype = MOVETYPE_NOCLIP;
 727                         //this.draw = Spawn_Draw;
 728                         IL_PUSH(g_drawables, this);
 729                 }*/
 730                 if(autocvar_cl_spawn_point_particles)
 731                 {
 732                         if(teamplay)
 733                         {
 734                                 switch(teamnum)
 735                                 {
 736                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 737                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 738                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 739                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 740                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 741                                 }
 742                         }
 743                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 744
 745                         this.draw = Spawn_Draw;
 746                         if (is_new) IL_PUSH(g_drawables, this);
 747                         setpredraw(this, Spawn_PreDraw);
 748                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 749                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 750                 }
 751         //}
 752
 753         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 754         return true;
 755 }
 756
 757 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 758 {
 759         // If entnum is 0, ONLY do the local spawn actions
 760         // this way the server can disable the sending of
 761         // spawn origin or such to clients if wanted.
 762         float entnum = ReadByte();
 763
 764         if(entnum)
 765         {
 766                 this.origin = ReadVector();
 767
 768                 if(is_new)
 769                 {
 770                         float teamnum = entcs_GetTeam(entnum - 1);
 771
 772                         if(autocvar_cl_spawn_event_particles)
 773                         {
 774                                 switch(teamnum)
 775                                 {
 776                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 777                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 778                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 779                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 780                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 781                                 }
 782                         }
 783                         if(autocvar_cl_spawn_event_sound)
 784                         {
 785                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 786                         }
 787                 }
 788         }
 789         return = true;
 790
 791         // local spawn actions
 792         if(is_new && (!entnum || (entnum == player_localentnum)))
 793         {
 794                 zoomin_effect = 1;
 795                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 796
 797                 if(autocvar_cl_unpress_zoom_on_spawn)
 798                 {
 799                         localcmd("-zoom\n");
 800                         button_zoom = false;
 801                 }
 802                 HUD_Radar_Hide_Maximized();
 803         }
 804         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 805 }
 806
 807 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 808 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 809 void CSQC_Ent_Update(entity this, bool isnew)
 810 {
 811         this.sourceLoc = __FILE__":"STR(__LINE__);
 812         int t = ReadByte();
 813
 814         // set up the "time" global for received entities to be correct for interpolation purposes
 815         float savetime = time;
 816         if(servertime)
 817         {
 818                 time = servertime;
 819         }
 820         else
 821         {
 822                 serverprevtime = time;
 823                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 824                 time = serverprevtime + serverdeltatime;
 825         }
 826
 827 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 828         if (this.enttype)
 829         {
 830                 if (t != this.enttype || isnew)
 831                 {
 832                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 833                         Ent_Remove(this);
 834                         clearentity(this);
 835                         isnew = true;
 836                 }
 837         }
 838         else
 839         {
 840                 if (!isnew)
 841                 {
 842                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 843                         isnew = true;
 844                 }
 845         }
 846 #endif
 847         this.enttype = t;
 848         bool done = false;
 849         FOREACH(LinkedEntities, it.m_id == t, {
 850                 if (isnew) this.classname = it.netname;
 851                 if (autocvar_developer_csqcentities)
 852             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 853                 done = it.m_read(this, NULL, isnew);
 854                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 855                 break;
 856         });
 857         time = savetime;
 858         if (!done)
 859         {
 860                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 861         }
 862 }
 863
 864 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 865 // used when an entity changes its type. For an entity that someone interacts
 866 // with others, make sure it can no longer do so.
 867 void Ent_Remove(entity this)
 868 {
 869         if(this.entremove) this.entremove(this);
 870
 871         if(this.skeletonindex)
 872         {
 873                 skel_delete(this.skeletonindex);
 874                 this.skeletonindex = 0;
 875         }
 876
 877         if(this.snd_looping > 0)
 878         {
 879                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 880                 this.snd_looping = 0;
 881         }
 882
 883         this.enttype = 0;
 884         this.classname = "";
 885         this.draw = func_null;
 886         this.entremove = func_null;
 887         // TODO possibly set more stuff to defaults
 888 }
 889 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 890 void CSQC_Ent_Remove(entity this)
 891 {
 892         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 893         if (wasfreed(this))
 894         {
 895                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 896                 return;
 897         }
 898         if (this.enttype) Ent_Remove(this);
 899         delete(this);
 900 }
 901
 902 void Gamemode_Init()
 903 {
 904         if (!isdemo())
 905         {
 906                 if(!(calledhooks & HOOK_START))
 907                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 908                 calledhooks |= HOOK_START;
 909         }
 910 }
 911 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 912 void CSQC_Parse_StuffCmd(string strMessage)
 913 {
 914         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 915         localcmd(strMessage);
 916 }
 917 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 918 void CSQC_Parse_Print(string strMessage)
 919 {
 920         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 921         print(ColorTranslateRGB(strMessage));
 922 }
 923
 924 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 925 void CSQC_Parse_CenterPrint(string strMessage)
 926 {
 927         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 928         centerprint_AddStandard(strMessage);
 929 }
 930
 931 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 932 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 933 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 934 bool CSQC_Parse_TempEntity()
 935 {
 936         // Acquire TE ID
 937         int nTEID = ReadByte();
 938
 939         FOREACH(TempEntities, it.m_id == nTEID, {
 940                 if (autocvar_developer_csqcentities)
 941                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 942                 return it.m_read(NULL, NULL, true);
 943         });
 944
 945         if (autocvar_developer_csqcentities)
 946                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 947
 948         // No special logic for this temporary entity; return 0 so the engine can handle it
 949         return false;
 950 }
 951
 952 string forcefog;
 953 void Fog_Force()
 954 {
 955         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 956                 localcmd("\nr_drawfog 0\n");
 957         else if (forcefog != "")
 958                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 959 }
 960
 961 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 962 {
 963         make_pure(this);
 964         gametype = ReadRegistered(Gametypes);
 965         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 966         HUD_ModIcons_SetFunc();
 967         FOREACH(Scores, true, {
 968                 strcpy(scores_label(it), ReadString());
 969                 scores_flags(it) = ReadByte();
 970         });
 971         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 972         {
 973                 strcpy(teamscores_label(i), ReadString());
 974                 teamscores_flags(i) = ReadByte();
 975         }
 976         return = true;
 977         Scoreboard_InitScores();
 978         Gamemode_Init();
 979 }
 980
 981 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 982 {
 983         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 984
 985         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 988         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 992         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 993
 994         strcpy(forcefog, ReadString());
 995
 996         armorblockpercent = ReadByte() / 255.0;
 997         damagepush_speedfactor = ReadByte() / 255.0;
 998
 999         serverflags = ReadByte();
1000
1001         g_trueaim_minrange = ReadCoord();
1002
1003         return = true;
1004
1005         MUTATOR_CALLHOOK(Ent_Init);
1006
1007         if (!postinit) PostInit();
1008 }
1009
1010 float GetSpeedUnitFactor(int speed_unit)
1011 {
1012         switch(speed_unit)
1013         {
1014                 default:
1015                 case 1:
1016                         return 1.0;
1017                 case 2:
1018                         return 0.0254;
1019                 case 3:
1020                         return 0.0254 * 3.6;
1021                 case 4:
1022                         return 0.0254 * 3.6 * 0.6213711922;
1023                 case 5:
1024                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1025         }
1026 }
1027
1028 string GetSpeedUnit(int speed_unit)
1029 {
1030         switch(speed_unit)
1031         {
1032                 default:
1033                 case 1:
1034                         return _(" qu/s");
1035                 case 2:
1036                         return _(" m/s");
1037                 case 3:
1038                         return _(" km/h");
1039                 case 4:
1040                         return _(" mph");
1041                 case 5:
1042                         return _(" knots");
1043         }
1044 }
1045
1046 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1047 {
1048         int b = ReadByte();
1049
1050         switch (b)
1051         {
1052                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1053                         race_checkpoint = ReadByte();
1054                         race_time = ReadInt24_t();
1055                         race_previousbesttime = ReadInt24_t();
1056                         race_mypreviousbesttime = ReadInt24_t();
1057                         string pbestname = ReadString();
1058                         if(autocvar_cl_race_cptimes_onlyself)
1059                         {
1060                                 race_previousbesttime = race_mypreviousbesttime;
1061                                 race_mypreviousbesttime = 0;
1062                                 strcpy(race_previousbestname, "");
1063                         }
1064                         else
1065                                 strcpy(race_previousbestname, pbestname);
1066
1067                         race_checkpointtime = time;
1068
1069                         if(race_checkpoint == 0 || race_checkpoint == 254)
1070                         {
1071                                 race_penaltyaccumulator = 0;
1072                                 race_laptime = time; // valid
1073                         }
1074                         break;
1075
1076                 case RACE_NET_CHECKPOINT_CLEAR:
1077                         race_laptime = 0;
1078                         race_checkpointtime = 0;
1079                         break;
1080
1081                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1082                         race_laptime = ReadCoord();
1083                         race_checkpointtime = -99999;
1084                         // fall through
1085                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1086                         race_nextcheckpoint = ReadByte();
1087
1088                         race_nextbesttime = ReadInt24_t();
1089                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1090                                 race_mybesttime = ReadInt24_t();
1091                         string newname = ReadString();
1092                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1093                         {
1094                                 race_nextbesttime = race_mybesttime;
1095                                 race_mybesttime = 0;
1096                                 strcpy(race_nextbestname, "");
1097                         }
1098                         else
1099                                 strcpy(race_nextbestname, newname);
1100                         break;
1101
1102                 case RACE_NET_CHECKPOINT_HIT_RACE:
1103                         race_mycheckpoint = ReadByte();
1104                         race_mycheckpointtime = time;
1105                         race_mycheckpointdelta = ReadInt24_t();
1106                         race_mycheckpointlapsdelta = ReadByte();
1107                         if(race_mycheckpointlapsdelta >= 128)
1108                                 race_mycheckpointlapsdelta -= 256;
1109                         int who = ReadByte();
1110                         if(who)
1111                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1112                         else
1113                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1114                         break;
1115
1116                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1117                         race_othercheckpoint = ReadByte();
1118                         race_othercheckpointtime = time;
1119                         race_othercheckpointdelta = ReadInt24_t();
1120                         race_othercheckpointlapsdelta = ReadByte();
1121                         if(race_othercheckpointlapsdelta >= 128)
1122                                 race_othercheckpointlapsdelta -= 256;
1123                         int what = ReadByte();
1124                         if(what)
1125                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1126                         else
1127                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1128                         break;
1129
1130                 case RACE_NET_PENALTY_RACE:
1131                 case RACE_NET_PENALTY_QUALIFYING:
1132                         race_penaltyeventtime = time;
1133                         race_penaltytime = ReadShort();
1134                         string reason = ReadString();
1135                         if (reason == "missing a checkpoint")
1136                                 reason = _("missing a checkpoint");
1137                         strcpy(race_penaltyreason, reason);
1138                         if (b == RACE_NET_PENALTY_QUALIFYING)
1139                                 race_penaltyaccumulator += race_penaltytime;
1140                         break;
1141
1142                 case RACE_NET_SERVER_RECORD:
1143                         race_server_record = ReadInt24_t();
1144                         break;
1145                 case RACE_NET_SPEED_AWARD:
1146                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1147                         strcpy(race_speedaward_holder, ReadString());
1148                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1149                         break;
1150                 case RACE_NET_SPEED_AWARD_BEST:
1151                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1152                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1153                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1154                         break;
1155                 case RACE_NET_RANKINGS_CNT:
1156                         RANKINGS_DISPLAY_CNT = ReadByte();
1157                         break;
1158                 case RACE_NET_SERVER_RANKINGS:
1159                         float prevpos, del;
1160                         int pos = ReadShort();
1161                         prevpos = ReadShort();
1162                         del = ReadShort();
1163
1164                         // move other rankings out of the way
1165                         int i;
1166                         if (prevpos) {
1167                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1168                                 for (i=m-1; i>pos-1; --i) {
1169                                         grecordtime[i] = grecordtime[i-1];
1170                                         strcpy(grecordholder[i], grecordholder[i-1]);
1171                                 }
1172                         } else if (del) { // a record has been deleted by the admin
1173                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1174                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1175                                                 grecordtime[i] = 0;
1176                                                 strfree(grecordholder[i]);
1177                                         }
1178                                         else {
1179                                                 grecordtime[i] = grecordtime[i+1];
1180                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1181                                         }
1182                                 }
1183                         } else { // player has no ranked record yet
1184                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1185                                         grecordtime[i] = grecordtime[i-1];
1186                                         strcpy(grecordholder[i], grecordholder[i-1]);
1187                                 }
1188                         }
1189
1190                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1191                                 // kick off the player who fell from the last displayed position
1192                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1193                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1194                         }
1195
1196                         // store new ranking
1197                         strcpy(grecordholder[pos-1], ReadString());
1198                         grecordtime[pos-1] = ReadInt24_t();
1199                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1200                                 race_myrank = pos;
1201                         break;
1202                 case RACE_NET_SERVER_STATUS:
1203                         race_status = ReadShort();
1204                         strcpy(race_status_name, ReadString());
1205         }
1206         return true;
1207 }
1208
1209 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1210 {
1211         teamnagger = 1;
1212         return true;
1213 }
1214
1215 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1216 {
1217         int i = ReadByte();
1218         int pi = ReadShort();
1219         int pl = ReadByte();
1220         int ml = ReadByte();
1221         return = true;
1222         entity e = playerslots[i];
1223         if (!e) return;
1224         e.ping = pi;
1225         e.ping_packetloss = pl / 255.0;
1226         e.ping_movementloss = ml / 255.0;
1227 }
1228
1229 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1230 {
1231         int weapon_id = ReadByte();
1232         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1233         complain_weapon_type = ReadByte();
1234         return = true;
1235
1236         complain_weapon_time = time;
1237         weapontime = time; // ping the weapon panel
1238
1239         switch(complain_weapon_type)
1240         {
1241                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1242                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1243                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1244         }
1245 }
1246
1247 string _getcommandkey(string cmd_name, string command, bool forcename)
1248 {
1249         string keys;
1250         float n, j, k, l = 0;
1251
1252         if (!autocvar_hud_showbinds)
1253                 return cmd_name;
1254
1255         keys = db_get(binddb, command);
1256         if (keys == "")
1257         {
1258                 bool joy_active = cvar("joy_active");
1259                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1260                 for(j = 0; j < n; ++j)
1261                 {
1262                         k = stof(argv(j));
1263                         if(k != -1)
1264                         {
1265                                 string key = keynumtostring(k);
1266                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1267                                         continue;
1268
1269                                 key = translate_key(key);
1270
1271                                 if (keys == "")
1272                                         keys = key;
1273                                 else
1274                                         keys = strcat(keys, ", ", key);
1275
1276                                 ++l;
1277                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1278                                         break;
1279                         }
1280
1281                 }
1282                 if (keys == "")
1283                         keys = "NO_KEY";
1284                 db_put(binddb, command, keys);
1285         }
1286
1287         if (keys == "NO_KEY") {
1288                 if (autocvar_hud_showbinds > 1)
1289                         return sprintf(_("%s (not bound)"), cmd_name);
1290                 else
1291                         return cmd_name;
1292         }
1293         else if (autocvar_hud_showbinds > 1 || forcename)
1294                 return sprintf("%s (%s)", cmd_name, keys);
1295         else
1296                 return keys;
1297 }