qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <common/effects/qc/all.qh>
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "mutators/events.qh"
   7 #include "quickmenu.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10 #include <common/t_items.qh>
  11 #include "wall.qh"
  12 #include "weapons/projectile.qh"
  13 #include <common/deathtypes/all.qh>
  14 #include <common/items/all.qh>
  15 #include <common/mapinfo.qh>
  16 #include <common/minigames/cl_minigames.qh>
  17 #include <common/minigames/cl_minigames_hud.qh>
  18 #include <common/net_notice.qh>
  19 #include <common/triggers/include.qh>
  20 #include <common/vehicles/all.qh>
  21 #include <lib/csqcmodel/cl_model.qh>
  22 #include <lib/csqcmodel/interpolate.qh>
  23 #include <lib/warpzone/client.qh>
  24
  25 // --------------------------------------------------------------------------
  26 // BEGIN REQUIRED CSQC FUNCTIONS
  27 //include "main.qh"
  28
  29 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  30
  31 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  32 {
  33         ofs = eX * (ofs.x * SIZE_CURSOR.x) + eY * (ofs.y * SIZE_CURSOR.y);
  34         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  35 }
  36
  37 void draw_cursor_normal(vector pos, vector col, float a)
  38 {
  39         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  40 }
  41
  42 void LoadMenuSkinValues()
  43 {
  44         int fh = -1;
  45         if(cvar_string("menu_skin") != "")
  46         {
  47                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  48                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  49         }
  50         if(fh < 0 && cvar_defstring("menu_skin") != "")
  51         {
  52                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  53                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  54                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  55         }
  56         if(fh < 0)
  57         {
  58                 draw_currentSkin = "gfx/menu/default";
  59                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  60         }
  61
  62         draw_currentSkin = strzone(draw_currentSkin);
  63
  64         if(fh >= 0)
  65         {
  66                 string s;
  67                 while((s = fgets(fh)))
  68                 {
  69                         int n = tokenize_console(s);
  70                         if (n < 2)
  71                                 continue;
  72                         if(substring(argv(0), 0, 2) == "//")
  73                                 continue;
  74                         if(argv(0) == "SIZE_CURSOR")
  75                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  76                         else if(argv(0) == "OFFSET_CURSOR")
  77                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  78                 }
  79                 fclose(fh);
  80         }
  81 }
  82
  83 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  84 // Useful for precaching things
  85
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init()
  88 {
  89         prvm_language = strzone(cvar_string("prvm_language"));
  90
  91 #ifdef WATERMARK
  92         LOG_INFOF("^4CSQC Build information: ^1%s\n", WATERMARK);
  93 #endif
  94
  95         {
  96                 int i = 0;
  97                 for ( ; i < 255; ++i)
  98                         if (getplayerkeyvalue(i, "viewentity") == "")
  99                                 break;
 100                 maxclients = i;
 101         }
 102
 103         // needs to be done so early because of the constants they create
 104         static_init();
 105         static_init_late();
 106         static_init_precache();
 107
 108         binddb = db_create();
 109         tempdb = db_create();
 110         ClientProgsDB = db_load("client.db");
 111         compressShortVector_init();
 112
 113         draw_endBoldFont();
 114
 115         //registercommand("hud_configure");
 116         //registercommand("hud_save");
 117         //registercommand("menu_action");
 118
 119         ConsoleCommand_macro_init();
 120
 121         registercvar("hud_usecsqc", "1");
 122         registercvar("scoreboard_columns", "default");
 123
 124         registercvar("cl_nade_type", "3");
 125         registercvar("cl_pokenade_type", "zombie");
 126
 127         registercvar("cl_jumpspeedcap_min", "");
 128         registercvar("cl_jumpspeedcap_max", "");
 129
 130         registercvar("cl_multijump", "1");
 131
 132         registercvar("cl_spawn_near_teammate", "1");
 133
 134         gametype = 0;
 135
 136         // hud_fields uses strunzone on the titles!
 137         for(int i = 0; i < MAX_HUD_FIELDS; ++i)
 138                 hud_title[i] = strzone("(null)");
 139
 140         Cmd_HUD_SetFields(0);
 141
 142         postinit = false;
 143
 144         calledhooks = 0;
 145
 146         teams = Sort_Spawn();
 147         players = Sort_Spawn();
 148
 149         GetTeam(NUM_SPECTATOR, true); // add specs first
 150
 151         // precaches
 152
 153         if(autocvar_cl_reticle)
 154         {
 155                 precache_pic("gfx/reticle_normal");
 156                 // weapon reticles are precached in weapon files
 157         }
 158
 159         {
 160                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 161                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 162                 shortmapname = mi_shortname;
 163
 164                 if (precache_pic(minimapname) == "")
 165                 {
 166                         // but maybe we have a non-clever minimap
 167                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 168                         if (precache_pic(minimapname) == "")
 169                                 minimapname = ""; // FAIL
 170                         else
 171                                 get_mi_min_max_texcoords(0); // load new texcoords
 172                 }
 173
 174                 mi_center = (mi_min + mi_max) * 0.5;
 175                 mi_scale = mi_max - mi_min;
 176                 minimapname = strzone(minimapname);
 177         }
 178
 179         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 180         LoadMenuSkinValues();
 181 }
 182
 183 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 184 void Shutdown()
 185 {
 186         WarpZone_Shutdown();
 187
 188         remove(teams);
 189         remove(players);
 190         db_close(binddb);
 191         db_close(tempdb);
 192         if(autocvar_cl_db_saveasdump)
 193                 db_dump(ClientProgsDB, "client.db");
 194         else
 195                 db_save(ClientProgsDB, "client.db");
 196         db_close(ClientProgsDB);
 197
 198         if(camera_active)
 199                 cvar_set("chase_active",ftos(chase_active_backup));
 200
 201         // unset the event chasecam's chase_active
 202         if(autocvar_chase_active < 0)
 203                 cvar_set("chase_active", "0");
 204
 205         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 206
 207         if (!isdemo())
 208         {
 209                 if (!(calledhooks & HOOK_START))
 210                         localcmd("\n_cl_hook_gamestart nop\n");
 211                 if (!(calledhooks & HOOK_END))
 212                         localcmd("\ncl_hook_gameend\n");
 213         }
 214
 215         deactivate_minigame();
 216         HUD_MinigameMenu_Close();
 217 }
 218
 219 .float has_team;
 220 float SetTeam(entity o, int Team)
 221 {
 222         devassert_once(Team);
 223         entity tm;
 224         if(teamplay)
 225         {
 226                 switch(Team)
 227                 {
 228                         case -1:
 229                         case NUM_TEAM_1:
 230                         case NUM_TEAM_2:
 231                         case NUM_TEAM_3:
 232                         case NUM_TEAM_4:
 233                                 break;
 234                         default:
 235                                 if(GetTeam(Team, false) == world)
 236                                 {
 237                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 238                                         Team = NUM_SPECTATOR;
 239                                 }
 240                                 break;
 241                 }
 242         }
 243         else
 244         {
 245                 switch(Team)
 246                 {
 247                         case -1:
 248                         case 0:
 249                                 break;
 250                         default:
 251                                 if(GetTeam(Team, false) == world)
 252                                 {
 253                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 254                                         Team = NUM_SPECTATOR;
 255                                 }
 256                                 break;
 257                 }
 258         }
 259         if(Team == -1) // leave
 260         {
 261                 if(o.has_team)
 262                 {
 263                         tm = GetTeam(o.team, false);
 264                         tm.team_size -= 1;
 265                         o.has_team = 0;
 266                         return true;
 267                 }
 268         }
 269         else
 270         {
 271                 if (!o.has_team)
 272                 {
 273                         o.team = Team;
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         o.has_team = 1;
 277                         return true;
 278                 }
 279                 else if(Team != o.team)
 280                 {
 281                         tm = GetTeam(o.team, false);
 282                         tm.team_size -= 1;
 283                         o.team = Team;
 284                         tm = GetTeam(Team, true);
 285                         tm.team_size += 1;
 286                         return true;
 287                 }
 288         }
 289         return false;
 290 }
 291
 292 void Playerchecker_Think()
 293 {
 294         SELFPARAM();
 295     int i;
 296         entity e;
 297         for(i = 0; i < maxclients; ++i)
 298         {
 299                 e = playerslots[i];
 300                 if(entcs_GetName(i) == "")
 301                 {
 302                         if(e.sort_prev)
 303                         {
 304                                 // player disconnected
 305                                 SetTeam(e, -1);
 306                                 RemovePlayer(e);
 307                                 e.sort_prev = world;
 308                                 //e.gotscores = 0;
 309                         }
 310                 }
 311                 else
 312                 {
 313                         if (!e.sort_prev)
 314                         {
 315                                 // player connected
 316                                 if (!e)
 317                                 {
 318                                         playerslots[i] = e = new_pure(playerslot);
 319                                 }
 320                                 e.sv_entnum = i;
 321                                 e.ping = 0;
 322                                 e.ping_packetloss = 0;
 323                                 e.ping_movementloss = 0;
 324                                 //e.gotscores = 0; // we might already have the scores...
 325                                 int t = entcs_GetScoreTeam(i);
 326                                 if (t) SetTeam(e, t); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         this.nextthink = time + 0.2;
 333 }
 334
 335 void TrueAim_Init();
 336 void PostInit()
 337 {
 338         entity playerchecker = new_pure(playerchecker);
 339         playerchecker.think = Playerchecker_Think;
 340         playerchecker.nextthink = time + 0.2;
 341
 342         TrueAim_Init();
 343
 344         postinit = true;
 345 }
 346
 347 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 348 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 349 // All keys are in ascii.
 350 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 351 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 352 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 353 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 354 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 355 {
 356         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 357                 return true;
 358
 359         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 360                 return true;
 361
 362         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 363                 return true;
 364
 365         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         return false;
 372 }
 373
 374 // END REQUIRED CSQC FUNCTIONS
 375 // --------------------------------------------------------------------------
 376
 377 // --------------------------------------------------------------------------
 378 // BEGIN OPTIONAL CSQC FUNCTIONS
 379
 380 .void(entity) predraw_qc;
 381 void PreDraw_self()
 382 {
 383         SELFPARAM();
 384         if (this.predraw_qc) this.predraw_qc(this);
 385 }
 386
 387 void setpredraw(entity this, void(entity) pdfunc)
 388 {
 389         this.predraw = PreDraw_self;
 390         this.predraw_qc = pdfunc;
 391 }
 392
 393 void Ent_Remove(entity this);
 394
 395 void Ent_RemovePlayerScore(entity this)
 396 {
 397         if(this.owner) {
 398                 SetTeam(this.owner, -1);
 399                 this.owner.gotscores = 0;
 400                 for(int i = 0; i < MAX_SCORE; ++i) {
 401                         this.owner.(scores[i]) = 0; // clear all scores
 402                 }
 403         }
 404 }
 405
 406 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 407 {
 408         make_pure(this);
 409         int i, n;
 410         bool isNew;
 411         entity o;
 412
 413         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 414         // (no I've never heard of M-x replace-string, sed, or anything like that)
 415         isNew = !this.owner; // workaround for DP bug
 416         n = ReadByte()-1;
 417
 418 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 419         if(!isNew && n != this.sv_entnum)
 420         {
 421                 //print("A CSQC entity changed its owner!\n");
 422                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", etof(this), this.classname);
 423                 isNew = true;
 424                 Ent_Remove(this);
 425         }
 426 #endif
 427
 428         this.sv_entnum = n;
 429
 430         o = playerslots[this.sv_entnum];
 431         if (!o)
 432         {
 433                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 434         }
 435         this.owner = o;
 436         o.sv_entnum = this.sv_entnum;
 437         o.gotscores = 1;
 438
 439         //if (!o.sort_prev)
 440         //      RegisterPlayer(o);
 441         //playerchecker will do this for us later, if it has not already done so
 442
 443     int sf, lf;
 444 #if MAX_SCORE <= 8
 445         sf = ReadByte();
 446         lf = ReadByte();
 447 #else
 448         sf = ReadShort();
 449         lf = ReadShort();
 450 #endif
 451     int p;
 452         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 453                 if(sf & p)
 454                 {
 455                         if(lf & p)
 456                                 o.(scores[i]) = ReadInt24_t();
 457                         else
 458                                 o.(scores[i]) = ReadChar();
 459                 }
 460
 461         return = true;
 462
 463         if(o.sort_prev)
 464                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 465
 466         this.entremove = Ent_RemovePlayerScore;
 467 }
 468
 469 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 470 {
 471         make_pure(this);
 472         int i;
 473         entity o;
 474
 475         this.team = ReadByte();
 476         o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 477
 478     int sf, lf;
 479 #if MAX_TEAMSCORE <= 8
 480         sf = ReadByte();
 481         lf = ReadByte();
 482 #else
 483         sf = ReadShort();
 484         lf = ReadShort();
 485 #endif
 486         int p;
 487         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 488                 if(sf & p)
 489                 {
 490                         if(lf & p)
 491                                 o.(teamscores[i]) = ReadInt24_t();
 492                         else
 493                                 o.(teamscores[i]) = ReadChar();
 494                 }
 495
 496         return = true;
 497
 498         HUD_UpdateTeamPos(o);
 499 }
 500
 501 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 502 {
 503         make_pure(this);
 504         float newspectatee_status;
 505
 506     int f = ReadByte();
 507
 508         scoreboard_showscores_force = (f & 1);
 509
 510         if(f & 2)
 511         {
 512                 newspectatee_status = ReadByte();
 513                 if(newspectatee_status == player_localnum + 1)
 514                         newspectatee_status = -1; // observing
 515         }
 516         else
 517                 newspectatee_status = 0;
 518
 519         spectatorbutton_zoom = (f & 4);
 520
 521         if(f & 8)
 522         {
 523                 angles_held_status = 1;
 524                 angles_held.x = ReadAngle();
 525                 angles_held.y = ReadAngle();
 526                 angles_held.z = 0;
 527         }
 528         else
 529                 angles_held_status = 0;
 530
 531         return = true;
 532
 533         if(newspectatee_status != spectatee_status)
 534         {
 535                 // clear race stuff
 536                 race_laptime = 0;
 537                 race_checkpointtime = 0;
 538         }
 539         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 540         {
 541                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 542                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 543                 )
 544                         prev_p_health = -1;
 545                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 546                         prev_health = -1;
 547         }
 548         spectatee_status = newspectatee_status;
 549
 550         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 551 }
 552
 553 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 554 {
 555         make_pure(this);
 556     int i, j, b, f;
 557
 558     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 559
 560         if(!(nags & BIT(2)))
 561         {
 562                 if(vote_called_vote)
 563                         strunzone(vote_called_vote);
 564                 vote_called_vote = string_null;
 565                 vote_active = 0;
 566         }
 567         else
 568         {
 569                 vote_active = 1;
 570         }
 571
 572         if(nags & BIT(6))
 573         {
 574                 vote_yescount = ReadByte();
 575                 vote_nocount = ReadByte();
 576                 vote_needed = ReadByte();
 577                 vote_highlighted = ReadChar();
 578         }
 579
 580         if(nags & BIT(7))
 581         {
 582                 if(vote_called_vote)
 583                         strunzone(vote_called_vote);
 584                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 585         }
 586
 587         if(nags & 1)
 588         {
 589                 for(j = 0; j < maxclients; ++j)
 590                         if(playerslots[j])
 591                                 playerslots[j].ready = 1;
 592                 for(i = 1; i <= maxclients; i += 8)
 593                 {
 594                         f = ReadByte();
 595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 596                                 if (!(f & b))
 597                                         if(playerslots[j])
 598                                                 playerslots[j].ready = 0;
 599                 }
 600         }
 601
 602         return = true;
 603
 604         ready_waiting = (nags & BIT(0));
 605         ready_waiting_for_me = (nags & BIT(1));
 606         vote_waiting = (nags & BIT(2));
 607         vote_waiting_for_me = (nags & BIT(3));
 608         warmup_stage = (nags & BIT(4));
 609 }
 610
 611 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 612 {
 613         make_pure(this);
 614     int i, j, b, f;
 615
 616     int sf = ReadByte();
 617         if(sf & 1)
 618         {
 619                 for(j = 0; j < maxclients; ++j)
 620                         if(playerslots[j])
 621                                 playerslots[j].eliminated = 1;
 622                 for(i = 1; i <= maxclients; i += 8)
 623                 {
 624                         f = ReadByte();
 625                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 626                                 if (!(f & b))
 627                                         if(playerslots[j])
 628                                                 playerslots[j].eliminated = 0;
 629                 }
 630         }
 631         return true;
 632 }
 633
 634 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 635 {
 636         make_pure(this);
 637         prandom_debug();
 638         float s = ReadShort();
 639         psrandom(s);
 640         return true;
 641 }
 642
 643 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 644 {
 645         make_pure(this);
 646     int sf = ReadInt24_t();
 647         if (sf == 0) {
 648                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 649                         weapon_accuracy[w] = -1;
 650                 return true;
 651         }
 652
 653         int f = 1;
 654         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 655                 if (sf & f) {
 656             int b = ReadByte();
 657                         if (b == 0)
 658                                 weapon_accuracy[w] = -1;
 659                         else if (b == 255)
 660                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 661                         else
 662                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 663                 }
 664                 f = (f == 0x800000) ? 1 : f * 2;
 665         }
 666         return true;
 667 }
 668
 669 void Spawn_Draw(entity this)
 670 {
 671         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 672 }
 673
 674 void Spawn_PreDraw(entity this)
 675 {
 676         float alph;
 677         vector org = getpropertyvec(VF_ORIGIN);
 678         if(this.fade_start)
 679                 alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 680         else
 681                 alph = 1;
 682         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 683         this.alpha = alph;
 684         if(alph <= 0)
 685                 this.drawmask = 0;
 686         else
 687                 this.drawmask = MASK_NORMAL;
 688 }
 689
 690 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 691 {
 692         float teamnum = (ReadByte() - 1);
 693         vector spn_origin;
 694         spn_origin.x = ReadCoord();
 695         spn_origin.y = ReadCoord();
 696         spn_origin.z = ReadCoord();
 697
 698         //if(is_new)
 699         //{
 700                 this.origin = spn_origin;
 701                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 702                 //droptofloor();
 703
 704                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 705                 {
 706                         this.mdl = "models/spawnpoint.md3";
 707                         this.colormod = Team_ColorRGB(teamnum);
 708                         precache_model(this.mdl);
 709                         setmodel(this, this.mdl);
 710                         this.drawmask = MASK_NORMAL;
 711                         //this.movetype = MOVETYPE_NOCLIP;
 712                         //this.draw = Spawn_Draw;
 713                 }*/
 714                 if(autocvar_cl_spawn_point_particles)
 715                 {
 716                         if((serverflags & SERVERFLAG_TEAMPLAY))
 717                         {
 718                                 switch(teamnum)
 719                                 {
 720                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 721                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 722                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 723                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 724                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 725                                 }
 726                         }
 727                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 728
 729                         this.draw = Spawn_Draw;
 730                         setpredraw(this, Spawn_PreDraw);
 731                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 732                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 733                 }
 734         //}
 735
 736         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 737         return true;
 738 }
 739
 740 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 741 {
 742         // If entnum is 0, ONLY do the local spawn actions
 743         // this way the server can disable the sending of
 744         // spawn origin or such to clients if wanted.
 745         float entnum = ReadByte();
 746
 747         if(entnum)
 748         {
 749                 this.origin_x = ReadCoord();
 750                 this.origin_y = ReadCoord();
 751                 this.origin_z = ReadCoord();
 752
 753                 if(is_new)
 754                 {
 755                         float teamnum = entcs_GetTeam(entnum - 1);
 756
 757                         if(autocvar_cl_spawn_event_particles)
 758                         {
 759                                 switch(teamnum)
 760                                 {
 761                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 765                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 766                                 }
 767                         }
 768                         if(autocvar_cl_spawn_event_sound)
 769                         {
 770                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 771                         }
 772                 }
 773         }
 774         return = true;
 775
 776         // local spawn actions
 777         if(is_new && (!entnum || (entnum == player_localentnum)))
 778         {
 779                 zoomin_effect = 1;
 780                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 781
 782                 if(autocvar_cl_unpress_zoom_on_spawn)
 783                 {
 784                         localcmd("-zoom\n");
 785                         button_zoom = false;
 786                 }
 787         }
 788         HUD_Radar_Hide_Maximized();
 789         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 790 }
 791
 792 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 793 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 794 void CSQC_Ent_Update(bool isnew)
 795 {
 796         SELFPARAM();
 797         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 798         int t = ReadByte();
 799
 800         // set up the "time" global for received entities to be correct for interpolation purposes
 801         float savetime = time;
 802         if(servertime)
 803         {
 804                 time = servertime;
 805         }
 806         else
 807         {
 808                 serverprevtime = time;
 809                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 810                 time = serverprevtime + serverdeltatime;
 811         }
 812
 813 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 814         if (this.enttype)
 815         {
 816                 if (t != this.enttype || isnew)
 817                 {
 818                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", etof(this), this.entnum, this.enttype, t);
 819                         Ent_Remove(this);
 820                         clearentity(this);
 821                         isnew = true;
 822                 }
 823         }
 824         else
 825         {
 826                 if (!isnew)
 827                 {
 828                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", etof(this), this.entnum, t);
 829                         isnew = true;
 830                 }
 831         }
 832 #endif
 833         this.enttype = t;
 834         bool done = false;
 835         FOREACH(LinkedEntities, it.m_id == t, {
 836                 if (isnew) this.classname = it.netname;
 837                 if (autocvar_developer_csqcentities)
 838             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 839                 done = it.m_read(this, NULL, isnew);
 840                 break;
 841         });
 842         time = savetime;
 843         if (!done)
 844         {
 845                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)\n", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 846         }
 847 }
 848
 849 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 850 // used when an entity changes its type. For an entity that someone interacts
 851 // with others, make sure it can no longer do so.
 852 void Ent_Remove(entity this)
 853 {
 854         if(this.entremove) this.entremove(this);
 855
 856         if(this.skeletonindex)
 857         {
 858                 skel_delete(this.skeletonindex);
 859                 this.skeletonindex = 0;
 860         }
 861
 862         if(this.snd_looping > 0)
 863         {
 864                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 865                 this.snd_looping = 0;
 866         }
 867
 868         this.enttype = 0;
 869         this.classname = "";
 870         this.draw = func_null;
 871         this.entremove = func_null;
 872         // TODO possibly set more stuff to defaults
 873 }
 874 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 875 void CSQC_Ent_Remove()
 876 {
 877         SELFPARAM();
 878         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}\n", this, this.entnum, this.enttype);
 879         if (wasfreed(this))
 880         {
 881                 LOG_WARNING("CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 882                 return;
 883         }
 884         if (this.enttype) Ent_Remove(this);
 885         remove(this);
 886 }
 887
 888 void Gamemode_Init()
 889 {
 890         if (!isdemo())
 891         {
 892                 if(!(calledhooks & HOOK_START))
 893                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 894                 calledhooks |= HOOK_START;
 895         }
 896 }
 897 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 898 void CSQC_Parse_StuffCmd(string strMessage)
 899 {
 900         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 901         localcmd(strMessage);
 902 }
 903 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 904 void CSQC_Parse_Print(string strMessage)
 905 {
 906         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 907         print(ColorTranslateRGB(strMessage));
 908 }
 909
 910 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 911 void CSQC_Parse_CenterPrint(string strMessage)
 912 {
 913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 914         centerprint_hud(strMessage);
 915 }
 916
 917 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 918 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 919 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 920 bool CSQC_Parse_TempEntity()
 921 {
 922         // Acquire TE ID
 923         int nTEID = ReadByte();
 924
 925         FOREACH(TempEntities, it.m_id == nTEID, {
 926                 if (autocvar_developer_csqcentities)
 927                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)\n", it.netname, nTEID);
 928                 return it.m_read(NULL, NULL, true);
 929         });
 930
 931         if (autocvar_developer_csqcentities)
 932                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
 933
 934         // No special logic for this temporary entity; return 0 so the engine can handle it
 935         return false;
 936 }
 937
 938 string forcefog;
 939 void Fog_Force()
 940 {
 941         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 942                 localcmd("\nr_drawfog 0\n");
 943         else if (forcefog != "")
 944                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 945 }
 946
 947 void Gamemode_Init();
 948 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 949 {
 950         make_pure(this);
 951         gametype = ReadInt24_t();
 952         HUD_ModIcons_SetFunc();
 953         for (int i = 0; i < MAX_SCORE; ++i)
 954         {
 955                 if (scores_label[i]) strunzone(scores_label[i]);
 956                 scores_label[i] = strzone(ReadString());
 957                 scores_flags[i] = ReadByte();
 958         }
 959         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 960         {
 961                 if (teamscores_label[i]) strunzone(teamscores_label[i]);
 962                 teamscores_label[i] = strzone(ReadString());
 963                 teamscores_flags[i] = ReadByte();
 964         }
 965         return = true;
 966         HUD_InitScores();
 967         Gamemode_Init();
 968 }
 969
 970 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 971 {
 972         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 973
 974         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 975         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 976         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 977         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 978         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 979         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 980         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 981         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 982
 983         if (forcefog) strunzone(forcefog);
 984         forcefog = strzone(ReadString());
 985
 986         armorblockpercent = ReadByte() / 255.0;
 987
 988         serverflags = ReadByte();
 989
 990         g_trueaim_minrange = ReadCoord();
 991
 992         return = true;
 993
 994         MUTATOR_CALLHOOK(Ent_Init);
 995
 996         if (!postinit) PostInit();
 997 }
 998
 999 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1000 {
1001         int b = ReadByte();
1002
1003         switch (b)
1004         {
1005                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1006                         race_checkpoint = ReadByte();
1007                         race_time = ReadInt24_t();
1008                         race_previousbesttime = ReadInt24_t();
1009                         if(race_previousbestname)
1010                                 strunzone(race_previousbestname);
1011                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1012
1013                         race_checkpointtime = time;
1014
1015                         if(race_checkpoint == 0 || race_checkpoint == 254)
1016                         {
1017                                 race_penaltyaccumulator = 0;
1018                                 race_laptime = time; // valid
1019                         }
1020
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_CLEAR:
1024                         race_laptime = 0;
1025                         race_checkpointtime = 0;
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1029                         race_laptime = ReadCoord();
1030                         race_checkpointtime = -99999;
1031                         // fall through
1032                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1033                         race_nextcheckpoint = ReadByte();
1034
1035                         race_nextbesttime = ReadInt24_t();
1036                         if(race_nextbestname)
1037                                 strunzone(race_nextbestname);
1038                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE:
1042                         race_mycheckpoint = ReadByte();
1043                         race_mycheckpointtime = time;
1044                         race_mycheckpointdelta = ReadInt24_t();
1045                         race_mycheckpointlapsdelta = ReadByte();
1046                         if(race_mycheckpointlapsdelta >= 128)
1047                                 race_mycheckpointlapsdelta -= 256;
1048                         if(race_mycheckpointenemy)
1049                                 strunzone(race_mycheckpointenemy);
1050                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1054                         race_othercheckpoint = ReadByte();
1055                         race_othercheckpointtime = time;
1056                         race_othercheckpointdelta = ReadInt24_t();
1057                         race_othercheckpointlapsdelta = ReadByte();
1058                         if(race_othercheckpointlapsdelta >= 128)
1059                                 race_othercheckpointlapsdelta -= 256;
1060                         if(race_othercheckpointenemy)
1061                                 strunzone(race_othercheckpointenemy);
1062                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_PENALTY_RACE:
1066                         race_penaltyeventtime = time;
1067                         race_penaltytime = ReadShort();
1068                         //race_penaltyaccumulator += race_penaltytime;
1069                         if(race_penaltyreason)
1070                                 strunzone(race_penaltyreason);
1071                         race_penaltyreason = strzone(ReadString());
1072                         break;
1073
1074                 case RACE_NET_PENALTY_QUALIFYING:
1075                         race_penaltyeventtime = time;
1076                         race_penaltytime = ReadShort();
1077                         race_penaltyaccumulator += race_penaltytime;
1078                         if(race_penaltyreason)
1079                                 strunzone(race_penaltyreason);
1080                         race_penaltyreason = strzone(ReadString());
1081                         break;
1082
1083                 case RACE_NET_SERVER_RECORD:
1084                         race_server_record = ReadInt24_t();
1085                         break;
1086                 case RACE_NET_SPEED_AWARD:
1087                         race_speedaward = ReadInt24_t();
1088                         if(race_speedaward_holder)
1089                                 strunzone(race_speedaward_holder);
1090                         race_speedaward_holder = strzone(ReadString());
1091                         break;
1092                 case RACE_NET_SPEED_AWARD_BEST:
1093                         race_speedaward_alltimebest = ReadInt24_t();
1094                         if(race_speedaward_alltimebest_holder)
1095                                 strunzone(race_speedaward_alltimebest_holder);
1096                         race_speedaward_alltimebest_holder = strzone(ReadString());
1097                         break;
1098                 case RACE_NET_SERVER_RANKINGS:
1099                         float prevpos, del;
1100             int pos = ReadShort();
1101                         prevpos = ReadShort();
1102                         del = ReadShort();
1103
1104                         // move other rankings out of the way
1105             int i;
1106                         if (prevpos) {
1107                                 for (i=prevpos-1;i>pos-1;--i) {
1108                                         grecordtime[i] = grecordtime[i-1];
1109                                         if(grecordholder[i])
1110                                                 strunzone(grecordholder[i]);
1111                                         grecordholder[i] = strzone(grecordholder[i-1]);
1112                                 }
1113                         } else if (del) { // a record has been deleted by the admin
1114                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1115                                         if (i == RANKINGS_CNT-1) { // clear out last record
1116                                                 grecordtime[i] = 0;
1117                                                 if (grecordholder[i])
1118                                                         strunzone(grecordholder[i]);
1119                                                 grecordholder[i] = string_null;
1120                                         }
1121                                         else {
1122                                                 grecordtime[i] = grecordtime[i+1];
1123                                                 if (grecordholder[i])
1124                                                         strunzone(grecordholder[i]);
1125                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1126                                         }
1127                                 }
1128                         } else { // player has no ranked record yet
1129                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1130                                         grecordtime[i] = grecordtime[i-1];
1131                                         if(grecordholder[i])
1132                                                 strunzone(grecordholder[i]);
1133                                         grecordholder[i] = strzone(grecordholder[i-1]);
1134                                 }
1135                         }
1136
1137                         // store new ranking
1138                         if(grecordholder[pos-1] != "")
1139                                 strunzone(grecordholder[pos-1]);
1140                         grecordholder[pos-1] = strzone(ReadString());
1141                         grecordtime[pos-1] = ReadInt24_t();
1142                         if(grecordholder[pos-1] == entcs_GetName(player_localnum))
1143                                 race_myrank = pos;
1144                         break;
1145                 case RACE_NET_SERVER_STATUS:
1146                         race_status = ReadShort();
1147                         if(race_status_name)
1148                                 strunzone(race_status_name);
1149                         race_status_name = strzone(ReadString());
1150         }
1151         return true;
1152 }
1153
1154 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1155 {
1156         teamnagger = 1;
1157         return true;
1158 }
1159
1160 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1161 {
1162         int i = ReadByte();
1163         int pi = ReadShort();
1164         int pl = ReadByte();
1165         int ml = ReadByte();
1166         return = true;
1167         entity e = playerslots[i];
1168         if (!e) return;
1169         e.ping = pi;
1170         e.ping_packetloss = pl / 255.0;
1171         e.ping_movementloss = ml / 255.0;
1172 }
1173
1174 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1175 {
1176         complain_weapon = ReadByte();
1177         complain_weapon_type = ReadByte();
1178         return = true;
1179
1180         complain_weapon_time = time;
1181         weapontime = time; // ping the weapon panel
1182
1183         switch(complain_weapon_type)
1184         {
1185                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1186                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1187                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1188         }
1189 }
1190
1191 string getcommandkey(string text, string command)
1192 {
1193         string keys;
1194         float n, j, k, l = 0;
1195
1196         if (!autocvar_hud_showbinds)
1197                 return text;
1198
1199         keys = db_get(binddb, command);
1200         if (keys == "")
1201         {
1202                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1203                 for(j = 0; j < n; ++j)
1204                 {
1205                         k = stof(argv(j));
1206                         if(k != -1)
1207                         {
1208                                 if ("" == keys)
1209                                         keys = keynumtostring(k);
1210                                 else
1211                                         keys = strcat(keys, ", ", keynumtostring(k));
1212
1213                                 ++l;
1214                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1215                                         break;
1216                         }
1217
1218                 }
1219                 if (keys == "")
1220                         keys = "NO_KEY";
1221                 db_put(binddb, command, keys);
1222         }
1223
1224         if (keys == "NO_KEY") {
1225                 if (autocvar_hud_showbinds > 1)
1226                         return sprintf(_("%s (not bound)"), text);
1227                 else
1228                         return text;
1229         }
1230         else if (autocvar_hud_showbinds > 1)
1231                 return sprintf("%s (%s)", text, keys);
1232         else
1233                 return keys;
1234 }