qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/centerprint.qh"
  15 #include "hud/panel/scoreboard.qh"
  16 #include "hud/panel/quickmenu.qh"
  17 #include "shownames.qh"
  18 #include "view.qh"
  19 #include <common/t_items.qh>
  20 #include "weapons/projectile.qh"
  21 #include <common/deathtypes/all.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/minigames/cl_minigames.qh>
  25 #include <common/minigames/cl_minigames_hud.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/scores.qh>
  29 #include <common/mapobjects/_mod.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 171
 172         if (!isdemo())
 173         {
 174                 if (!(calledhooks & HOOK_START))
 175                         localcmd("\n_cl_hook_gamestart nop\n");
 176                 if (!(calledhooks & HOOK_END))
 177                         localcmd("\ncl_hook_gameend\n");
 178         }
 179
 180         localcmd("\ncl_hook_shutdown\n");
 181
 182         localcmd("\n-button12\n");
 183
 184         deactivate_minigame();
 185         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 186
 187         ReplicateVars(true); // destroy
 188 }
 189
 190 .float has_team;
 191 bool SetTeam(entity o, int Team)
 192 {
 193         TC(int, Team);
 194         //devassert_once(Team);
 195         entity tm;
 196         if(teamplay)
 197         {
 198                 switch(Team)
 199                 {
 200                         case -1:
 201                         case NUM_TEAM_1:
 202                         case NUM_TEAM_2:
 203                         case NUM_TEAM_3:
 204                         case NUM_TEAM_4:
 205                                 break;
 206                         default:
 207                                 if(GetTeam(Team, false) == NULL)
 208                                 {
 209                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 210                                         Team = NUM_SPECTATOR;
 211                                 }
 212                                 break;
 213                 }
 214         }
 215         else
 216         {
 217                 switch(Team)
 218                 {
 219                         case -1:
 220                         case 0:
 221                                 break;
 222                         default:
 223                                 if(GetTeam(Team, false) == NULL)
 224                                 {
 225                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 226                                         Team = NUM_SPECTATOR;
 227                                 }
 228                                 break;
 229                 }
 230         }
 231         if(Team == -1) // leave
 232         {
 233                 if(o.has_team)
 234                 {
 235                         tm = GetTeam(o.team, false);
 236                         tm.team_size -= 1;
 237                         o.has_team = 0;
 238                         return true;
 239                 }
 240         }
 241         else
 242         {
 243                 if (!o.has_team)
 244                 {
 245                         o.team = Team;
 246                         tm = GetTeam(Team, true);
 247                         tm.team_size += 1;
 248                         o.has_team = 1;
 249                         return true;
 250                 }
 251                 else if(Team != o.team)
 252                 {
 253                         tm = GetTeam(o.team, false);
 254                         tm.team_size -= 1;
 255                         o.team = Team;
 256                         tm = GetTeam(Team, true);
 257                         tm.team_size += 1;
 258                         return true;
 259                 }
 260         }
 261         return false;
 262 }
 263
 264 void Playerchecker_Think(entity this)
 265 {
 266         int i;
 267         entity e;
 268         for(i = 0; i < maxclients; ++i)
 269         {
 270                 e = playerslots[i];
 271                 if(entcs_GetName(i) == "")
 272                 {
 273                         if(e.sort_prev)
 274                         {
 275                                 // player disconnected
 276                                 SetTeam(e, -1);
 277                                 RemovePlayer(e);
 278                                 e.sort_prev = NULL;
 279                                 //e.gotscores = 0;
 280                         }
 281                 }
 282                 else
 283                 {
 284                         if (!e.sort_prev)
 285                         {
 286                                 // player connected
 287                                 if (!e)
 288                                 {
 289                                         playerslots[i] = e = new_pure(playerslot);
 290                                 }
 291                                 e.sv_entnum = i;
 292                                 e.ping = 0;
 293                                 e.ping_packetloss = 0;
 294                                 e.ping_movementloss = 0;
 295                                 //e.gotscores = 0; // we might already have the scores...
 296                                 int t = entcs_GetScoreTeam(i);
 297                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 298                                 RegisterPlayer(e);
 299                                 Scoreboard_UpdatePlayerPos(e);
 300                         }
 301                 }
 302         }
 303         this.nextthink = time + 0.2;
 304 }
 305
 306 void PostInit()
 307 {
 308         entity playerchecker = new_pure(playerchecker);
 309         setthink(playerchecker, Playerchecker_Think);
 310         playerchecker.nextthink = time + 0.2;
 311
 312         TrueAim_Init();
 313
 314         postinit = true;
 315 }
 316
 317 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 318 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 319 // All keys are in ascii.
 320 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 321 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 322 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 323 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 324 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 325 {
 326         TC(int, bInputType);
 327         bool override = false;
 328         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 329         if (override)
 330                 return true;
 331
 332         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 333
 334         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 335
 336         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 337
 338         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 339
 340         if(override)
 341                 return true;
 342
 343         return false;
 344 }
 345
 346 // END REQUIRED CSQC FUNCTIONS
 347 // --------------------------------------------------------------------------
 348
 349 // --------------------------------------------------------------------------
 350 // BEGIN OPTIONAL CSQC FUNCTIONS
 351
 352 void Ent_RemovePlayerScore(entity this)
 353 {
 354         if(this.owner) {
 355                 SetTeam(this.owner, -1);
 356                 this.owner.gotscores = 0;
 357                 FOREACH(Scores, true, {
 358                         this.owner.(scores(it)) = 0; // clear all scores
 359                 });
 360         }
 361 }
 362
 363 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 364 {
 365         make_pure(this);
 366         entity o;
 367
 368         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 369         // (no I've never heard of M-x replace-string, sed, or anything like that)
 370         bool isNew = !this.owner; // workaround for DP bug
 371         int n = ReadByte()-1;
 372
 373 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 374         if(!isNew && n != this.sv_entnum)
 375         {
 376                 //print("A CSQC entity changed its owner!\n");
 377                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 378                 isNew = true;
 379                 Ent_Remove(this);
 380         }
 381 #endif
 382
 383         this.sv_entnum = n;
 384
 385         o = playerslots[this.sv_entnum];
 386         if (!o)
 387         {
 388                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 389         }
 390         this.owner = o;
 391         o.sv_entnum = this.sv_entnum;
 392         o.gotscores = 1;
 393
 394         //if (!o.sort_prev)
 395         //      RegisterPlayer(o);
 396         //playerchecker will do this for us later, if it has not already done so
 397
 398         int sf = ReadShort();
 399         int lf = ReadShort();
 400         FOREACH(Scores, true, {
 401                 int p = 1 << (i % 16);
 402                 if (sf & p)
 403                 {
 404                         if (lf & p)
 405                                 o.(scores(it)) = ReadInt24_t();
 406                         else
 407                                 o.(scores(it)) = ReadChar();
 408                 }
 409         });
 410
 411         return = true;
 412
 413         if(o.sort_prev)
 414                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 415
 416         this.entremove = Ent_RemovePlayerScore;
 417 }
 418
 419 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 420 {
 421         make_pure(this);
 422         int i;
 423
 424         this.team = ReadByte();
 425         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 426
 427 #if MAX_TEAMSCORE <= 8
 428         int sf = ReadByte();
 429         int lf = ReadByte();
 430 #else
 431         int sf = ReadShort();
 432         int lf = ReadShort();
 433 #endif
 434         for(i = 0; i < MAX_TEAMSCORE; ++i)
 435                 if(sf & BIT(i))
 436                 {
 437                         if(lf & BIT(i))
 438                                 o.(teamscores(i)) = ReadInt24_t();
 439                         else
 440                                 o.(teamscores(i)) = ReadChar();
 441                 }
 442
 443         return = true;
 444
 445         Scoreboard_UpdateTeamPos(o);
 446 }
 447
 448 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 449 {
 450         make_pure(this);
 451         float newspectatee_status;
 452
 453         int f = ReadByte();
 454
 455         scoreboard_showscores_force = (f & BIT(0));
 456
 457         if(f & BIT(1))
 458         {
 459                 newspectatee_status = ReadByte();
 460                 if(newspectatee_status == player_localnum + 1)
 461                         newspectatee_status = -1; // observing
 462         }
 463         else
 464                 newspectatee_status = 0;
 465
 466         spectatorbutton_zoom = (f & BIT(2));
 467
 468         if(f & BIT(4))
 469         {
 470                 num_spectators = ReadByte();
 471
 472                 float i, slot;
 473
 474                 for(i = 0; i < MAX_SPECTATORS; ++i)
 475                         spectatorlist[i] = 0; // reset list first
 476
 477                 for(i = 0; i < num_spectators; ++i)
 478                 {
 479                         slot = ReadByte();
 480                         spectatorlist[i] = slot - 1;
 481                 }
 482         }
 483
 484         return = true;
 485
 486         if(newspectatee_status != spectatee_status)
 487         {
 488                 // clear race stuff
 489                 race_laptime = 0;
 490                 race_checkpointtime = 0;
 491                 hud_dynamic_shake_factor = -1;
 492                 spectatee_status_changed_time = time;
 493         }
 494         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 495         {
 496                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 497                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 498                 )
 499                         prev_p_health = -1;
 500                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 501                         prev_health = -1;
 502         }
 503         spectatee_status = newspectatee_status;
 504
 505         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 506 }
 507
 508 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 509 {
 510         make_pure(this);
 511         int i, j, b, f;
 512
 513         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 514
 515         if(!(nags & BIT(2)))
 516         {
 517                 strfree(vote_called_vote);
 518                 vote_active = 0;
 519         }
 520         else
 521         {
 522                 vote_active = 1;
 523         }
 524
 525         if(nags & BIT(6))
 526         {
 527                 vote_yescount = ReadByte();
 528                 vote_nocount = ReadByte();
 529                 vote_needed = ReadByte();
 530                 vote_highlighted = ReadChar();
 531         }
 532
 533         if(nags & BIT(7))
 534         {
 535                 strcpy(vote_called_vote, ReadString());
 536         }
 537
 538         if(nags & 1)
 539         {
 540                 for(j = 0; j < maxclients; ++j)
 541                         if(playerslots[j])
 542                                 playerslots[j].ready = true;
 543                 for(i = 1; i <= maxclients; i += 8)
 544                 {
 545                         f = ReadByte();
 546                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 547                                 if (!(f & b))
 548                                         if(playerslots[j])
 549                                                 playerslots[j].ready = false;
 550                 }
 551         }
 552
 553         return = true;
 554
 555         ready_waiting = (nags & BIT(0));
 556         ready_waiting_for_me = (nags & BIT(1));
 557         vote_waiting = (nags & BIT(2));
 558         vote_waiting_for_me = (nags & BIT(3));
 559         warmup_stage = (nags & BIT(4));
 560 }
 561
 562 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 563 {
 564         make_pure(this);
 565         int sf = 0;
 566         serialize(byte, 0, sf);
 567         if (sf & 1) {
 568                 for (int j = 0; j < maxclients; ++j) {
 569                         if (playerslots[j]) {
 570                                 playerslots[j].eliminated = true;
 571                         }
 572                 }
 573                 for (int i = 1; i <= maxclients; i += 8) {
 574                         int f = 0;
 575                         serialize(byte, 0, f);
 576                         for (int b = 0; b < 8; ++b) {
 577                                 if (f & BIT(b)) continue;
 578                                 int j = i - 1 + b;
 579                                 if (playerslots[j]) {
 580                                         playerslots[j].eliminated = false;
 581                                 }
 582                         }
 583                 }
 584         }
 585         return true;
 586 }
 587
 588 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 589 {
 590         make_pure(this);
 591         prandom_debug();
 592         float s = ReadShort();
 593         psrandom(s);
 594         return true;
 595 }
 596
 597 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 598 {
 599         make_pure(this);
 600         int sf = ReadInt24_t();
 601         if (sf == 0) {
 602                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 603                         weapon_accuracy[w] = -1;
 604                 return true;
 605         }
 606
 607         int f = 1;
 608         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 609                 if (sf & f) {
 610                         int b = ReadByte();
 611                         if (b == 0)
 612                                 weapon_accuracy[w] = -1;
 613                         else if (b == 255)
 614                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 615                         else
 616                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 617                 }
 618                 f = (f == 0x800000) ? 1 : f * 2;
 619         }
 620         return true;
 621 }
 622
 623 void Spawn_Draw(entity this)
 624 {
 625         bool dodraw = autocvar_cl_spawn_point_particles;
 626         if(dodraw && autocvar_cl_spawn_point_dist_max)
 627         {
 628                 vector org = getpropertyvec(VF_ORIGIN);
 629                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 630         }
 631
 632         if(dodraw)
 633                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 634 }
 635
 636 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 637 {
 638         float teamnum = (ReadByte() - 1);
 639         vector spn_origin = ReadVector();
 640
 641         this.team = (teamnum + 1);
 642
 643         //if(is_new)
 644         //{
 645                 this.origin = spn_origin;
 646                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 647                 //droptofloor();
 648
 649                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 650                 {
 651                         this.mdl = "models/spawnpoint.md3";
 652                         this.colormod = Team_ColorRGB(teamnum);
 653                         precache_model(this.mdl);
 654                         setmodel(this, this.mdl);
 655                         this.drawmask = MASK_NORMAL;
 656                         //this.move_movetype = MOVETYPE_NOCLIP;
 657                         //this.draw = Spawn_Draw;
 658                         IL_PUSH(g_drawables, this);
 659                 }*/
 660                 this.draw = Spawn_Draw;
 661                 if (is_new) IL_PUSH(g_drawables, this);
 662         //}
 663
 664         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 665         return true;
 666 }
 667
 668 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 669 {
 670         // If entnum is 0, ONLY do the local spawn actions
 671         // this way the server can disable the sending of
 672         // spawn origin or such to clients if wanted.
 673         float entnum = ReadByte();
 674
 675         if(entnum)
 676         {
 677                 this.origin = ReadVector();
 678
 679                 if(is_new)
 680                 {
 681                         float teamnum = entcs_GetTeam(entnum - 1);
 682
 683                         if(autocvar_cl_spawn_event_particles)
 684                         {
 685                                 switch(teamnum)
 686                                 {
 687                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 688                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 689                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 690                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 691                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 692                                 }
 693                         }
 694                         if(autocvar_cl_spawn_event_sound)
 695                         {
 696                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 697                         }
 698                 }
 699         }
 700         return = true;
 701
 702         // local spawn actions
 703         if(is_new && (!entnum || (entnum == player_localentnum)))
 704         {
 705                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 706                 {
 707                         zoomin_effect = 1;
 708                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 709                 }
 710
 711                 if(autocvar_cl_unpress_zoom_on_spawn)
 712                 {
 713                         localcmd("-zoom\n");
 714                         button_zoom = false;
 715                 }
 716                 HUD_Radar_Hide_Maximized();
 717         }
 718         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 719 }
 720
 721 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 722 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 723 void CSQC_Ent_Update(entity this, bool isnew)
 724 {
 725         this.sourceLoc = __FILE__":"STR(__LINE__);
 726         int t = ReadByte();
 727
 728         // set up the "time" global for received entities to be correct for interpolation purposes
 729         float savetime = time;
 730         if(servertime)
 731         {
 732                 time = servertime;
 733         }
 734         else
 735         {
 736                 serverprevtime = time;
 737                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 738                 time = serverprevtime + serverdeltatime;
 739         }
 740
 741 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 742         if (this.enttype)
 743         {
 744                 if (t != this.enttype || isnew)
 745                 {
 746                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 747                         Ent_Remove(this);
 748                         clearentity(this);
 749                         isnew = true;
 750                 }
 751         }
 752         else
 753         {
 754                 if (!isnew)
 755                 {
 756                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 757                         isnew = true;
 758                 }
 759         }
 760 #endif
 761         this.enttype = t;
 762         bool done = false;
 763         FOREACH(LinkedEntities, it.m_id == t, {
 764                 if (isnew) this.classname = it.netname;
 765                 if (autocvar_developer_csqcentities)
 766             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 767                 done = it.m_read(this, NULL, isnew);
 768                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 769                 break;
 770         });
 771         time = savetime;
 772         if (!done)
 773         {
 774                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 775         }
 776 }
 777
 778 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 779 // used when an entity changes its type. For an entity that someone interacts
 780 // with others, make sure it can no longer do so.
 781 void Ent_Remove(entity this)
 782 {
 783         if(this.entremove) this.entremove(this);
 784
 785         if(this.skeletonindex)
 786         {
 787                 skel_delete(this.skeletonindex);
 788                 this.skeletonindex = 0;
 789         }
 790
 791         if(this.snd_looping > 0)
 792         {
 793                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 794                 this.snd_looping = 0;
 795         }
 796
 797         this.enttype = 0;
 798         this.classname = "";
 799         this.draw = func_null;
 800         this.entremove = func_null;
 801         // TODO possibly set more stuff to defaults
 802 }
 803 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 804 void CSQC_Ent_Remove(entity this)
 805 {
 806         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 807         if (wasfreed(this))
 808         {
 809                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 810                 return;
 811         }
 812         if (this.enttype) Ent_Remove(this);
 813         delete(this);
 814 }
 815
 816 void Gamemode_Init()
 817 {
 818         if (!isdemo())
 819         {
 820                 if(!(calledhooks & HOOK_START))
 821                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 822                 calledhooks |= HOOK_START;
 823         }
 824 }
 825 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 826 void CSQC_Parse_StuffCmd(string strMessage)
 827 {
 828         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 829         localcmd(strMessage);
 830 }
 831 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 832 void CSQC_Parse_Print(string strMessage)
 833 {
 834         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 835         print(ColorTranslateRGB(strMessage));
 836 }
 837
 838 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 839 void CSQC_Parse_CenterPrint(string strMessage)
 840 {
 841         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 842         centerprint_AddStandard(strMessage);
 843 }
 844
 845 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 846 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 847 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 848 bool CSQC_Parse_TempEntity()
 849 {
 850         // Acquire TE ID
 851         int nTEID = ReadByte();
 852
 853         FOREACH(TempEntities, it.m_id == nTEID, {
 854                 if (autocvar_developer_csqcentities)
 855                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 856                 return it.m_read(NULL, NULL, true);
 857         });
 858
 859         if (autocvar_developer_csqcentities)
 860                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 861
 862         // No special logic for this temporary entity; return 0 so the engine can handle it
 863         return false;
 864 }
 865
 866 string forcefog;
 867 void Fog_Force()
 868 {
 869         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 870                 localcmd("\nr_drawfog 0\n");
 871         else if (forcefog != "")
 872                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 873 }
 874
 875 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 876 {
 877         make_pure(this);
 878         gametype = ReadRegistered(Gametypes);
 879         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 880         HUD_ModIcons_SetFunc();
 881         FOREACH(Scores, true, {
 882                 strcpy(scores_label(it), ReadString());
 883                 scores_flags(it) = ReadByte();
 884         });
 885         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 886         {
 887                 strcpy(teamscores_label(i), ReadString());
 888                 teamscores_flags(i) = ReadByte();
 889         }
 890         return = true;
 891         Scoreboard_InitScores();
 892         Gamemode_Init();
 893 }
 894
 895 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 896 {
 897         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 898
 899         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 900         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 901         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 902         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 903         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 904         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 905         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 906         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 907
 908         strcpy(forcefog, ReadString());
 909
 910         armorblockpercent = ReadByte() / 255.0;
 911         damagepush_speedfactor = ReadByte() / 255.0;
 912
 913         serverflags = ReadByte();
 914
 915         g_trueaim_minrange = ReadCoord();
 916
 917         return = true;
 918
 919         MUTATOR_CALLHOOK(Ent_Init);
 920
 921         if (!postinit) PostInit();
 922 }
 923
 924 float GetSpeedUnitFactor(int speed_unit)
 925 {
 926         switch(speed_unit)
 927         {
 928                 default:
 929                 case 1: return 1.0;
 930                 case 2: return 0.0254;
 931                 case 3: return 0.0254 * 3.6;
 932                 case 4: return 0.0254 * 3.6 * 0.6213711922;
 933                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
 934         }
 935 }
 936
 937 string GetSpeedUnit(int speed_unit)
 938 {
 939         switch(speed_unit)
 940         {
 941                 // translator-friendly strings without the initial space
 942                 default:
 943                 case 1: return strcat(" ", _("qu/s"));
 944                 case 2: return strcat(" ", _("m/s"));
 945                 case 3: return strcat(" ", _("km/h"));
 946                 case 4: return strcat(" ", _("mph"));
 947                 case 5: return strcat(" ", _("knots"));
 948         }
 949 }
 950
 951 NET_HANDLE(TE_CSQC_RACE, bool isNew)
 952 {
 953         int b = ReadByte();
 954
 955         switch (b)
 956         {
 957                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 958                         race_checkpoint = ReadByte();
 959                         race_time = ReadInt24_t();
 960                         race_previousbesttime = ReadInt24_t();
 961                         race_mypreviousbesttime = ReadInt24_t();
 962                         string pbestname = ReadString();
 963                         if(autocvar_cl_race_cptimes_onlyself)
 964                         {
 965                                 race_previousbesttime = race_mypreviousbesttime;
 966                                 race_mypreviousbesttime = 0;
 967                                 strcpy(race_previousbestname, "");
 968                         }
 969                         else
 970                                 strcpy(race_previousbestname, pbestname);
 971
 972                         race_checkpointtime = time;
 973
 974                         if(race_checkpoint == 0 || race_checkpoint == 254)
 975                         {
 976                                 race_penaltyaccumulator = 0;
 977                                 race_laptime = time; // valid
 978                         }
 979                         break;
 980
 981                 case RACE_NET_CHECKPOINT_CLEAR:
 982                         race_laptime = 0;
 983                         race_checkpointtime = 0;
 984                         break;
 985
 986                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 987                         race_laptime = ReadCoord();
 988                         race_checkpointtime = -99999;
 989                         // fall through
 990                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 991                         race_nextcheckpoint = ReadByte();
 992
 993                         race_nextbesttime = ReadInt24_t();
 994                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
 995                                 race_mybesttime = ReadInt24_t();
 996                         string newname = ReadString();
 997                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
 998                         {
 999                                 race_nextbesttime = race_mybesttime;
1000                                 race_mybesttime = 0;
1001                                 strcpy(race_nextbestname, "");
1002                         }
1003                         else
1004                                 strcpy(race_nextbestname, newname);
1005                         break;
1006
1007                 case RACE_NET_CHECKPOINT_HIT_RACE:
1008                         race_mycheckpoint = ReadByte();
1009                         race_mycheckpointtime = time;
1010                         race_mycheckpointdelta = ReadInt24_t();
1011                         race_mycheckpointlapsdelta = ReadByte();
1012                         if(race_mycheckpointlapsdelta >= 128)
1013                                 race_mycheckpointlapsdelta -= 256;
1014                         int who = ReadByte();
1015                         if(who)
1016                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1017                         else
1018                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1019                         break;
1020
1021                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1022                         race_othercheckpoint = ReadByte();
1023                         race_othercheckpointtime = time;
1024                         race_othercheckpointdelta = ReadInt24_t();
1025                         race_othercheckpointlapsdelta = ReadByte();
1026                         if(race_othercheckpointlapsdelta >= 128)
1027                                 race_othercheckpointlapsdelta -= 256;
1028                         int what = ReadByte();
1029                         if(what)
1030                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1031                         else
1032                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1033                         break;
1034
1035                 case RACE_NET_PENALTY_RACE:
1036                 case RACE_NET_PENALTY_QUALIFYING:
1037                         race_penaltyeventtime = time;
1038                         race_penaltytime = ReadShort();
1039                         string reason = ReadString();
1040                         if (reason == "missing a checkpoint")
1041                                 reason = _("missing a checkpoint");
1042                         strcpy(race_penaltyreason, reason);
1043                         if (b == RACE_NET_PENALTY_QUALIFYING)
1044                                 race_penaltyaccumulator += race_penaltytime;
1045                         break;
1046
1047                 case RACE_NET_SERVER_RECORD:
1048                         race_server_record = ReadInt24_t();
1049                         break;
1050                 case RACE_NET_SPEED_AWARD:
1051                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1052                         strcpy(race_speedaward_holder, ReadString());
1053                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1054                         break;
1055                 case RACE_NET_SPEED_AWARD_BEST:
1056                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1057                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1058                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1059                         break;
1060                 case RACE_NET_RANKINGS_CNT:
1061                         RANKINGS_DISPLAY_CNT = ReadByte();
1062                         break;
1063                 case RACE_NET_SERVER_RANKINGS:
1064                         float prevpos, del;
1065                         int pos = ReadShort();
1066                         prevpos = ReadShort();
1067                         del = ReadShort();
1068
1069                         // move other rankings out of the way
1070                         int i;
1071                         if (prevpos) {
1072                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1073                                 for (i=m-1; i>pos-1; --i) {
1074                                         grecordtime[i] = grecordtime[i-1];
1075                                         strcpy(grecordholder[i], grecordholder[i-1]);
1076                                 }
1077                         } else if (del) { // a record has been deleted by the admin
1078                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1079                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1080                                                 grecordtime[i] = 0;
1081                                                 strfree(grecordholder[i]);
1082                                         }
1083                                         else {
1084                                                 grecordtime[i] = grecordtime[i+1];
1085                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1086                                         }
1087                                 }
1088                         } else { // player has no ranked record yet
1089                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1090                                         grecordtime[i] = grecordtime[i-1];
1091                                         strcpy(grecordholder[i], grecordholder[i-1]);
1092                                 }
1093                         }
1094
1095                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1096                                 // kick off the player who fell from the last displayed position
1097                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1098                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1099                         }
1100
1101                         // store new ranking
1102                         strcpy(grecordholder[pos-1], ReadString());
1103                         grecordtime[pos-1] = ReadInt24_t();
1104                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1105                                 race_myrank = pos;
1106                         break;
1107                 case RACE_NET_SERVER_STATUS:
1108                         race_status = ReadShort();
1109                         strcpy(race_status_name, ReadString());
1110         }
1111         return true;
1112 }
1113
1114 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1115 {
1116         teamnagger = 1;
1117         return true;
1118 }
1119
1120 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1121 {
1122         int i = ReadByte();
1123         int pi = ReadShort();
1124         int pl = ReadByte();
1125         int ml = ReadByte();
1126         return = true;
1127         entity e = playerslots[i];
1128         if (!e) return;
1129         e.ping = pi;
1130         e.ping_packetloss = pl / 255.0;
1131         e.ping_movementloss = ml / 255.0;
1132 }
1133
1134 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1135 {
1136         int weapon_id = ReadByte();
1137         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1138         complain_weapon_type = ReadByte();
1139         return = true;
1140
1141         complain_weapon_time = time;
1142         weapontime = time; // ping the weapon panel
1143
1144         switch(complain_weapon_type)
1145         {
1146                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1147                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1148                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1149         }
1150 }
1151
1152 string _getcommandkey(string cmd_name, string command, bool forcename)
1153 {
1154         string keys;
1155         float n, j, k, l = 0;
1156
1157         if (!autocvar_hud_showbinds)
1158                 return cmd_name;
1159
1160         keys = db_get(binddb, command);
1161         if (keys == "")
1162         {
1163                 bool joy_active = cvar("joy_active");
1164                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1165                 for(j = 0; j < n; ++j)
1166                 {
1167                         k = stof(argv(j));
1168                         if(k != -1)
1169                         {
1170                                 string key = keynumtostring(k);
1171                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1172                                         continue;
1173
1174                                 key = translate_key(key);
1175
1176                                 if (keys == "")
1177                                         keys = key;
1178                                 else
1179                                         keys = strcat(keys, ", ", key);
1180
1181                                 ++l;
1182                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1183                                         break;
1184                         }
1185
1186                 }
1187                 if (keys == "")
1188                         keys = "NO_KEY";
1189                 db_put(binddb, command, keys);
1190         }
1191
1192         if (keys == "NO_KEY") {
1193                 if (autocvar_hud_showbinds > 1)
1194                         return sprintf(_("%s (not bound)"), cmd_name);
1195                 else
1196                         return cmd_name;
1197         }
1198         else if (autocvar_hud_showbinds > 1 || forcename)
1199                 return sprintf("%s (%s)", cmd_name, keys);
1200         else
1201                 return keys;
1202 }