qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "mapvoting.qh"
  12 #include "mutators/events.qh"
  13 #include "hud/panel/scoreboard.qh"
  14 #include "hud/panel/quickmenu.qh"
  15 #include "shownames.qh"
  16 #include <common/t_items.qh>
  17 #include "wall.qh"
  18 #include "weapons/projectile.qh"
  19 #include <common/deathtypes/all.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/net_linked.qh>
  25 #include <common/net_notice.qh>
  26 #include <common/scores.qh>
  27 #include <common/triggers/include.qh>
  28 #include <common/vehicles/all.qh>
  29 #include <lib/csqcmodel/cl_model.qh>
  30 #include <lib/csqcmodel/interpolate.qh>
  31 #include <lib/warpzone/client.qh>
  32
  33 // --------------------------------------------------------------------------
  34 // BEGIN REQUIRED CSQC FUNCTIONS
  35 //include "main.qh"
  36
  37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  38
  39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  40 {
  41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  43 }
  44
  45 void draw_cursor_normal(vector pos, vector col, float a)
  46 {
  47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  48 }
  49
  50 void LoadMenuSkinValues()
  51 {
  52         int fh = -1;
  53         if(cvar_string("menu_skin") != "")
  54         {
  55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  57         }
  58         if(fh < 0 && cvar_defstring("menu_skin") != "")
  59         {
  60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  63         }
  64         if(fh < 0)
  65         {
  66                 draw_currentSkin = "gfx/menu/default";
  67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  68         }
  69
  70         draw_currentSkin = strzone(draw_currentSkin);
  71
  72         if(fh >= 0)
  73         {
  74                 string s;
  75                 while((s = fgets(fh)))
  76                 {
  77                         int n = tokenize_console(s);
  78                         if (n < 2)
  79                                 continue;
  80                         if(substring(argv(0), 0, 2) == "//")
  81                                 continue;
  82                         if(argv(0) == "SIZE_CURSOR")
  83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  84                         else if(argv(0) == "OFFSET_CURSOR")
  85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                 }
  87                 fclose(fh);
  88         }
  89 }
  90
  91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  92 // Useful for precaching things
  93
  94 void ConsoleCommand_macro_init();
  95 void CSQC_Init()
  96 {
  97         prvm_language = strzone(cvar_string("prvm_language"));
  98
  99 #ifdef WATERMARK
 100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 101 #endif
 102
 103         {
 104                 int i = 0;
 105                 for ( ; i < 255; ++i)
 106                         if (getplayerkeyvalue(i, "viewentity") == "")
 107                                 break;
 108                 maxclients = i;
 109         }
 110
 111         // needs to be done so early because of the constants they create
 112         static_init();
 113         static_init_late();
 114         static_init_precache();
 115
 116         binddb = db_create();
 117         tempdb = db_create();
 118         ClientProgsDB = db_load("client.db");
 119
 120         draw_endBoldFont();
 121
 122         //registercommand("hud_configure");
 123         //registercommand("hud_save");
 124         //registercommand("menu_action");
 125
 126         ConsoleCommand_macro_init();
 127
 128         registercvar("hud_usecsqc", "1");
 129         registercvar("scoreboard_columns", "default");
 130
 131         registercvar("cl_nade_type", "3");
 132         registercvar("cl_pokenade_type", "zombie");
 133
 134         registercvar("cl_jumpspeedcap_min", "");
 135         registercvar("cl_jumpspeedcap_max", "");
 136
 137         registercvar("cl_shootfromfixedorigin", "");
 138
 139         registercvar("cl_multijump", "1");
 140
 141         registercvar("cl_spawn_near_teammate", "1");
 142
 143         if(autocvar_cl_lockview)
 144                 cvar_set("cl_lockview", "0");
 145
 146         gametype = NULL;
 147
 148         postinit = false;
 149
 150         calledhooks = 0;
 151
 152         teams = Sort_Spawn();
 153         players = Sort_Spawn();
 154
 155         GetTeam(NUM_SPECTATOR, true); // add specs first
 156
 157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 158                 weapon_accuracy[w] = -1;
 159
 160         // precaches
 161
 162         if(autocvar_cl_reticle)
 163         {
 164                 precache_pic("gfx/reticle_normal");
 165                 // weapon reticles are precached in weapon files
 166         }
 167
 168         {
 169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 171                 shortmapname = mi_shortname;
 172
 173                 if (precache_pic(minimapname) == "")
 174                 {
 175                         // but maybe we have a non-clever minimap
 176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 177                         if (precache_pic(minimapname) == "")
 178                                 minimapname = ""; // FAIL
 179                         else
 180                                 get_mi_min_max_texcoords(0); // load new texcoords
 181                 }
 182
 183                 mi_center = (mi_min + mi_max) * 0.5;
 184                 mi_scale = mi_max - mi_min;
 185                 minimapname = strzone(minimapname);
 186         }
 187
 188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 189         LoadMenuSkinValues();
 190 }
 191
 192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 193 void Shutdown()
 194 {
 195         WarpZone_Shutdown();
 196
 197         delete(teams);
 198         delete(players);
 199         db_close(binddb);
 200         db_close(tempdb);
 201         if(autocvar_cl_db_saveasdump)
 202                 db_dump(ClientProgsDB, "client.db");
 203         else
 204                 db_save(ClientProgsDB, "client.db");
 205         db_close(ClientProgsDB);
 206
 207         if(camera_active)
 208                 cvar_set("chase_active",ftos(chase_active_backup));
 209
 210         // unset the event chasecam's chase_active
 211         if(autocvar_chase_active < 0)
 212                 cvar_set("chase_active", "0");
 213
 214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 215
 216         if (!isdemo())
 217         {
 218                 if (!(calledhooks & HOOK_START))
 219                         localcmd("\n_cl_hook_gamestart nop\n");
 220                 if (!(calledhooks & HOOK_END))
 221                         localcmd("\ncl_hook_gameend\n");
 222         }
 223
 224         localcmd("\ncl_hook_shutdown\n");
 225
 226         deactivate_minigame();
 227         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 228 }
 229
 230 .float has_team;
 231 float SetTeam(entity o, int Team)
 232 {
 233     TC(int, Team);
 234         devassert_once(Team);
 235         entity tm;
 236         if(teamplay)
 237         {
 238                 switch(Team)
 239                 {
 240                         case -1:
 241                         case NUM_TEAM_1:
 242                         case NUM_TEAM_2:
 243                         case NUM_TEAM_3:
 244                         case NUM_TEAM_4:
 245                                 break;
 246                         default:
 247                                 if(GetTeam(Team, false) == NULL)
 248                                 {
 249                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 250                                         Team = NUM_SPECTATOR;
 251                                 }
 252                                 break;
 253                 }
 254         }
 255         else
 256         {
 257                 switch(Team)
 258                 {
 259                         case -1:
 260                         case 0:
 261                                 break;
 262                         default:
 263                                 if(GetTeam(Team, false) == NULL)
 264                                 {
 265                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 266                                         Team = NUM_SPECTATOR;
 267                                 }
 268                                 break;
 269                 }
 270         }
 271         if(Team == -1) // leave
 272         {
 273                 if(o.has_team)
 274                 {
 275                         tm = GetTeam(o.team, false);
 276                         tm.team_size -= 1;
 277                         o.has_team = 0;
 278                         return true;
 279                 }
 280         }
 281         else
 282         {
 283                 if (!o.has_team)
 284                 {
 285                         o.team = Team;
 286                         tm = GetTeam(Team, true);
 287                         tm.team_size += 1;
 288                         o.has_team = 1;
 289                         return true;
 290                 }
 291                 else if(Team != o.team)
 292                 {
 293                         tm = GetTeam(o.team, false);
 294                         tm.team_size -= 1;
 295                         o.team = Team;
 296                         tm = GetTeam(Team, true);
 297                         tm.team_size += 1;
 298                         return true;
 299                 }
 300         }
 301         return false;
 302 }
 303
 304 void Playerchecker_Think(entity this)
 305 {
 306     int i;
 307         entity e;
 308         for(i = 0; i < maxclients; ++i)
 309         {
 310                 e = playerslots[i];
 311                 if(entcs_GetName(i) == "")
 312                 {
 313                         if(e.sort_prev)
 314                         {
 315                                 // player disconnected
 316                                 SetTeam(e, -1);
 317                                 RemovePlayer(e);
 318                                 e.sort_prev = NULL;
 319                                 //e.gotscores = 0;
 320                         }
 321                 }
 322                 else
 323                 {
 324                         if (!e.sort_prev)
 325                         {
 326                                 // player connected
 327                                 if (!e)
 328                                 {
 329                                         playerslots[i] = e = new_pure(playerslot);
 330                                 }
 331                                 e.sv_entnum = i;
 332                                 e.ping = 0;
 333                                 e.ping_packetloss = 0;
 334                                 e.ping_movementloss = 0;
 335                                 //e.gotscores = 0; // we might already have the scores...
 336                                 int t = entcs_GetScoreTeam(i);
 337                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 338                                 RegisterPlayer(e);
 339                                 Scoreboard_UpdatePlayerPos(e);
 340                         }
 341                 }
 342         }
 343         this.nextthink = time + 0.2;
 344 }
 345
 346 void TrueAim_Init();
 347 void PostInit()
 348 {
 349         entity playerchecker = new_pure(playerchecker);
 350         setthink(playerchecker, Playerchecker_Think);
 351         playerchecker.nextthink = time + 0.2;
 352
 353         TrueAim_Init();
 354
 355         postinit = true;
 356 }
 357
 358 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 359 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 360 // All keys are in ascii.
 361 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 362 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 363 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 364 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 365 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 366 {
 367     TC(int, bInputType);
 368         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 369                 return true;
 370
 371         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 372                 return true;
 373
 374         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
 375                 return true;
 376
 377         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 378                 return true;
 379
 380         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 381                 return true;
 382
 383         return false;
 384 }
 385
 386 // END REQUIRED CSQC FUNCTIONS
 387 // --------------------------------------------------------------------------
 388
 389 // --------------------------------------------------------------------------
 390 // BEGIN OPTIONAL CSQC FUNCTIONS
 391
 392 void Ent_Remove(entity this);
 393
 394 void Ent_RemovePlayerScore(entity this)
 395 {
 396         if(this.owner) {
 397                 SetTeam(this.owner, -1);
 398                 this.owner.gotscores = 0;
 399                 FOREACH(Scores, true, {
 400                         this.owner.(scores(it)) = 0; // clear all scores
 401                 });
 402         }
 403 }
 404
 405 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 406 {
 407         make_pure(this);
 408         entity o;
 409
 410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 411         // (no I've never heard of M-x replace-string, sed, or anything like that)
 412         bool isNew = !this.owner; // workaround for DP bug
 413         int n = ReadByte()-1;
 414
 415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 416         if(!isNew && n != this.sv_entnum)
 417         {
 418                 //print("A CSQC entity changed its owner!\n");
 419                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 420                 isNew = true;
 421                 Ent_Remove(this);
 422         }
 423 #endif
 424
 425         this.sv_entnum = n;
 426
 427         o = playerslots[this.sv_entnum];
 428         if (!o)
 429         {
 430                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 431         }
 432         this.owner = o;
 433         o.sv_entnum = this.sv_entnum;
 434         o.gotscores = 1;
 435
 436         //if (!o.sort_prev)
 437         //      RegisterPlayer(o);
 438         //playerchecker will do this for us later, if it has not already done so
 439
 440         int sf = ReadShort();
 441         int lf = ReadShort();
 442         FOREACH(Scores, true, {
 443                 int p = 1 << (i % 16);
 444                 if (sf & p)
 445                 {
 446                         if (lf & p)
 447                                 o.(scores(it)) = ReadInt24_t();
 448                         else
 449                                 o.(scores(it)) = ReadChar();
 450                 }
 451         });
 452
 453         return = true;
 454
 455         if(o.sort_prev)
 456                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 457
 458         this.entremove = Ent_RemovePlayerScore;
 459 }
 460
 461 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 462 {
 463         make_pure(this);
 464         int i;
 465
 466         this.team = ReadByte();
 467         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 468
 469 #if MAX_TEAMSCORE <= 8
 470         int sf = ReadByte();
 471         int lf = ReadByte();
 472 #else
 473         int sf = ReadShort();
 474         int lf = ReadShort();
 475 #endif
 476         for(i = 0; i < MAX_TEAMSCORE; ++i)
 477                 if(sf & BIT(i))
 478                 {
 479                         if(lf & BIT(i))
 480                                 o.(teamscores(i)) = ReadInt24_t();
 481                         else
 482                                 o.(teamscores(i)) = ReadChar();
 483                 }
 484
 485         return = true;
 486
 487         Scoreboard_UpdateTeamPos(o);
 488 }
 489
 490 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 491 {
 492         make_pure(this);
 493         float newspectatee_status;
 494
 495         int f = ReadByte();
 496
 497         scoreboard_showscores_force = (f & BIT(0));
 498
 499         if(f & BIT(1))
 500         {
 501                 newspectatee_status = ReadByte();
 502                 if(newspectatee_status == player_localnum + 1)
 503                         newspectatee_status = -1; // observing
 504         }
 505         else
 506                 newspectatee_status = 0;
 507
 508         spectatorbutton_zoom = (f & BIT(2));
 509
 510         if(f & BIT(4))
 511         {
 512                 num_spectators = ReadByte();
 513
 514                 float i, slot;
 515
 516                 for(i = 0; i < MAX_SPECTATORS; ++i)
 517                         spectatorlist[i] = 0; // reset list first
 518
 519                 for(i = 0; i < num_spectators; ++i)
 520                 {
 521                         slot = ReadByte();
 522                         spectatorlist[i] = slot - 1;
 523                 }
 524         }
 525
 526         return = true;
 527
 528         if(newspectatee_status != spectatee_status)
 529         {
 530                 // clear race stuff
 531                 race_laptime = 0;
 532                 race_checkpointtime = 0;
 533                 hud_dynamic_shake_factor = -1;
 534         }
 535         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 536         {
 537                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 538                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 539                 )
 540                         prev_p_health = -1;
 541                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 542                         prev_health = -1;
 543         }
 544         spectatee_status = newspectatee_status;
 545
 546         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 547 }
 548
 549 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 550 {
 551         make_pure(this);
 552         int i, j, b, f;
 553
 554         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 555
 556         if(!(nags & BIT(2)))
 557         {
 558                 if(vote_called_vote)
 559                         strunzone(vote_called_vote);
 560                 vote_called_vote = string_null;
 561                 vote_active = 0;
 562         }
 563         else
 564         {
 565                 vote_active = 1;
 566         }
 567
 568         if(nags & BIT(6))
 569         {
 570                 vote_yescount = ReadByte();
 571                 vote_nocount = ReadByte();
 572                 vote_needed = ReadByte();
 573                 vote_highlighted = ReadChar();
 574         }
 575
 576         if(nags & BIT(7))
 577         {
 578                 if(vote_called_vote)
 579                         strunzone(vote_called_vote);
 580                 vote_called_vote = strzone(ReadString());
 581         }
 582
 583         if(nags & 1)
 584         {
 585                 for(j = 0; j < maxclients; ++j)
 586                         if(playerslots[j])
 587                                 playerslots[j].ready = 1;
 588                 for(i = 1; i <= maxclients; i += 8)
 589                 {
 590                         f = ReadByte();
 591                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 592                                 if (!(f & b))
 593                                         if(playerslots[j])
 594                                                 playerslots[j].ready = 0;
 595                 }
 596         }
 597
 598         return = true;
 599
 600         ready_waiting = (nags & BIT(0));
 601         ready_waiting_for_me = (nags & BIT(1));
 602         vote_waiting = (nags & BIT(2));
 603         vote_waiting_for_me = (nags & BIT(3));
 604         warmup_stage = (nags & BIT(4));
 605 }
 606
 607 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 608 {
 609         make_pure(this);
 610         int sf = 0;
 611         serialize(byte, 0, sf);
 612         if (sf & 1) {
 613                 for (int j = 0; j < maxclients; ++j) {
 614                         if (playerslots[j]) {
 615                                 playerslots[j].eliminated = 1;
 616                         }
 617                 }
 618                 for (int i = 1; i <= maxclients; i += 8) {
 619                         int f = 0;
 620                         serialize(byte, 0, f);
 621                         for (int b = 0; b < 8; ++b) {
 622                                 if (f & BIT(b)) continue;
 623                                 int j = i - 1 + b;
 624                                 if (playerslots[j]) {
 625                                         playerslots[j].eliminated = 0;
 626                                 }
 627                         }
 628                 }
 629         }
 630         return true;
 631 }
 632
 633 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 634 {
 635         make_pure(this);
 636         prandom_debug();
 637         float s = ReadShort();
 638         psrandom(s);
 639         return true;
 640 }
 641
 642 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 643 {
 644         make_pure(this);
 645         int sf = ReadInt24_t();
 646         if (sf == 0) {
 647                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 648                         weapon_accuracy[w] = -1;
 649                 return true;
 650         }
 651
 652         int f = 1;
 653         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 654                 if (sf & f) {
 655                         int b = ReadByte();
 656                         if (b == 0)
 657                                 weapon_accuracy[w] = -1;
 658                         else if (b == 255)
 659                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 660                         else
 661                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 662                 }
 663                 f = (f == 0x800000) ? 1 : f * 2;
 664         }
 665         return true;
 666 }
 667
 668 void Spawn_Draw(entity this)
 669 {
 670         if(this.alpha <= 0)
 671                 return;
 672
 673         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 674 }
 675
 676 void Spawn_PreDraw(entity this)
 677 {
 678         float alph;
 679         vector org = getpropertyvec(VF_ORIGIN);
 680         if(this.fade_start)
 681         {
 682                 if(vdist(org - this.origin, >, this.fade_end))
 683                         alph = 0; // save on some processing
 684                 else if(vdist(org - this.origin, <, this.fade_start))
 685                         alph = 1; // more processing saved
 686                 else
 687                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
 688         }
 689         else
 690                 alph = 1;
 691         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
 692         this.alpha = alph;
 693         if(alph <= 0)
 694                 this.drawmask = 0;
 695         else
 696                 this.drawmask = MASK_NORMAL;
 697 }
 698
 699 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 700 {
 701         float teamnum = (ReadByte() - 1);
 702         vector spn_origin = ReadVector();
 703
 704         this.team = (teamnum + 1);
 705
 706         //if(is_new)
 707         //{
 708                 this.origin = spn_origin;
 709                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 710                 //droptofloor();
 711
 712                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 713                 {
 714                         this.mdl = "models/spawnpoint.md3";
 715                         this.colormod = Team_ColorRGB(teamnum);
 716                         precache_model(this.mdl);
 717                         setmodel(this, this.mdl);
 718                         this.drawmask = MASK_NORMAL;
 719                         //this.move_movetype = MOVETYPE_NOCLIP;
 720                         //this.draw = Spawn_Draw;
 721                         IL_PUSH(g_drawables, this);
 722                 }*/
 723                 if(autocvar_cl_spawn_point_particles)
 724                 {
 725                         if(teamplay)
 726                         {
 727                                 switch(teamnum)
 728                                 {
 729                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 730                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 731                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 732                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 733                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 734                                 }
 735                         }
 736                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 737
 738                         this.draw = Spawn_Draw;
 739                         if (is_new) IL_PUSH(g_drawables, this);
 740                         setpredraw(this, Spawn_PreDraw);
 741                         this.fade_start = autocvar_cl_spawn_point_dist_min;
 742                         this.fade_end = autocvar_cl_spawn_point_dist_max;
 743                 }
 744         //}
 745
 746         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 747         return true;
 748 }
 749
 750 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 751 {
 752         // If entnum is 0, ONLY do the local spawn actions
 753         // this way the server can disable the sending of
 754         // spawn origin or such to clients if wanted.
 755         float entnum = ReadByte();
 756
 757         if(entnum)
 758         {
 759                 this.origin = ReadVector();
 760
 761                 if(is_new)
 762                 {
 763                         float teamnum = entcs_GetTeam(entnum - 1);
 764
 765                         if(autocvar_cl_spawn_event_particles)
 766                         {
 767                                 switch(teamnum)
 768                                 {
 769                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 770                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 771                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 772                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 773                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 774                                 }
 775                         }
 776                         if(autocvar_cl_spawn_event_sound)
 777                         {
 778                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 779                         }
 780                 }
 781         }
 782         return = true;
 783
 784         // local spawn actions
 785         if(is_new && (!entnum || (entnum == player_localentnum)))
 786         {
 787                 zoomin_effect = 1;
 788                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 789
 790                 if(autocvar_cl_unpress_zoom_on_spawn)
 791                 {
 792                         localcmd("-zoom\n");
 793                         button_zoom = false;
 794                 }
 795                 HUD_Radar_Hide_Maximized();
 796         }
 797         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 798 }
 799
 800 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 801 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 802 void CSQC_Ent_Update(entity this, bool isnew)
 803 {
 804         this.sourceLoc = __FILE__ ":" STR(__LINE__);
 805         int t = ReadByte();
 806
 807         // set up the "time" global for received entities to be correct for interpolation purposes
 808         float savetime = time;
 809         if(servertime)
 810         {
 811                 time = servertime;
 812         }
 813         else
 814         {
 815                 serverprevtime = time;
 816                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 817                 time = serverprevtime + serverdeltatime;
 818         }
 819
 820 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 821         if (this.enttype)
 822         {
 823                 if (t != this.enttype || isnew)
 824                 {
 825                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 826                         Ent_Remove(this);
 827                         clearentity(this);
 828                         isnew = true;
 829                 }
 830         }
 831         else
 832         {
 833                 if (!isnew)
 834                 {
 835                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 836                         isnew = true;
 837                 }
 838         }
 839 #endif
 840         this.enttype = t;
 841         bool done = false;
 842         FOREACH(LinkedEntities, it.m_id == t, {
 843                 if (isnew) this.classname = it.netname;
 844                 if (autocvar_developer_csqcentities)
 845             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 846                 done = it.m_read(this, NULL, isnew);
 847                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 848                 break;
 849         });
 850         time = savetime;
 851         if (!done)
 852         {
 853                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 854         }
 855 }
 856
 857 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 858 // used when an entity changes its type. For an entity that someone interacts
 859 // with others, make sure it can no longer do so.
 860 void Ent_Remove(entity this)
 861 {
 862         if(this.entremove) this.entremove(this);
 863
 864         if(this.skeletonindex)
 865         {
 866                 skel_delete(this.skeletonindex);
 867                 this.skeletonindex = 0;
 868         }
 869
 870         if(this.snd_looping > 0)
 871         {
 872                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 873                 this.snd_looping = 0;
 874         }
 875
 876         this.enttype = 0;
 877         this.classname = "";
 878         this.draw = func_null;
 879         this.entremove = func_null;
 880         // TODO possibly set more stuff to defaults
 881 }
 882 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 883 void CSQC_Ent_Remove(entity this)
 884 {
 885         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 886         if (wasfreed(this))
 887         {
 888                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 889                 return;
 890         }
 891         if (this.enttype) Ent_Remove(this);
 892         delete(this);
 893 }
 894
 895 void Gamemode_Init()
 896 {
 897         if (!isdemo())
 898         {
 899                 if(!(calledhooks & HOOK_START))
 900                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 901                 calledhooks |= HOOK_START;
 902         }
 903 }
 904 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 905 void CSQC_Parse_StuffCmd(string strMessage)
 906 {
 907         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 908         localcmd(strMessage);
 909 }
 910 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 911 void CSQC_Parse_Print(string strMessage)
 912 {
 913         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 914         print(ColorTranslateRGB(strMessage));
 915 }
 916
 917 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 918 void CSQC_Parse_CenterPrint(string strMessage)
 919 {
 920         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 921         centerprint_hud(strMessage);
 922 }
 923
 924 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 925 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 926 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 927 bool CSQC_Parse_TempEntity()
 928 {
 929         // Acquire TE ID
 930         int nTEID = ReadByte();
 931
 932         FOREACH(TempEntities, it.m_id == nTEID, {
 933                 if (autocvar_developer_csqcentities)
 934                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 935                 return it.m_read(NULL, NULL, true);
 936         });
 937
 938         if (autocvar_developer_csqcentities)
 939                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 940
 941         // No special logic for this temporary entity; return 0 so the engine can handle it
 942         return false;
 943 }
 944
 945 string forcefog;
 946 void Fog_Force()
 947 {
 948         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 949                 localcmd("\nr_drawfog 0\n");
 950         else if (forcefog != "")
 951                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 952 }
 953
 954 void Gamemode_Init();
 955 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 956 {
 957         make_pure(this);
 958         gametype = ReadRegistered(Gametypes);
 959         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 960         HUD_ModIcons_SetFunc();
 961         FOREACH(Scores, true, {
 962                 if (scores_label(it)) strunzone(scores_label(it));
 963                 scores_label(it) = strzone(ReadString());
 964                 scores_flags(it) = ReadByte();
 965         });
 966         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 967         {
 968                 if (teamscores_label(i)) strunzone(teamscores_label(i));
 969                 teamscores_label(i) = strzone(ReadString());
 970                 teamscores_flags(i) = ReadByte();
 971         }
 972         return = true;
 973         Scoreboard_InitScores();
 974         Gamemode_Init();
 975 }
 976
 977 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 978 {
 979         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 980
 981         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 982         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 983         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 984         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 985         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 986         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 987         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 988         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 989
 990         if (forcefog) strunzone(forcefog);
 991         forcefog = strzone(ReadString());
 992
 993         armorblockpercent = ReadByte() / 255.0;
 994         damagepush_speedfactor = ReadByte() / 255.0;
 995
 996         serverflags = ReadByte();
 997
 998         g_trueaim_minrange = ReadCoord();
 999
1000         return = true;
1001
1002         MUTATOR_CALLHOOK(Ent_Init);
1003
1004         if (!postinit) PostInit();
1005 }
1006
1007 float GetSpeedUnitFactor(int speed_unit)
1008 {
1009         switch(speed_unit)
1010         {
1011                 default:
1012                 case 1:
1013                         return 1.0;
1014                 case 2:
1015                         return 0.0254;
1016                 case 3:
1017                         return 0.0254 * 3.6;
1018                 case 4:
1019                         return 0.0254 * 3.6 * 0.6213711922;
1020                 case 5:
1021                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1022         }
1023 }
1024
1025 string GetSpeedUnit(int speed_unit)
1026 {
1027         switch(speed_unit)
1028         {
1029                 default:
1030                 case 1:
1031                         return _(" qu/s");
1032                 case 2:
1033                         return _(" m/s");
1034                 case 3:
1035                         return _(" km/h");
1036                 case 4:
1037                         return _(" mph");
1038                 case 5:
1039                         return _(" knots");
1040         }
1041 }
1042
1043 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1044 {
1045         int b = ReadByte();
1046
1047         switch (b)
1048         {
1049                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1050                         race_checkpoint = ReadByte();
1051                         race_time = ReadInt24_t();
1052                         race_previousbesttime = ReadInt24_t();
1053                         race_mypreviousbesttime = ReadInt24_t();
1054                         if(race_previousbestname)
1055                                 strunzone(race_previousbestname);
1056                         string pbestname = ReadString();
1057                         if(autocvar_cl_race_cptimes_onlyself)
1058                         {
1059                                 race_previousbesttime = race_mypreviousbesttime;
1060                                 race_mypreviousbesttime = 0;
1061                                 race_previousbestname = strzone("");
1062                         }
1063                         else
1064                                 race_previousbestname = strzone(pbestname);
1065
1066                         race_checkpointtime = time;
1067
1068                         if(race_checkpoint == 0 || race_checkpoint == 254)
1069                         {
1070                                 race_penaltyaccumulator = 0;
1071                                 race_laptime = time; // valid
1072                         }
1073                         break;
1074
1075                 case RACE_NET_CHECKPOINT_CLEAR:
1076                         race_laptime = 0;
1077                         race_checkpointtime = 0;
1078                         break;
1079
1080                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1081                         race_laptime = ReadCoord();
1082                         race_checkpointtime = -99999;
1083                         // fall through
1084                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1085                         race_nextcheckpoint = ReadByte();
1086
1087                         race_nextbesttime = ReadInt24_t();
1088                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1089                                 race_mybesttime = ReadInt24_t();
1090                         if(race_nextbestname)
1091                                 strunzone(race_nextbestname);
1092                         string newname = ReadString();
1093                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1094                         {
1095                                 race_nextbesttime = race_mybesttime;
1096                                 race_mybesttime = 0;
1097                                 race_nextbestname = strzone("");
1098                         }
1099                         else
1100                                 race_nextbestname = strzone(newname);
1101                         break;
1102
1103                 case RACE_NET_CHECKPOINT_HIT_RACE:
1104                         race_mycheckpoint = ReadByte();
1105                         race_mycheckpointtime = time;
1106                         race_mycheckpointdelta = ReadInt24_t();
1107                         race_mycheckpointlapsdelta = ReadByte();
1108                         if(race_mycheckpointlapsdelta >= 128)
1109                                 race_mycheckpointlapsdelta -= 256;
1110                         if(race_mycheckpointenemy)
1111                                 strunzone(race_mycheckpointenemy);
1112                         int who = ReadByte();
1113                         if(who)
1114                                 race_mycheckpointenemy = strzone(entcs_GetName(who - 1));
1115                         else
1116                                 race_mycheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1117                         break;
1118
1119                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1120                         race_othercheckpoint = ReadByte();
1121                         race_othercheckpointtime = time;
1122                         race_othercheckpointdelta = ReadInt24_t();
1123                         race_othercheckpointlapsdelta = ReadByte();
1124                         if(race_othercheckpointlapsdelta >= 128)
1125                                 race_othercheckpointlapsdelta -= 256;
1126                         if(race_othercheckpointenemy)
1127                                 strunzone(race_othercheckpointenemy);
1128                         int what = ReadByte();
1129                         if(what)
1130                                 race_othercheckpointenemy = strzone(entcs_GetName(what - 1));
1131                         else
1132                                 race_othercheckpointenemy = strzone(""); // TODO: maybe string_null works fine here?
1133                         break;
1134
1135                 case RACE_NET_PENALTY_RACE:
1136                         race_penaltyeventtime = time;
1137                         race_penaltytime = ReadShort();
1138                         //race_penaltyaccumulator += race_penaltytime;
1139                         if(race_penaltyreason)
1140                                 strunzone(race_penaltyreason);
1141                         race_penaltyreason = strzone(ReadString());
1142                         break;
1143
1144                 case RACE_NET_PENALTY_QUALIFYING:
1145                         race_penaltyeventtime = time;
1146                         race_penaltytime = ReadShort();
1147                         race_penaltyaccumulator += race_penaltytime;
1148                         if(race_penaltyreason)
1149                                 strunzone(race_penaltyreason);
1150                         race_penaltyreason = strzone(ReadString());
1151                         break;
1152
1153                 case RACE_NET_SERVER_RECORD:
1154                         race_server_record = ReadInt24_t();
1155                         break;
1156                 case RACE_NET_SPEED_AWARD:
1157                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1158                         if(race_speedaward_holder)
1159                                 strunzone(race_speedaward_holder);
1160                         race_speedaward_holder = strzone(ReadString());
1161                         if(race_speedaward_unit)
1162                                 strunzone(race_speedaward_unit);
1163                         race_speedaward_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1164                         break;
1165                 case RACE_NET_SPEED_AWARD_BEST:
1166                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1167                         if(race_speedaward_alltimebest_holder)
1168                                 strunzone(race_speedaward_alltimebest_holder);
1169                         race_speedaward_alltimebest_holder = strzone(ReadString());
1170                         if(race_speedaward_alltimebest_unit)
1171                                 strunzone(race_speedaward_alltimebest_unit);
1172                         race_speedaward_alltimebest_unit = strzone(GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1173                         break;
1174                 case RACE_NET_SERVER_RANKINGS:
1175                         float prevpos, del;
1176             int pos = ReadShort();
1177                         prevpos = ReadShort();
1178                         del = ReadShort();
1179
1180                         // move other rankings out of the way
1181             int i;
1182                         if (prevpos) {
1183                                 for (i=prevpos-1;i>pos-1;--i) {
1184                                         grecordtime[i] = grecordtime[i-1];
1185                                         if(grecordholder[i])
1186                                                 strunzone(grecordholder[i]);
1187                                         grecordholder[i] = strzone(grecordholder[i-1]);
1188                                 }
1189                         } else if (del) { // a record has been deleted by the admin
1190                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1191                                         if (i == RANKINGS_CNT-1) { // clear out last record
1192                                                 grecordtime[i] = 0;
1193                                                 if (grecordholder[i])
1194                                                         strunzone(grecordholder[i]);
1195                                                 grecordholder[i] = string_null;
1196                                         }
1197                                         else {
1198                                                 grecordtime[i] = grecordtime[i+1];
1199                                                 if (grecordholder[i])
1200                                                         strunzone(grecordholder[i]);
1201                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1202                                         }
1203                                 }
1204                         } else { // player has no ranked record yet
1205                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1206                                         grecordtime[i] = grecordtime[i-1];
1207                                         if(grecordholder[i])
1208                                                 strunzone(grecordholder[i]);
1209                                         grecordholder[i] = strzone(grecordholder[i-1]);
1210                                 }
1211                         }
1212
1213                         // store new ranking
1214                         if(grecordholder[pos-1] != "")
1215                                 strunzone(grecordholder[pos-1]);
1216                         grecordholder[pos-1] = strzone(ReadString());
1217                         grecordtime[pos-1] = ReadInt24_t();
1218                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1219                                 race_myrank = pos;
1220                         break;
1221                 case RACE_NET_SERVER_STATUS:
1222                         race_status = ReadShort();
1223                         if(race_status_name)
1224                                 strunzone(race_status_name);
1225                         race_status_name = strzone(ReadString());
1226         }
1227         return true;
1228 }
1229
1230 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1231 {
1232         teamnagger = 1;
1233         return true;
1234 }
1235
1236 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1237 {
1238         int i = ReadByte();
1239         int pi = ReadShort();
1240         int pl = ReadByte();
1241         int ml = ReadByte();
1242         return = true;
1243         entity e = playerslots[i];
1244         if (!e) return;
1245         e.ping = pi;
1246         e.ping_packetloss = pl / 255.0;
1247         e.ping_movementloss = ml / 255.0;
1248 }
1249
1250 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1251 {
1252         complain_weapon = ReadByte();
1253         complain_weapon_type = ReadByte();
1254         return = true;
1255
1256         complain_weapon_time = time;
1257         weapontime = time; // ping the weapon panel
1258
1259         switch(complain_weapon_type)
1260         {
1261                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1262                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1263                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1264         }
1265 }
1266
1267 string _getcommandkey(string cmd_name, string command, bool forcename)
1268 {
1269         string keys;
1270         float n, j, k, l = 0;
1271
1272         if (!autocvar_hud_showbinds)
1273                 return cmd_name;
1274
1275         keys = db_get(binddb, command);
1276         if (keys == "")
1277         {
1278                 bool joy_active = cvar("joy_active");
1279                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1280                 for(j = 0; j < n; ++j)
1281                 {
1282                         k = stof(argv(j));
1283                         if(k != -1)
1284                         {
1285                                 string key = keynumtostring(k);
1286                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1287                                         continue;
1288
1289                                 if (keys == "")
1290                                         keys = key;
1291                                 else
1292                                         keys = strcat(keys, ", ", key);
1293
1294                                 ++l;
1295                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1296                                         break;
1297                         }
1298
1299                 }
1300                 if (keys == "")
1301                         keys = "NO_KEY";
1302                 db_put(binddb, command, keys);
1303         }
1304
1305         if (keys == "NO_KEY") {
1306                 if (autocvar_hud_showbinds > 1)
1307                         return sprintf(_("%s (not bound)"), cmd_name);
1308                 else
1309                         return cmd_name;
1310         }
1311         else if (autocvar_hud_showbinds > 1 || forcename)
1312                 return sprintf("%s (%s)", cmd_name, keys);
1313         else
1314                 return keys;
1315 }