qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/items/items.qh>
  10 #include <client/mapvoting.qh>
  11 #include <client/mutators/_mod.qh>
  12 #include <client/shownames.qh>
  13 #include <client/view.qh>
  14 #include <client/weapons/projectile.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/effects/all.inc>
  17 #include <common/effects/all.qh>
  18 #include <common/effects/effect.qh>
  19 #include <common/effects/qc/_mod.qh>
  20 #include <common/ent_cs.qh>
  21 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/mapobjects/_mod.qh>
  25 #include <common/minigames/cl_minigames.qh>
  26 #include <common/minigames/cl_minigames_hud.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/scores.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  42 // Useful for precaching things
  43
  44 void CSQC_Init()
  45 {
  46         prvm_language = strzone(cvar_string("prvm_language"));
  47
  48 #ifdef WATERMARK
  49         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  50 #endif
  51
  52         {
  53                 int i = 0;
  54                 for ( ; i < 255; ++i)
  55                         if (getplayerkeyvalue(i, "viewentity") == "")
  56                                 break;
  57                 maxclients = i;
  58         }
  59
  60         // needs to be done so early because of the constants they create
  61         static_init();
  62         static_init_late();
  63         static_init_precache();
  64
  65         binddb = db_create();
  66         tempdb = db_create();
  67         ClientProgsDB = db_load("client.db");
  68
  69         draw_endBoldFont();
  70
  71         //registercommand("hud_configure");
  72         //registercommand("hud_save");
  73         //registercommand("menu_action");
  74
  75         ConsoleCommand_macro_init();
  76
  77         registercvar("hud_usecsqc", "1");
  78         registercvar("scoreboard_columns", "default");
  79
  80         registercvar("cl_nade_type", "3");
  81         registercvar("cl_pokenade_type", "zombie");
  82
  83         registercvar("cl_jumpspeedcap_min", "");
  84         registercvar("cl_jumpspeedcap_max", "");
  85
  86         registercvar("cl_shootfromfixedorigin", "");
  87
  88         registercvar("cl_multijump", "-1");
  89
  90         registercvar("cl_dodging", "0");
  91
  92         registercvar("cl_spawn_near_teammate", "1");
  93
  94         registercvar("cl_weapon_switch_reload", "1");
  95         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  96
  97         registercvar("cl_allow_uidranking", "1");
  98
  99         if(autocvar_cl_lockview)
 100                 cvar_set("cl_lockview", "0");
 101
 102         gametype = NULL;
 103
 104         postinit = false;
 105
 106         calledhooks = 0;
 107
 108         teams = Sort_Spawn();
 109         players = Sort_Spawn();
 110
 111         GetTeam(NUM_SPECTATOR, true); // add specs first
 112
 113         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 114                 weapon_accuracy[w] = -1;
 115
 116         // precaches
 117
 118         if(autocvar_cl_reticle)
 119         {
 120                 precache_pic("gfx/reticle_normal");
 121                 // weapon reticles are precached in weapon files
 122         }
 123
 124         {
 125                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 126                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 127                 shortmapname = mi_shortname;
 128
 129                 if (precache_pic(minimapname) == "")
 130                 {
 131                         // but maybe we have a non-clever minimap
 132                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 133                         if (precache_pic(minimapname) == "")
 134                                 minimapname = ""; // FAIL
 135                         else
 136                                 get_mi_min_max_texcoords(0); // load new texcoords
 137                 }
 138
 139                 mi_center = (mi_min + mi_max) * 0.5;
 140                 mi_scale = mi_max - mi_min;
 141                 minimapname = strzone(minimapname);
 142         }
 143
 144         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 145         LoadMenuSkinValues();
 146 }
 147
 148 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 149 void Shutdown()
 150 {
 151         WarpZone_Shutdown();
 152
 153         delete(teams);
 154         delete(players);
 155         db_close(binddb);
 156         db_close(tempdb);
 157         if(autocvar_cl_db_saveasdump)
 158                 db_dump(ClientProgsDB, "client.db");
 159         else
 160                 db_save(ClientProgsDB, "client.db");
 161         db_close(ClientProgsDB);
 162
 163         if(camera_active)
 164                 cvar_set("chase_active",ftos(chase_active_backup));
 165
 166         // unset the event chasecam's chase_active
 167         if(autocvar_chase_active < 0)
 168                 cvar_set("chase_active", "0");
 169
 170         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 171
 172         if (!isdemo())
 173         {
 174                 if (!(calledhooks & HOOK_START))
 175                         localcmd("\n_cl_hook_gamestart nop\n");
 176                 if (!(calledhooks & HOOK_END))
 177                         localcmd("\ncl_hook_gameend\n");
 178         }
 179
 180         localcmd("\ncl_hook_shutdown\n");
 181
 182         localcmd("\n-button12\n");
 183
 184         deactivate_minigame();
 185         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 186
 187         ReplicateVars(true); // destroy
 188 }
 189
 190 void AuditLists()
 191 {
 192         entity e;
 193         entity prev;
 194
 195         prev = players;
 196         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 197         {
 198                 if(prev != e.sort_prev)
 199                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 200         }
 201
 202         prev = teams;
 203         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 204         {
 205                 if(prev != e.sort_prev)
 206                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 207         }
 208 }
 209
 210 float RegisterPlayer(entity player)
 211 {
 212         entity pl;
 213         AuditLists();
 214         for(pl = players.sort_next; pl; pl = pl.sort_next)
 215                 if(pl == player)
 216                         error("Player already registered!");
 217         player.sort_next = players.sort_next;
 218         player.sort_prev = players;
 219         if(players.sort_next)
 220                 players.sort_next.sort_prev = player;
 221         players.sort_next = player;
 222         AuditLists();
 223         return true;
 224 }
 225
 226 void RemovePlayer(entity player)
 227 {
 228         entity pl, parent;
 229         AuditLists();
 230         parent = players;
 231         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 232                 parent = pl;
 233
 234         if(!pl)
 235         {
 236                 error("Trying to remove a player which is not in the playerlist!");
 237                 return;
 238         }
 239         parent.sort_next = player.sort_next;
 240         if(player.sort_next)
 241                 player.sort_next.sort_prev = parent;
 242         AuditLists();
 243 }
 244
 245 void MoveToLast(entity e)
 246 {
 247         AuditLists();
 248         entity ent = e.sort_next;
 249         while(ent)
 250         {
 251                 SORT_SWAP(ent, e);
 252                 ent = e.sort_next;
 253         }
 254         AuditLists();
 255 }
 256
 257 float RegisterTeam(entity Team)
 258 {
 259         assert_once(Team.team, eprint(Team));
 260         entity tm;
 261         AuditLists();
 262         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 263                 if(tm == Team)
 264                         error("Team already registered!");
 265         Team.sort_next = teams.sort_next;
 266         Team.sort_prev = teams;
 267         if(teams.sort_next)
 268                 teams.sort_next.sort_prev = Team;
 269         teams.sort_next = Team;
 270         if(Team.team && Team.team != NUM_SPECTATOR)
 271                 ++team_count;
 272         AuditLists();
 273         return true;
 274 }
 275
 276 void RemoveTeam(entity Team)
 277 {
 278         entity tm, parent;
 279         AuditLists();
 280         parent = teams;
 281         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 282                 parent = tm;
 283
 284         if(!tm)
 285         {
 286                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 287                 return;
 288         }
 289         parent.sort_next = Team.sort_next;
 290         if(Team.sort_next)
 291                 Team.sort_next.sort_prev = parent;
 292         if(Team.team && Team.team != NUM_SPECTATOR)
 293                 --team_count;
 294         AuditLists();
 295 }
 296
 297 entity GetTeam(int Team, bool add)
 298 {
 299         TC(int, Team); TC(bool, add);
 300         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 301         if(teamslots[num])
 302                 return teamslots[num];
 303         if (!add)
 304                 return NULL;
 305         entity tm = new_pure(team);
 306         tm.team = Team;
 307         teamslots[num] = tm;
 308         RegisterTeam(tm);
 309         return tm;
 310 }
 311
 312 .float has_team;
 313 bool SetTeam(entity o, int Team)
 314 {
 315         TC(int, Team);
 316         //devassert_once(Team);
 317         entity tm;
 318         if(teamplay)
 319         {
 320                 switch(Team)
 321                 {
 322                         case -1:
 323                         case NUM_TEAM_1:
 324                         case NUM_TEAM_2:
 325                         case NUM_TEAM_3:
 326                         case NUM_TEAM_4:
 327                                 break;
 328                         default:
 329                                 if(GetTeam(Team, false) == NULL)
 330                                 {
 331                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 332                                         Team = NUM_SPECTATOR;
 333                                 }
 334                                 break;
 335                 }
 336         }
 337         else
 338         {
 339                 switch(Team)
 340                 {
 341                         case -1:
 342                         case 0:
 343                                 break;
 344                         default:
 345                                 if(GetTeam(Team, false) == NULL)
 346                                 {
 347                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 348                                         Team = NUM_SPECTATOR;
 349                                 }
 350                                 break;
 351                 }
 352         }
 353         if(Team == -1) // leave
 354         {
 355                 if(o.has_team)
 356                 {
 357                         tm = GetTeam(o.team, false);
 358                         tm.team_size -= 1;
 359                         o.has_team = 0;
 360                         return true;
 361                 }
 362         }
 363         else
 364         {
 365                 if (!o.has_team)
 366                 {
 367                         o.team = Team;
 368                         tm = GetTeam(Team, true);
 369                         tm.team_size += 1;
 370                         o.has_team = 1;
 371                         return true;
 372                 }
 373                 else if(Team != o.team)
 374                 {
 375                         tm = GetTeam(o.team, false);
 376                         tm.team_size -= 1;
 377                         o.team = Team;
 378                         tm = GetTeam(Team, true);
 379                         tm.team_size += 1;
 380                         return true;
 381                 }
 382         }
 383         return false;
 384 }
 385
 386 void Playerchecker_Think(entity this)
 387 {
 388         int i;
 389         entity e;
 390         for(i = 0; i < maxclients; ++i)
 391         {
 392                 e = playerslots[i];
 393                 if(entcs_GetName(i) == "")
 394                 {
 395                         if(e.sort_prev)
 396                         {
 397                                 // player disconnected
 398                                 SetTeam(e, -1);
 399                                 RemovePlayer(e);
 400                                 e.sort_prev = NULL;
 401                                 //e.gotscores = 0;
 402                         }
 403                 }
 404                 else
 405                 {
 406                         if (!e.sort_prev)
 407                         {
 408                                 // player connected
 409                                 if (!e)
 410                                 {
 411                                         playerslots[i] = e = new_pure(playerslot);
 412                                 }
 413                                 e.sv_entnum = i;
 414                                 e.ping = 0;
 415                                 e.ping_packetloss = 0;
 416                                 e.ping_movementloss = 0;
 417                                 //e.gotscores = 0; // we might already have the scores...
 418                                 int t = entcs_GetScoreTeam(i);
 419                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 420                                 RegisterPlayer(e);
 421                                 Scoreboard_UpdatePlayerPos(e);
 422                         }
 423                 }
 424         }
 425         this.nextthink = time + 0.2;
 426 }
 427
 428 void PostInit()
 429 {
 430         entity playerchecker = new_pure(playerchecker);
 431         setthink(playerchecker, Playerchecker_Think);
 432         playerchecker.nextthink = time + 0.2;
 433
 434         TrueAim_Init();
 435
 436         postinit = true;
 437 }
 438
 439 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 440 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 441 // All keys are in ascii.
 442 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 443 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 444 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 445 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 446 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 447 {
 448         TC(int, bInputType);
 449         bool override = false;
 450         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 451         if (override)
 452                 return true;
 453
 454         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 455
 456         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 457
 458         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 459
 460         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 461
 462         if(override)
 463                 return true;
 464
 465         return false;
 466 }
 467
 468 // END REQUIRED CSQC FUNCTIONS
 469 // --------------------------------------------------------------------------
 470
 471 // --------------------------------------------------------------------------
 472 // BEGIN OPTIONAL CSQC FUNCTIONS
 473
 474 void Ent_RemovePlayerScore(entity this)
 475 {
 476         if(this.owner) {
 477                 SetTeam(this.owner, -1);
 478                 this.owner.gotscores = 0;
 479                 FOREACH(Scores, true, {
 480                         this.owner.(scores(it)) = 0; // clear all scores
 481                 });
 482         }
 483 }
 484
 485 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 486 {
 487         make_pure(this);
 488         entity o;
 489
 490         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 491         // (no I've never heard of M-x replace-string, sed, or anything like that)
 492         bool isNew = !this.owner; // workaround for DP bug
 493         int n = ReadByte()-1;
 494
 495 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 496         if(!isNew && n != this.sv_entnum)
 497         {
 498                 //print("A CSQC entity changed its owner!\n");
 499                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 500                 isNew = true;
 501                 Ent_Remove(this);
 502         }
 503 #endif
 504
 505         this.sv_entnum = n;
 506
 507         o = playerslots[this.sv_entnum];
 508         if (!o)
 509         {
 510                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 511         }
 512         this.owner = o;
 513         o.sv_entnum = this.sv_entnum;
 514         o.gotscores = 1;
 515
 516         //if (!o.sort_prev)
 517         //      RegisterPlayer(o);
 518         //playerchecker will do this for us later, if it has not already done so
 519
 520         int sf = ReadShort();
 521         int lf = ReadShort();
 522         FOREACH(Scores, true, {
 523                 int p = 1 << (i % 16);
 524                 if (sf & p)
 525                 {
 526                         if (lf & p)
 527                                 o.(scores(it)) = ReadInt24_t();
 528                         else
 529                                 o.(scores(it)) = ReadChar();
 530                 }
 531         });
 532
 533         return = true;
 534
 535         if(o.sort_prev)
 536                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 537
 538         this.entremove = Ent_RemovePlayerScore;
 539 }
 540
 541 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 542 {
 543         make_pure(this);
 544         int i;
 545
 546         this.team = ReadByte();
 547         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 548
 549 #if MAX_TEAMSCORE <= 8
 550         int sf = ReadByte();
 551         int lf = ReadByte();
 552 #else
 553         int sf = ReadShort();
 554         int lf = ReadShort();
 555 #endif
 556         for(i = 0; i < MAX_TEAMSCORE; ++i)
 557                 if(sf & BIT(i))
 558                 {
 559                         if(lf & BIT(i))
 560                                 o.(teamscores(i)) = ReadInt24_t();
 561                         else
 562                                 o.(teamscores(i)) = ReadChar();
 563                 }
 564
 565         return = true;
 566
 567         Scoreboard_UpdateTeamPos(o);
 568 }
 569
 570 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 571 {
 572         make_pure(this);
 573         float newspectatee_status;
 574
 575         int f = ReadByte();
 576
 577         scoreboard_showscores_force = (f & BIT(0));
 578
 579         if(f & BIT(1))
 580         {
 581                 newspectatee_status = ReadByte();
 582                 if(newspectatee_status == player_localnum + 1)
 583                         newspectatee_status = -1; // observing
 584         }
 585         else
 586                 newspectatee_status = 0;
 587
 588         spectatorbutton_zoom = (f & BIT(2));
 589
 590         if(f & BIT(4))
 591         {
 592                 num_spectators = ReadByte();
 593
 594                 float i, slot;
 595
 596                 for(i = 0; i < MAX_SPECTATORS; ++i)
 597                         spectatorlist[i] = 0; // reset list first
 598
 599                 int limit = min(num_spectators, MAX_SPECTATORS);
 600                 for(i = 0; i < limit; ++i)
 601                 {
 602                         slot = ReadByte();
 603                         spectatorlist[i] = slot - 1;
 604                 }
 605         }
 606         else
 607         {
 608                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 609                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 610                 num_spectators = 0;
 611         }
 612
 613         return = true;
 614
 615         if(newspectatee_status != spectatee_status)
 616         {
 617                 // clear race stuff
 618                 race_laptime = 0;
 619                 race_checkpointtime = 0;
 620                 hud_dynamic_shake_factor = -1;
 621                 spectatee_status_changed_time = time;
 622         }
 623         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 624         {
 625                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 626                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 627                 )
 628                         prev_p_health = -1;
 629                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 630                         prev_health = -1;
 631         }
 632         spectatee_status = newspectatee_status;
 633
 634         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 635 }
 636
 637 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 638 {
 639         make_pure(this);
 640         int i, j, b, f;
 641
 642         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 643
 644         if(!(nags & BIT(2)))
 645         {
 646                 strfree(vote_called_vote);
 647                 vote_active = 0;
 648         }
 649         else
 650         {
 651                 vote_active = 1;
 652         }
 653
 654         if(nags & BIT(6))
 655         {
 656                 vote_yescount = ReadByte();
 657                 vote_nocount = ReadByte();
 658                 vote_needed = ReadByte();
 659                 vote_highlighted = ReadChar();
 660         }
 661
 662         if(nags & BIT(7))
 663         {
 664                 strcpy(vote_called_vote, ReadString());
 665         }
 666
 667         if(nags & 1)
 668         {
 669                 for(j = 0; j < maxclients; ++j)
 670                         if(playerslots[j])
 671                                 playerslots[j].ready = true;
 672                 for(i = 1; i <= maxclients; i += 8)
 673                 {
 674                         f = ReadByte();
 675                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 676                                 if (!(f & b))
 677                                         if(playerslots[j])
 678                                                 playerslots[j].ready = false;
 679                 }
 680         }
 681
 682         return = true;
 683
 684         ready_waiting = (nags & BIT(0));
 685         ready_waiting_for_me = (nags & BIT(1));
 686         vote_waiting = (nags & BIT(2));
 687         vote_waiting_for_me = (nags & BIT(3));
 688         warmup_stage = (nags & BIT(4));
 689 }
 690
 691 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 692 {
 693         make_pure(this);
 694         int sf = 0;
 695         serialize(byte, 0, sf);
 696         if (sf & 1) {
 697                 for (int j = 0; j < maxclients; ++j) {
 698                         if (playerslots[j]) {
 699                                 playerslots[j].eliminated = true;
 700                         }
 701                 }
 702                 for (int i = 1; i <= maxclients; i += 8) {
 703                         int f = 0;
 704                         serialize(byte, 0, f);
 705                         for (int b = 0; b < 8; ++b) {
 706                                 if (f & BIT(b)) continue;
 707                                 int j = i - 1 + b;
 708                                 if (playerslots[j]) {
 709                                         playerslots[j].eliminated = false;
 710                                 }
 711                         }
 712                 }
 713         }
 714         return true;
 715 }
 716
 717 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 718 {
 719         make_pure(this);
 720         prandom_debug();
 721         float s = ReadShort();
 722         psrandom(s);
 723         return true;
 724 }
 725
 726 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 727 {
 728         make_pure(this);
 729         int sf = ReadInt24_t();
 730         if (sf == 0) {
 731                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 732                         weapon_accuracy[w] = -1;
 733                 return true;
 734         }
 735
 736         int f = 1;
 737         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 738                 if (sf & f) {
 739                         int b = ReadByte();
 740                         if (b == 0)
 741                                 weapon_accuracy[w] = -1;
 742                         else if (b == 255)
 743                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 744                         else
 745                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 746                 }
 747                 f = (f == 0x800000) ? 1 : f * 2;
 748         }
 749         return true;
 750 }
 751
 752 void Spawn_Draw(entity this)
 753 {
 754         bool dodraw = autocvar_cl_spawn_point_particles;
 755         if(dodraw && autocvar_cl_spawn_point_dist_max)
 756         {
 757                 vector org = getpropertyvec(VF_ORIGIN);
 758                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 759         }
 760
 761         if(dodraw)
 762                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 763 }
 764
 765 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 766 {
 767         float teamnum = (ReadByte() - 1);
 768         vector spn_origin = ReadVector();
 769
 770         this.team = (teamnum + 1);
 771
 772         //if(is_new)
 773         //{
 774                 this.origin = spn_origin;
 775                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 776                 //droptofloor();
 777
 778                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 779                 {
 780                         this.mdl = "models/spawnpoint.md3";
 781                         this.colormod = Team_ColorRGB(teamnum);
 782                         precache_model(this.mdl);
 783                         setmodel(this, this.mdl);
 784                         this.drawmask = MASK_NORMAL;
 785                         //this.move_movetype = MOVETYPE_NOCLIP;
 786                         //this.draw = Spawn_Draw;
 787                         IL_PUSH(g_drawables, this);
 788                 }*/
 789                 this.draw = Spawn_Draw;
 790                 if (is_new) IL_PUSH(g_drawables, this);
 791         //}
 792
 793         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 794         return true;
 795 }
 796
 797 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 798 {
 799         // If entnum is 0, ONLY do the local spawn actions
 800         // this way the server can disable the sending of
 801         // spawn origin or such to clients if wanted.
 802         float entnum = ReadByte();
 803
 804         if(entnum)
 805         {
 806                 this.origin = ReadVector();
 807
 808                 if(is_new)
 809                 {
 810                         float teamnum = entcs_GetTeam(entnum - 1);
 811
 812                         if(autocvar_cl_spawn_event_particles)
 813                         {
 814                                 switch(teamnum)
 815                                 {
 816                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 817                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 818                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 819                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 820                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 821                                 }
 822                         }
 823                         if(autocvar_cl_spawn_event_sound)
 824                         {
 825                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 826                         }
 827                 }
 828         }
 829         return = true;
 830
 831         // local spawn actions
 832         if(is_new && (!entnum || (entnum == player_localentnum)))
 833         {
 834                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 835                 {
 836                         zoomin_effect = 1;
 837                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 838                 }
 839
 840                 if(autocvar_cl_unpress_zoom_on_spawn)
 841                 {
 842                         localcmd("-zoom\n");
 843                         button_zoom = false;
 844                 }
 845                 HUD_Radar_Hide_Maximized();
 846         }
 847         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 848 }
 849
 850 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 851 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 852 void CSQC_Ent_Update(entity this, bool isnew)
 853 {
 854         this.sourceLoc = __FILE__":"STR(__LINE__);
 855         int t = ReadByte();
 856
 857         // set up the "time" global for received entities to be correct for interpolation purposes
 858         float savetime = time;
 859         if(servertime)
 860         {
 861                 time = servertime;
 862         }
 863         else
 864         {
 865                 serverprevtime = time;
 866                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 867                 time = serverprevtime + serverdeltatime;
 868         }
 869
 870 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 871         if (this.enttype)
 872         {
 873                 if (t != this.enttype || isnew)
 874                 {
 875                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 876                         Ent_Remove(this);
 877                         clearentity(this);
 878                         isnew = true;
 879                 }
 880         }
 881         else
 882         {
 883                 if (!isnew)
 884                 {
 885                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 886                         isnew = true;
 887                 }
 888         }
 889 #endif
 890         this.enttype = t;
 891         bool done = false;
 892         FOREACH(LinkedEntities, it.m_id == t, {
 893                 if (isnew) this.classname = it.netname;
 894                 if (autocvar_developer_csqcentities)
 895             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 896                 done = it.m_read(this, NULL, isnew);
 897                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 898                 break;
 899         });
 900         time = savetime;
 901         if (!done)
 902         {
 903                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 904         }
 905 }
 906
 907 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 908 // used when an entity changes its type. For an entity that someone interacts
 909 // with others, make sure it can no longer do so.
 910 void Ent_Remove(entity this)
 911 {
 912         if(this.entremove) this.entremove(this);
 913
 914         if(this.skeletonindex)
 915         {
 916                 skel_delete(this.skeletonindex);
 917                 this.skeletonindex = 0;
 918         }
 919
 920         if(this.snd_looping > 0)
 921         {
 922                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 923                 this.snd_looping = 0;
 924         }
 925
 926         this.enttype = 0;
 927         this.classname = "";
 928         this.draw = func_null;
 929         this.entremove = func_null;
 930         // TODO possibly set more stuff to defaults
 931 }
 932 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 933 void CSQC_Ent_Remove(entity this)
 934 {
 935         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 936         if (wasfreed(this))
 937         {
 938                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 939                 return;
 940         }
 941         if (this.enttype) Ent_Remove(this);
 942         delete(this);
 943 }
 944
 945 void Gamemode_Init()
 946 {
 947         if (!isdemo())
 948         {
 949                 if(!(calledhooks & HOOK_START))
 950                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 951                 calledhooks |= HOOK_START;
 952         }
 953 }
 954 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 955 void CSQC_Parse_StuffCmd(string strMessage)
 956 {
 957         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 958         localcmd(strMessage);
 959 }
 960 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 961 void CSQC_Parse_Print(string strMessage)
 962 {
 963         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 964         print(ColorTranslateRGB(strMessage));
 965 }
 966
 967 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 968 void CSQC_Parse_CenterPrint(string strMessage)
 969 {
 970         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 971         centerprint_AddStandard(strMessage);
 972 }
 973
 974 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 975 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 976 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 977 bool CSQC_Parse_TempEntity()
 978 {
 979         // Acquire TE ID
 980         int nTEID = ReadByte();
 981
 982         FOREACH(TempEntities, it.m_id == nTEID, {
 983                 if (autocvar_developer_csqcentities)
 984                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 985                 return it.m_read(NULL, NULL, true);
 986         });
 987
 988         if (autocvar_developer_csqcentities)
 989                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 990
 991         // No special logic for this temporary entity; return 0 so the engine can handle it
 992         return false;
 993 }
 994
 995 string forcefog;
 996 void Fog_Force()
 997 {
 998         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 999                 localcmd("\nr_drawfog 0\n");
1000         else if (forcefog != "")
1001                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1002 }
1003
1004 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1005 {
1006         make_pure(this);
1007         gametype = ReadRegistered(Gametypes);
1008         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1009         HUD_ModIcons_SetFunc();
1010         FOREACH(Scores, true, {
1011                 strcpy(scores_label(it), ReadString());
1012                 scores_flags(it) = ReadByte();
1013         });
1014         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1015         {
1016                 strcpy(teamscores_label(i), ReadString());
1017                 teamscores_flags(i) = ReadByte();
1018         }
1019         return = true;
1020         Scoreboard_InitScores();
1021         Gamemode_Init();
1022 }
1023
1024 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1025 {
1026         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1027
1028         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1029         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1030         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1031         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1032         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1033         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1034         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1035         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1036
1037         strcpy(forcefog, ReadString());
1038
1039         armorblockpercent = ReadByte() / 255.0;
1040         damagepush_speedfactor = ReadByte() / 255.0;
1041
1042         serverflags = ReadByte();
1043
1044         g_trueaim_minrange = ReadCoord();
1045
1046         return = true;
1047
1048         MUTATOR_CALLHOOK(Ent_Init);
1049
1050         if (!postinit) PostInit();
1051 }
1052
1053 float GetSpeedUnitFactor(int speed_unit)
1054 {
1055         switch(speed_unit)
1056         {
1057                 default:
1058                 case 1: return 1.0;
1059                 case 2: return 0.0254;
1060                 case 3: return 0.0254 * 3.6;
1061                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1062                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1063         }
1064 }
1065
1066 string GetSpeedUnit(int speed_unit)
1067 {
1068         switch(speed_unit)
1069         {
1070                 // translator-friendly strings without the initial space
1071                 default:
1072                 case 1: return strcat(" ", _("qu/s"));
1073                 case 2: return strcat(" ", _("m/s"));
1074                 case 3: return strcat(" ", _("km/h"));
1075                 case 4: return strcat(" ", _("mph"));
1076                 case 5: return strcat(" ", _("knots"));
1077         }
1078 }
1079
1080 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1081 {
1082         int b = ReadByte();
1083
1084         switch (b)
1085         {
1086                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1087                         race_checkpoint = ReadByte();
1088                         race_time = ReadInt24_t();
1089                         race_previousbesttime = ReadInt24_t();
1090                         race_mypreviousbesttime = ReadInt24_t();
1091                         string pbestname = ReadString();
1092                         if(autocvar_cl_race_cptimes_onlyself)
1093                         {
1094                                 race_previousbesttime = race_mypreviousbesttime;
1095                                 race_mypreviousbesttime = 0;
1096                                 strcpy(race_previousbestname, "");
1097                         }
1098                         else
1099                                 strcpy(race_previousbestname, pbestname);
1100
1101                         race_checkpointtime = time;
1102
1103                         if(race_checkpoint == 0 || race_checkpoint == 254)
1104                         {
1105                                 race_penaltyaccumulator = 0;
1106                                 race_laptime = time; // valid
1107                         }
1108                         break;
1109
1110                 case RACE_NET_CHECKPOINT_CLEAR:
1111                         race_laptime = 0;
1112                         race_checkpointtime = 0;
1113                         break;
1114
1115                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1116                         race_laptime = ReadCoord();
1117                         race_checkpointtime = -99999;
1118                         // fall through
1119                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1120                         race_nextcheckpoint = ReadByte();
1121
1122                         race_nextbesttime = ReadInt24_t();
1123                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1124                                 race_mybesttime = ReadInt24_t();
1125                         string newname = ReadString();
1126                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1127                         {
1128                                 race_nextbesttime = race_mybesttime;
1129                                 race_mybesttime = 0;
1130                                 strcpy(race_nextbestname, "");
1131                         }
1132                         else
1133                                 strcpy(race_nextbestname, newname);
1134                         break;
1135
1136                 case RACE_NET_CHECKPOINT_HIT_RACE:
1137                         race_mycheckpoint = ReadByte();
1138                         race_mycheckpointtime = time;
1139                         race_mycheckpointdelta = ReadInt24_t();
1140                         race_mycheckpointlapsdelta = ReadByte();
1141                         if(race_mycheckpointlapsdelta >= 128)
1142                                 race_mycheckpointlapsdelta -= 256;
1143                         int who = ReadByte();
1144                         if(who)
1145                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1146                         else
1147                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1148                         break;
1149
1150                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1151                         race_othercheckpoint = ReadByte();
1152                         race_othercheckpointtime = time;
1153                         race_othercheckpointdelta = ReadInt24_t();
1154                         race_othercheckpointlapsdelta = ReadByte();
1155                         if(race_othercheckpointlapsdelta >= 128)
1156                                 race_othercheckpointlapsdelta -= 256;
1157                         int what = ReadByte();
1158                         if(what)
1159                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1160                         else
1161                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1162                         break;
1163
1164                 case RACE_NET_PENALTY_RACE:
1165                 case RACE_NET_PENALTY_QUALIFYING:
1166                         race_penaltyeventtime = time;
1167                         race_penaltytime = ReadShort();
1168                         string reason = ReadString();
1169                         if (reason == "missing a checkpoint")
1170                                 reason = _("missing a checkpoint");
1171                         strcpy(race_penaltyreason, reason);
1172                         if (b == RACE_NET_PENALTY_QUALIFYING)
1173                                 race_penaltyaccumulator += race_penaltytime;
1174                         break;
1175
1176                 case RACE_NET_SERVER_RECORD:
1177                         race_server_record = ReadInt24_t();
1178                         break;
1179                 case RACE_NET_SPEED_AWARD:
1180                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1181                         strcpy(race_speedaward_holder, ReadString());
1182                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1183                         break;
1184                 case RACE_NET_SPEED_AWARD_BEST:
1185                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1186                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1187                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1188                         break;
1189                 case RACE_NET_RANKINGS_CNT:
1190                         RANKINGS_DISPLAY_CNT = ReadByte();
1191                         break;
1192                 case RACE_NET_SERVER_RANKINGS:
1193                         float prevpos, del;
1194                         int pos = ReadShort();
1195                         prevpos = ReadShort();
1196                         del = ReadShort();
1197
1198                         // move other rankings out of the way
1199                         int i;
1200                         if (prevpos) {
1201                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1202                                 for (i=m-1; i>pos-1; --i) {
1203                                         grecordtime[i] = grecordtime[i-1];
1204                                         strcpy(grecordholder[i], grecordholder[i-1]);
1205                                 }
1206                         } else if (del) { // a record has been deleted by the admin
1207                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1208                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1209                                                 grecordtime[i] = 0;
1210                                                 strfree(grecordholder[i]);
1211                                         }
1212                                         else {
1213                                                 grecordtime[i] = grecordtime[i+1];
1214                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1215                                         }
1216                                 }
1217                         } else { // player has no ranked record yet
1218                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1219                                         grecordtime[i] = grecordtime[i-1];
1220                                         strcpy(grecordholder[i], grecordholder[i-1]);
1221                                 }
1222                         }
1223
1224                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1225                                 // kick off the player who fell from the last displayed position
1226                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1227                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1228                         }
1229
1230                         // store new ranking
1231                         strcpy(grecordholder[pos-1], ReadString());
1232                         grecordtime[pos-1] = ReadInt24_t();
1233                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1234                                 race_myrank = pos;
1235                         break;
1236                 case RACE_NET_SERVER_STATUS:
1237                         race_status = ReadShort();
1238                         strcpy(race_status_name, ReadString());
1239         }
1240         return true;
1241 }
1242
1243 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1244 {
1245         teamnagger = 1;
1246         return true;
1247 }
1248
1249 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1250 {
1251         int i = ReadByte();
1252         int pi = ReadShort();
1253         int pl = ReadByte();
1254         int ml = ReadByte();
1255         return = true;
1256         entity e = playerslots[i];
1257         if (!e) return;
1258         e.ping = pi;
1259         e.ping_packetloss = pl / 255.0;
1260         e.ping_movementloss = ml / 255.0;
1261 }
1262
1263 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1264 {
1265         int weapon_id = ReadByte();
1266         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1267         complain_weapon_type = ReadByte();
1268         return = true;
1269
1270         complain_weapon_time = time;
1271         weapontime = time; // ping the weapon panel
1272
1273         switch(complain_weapon_type)
1274         {
1275                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1276                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1277                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1278         }
1279 }
1280
1281 string _getcommandkey(string cmd_name, string command, bool forcename)
1282 {
1283         string keys;
1284         float n, j, k, l = 0;
1285
1286         if (!autocvar_hud_showbinds)
1287                 return cmd_name;
1288
1289         keys = db_get(binddb, command);
1290         if (keys == "")
1291         {
1292                 bool joy_active = cvar("joy_active");
1293                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1294                 for(j = 0; j < n; ++j)
1295                 {
1296                         k = stof(argv(j));
1297                         if(k != -1)
1298                         {
1299                                 string key = keynumtostring(k);
1300                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1301                                         continue;
1302
1303                                 key = translate_key(key);
1304
1305                                 if (keys == "")
1306                                         keys = key;
1307                                 else
1308                                         keys = strcat(keys, ", ", key);
1309
1310                                 ++l;
1311                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1312                                         break;
1313                         }
1314
1315                 }
1316                 if (keys == "")
1317                         keys = "NO_KEY";
1318                 db_put(binddb, command, keys);
1319         }
1320
1321         if (keys == "NO_KEY") {
1322                 if (autocvar_hud_showbinds > 1)
1323                         return sprintf(_("%s (not bound)"), cmd_name);
1324                 else
1325                         return cmd_name;
1326         }
1327         else if (autocvar_hud_showbinds > 1 || forcename)
1328                 return sprintf("%s (%s)", cmd_name, keys);
1329         else
1330                 return keys;
1331 }
1332
1333 /** engine callback */
1334 void URI_Get_Callback(int id, int status, string data)
1335 {
1336         TC(int, id); TC(int, status);
1337         if(url_URI_Get_Callback(id, status, data))
1338         {
1339                 // handled
1340         }
1341         else if (id == URI_GET_DISCARD)
1342         {
1343                 // discard
1344         }
1345         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1346         {
1347                 // sv_cmd curl
1348                 Curl_URI_Get_Callback(id, status, data);
1349         }
1350         else
1351         {
1352                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1353         }
1354 }