qcsrc/client/main.qc

   1 #include "main.qh"
   2
   3 #include "defs.qh"
   4 #include <common/ent_cs.qh>
   5 #include "miscfunctions.qh"
   6 #include <common/effects/effect.qh>
   7 #include <common/effects/qc/_mod.qh>
   8 #include <common/effects/all.qh>
   9 #include <common/effects/all.inc>
  10 #include "hud/_mod.qh"
  11 #include "commands/cl_cmd.qh"
  12 #include "mapvoting.qh"
  13 #include <client/mutators/_mod.qh>
  14 #include "hud/panel/centerprint.qh"
  15 #include "hud/panel/scoreboard.qh"
  16 #include "hud/panel/quickmenu.qh"
  17 #include "shownames.qh"
  18 #include "view.qh"
  19 #include <common/t_items.qh>
  20 #include "weapons/projectile.qh"
  21 #include <common/deathtypes/all.qh>
  22 #include <common/items/_mod.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/minigames/cl_minigames.qh>
  25 #include <common/minigames/cl_minigames_hud.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/scores.qh>
  29 #include <common/mapobjects/_mod.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include <lib/csqcmodel/interpolate.qh>
  33 #include <lib/warpzone/client.qh>
  34
  35 // --------------------------------------------------------------------------
  36 // BEGIN REQUIRED CSQC FUNCTIONS
  37 //include "main.qh"
  38
  39 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  40
  41 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
  42 {
  43         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
  44         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
  45 }
  46
  47 void draw_cursor_normal(vector pos, vector col, float a)
  48 {
  49         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
  50 }
  51
  52 void LoadMenuSkinValues()
  53 {
  54         int fh = -1;
  55         if(cvar_string("menu_skin") != "")
  56         {
  57                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  58                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  59         }
  60         if(fh < 0 && cvar_defstring("menu_skin") != "")
  61         {
  62                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
  63                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
  64                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  65         }
  66         if(fh < 0)
  67         {
  68                 draw_currentSkin = "gfx/menu/default";
  69                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
  70         }
  71
  72         draw_currentSkin = strzone(draw_currentSkin);
  73
  74         if(fh >= 0)
  75         {
  76                 string s;
  77                 while((s = fgets(fh)))
  78                 {
  79                         int n = tokenize_console(s);
  80                         if (n < 2)
  81                                 continue;
  82                         if(substring(argv(0), 0, 2) == "//")
  83                                 continue;
  84                         if(argv(0) == "SIZE_CURSOR")
  85                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  86                         else if(argv(0) == "OFFSET_CURSOR")
  87                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
  88                 }
  89                 fclose(fh);
  90         }
  91 }
  92
  93 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  94 // Useful for precaching things
  95
  96 void CSQC_Init()
  97 {
  98         prvm_language = strzone(cvar_string("prvm_language"));
  99
 100 #ifdef WATERMARK
 101         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
 102 #endif
 103
 104         {
 105                 int i = 0;
 106                 for ( ; i < 255; ++i)
 107                         if (getplayerkeyvalue(i, "viewentity") == "")
 108                                 break;
 109                 maxclients = i;
 110         }
 111
 112         // needs to be done so early because of the constants they create
 113         static_init();
 114         static_init_late();
 115         static_init_precache();
 116
 117         binddb = db_create();
 118         tempdb = db_create();
 119         ClientProgsDB = db_load("client.db");
 120
 121         draw_endBoldFont();
 122
 123         //registercommand("hud_configure");
 124         //registercommand("hud_save");
 125         //registercommand("menu_action");
 126
 127         ConsoleCommand_macro_init();
 128
 129         registercvar("hud_usecsqc", "1");
 130         registercvar("scoreboard_columns", "default");
 131
 132         registercvar("cl_nade_type", "3");
 133         registercvar("cl_pokenade_type", "zombie");
 134
 135         registercvar("cl_jumpspeedcap_min", "");
 136         registercvar("cl_jumpspeedcap_max", "");
 137
 138         registercvar("cl_shootfromfixedorigin", "");
 139
 140         registercvar("cl_multijump", "-1");
 141
 142         registercvar("cl_dodging", "0");
 143
 144         registercvar("cl_spawn_near_teammate", "1");
 145
 146         registercvar("cl_weapon_switch_reload", "1");
 147         registercvar("cl_weapon_switch_fallback_to_impulse", "1");
 148
 149         registercvar("cl_allow_uidranking", "1");
 150
 151         if(autocvar_cl_lockview)
 152                 cvar_set("cl_lockview", "0");
 153
 154         gametype = NULL;
 155
 156         postinit = false;
 157
 158         calledhooks = 0;
 159
 160         teams = Sort_Spawn();
 161         players = Sort_Spawn();
 162
 163         GetTeam(NUM_SPECTATOR, true); // add specs first
 164
 165         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 166                 weapon_accuracy[w] = -1;
 167
 168         // precaches
 169
 170         if(autocvar_cl_reticle)
 171         {
 172                 precache_pic("gfx/reticle_normal");
 173                 // weapon reticles are precached in weapon files
 174         }
 175
 176         {
 177                 get_mi_min_max_texcoords(1); // try the CLEVER way first
 178                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 179                 shortmapname = mi_shortname;
 180
 181                 if (precache_pic(minimapname) == "")
 182                 {
 183                         // but maybe we have a non-clever minimap
 184                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 185                         if (precache_pic(minimapname) == "")
 186                                 minimapname = ""; // FAIL
 187                         else
 188                                 get_mi_min_max_texcoords(0); // load new texcoords
 189                 }
 190
 191                 mi_center = (mi_min + mi_max) * 0.5;
 192                 mi_scale = mi_max - mi_min;
 193                 minimapname = strzone(minimapname);
 194         }
 195
 196         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 197         LoadMenuSkinValues();
 198 }
 199
 200 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 201 void Shutdown()
 202 {
 203         WarpZone_Shutdown();
 204
 205         delete(teams);
 206         delete(players);
 207         db_close(binddb);
 208         db_close(tempdb);
 209         if(autocvar_cl_db_saveasdump)
 210                 db_dump(ClientProgsDB, "client.db");
 211         else
 212                 db_save(ClientProgsDB, "client.db");
 213         db_close(ClientProgsDB);
 214
 215         if(camera_active)
 216                 cvar_set("chase_active",ftos(chase_active_backup));
 217
 218         // unset the event chasecam's chase_active
 219         if(autocvar_chase_active < 0)
 220                 cvar_set("chase_active", "0");
 221
 222         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
 223
 224         if (!isdemo())
 225         {
 226                 if (!(calledhooks & HOOK_START))
 227                         localcmd("\n_cl_hook_gamestart nop\n");
 228                 if (!(calledhooks & HOOK_END))
 229                         localcmd("\ncl_hook_gameend\n");
 230         }
 231
 232         localcmd("\ncl_hook_shutdown\n");
 233
 234         localcmd("\n-button12\n");
 235
 236         deactivate_minigame();
 237         HUD_MinigameMenu_Close(NULL, NULL, NULL);
 238
 239         ReplicateVars(true); // destroy
 240 }
 241
 242 .float has_team;
 243 bool SetTeam(entity o, int Team)
 244 {
 245         TC(int, Team);
 246         //devassert_once(Team);
 247         entity tm;
 248         if(teamplay)
 249         {
 250                 switch(Team)
 251                 {
 252                         case -1:
 253                         case NUM_TEAM_1:
 254                         case NUM_TEAM_2:
 255                         case NUM_TEAM_3:
 256                         case NUM_TEAM_4:
 257                                 break;
 258                         default:
 259                                 if(GetTeam(Team, false) == NULL)
 260                                 {
 261                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 262                                         Team = NUM_SPECTATOR;
 263                                 }
 264                                 break;
 265                 }
 266         }
 267         else
 268         {
 269                 switch(Team)
 270                 {
 271                         case -1:
 272                         case 0:
 273                                 break;
 274                         default:
 275                                 if(GetTeam(Team, false) == NULL)
 276                                 {
 277                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
 278                                         Team = NUM_SPECTATOR;
 279                                 }
 280                                 break;
 281                 }
 282         }
 283         if(Team == -1) // leave
 284         {
 285                 if(o.has_team)
 286                 {
 287                         tm = GetTeam(o.team, false);
 288                         tm.team_size -= 1;
 289                         o.has_team = 0;
 290                         return true;
 291                 }
 292         }
 293         else
 294         {
 295                 if (!o.has_team)
 296                 {
 297                         o.team = Team;
 298                         tm = GetTeam(Team, true);
 299                         tm.team_size += 1;
 300                         o.has_team = 1;
 301                         return true;
 302                 }
 303                 else if(Team != o.team)
 304                 {
 305                         tm = GetTeam(o.team, false);
 306                         tm.team_size -= 1;
 307                         o.team = Team;
 308                         tm = GetTeam(Team, true);
 309                         tm.team_size += 1;
 310                         return true;
 311                 }
 312         }
 313         return false;
 314 }
 315
 316 void Playerchecker_Think(entity this)
 317 {
 318         int i;
 319         entity e;
 320         for(i = 0; i < maxclients; ++i)
 321         {
 322                 e = playerslots[i];
 323                 if(entcs_GetName(i) == "")
 324                 {
 325                         if(e.sort_prev)
 326                         {
 327                                 // player disconnected
 328                                 SetTeam(e, -1);
 329                                 RemovePlayer(e);
 330                                 e.sort_prev = NULL;
 331                                 //e.gotscores = 0;
 332                         }
 333                 }
 334                 else
 335                 {
 336                         if (!e.sort_prev)
 337                         {
 338                                 // player connected
 339                                 if (!e)
 340                                 {
 341                                         playerslots[i] = e = new_pure(playerslot);
 342                                 }
 343                                 e.sv_entnum = i;
 344                                 e.ping = 0;
 345                                 e.ping_packetloss = 0;
 346                                 e.ping_movementloss = 0;
 347                                 //e.gotscores = 0; // we might already have the scores...
 348                                 int t = entcs_GetScoreTeam(i);
 349                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
 350                                 RegisterPlayer(e);
 351                                 Scoreboard_UpdatePlayerPos(e);
 352                         }
 353                 }
 354         }
 355         this.nextthink = time + 0.2;
 356 }
 357
 358 void PostInit()
 359 {
 360         entity playerchecker = new_pure(playerchecker);
 361         setthink(playerchecker, Playerchecker_Think);
 362         playerchecker.nextthink = time + 0.2;
 363
 364         TrueAim_Init();
 365
 366         postinit = true;
 367 }
 368
 369 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 370 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 371 // All keys are in ascii.
 372 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 373 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 374 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 375 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 376 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
 377 {
 378         TC(int, bInputType);
 379         bool override = false;
 380         override |= HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary);
 381         if (override)
 382                 return true;
 383
 384         override |= QuickMenu_InputEvent(bInputType, nPrimary, nSecondary);
 385
 386         override |= HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary);
 387
 388         override |= MapVote_InputEvent(bInputType, nPrimary, nSecondary);
 389
 390         override |= HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary);
 391
 392         if(override)
 393                 return true;
 394
 395         return false;
 396 }
 397
 398 // END REQUIRED CSQC FUNCTIONS
 399 // --------------------------------------------------------------------------
 400
 401 // --------------------------------------------------------------------------
 402 // BEGIN OPTIONAL CSQC FUNCTIONS
 403
 404 void Ent_RemovePlayerScore(entity this)
 405 {
 406         if(this.owner) {
 407                 SetTeam(this.owner, -1);
 408                 this.owner.gotscores = 0;
 409                 FOREACH(Scores, true, {
 410                         this.owner.(scores(it)) = 0; // clear all scores
 411                 });
 412         }
 413 }
 414
 415 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
 416 {
 417         make_pure(this);
 418         entity o;
 419
 420         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 421         // (no I've never heard of M-x replace-string, sed, or anything like that)
 422         bool isNew = !this.owner; // workaround for DP bug
 423         int n = ReadByte()-1;
 424
 425 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 426         if(!isNew && n != this.sv_entnum)
 427         {
 428                 //print("A CSQC entity changed its owner!\n");
 429                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
 430                 isNew = true;
 431                 Ent_Remove(this);
 432         }
 433 #endif
 434
 435         this.sv_entnum = n;
 436
 437         o = playerslots[this.sv_entnum];
 438         if (!o)
 439         {
 440                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
 441         }
 442         this.owner = o;
 443         o.sv_entnum = this.sv_entnum;
 444         o.gotscores = 1;
 445
 446         //if (!o.sort_prev)
 447         //      RegisterPlayer(o);
 448         //playerchecker will do this for us later, if it has not already done so
 449
 450         int sf = ReadShort();
 451         int lf = ReadShort();
 452         FOREACH(Scores, true, {
 453                 int p = 1 << (i % 16);
 454                 if (sf & p)
 455                 {
 456                         if (lf & p)
 457                                 o.(scores(it)) = ReadInt24_t();
 458                         else
 459                                 o.(scores(it)) = ReadChar();
 460                 }
 461         });
 462
 463         return = true;
 464
 465         if(o.sort_prev)
 466                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 467
 468         this.entremove = Ent_RemovePlayerScore;
 469 }
 470
 471 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
 472 {
 473         make_pure(this);
 474         int i;
 475
 476         this.team = ReadByte();
 477         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
 478
 479 #if MAX_TEAMSCORE <= 8
 480         int sf = ReadByte();
 481         int lf = ReadByte();
 482 #else
 483         int sf = ReadShort();
 484         int lf = ReadShort();
 485 #endif
 486         for(i = 0; i < MAX_TEAMSCORE; ++i)
 487                 if(sf & BIT(i))
 488                 {
 489                         if(lf & BIT(i))
 490                                 o.(teamscores(i)) = ReadInt24_t();
 491                         else
 492                                 o.(teamscores(i)) = ReadChar();
 493                 }
 494
 495         return = true;
 496
 497         Scoreboard_UpdateTeamPos(o);
 498 }
 499
 500 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
 501 {
 502         make_pure(this);
 503         float newspectatee_status;
 504
 505         int f = ReadByte();
 506
 507         scoreboard_showscores_force = (f & BIT(0));
 508
 509         if(f & BIT(1))
 510         {
 511                 newspectatee_status = ReadByte();
 512                 if(newspectatee_status == player_localnum + 1)
 513                         newspectatee_status = -1; // observing
 514         }
 515         else
 516                 newspectatee_status = 0;
 517
 518         spectatorbutton_zoom = (f & BIT(2));
 519
 520         if(f & BIT(4))
 521         {
 522                 num_spectators = ReadByte();
 523
 524                 float i, slot;
 525
 526                 for(i = 0; i < MAX_SPECTATORS; ++i)
 527                         spectatorlist[i] = 0; // reset list first
 528
 529                 for(i = 0; i < num_spectators; ++i)
 530                 {
 531                         slot = ReadByte();
 532                         spectatorlist[i] = slot - 1;
 533                 }
 534         }
 535
 536         return = true;
 537
 538         if(newspectatee_status != spectatee_status)
 539         {
 540                 // clear race stuff
 541                 race_laptime = 0;
 542                 race_checkpointtime = 0;
 543                 hud_dynamic_shake_factor = -1;
 544                 spectatee_status_changed_time = time;
 545         }
 546         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 547         {
 548                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 549                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 550                 )
 551                         prev_p_health = -1;
 552                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 553                         prev_health = -1;
 554         }
 555         spectatee_status = newspectatee_status;
 556
 557         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 558 }
 559
 560 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
 561 {
 562         make_pure(this);
 563         int i, j, b, f;
 564
 565         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 566
 567         if(!(nags & BIT(2)))
 568         {
 569                 strfree(vote_called_vote);
 570                 vote_active = 0;
 571         }
 572         else
 573         {
 574                 vote_active = 1;
 575         }
 576
 577         if(nags & BIT(6))
 578         {
 579                 vote_yescount = ReadByte();
 580                 vote_nocount = ReadByte();
 581                 vote_needed = ReadByte();
 582                 vote_highlighted = ReadChar();
 583         }
 584
 585         if(nags & BIT(7))
 586         {
 587                 strcpy(vote_called_vote, ReadString());
 588         }
 589
 590         if(nags & 1)
 591         {
 592                 for(j = 0; j < maxclients; ++j)
 593                         if(playerslots[j])
 594                                 playerslots[j].ready = true;
 595                 for(i = 1; i <= maxclients; i += 8)
 596                 {
 597                         f = ReadByte();
 598                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
 599                                 if (!(f & b))
 600                                         if(playerslots[j])
 601                                                 playerslots[j].ready = false;
 602                 }
 603         }
 604
 605         return = true;
 606
 607         ready_waiting = (nags & BIT(0));
 608         ready_waiting_for_me = (nags & BIT(1));
 609         vote_waiting = (nags & BIT(2));
 610         vote_waiting_for_me = (nags & BIT(3));
 611         warmup_stage = (nags & BIT(4));
 612 }
 613
 614 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
 615 {
 616         make_pure(this);
 617         int sf = 0;
 618         serialize(byte, 0, sf);
 619         if (sf & 1) {
 620                 for (int j = 0; j < maxclients; ++j) {
 621                         if (playerslots[j]) {
 622                                 playerslots[j].eliminated = true;
 623                         }
 624                 }
 625                 for (int i = 1; i <= maxclients; i += 8) {
 626                         int f = 0;
 627                         serialize(byte, 0, f);
 628                         for (int b = 0; b < 8; ++b) {
 629                                 if (f & BIT(b)) continue;
 630                                 int j = i - 1 + b;
 631                                 if (playerslots[j]) {
 632                                         playerslots[j].eliminated = false;
 633                                 }
 634                         }
 635                 }
 636         }
 637         return true;
 638 }
 639
 640 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
 641 {
 642         make_pure(this);
 643         prandom_debug();
 644         float s = ReadShort();
 645         psrandom(s);
 646         return true;
 647 }
 648
 649 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
 650 {
 651         make_pure(this);
 652         int sf = ReadInt24_t();
 653         if (sf == 0) {
 654                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 655                         weapon_accuracy[w] = -1;
 656                 return true;
 657         }
 658
 659         int f = 1;
 660         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
 661                 if (sf & f) {
 662                         int b = ReadByte();
 663                         if (b == 0)
 664                                 weapon_accuracy[w] = -1;
 665                         else if (b == 255)
 666                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 667                         else
 668                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 669                 }
 670                 f = (f == 0x800000) ? 1 : f * 2;
 671         }
 672         return true;
 673 }
 674
 675 void Spawn_Draw(entity this)
 676 {
 677         bool dodraw = autocvar_cl_spawn_point_particles;
 678         if(dodraw && autocvar_cl_spawn_point_dist_max)
 679         {
 680                 vector org = getpropertyvec(VF_ORIGIN);
 681                 dodraw = vdist(org - this.origin, <, autocvar_cl_spawn_point_dist_max);
 682         }
 683
 684         if(dodraw)
 685                 pointparticles(((!teamplay) ? EFFECT_SPAWNPOINT_NEUTRAL : EFFECT_SPAWNPOINT(this.team - 1)), this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 686 }
 687
 688 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
 689 {
 690         float teamnum = (ReadByte() - 1);
 691         vector spn_origin = ReadVector();
 692
 693         this.team = (teamnum + 1);
 694
 695         //if(is_new)
 696         //{
 697                 this.origin = spn_origin;
 698                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
 699                 //droptofloor();
 700
 701                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 702                 {
 703                         this.mdl = "models/spawnpoint.md3";
 704                         this.colormod = Team_ColorRGB(teamnum);
 705                         precache_model(this.mdl);
 706                         setmodel(this, this.mdl);
 707                         this.drawmask = MASK_NORMAL;
 708                         //this.move_movetype = MOVETYPE_NOCLIP;
 709                         //this.draw = Spawn_Draw;
 710                         IL_PUSH(g_drawables, this);
 711                 }*/
 712                 this.draw = Spawn_Draw;
 713                 if (is_new) IL_PUSH(g_drawables, this);
 714         //}
 715
 716         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
 717         return true;
 718 }
 719
 720 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
 721 {
 722         // If entnum is 0, ONLY do the local spawn actions
 723         // this way the server can disable the sending of
 724         // spawn origin or such to clients if wanted.
 725         float entnum = ReadByte();
 726
 727         if(entnum)
 728         {
 729                 this.origin = ReadVector();
 730
 731                 if(is_new)
 732                 {
 733                         float teamnum = entcs_GetTeam(entnum - 1);
 734
 735                         if(autocvar_cl_spawn_event_particles)
 736                         {
 737                                 switch(teamnum)
 738                                 {
 739                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
 740                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
 741                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
 742                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
 743                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
 744                                 }
 745                         }
 746                         if(autocvar_cl_spawn_event_sound)
 747                         {
 748                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 749                         }
 750                 }
 751         }
 752         return = true;
 753
 754         // local spawn actions
 755         if(is_new && (!entnum || (entnum == player_localentnum)))
 756         {
 757                 if(autocvar_cl_spawnzoom && !autocvar_cl_lockview)
 758                 {
 759                         zoomin_effect = 1;
 760                         current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 761                 }
 762
 763                 if(autocvar_cl_unpress_zoom_on_spawn)
 764                 {
 765                         localcmd("-zoom\n");
 766                         button_zoom = false;
 767                 }
 768                 HUD_Radar_Hide_Maximized();
 769         }
 770         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
 771 }
 772
 773 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 774 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 775 void CSQC_Ent_Update(entity this, bool isnew)
 776 {
 777         this.sourceLoc = __FILE__":"STR(__LINE__);
 778         int t = ReadByte();
 779
 780         // set up the "time" global for received entities to be correct for interpolation purposes
 781         float savetime = time;
 782         if(servertime)
 783         {
 784                 time = servertime;
 785         }
 786         else
 787         {
 788                 serverprevtime = time;
 789                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
 790                 time = serverprevtime + serverdeltatime;
 791         }
 792
 793 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 794         if (this.enttype)
 795         {
 796                 if (t != this.enttype || isnew)
 797                 {
 798                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
 799                         Ent_Remove(this);
 800                         clearentity(this);
 801                         isnew = true;
 802                 }
 803         }
 804         else
 805         {
 806                 if (!isnew)
 807                 {
 808                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
 809                         isnew = true;
 810                 }
 811         }
 812 #endif
 813         this.enttype = t;
 814         bool done = false;
 815         FOREACH(LinkedEntities, it.m_id == t, {
 816                 if (isnew) this.classname = it.netname;
 817                 if (autocvar_developer_csqcentities)
 818             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 819                 done = it.m_read(this, NULL, isnew);
 820                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
 821                 break;
 822         });
 823         time = savetime;
 824         if (!done)
 825         {
 826                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
 827         }
 828 }
 829
 830 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 831 // used when an entity changes its type. For an entity that someone interacts
 832 // with others, make sure it can no longer do so.
 833 void Ent_Remove(entity this)
 834 {
 835         if(this.entremove) this.entremove(this);
 836
 837         if(this.skeletonindex)
 838         {
 839                 skel_delete(this.skeletonindex);
 840                 this.skeletonindex = 0;
 841         }
 842
 843         if(this.snd_looping > 0)
 844         {
 845                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 846                 this.snd_looping = 0;
 847         }
 848
 849         this.enttype = 0;
 850         this.classname = "";
 851         this.draw = func_null;
 852         this.entremove = func_null;
 853         // TODO possibly set more stuff to defaults
 854 }
 855 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
 856 void CSQC_Ent_Remove(entity this)
 857 {
 858         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
 859         if (wasfreed(this))
 860         {
 861                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
 862                 return;
 863         }
 864         if (this.enttype) Ent_Remove(this);
 865         delete(this);
 866 }
 867
 868 void Gamemode_Init()
 869 {
 870         if (!isdemo())
 871         {
 872                 if(!(calledhooks & HOOK_START))
 873                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 874                 calledhooks |= HOOK_START;
 875         }
 876 }
 877 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 878 void CSQC_Parse_StuffCmd(string strMessage)
 879 {
 880         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
 881         localcmd(strMessage);
 882 }
 883 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 884 void CSQC_Parse_Print(string strMessage)
 885 {
 886         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
 887         print(ColorTranslateRGB(strMessage));
 888 }
 889
 890 // CSQC_Parse_CenterPrint : Provides the centerprint_AddStandard string in the first parameter that the server provided.
 891 void CSQC_Parse_CenterPrint(string strMessage)
 892 {
 893         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
 894         centerprint_AddStandard(strMessage);
 895 }
 896
 897 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
 898 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
 899 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
 900 bool CSQC_Parse_TempEntity()
 901 {
 902         // Acquire TE ID
 903         int nTEID = ReadByte();
 904
 905         FOREACH(TempEntities, it.m_id == nTEID, {
 906                 if (autocvar_developer_csqcentities)
 907                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
 908                 return it.m_read(NULL, NULL, true);
 909         });
 910
 911         if (autocvar_developer_csqcentities)
 912                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
 913
 914         // No special logic for this temporary entity; return 0 so the engine can handle it
 915         return false;
 916 }
 917
 918 string forcefog;
 919 void Fog_Force()
 920 {
 921         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 922                 localcmd("\nr_drawfog 0\n");
 923         else if (forcefog != "")
 924                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
 925 }
 926
 927 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
 928 {
 929         make_pure(this);
 930         gametype = ReadRegistered(Gametypes);
 931         teamplay = _MapInfo_GetTeamPlayBool(gametype);
 932         HUD_ModIcons_SetFunc();
 933         FOREACH(Scores, true, {
 934                 strcpy(scores_label(it), ReadString());
 935                 scores_flags(it) = ReadByte();
 936         });
 937         for (int i = 0; i < MAX_TEAMSCORE; ++i)
 938         {
 939                 strcpy(teamscores_label(i), ReadString());
 940                 teamscores_flags(i) = ReadByte();
 941         }
 942         return = true;
 943         Scoreboard_InitScores();
 944         Gamemode_Init();
 945 }
 946
 947 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
 948 {
 949         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 950
 951         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 952         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 953         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 954         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 955         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 956         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 957         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 958         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 959
 960         strcpy(forcefog, ReadString());
 961
 962         armorblockpercent = ReadByte() / 255.0;
 963         damagepush_speedfactor = ReadByte() / 255.0;
 964
 965         serverflags = ReadByte();
 966
 967         g_trueaim_minrange = ReadCoord();
 968
 969         return = true;
 970
 971         MUTATOR_CALLHOOK(Ent_Init);
 972
 973         if (!postinit) PostInit();
 974 }
 975
 976 float GetSpeedUnitFactor(int speed_unit)
 977 {
 978         switch(speed_unit)
 979         {
 980                 default:
 981                 case 1:
 982                         return 1.0;
 983                 case 2:
 984                         return 0.0254;
 985                 case 3:
 986                         return 0.0254 * 3.6;
 987                 case 4:
 988                         return 0.0254 * 3.6 * 0.6213711922;
 989                 case 5:
 990                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
 991         }
 992 }
 993
 994 string GetSpeedUnit(int speed_unit)
 995 {
 996         switch(speed_unit)
 997         {
 998                 default:
 999                 case 1:
1000                         return _(" qu/s");
1001                 case 2:
1002                         return _(" m/s");
1003                 case 3:
1004                         return _(" km/h");
1005                 case 4:
1006                         return _(" mph");
1007                 case 5:
1008                         return _(" knots");
1009         }
1010 }
1011
1012 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1013 {
1014         int b = ReadByte();
1015
1016         switch (b)
1017         {
1018                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1019                         race_checkpoint = ReadByte();
1020                         race_time = ReadInt24_t();
1021                         race_previousbesttime = ReadInt24_t();
1022                         race_mypreviousbesttime = ReadInt24_t();
1023                         string pbestname = ReadString();
1024                         if(autocvar_cl_race_cptimes_onlyself)
1025                         {
1026                                 race_previousbesttime = race_mypreviousbesttime;
1027                                 race_mypreviousbesttime = 0;
1028                                 strcpy(race_previousbestname, "");
1029                         }
1030                         else
1031                                 strcpy(race_previousbestname, pbestname);
1032
1033                         race_checkpointtime = time;
1034
1035                         if(race_checkpoint == 0 || race_checkpoint == 254)
1036                         {
1037                                 race_penaltyaccumulator = 0;
1038                                 race_laptime = time; // valid
1039                         }
1040                         break;
1041
1042                 case RACE_NET_CHECKPOINT_CLEAR:
1043                         race_laptime = 0;
1044                         race_checkpointtime = 0;
1045                         break;
1046
1047                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1048                         race_laptime = ReadCoord();
1049                         race_checkpointtime = -99999;
1050                         // fall through
1051                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1052                         race_nextcheckpoint = ReadByte();
1053
1054                         race_nextbesttime = ReadInt24_t();
1055                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1056                                 race_mybesttime = ReadInt24_t();
1057                         string newname = ReadString();
1058                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1059                         {
1060                                 race_nextbesttime = race_mybesttime;
1061                                 race_mybesttime = 0;
1062                                 strcpy(race_nextbestname, "");
1063                         }
1064                         else
1065                                 strcpy(race_nextbestname, newname);
1066                         break;
1067
1068                 case RACE_NET_CHECKPOINT_HIT_RACE:
1069                         race_mycheckpoint = ReadByte();
1070                         race_mycheckpointtime = time;
1071                         race_mycheckpointdelta = ReadInt24_t();
1072                         race_mycheckpointlapsdelta = ReadByte();
1073                         if(race_mycheckpointlapsdelta >= 128)
1074                                 race_mycheckpointlapsdelta -= 256;
1075                         int who = ReadByte();
1076                         if(who)
1077                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1078                         else
1079                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1080                         break;
1081
1082                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1083                         race_othercheckpoint = ReadByte();
1084                         race_othercheckpointtime = time;
1085                         race_othercheckpointdelta = ReadInt24_t();
1086                         race_othercheckpointlapsdelta = ReadByte();
1087                         if(race_othercheckpointlapsdelta >= 128)
1088                                 race_othercheckpointlapsdelta -= 256;
1089                         int what = ReadByte();
1090                         if(what)
1091                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1092                         else
1093                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1094                         break;
1095
1096                 case RACE_NET_PENALTY_RACE:
1097                 case RACE_NET_PENALTY_QUALIFYING:
1098                         race_penaltyeventtime = time;
1099                         race_penaltytime = ReadShort();
1100                         string reason = ReadString();
1101                         if (reason == "missing a checkpoint")
1102                                 reason = _("missing a checkpoint");
1103                         strcpy(race_penaltyreason, reason);
1104                         if (b == RACE_NET_PENALTY_QUALIFYING)
1105                                 race_penaltyaccumulator += race_penaltytime;
1106                         break;
1107
1108                 case RACE_NET_SERVER_RECORD:
1109                         race_server_record = ReadInt24_t();
1110                         break;
1111                 case RACE_NET_SPEED_AWARD:
1112                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1113                         strcpy(race_speedaward_holder, ReadString());
1114                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1115                         break;
1116                 case RACE_NET_SPEED_AWARD_BEST:
1117                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1118                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1119                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1120                         break;
1121                 case RACE_NET_RANKINGS_CNT:
1122                         RANKINGS_DISPLAY_CNT = ReadByte();
1123                         break;
1124                 case RACE_NET_SERVER_RANKINGS:
1125                         float prevpos, del;
1126                         int pos = ReadShort();
1127                         prevpos = ReadShort();
1128                         del = ReadShort();
1129
1130                         // move other rankings out of the way
1131                         int i;
1132                         if (prevpos) {
1133                                 int m = min(prevpos, RANKINGS_DISPLAY_CNT);
1134                                 for (i=m-1; i>pos-1; --i) {
1135                                         grecordtime[i] = grecordtime[i-1];
1136                                         strcpy(grecordholder[i], grecordholder[i-1]);
1137                                 }
1138                         } else if (del) { // a record has been deleted by the admin
1139                                 for (i=pos-1; i<= RANKINGS_DISPLAY_CNT-1; ++i) {
1140                                         if (i == RANKINGS_DISPLAY_CNT-1) { // clear out last record
1141                                                 grecordtime[i] = 0;
1142                                                 strfree(grecordholder[i]);
1143                                         }
1144                                         else {
1145                                                 grecordtime[i] = grecordtime[i+1];
1146                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1147                                         }
1148                                 }
1149                         } else { // player has no ranked record yet
1150                                 for (i=RANKINGS_DISPLAY_CNT-1;i>pos-1;--i) {
1151                                         grecordtime[i] = grecordtime[i-1];
1152                                         strcpy(grecordholder[i], grecordholder[i-1]);
1153                                 }
1154                         }
1155
1156                         if (grecordtime[RANKINGS_DISPLAY_CNT]) {
1157                                 // kick off the player who fell from the last displayed position
1158                                 grecordtime[RANKINGS_DISPLAY_CNT] = 0;
1159                                 strfree(grecordholder[RANKINGS_DISPLAY_CNT]);
1160                         }
1161
1162                         // store new ranking
1163                         strcpy(grecordholder[pos-1], ReadString());
1164                         grecordtime[pos-1] = ReadInt24_t();
1165                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1166                                 race_myrank = pos;
1167                         break;
1168                 case RACE_NET_SERVER_STATUS:
1169                         race_status = ReadShort();
1170                         strcpy(race_status_name, ReadString());
1171         }
1172         return true;
1173 }
1174
1175 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1176 {
1177         teamnagger = 1;
1178         return true;
1179 }
1180
1181 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1182 {
1183         int i = ReadByte();
1184         int pi = ReadShort();
1185         int pl = ReadByte();
1186         int ml = ReadByte();
1187         return = true;
1188         entity e = playerslots[i];
1189         if (!e) return;
1190         e.ping = pi;
1191         e.ping_packetloss = pl / 255.0;
1192         e.ping_movementloss = ml / 255.0;
1193 }
1194
1195 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1196 {
1197         int weapon_id = ReadByte();
1198         complain_weapon = REGISTRY_GET(Weapons, weapon_id);
1199         complain_weapon_type = ReadByte();
1200         return = true;
1201
1202         complain_weapon_time = time;
1203         weapontime = time; // ping the weapon panel
1204
1205         switch(complain_weapon_type)
1206         {
1207                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, weapon_id); break;
1208                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, weapon_id); break;
1209                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, weapon_id); break;
1210         }
1211 }
1212
1213 string _getcommandkey(string cmd_name, string command, bool forcename)
1214 {
1215         string keys;
1216         float n, j, k, l = 0;
1217
1218         if (!autocvar_hud_showbinds)
1219                 return cmd_name;
1220
1221         keys = db_get(binddb, command);
1222         if (keys == "")
1223         {
1224                 bool joy_active = cvar("joy_active");
1225                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1226                 for(j = 0; j < n; ++j)
1227                 {
1228                         k = stof(argv(j));
1229                         if(k != -1)
1230                         {
1231                                 string key = keynumtostring(k);
1232                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1233                                         continue;
1234
1235                                 key = translate_key(key);
1236
1237                                 if (keys == "")
1238                                         keys = key;
1239                                 else
1240                                         keys = strcat(keys, ", ", key);
1241
1242                                 ++l;
1243                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1244                                         break;
1245                         }
1246
1247                 }
1248                 if (keys == "")
1249                         keys = "NO_KEY";
1250                 db_put(binddb, command, keys);
1251         }
1252
1253         if (keys == "NO_KEY") {
1254                 if (autocvar_hud_showbinds > 1)
1255                         return sprintf(_("%s (not bound)"), cmd_name);
1256                 else
1257                         return cmd_name;
1258         }
1259         else if (autocvar_hud_showbinds > 1 || forcename)
1260                 return sprintf("%s (%s)", cmd_name, keys);
1261         else
1262                 return keys;
1263 }