qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/scoreboard.qh"
  15 #include "hud/panel/quickmenu.qh"
  16 #include "shownames.qh"
  17 #include "view.qh"
  18 #include <common/t_items.qh>
  19 #include "weapons/projectile.qh"
  20 #include <common/deathtypes/all.qh>
  21 #include <common/items/_mod.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/minigames/cl_minigames.qh>
  24 #include <common/minigames/cl_minigames_hud.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/net_notice.qh>
  27 #include <common/scores.qh>
  28 #include <common/mapobjects/_mod.qh>
  29 #include <common/vehicles/all.qh>
  30 #include <lib/csqcmodel/cl_model.qh>
  31 #include <lib/csqcmodel/interpolate.qh>
  32 #include <lib/warpzone/client.qh>
  33
  34 // --------------------------------------------------------------------------
  35 // BEGIN REQUIRED CSQC FUNCTIONS
  36 //include "main.qh"
  37
  38 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  39
  40 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  41 {
  42         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  43         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  44 }
  45
  46 void draw_cursor_normal(vector pos, vector col, float a)
  47 {
  48         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  49 }
  50
  51 void LoadMenuSkinValues()
  52 {
  53         int fh = -1;
  54         if(cvar_string("menu_skin") != "")
  55         {
  56                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  57                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  58         }
  59         if(fh < 0 && cvar_defstring("menu_skin") != "")
  60         {
  61                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  62                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  63                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  64         }
  65         if(fh < 0)
  66         {
  67                 draw_currentSkin = "gfx/menu/default";
  68                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  69         }
  70
  71         draw_currentSkin = strzone(draw_currentSkin);
  72
  73         if(fh >= 0)
  74         {
  75                 string s;
  76                 while((s = fgets(fh)))
  77                 {
  78                         int n = tokenize_console(s);
  79                         if (n < 2)
  80                                 continue;
  81                         if(substring(argv(0), 0, 2) == "//")
  82                                 continue;
  83                         if(argv(0) == "SIZE_CURSOR")
  84                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  85                         else if(argv(0) == "OFFSET_CURSOR")
  86                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  87                 }
  88                 fclose(fh);
  89         }
  90 }
  91
  92 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  93 // Useful for precaching things
  94
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_shootfromfixedorigin", "");
 138
 139         registercvar("cl_multijump", "-1");
 140
 141         registercvar("cl_dodging", "0");
 142
 143         registercvar("cl_spawn_near_teammate", "1");
 144
 145         registercvar("cl_weapon_switch_reload", "1");
 146         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 147
 148         registercvar("cl_allow_uidranking", "1");
 149
 150         if(autocvar_cl_lockview)
 151                 cvar_set("cl_lockview", "0");
 152
 153         gametype = NULL;
 154
 155         postinit = false;
 156
 157         calledhooks = 0;
 158
 159         teams = Sort_Spawn();
 160         players = Sort_Spawn();
 161
 162         GetTeam(NUM_SPECTATOR, true); // add specs first
 163
 164         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 165                 weapon_accuracy[w] = -1;
 166
 167         // precaches
 168
 169         if(autocvar_cl_reticle)
 170         {
 171                 precache_pic("gfx/reticle_normal");
 172                 // weapon reticles are precached in weapon files
 173         }
 174
 175         {
 176                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 177                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 178                 shortmapname = mi_shortname;
 179
 180                 if (precache_pic(minimapname) == "")
 181                 {
 182                         // but maybe we have a non-clever minimap
 183                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 184                         if (precache_pic(minimapname) == "")
 185                                 minimapname = ""; // FAIL
 186                         else
 187                                 get_mi_min_max_texcoords(0); // load new texcoords
 188                 }
 189
 190                 mi_center = (mi_min + mi_max) * 0.5;
 191                 mi_scale = mi_max - mi_min;
 192                 minimapname = strzone(minimapname);
 193         }
 194
 195         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 196         LoadMenuSkinValues();
 197 }
 198
 199 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 200 void Shutdown()
 201 {
 202         WarpZone_Shutdown();
 203
 204         delete(teams);
 205         delete(players);
 206         db_close(binddb);
 207         db_close(tempdb);
 208         if(autocvar_cl_db_saveasdump)
 209                 db_dump(ClientProgsDB, "client.db");
 210         else
 211                 db_save(ClientProgsDB, "client.db");
 212         db_close(ClientProgsDB);
 213
 214         if(camera_active)
 215                 cvar_set("chase_active",ftos(chase_active_backup));
 216
 217         // unset the event chasecam's chase_active
 218         if(autocvar_chase_active < 0)
 219                 cvar_set("chase_active", "0");
 220
 221         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 222
 223         if (!isdemo())
 224         {
 225                 if (!(calledhooks & HOOK_START))
 226                         localcmd("\n_cl_hook_gamestart nop\n");
 227                 if (!(calledhooks & HOOK_END))
 228                         localcmd("\ncl_hook_gameend\n");
 229         }
 230
 231         localcmd("\ncl_hook_shutdown\n");
 232
 233         localcmd("\n-button12\n");
 234
 235         deactivate_minigame();
 236         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 237
 238         ReplicateVars(true); // destroy
 239 }
 240
 241 .float has_team;
 242 bool SetTeam(entity o, int Team)
 243 {
 244         TC(int, Team);
 245         //devassert_once(Team);
 246         entity tm;
 247         if(teamplay)
 248         {
 249                 switch(Team)
 250                 {
 251                         case -1:
 252                         case NUM_TEAM_1:
 253                         case NUM_TEAM_2:
 254                         case NUM_TEAM_3:
 255                         case NUM_TEAM_4:
 256                                 break;
 257                         default:
 258                                 if(GetTeam(Team, false) == NULL)
 259                                 {
 260                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 261                                         Team = NUM_SPECTATOR;
 262                                 }
 263                                 break;
 264                 }
 265         }
 266         else
 267         {
 268                 switch(Team)
 269                 {
 270                         case -1:
 271                         case 0:
 272                                 break;
 273                         default:
 274                                 if(GetTeam(Team, false) == NULL)
 275                                 {
 276                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 277                                         Team = NUM_SPECTATOR;
 278                                 }
 279                                 break;
 280                 }
 281         }
 282         if(Team == -1) // leave
 283         {
 284                 if(o.has_team)
 285                 {
 286                         tm = GetTeam(o.team, false);
 287                         tm.team_size -= 1;
 288                         o.has_team = 0;
 289                         return true;
 290                 }
 291         }
 292         else
 293         {
 294                 if (!o.has_team)
 295                 {
 296                         o.team = Team;
 297                         tm = GetTeam(Team, true);
 298                         tm.team_size += 1;
 299                         o.has_team = 1;
 300                         return true;
 301                 }
 302                 else if(Team != o.team)
 303                 {
 304                         tm = GetTeam(o.team, false);
 305                         tm.team_size -= 1;
 306                         o.team = Team;
 307                         tm = GetTeam(Team, true);
 308                         tm.team_size += 1;
 309                         return true;
 310                 }
 311         }
 312         return false;
 313 }
 314
 315 void Playerchecker_Think(entity this)
 316 {
 317         int i;
 318         entity e;
 319         for(i = 0; i < maxclients; ++i)
 320         {
 321                 e = playerslots[i];
 322                 if(entcs_GetName(i) == "")
 323                 {
 324                         if(e.sort_prev)
 325                         {
 326                                 // player disconnected
 327                                 SetTeam(e, -1);
 328                                 RemovePlayer(e);
 329                                 e.sort_prev = NULL;
 330                                 //e.gotscores = 0;
 331                         }
 332                 }
 333                 else
 334                 {
 335                         if (!e.sort_prev)
 336                         {
 337                                 // player connected
 338                                 if (!e)
 339                                 {
 340                                         playerslots[i] = e = new_pure(playerslot);
 341                                 }
 342                                 e.sv_entnum = i;
 343                                 e.ping = 0;
 344                                 e.ping_packetloss = 0;
 345                                 e.ping_movementloss = 0;
 346                                 //e.gotscores = 0; // we might already have the scores...
 347                                 int t = entcs_GetScoreTeam(i);
 348                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 349                                 RegisterPlayer(e);
 350                                 Scoreboard_UpdatePlayerPos(e);
 351                         }
 352                 }
 353         }
 354         this.nextthink = time + 0.2;
 355 }
 356
 357 void PostInit()
 358 {
 359         entity playerchecker = new_pure(playerchecker);
 360         setthink(playerchecker, Playerchecker_Think);
 361         playerchecker.nextthink = time + 0.2;
 362
 363         TrueAim_Init();
 364
 365         postinit = true;
 366 }
 367
 368 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 369 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 370 // All keys are in ascii.
 371 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 372 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 373 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 374 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 375 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 376 {
 377         TC(int, bInputType);
 378         bool override = false;
 379         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 380         if (override)
 381                 return true;
 382
 383         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 384
 385         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 386
 387         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 388
 389         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 390
 391         if(override)
 392                 return true;
 393
 394         return false;
 395 }
 396
 397 // END REQUIRED CSQC FUNCTIONS
 398 // --------------------------------------------------------------------------
 399
 400 // --------------------------------------------------------------------------
 401 // BEGIN OPTIONAL CSQC FUNCTIONS
 402
 403 void Ent_RemovePlayerScore(entity this)
 404 {
 405         if(this.owner) {
 406                 SetTeam(this.owner, -1);
 407                 this.owner.gotscores = 0;
 408                 FOREACH(Scores, true, {
 409                         this.owner.(scores(it)) = 0; // clear all scores
 410                 });
 411         }
 412 }
 413
 414 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 415 {
 416         make_pure(this);
 417         entity o;
 418
 419         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 420         // (no I've never heard of M-x replace-string, sed, or anything like that)
 421         bool isNew = !this.owner; // workaround for DP bug
 422         int n = ReadByte()-1;
 423
 424 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 425         if(!isNew && n != this.sv_entnum)
 426         {
 427                 //print("A CSQC entity changed its owner!\n");
 428                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 429                 isNew = true;
 430                 Ent_Remove(this);
 431         }
 432 #endif
 433
 434         this.sv_entnum = n;
 435
 436         o = playerslots[this.sv_entnum];
 437         if (!o)
 438         {
 439                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 440         }
 441         this.owner = o;
 442         o.sv_entnum = this.sv_entnum;
 443         o.gotscores = 1;
 444
 445         //if (!o.sort_prev)
 446         //      RegisterPlayer(o);
 447         //playerchecker will do this for us later, if it has not already done so
 448
 449         int sf = ReadShort();
 450         int lf = ReadShort();
 451         FOREACH(Scores, true, {
 452                 int p = 1 << (i % 16);
 453                 if (sf & p)
 454                 {
 455                         if (lf & p)
 456                                 o.(scores(it)) = ReadInt24_t();
 457                         else
 458                                 o.(scores(it)) = ReadChar();
 459                 }
 460         });
 461
 462         return = true;
 463
 464         if(o.sort_prev)
 465                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 466
 467         this.entremove = Ent_RemovePlayerScore;
 468 }
 469
 470 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 471 {
 472         make_pure(this);
 473         int i;
 474
 475         this.team = ReadByte();
 476         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 477
 478 #if MAX_TEAMSCORE <= 8
 479         int sf = ReadByte();
 480         int lf = ReadByte();
 481 #else
 482         int sf = ReadShort();
 483         int lf = ReadShort();
 484 #endif
 485         for(i = 0; i < MAX_TEAMSCORE; ++i)
 486                 if(sf & BIT(i))
 487                 {
 488                         if(lf & BIT(i))
 489                                 o.(teamscores(i)) = ReadInt24_t();
 490                         else
 491                                 o.(teamscores(i)) = ReadChar();
 492                 }
 493
 494         return = true;
 495
 496         Scoreboard_UpdateTeamPos(o);
 497 }
 498
 499 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 500 {
 501         make_pure(this);
 502         float newspectatee_status;
 503
 504         int f = ReadByte();
 505
 506         scoreboard_showscores_force = (f & BIT(0));
 507
 508         if(f & BIT(1))
 509         {
 510                 newspectatee_status = ReadByte();
 511                 if(newspectatee_status == player_localnum + 1)
 512                         newspectatee_status = -1; // observing
 513         }
 514         else
 515                 newspectatee_status = 0;
 516
 517         spectatorbutton_zoom = (f & BIT(2));
 518
 519         if(f & BIT(4))
 520         {
 521                 num_spectators = ReadByte();
 522
 523                 float i, slot;
 524
 525                 for(i = 0; i < MAX_SPECTATORS; ++i)
 526                         spectatorlist[i] = 0; // reset list first
 527
 528                 for(i = 0; i < num_spectators; ++i)
 529                 {
 530                         slot = ReadByte();
 531                         spectatorlist[i] = slot - 1;
 532                 }
 533         }
 534
 535         return = true;
 536
 537         if(newspectatee_status != spectatee_status)
 538         {
 539                 // clear race stuff
 540                 race_laptime = 0;
 541                 race_checkpointtime = 0;
 542                 hud_dynamic_shake_factor = -1;
 543                 spectatee_status_changed_time = time;
 544         }
 545         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 546         {
 547                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 548                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 549                 )
 550                         prev_p_health = -1;
 551                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 552                         prev_health = -1;
 553         }
 554         spectatee_status = newspectatee_status;
 555
 556         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 557 }
 558
 559 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 560 {
 561         make_pure(this);
 562         int i, j, b, f;
 563
 564         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 565
 566         if(!(nags & BIT(2)))
 567         {
 568                 strfree(vote_called_vote);
 569                 vote_active = 0;
 570         }
 571         else
 572         {
 573                 vote_active = 1;
 574         }
 575
 576         if(nags & BIT(6))
 577         {
 578                 vote_yescount = ReadByte();
 579                 vote_nocount = ReadByte();
 580                 vote_needed = ReadByte();
 581                 vote_highlighted = ReadChar();
 582         }
 583
 584         if(nags & BIT(7))
 585         {
 586                 strcpy(vote_called_vote, ReadString());
 587         }
 588
 589         if(nags & 1)
 590         {
 591                 for(j = 0; j < maxclients; ++j)
 592                         if(playerslots[j])
 593                                 playerslots[j].ready = true;
 594                 for(i = 1; i <= maxclients; i += 8)
 595                 {
 596                         f = ReadByte();
 597                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 598                                 if (!(f & b))
 599                                         if(playerslots[j])
 600                                                 playerslots[j].ready = false;
 601                 }
 602         }
 603
 604         return = true;
 605
 606         ready_waiting = (nags & BIT(0));
 607         ready_waiting_for_me = (nags & BIT(1));
 608         vote_waiting = (nags & BIT(2));
 609         vote_waiting_for_me = (nags & BIT(3));
 610         warmup_stage = (nags & BIT(4));
 611 }
 612
 613 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 614 {
 615         make_pure(this);
 616         int sf = 0;
 617         serialize(byte, 0, sf);
 618         if (sf & 1) {
 619                 for (int j = 0; j < maxclients; ++j) {
 620                         if (playerslots[j]) {
 621                                 playerslots[j].eliminated = true;
 622                         }
 623                 }
 624                 for (int i = 1; i <= maxclients; i += 8) {
 625                         int f = 0;
 626                         serialize(byte, 0, f);
 627                         for (int b = 0; b < 8; ++b) {
 628                                 if (f & BIT(b)) continue;
 629                                 int j = i - 1 + b;
 630                                 if (playerslots[j]) {
 631                                         playerslots[j].eliminated = false;
 632                                 }
 633                         }
 634                 }
 635         }
 636         return true;
 637 }
 638
 639 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 640 {
 641         make_pure(this);
 642         prandom_debug();
 643         float s = ReadShort();
 644         psrandom(s);
 645         return true;
 646 }
 647
 648 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 649 {
 650         make_pure(this);
 651         int sf = ReadInt24_t();
 652         if (sf == 0) {
 653                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 654                         weapon_accuracy[w] = -1;
 655                 return true;
 656         }
 657
 658         int f = 1;
 659         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 660                 if (sf & f) {
 661                         int b = ReadByte();
 662                         if (b == 0)
 663                                 weapon_accuracy[w] = -1;
 664                         else if (b == 255)
 665                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 666                         else
 667                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 668                 }
 669                 f = (f == 0x800000) ? 1 : f * 2;
 670         }
 671         return true;
 672 }
 673
 674 void Spawn_Draw(entity this)
 675 {
 676         if(this.alpha <= 0)
 677                 return;
 678
 679         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 680 }
 681
 682 void Spawn_PreDraw(entity this)
 683 {
 684         float alph;
 685         vector org = getpropertyvec(VF_ORIGIN);
 686         if(this.fade_start)
 687         {
 688                 if(vdist(org - this.origin, >, this.fade_end))
 689                         alph = 0; // save on some processing
 690                 else if(vdist(org - this.origin, <, this.fade_start))
 691                         alph = 1; // more processing saved
 692                 else
 693                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 694         }
 695         else
 696                 alph = 1;
 697         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 698         this.alpha = alph;
 699         if(alph <= 0)
 700                 this.drawmask = 0;
 701         else
 702                 this.drawmask = MASK_NORMAL;
 703 }
 704
 705 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 706 {
 707         float teamnum = (ReadByte() - 1);
 708         vector spn_origin = ReadVector();
 709
 710         this.team = (teamnum + 1);
 711
 712         //if(is_new)
 713         //{
 714                 this.origin = spn_origin;
 715                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 716                 //droptofloor();
 717
 718                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 719                 {
 720                         this.mdl = "models/spawnpoint.md3";
 721                         this.colormod = Team_ColorRGB(teamnum);
 722                         precache_model(this.mdl);
 723                         setmodel(this, this.mdl);
 724                         this.drawmask = MASK_NORMAL;
 725                         //this.move_movetype = MOVETYPE_NOCLIP;
 726                         //this.draw = Spawn_Draw;
 727                         IL_PUSH(g_drawables, this);
 728                 }*/
 729                 if(autocvar_cl_spawn_point_particles)
 730                 {
 731                         if(teamplay)
 732                         {
 733                                 switch(teamnum)
 734                                 {
 735                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 736                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 737                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 738                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 739                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 740                                 }
 741                         }
 742                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 743
 744                         this.draw = Spawn_Draw;
 745                         if (is_new) IL_PUSH(g_drawables, this);
 746                         setpredraw(this, Spawn_PreDraw);
 747                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 748                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 749                 }
 750         //}
 751
 752         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 753         return true;
 754 }
 755
 756 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 757 {
 758         // If entnum is 0, ONLY do the local spawn actions
 759         // this way the server can disable the sending of
 760         // spawn origin or such to clients if wanted.
 761         float entnum = ReadByte();
 762
 763         if(entnum)
 764         {
 765                 this.origin = ReadVector();
 766
 767                 if(is_new)
 768                 {
 769                         float teamnum = entcs_GetTeam(entnum - 1);
 770
 771                         if(autocvar_cl_spawn_event_particles)
 772                         {
 773                                 switch(teamnum)
 774                                 {
 775                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 776                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 777                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 778                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 779                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 780                                 }
 781                         }
 782                         if(autocvar_cl_spawn_event_sound)
 783                         {
 784                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 785                         }
 786                 }
 787         }
 788         return = true;
 789
 790         // local spawn actions
 791         if(is_new && (!entnum || (entnum == player_localentnum)))
 792         {
 793                 zoomin_effect = 1;
 794                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 795
 796                 if(autocvar_cl_unpress_zoom_on_spawn)
 797                 {
 798                         localcmd("-zoom\n");
 799                         button_zoom = false;
 800                 }
 801                 HUD_Radar_Hide_Maximized();
 802         }
 803         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 804 }
 805
 806 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 807 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 808 void CSQC_Ent_Update(entity this, bool isnew)
 809 {
 810         this.sourceLoc = __FILE__":"STR(__LINE__);
 811         int t = ReadByte();
 812
 813         // set up the "time" global for received entities to be correct for interpolation purposes
 814         float savetime = time;
 815         if(servertime)
 816         {
 817                 time = servertime;
 818         }
 819         else
 820         {
 821                 serverprevtime = time;
 822                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 823                 time = serverprevtime + serverdeltatime;
 824         }
 825
 826 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 827         if (this.enttype)
 828         {
 829                 if (t != this.enttype || isnew)
 830                 {
 831                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 832                         Ent_Remove(this);
 833                         clearentity(this);
 834                         isnew = true;
 835                 }
 836         }
 837         else
 838         {
 839                 if (!isnew)
 840                 {
 841                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 842                         isnew = true;
 843                 }
 844         }
 845 #endif
 846         this.enttype = t;
 847         bool done = false;
 848         FOREACH(LinkedEntities, it.m_id == t, {
 849                 if (isnew) this.classname = it.netname;
 850                 if (autocvar_developer_csqcentities)
 851             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 852                 done = it.m_read(this, NULL, isnew);
 853                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 854                 break;
 855         });
 856         time = savetime;
 857         if (!done)
 858         {
 859                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 860         }
 861 }
 862
 863 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 864 // used when an entity changes its type. For an entity that someone interacts
 865 // with others, make sure it can no longer do so.
 866 void Ent_Remove(entity this)
 867 {
 868         if(this.entremove) this.entremove(this);
 869
 870         if(this.skeletonindex)
 871         {
 872                 skel_delete(this.skeletonindex);
 873                 this.skeletonindex = 0;
 874         }
 875
 876         if(this.snd_looping > 0)
 877         {
 878                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 879                 this.snd_looping = 0;
 880         }
 881
 882         this.enttype = 0;
 883         this.classname = "";
 884         this.draw = func_null;
 885         this.entremove = func_null;
 886         // TODO possibly set more stuff to defaults
 887 }
 888 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 889 void CSQC_Ent_Remove(entity this)
 890 {
 891         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 892         if (wasfreed(this))
 893         {
 894                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 895                 return;
 896         }
 897         if (this.enttype) Ent_Remove(this);
 898         delete(this);
 899 }
 900
 901 void Gamemode_Init()
 902 {
 903         if (!isdemo())
 904         {
 905                 if(!(calledhooks & HOOK_START))
 906                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 907                 calledhooks |= HOOK_START;
 908         }
 909 }
 910 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 911 void CSQC_Parse_StuffCmd(string strMessage)
 912 {
 913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 914         localcmd(strMessage);
 915 }
 916 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 917 void CSQC_Parse_Print(string strMessage)
 918 {
 919         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 920         print(ColorTranslateRGB(strMessage));
 921 }
 922
 923 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 924 void CSQC_Parse_CenterPrint(string strMessage)
 925 {
 926         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 927         centerprint_hud(strMessage);
 928 }
 929
 930 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 931 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 932 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 933 bool CSQC_Parse_TempEntity()
 934 {
 935         // Acquire TE ID
 936         int nTEID = ReadByte();
 937
 938         FOREACH(TempEntities, it.m_id == nTEID, {
 939                 if (autocvar_developer_csqcentities)
 940                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 941                 return it.m_read(NULL, NULL, true);
 942         });
 943
 944         if (autocvar_developer_csqcentities)
 945                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 946
 947         // No special logic for this temporary entity; return 0 so the engine can handle it
 948         return false;
 949 }
 950
 951 string forcefog;
 952 void Fog_Force()
 953 {
 954         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 955                 localcmd("\nr_drawfog 0\n");
 956         else if (forcefog != "")
 957                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 958 }
 959
 960 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 961 {
 962         make_pure(this);
 963         gametype = ReadRegistered(Gametypes);
 964         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 965         HUD_ModIcons_SetFunc();
 966         FOREACH(Scores, true, {
 967                 strcpy(scores_label(it), ReadString());
 968                 scores_flags(it) = ReadByte();
 969         });
 970         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 971         {
 972                 strcpy(teamscores_label(i), ReadString());
 973                 teamscores_flags(i) = ReadByte();
 974         }
 975         return = true;
 976         Scoreboard_InitScores();
 977         Gamemode_Init();
 978 }
 979
 980 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 981 {
 982         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 983
 984         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 985         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 986         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 987         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 988         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 989         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 990         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 991         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 992
 993         strcpy(forcefog, ReadString());
 994
 995         armorblockpercent = ReadByte() / 255.0;
 996         damagepush_speedfactor = ReadByte() / 255.0;
 997
 998         serverflags = ReadByte();
 999
1000         g_trueaim_minrange = ReadCoord();
1001
1002         return = true;
1003
1004         MUTATOR_CALLHOOK(Ent_Init);
1005
1006         if (!postinit) PostInit();
1007 }
1008
1009 float GetSpeedUnitFactor(int speed_unit)
1010 {
1011         switch(speed_unit)
1012         {
1013                 default:
1014                 case 1:
1015                         return 1.0;
1016                 case 2:
1017                         return 0.0254;
1018                 case 3:
1019                         return 0.0254 * 3.6;
1020                 case 4:
1021                         return 0.0254 * 3.6 * 0.6213711922;
1022                 case 5:
1023                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1024         }
1025 }
1026
1027 string GetSpeedUnit(int speed_unit)
1028 {
1029         switch(speed_unit)
1030         {
1031                 default:
1032                 case 1:
1033                         return _(" qu/s");
1034                 case 2:
1035                         return _(" m/s");
1036                 case 3:
1037                         return _(" km/h");
1038                 case 4:
1039                         return _(" mph");
1040                 case 5:
1041                         return _(" knots");
1042         }
1043 }
1044
1045 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1046 {
1047         int b = ReadByte();
1048
1049         switch (b)
1050         {
1051                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1052                         race_checkpoint = ReadByte();
1053                         race_time = ReadInt24_t();
1054                         race_previousbesttime = ReadInt24_t();
1055                         race_mypreviousbesttime = ReadInt24_t();
1056                         string pbestname = ReadString();
1057                         if(autocvar_cl_race_cptimes_onlyself)
1058                         {
1059                                 race_previousbesttime = race_mypreviousbesttime;
1060                                 race_mypreviousbesttime = 0;
1061                                 strcpy(race_previousbestname, "");
1062                         }
1063                         else
1064                                 strcpy(race_previousbestname, pbestname);
1065
1066                         race_checkpointtime = time;
1067
1068                         if(race_checkpoint == 0 || race_checkpoint == 254)
1069                         {
1070                                 race_penaltyaccumulator = 0;
1071                                 race_laptime = time; // valid
1072                         }
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_CLEAR:
1076                         race_laptime = 0;
1077                         race_checkpointtime = 0;
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1081                         race_laptime = ReadCoord();
1082                         race_checkpointtime = -99999;
1083                         // fall through
1084                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1085                         race_nextcheckpoint = ReadByte();
1086
1087                         race_nextbesttime = ReadInt24_t();
1088                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1089                                 race_mybesttime = ReadInt24_t();
1090                         string newname = ReadString();
1091                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1092                         {
1093                                 race_nextbesttime = race_mybesttime;
1094                                 race_mybesttime = 0;
1095                                 strcpy(race_nextbestname, "");
1096                         }
1097                         else
1098                                 strcpy(race_nextbestname, newname);
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_HIT_RACE:
1102                         race_mycheckpoint = ReadByte();
1103                         race_mycheckpointtime = time;
1104                         race_mycheckpointdelta = ReadInt24_t();
1105                         race_mycheckpointlapsdelta = ReadByte();
1106                         if(race_mycheckpointlapsdelta >= 128)
1107                                 race_mycheckpointlapsdelta -= 256;
1108                         int who = ReadByte();
1109                         if(who)
1110                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1111                         else
1112                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1113                         break;
1114
1115                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1116                         race_othercheckpoint = ReadByte();
1117                         race_othercheckpointtime = time;
1118                         race_othercheckpointdelta = ReadInt24_t();
1119                         race_othercheckpointlapsdelta = ReadByte();
1120                         if(race_othercheckpointlapsdelta >= 128)
1121                                 race_othercheckpointlapsdelta -= 256;
1122                         int what = ReadByte();
1123                         if(what)
1124                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1125                         else
1126                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1127                         break;
1128
1129                 case RACE_NET_PENALTY_RACE:
1130                 case RACE_NET_PENALTY_QUALIFYING:
1131                         race_penaltyeventtime = time;
1132                         race_penaltytime = ReadShort();
1133                         string reason = ReadString();
1134                         if (reason == "missing a checkpoint")
1135                                 reason = _("missing a checkpoint");
1136                         strcpy(race_penaltyreason, reason);
1137                         if (b == RACE_NET_PENALTY_QUALIFYING)
1138                                 race_penaltyaccumulator += race_penaltytime;
1139                         break;
1140
1141                 case RACE_NET_SERVER_RECORD:
1142                         race_server_record = ReadInt24_t();
1143                         break;
1144                 case RACE_NET_SPEED_AWARD:
1145                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1146                         strcpy(race_speedaward_holder, ReadString());
1147                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1148                         break;
1149                 case RACE_NET_SPEED_AWARD_BEST:
1150                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1151                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1152                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1153                         break;
1154                 case RACE_NET_RANKINGS_CNT:
1155                         RANKINGS_DISPLAY_CNT = ReadByte();
1156                         break;
1157                 case RACE_NET_SERVER_RANKINGS:
1158                         float prevpos, del;
1159                         int pos = ReadShort();
1160                         prevpos = ReadShort();
1161                         del = ReadShort();
1162
1163                         // move other rankings out of the way
1164                         int i;
1165                         if (prevpos) {
1166                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1167                                 for (i=m-1; i>pos-1; --i) {
1168                                         grecordtime[i] = grecordtime[i-1];
1169                                         strcpy(grecordholder[i], grecordholder[i-1]);
1170                                 }
1171                         } else if (del) { // a record has been deleted by the admin
1172                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1173                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1174                                                 grecordtime[i] = 0;
1175                                                 strfree(grecordholder[i]);
1176                                         }
1177                                         else {
1178                                                 grecordtime[i] = grecordtime[i+1];
1179                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1180                                         }
1181                                 }
1182                         } else { // player has no ranked record yet
1183                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1184                                         grecordtime[i] = grecordtime[i-1];
1185                                         strcpy(grecordholder[i], grecordholder[i-1]);
1186                                 }
1187                         }
1188
1189                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1190                                 // kick off the player who fell from the last displayed position
1191                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1192                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1193                         }
1194
1195                         // store new ranking
1196                         strcpy(grecordholder[pos-1], ReadString());
1197                         grecordtime[pos-1] = ReadInt24_t();
1198                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1199                                 race_myrank = pos;
1200                         break;
1201                 case RACE_NET_SERVER_STATUS:
1202                         race_status = ReadShort();
1203                         strcpy(race_status_name, ReadString());
1204         }
1205         return true;
1206 }
1207
1208 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1209 {
1210         teamnagger = 1;
1211         return true;
1212 }
1213
1214 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1215 {
1216         int i = ReadByte();
1217         int pi = ReadShort();
1218         int pl = ReadByte();
1219         int ml = ReadByte();
1220         return = true;
1221         entity e = playerslots[i];
1222         if (!e) return;
1223         e.ping = pi;
1224         e.ping_packetloss = pl / 255.0;
1225         e.ping_movementloss = ml / 255.0;
1226 }
1227
1228 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1229 {
1230         int weapon_id = ReadByte();
1231         complain_weapon = Weapons_from(weapon_id);
1232         complain_weapon_type = ReadByte();
1233         return = true;
1234
1235         complain_weapon_time = time;
1236         weapontime = time; // ping the weapon panel
1237
1238         switch(complain_weapon_type)
1239         {
1240                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1241                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1242                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1243         }
1244 }
1245
1246 string _getcommandkey(string cmd_name, string command, bool forcename)
1247 {
1248         string keys;
1249         float n, j, k, l = 0;
1250
1251         if (!autocvar_hud_showbinds)
1252                 return cmd_name;
1253
1254         keys = db_get(binddb, command);
1255         if (keys == "")
1256         {
1257                 bool joy_active = cvar("joy_active");
1258                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1259                 for(j = 0; j < n; ++j)
1260                 {
1261                         k = stof(argv(j));
1262                         if(k != -1)
1263                         {
1264                                 string key = keynumtostring(k);
1265                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1266                                         continue;
1267
1268                                 key = translate_key(key);
1269
1270                                 if (keys == "")
1271                                         keys = key;
1272                                 else
1273                                         keys = strcat(keys, ", ", key);
1274
1275                                 ++l;
1276                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1277                                         break;
1278                         }
1279
1280                 }
1281                 if (keys == "")
1282                         keys = "NO_KEY";
1283                 db_put(binddb, command, keys);
1284         }
1285
1286         if (keys == "NO_KEY") {
1287                 if (autocvar_hud_showbinds > 1)
1288                         return sprintf(_("%s (not bound)"), cmd_name);
1289                 else
1290                         return cmd_name;
1291         }
1292         else if (autocvar_hud_showbinds > 1 || forcename)
1293                 return sprintf("%s (%s)", cmd_name, keys);
1294         else
1295                 return keys;
1296 }