qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         ReplicateVars(REPLICATEVARS_SEND_ALL);
  62
  63         // needs to be done so early because of the constants they create
  64         static_init();
  65         static_init_late();
  66         static_init_precache();
  67
  68         binddb = db_create();
  69         tempdb = db_create();
  70         ClientProgsDB = db_load("client.db");
  71
  72         draw_endBoldFont();
  73
  74         //registercommand("hud_configure");
  75         //registercommand("hud_save");
  76         //registercommand("menu_action");
  77
  78         ConsoleCommand_macro_init();
  79
  80         registercvar("hud_usecsqc", "1");
  81         registercvar("scoreboard_columns", "default");
  82
  83         registercvar("cl_nade_type", "3");
  84         registercvar("cl_pokenade_type", "zombie");
  85
  86         registercvar("cl_jumpspeedcap_min", "");
  87         registercvar("cl_jumpspeedcap_max", "");
  88
  89         registercvar("cl_shootfromfixedorigin", "");
  90
  91         registercvar("cl_multijump", "-1");
  92
  93         registercvar("cl_dodging", "0");
  94
  95         registercvar("cl_spawn_near_teammate", "1");
  96
  97         registercvar("cl_weapon_switch_reload", "1");
  98         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  99
 100         registercvar("cl_allow_uidranking", "1");
 101
 102         if(autocvar_cl_lockview)
 103                 cvar_set("cl_lockview", "0");
 104
 105         gametype = NULL;
 106
 107         postinit = false;
 108
 109         calledhooks = 0;
 110
 111         teams = Sort_Spawn();
 112         players = Sort_Spawn();
 113
 114         GetTeam(NUM_SPECTATOR, true); // add specs first
 115
 116         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 117                 weapon_accuracy[w] = -1;
 118
 119         // precaches
 120
 121         if(autocvar_cl_reticle)
 122         {
 123                 precache_pic("gfx/reticle_normal");
 124                 // weapon reticles are precached in weapon files
 125         }
 126
 127         {
 128                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 129                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 130                 shortmapname = mi_shortname;
 131
 132                 if (precache_pic(minimapname) == "")
 133                 {
 134                         // but maybe we have a non-clever minimap
 135                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 136                         if (precache_pic(minimapname) == "")
 137                                 minimapname = ""; // FAIL
 138                         else
 139                                 get_mi_min_max_texcoords(0); // load new texcoords
 140                 }
 141
 142                 mi_center = (mi_min + mi_max) * 0.5;
 143                 mi_scale = mi_max - mi_min;
 144                 minimapname = strzone(minimapname);
 145         }
 146
 147         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 148         LoadMenuSkinValues();
 149 }
 150
 151 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 152 void Shutdown()
 153 {
 154         WarpZone_Shutdown();
 155
 156         delete(teams);
 157         delete(players);
 158         db_close(binddb);
 159         db_close(tempdb);
 160         if(autocvar_cl_db_saveasdump)
 161                 db_dump(ClientProgsDB, "client.db");
 162         else
 163                 db_save(ClientProgsDB, "client.db");
 164         db_close(ClientProgsDB);
 165
 166         if(camera_active)
 167                 cvar_set("chase_active",ftos(chase_active_backup));
 168
 169         // unset the event chasecam's chase_active
 170         if(autocvar_chase_active < 0)
 171                 cvar_set("chase_active", "0");
 172
 173         if (autocvar_r_drawviewmodel < 0)
 174                 cvar_set("r_drawviewmodel", "0");
 175
 176         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 177
 178         if (!isdemo())
 179         {
 180                 if (!(calledhooks & HOOK_START))
 181                         localcmd("\n_cl_hook_gamestart nop\n");
 182                 if (!(calledhooks & HOOK_END))
 183                         localcmd("\ncl_hook_gameend\n");
 184         }
 185
 186         localcmd("\ncl_hook_shutdown\n");
 187
 188         localcmd("\n-button12\n");
 189
 190         deactivate_minigame();
 191         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 192
 193         ReplicateVars(REPLICATEVARS_DESTROY);
 194 }
 195
 196 void AuditLists()
 197 {
 198         entity e;
 199         entity prev;
 200
 201         prev = players;
 202         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 203         {
 204                 if(prev != e.sort_prev)
 205                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 206         }
 207
 208         prev = teams;
 209         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 210         {
 211                 if(prev != e.sort_prev)
 212                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 213         }
 214 }
 215
 216 float RegisterPlayer(entity player)
 217 {
 218         entity pl;
 219         AuditLists();
 220         for(pl = players.sort_next; pl; pl = pl.sort_next)
 221                 if(pl == player)
 222                         error("Player already registered!");
 223         player.sort_next = players.sort_next;
 224         player.sort_prev = players;
 225         if(players.sort_next)
 226                 players.sort_next.sort_prev = player;
 227         players.sort_next = player;
 228         AuditLists();
 229         return true;
 230 }
 231
 232 void RemovePlayer(entity player)
 233 {
 234         entity pl, parent;
 235         AuditLists();
 236         parent = players;
 237         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 238                 parent = pl;
 239
 240         if(!pl)
 241         {
 242                 error("Trying to remove a player which is not in the playerlist!");
 243                 return;
 244         }
 245         parent.sort_next = player.sort_next;
 246         if(player.sort_next)
 247                 player.sort_next.sort_prev = parent;
 248         AuditLists();
 249 }
 250
 251 void MoveToLast(entity e)
 252 {
 253         AuditLists();
 254         entity ent = e.sort_next;
 255         while(ent)
 256         {
 257                 SORT_SWAP(ent, e);
 258                 ent = e.sort_next;
 259         }
 260         AuditLists();
 261 }
 262
 263 float RegisterTeam(entity Team)
 264 {
 265         assert_once(Team.team, eprint(Team));
 266         entity tm;
 267         AuditLists();
 268         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 269                 if(tm == Team)
 270                         error("Team already registered!");
 271         Team.sort_next = teams.sort_next;
 272         Team.sort_prev = teams;
 273         if(teams.sort_next)
 274                 teams.sort_next.sort_prev = Team;
 275         teams.sort_next = Team;
 276         if(Team.team && Team.team != NUM_SPECTATOR)
 277                 ++team_count;
 278         AuditLists();
 279         return true;
 280 }
 281
 282 void RemoveTeam(entity Team)
 283 {
 284         entity tm, parent;
 285         AuditLists();
 286         parent = teams;
 287         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 288                 parent = tm;
 289
 290         if(!tm)
 291         {
 292                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 293                 return;
 294         }
 295         parent.sort_next = Team.sort_next;
 296         if(Team.sort_next)
 297                 Team.sort_next.sort_prev = parent;
 298         if(Team.team && Team.team != NUM_SPECTATOR)
 299                 --team_count;
 300         AuditLists();
 301 }
 302
 303 entity GetTeam(int Team, bool add)
 304 {
 305         TC(int, Team); TC(bool, add);
 306         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 307         if(teamslots[num])
 308                 return teamslots[num];
 309         if (!add)
 310                 return NULL;
 311         entity tm = new_pure(team);
 312         tm.team = Team;
 313         teamslots[num] = tm;
 314         RegisterTeam(tm);
 315         return tm;
 316 }
 317
 318 .float has_team;
 319 bool SetTeam(entity o, int Team)
 320 {
 321         TC(int, Team);
 322         //devassert_once(Team);
 323         entity tm;
 324         if(teamplay)
 325         {
 326                 switch(Team)
 327                 {
 328                         case -1:
 329                         case NUM_TEAM_1:
 330                         case NUM_TEAM_2:
 331                         case NUM_TEAM_3:
 332                         case NUM_TEAM_4:
 333                                 break;
 334                         default:
 335                                 if(GetTeam(Team, false) == NULL)
 336                                 {
 337                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 338                                         Team = NUM_SPECTATOR;
 339                                 }
 340                                 break;
 341                 }
 342         }
 343         else
 344         {
 345                 switch(Team)
 346                 {
 347                         case -1:
 348                         case 0:
 349                                 break;
 350                         default:
 351                                 if(GetTeam(Team, false) == NULL)
 352                                 {
 353                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 354                                         Team = NUM_SPECTATOR;
 355                                 }
 356                                 break;
 357                 }
 358         }
 359         if(Team == -1) // leave
 360         {
 361                 if(o.has_team)
 362                 {
 363                         tm = GetTeam(o.team, false);
 364                         tm.team_size -= 1;
 365                         o.has_team = 0;
 366                         return true;
 367                 }
 368         }
 369         else
 370         {
 371                 if (!o.has_team)
 372                 {
 373                         o.team = Team;
 374                         tm = GetTeam(Team, true);
 375                         tm.team_size += 1;
 376                         o.has_team = 1;
 377                         return true;
 378                 }
 379                 else if(Team != o.team)
 380                 {
 381                         tm = GetTeam(o.team, false);
 382                         tm.team_size -= 1;
 383                         o.team = Team;
 384                         tm = GetTeam(Team, true);
 385                         tm.team_size += 1;
 386                         return true;
 387                 }
 388         }
 389         return false;
 390 }
 391
 392 void Playerchecker_Think(entity this)
 393 {
 394         int i;
 395         entity e;
 396         for(i = 0; i < maxclients; ++i)
 397         {
 398                 e = playerslots[i];
 399                 if(entcs_GetName(i) == "")
 400                 {
 401                         if(e.sort_prev)
 402                         {
 403                                 // player disconnected
 404                                 SetTeam(e, -1);
 405                                 RemovePlayer(e);
 406                                 e.sort_prev = NULL;
 407                                 //e.gotscores = 0;
 408                         }
 409                 }
 410                 else
 411                 {
 412                         if (!e.sort_prev)
 413                         {
 414                                 // player connected
 415                                 if (!e)
 416                                 {
 417                                         playerslots[i] = e = new_pure(playerslot);
 418                                 }
 419                                 e.sv_entnum = i;
 420                                 e.ping = 0;
 421                                 e.ping_packetloss = 0;
 422                                 e.ping_movementloss = 0;
 423                                 //e.gotscores = 0; // we might already have the scores...
 424                                 int t = entcs_GetScoreTeam(i);
 425                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 426                                 RegisterPlayer(e);
 427                                 Scoreboard_UpdatePlayerPos(e);
 428                         }
 429                 }
 430         }
 431         this.nextthink = time + 0.2;
 432 }
 433
 434 void PostInit()
 435 {
 436         entity playerchecker = new_pure(playerchecker);
 437         setthink(playerchecker, Playerchecker_Think);
 438         playerchecker.nextthink = time + 0.2;
 439
 440         TrueAim_Init();
 441
 442         postinit = true;
 443 }
 444
 445 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 446 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 447 // All keys are in ascii.
 448 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 449 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 450 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 451 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 452 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 453 {
 454         TC(int, bInputType);
 455         bool override = false;
 456
 457         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 458         if (override)
 459                 return true;
 460
 461         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 462
 463         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 464
 465         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 466
 467         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 468
 469         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 470
 471         if(override)
 472                 return true;
 473
 474         return false;
 475 }
 476
 477 // END REQUIRED CSQC FUNCTIONS
 478 // --------------------------------------------------------------------------
 479
 480 // --------------------------------------------------------------------------
 481 // BEGIN OPTIONAL CSQC FUNCTIONS
 482
 483 void Ent_RemovePlayerScore(entity this)
 484 {
 485         if(this.owner) {
 486                 SetTeam(this.owner, -1);
 487                 this.owner.gotscores = 0;
 488                 FOREACH(Scores, true, {
 489                         this.owner.(scores(it)) = 0; // clear all scores
 490                 });
 491         }
 492 }
 493
 494 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 495 {
 496         make_pure(this);
 497         entity o;
 498
 499         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 500         // (no I've never heard of M-x replace-string, sed, or anything like that)
 501         bool isNew = !this.owner; // workaround for DP bug
 502         int n = ReadByte()-1;
 503
 504 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 505         if(!isNew && n != this.sv_entnum)
 506         {
 507                 //print("A CSQC entity changed its owner!\n");
 508                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 509                 isNew = true;
 510                 Ent_Remove(this);
 511         }
 512 #endif
 513
 514         this.sv_entnum = n;
 515
 516         o = playerslots[this.sv_entnum];
 517         if (!o)
 518         {
 519                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 520         }
 521         this.owner = o;
 522         o.sv_entnum = this.sv_entnum;
 523         o.gotscores = 1;
 524
 525         //if (!o.sort_prev)
 526         //      RegisterPlayer(o);
 527         //playerchecker will do this for us later, if it has not already done so
 528
 529         int sf = ReadShort();
 530         int lf = ReadShort();
 531         FOREACH(Scores, true, {
 532                 int p = 1 << (i % 16);
 533                 if (sf & p)
 534                 {
 535                         if (lf & p)
 536                                 o.(scores(it)) = ReadInt24_t();
 537                         else
 538                                 o.(scores(it)) = ReadChar();
 539                 }
 540         });
 541
 542         return = true;
 543
 544         if(o.sort_prev)
 545                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 546
 547         this.entremove = Ent_RemovePlayerScore;
 548 }
 549
 550 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 551 {
 552         make_pure(this);
 553         int i;
 554
 555         this.team = ReadByte();
 556         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 557
 558 #if MAX_TEAMSCORE <= 8
 559         int sf = ReadByte();
 560         int lf = ReadByte();
 561 #else
 562         int sf = ReadShort();
 563         int lf = ReadShort();
 564 #endif
 565         for(i = 0; i < MAX_TEAMSCORE; ++i)
 566                 if(sf & BIT(i))
 567                 {
 568                         if(lf & BIT(i))
 569                                 o.(teamscores(i)) = ReadInt24_t();
 570                         else
 571                                 o.(teamscores(i)) = ReadChar();
 572                 }
 573
 574         return = true;
 575
 576         Scoreboard_UpdateTeamPos(o);
 577 }
 578
 579 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 580 {
 581         make_pure(this);
 582         float newspectatee_status;
 583
 584         int f = ReadByte();
 585
 586         scoreboard_showscores_force = (f & BIT(0));
 587
 588         if(f & BIT(1))
 589         {
 590                 newspectatee_status = ReadByte();
 591                 if(newspectatee_status == player_localnum + 1)
 592                         newspectatee_status = -1; // observing
 593         }
 594         else
 595                 newspectatee_status = 0;
 596
 597         spectatorbutton_zoom = (f & BIT(2));
 598
 599         if(f & BIT(4))
 600         {
 601                 num_spectators = ReadByte();
 602
 603                 float i, slot;
 604
 605                 for(i = 0; i < MAX_SPECTATORS; ++i)
 606                         spectatorlist[i] = 0; // reset list first
 607
 608                 int limit = min(num_spectators, MAX_SPECTATORS);
 609                 for(i = 0; i < limit; ++i)
 610                 {
 611                         slot = ReadByte();
 612                         spectatorlist[i] = slot - 1;
 613                 }
 614         }
 615         else
 616         {
 617                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 618                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 619                 num_spectators = 0;
 620         }
 621
 622         return = true;
 623
 624         if(newspectatee_status != spectatee_status)
 625         {
 626                 // clear race stuff
 627                 race_laptime = 0;
 628                 race_checkpointtime = 0;
 629                 hud_dynamic_shake_factor = -1;
 630                 spectatee_status_changed_time = time;
 631         }
 632         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 633         {
 634                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 635                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 636                 )
 637                         prev_p_health = -1;
 638                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 639                         prev_health = -1;
 640         }
 641         spectatee_status = newspectatee_status;
 642
 643         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 644 }
 645
 646 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 647 {
 648         make_pure(this);
 649         int i, j, b, f;
 650
 651         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 652
 653         if(!(nags & BIT(2)))
 654         {
 655                 strfree(vote_called_vote);
 656                 vote_active = 0;
 657         }
 658         else
 659         {
 660                 vote_active = 1;
 661         }
 662
 663         if(nags & BIT(6))
 664         {
 665                 vote_yescount = ReadByte();
 666                 vote_nocount = ReadByte();
 667                 vote_needed = ReadByte();
 668                 vote_highlighted = ReadChar();
 669         }
 670
 671         if(nags & BIT(7))
 672         {
 673                 strcpy(vote_called_vote, ReadString());
 674         }
 675
 676         if(nags & 1)
 677         {
 678                 for(j = 0; j < maxclients; ++j)
 679                         if(playerslots[j])
 680                                 playerslots[j].ready = true;
 681                 for(i = 1; i <= maxclients; i += 8)
 682                 {
 683                         f = ReadByte();
 684                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 685                                 if (!(f & b))
 686                                         if(playerslots[j])
 687                                                 playerslots[j].ready = false;
 688                 }
 689         }
 690
 691         return = true;
 692
 693         ready_waiting = (nags & BIT(0));
 694         ready_waiting_for_me = (nags & BIT(1));
 695         vote_waiting = (nags & BIT(2));
 696         vote_waiting_for_me = (nags & BIT(3));
 697         warmup_stage = (nags & BIT(4));
 698 }
 699
 700 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 701 {
 702         make_pure(this);
 703         int sf = 0;
 704         serialize(byte, 0, sf);
 705         if (sf & 1) {
 706                 for (int j = 0; j < maxclients; ++j) {
 707                         if (playerslots[j]) {
 708                                 playerslots[j].eliminated = true;
 709                         }
 710                 }
 711                 for (int i = 1; i <= maxclients; i += 8) {
 712                         int f = 0;
 713                         serialize(byte, 0, f);
 714                         for (int b = 0; b < 8; ++b) {
 715                                 if (f & BIT(b)) continue;
 716                                 int j = i - 1 + b;
 717                                 if (playerslots[j]) {
 718                                         playerslots[j].eliminated = false;
 719                                 }
 720                         }
 721                 }
 722         }
 723         return true;
 724 }
 725
 726 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 727 {
 728         make_pure(this);
 729         prandom_debug();
 730         float s = ReadShort();
 731         psrandom(s);
 732         return true;
 733 }
 734
 735 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 736 {
 737         make_pure(this);
 738         int sf = ReadInt24_t();
 739         if (sf == 0) {
 740                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 741                         weapon_accuracy[w] = -1;
 742                 return true;
 743         }
 744
 745         int f = 1;
 746         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 747                 if (sf & f) {
 748                         int b = ReadByte();
 749                         if (b == 0)
 750                                 weapon_accuracy[w] = -1;
 751                         else if (b == 255)
 752                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 753                         else
 754                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 755                 }
 756                 f = (f == 0x800000) ? 1 : f * 2;
 757         }
 758         return true;
 759 }
 760
 761 void Spawn_Draw(entity this)
 762 {
 763         bool dodraw = autocvar_cl_spawn_point_particles;
 764         if(dodraw && autocvar_cl_spawn_point_dist_max)
 765         {
 766                 vector org = getpropertyvec(VF_ORIGIN);
 767                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 768         }
 769
 770         if(dodraw)
 771                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 772 }
 773
 774 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 775 {
 776         float teamnum = (ReadByte() - 1);
 777         vector spn_origin = ReadVector();
 778
 779         this.team = (teamnum + 1);
 780
 781         //if(is_new)
 782         //{
 783                 this.origin = spn_origin;
 784                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 785                 //droptofloor();
 786
 787                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 788                 {
 789                         this.mdl = "models/spawnpoint.md3";
 790                         this.colormod = Team_ColorRGB(teamnum);
 791                         precache_model(this.mdl);
 792                         setmodel(this, this.mdl);
 793                         this.drawmask = MASK_NORMAL;
 794                         //this.move_movetype = MOVETYPE_NOCLIP;
 795                         //this.draw = Spawn_Draw;
 796                         IL_PUSH(g_drawables, this);
 797                 }*/
 798                 this.draw = Spawn_Draw;
 799                 if (is_new) IL_PUSH(g_drawables, this);
 800         //}
 801
 802         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 803         return true;
 804 }
 805
 806 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 807 {
 808         // If entnum is 0, ONLY do the local spawn actions
 809         // this way the server can disable the sending of
 810         // spawn origin or such to clients if wanted.
 811         float entnum = ReadByte();
 812
 813         if(entnum)
 814         {
 815                 this.origin = ReadVector();
 816
 817                 if(is_new)
 818                 {
 819                         float teamnum = entcs_GetTeam(entnum - 1);
 820
 821                         if(autocvar_cl_spawn_event_particles)
 822                         {
 823                                 switch(teamnum)
 824                                 {
 825                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 826                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 827                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 828                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 829                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 830                                 }
 831                         }
 832                         if(autocvar_cl_spawn_event_sound)
 833                         {
 834                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 835                         }
 836                 }
 837         }
 838         return = true;
 839
 840         // local spawn actions
 841         if(is_new && (!entnum || (entnum == player_localentnum)))
 842         {
 843                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 844                 {
 845                         zoomin_effect = 1;
 846                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 847                 }
 848
 849                 if(autocvar_cl_unpress_zoom_on_spawn)
 850                 {
 851                         localcmd("-zoom\n");
 852                         button_zoom = false;
 853                 }
 854                 HUD_Radar_Hide_Maximized();
 855         }
 856         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 857 }
 858
 859 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 860 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 861 void CSQC_Ent_Update(entity this, bool isnew)
 862 {
 863         this.sourceLoc = __FILE__":"STR(__LINE__);
 864         int t = ReadByte();
 865
 866         // set up the "time" global for received entities to be correct for interpolation purposes
 867         float savetime = time;
 868         if(servertime)
 869         {
 870                 time = servertime;
 871         }
 872         else
 873         {
 874                 serverprevtime = time;
 875                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 876                 time = serverprevtime + serverdeltatime;
 877         }
 878
 879 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 880         if (this.enttype)
 881         {
 882                 if (t != this.enttype || isnew)
 883                 {
 884                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 885                         Ent_Remove(this);
 886                         ONREMOVE(this);
 887                         clearentity(this);
 888                         isnew = true;
 889                 }
 890         }
 891         else
 892         {
 893                 if (!isnew)
 894                 {
 895                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 896                         isnew = true;
 897                 }
 898         }
 899 #endif
 900         this.enttype = t;
 901         bool done = false;
 902         FOREACH(LinkedEntities, it.m_id == t, {
 903                 if (isnew) this.classname = it.netname;
 904                 if (autocvar_developer_csqcentities)
 905                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 906                 done = it.m_read(this, NULL, isnew);
 907                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 908                 break;
 909         });
 910         time = savetime;
 911         if (!done)
 912         {
 913                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 914         }
 915 }
 916
 917 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 918 // used when an entity changes its type. For an entity that someone interacts
 919 // with others, make sure it can no longer do so.
 920 void Ent_Remove(entity this)
 921 {
 922         if(this.entremove) this.entremove(this);
 923
 924         if(this.skeletonindex)
 925         {
 926                 skel_delete(this.skeletonindex);
 927                 this.skeletonindex = 0;
 928         }
 929
 930         if(this.snd_looping > 0)
 931         {
 932                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 933                 this.snd_looping = 0;
 934         }
 935
 936         this.enttype = 0;
 937         this.classname = "";
 938         this.draw = func_null;
 939         this.entremove = func_null;
 940         // TODO possibly set more stuff to defaults
 941 }
 942 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 943 void CSQC_Ent_Remove(entity this)
 944 {
 945         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 946         if (wasfreed(this))
 947         {
 948                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 949                 return;
 950         }
 951         if (this.enttype) Ent_Remove(this);
 952         delete(this);
 953 }
 954
 955 void Gamemode_Init()
 956 {
 957         if (!isdemo())
 958         {
 959                 if(!(calledhooks & HOOK_START))
 960                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 961                 calledhooks |= HOOK_START;
 962         }
 963 }
 964 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 965 void CSQC_Parse_StuffCmd(string strMessage)
 966 {
 967         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 968         localcmd(strMessage);
 969 }
 970 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 971 void CSQC_Parse_Print(string strMessage)
 972 {
 973         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 974         print(ColorTranslateRGB(strMessage));
 975 }
 976
 977 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 978 void CSQC_Parse_CenterPrint(string strMessage)
 979 {
 980         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 981         centerprint_AddStandard(strMessage);
 982 }
 983
 984 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 985 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 986 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 987 bool CSQC_Parse_TempEntity()
 988 {
 989         // Acquire TE ID
 990         int nTEID = ReadByte();
 991
 992         FOREACH(TempEntities, it.m_id == nTEID, {
 993                 if (autocvar_developer_csqcentities)
 994                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 995                 return it.m_read(NULL, NULL, true);
 996         });
 997
 998         if (autocvar_developer_csqcentities)
 999                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1000
1001         // No special logic for this temporary entity; return 0 so the engine can handle it
1002         return false;
1003 }
1004
1005 string forcefog;
1006 void Fog_Force()
1007 {
1008         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1009                 localcmd("\nr_drawfog 0\n");
1010         else if (forcefog != "")
1011                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1012 }
1013
1014 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1015 {
1016         make_pure(this);
1017         gametype = ReadRegistered(Gametypes);
1018         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1019         HUD_ModIcons_SetFunc();
1020         FOREACH(Scores, true, {
1021                 strcpy(scores_label(it), ReadString());
1022                 scores_flags(it) = ReadByte();
1023         });
1024         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1025         {
1026                 strcpy(teamscores_label(i), ReadString());
1027                 teamscores_flags(i) = ReadByte();
1028         }
1029         return = true;
1030         Scoreboard_InitScores();
1031         Gamemode_Init();
1032 }
1033
1034 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1035 {
1036         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1037
1038         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1043         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1044         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1045         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1046
1047         strcpy(forcefog, ReadString());
1048
1049         armorblockpercent = ReadByte() / 255.0;
1050         damagepush_speedfactor = ReadByte() / 255.0;
1051
1052         serverflags = ReadByte();
1053
1054         g_trueaim_minrange = ReadCoord();
1055
1056         return = true;
1057
1058         MUTATOR_CALLHOOK(Ent_Init);
1059
1060         if (!postinit) PostInit();
1061 }
1062
1063 float GetSpeedUnitFactor(int speed_unit)
1064 {
1065         switch(speed_unit)
1066         {
1067                 default:
1068                 case 1: return 1.0;
1069                 case 2: return 0.0254;
1070                 case 3: return 0.0254 * 3.6;
1071                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1072                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1073         }
1074 }
1075
1076 string GetSpeedUnit(int speed_unit)
1077 {
1078         switch(speed_unit)
1079         {
1080                 // translator-friendly strings without the initial space
1081                 default:
1082                 case 1: return strcat(" ", _("qu/s"));
1083                 case 2: return strcat(" ", _("m/s"));
1084                 case 3: return strcat(" ", _("km/h"));
1085                 case 4: return strcat(" ", _("mph"));
1086                 case 5: return strcat(" ", _("knots"));
1087         }
1088 }
1089
1090 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1091 {
1092         int b = ReadByte();
1093
1094         switch (b)
1095         {
1096                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1097                         race_checkpoint = ReadByte();
1098                         race_time = ReadInt24_t();
1099                         race_previousbesttime = ReadInt24_t();
1100                         race_mypreviousbesttime = ReadInt24_t();
1101                         string pbestname = ReadString();
1102                         if(autocvar_cl_race_cptimes_onlyself)
1103                         {
1104                                 race_previousbesttime = race_mypreviousbesttime;
1105                                 race_mypreviousbesttime = 0;
1106                                 strcpy(race_previousbestname, "");
1107                         }
1108                         else
1109                                 strcpy(race_previousbestname, pbestname);
1110
1111                         race_checkpointtime = time;
1112
1113                         if(race_checkpoint == 0 || race_checkpoint == 254)
1114                         {
1115                                 race_penaltyaccumulator = 0;
1116                                 race_laptime = time; // valid
1117                         }
1118                         break;
1119
1120                 case RACE_NET_CHECKPOINT_CLEAR:
1121                         race_laptime = 0;
1122                         race_checkpointtime = 0;
1123                         break;
1124
1125                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1126                         race_laptime = ReadCoord();
1127                         race_checkpointtime = -99999;
1128                         // fall through
1129                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1130                         race_nextcheckpoint = ReadByte();
1131
1132                         race_nextbesttime = ReadInt24_t();
1133                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1134                                 race_mybesttime = ReadInt24_t();
1135                         string newname = ReadString();
1136                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1137                         {
1138                                 race_nextbesttime = race_mybesttime;
1139                                 race_mybesttime = 0;
1140                                 strcpy(race_nextbestname, "");
1141                         }
1142                         else
1143                                 strcpy(race_nextbestname, newname);
1144                         break;
1145
1146                 case RACE_NET_CHECKPOINT_HIT_RACE:
1147                         race_mycheckpoint = ReadByte();
1148                         race_mycheckpointtime = time;
1149                         race_mycheckpointdelta = ReadInt24_t();
1150                         race_mycheckpointlapsdelta = ReadByte();
1151                         if(race_mycheckpointlapsdelta >= 128)
1152                                 race_mycheckpointlapsdelta -= 256;
1153                         int who = ReadByte();
1154                         if(who)
1155                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1156                         else
1157                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1158                         break;
1159
1160                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1161                         race_othercheckpoint = ReadByte();
1162                         race_othercheckpointtime = time;
1163                         race_othercheckpointdelta = ReadInt24_t();
1164                         race_othercheckpointlapsdelta = ReadByte();
1165                         if(race_othercheckpointlapsdelta >= 128)
1166                                 race_othercheckpointlapsdelta -= 256;
1167                         int what = ReadByte();
1168                         if(what)
1169                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1170                         else
1171                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1172                         break;
1173
1174                 case RACE_NET_PENALTY_RACE:
1175                 case RACE_NET_PENALTY_QUALIFYING:
1176                         race_penaltyeventtime = time;
1177                         race_penaltytime = ReadShort();
1178                         string reason = ReadString();
1179                         if (reason == "missing a checkpoint")
1180                                 reason = _("missing a checkpoint");
1181                         strcpy(race_penaltyreason, reason);
1182                         if (b == RACE_NET_PENALTY_QUALIFYING)
1183                                 race_penaltyaccumulator += race_penaltytime;
1184                         break;
1185
1186                 case RACE_NET_SERVER_RECORD:
1187                         race_server_record = ReadInt24_t();
1188                         break;
1189                 case RACE_NET_SPEED_AWARD:
1190                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1191                         strcpy(race_speedaward_holder, ReadString());
1192                         break;
1193                 case RACE_NET_SPEED_AWARD_BEST:
1194                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1195                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1196                         break;
1197                 case RACE_NET_RANKINGS_CNT:
1198                         RANKINGS_DISPLAY_CNT = ReadByte();
1199                         break;
1200                 case RACE_NET_SERVER_RANKINGS:
1201                         float prevpos, del;
1202                         int pos = ReadShort();
1203                         prevpos = ReadShort();
1204                         del = ReadShort();
1205
1206                         // move other rankings out of the way
1207                         int i;
1208                         if (prevpos) {
1209                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1210                                 for (i=m-1; i>pos-1; --i) {
1211                                         grecordtime[i] = grecordtime[i-1];
1212                                         strcpy(grecordholder[i], grecordholder[i-1]);
1213                                 }
1214                         } else if (del) { // a record has been deleted by the admin
1215                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1216                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1217                                                 grecordtime[i] = 0;
1218                                                 strfree(grecordholder[i]);
1219                                         }
1220                                         else {
1221                                                 grecordtime[i] = grecordtime[i+1];
1222                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1223                                         }
1224                                 }
1225                         } else { // player has no ranked record yet
1226                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1227                                         grecordtime[i] = grecordtime[i-1];
1228                                         strcpy(grecordholder[i], grecordholder[i-1]);
1229                                 }
1230                         }
1231
1232                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1233                                 // kick off the player who fell from the last displayed position
1234                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1235                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1236                         }
1237
1238                         // store new ranking
1239                         strcpy(grecordholder[pos-1], ReadString());
1240                         grecordtime[pos-1] = ReadInt24_t();
1241                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1242                                 race_myrank = pos;
1243                         break;
1244                 case RACE_NET_SERVER_STATUS:
1245                         race_status = ReadShort();
1246                         strcpy(race_status_name, ReadString());
1247         }
1248         return true;
1249 }
1250
1251 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1252 {
1253         teamnagger = 1;
1254         return true;
1255 }
1256
1257 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1258 {
1259         int i = ReadByte();
1260         int pi = ReadShort();
1261         int pl = ReadByte();
1262         int ml = ReadByte();
1263         return = true;
1264         entity e = playerslots[i];
1265         if (!e) return;
1266         e.ping = pi;
1267         e.ping_packetloss = pl / 255.0;
1268         e.ping_movementloss = ml / 255.0;
1269 }
1270
1271 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1272 {
1273         int weapon_id = ReadByte();
1274         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1275         complain_weapon_type = ReadByte();
1276         return = true;
1277
1278         complain_weapon_time = time;
1279         weapontime = time; // ping the weapon panel
1280
1281         switch(complain_weapon_type)
1282         {
1283                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1284                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1285                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1286         }
1287 }
1288
1289 string _getcommandkey(string cmd_name, string command, bool forcename)
1290 {
1291         string keys;
1292         float n, j, k, l = 0;
1293
1294         if (!autocvar_hud_showbinds)
1295                 return cmd_name;
1296
1297         keys = db_get(binddb, command);
1298         if (keys == "")
1299         {
1300                 bool joy_active = cvar("joy_active");
1301                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1302                 for(j = 0; j < n; ++j)
1303                 {
1304                         k = stof(argv(j));
1305                         if(k != -1)
1306                         {
1307                                 string key = keynumtostring(k);
1308                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1309                                         continue;
1310
1311                                 key = translate_key(key);
1312
1313                                 if (keys == "")
1314                                         keys = key;
1315                                 else
1316                                         keys = strcat(keys, ", ", key);
1317
1318                                 ++l;
1319                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1320                                         break;
1321                         }
1322
1323                 }
1324                 if (keys == "")
1325                         keys = "NO_KEY";
1326                 db_put(binddb, command, keys);
1327         }
1328
1329         if (keys == "NO_KEY") {
1330                 if (autocvar_hud_showbinds > 1)
1331                         return sprintf(_("%s (not bound)"), cmd_name);
1332                 else
1333                         return cmd_name;
1334         }
1335         else if (autocvar_hud_showbinds > 1 || forcename)
1336                 return sprintf("%s (%s)", cmd_name, keys);
1337         else
1338                 return keys;
1339 }
1340
1341 /** engine callback */
1342 void URI_Get_Callback(int id, int status, string data)
1343 {
1344         TC(int, id); TC(int, status);
1345         if(url_URI_Get_Callback(id, status, data))
1346         {
1347                 // handled
1348         }
1349         else if (id == URI_GET_DISCARD)
1350         {
1351                 // discard
1352         }
1353         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1354         {
1355                 // sv_cmd curl
1356                 Curl_URI_Get_Callback(id, status, data);
1357         }
1358         else
1359         {
1360                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1361         }
1362 }