qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "controlpoint.qh"
   4 #include "damage.qh"
   5 #include "effects.qh"
   6 #include "generator.qh"
   7 #include "gibs.qh"
   8 #include "hook.qh"
   9 #include "hud.qh"
  10 #include "hud_config.qh"
  11 #include "laser.qh"
  12 #include "mapvoting.qh"
  13 #include "modeleffects.qh"
  14 #include "mutators/events.qh"
  15 #include "particles.qh"
  16 #include "quickmenu.qh"
  17 #include "scoreboard.qh"
  18 #include "shownames.qh"
  19 #include "tuba.qh"
  20 #include "t_items.qh"
  21 #include "wall.qh"
  22 #include "weapons/projectile.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/items/all.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/minigames/cl_minigames.qh"
  27 #include "../common/minigames/cl_minigames_hud.qh"
  28 #include "../common/net_notice.qh"
  29 #include "../common/triggers/include.qh"
  30 #include "../common/turrets/cl_turrets.qh"
  31 #include "../common/vehicles/all.qh"
  32 #include "../lib/csqcmodel/cl_model.qh"
  33 #include "../lib/csqcmodel/interpolate.qh"
  34 #include "../lib/warpzone/client.qh"
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 entity clearentity_ent;
  41 void clearentity(entity e)
  42 {
  43         if (!clearentity_ent)
  44         {
  45                 clearentity_ent = spawn();
  46                 clearentity_ent.classname = "clearentity";
  47         }
  48         int n = e.entnum;
  49         copyentity(clearentity_ent, e);
  50         e.entnum = n;
  51 }
  52
  53 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  54 void menu_show_error()
  55 {
  56         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  57 }
  58
  59 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  60 // Useful for precaching things
  61
  62 void menu_sub_null()
  63 {
  64 }
  65
  66 void draw_null(entity this) { }
  67
  68 string forcefog;
  69 void ConsoleCommand_macro_init();
  70 void CSQC_Init(void)
  71 {
  72         prvm_language = strzone(cvar_string("prvm_language"));
  73
  74 #ifdef WATERMARK
  75         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  76 #endif
  77
  78         int i;
  79
  80         binddb = db_create();
  81         tempdb = db_create();
  82         ClientProgsDB = db_load("client.db");
  83         compressShortVector_init();
  84
  85         draw_endBoldFont();
  86         menu_visible = false;
  87         menu_show = menu_show_error;
  88         menu_action = func_null;
  89
  90         for(i = 0; i < 255; ++i)
  91                 if(getplayerkeyvalue(i, "viewentity") == "")
  92                         break;
  93         maxclients = i;
  94
  95         //registercommand("hud_configure");
  96         //registercommand("hud_save");
  97         //registercommand("menu_action");
  98
  99         ConsoleCommand_macro_init();
 100
 101         registercvar("hud_usecsqc", "1");
 102         registercvar("scoreboard_columns", "default");
 103
 104         registercvar("cl_nade_type", "3");
 105         registercvar("cl_pokenade_type", "zombie");
 106
 107         registercvar("cl_jumpspeedcap_min", "");
 108         registercvar("cl_jumpspeedcap_max", "");
 109
 110         registercvar("cl_multijump", "0");
 111
 112         registercvar("cl_spawn_near_teammate", "1");
 113
 114         gametype = 0;
 115
 116         // hud_fields uses strunzone on the titles!
 117         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 118                 hud_title[i] = strzone("(null)");
 119
 120         Cmd_HUD_SetFields(0);
 121
 122         postinit = false;
 123
 124         calledhooks = 0;
 125
 126         teams = Sort_Spawn();
 127         players = Sort_Spawn();
 128
 129         GetTeam(NUM_SPECTATOR, true); // add specs first
 130
 131         // needs to be done so early because of the constants they create
 132         static_init();
 133         static_init_late();
 134         static_init_precache();
 135
 136         // precaches
 137
 138         Projectile_Precache();
 139         Tuba_Precache();
 140
 141         if(autocvar_cl_reticle)
 142         {
 143                 precache_pic("gfx/reticle_normal");
 144                 // weapon reticles are precached in weapon files
 145         }
 146
 147         get_mi_min_max_texcoords(1); // try the CLEVER way first
 148         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 149         shortmapname = mi_shortname;
 150
 151         if(precache_pic(minimapname) == "")
 152         {
 153                 // but maybe we have a non-clever minimap
 154                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 155                 if(precache_pic(minimapname) == "")
 156                         minimapname = ""; // FAIL
 157                 else
 158                         get_mi_min_max_texcoords(0); // load new texcoords
 159         }
 160
 161         mi_center = (mi_min + mi_max) * 0.5;
 162         mi_scale = mi_max - mi_min;
 163         minimapname = strzone(minimapname);
 164
 165         WarpZone_Init();
 166
 167         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 168         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 169 }
 170
 171 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 172 void Shutdown(void)
 173 {
 174         WarpZone_Shutdown();
 175
 176         remove(teams);
 177         remove(players);
 178         db_close(binddb);
 179         db_close(tempdb);
 180         if(autocvar_cl_db_saveasdump)
 181                 db_dump(ClientProgsDB, "client.db");
 182         else
 183                 db_save(ClientProgsDB, "client.db");
 184         db_close(ClientProgsDB);
 185
 186         if(camera_active)
 187                 cvar_set("chase_active",ftos(chase_active_backup));
 188
 189         // unset the event chasecam's chase_active
 190         if(autocvar_chase_active < 0)
 191                 cvar_set("chase_active", "0");
 192
 193         if (!isdemo())
 194         {
 195                 if (!(calledhooks & HOOK_START))
 196                         localcmd("\n_cl_hook_gamestart nop\n");
 197                 if (!(calledhooks & HOOK_END))
 198                         localcmd("\ncl_hook_gameend\n");
 199         }
 200
 201         deactivate_minigame();
 202         HUD_MinigameMenu_Close();
 203 }
 204
 205 .float has_team;
 206 float SetTeam(entity o, int Team)
 207 {
 208         entity tm;
 209         if(teamplay)
 210         {
 211                 switch(Team)
 212                 {
 213                         case -1:
 214                         case NUM_TEAM_1:
 215                         case NUM_TEAM_2:
 216                         case NUM_TEAM_3:
 217                         case NUM_TEAM_4:
 218                                 break;
 219                         default:
 220                                 if(GetTeam(Team, false) == world)
 221                                 {
 222                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 223                                         Team = NUM_SPECTATOR;
 224                                 }
 225                                 break;
 226                 }
 227         }
 228         else
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case 0:
 234                                 break;
 235                         default:
 236                                 if(GetTeam(Team, false) == world)
 237                                 {
 238                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 239                                         Team = NUM_SPECTATOR;
 240                                 }
 241                                 break;
 242                 }
 243         }
 244         if(Team == -1) // leave
 245         {
 246                 if(o.has_team)
 247                 {
 248                         tm = GetTeam(o.team, false);
 249                         tm.team_size -= 1;
 250                         o.has_team = 0;
 251                         return true;
 252                 }
 253         }
 254         else
 255         {
 256                 if (!o.has_team)
 257                 {
 258                         o.team = Team;
 259                         tm = GetTeam(Team, true);
 260                         tm.team_size += 1;
 261                         o.has_team = 1;
 262                         return true;
 263                 }
 264                 else if(Team != o.team)
 265                 {
 266                         tm = GetTeam(o.team, false);
 267                         tm.team_size -= 1;
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         return true;
 272                 }
 273         }
 274         return false;
 275 }
 276
 277 void Playerchecker_Think()
 278 {SELFPARAM();
 279     int i;
 280         entity e;
 281         for(i = 0; i < maxclients; ++i)
 282         {
 283                 e = playerslots[i];
 284                 if(GetPlayerName(i) == "")
 285                 {
 286                         if(e.sort_prev)
 287                         {
 288                                 // player disconnected
 289                                 SetTeam(e, -1);
 290                                 RemovePlayer(e);
 291                                 e.sort_prev = world;
 292                                 //e.gotscores = 0;
 293                         }
 294                 }
 295                 else
 296                 {
 297                         if (!e.sort_prev)
 298                         {
 299                                 // player connected
 300                                 if (!e)
 301                                         playerslots[i] = e = spawn();
 302                                 e.sv_entnum = i;
 303                                 e.ping = 0;
 304                                 e.ping_packetloss = 0;
 305                                 e.ping_movementloss = 0;
 306                                 //e.gotscores = 0; // we might already have the scores...
 307                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 308                                 RegisterPlayer(e);
 309                                 HUD_UpdatePlayerPos(e);
 310                         }
 311                 }
 312         }
 313         self.nextthink = time + 0.2;
 314 }
 315
 316 void Porto_Init();
 317 void TrueAim_Init();
 318 void PostInit(void)
 319 {
 320         entity playerchecker;
 321         playerchecker = spawn();
 322         playerchecker.think = Playerchecker_Think;
 323         playerchecker.nextthink = time + 0.2;
 324
 325         Porto_Init();
 326         TrueAim_Init();
 327
 328         postinit = true;
 329 }
 330
 331 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 332 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 333 // All keys are in ascii.
 334 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 335 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 336 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 337 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 338 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 339 {
 340         float bSkipKey;
 341         bSkipKey = false;
 342
 343         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 344                 return true;
 345
 346         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 347                 return true;
 348
 349         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 350                 return true;
 351
 352         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 353                 return true;
 354
 355         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 356                 return true;
 357
 358         if(menu_visible && menu_action)
 359                 if(menu_action(bInputType, nPrimary, nSecondary))
 360                         return true;
 361
 362         return bSkipKey;
 363 }
 364
 365 // END REQUIRED CSQC FUNCTIONS
 366 // --------------------------------------------------------------------------
 367
 368 // --------------------------------------------------------------------------
 369 // BEGIN OPTIONAL CSQC FUNCTIONS
 370
 371 void Ent_RemoveEntCS()
 372 {SELFPARAM();
 373         entcs_receiver[self.sv_entnum] = NULL;
 374 }
 375 void Ent_ReadEntCS()
 376 {SELFPARAM();
 377         InterpolateOrigin_Undo();
 378         self.classname = "entcs_receiver";
 379         int sf = ReadByte();
 380
 381         if(sf & BIT(0))
 382                 self.sv_entnum = ReadByte();
 383         if (sf & BIT(1))
 384         {
 385                 self.origin_x = ReadShort();
 386                 self.origin_y = ReadShort();
 387                 self.origin_z = ReadShort();
 388                 setorigin(self, self.origin);
 389         }
 390         if (sf & BIT(2))
 391         {
 392                 self.angles_y = ReadByte() * 360.0 / 256;
 393                 self.angles_x = self.angles_z = 0;
 394         }
 395         if (sf & BIT(3))
 396                 self.healthvalue = ReadByte() * 10;
 397         if (sf & BIT(4))
 398                 self.armorvalue = ReadByte() * 10;
 399
 400         entcs_receiver[self.sv_entnum] = self;
 401         self.entremove = Ent_RemoveEntCS;
 402         self.iflags |= IFLAG_ORIGIN;
 403
 404         InterpolateOrigin_Note();
 405 }
 406
 407 void Ent_Remove();
 408
 409 void Ent_RemovePlayerScore()
 410 {SELFPARAM();
 411         if(self.owner) {
 412                 SetTeam(self.owner, -1);
 413                 self.owner.gotscores = 0;
 414                 for(int i = 0; i < MAX_SCORE; ++i) {
 415                         self.owner.(scores[i]) = 0; // clear all scores
 416                 }
 417         }
 418 }
 419
 420 void Ent_ReadPlayerScore()
 421 {SELFPARAM();
 422         int i, n;
 423         bool isNew;
 424         entity o;
 425
 426         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 427         // (no I've never heard of M-x replace-string, sed, or anything like that)
 428         isNew = !self.owner; // workaround for DP bug
 429         n = ReadByte()-1;
 430
 431 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 432         if(!isNew && n != self.sv_entnum)
 433         {
 434                 //print("A CSQC entity changed its owner!\n");
 435                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 436                 isNew = true;
 437                 Ent_Remove();
 438                 self.enttype = ENT_CLIENT_SCORES;
 439         }
 440 #endif
 441
 442         self.sv_entnum = n;
 443
 444         if (!(playerslots[self.sv_entnum]))
 445                 playerslots[self.sv_entnum] = spawn();
 446         o = self.owner = playerslots[self.sv_entnum];
 447         o.sv_entnum = self.sv_entnum;
 448         o.gotscores = 1;
 449
 450         //if (!o.sort_prev)
 451         //      RegisterPlayer(o);
 452         //playerchecker will do this for us later, if it has not already done so
 453
 454     int sf, lf;
 455 #if MAX_SCORE <= 8
 456         sf = ReadByte();
 457         lf = ReadByte();
 458 #else
 459         sf = ReadShort();
 460         lf = ReadShort();
 461 #endif
 462     int p;
 463         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 464                 if(sf & p)
 465                 {
 466                         if(lf & p)
 467                                 o.(scores[i]) = ReadInt24_t();
 468                         else
 469                                 o.(scores[i]) = ReadChar();
 470                 }
 471
 472         if(o.sort_prev)
 473                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 474
 475         self.entremove = Ent_RemovePlayerScore;
 476 }
 477
 478 void Ent_ReadTeamScore()
 479 {SELFPARAM();
 480         int i;
 481         entity o;
 482
 483         self.team = ReadByte();
 484         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 485
 486     int sf, lf;
 487 #if MAX_TEAMSCORE <= 8
 488         sf = ReadByte();
 489         lf = ReadByte();
 490 #else
 491         sf = ReadShort();
 492         lf = ReadShort();
 493 #endif
 494         int p;
 495         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 496                 if(sf & p)
 497                 {
 498                         if(lf & p)
 499                                 o.(teamscores[i]) = ReadInt24_t();
 500                         else
 501                                 o.(teamscores[i]) = ReadChar();
 502                 }
 503
 504         HUD_UpdateTeamPos(o);
 505 }
 506
 507 void Ent_ClientData()
 508 {
 509         float newspectatee_status;
 510
 511     int f = ReadByte();
 512
 513         scoreboard_showscores_force = (f & 1);
 514
 515         if(f & 2)
 516         {
 517                 newspectatee_status = ReadByte();
 518                 if(newspectatee_status == player_localnum + 1)
 519                         newspectatee_status = -1; // observing
 520         }
 521         else
 522                 newspectatee_status = 0;
 523
 524         spectatorbutton_zoom = (f & 4);
 525
 526         if(f & 8)
 527         {
 528                 angles_held_status = 1;
 529                 angles_held.x = ReadAngle();
 530                 angles_held.y = ReadAngle();
 531                 angles_held.z = 0;
 532         }
 533         else
 534                 angles_held_status = 0;
 535
 536         if(newspectatee_status != spectatee_status)
 537         {
 538                 // clear race stuff
 539                 race_laptime = 0;
 540                 race_checkpointtime = 0;
 541         }
 542         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 543         {
 544                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 545                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 546                 )
 547                         prev_p_health = -1;
 548                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 549                         prev_health = -1;
 550         }
 551         spectatee_status = newspectatee_status;
 552
 553         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 554 }
 555
 556 void Ent_Nagger()
 557 {
 558     int i, j, b, f;
 559
 560     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 561
 562         if(!(nags & BIT(2)))
 563         {
 564                 if(vote_called_vote)
 565                         strunzone(vote_called_vote);
 566                 vote_called_vote = string_null;
 567                 vote_active = 0;
 568         }
 569         else
 570         {
 571                 vote_active = 1;
 572         }
 573
 574         if(nags & BIT(6))
 575         {
 576                 vote_yescount = ReadByte();
 577                 vote_nocount = ReadByte();
 578                 vote_needed = ReadByte();
 579                 vote_highlighted = ReadChar();
 580         }
 581
 582         if(nags & BIT(7))
 583         {
 584                 if(vote_called_vote)
 585                         strunzone(vote_called_vote);
 586                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 587         }
 588
 589         if(nags & 1)
 590         {
 591                 for(j = 0; j < maxclients; ++j)
 592                         if(playerslots[j])
 593                                 playerslots[j].ready = 1;
 594                 for(i = 1; i <= maxclients; i += 8)
 595                 {
 596                         f = ReadByte();
 597                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 598                                 if (!(f & b))
 599                                         if(playerslots[j])
 600                                                 playerslots[j].ready = 0;
 601                 }
 602         }
 603
 604         ready_waiting = (nags & BIT(0));
 605         ready_waiting_for_me = (nags & BIT(1));
 606         vote_waiting = (nags & BIT(2));
 607         vote_waiting_for_me = (nags & BIT(3));
 608         warmup_stage = (nags & BIT(4));
 609 }
 610
 611 void Ent_EliminatedPlayers()
 612 {
 613     int i, j, b, f;
 614
 615     int sf = ReadByte();
 616         if(sf & 1)
 617         {
 618                 for(j = 0; j < maxclients; ++j)
 619                         if(playerslots[j])
 620                                 playerslots[j].eliminated = 1;
 621                 for(i = 1; i <= maxclients; i += 8)
 622                 {
 623                         f = ReadByte();
 624                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 625                                 if (!(f & b))
 626                                         if(playerslots[j])
 627                                                 playerslots[j].eliminated = 0;
 628                 }
 629         }
 630 }
 631
 632 void Ent_RandomSeed()
 633 {
 634         float s;
 635         prandom_debug();
 636         s = ReadShort();
 637         psrandom(s);
 638 }
 639
 640 void Ent_ReadAccuracy()
 641 {
 642     int sf = ReadInt24_t();
 643         if (sf == 0) {
 644                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 645                         weapon_accuracy[w] = -1;
 646                 return;
 647         }
 648
 649         int f = 1;
 650         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 651                 if (sf & f) {
 652             int b = ReadByte();
 653                         if (b == 0)
 654                                 weapon_accuracy[w] = -1;
 655                         else if (b == 255)
 656                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 657                         else
 658                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 659                 }
 660                 f = (f == 0x800000) ? 1 : f * 2;
 661         }
 662 }
 663
 664 void Spawn_Draw(entity this)
 665 {
 666         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 667 }
 668
 669 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 670 {SELFPARAM();
 671         float teamnum = (ReadByte() - 1);
 672         vector spn_origin;
 673         spn_origin.x = ReadShort();
 674         spn_origin.y = ReadShort();
 675         spn_origin.z = ReadShort();
 676
 677         //if(is_new)
 678         //{
 679                 self.origin = spn_origin;
 680                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 681                 //droptofloor();
 682
 683                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 684                 {
 685                         self.mdl = "models/spawnpoint.md3";
 686                         self.colormod = Team_ColorRGB(teamnum);
 687                         precache_model(self.mdl);
 688                         setmodel(self, self.mdl);
 689                         self.drawmask = MASK_NORMAL;
 690                         //self.movetype = MOVETYPE_NOCLIP;
 691                         //self.draw = Spawn_Draw;
 692                 }*/
 693                 if(autocvar_cl_spawn_point_particles)
 694                 {
 695                         if((serverflags & SERVERFLAG_TEAMPLAY))
 696                         {
 697                                 switch(teamnum)
 698                                 {
 699                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 700                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 701                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 702                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 703                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 704                                 }
 705                         }
 706                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 707
 708                         self.draw = Spawn_Draw;
 709                 }
 710         //}
 711
 712         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 713 }
 714
 715 void Ent_ReadSpawnEvent(float is_new)
 716 {SELFPARAM();
 717         // If entnum is 0, ONLY do the local spawn actions
 718         // this way the server can disable the sending of
 719         // spawn origin or such to clients if wanted.
 720         float entnum = ReadByte();
 721
 722         if(entnum)
 723         {
 724                 self.origin_x = ReadShort();
 725                 self.origin_y = ReadShort();
 726                 self.origin_z = ReadShort();
 727
 728                 if(is_new)
 729                 {
 730                         float teamnum = GetPlayerColor(entnum - 1);
 731
 732                         if(autocvar_cl_spawn_event_particles)
 733                         {
 734                                 switch(teamnum)
 735                                 {
 736                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, self.origin, '0 0 0', 1); break;
 737                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, self.origin, '0 0 0', 1); break;
 738                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, self.origin, '0 0 0', 1); break;
 739                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, self.origin, '0 0 0', 1); break;
 740                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, self.origin, '0 0 0', 1); break;
 741                                 }
 742                         }
 743                         if(autocvar_cl_spawn_event_sound)
 744                         {
 745                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 746                         }
 747                 }
 748         }
 749
 750         // local spawn actions
 751         if(is_new && (!entnum || (entnum == player_localentnum)))
 752         {
 753                 zoomin_effect = 1;
 754                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 755
 756                 if(autocvar_cl_unpress_zoom_on_spawn)
 757                 {
 758                         localcmd("-zoom\n");
 759                         button_zoom = false;
 760                 }
 761         }
 762         HUD_Radar_Hide_Maximized();
 763         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 764 }
 765
 766 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 767 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 768 void Ent_RadarLink();
 769 void Ent_Init();
 770 void Ent_ScoresInfo();
 771 void CSQC_Ent_Update(float bIsNewEntity)
 772 {SELFPARAM();
 773         int t = ReadByte();
 774
 775         if(autocvar_developer_csqcentities)
 776                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 777
 778         // set up the "time" global for received entities to be correct for interpolation purposes
 779         float savetime = time;
 780         if(servertime)
 781         {
 782                 time = servertime;
 783         }
 784         else
 785         {
 786                 serverprevtime = time;
 787                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 788                 time = serverprevtime + serverdeltatime;
 789         }
 790
 791 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 792         if(self.enttype)
 793         {
 794                 if(t != self.enttype || bIsNewEntity)
 795                 {
 796                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 797                         Ent_Remove();
 798                         clearentity(self);
 799                         bIsNewEntity = 1;
 800                 }
 801         }
 802         else
 803         {
 804                 if(!bIsNewEntity)
 805                 {
 806                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 807                         bIsNewEntity = 1;
 808                 }
 809         }
 810 #endif
 811         self.enttype = t;
 812         bool done = false;
 813         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 814                 it.m_read(self, bIsNewEntity);
 815                 done = true;
 816                 break;
 817         ));
 818         if (!done)
 819         switch(t)
 820         {
 821                 case ENT_CLIENT_MUTATOR: {
 822                         int mutID = ReadMutator();
 823                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 824                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 825                         break;
 826                 }
 827                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 828                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 829                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 830                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 831                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 832                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 833                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 834                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 835                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 836                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 837                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 838                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 839                 case ENT_CLIENT_INIT: Ent_Init(); break;
 840                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 841                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 842                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 843                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 844                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 845                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 846                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 847                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 848                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 849                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 850                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 851                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 852                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 853                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 854                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 855                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 856                 case ENT_CLIENT_TURRET: ent_turret(); break;
 857                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 858                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
 859                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 860                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 861                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 862                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 863                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 864                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 865                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 866                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 867                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 868                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 869                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 870                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 871                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 872                 case ENT_CLIENT_DOOR: ent_door(); break;
 873                 case ENT_CLIENT_PLAT: ent_plat(); break;
 874                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 875                 case ENT_CLIENT_CORNER: ent_corner(); break;
 876                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 877                 case ENT_CLIENT_TRAIN: ent_train(); break;
 878                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 879                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 880
 881                 default:
 882                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 883                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 884                         break;
 885         }
 886
 887         time = savetime;
 888 }
 889 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 890 // used when an entity changes its type. For an entity that someone interacts
 891 // with others, make sure it can no longer do so.
 892 void Ent_Remove()
 893 {SELFPARAM();
 894         if(self.entremove)
 895                 self.entremove();
 896
 897         if(self.skeletonindex)
 898         {
 899                 skel_delete(self.skeletonindex);
 900                 self.skeletonindex = 0;
 901         }
 902
 903         if(self.snd_looping > 0)
 904         {
 905                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 906                 self.snd_looping = 0;
 907         }
 908
 909         self.enttype = 0;
 910         self.classname = "";
 911         self.draw = draw_null;
 912         self.entremove = menu_sub_null;
 913         // TODO possibly set more stuff to defaults
 914 }
 915 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 916 void CSQC_Ent_Remove()
 917 {SELFPARAM();
 918         if(autocvar_developer_csqcentities)
 919                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 920
 921         if(wasfreed(self))
 922         {
 923                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 924                 return;
 925         }
 926         if(self.enttype)
 927                 Ent_Remove();
 928         remove(self);
 929 }
 930
 931 void Gamemode_Init()
 932 {
 933         if (!isdemo())
 934         {
 935                 if(!(calledhooks & HOOK_START))
 936                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 937                 calledhooks |= HOOK_START;
 938         }
 939 }
 940 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 941 void CSQC_Parse_StuffCmd(string strMessage)
 942 {
 943         if(autocvar_developer_csqcentities)
 944                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 945
 946         localcmd(strMessage);
 947 }
 948 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 949 void CSQC_Parse_Print(string strMessage)
 950 {
 951         if(autocvar_developer_csqcentities)
 952                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 953
 954         print(ColorTranslateRGB(strMessage));
 955 }
 956
 957 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 958 void CSQC_Parse_CenterPrint(string strMessage)
 959 {
 960         if(autocvar_developer_csqcentities)
 961                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 962
 963         centerprint_hud(strMessage);
 964 }
 965
 966 string notranslate_fogcmd1 = "\nfog ";
 967 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 968 void Fog_Force()
 969 {
 970         // TODO somehow thwart prvm_globalset client ...
 971
 972         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 973                 { localcmd("\nr_drawfog 0\n"); }
 974         else if(forcefog != "")
 975                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 976 }
 977
 978 void Gamemode_Init();
 979 void Ent_ScoresInfo()
 980 {SELFPARAM();
 981     int i;
 982         self.classname = "ent_client_scores_info";
 983         gametype = ReadInt24_t();
 984         HUD_ModIcons_SetFunc();
 985         for(i = 0; i < MAX_SCORE; ++i)
 986         {
 987                 if(scores_label[i])
 988                         strunzone(scores_label[i]);
 989                 scores_label[i] = strzone(ReadString());
 990                 scores_flags[i] = ReadByte();
 991         }
 992         for(i = 0; i < MAX_TEAMSCORE; ++i)
 993         {
 994                 if(teamscores_label[i])
 995                         strunzone(teamscores_label[i]);
 996                 teamscores_label[i] = strzone(ReadString());
 997                 teamscores_flags[i] = ReadByte();
 998         }
 999         HUD_InitScores();
1000         Gamemode_Init();
1001 }
1002
1003 void Ent_Init()
1004 {SELFPARAM();
1005         self.classname = "ent_client_init";
1006
1007         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1008
1009         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1010         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1011         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1012         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1013         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1014         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1015         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1016         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1017
1018         if(forcefog)
1019                 strunzone(forcefog);
1020         forcefog = strzone(ReadString());
1021
1022         armorblockpercent = ReadByte() / 255.0;
1023
1024         g_balance_mortar_bouncefactor = ReadCoord();
1025         g_balance_mortar_bouncestop = ReadCoord();
1026         g_balance_electro_secondary_bouncefactor = ReadCoord();
1027         g_balance_electro_secondary_bouncestop = ReadCoord();
1028
1029         vortex_scope = !ReadByte();
1030         rifle_scope = !ReadByte();
1031
1032         serverflags = ReadByte();
1033
1034         minelayer_maxmines = ReadByte();
1035
1036         hagar_maxrockets = ReadByte();
1037
1038         g_trueaim_minrange = ReadCoord();
1039         g_balance_porto_secondary = ReadByte();
1040
1041         MUTATOR_CALLHOOK(Ent_Init);
1042
1043         if(!postinit)
1044                 PostInit();
1045 }
1046
1047 void Net_ReadRace()
1048 {
1049         float b;
1050
1051         b = ReadByte();
1052
1053         switch(b)
1054         {
1055                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1056                         race_checkpoint = ReadByte();
1057                         race_time = ReadInt24_t();
1058                         race_previousbesttime = ReadInt24_t();
1059                         if(race_previousbestname)
1060                                 strunzone(race_previousbestname);
1061                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1062
1063                         race_checkpointtime = time;
1064
1065                         if(race_checkpoint == 0 || race_checkpoint == 254)
1066                         {
1067                                 race_penaltyaccumulator = 0;
1068                                 race_laptime = time; // valid
1069                         }
1070
1071                         break;
1072
1073                 case RACE_NET_CHECKPOINT_CLEAR:
1074                         race_laptime = 0;
1075                         race_checkpointtime = 0;
1076                         break;
1077
1078                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1079                         race_laptime = ReadCoord();
1080                         race_checkpointtime = -99999;
1081                         // fall through
1082                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1083                         race_nextcheckpoint = ReadByte();
1084
1085                         race_nextbesttime = ReadInt24_t();
1086                         if(race_nextbestname)
1087                                 strunzone(race_nextbestname);
1088                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1089                         break;
1090
1091                 case RACE_NET_CHECKPOINT_HIT_RACE:
1092                         race_mycheckpoint = ReadByte();
1093                         race_mycheckpointtime = time;
1094                         race_mycheckpointdelta = ReadInt24_t();
1095                         race_mycheckpointlapsdelta = ReadByte();
1096                         if(race_mycheckpointlapsdelta >= 128)
1097                                 race_mycheckpointlapsdelta -= 256;
1098                         if(race_mycheckpointenemy)
1099                                 strunzone(race_mycheckpointenemy);
1100                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1101                         break;
1102
1103                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1104                         race_othercheckpoint = ReadByte();
1105                         race_othercheckpointtime = time;
1106                         race_othercheckpointdelta = ReadInt24_t();
1107                         race_othercheckpointlapsdelta = ReadByte();
1108                         if(race_othercheckpointlapsdelta >= 128)
1109                                 race_othercheckpointlapsdelta -= 256;
1110                         if(race_othercheckpointenemy)
1111                                 strunzone(race_othercheckpointenemy);
1112                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1113                         break;
1114
1115                 case RACE_NET_PENALTY_RACE:
1116                         race_penaltyeventtime = time;
1117                         race_penaltytime = ReadShort();
1118                         //race_penaltyaccumulator += race_penaltytime;
1119                         if(race_penaltyreason)
1120                                 strunzone(race_penaltyreason);
1121                         race_penaltyreason = strzone(ReadString());
1122                         break;
1123
1124                 case RACE_NET_PENALTY_QUALIFYING:
1125                         race_penaltyeventtime = time;
1126                         race_penaltytime = ReadShort();
1127                         race_penaltyaccumulator += race_penaltytime;
1128                         if(race_penaltyreason)
1129                                 strunzone(race_penaltyreason);
1130                         race_penaltyreason = strzone(ReadString());
1131                         break;
1132
1133                 case RACE_NET_SERVER_RECORD:
1134                         race_server_record = ReadInt24_t();
1135                         break;
1136                 case RACE_NET_SPEED_AWARD:
1137                         race_speedaward = ReadInt24_t();
1138                         if(race_speedaward_holder)
1139                                 strunzone(race_speedaward_holder);
1140                         race_speedaward_holder = strzone(ReadString());
1141                         break;
1142                 case RACE_NET_SPEED_AWARD_BEST:
1143                         race_speedaward_alltimebest = ReadInt24_t();
1144                         if(race_speedaward_alltimebest_holder)
1145                                 strunzone(race_speedaward_alltimebest_holder);
1146                         race_speedaward_alltimebest_holder = strzone(ReadString());
1147                         break;
1148                 case RACE_NET_SERVER_RANKINGS:
1149                         float prevpos, del;
1150             int pos = ReadShort();
1151                         prevpos = ReadShort();
1152                         del = ReadShort();
1153
1154                         // move other rankings out of the way
1155             int i;
1156                         if (prevpos) {
1157                                 for (i=prevpos-1;i>pos-1;--i) {
1158                                         grecordtime[i] = grecordtime[i-1];
1159                                         if(grecordholder[i])
1160                                                 strunzone(grecordholder[i]);
1161                                         grecordholder[i] = strzone(grecordholder[i-1]);
1162                                 }
1163                         } else if (del) { // a record has been deleted by the admin
1164                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1165                                         if (i == RANKINGS_CNT-1) { // clear out last record
1166                                                 grecordtime[i] = 0;
1167                                                 if (grecordholder[i])
1168                                                         strunzone(grecordholder[i]);
1169                                                 grecordholder[i] = string_null;
1170                                         }
1171                                         else {
1172                                                 grecordtime[i] = grecordtime[i+1];
1173                                                 if (grecordholder[i])
1174                                                         strunzone(grecordholder[i]);
1175                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1176                                         }
1177                                 }
1178                         } else { // player has no ranked record yet
1179                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1180                                         grecordtime[i] = grecordtime[i-1];
1181                                         if(grecordholder[i])
1182                                                 strunzone(grecordholder[i]);
1183                                         grecordholder[i] = strzone(grecordholder[i-1]);
1184                                 }
1185                         }
1186
1187                         // store new ranking
1188                         if(grecordholder[pos-1] != "")
1189                                 strunzone(grecordholder[pos-1]);
1190                         grecordholder[pos-1] = strzone(ReadString());
1191                         grecordtime[pos-1] = ReadInt24_t();
1192                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1193                                 race_myrank = pos;
1194                         break;
1195                 case RACE_NET_SERVER_STATUS:
1196                         race_status = ReadShort();
1197                         if(race_status_name)
1198                                 strunzone(race_status_name);
1199                         race_status_name = strzone(ReadString());
1200         }
1201 }
1202
1203 void Net_TeamNagger()
1204 {
1205         teamnagger = 1;
1206 }
1207
1208 void Net_ReadPingPLReport()
1209 {
1210         int e, pi, pl, ml;
1211         e = ReadByte();
1212         pi = ReadShort();
1213         pl = ReadByte();
1214         ml = ReadByte();
1215         if (!(playerslots[e]))
1216                 return;
1217         playerslots[e].ping = pi;
1218         playerslots[e].ping_packetloss = pl / 255.0;
1219         playerslots[e].ping_movementloss = ml / 255.0;
1220 }
1221
1222 void Net_WeaponComplain()
1223 {
1224         complain_weapon = ReadByte();
1225
1226         if(complain_weapon_name)
1227                 strunzone(complain_weapon_name);
1228         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1229
1230         complain_weapon_type = ReadByte();
1231
1232         complain_weapon_time = time;
1233         weapontime = time; // ping the weapon panel
1234
1235         switch(complain_weapon_type)
1236         {
1237                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1238                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1239                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1240         }
1241 }
1242
1243 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1244 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1245 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1246 bool CSQC_Parse_TempEntity()
1247 {
1248         // Acquire TE ID
1249         int nTEID = ReadByte();
1250
1251         if (autocvar_developer_csqcentities)
1252                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1253
1254         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1255                 it.m_read(NULL, true);
1256                 return true;
1257         ));
1258         switch (nTEID)
1259         {
1260                 case TE_CSQC_MUTATOR:
1261                         int mutID = ReadMutator();
1262                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1263                         return true;
1264                 case TE_CSQC_TARGET_MUSIC:
1265                         Net_TargetMusic();
1266                         return true;
1267                 case TE_CSQC_PICTURE:
1268                         Net_MapVote_Picture();
1269                         return true;
1270                 case TE_CSQC_RACE:
1271                         Net_ReadRace();
1272                         return true;
1273                 case TE_CSQC_VORTEXBEAMPARTICLE:
1274                         Net_ReadVortexBeamParticle();
1275                         return true;
1276                 case TE_CSQC_TEAMNAGGER:
1277                         Net_TeamNagger();
1278                         return true;
1279                 case TE_CSQC_ARC:
1280                         Net_ReadArc();
1281                         return true;
1282                 case TE_CSQC_PINGPLREPORT:
1283                         Net_ReadPingPLReport();
1284                         return true;
1285                 case TE_CSQC_WEAPONCOMPLAIN:
1286                         Net_WeaponComplain();
1287                         return true;
1288                 case TE_CSQC_VEHICLESETUP:
1289                         Net_VehicleSetup();
1290                         return true;
1291                 case TE_CSQC_SVNOTICE:
1292                         cl_notice_read();
1293                         return true;
1294                 case TE_CSQC_SHOCKWAVEPARTICLE:
1295                         Net_ReadShockwaveParticle();
1296                         return true;
1297                 default:
1298                         // No special logic for this temporary entity; return 0 so the engine can handle it
1299                         return false;
1300         }
1301 }
1302
1303 string getcommandkey(string text, string command)
1304 {
1305         string keys;
1306         float n, j, k, l = 0;
1307
1308         if (!autocvar_hud_showbinds)
1309                 return text;
1310
1311         keys = db_get(binddb, command);
1312         if (keys == "")
1313         {
1314                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1315                 for(j = 0; j < n; ++j)
1316                 {
1317                         k = stof(argv(j));
1318                         if(k != -1)
1319                         {
1320                                 if ("" == keys)
1321                                         keys = keynumtostring(k);
1322                                 else
1323                                         keys = strcat(keys, ", ", keynumtostring(k));
1324
1325                                 ++l;
1326                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1327                                         break;
1328                         }
1329
1330                 }
1331                 if (keys == "")
1332                         keys = "NO_KEY";
1333                 db_put(binddb, command, keys);
1334         }
1335
1336         if (keys == "NO_KEY") {
1337                 if (autocvar_hud_showbinds > 1)
1338                         return sprintf(_("%s (not bound)"), text);
1339                 else
1340                         return text;
1341         }
1342         else if (autocvar_hud_showbinds > 1)
1343                 return sprintf("%s (%s)", text, keys);
1344         else
1345                 return keys;
1346 }