qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include <client/command/cl_cmd.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/_mod.qh>
   6 #include <client/hud/panel/centerprint.qh>
   7 #include <client/hud/panel/chat.qh>
   8 #include <client/hud/panel/quickmenu.qh>
   9 #include <client/hud/panel/scoreboard.qh>
  10 #include <client/items/items.qh>
  11 #include <client/mapvoting.qh>
  12 #include <client/mutators/_mod.qh>
  13 #include <client/shownames.qh>
  14 #include <client/view.qh>
  15 #include <client/weapons/projectile.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/effects/all.inc>
  18 #include <common/effects/all.qh>
  19 #include <common/effects/effect.qh>
  20 #include <common/effects/qc/_mod.qh>
  21 #include <common/ent_cs.qh>
  22 #include <common/gamemodes/gamemode/nexball/cl_nexball.qh>
  23 #include <common/items/_mod.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/mapobjects/_mod.qh>
  26 #include <common/minigames/cl_minigames.qh>
  27 #include <common/minigames/cl_minigames_hud.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/scores.qh>
  31 #include <common/vehicles/all.qh>
  32 #include <lib/csqcmodel/cl_model.qh>
  33 #include <lib/csqcmodel/interpolate.qh>
  34 #include <lib/warpzone/client.qh>
  35
  36 // --------------------------------------------------------------------------
  37 // BEGIN REQUIRED CSQC FUNCTIONS
  38 //include "main.qh"
  39
  40 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  41
  42 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  43 // Useful for precaching things
  44
  45 void CSQC_Init()
  46 {
  47         prvm_language = strzone(cvar_string("prvm_language"));
  48
  49 #ifdef WATERMARK
  50         LOG_TRACEF("^4CSQC Build information: ^1%s", WATERMARK);
  51 #endif
  52
  53         {
  54                 int i = 0;
  55                 for ( ; i < 255; ++i)
  56                         if (getplayerkeyvalue(i, "viewentity") == "")
  57                                 break;
  58                 maxclients = i;
  59         }
  60
  61         // needs to be done so early because of the constants they create
  62         static_init();
  63         static_init_late();
  64         static_init_precache();
  65
  66         binddb = db_create();
  67         tempdb = db_create();
  68         ClientProgsDB = db_load("client.db");
  69
  70         draw_endBoldFont();
  71
  72         //registercommand("hud_configure");
  73         //registercommand("hud_save");
  74         //registercommand("menu_action");
  75
  76         ConsoleCommand_macro_init();
  77
  78         registercvar("hud_usecsqc", "1");
  79         registercvar("scoreboard_columns", "default");
  80
  81         registercvar("cl_nade_type", "3");
  82         registercvar("cl_pokenade_type", "zombie");
  83
  84         registercvar("cl_jumpspeedcap_min", "");
  85         registercvar("cl_jumpspeedcap_max", "");
  86
  87         registercvar("cl_shootfromfixedorigin", "");
  88
  89         registercvar("cl_multijump", "-1");
  90
  91         registercvar("cl_dodging", "0");
  92
  93         registercvar("cl_spawn_near_teammate", "1");
  94
  95         registercvar("cl_weapon_switch_reload", "1");
  96         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
  97
  98         registercvar("cl_allow_uidranking", "1");
  99
 100         if(autocvar_cl_lockview)
 101                 cvar_set("cl_lockview", "0");
 102
 103         gametype = NULL;
 104
 105         postinit = false;
 106
 107         calledhooks = 0;
 108
 109         teams = Sort_Spawn();
 110         players = Sort_Spawn();
 111
 112         GetTeam(NUM_SPECTATOR, true); // add specs first
 113
 114         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 115                 weapon_accuracy[w] = -1;
 116
 117         // precaches
 118
 119         if(autocvar_cl_reticle)
 120         {
 121                 precache_pic("gfx/reticle_normal");
 122                 // weapon reticles are precached in weapon files
 123         }
 124
 125         {
 126                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 127                 minimapname = strcat("gfx/", mi_shortname, "_radar");
 128                 shortmapname = mi_shortname;
 129
 130                 if (precache_pic(minimapname) == "")
 131                 {
 132                         // but maybe we have a non-clever minimap
 133                         minimapname = strcat("gfx/", mi_shortname, "_mini");
 134                         if (precache_pic(minimapname) == "")
 135                                 minimapname = ""; // FAIL
 136                         else
 137                                 get_mi_min_max_texcoords(0); // load new texcoords
 138                 }
 139
 140                 mi_center = (mi_min + mi_max) * 0.5;
 141                 mi_scale = mi_max - mi_min;
 142                 minimapname = strzone(minimapname);
 143         }
 144
 145         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 146         LoadMenuSkinValues();
 147 }
 148
 149 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 150 void Shutdown()
 151 {
 152         WarpZone_Shutdown();
 153
 154         delete(teams);
 155         delete(players);
 156         db_close(binddb);
 157         db_close(tempdb);
 158         if(autocvar_cl_db_saveasdump)
 159                 db_dump(ClientProgsDB, "client.db");
 160         else
 161                 db_save(ClientProgsDB, "client.db");
 162         db_close(ClientProgsDB);
 163
 164         if(camera_active)
 165                 cvar_set("chase_active",ftos(chase_active_backup));
 166
 167         // unset the event chasecam's chase_active
 168         if(autocvar_chase_active < 0)
 169                 cvar_set("chase_active", "0");
 170
 171         if (autocvar_r_drawviewmodel < 0)
 172                 cvar_set("r_drawviewmodel", "0");
 173
 174         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 175
 176         if (!isdemo())
 177         {
 178                 if (!(calledhooks & HOOK_START))
 179                         localcmd("\n_cl_hook_gamestart nop\n");
 180                 if (!(calledhooks & HOOK_END))
 181                         localcmd("\ncl_hook_gameend\n");
 182         }
 183
 184         localcmd("\ncl_hook_shutdown\n");
 185
 186         localcmd("\n-button12\n");
 187
 188         deactivate_minigame();
 189         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 190
 191         ReplicateVars(REPLICATEVARS_DESTROY);
 192 }
 193
 194 void AuditLists()
 195 {
 196         entity e;
 197         entity prev;
 198
 199         prev = players;
 200         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 201         {
 202                 if(prev != e.sort_prev)
 203                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 204         }
 205
 206         prev = teams;
 207         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 208         {
 209                 if(prev != e.sort_prev)
 210                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 211         }
 212 }
 213
 214 float RegisterPlayer(entity player)
 215 {
 216         entity pl;
 217         AuditLists();
 218         for(pl = players.sort_next; pl; pl = pl.sort_next)
 219                 if(pl == player)
 220                         error("Player already registered!");
 221         player.sort_next = players.sort_next;
 222         player.sort_prev = players;
 223         if(players.sort_next)
 224                 players.sort_next.sort_prev = player;
 225         players.sort_next = player;
 226         AuditLists();
 227         return true;
 228 }
 229
 230 void RemovePlayer(entity player)
 231 {
 232         entity pl, parent;
 233         AuditLists();
 234         parent = players;
 235         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 236                 parent = pl;
 237
 238         if(!pl)
 239         {
 240                 error("Trying to remove a player which is not in the playerlist!");
 241                 return;
 242         }
 243         parent.sort_next = player.sort_next;
 244         if(player.sort_next)
 245                 player.sort_next.sort_prev = parent;
 246         AuditLists();
 247 }
 248
 249 void MoveToLast(entity e)
 250 {
 251         AuditLists();
 252         entity ent = e.sort_next;
 253         while(ent)
 254         {
 255                 SORT_SWAP(ent, e);
 256                 ent = e.sort_next;
 257         }
 258         AuditLists();
 259 }
 260
 261 float RegisterTeam(entity Team)
 262 {
 263         assert_once(Team.team, eprint(Team));
 264         entity tm;
 265         AuditLists();
 266         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 267                 if(tm == Team)
 268                         error("Team already registered!");
 269         Team.sort_next = teams.sort_next;
 270         Team.sort_prev = teams;
 271         if(teams.sort_next)
 272                 teams.sort_next.sort_prev = Team;
 273         teams.sort_next = Team;
 274         if(Team.team && Team.team != NUM_SPECTATOR)
 275                 ++team_count;
 276         AuditLists();
 277         return true;
 278 }
 279
 280 void RemoveTeam(entity Team)
 281 {
 282         entity tm, parent;
 283         AuditLists();
 284         parent = teams;
 285         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 286                 parent = tm;
 287
 288         if(!tm)
 289         {
 290                 LOG_INFO(_("Trying to remove a team which is not in the teamlist!"));
 291                 return;
 292         }
 293         parent.sort_next = Team.sort_next;
 294         if(Team.sort_next)
 295                 Team.sort_next.sort_prev = parent;
 296         if(Team.team && Team.team != NUM_SPECTATOR)
 297                 --team_count;
 298         AuditLists();
 299 }
 300
 301 entity GetTeam(int Team, bool add)
 302 {
 303         TC(int, Team); TC(bool, add);
 304         int num = (Team == NUM_SPECTATOR) ? 16 : Team;
 305         if(teamslots[num])
 306                 return teamslots[num];
 307         if (!add)
 308                 return NULL;
 309         entity tm = new_pure(team);
 310         tm.team = Team;
 311         teamslots[num] = tm;
 312         RegisterTeam(tm);
 313         return tm;
 314 }
 315
 316 .float has_team;
 317 bool SetTeam(entity o, int Team)
 318 {
 319         TC(int, Team);
 320         //devassert_once(Team);
 321         entity tm;
 322         if(teamplay)
 323         {
 324                 switch(Team)
 325                 {
 326                         case -1:
 327                         case NUM_TEAM_1:
 328                         case NUM_TEAM_2:
 329                         case NUM_TEAM_3:
 330                         case NUM_TEAM_4:
 331                                 break;
 332                         default:
 333                                 if(GetTeam(Team, false) == NULL)
 334                                 {
 335                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 336                                         Team = NUM_SPECTATOR;
 337                                 }
 338                                 break;
 339                 }
 340         }
 341         else
 342         {
 343                 switch(Team)
 344                 {
 345                         case -1:
 346                         case 0:
 347                                 break;
 348                         default:
 349                                 if(GetTeam(Team, false) == NULL)
 350                                 {
 351                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 352                                         Team = NUM_SPECTATOR;
 353                                 }
 354                                 break;
 355                 }
 356         }
 357         if(Team == -1) // leave
 358         {
 359                 if(o.has_team)
 360                 {
 361                         tm = GetTeam(o.team, false);
 362                         tm.team_size -= 1;
 363                         o.has_team = 0;
 364                         return true;
 365                 }
 366         }
 367         else
 368         {
 369                 if (!o.has_team)
 370                 {
 371                         o.team = Team;
 372                         tm = GetTeam(Team, true);
 373                         tm.team_size += 1;
 374                         o.has_team = 1;
 375                         return true;
 376                 }
 377                 else if(Team != o.team)
 378                 {
 379                         tm = GetTeam(o.team, false);
 380                         tm.team_size -= 1;
 381                         o.team = Team;
 382                         tm = GetTeam(Team, true);
 383                         tm.team_size += 1;
 384                         return true;
 385                 }
 386         }
 387         return false;
 388 }
 389
 390 void Playerchecker_Think(entity this)
 391 {
 392         int i;
 393         entity e;
 394         for(i = 0; i < maxclients; ++i)
 395         {
 396                 e = playerslots[i];
 397                 if(entcs_GetName(i) == "")
 398                 {
 399                         if(e.sort_prev)
 400                         {
 401                                 // player disconnected
 402                                 SetTeam(e, -1);
 403                                 RemovePlayer(e);
 404                                 e.sort_prev = NULL;
 405                                 //e.gotscores = 0;
 406                         }
 407                 }
 408                 else
 409                 {
 410                         if (!e.sort_prev)
 411                         {
 412                                 // player connected
 413                                 if (!e)
 414                                 {
 415                                         playerslots[i] = e = new_pure(playerslot);
 416                                 }
 417                                 e.sv_entnum = i;
 418                                 e.ping = 0;
 419                                 e.ping_packetloss = 0;
 420                                 e.ping_movementloss = 0;
 421                                 //e.gotscores = 0; // we might already have the scores...
 422                                 int t = entcs_GetScoreTeam(i);
 423                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 424                                 RegisterPlayer(e);
 425                                 Scoreboard_UpdatePlayerPos(e);
 426                         }
 427                 }
 428         }
 429         this.nextthink = time + 0.2;
 430 }
 431
 432 void PostInit()
 433 {
 434         entity playerchecker = new_pure(playerchecker);
 435         setthink(playerchecker, Playerchecker_Think);
 436         playerchecker.nextthink = time + 0.2;
 437
 438         TrueAim_Init();
 439
 440         // this can't be called in CSQC_Init as it'd send cvars too early
 441         ReplicateVars_Start();
 442
 443         postinit = true;
 444 }
 445
 446 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 447 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 448 // All keys are in ascii.
 449 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 450 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 451 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 452 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 453 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 454 {
 455         TC(int, bInputType);
 456         bool override = false;
 457
 458         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 459         if (override)
 460                 return true;
 461
 462         override |= HUD_Panel_Chat_InputEvent(bInputType, nPrimary, nSecondary);
 463
 464         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 465
 466         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 467
 468         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 469
 470         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 471
 472         if(override)
 473                 return true;
 474
 475         if(bInputType == 3 || bInputType == 2)
 476                 return false;
 477
 478         // at this point bInputType can only be 0 or 1 (key pressed or released)
 479         bool key_pressed = (bInputType == 0);
 480
 481         if(key_pressed) {
 482                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 483                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 484                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 485         }
 486         else {
 487                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 488                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 489                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 490         }
 491
 492         if (nPrimary == K_ESCAPE && !(hudShiftState & S_SHIFT) && key_pressed)
 493         {
 494                 if (!isdemo() && cvar("_menu_gamemenu_dialog_available"))
 495                 {
 496                         localcmd("\nmenu_showgamemenudialog\n");
 497                         return true;
 498                 }
 499         }
 500
 501         return false;
 502 }
 503
 504 // END REQUIRED CSQC FUNCTIONS
 505 // --------------------------------------------------------------------------
 506
 507 // --------------------------------------------------------------------------
 508 // BEGIN OPTIONAL CSQC FUNCTIONS
 509
 510 void Ent_RemovePlayerScore(entity this)
 511 {
 512         if(this.owner) {
 513                 SetTeam(this.owner, -1);
 514                 this.owner.gotscores = 0;
 515                 FOREACH(Scores, true, {
 516                         this.owner.(scores(it)) = 0; // clear all scores
 517                 });
 518         }
 519 }
 520
 521 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 522 {
 523         make_pure(this);
 524         entity o;
 525
 526         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 527         // (no I've never heard of M-x replace-string, sed, or anything like that)
 528         bool isNew = !this.owner; // workaround for DP bug
 529         int n = ReadByte()-1;
 530
 531 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 532         if(!isNew && n != this.sv_entnum)
 533         {
 534                 //print("A CSQC entity changed its owner!\n");
 535                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 536                 isNew = true;
 537                 Ent_Remove(this);
 538         }
 539 #endif
 540
 541         this.sv_entnum = n;
 542
 543         o = playerslots[this.sv_entnum];
 544         if (!o)
 545         {
 546                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 547         }
 548         this.owner = o;
 549         o.sv_entnum = this.sv_entnum;
 550         o.gotscores = 1;
 551
 552         //if (!o.sort_prev)
 553         //      RegisterPlayer(o);
 554         //playerchecker will do this for us later, if it has not already done so
 555
 556         int sf = ReadShort();
 557         int lf = ReadShort();
 558         FOREACH(Scores, true, {
 559                 int p = 1 << (i % 16);
 560                 if (sf & p)
 561                 {
 562                         if (lf & p)
 563                                 o.(scores(it)) = ReadInt24_t();
 564                         else
 565                                 o.(scores(it)) = ReadChar();
 566                 }
 567         });
 568
 569         return = true;
 570
 571         if(o.sort_prev)
 572                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 573
 574         this.entremove = Ent_RemovePlayerScore;
 575 }
 576
 577 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 578 {
 579         make_pure(this);
 580         int i;
 581
 582         this.team = ReadByte();
 583         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 584
 585 #if MAX_TEAMSCORE <= 8
 586         int sf = ReadByte();
 587         int lf = ReadByte();
 588 #else
 589         int sf = ReadShort();
 590         int lf = ReadShort();
 591 #endif
 592         for(i = 0; i < MAX_TEAMSCORE; ++i)
 593                 if(sf & BIT(i))
 594                 {
 595                         if(lf & BIT(i))
 596                                 o.(teamscores(i)) = ReadInt24_t();
 597                         else
 598                                 o.(teamscores(i)) = ReadChar();
 599                 }
 600
 601         return = true;
 602
 603         Scoreboard_UpdateTeamPos(o);
 604 }
 605
 606 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 607 {
 608         make_pure(this);
 609         float newspectatee_status;
 610
 611         int f = ReadByte();
 612
 613         scoreboard_showscores_force = (f & BIT(0));
 614
 615         if(f & BIT(1))
 616         {
 617                 newspectatee_status = ReadByte();
 618                 if(newspectatee_status == player_localnum + 1)
 619                         newspectatee_status = -1; // observing
 620         }
 621         else
 622                 newspectatee_status = 0;
 623
 624         spectatorbutton_zoom = (f & BIT(2));
 625
 626         if(f & BIT(4))
 627         {
 628                 num_spectators = ReadByte();
 629
 630                 float i, slot;
 631
 632                 for(i = 0; i < MAX_SPECTATORS; ++i)
 633                         spectatorlist[i] = 0; // reset list first
 634
 635                 int limit = min(num_spectators, MAX_SPECTATORS);
 636                 for(i = 0; i < limit; ++i)
 637                 {
 638                         slot = ReadByte();
 639                         spectatorlist[i] = slot - 1;
 640                 }
 641         }
 642         else
 643         {
 644                 for(int j = 0; j < MAX_SPECTATORS; ++j)
 645                         spectatorlist[j] = 0; // reset list if showspectators has been turned off
 646                 num_spectators = 0;
 647         }
 648
 649         return = true;
 650
 651         if(newspectatee_status != spectatee_status)
 652         {
 653                 // clear race stuff
 654                 race_laptime = 0;
 655                 race_checkpointtime = 0;
 656                 hud_dynamic_shake_factor = -1;
 657                 spectatee_status_changed_time = time;
 658         }
 659         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 660         {
 661                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 662                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 663                 )
 664                         prev_p_health = -1;
 665                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 666                         prev_health = -1;
 667         }
 668         spectatee_status = newspectatee_status;
 669
 670         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 671 }
 672
 673 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 674 {
 675         make_pure(this);
 676         int i, j, b, f;
 677
 678         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 679
 680         if(!(nags & BIT(2)))
 681         {
 682                 strfree(vote_called_vote);
 683                 vote_active = 0;
 684         }
 685         else
 686         {
 687                 vote_active = 1;
 688         }
 689
 690         if(nags & BIT(6))
 691         {
 692                 vote_yescount = ReadByte();
 693                 vote_nocount = ReadByte();
 694                 vote_needed = ReadByte();
 695                 vote_highlighted = ReadChar();
 696         }
 697
 698         if(nags & BIT(7))
 699         {
 700                 strcpy(vote_called_vote, ReadString());
 701         }
 702
 703         if(nags & 1)
 704         {
 705                 for(j = 0; j < maxclients; ++j)
 706                         if(playerslots[j])
 707                                 playerslots[j].ready = true;
 708                 for(i = 1; i <= maxclients; i += 8)
 709                 {
 710                         f = ReadByte();
 711                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 712                                 if (!(f & b))
 713                                         if(playerslots[j])
 714                                                 playerslots[j].ready = false;
 715                 }
 716         }
 717
 718         return = true;
 719
 720         ready_waiting = (nags & BIT(0));
 721         ready_waiting_for_me = (nags & BIT(1));
 722         vote_waiting = (nags & BIT(2));
 723         vote_waiting_for_me = (nags & BIT(3));
 724         warmup_stage = (nags & BIT(4));
 725 }
 726
 727 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 728 {
 729         make_pure(this);
 730         int sf = 0;
 731         serialize(byte, 0, sf);
 732         if (sf & 1) {
 733                 for (int j = 0; j < maxclients; ++j) {
 734                         if (playerslots[j]) {
 735                                 playerslots[j].eliminated = true;
 736                         }
 737                 }
 738                 for (int i = 1; i <= maxclients; i += 8) {
 739                         int f = 0;
 740                         serialize(byte, 0, f);
 741                         for (int b = 0; b < 8; ++b) {
 742                                 if (f & BIT(b)) continue;
 743                                 int j = i - 1 + b;
 744                                 if (playerslots[j]) {
 745                                         playerslots[j].eliminated = false;
 746                                 }
 747                         }
 748                 }
 749         }
 750         return true;
 751 }
 752
 753 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 754 {
 755         make_pure(this);
 756         prandom_debug();
 757         float s = ReadShort();
 758         psrandom(s);
 759         return true;
 760 }
 761
 762 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 763 {
 764         make_pure(this);
 765         int sf = ReadInt24_t();
 766         if (sf == 0) {
 767                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 768                         weapon_accuracy[w] = -1;
 769                 return true;
 770         }
 771
 772         int f = 1;
 773         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 774                 if (sf & f) {
 775                         int b = ReadByte();
 776                         if (b == 0)
 777                                 weapon_accuracy[w] = -1;
 778                         else if (b == 255)
 779                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 780                         else
 781                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 782                 }
 783                 f = (f == 0x800000) ? 1 : f * 2;
 784         }
 785         return true;
 786 }
 787
 788 void Spawn_Draw(entity this)
 789 {
 790         bool dodraw = autocvar_cl_spawn_point_particles;
 791         if(dodraw && autocvar_cl_spawn_point_dist_max)
 792         {
 793                 vector org = getpropertyvec(VF_ORIGIN);
 794                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 795         }
 796
 797         if(dodraw)
 798                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 799 }
 800
 801 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 802 {
 803         float teamnum = (ReadByte() - 1);
 804         vector spn_origin = ReadVector();
 805
 806         this.team = (teamnum + 1);
 807
 808         //if(is_new)
 809         //{
 810                 this.origin = spn_origin;
 811                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 812                 //droptofloor();
 813
 814                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 815                 {
 816                         this.mdl = "models/spawnpoint.md3";
 817                         this.colormod = Team_ColorRGB(teamnum);
 818                         precache_model(this.mdl);
 819                         setmodel(this, this.mdl);
 820                         this.drawmask = MASK_NORMAL;
 821                         //this.move_movetype = MOVETYPE_NOCLIP;
 822                         //this.draw = Spawn_Draw;
 823                         IL_PUSH(g_drawables, this);
 824                 }*/
 825                 this.draw = Spawn_Draw;
 826                 if (is_new) IL_PUSH(g_drawables, this);
 827         //}
 828
 829         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 830         return true;
 831 }
 832
 833 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 834 {
 835         // If entnum is 0, ONLY do the local spawn actions
 836         // this way the server can disable the sending of
 837         // spawn origin or such to clients if wanted.
 838         float entnum = ReadByte();
 839
 840         if(entnum)
 841         {
 842                 this.origin = ReadVector();
 843
 844                 if(is_new)
 845                 {
 846                         float teamnum = entcs_GetTeam(entnum - 1);
 847
 848                         if(autocvar_cl_spawn_event_particles)
 849                         {
 850                                 switch(teamnum)
 851                                 {
 852                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 853                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 854                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 855                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 856                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 857                                 }
 858                         }
 859                         if(autocvar_cl_spawn_event_sound)
 860                         {
 861                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 862                         }
 863                 }
 864         }
 865         return = true;
 866
 867         // local spawn actions
 868         if(is_new && (!entnum || (entnum == player_localentnum)))
 869         {
 870                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 871                 {
 872                         zoomin_effect = 1;
 873                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 874                 }
 875
 876                 if(autocvar_cl_unpress_zoom_on_spawn)
 877                 {
 878                         localcmd("-zoom\n");
 879                         button_zoom = false;
 880                 }
 881                 HUD_Radar_Hide_Maximized();
 882         }
 883         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 884 }
 885
 886 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 887 // The parameter isnew reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 888 void CSQC_Ent_Update(entity this, bool isnew)
 889 {
 890         this.sourceLoc = __FILE__":"STR(__LINE__);
 891         int t = ReadByte();
 892
 893         // set up the "time" global for received entities to be correct for interpolation purposes
 894         float savetime = time;
 895         if(servertime)
 896         {
 897                 time = servertime;
 898         }
 899         else
 900         {
 901                 serverprevtime = time;
 902                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 903                 time = serverprevtime + serverdeltatime;
 904         }
 905
 906 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 907         if (this.enttype)
 908         {
 909                 if (t != this.enttype || isnew)
 910                 {
 911                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 912                         Ent_Remove(this);
 913                         ONREMOVE(this);
 914                         clearentity(this);
 915                         isnew = true;
 916                 }
 917         }
 918         else
 919         {
 920                 if (!isnew)
 921                 {
 922                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 923                         isnew = true;
 924                 }
 925         }
 926 #endif
 927         this.enttype = t;
 928         bool done = false;
 929         FOREACH(LinkedEntities, it.m_id == t, {
 930                 if (isnew) this.classname = it.netname;
 931                 if (autocvar_developer_csqcentities)
 932                         LOG_INFOF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 933                 done = it.m_read(this, NULL, isnew);
 934                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 935                 break;
 936         });
 937         time = savetime;
 938         if (!done)
 939         {
 940                 LOG_FATALF("CSQC_Ent_Update(%i, %d) at %f {.entnum=%d, .enttype=%d} t=%s (%d)", this, isnew, savetime, this.entnum, this.enttype, this.classname, t);
 941         }
 942 }
 943
 944 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 945 // used when an entity changes its type. For an entity that someone interacts
 946 // with others, make sure it can no longer do so.
 947 void Ent_Remove(entity this)
 948 {
 949         if(this.entremove) this.entremove(this);
 950
 951         if(this.skeletonindex)
 952         {
 953                 skel_delete(this.skeletonindex);
 954                 this.skeletonindex = 0;
 955         }
 956
 957         if(this.snd_looping > 0)
 958         {
 959                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 960                 this.snd_looping = 0;
 961         }
 962
 963         this.enttype = 0;
 964         this.classname = "";
 965         this.draw = func_null;
 966         this.entremove = func_null;
 967         // TODO possibly set more stuff to defaults
 968 }
 969 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 970 void CSQC_Ent_Remove(entity this)
 971 {
 972         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 973         if (wasfreed(this))
 974         {
 975                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 976                 return;
 977         }
 978         if (this.enttype) Ent_Remove(this);
 979         delete(this);
 980 }
 981
 982 void Gamemode_Init()
 983 {
 984         if (!isdemo())
 985         {
 986                 if(!(calledhooks & HOOK_START))
 987                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 988                 calledhooks |= HOOK_START;
 989         }
 990 }
 991 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 992 void CSQC_Parse_StuffCmd(string strMessage)
 993 {
 994         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 995         localcmd(strMessage);
 996 }
 997 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 998 void CSQC_Parse_Print(string strMessage)
 999 {
1000         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
1001         print(ColorTranslateRGB(strMessage));
1002 }
1003
1004 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
1005 void CSQC_Parse_CenterPrint(string strMessage)
1006 {
1007         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
1008         centerprint_AddStandard(strMessage);
1009 }
1010
1011 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1012 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1013 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1014 bool CSQC_Parse_TempEntity()
1015 {
1016         // Acquire TE ID
1017         int nTEID = ReadByte();
1018
1019         FOREACH(TempEntities, it.m_id == nTEID, {
1020                 if (autocvar_developer_csqcentities)
1021                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
1022                 return it.m_read(NULL, NULL, true);
1023         });
1024
1025         if (autocvar_developer_csqcentities)
1026                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
1027
1028         // No special logic for this temporary entity; return 0 so the engine can handle it
1029         return false;
1030 }
1031
1032 string forcefog;
1033 void Fog_Force()
1034 {
1035         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
1036                 localcmd("\nr_drawfog 0\n");
1037         else if (forcefog != "")
1038                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
1039 }
1040
1041 bool net_handle_ServerWelcome();
1042 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
1043 {
1044         make_pure(this);
1045         gametype = ReadRegistered(Gametypes);
1046         teamplay = _MapInfo_GetTeamPlayBool(gametype);
1047         HUD_ModIcons_SetFunc();
1048         FOREACH(Scores, true, {
1049                 strcpy(scores_label(it), ReadString());
1050                 scores_flags(it) = ReadByte();
1051         });
1052         for (int i = 0; i < MAX_TEAMSCORE; ++i)
1053         {
1054                 strcpy(teamscores_label(i), ReadString());
1055                 teamscores_flags(i) = ReadByte();
1056         }
1057         bool welcome_msg_too = ReadByte();
1058         if (welcome_msg_too)
1059                 net_handle_ServerWelcome();
1060         return = true;
1061         Scoreboard_InitScores();
1062         Gamemode_Init();
1063 }
1064
1065 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
1066 {
1067         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1068
1069         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1070         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1071         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1072         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1073         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1074         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1075         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1076         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1077
1078         strcpy(forcefog, ReadString());
1079
1080         armorblockpercent = ReadByte() / 255.0;
1081         damagepush_speedfactor = ReadByte() / 255.0;
1082
1083         serverflags = ReadByte();
1084
1085         g_trueaim_minrange = ReadCoord();
1086
1087         return = true;
1088
1089         MUTATOR_CALLHOOK(Ent_Init);
1090
1091         if (!postinit) PostInit();
1092 }
1093
1094 float GetSpeedUnitFactor(int speed_unit)
1095 {
1096         switch(speed_unit)
1097         {
1098                 default:
1099                 case 1: return 1.0;
1100                 case 2: return 0.0254;
1101                 case 3: return 0.0254 * 3.6;
1102                 case 4: return 0.0254 * 3.6 * 0.6213711922;
1103                 case 5: return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1104         }
1105 }
1106
1107 string GetSpeedUnit(int speed_unit)
1108 {
1109         switch(speed_unit)
1110         {
1111                 // translator-friendly strings without the initial space
1112                 default:
1113                 case 1: return strcat(" ", _("qu/s"));
1114                 case 2: return strcat(" ", _("m/s"));
1115                 case 3: return strcat(" ", _("km/h"));
1116                 case 4: return strcat(" ", _("mph"));
1117                 case 5: return strcat(" ", _("knots"));
1118         }
1119 }
1120
1121 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1122 {
1123         int b = ReadByte();
1124
1125         switch (b)
1126         {
1127                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1128                         race_checkpoint = ReadByte();
1129                         race_time = ReadInt24_t();
1130                         race_previousbesttime = ReadInt24_t();
1131                         race_mypreviousbesttime = ReadInt24_t();
1132                         string pbestname = ReadString();
1133                         if(autocvar_cl_race_cptimes_onlyself)
1134                         {
1135                                 race_previousbesttime = race_mypreviousbesttime;
1136                                 race_mypreviousbesttime = 0;
1137                                 strcpy(race_previousbestname, "");
1138                         }
1139                         else
1140                                 strcpy(race_previousbestname, pbestname);
1141
1142                         race_checkpointtime = time;
1143
1144                         if(race_checkpoint == 0 || race_checkpoint == 254)
1145                         {
1146                                 race_penaltyaccumulator = 0;
1147                                 race_laptime = time; // valid
1148                         }
1149                         break;
1150
1151                 case RACE_NET_CHECKPOINT_CLEAR:
1152                         race_laptime = 0;
1153                         race_checkpointtime = 0;
1154                         break;
1155
1156                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1157                         race_laptime = ReadCoord();
1158                         race_checkpointtime = -99999;
1159                         // fall through
1160                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1161                         race_nextcheckpoint = ReadByte();
1162
1163                         race_nextbesttime = ReadInt24_t();
1164                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1165                                 race_mybesttime = ReadInt24_t();
1166                         string newname = ReadString();
1167                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1168                         {
1169                                 race_nextbesttime = race_mybesttime;
1170                                 race_mybesttime = 0;
1171                                 strcpy(race_nextbestname, "");
1172                         }
1173                         else
1174                                 strcpy(race_nextbestname, newname);
1175                         break;
1176
1177                 case RACE_NET_CHECKPOINT_HIT_RACE:
1178                         race_mycheckpoint = ReadByte();
1179                         race_mycheckpointtime = time;
1180                         race_mycheckpointdelta = ReadInt24_t();
1181                         race_mycheckpointlapsdelta = ReadByte();
1182                         if(race_mycheckpointlapsdelta >= 128)
1183                                 race_mycheckpointlapsdelta -= 256;
1184                         int who = ReadByte();
1185                         if(who)
1186                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1187                         else
1188                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1189                         break;
1190
1191                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1192                         race_othercheckpoint = ReadByte();
1193                         race_othercheckpointtime = time;
1194                         race_othercheckpointdelta = ReadInt24_t();
1195                         race_othercheckpointlapsdelta = ReadByte();
1196                         if(race_othercheckpointlapsdelta >= 128)
1197                                 race_othercheckpointlapsdelta -= 256;
1198                         int what = ReadByte();
1199                         if(what)
1200                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1201                         else
1202                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1203                         break;
1204
1205                 case RACE_NET_PENALTY_RACE:
1206                 case RACE_NET_PENALTY_QUALIFYING:
1207                         race_penaltyeventtime = time;
1208                         race_penaltytime = ReadShort();
1209                         string reason = ReadString();
1210                         if (reason == "missing a checkpoint")
1211                                 reason = _("missing a checkpoint");
1212                         strcpy(race_penaltyreason, reason);
1213                         if (b == RACE_NET_PENALTY_QUALIFYING)
1214                                 race_penaltyaccumulator += race_penaltytime;
1215                         break;
1216
1217                 case RACE_NET_SERVER_RECORD:
1218                         race_server_record = ReadInt24_t();
1219                         break;
1220                 case RACE_NET_SPEED_AWARD:
1221                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1222                         strcpy(race_speedaward_holder, ReadString());
1223                         break;
1224                 case RACE_NET_SPEED_AWARD_BEST:
1225                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1226                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1227                         break;
1228                 case RACE_NET_RANKINGS_CNT:
1229                         RANKINGS_DISPLAY_CNT = ReadByte();
1230                         break;
1231                 case RACE_NET_SERVER_RANKINGS:
1232                         float prevpos, del;
1233                         int pos = ReadShort();
1234                         prevpos = ReadShort();
1235                         del = ReadShort();
1236
1237                         // move other rankings out of the way
1238                         int i;
1239                         if (prevpos) {
1240                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1241                                 for (i=m-1; i>pos-1; --i) {
1242                                         grecordtime[i] = grecordtime[i-1];
1243                                         strcpy(grecordholder[i], grecordholder[i-1]);
1244                                 }
1245                         } else if (del) { // a record has been deleted by the admin
1246                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1247                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1248                                                 grecordtime[i] = 0;
1249                                                 strfree(grecordholder[i]);
1250                                         }
1251                                         else {
1252                                                 grecordtime[i] = grecordtime[i+1];
1253                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1254                                         }
1255                                 }
1256                         } else { // player has no ranked record yet
1257                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1258                                         grecordtime[i] = grecordtime[i-1];
1259                                         strcpy(grecordholder[i], grecordholder[i-1]);
1260                                 }
1261                         }
1262
1263                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1264                                 // kick off the player who fell from the last displayed position
1265                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1266                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1267                         }
1268
1269                         // store new ranking
1270                         strcpy(grecordholder[pos-1], ReadString());
1271                         grecordtime[pos-1] = ReadInt24_t();
1272                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1273                                 race_myrank = pos;
1274                         break;
1275                 case RACE_NET_SERVER_STATUS:
1276                         race_status = ReadShort();
1277                         strcpy(race_status_name, ReadString());
1278         }
1279         return true;
1280 }
1281
1282 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1283 {
1284         teamnagger = 1;
1285         return true;
1286 }
1287
1288 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1289 {
1290         int i = ReadByte();
1291         int pi = ReadShort();
1292         int pl = ReadByte();
1293         int ml = ReadByte();
1294         return = true;
1295         entity e = playerslots[i];
1296         if (!e) return;
1297         e.ping = pi;
1298         e.ping_packetloss = pl / 255.0;
1299         e.ping_movementloss = ml / 255.0;
1300 }
1301
1302 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1303 {
1304         int weapon_id = ReadByte();
1305         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1306         complain_weapon_type = ReadByte();
1307         return = true;
1308
1309         complain_weapon_time = time;
1310         weapontime = time; // ping the weapon panel
1311
1312         switch(complain_weapon_type)
1313         {
1314                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1315                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1316                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1317         }
1318 }
1319
1320 string translate_modifications(string s)
1321 {
1322         return build_mutator_list(s);
1323 }
1324
1325 string translate_weaponarena(string s)
1326 {
1327         if (s == "") return s;
1328         if (s == "All Weapons Arena") return _("All Weapons Arena");
1329         if (s == "All Available Weapons Arena") return _("All Available Weapons Arena");
1330         if (s == "Most Weapons Arena") return _("Most Weapons Arena");
1331         if (s == "Most Available Weapons Arena") return _("Most Available Weapons Arena");
1332         if (s == "Dev All Weapons Arena") return s; // development option, do not translate
1333         if (s == "Dev All Available Weapons Arena") return s; // development option, do not translate
1334         if (s == "No Weapons Arena") return _("No Weapons Arena");
1335
1336         int n = tokenizebyseparator(s, " & ");
1337         string wpn_list = "";
1338         for (int i = 0; i < n; i++)
1339         {
1340                 Weapon wep = Weapon_from_name(argv(i));
1341                 if (wep == WEP_Null)
1342                         LOG_INFO("^3Warning: ^7server sent an invalid weapon name\n");
1343                 wpn_list = cons_mid(wpn_list, " & ", wep.m_name);
1344         }
1345         if (wpn_list != "")
1346                 return sprintf(_("%s Arena"), wpn_list);
1347         else
1348                 return _("No Weapons Arena");
1349 }
1350
1351 string GetVersionMessage(string hostversion, bool version_mismatch, bool version_check)
1352 {
1353         string xonotic_hostversion = strcat("Xonotic ", hostversion);
1354         if (version_mismatch)
1355         {
1356                 if(!version_check)
1357                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1358                                 _("Your client version is outdated."), "\n\n\n",
1359                                 _("### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###"), "\n\n\n",
1360                                 _("Please update!"));
1361                 else
1362                         return strcat(sprintf(_("This is %s"), xonotic_hostversion), "\n^3",
1363                                 _("This server is using an outdated Xonotic version."), "\n\n\n",
1364                                 _("### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###"));
1365         }
1366         return sprintf(_("Welcome to %s"), xonotic_hostversion);
1367 }
1368
1369 bool net_handle_ServerWelcome()
1370 {
1371         bool campaign = ReadByte();
1372         if (campaign)
1373         {
1374                 string campaign_title = ReadString();
1375                 int campaign_level = ReadByte();
1376                 string campaign_msg = ReadString();
1377                 string welcomedialog_args;
1378                 welcomedialog_args = strcat("HOSTNAME \"", campaign_title, "\"");
1379                 string key = getcommandkey(_("jump"), "+jump");
1380                 string msg = strcat(
1381                         CCR("^F1"), sprintf(_("Level %d:"), campaign_level),
1382                         sprintf(CCR(" ^BG%s\n^3\n"), campaign_msg),
1383                         sprintf(CCR(_("^BGPress ^F2%s^BG to enter the game")), key));
1384                 msg = MakeConsoleSafe(strreplace("\n", "\\n", msg));
1385                 welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1386                 localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1387                 return true;
1388         }
1389
1390         welcome_msg_force_centerprint = ReadByte();
1391         strcpy(hostname, ReadString());
1392
1393         string hostversion = ReadString();
1394         bool version_mismatch = ReadByte();
1395         bool version_check = ReadByte();
1396         string ver = GetVersionMessage(hostversion, version_mismatch, version_check);
1397
1398         string modifications = translate_modifications(ReadString());
1399         string weaponarena_list = translate_weaponarena(ReadString());
1400         string cache_mutatormsg = ReadString();
1401         string motd = ReadString();
1402
1403         string msg = "";
1404         msg = strcat(msg, ver);
1405         msg = strcat(msg, "^8\n\n", strcat(_("Gametype:"), " ^1", MapInfo_Type_ToText(gametype)), "^8\n");
1406
1407         modifications = cons_mid(modifications, ", ", weaponarena_list);
1408         if(modifications != "")
1409                 msg = strcat(msg, "^8\n", _("Active modifications:"), " ^3", modifications, "^8\n");
1410
1411         if (cache_mutatormsg != "")
1412                 msg = strcat(msg, "\n\n^8", _("Special gameplay tips:"), " ^7", cache_mutatormsg);
1413         string mutator_msg = "";
1414         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1415         mutator_msg = M_ARGV(0, string);
1416         msg = strcat(msg, mutator_msg); // trust that the mutator will do proper formatting
1417
1418         if (motd != "")
1419                 msg = strcat(msg, "\n\n^8", _("MOTD:"), " ^7", motd);
1420
1421         strcpy(welcome_msg, msg);
1422         welcome_msg_menu_check_maxtime = time + 1; // wait for menu to load before showing the welcome dialog
1423         return true;
1424 }
1425
1426 void Welcome_Message_Show_Try()
1427 {
1428         if (!welcome_msg_menu_check_maxtime)
1429                 return;
1430
1431         bool want_dialog = (!welcome_msg_force_centerprint && !isdemo() && autocvar_cl_welcome_in_menu_dialog);
1432         // if want dialog check if menu is initialized but for a short time
1433         if (!want_dialog || cvar("_menu_initialized") == 2 || time > welcome_msg_menu_check_maxtime)
1434         {
1435                 if (want_dialog && cvar("_menu_welcome_dialog_available"))
1436                 {
1437                         string welcomedialog_args = strcat("HOSTNAME \"", hostname, "\"");
1438                         string msg = MakeConsoleSafe(strreplace("\n", "\\n", welcome_msg));
1439                         welcomedialog_args = strcat(welcomedialog_args, " WELCOME \"", msg, "\"");
1440                         localcmd("\nmenu_cmd directmenu Welcome ", welcomedialog_args, "\n");
1441                         if (intermission) // close it after it's been initialized so it can still be opened manually
1442                                 localcmd("\ntogglemenu 0\n");
1443                 }
1444                 else
1445                         centerprint_Add(ORDINAL(CPID_MOTD), strcat(hostname, "\n\n\n", welcome_msg), -1, 0);
1446
1447                 strfree(welcome_msg);
1448                 welcome_msg_menu_check_maxtime = 0;
1449         }
1450 }
1451
1452 NET_HANDLE(TE_CSQC_SERVERWELCOME, bool isNew)
1453 {
1454         return net_handle_ServerWelcome();
1455 }
1456
1457 string _getcommandkey(string cmd_name, string command, bool forcename)
1458 {
1459         string keys;
1460         float n, j, k, l = 0;
1461
1462         if (!autocvar_hud_showbinds)
1463                 return cmd_name;
1464
1465         keys = db_get(binddb, command);
1466         if (keys == "")
1467         {
1468                 bool joy_active = cvar("joy_active");
1469                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1470                 for(j = 0; j < n; ++j)
1471                 {
1472                         k = stof(argv(j));
1473                         if(k != -1)
1474                         {
1475                                 string key = keynumtostring(k);
1476                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1477                                         continue;
1478
1479                                 key = translate_key(key);
1480
1481                                 if (keys == "")
1482                                         keys = key;
1483                                 else
1484                                         keys = strcat(keys, ", ", key);
1485
1486                                 ++l;
1487                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1488                                         break;
1489                         }
1490
1491                 }
1492                 if (keys == "")
1493                         keys = "NO_KEY";
1494                 db_put(binddb, command, keys);
1495         }
1496
1497         if (keys == "NO_KEY") {
1498                 if (autocvar_hud_showbinds > 1)
1499                         return sprintf(_("%s (not bound)"), cmd_name);
1500                 else
1501                         return cmd_name;
1502         }
1503         else if (autocvar_hud_showbinds > 1 || forcename)
1504                 return sprintf("%s (%s)", cmd_name, keys);
1505         else
1506                 return keys;
1507 }
1508
1509 /** engine callback */
1510 void URI_Get_Callback(int id, int status, string data)
1511 {
1512         TC(int, id); TC(int, status);
1513         if(url_URI_Get_Callback(id, status, data))
1514         {
1515                 // handled
1516         }
1517         else if (id == URI_GET_DISCARD)
1518         {
1519                 // discard
1520         }
1521         else if (id >= URI_GET_CURL && id <= URI_GET_CURL_END)
1522         {
1523                 // sv_cmd curl
1524                 Curl_URI_Get_Callback(id, status, data);
1525         }
1526         else
1527         {
1528                 LOG_INFOF("Received HTTP request data for an invalid id %d.", id);
1529         }
1530 }