qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "defs.qh"
   6 #include "hud/_mod.qh"
   7 #include "hud/panel/scoreboard.qh"
   8
   9 #include <common/mapinfo.qh>
  10
  11
  12 int mv_num_maps;
  13
  14 string mv_maps[MAPVOTE_COUNT];
  15 string mv_pics[MAPVOTE_COUNT];
  16 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  17 string mv_desc[MAPVOTE_COUNT];
  18 float mv_preview[MAPVOTE_COUNT];
  19 float mv_votes[MAPVOTE_COUNT];
  20 float mv_flags[MAPVOTE_COUNT];
  21 float mv_flags_start[MAPVOTE_COUNT];
  22 entity mv_pk3list;
  23 float mv_abstain;
  24 float mv_ownvote;
  25 float mv_detail;
  26 float mv_timeout;
  27 float mv_top2_time;
  28 float mv_top2_alpha;
  29
  30 int mv_selection;
  31 int mv_columns;
  32 int mv_mouse_selection;
  33 int mv_selection_keyboard;
  34
  35 float gametypevote;
  36 string mapvote_chosenmap;
  37 vector gtv_text_size;
  38 vector gtv_text_size_small;
  39
  40 const int NUM_SSDIRS = 4;
  41 string ssdirs[NUM_SSDIRS];
  42 int n_ssdirs;
  43
  44 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  45 {
  46         TC(int, id);
  47         string pre, post;
  48         pre = sprintf("%d. ", id+1);
  49         if(mv_detail)
  50         {
  51                 if(_count == 1)
  52                         post = _(" (1 vote)");
  53                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  54                         post = sprintf(_(" (%d votes)"), _count);
  55                 else
  56                         post = "";
  57         }
  58         else
  59                 post = "";
  60         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  61         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  62         return strcat(pre, map, post);
  63 }
  64
  65 vector MapVote_RGB(int id)
  66 {
  67         TC(int, id);
  68         if(!(mv_flags[id] & GTV_AVAILABLE))
  69                 return '1 1 1';
  70         if(id == mv_ownvote)
  71                 return '0 1 0';
  72         else if (id == mv_selection)
  73                 return '1 1 0';
  74         else
  75                 return '1 1 1';
  76 }
  77
  78 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  79 {
  80         TC(int, id);
  81         // Find the correct alpha
  82         float alpha;
  83         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  84                 alpha = 0.2; // The gametype isn't supported by the map
  85         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  86                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  87         else
  88                 alpha = 1; // Normal, full alpha
  89         alpha *= panel_fg_alpha;
  90
  91         // Bounding box details
  92         float rect_margin = hud_fontsize.y / 2;
  93
  94         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  95         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  96         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  97         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  98
  99         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 100         vector rect_size = '1 1 0';
 101         rect_size.x = tsize + rect_margin;
 102         rect_size.y = maxh + rect_margin;
 103
 104         // Highlight selected item
 105         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 106         {
 107                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 108         }
 109
 110         // Highlight current vote
 111         vector rgb = MapVote_RGB(id);
 112         if(id == mv_ownvote)
 113         {
 114                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 115                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 116         }
 117
 118         vector offset = pos;
 119
 120         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 121         pos.y += title_gap;
 122         maxh -= title_gap;
 123
 124         // Evaluate the image size
 125         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 126         if ( maxh < image_size.y )
 127                 image_size = '1 1 0' * maxh;
 128         image_size *= 0.8;
 129         float desc_padding = gtv_text_size.x * 0.6;
 130         pos.x += image_size.x + desc_padding;
 131         tsize -= image_size.x + desc_padding;
 132
 133         // Split the description into lines
 134         entity title;
 135         title = spawn();
 136         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 137
 138         string thelabel = mv_desc[id], ts;
 139         entity last = title;
 140         entity next = NULL;
 141         float nlines = 0;
 142         if( thelabel != "")
 143         {
 144                 float i,n = tokenizebyseparator(thelabel, "\n");
 145                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 146                 {
 147                         getWrappedLine_remaining = argv(i);
 148                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 149                         {
 150                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 151                                 if (ts != "")
 152                                 {
 153                                         next = spawn();
 154                                         next.message = ts;
 155                                         next.origin = pos-offset;
 156                                         last.chain = next;
 157                                         last = next;
 158                                         pos.y += gtv_text_size_small.y;
 159                                         nlines++;
 160                                 }
 161                         }
 162                 }
 163         }
 164
 165         // Center the contents in the bounding box
 166         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 167         if ( maxh > 0 )
 168                 offset.y += maxh/2;
 169
 170         // Draw the title
 171         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 172
 173         // Draw the icon
 174         if(pic != "")
 175                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 176
 177         // Draw the description
 178         for ( last = title.chain; last ; )
 179         {
 180                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 181                 next = last;
 182                 last = last.chain;
 183                 delete(next);
 184         }
 185
 186         // Cleanup
 187         delete(title);
 188 }
 189
 190 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 191 {
 192         TC(int, id);
 193         vector img_size = '0 0 0';
 194         string label;
 195         float text_size;
 196
 197         float rect_margin = hud_fontsize.y / 2;
 198
 199         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 200         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 201         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 202         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 203
 204         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 205         vector rect_size = '1 1 0';
 206         rect_size.x = tsize + rect_margin;
 207         rect_size.y = isize + rect_margin;
 208
 209         float img_ar = 4/3;
 210         img_size.x = min(tsize, isize * img_ar);
 211         img_size.y = img_size.x / img_ar;
 212         img_size.y -= hud_fontsize.y;
 213         img_size.x = img_size.y * img_ar;
 214
 215         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 216
 217         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 218
 219         text_size = stringwidth(label, false, hud_fontsize);
 220
 221         float save_rect_sizex = rect_size.x;
 222         rect_size.x = max(img_size.x, text_size) + rect_margin;
 223         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 224
 225         vector text_pos = '0 0 0';
 226         text_pos.x = pos.x + (tsize - text_size) / 2;
 227         text_pos.y = pos.y + img_size.y;
 228
 229         pos.x += (tsize - img_size.x) / 2;
 230
 231         float theAlpha;
 232         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 233                 theAlpha = mv_top2_alpha;
 234         else
 235                 theAlpha = 1;
 236         theAlpha *= panel_fg_alpha;
 237
 238         // Highlight selected item
 239         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 240                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 241
 242         // Highlight current vote
 243         vector rgb = MapVote_RGB(id);
 244         if(id == mv_ownvote)
 245         {
 246                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 247                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 248         }
 249
 250         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 251
 252         if(pic == "")
 253         {
 254                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 255         }
 256         else
 257         {
 258                 if(drawgetimagesize(pic) == '0 0 0')
 259                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 260                 else
 261                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 262         }
 263 }
 264
 265 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 266 {
 267         TC(int, id);
 268         vector rgb;
 269         float text_size;
 270         string label;
 271
 272         rgb = MapVote_RGB(id);
 273
 274         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 275
 276         text_size = stringwidth(label, false, hud_fontsize);
 277
 278         pos.x -= text_size*0.5;
 279         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 280 }
 281
 282 vector MapVote_GridVec(vector gridspec, int i, int m)
 283 {
 284         TC(int, i); TC(int, m);
 285         int r = i % m;
 286         return
 287                 '1 0 0' * (gridspec.x * r)
 288                 +
 289                 '0 1 0' * (gridspec.y * (i - r) / m);
 290 }
 291
 292 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 293 {
 294
 295         float c, r;
 296
 297         mv_mouse_selection = -1;
 298
 299         for (r = 0; r < rows; ++r)
 300                 for (c = 0; c < columns; ++c)
 301                 {
 302                         if (mousepos.x >= topleft.x + cellsize.x *  c &&
 303                                 mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 304                                 mousepos.y >= topleft.y + cellsize.y *  r &&
 305                                 mousepos.y <= topleft.y + cellsize.y * (r + 1))
 306                         {
 307                                 mv_mouse_selection = r * columns + c;
 308                                 break;
 309                         }
 310                 }
 311
 312         if (mv_mouse_selection >= mv_num_maps)
 313                 mv_mouse_selection = -1;
 314
 315         if (mv_abstain && mv_mouse_selection < 0)
 316                 mv_mouse_selection = mv_num_maps;
 317
 318         if ( mv_selection_keyboard )
 319                 return mv_selection;
 320
 321         return mv_mouse_selection;
 322 }
 323
 324 vector prev_mousepos;
 325 void MapVote_Draw()
 326 {
 327         string map;
 328         int i;
 329         float tmp;
 330         vector pos;
 331         float center;
 332         float rows;
 333         vector dist = '0 0 0';
 334
 335         //if(intermission != 2) return;
 336         if(!mv_active)
 337                 return;
 338
 339         HUD_Panel_LoadCvars();
 340
 341         if (!autocvar_hud_cursormode)
 342         {
 343                 if (mousepos.x != prev_mousepos.x || mousepos.y != prev_mousepos.y)
 344                 {
 345                         mv_selection_keyboard = 0;
 346                         prev_mousepos = mousepos;
 347                 }
 348         }
 349
 350         center = (vid_conwidth - 1)/2;
 351         xmin = vid_conwidth * 0.08;
 352         xmax = vid_conwidth - xmin;
 353         ymin = 20;
 354         ymax = vid_conheight - ymin;
 355
 356         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 357                 ymin += chat_sizey;
 358         else
 359                 ymax -= chat_sizey;
 360
 361         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 362
 363         pos.y = ymin;
 364         pos.z = 0;
 365
 366         HUD_Scale_Disable();
 367         draw_beginBoldFont();
 368
 369         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 370         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 371         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 372         pos.y += hud_fontsize.y * 2;
 373
 374         if( mapvote_chosenmap != "" )
 375         {
 376                 pos.y += hud_fontsize.y * 0.25;
 377                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 378                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 379                 pos.y += hud_fontsize.y * 1.5;
 380         }
 381         pos.y += hud_fontsize.y * 0.5;
 382
 383         draw_endBoldFont();
 384
 385         i = ceil(max(0, mv_timeout - time));
 386         map = sprintf(_("%d seconds left"), i);
 387         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 388         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 389         pos.y += hud_fontsize.y * 1.5;
 390         pos.y += hud_fontsize.y * 0.5;
 391
 392         // base for multi-column stuff...
 393         pos.y += hud_fontsize.y;
 394         pos.x = xmin;
 395         ymin = pos.y;
 396         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 397         if(mv_abstain)
 398         {
 399                 mv_num_maps -= 1;
 400                 ymax -= abstain_spacing;
 401         }
 402
 403         // higher than the image itself ratio for mapvote items to reserve space for long map names
 404         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 405         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, vec2(xmax - xmin, ymax - ymin), item_aspect);
 406         mv_columns = table_size.x;
 407         rows = table_size.y;
 408
 409         dist.x = (xmax - xmin) / mv_columns;
 410         dist.y = (ymax - pos.y) / rows;
 411
 412         // reduce size of too wide items
 413         tmp = vid_conwidth / 3; // max width
 414         if(dist.x > tmp)
 415         {
 416                 dist.x = tmp;
 417                 dist.y = min(dist.y, dist.x / item_aspect);
 418         }
 419         tmp = vid_conheight / 3; // max height
 420         if(dist.y > tmp)
 421         {
 422                 dist.y = tmp;
 423                 dist.x = min(dist.x, dist.y * item_aspect);
 424         }
 425
 426         // reduce size to fix aspect ratio
 427         if(dist.x / dist.y > item_aspect)
 428                 dist.x = dist.y * item_aspect;
 429         else
 430                 dist.y = dist.x / item_aspect;
 431
 432         // adjust table pos and size according to the new size
 433         float offset;
 434         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 435         xmin = pos.x += offset;
 436         xmax -= offset;
 437         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 438         ymax -= 2 * offset;
 439
 440         // override panel_pos and panel_size
 441         panel_pos.x = pos.x;
 442         panel_pos.y = pos.y;
 443         panel_size.x = xmax - xmin;
 444         panel_size.y = ymax - ymin;
 445         HUD_Panel_DrawBg();
 446
 447         if(panel_bg_padding)
 448         {
 449                 // FIXME item AR gets slightly changed here...
 450                 // it's rather hard to avoid it at this point
 451                 dist.x -= 2 * panel_bg_padding / mv_columns;
 452                 dist.y -= 2 * panel_bg_padding / rows;
 453                 xmin = pos.x += panel_bg_padding;
 454                 ymin = pos.y += panel_bg_padding;
 455                 xmax -= 2 * panel_bg_padding;
 456                 ymax -= 2 * panel_bg_padding;
 457         }
 458
 459         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 460
 461         if (mv_top2_time)
 462                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 463
 464         void (vector, float, float, string, string, float, float) DrawItem;
 465
 466         if(gametypevote)
 467                 DrawItem = GameTypeVote_DrawGameTypeItem;
 468         else
 469                 DrawItem = MapVote_DrawMapItem;
 470
 471         for(i = 0; i < mv_num_maps; ++i)
 472         {
 473                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 474                 map = mv_maps[i];
 475                 if(mv_preview[i])
 476                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 477                 else
 478                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 479         }
 480
 481         if(mv_abstain)
 482                 ++mv_num_maps;
 483
 484         if(mv_abstain && i < mv_num_maps) {
 485                 tmp = mv_votes[i];
 486                 pos.y = ymax + abstain_spacing;
 487                 pos.x = (xmax+xmin)*0.5;
 488                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 489         }
 490 }
 491
 492 void Cmd_MapVote_MapDownload(int argc)
 493 {
 494         TC(int, argc);
 495         entity pak;
 496
 497         if(argc != 2 || !mv_pk3list)
 498         {
 499                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!"));
 500                 return;
 501         }
 502
 503         int id = stof(argv(1));
 504         for(pak = mv_pk3list; pak; pak = pak.chain)
 505                 if(pak.sv_entnum == id)
 506                         break;
 507
 508         if(!pak || pak.sv_entnum != id) {
 509                 LOG_INFO(_("^1Error:^7 Couldn't find pak index."));
 510                 return;
 511         }
 512
 513         if(PreviewExists(pak.message))
 514         {
 515                 mv_preview[id] = true;
 516                 return;
 517         } else {
 518                 LOG_INFO(_("Requesting preview..."));
 519                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 520         }
 521 }
 522
 523 void MapVote_CheckPK3(string pic, string pk3, int id)
 524 {
 525         TC(int, id);
 526         entity pak;
 527         pak = spawn();
 528         pak.netname = pk3;
 529         pak.message = pic;
 530         pak.sv_entnum = id;
 531
 532         pak.chain = mv_pk3list;
 533         mv_pk3list = pak;
 534
 535         if(pk3 != "")
 536         {
 537                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 538         }
 539         else
 540         {
 541                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 542         }
 543 }
 544
 545 void MapVote_CheckPic(string pic, string pk3, int id)
 546 {
 547         TC(int, id);
 548         // never try to retrieve a pic for the "don't care" 'map'
 549         if(mv_abstain && id == mv_num_maps - 1)
 550                 return;
 551
 552         if(PreviewExists(pic))
 553         {
 554                 mv_preview[id] = true;
 555                 return;
 556         }
 557         MapVote_CheckPK3(pic, pk3, id);
 558 }
 559
 560 void MapVote_ReadMask()
 561 {
 562         int i;
 563         if ( mv_num_maps < 24 )
 564         {
 565                 int mask;
 566                 if(mv_num_maps < 8)
 567                         mask = ReadByte();
 568                 else if(mv_num_maps < 16)
 569                         mask = ReadShort();
 570                 else
 571                         mask = ReadLong();
 572
 573                 for(i = 0; i < mv_num_maps; ++i)
 574                 {
 575                         if (mask & BIT(i))
 576                                 mv_flags[i] |= GTV_AVAILABLE;
 577                         else
 578                                 mv_flags[i] &= ~GTV_AVAILABLE;
 579                 }
 580         }
 581         else
 582         {
 583                 for(i = 0; i < mv_num_maps; ++i )
 584                         mv_flags[i] = ReadByte();
 585         }
 586 }
 587
 588 void MapVote_ReadOption(int i)
 589 {
 590         TC(int, i);
 591         string map = strzone(ReadString());
 592         string pk3 = strzone(ReadString());
 593         int j = bound(0, ReadByte(), n_ssdirs - 1);
 594
 595         mv_maps[i] = map;
 596         mv_pk3[i] = pk3;
 597         mv_flags[i] = GTV_AVAILABLE;
 598
 599         string pic = strzone(strcat(ssdirs[j], "/", map));
 600         mv_pics[i] = pic;
 601         mv_preview[i] = false;
 602         MapVote_CheckPic(pic, pk3, i);
 603 }
 604
 605 void GameTypeVote_ReadOption(int i)
 606 {
 607         TC(int, i);
 608         string gt = strzone(ReadString());
 609
 610         mv_maps[i] = gt;
 611         mv_flags[i] = ReadByte();
 612
 613         string basetype = "";
 614
 615         if ( mv_flags[i] & GTV_CUSTOM )
 616         {
 617                 string name = ReadString();
 618                 if ( strlen(name) < 1 )
 619                         name = gt;
 620                 mv_pk3[i] = strzone(name);
 621                 mv_desc[i] = strzone(ReadString());
 622                 basetype = strzone(ReadString());
 623         }
 624         else
 625         {
 626                 Gametype type = MapInfo_Type_FromString(gt);
 627                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 628                 mv_desc[i] = MapInfo_Type_Description(type);
 629         }
 630
 631         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 632         if(precache_pic(mv_picpath) == "")
 633         {
 634                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 635                 if(precache_pic(mv_picpath) == "")
 636                 {
 637                         mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, basetype);
 638                         if(precache_pic(mv_picpath) == "")
 639                         {
 640                                 mv_picpath = strcat("gfx/menu/default/gametype_", basetype);
 641                         }
 642                 }
 643         }
 644         string pic = strzone(mv_picpath);
 645         mv_pics[i] = pic;
 646         mv_preview[i] = PreviewExists(pic);
 647 }
 648
 649 void MapVote_Init()
 650 {
 651         mv_active = 1;
 652         if(!autocvar_hud_cursormode) mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 653         mv_selection = -1;
 654         mv_selection_keyboard = 0;
 655
 656         string s;
 657         for(n_ssdirs = 0; ; ++n_ssdirs)
 658         {
 659                 s = ReadString();
 660                 if(s == "")
 661                         break;
 662                 if(n_ssdirs < NUM_SSDIRS)
 663                         ssdirs[n_ssdirs] = s;
 664         }
 665         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 666
 667         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 668         mv_abstain = ReadByte();
 669         if(mv_abstain)
 670                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 671         mv_detail = ReadByte();
 672
 673         mv_ownvote = -1;
 674         mv_timeout = ReadCoord();
 675
 676         gametypevote = ReadByte();
 677
 678         if(gametypevote)
 679         {
 680                 mapvote_chosenmap = strzone(ReadString());
 681                 if ( gametypevote == 2 )
 682                         gametypevote = 0;
 683
 684                 gtv_text_size = hud_fontsize*1.4;
 685                 gtv_text_size_small = hud_fontsize*1.1;
 686         }
 687
 688         MapVote_ReadMask();
 689         int i;
 690         for(i = 0; i < mv_num_maps; ++i )
 691                 mv_flags_start[i] = mv_flags[i];
 692
 693         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 694         mv_pk3list = NULL; // I'm still paranoid!
 695
 696         for(i = 0; i < mv_num_maps; ++i)
 697         {
 698                 mv_votes[i] = 0;
 699
 700                 if ( gametypevote )
 701                         GameTypeVote_ReadOption(i);
 702                 else
 703                         MapVote_ReadOption(i);
 704         }
 705
 706         for(i = 0; i < n_ssdirs; ++i)
 707                 ssdirs[n_ssdirs] = string_null;
 708         n_ssdirs = 0;
 709 }
 710
 711 void MapVote_SendChoice(int index)
 712 {
 713         TC(int, index);
 714         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 715 }
 716
 717 int MapVote_MoveLeft(int pos)
 718 {
 719         TC(int, pos);
 720         int imp;
 721         if ( pos < 0 )
 722                 imp = mv_num_maps - 1;
 723         else
 724                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 725         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 726                 imp = MapVote_MoveLeft(imp);
 727         return imp;
 728 }
 729 int MapVote_MoveRight(int pos)
 730 {
 731         TC(int, pos);
 732         int imp;
 733         if ( pos < 0 )
 734                 imp = 0;
 735         else
 736                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 737         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 738                 imp = MapVote_MoveRight(imp);
 739         return imp;
 740 }
 741 int MapVote_MoveUp(int pos)
 742 {
 743         TC(int, pos);
 744         int imp;
 745         if ( pos < 0 )
 746                 imp = mv_num_maps - 1;
 747         else
 748         {
 749                 imp = pos - mv_columns;
 750                 if ( imp < 0 )
 751                 {
 752                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 753                         if ( imp >= mv_num_maps )
 754                                 imp -= mv_columns;
 755                 }
 756         }
 757         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 758                 imp = MapVote_MoveUp(imp);
 759         return imp;
 760 }
 761 int MapVote_MoveDown(int pos)
 762 {
 763         TC(int, pos);
 764         int imp;
 765         if ( pos < 0 )
 766                 imp = 0;
 767         else
 768         {
 769                 imp = pos + mv_columns;
 770                 if ( imp >= mv_num_maps )
 771                         imp = imp % mv_columns;
 772         }
 773         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 774                 imp = MapVote_MoveDown(imp);
 775         return imp;
 776 }
 777
 778 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 779 {
 780         TC(int, bInputType);
 781         float imp;
 782
 783         if (!mv_active)
 784                 return false;
 785
 786         if(bInputType == 3)
 787         {
 788                 mousepos.x = nPrimary;
 789                 mousepos.y = nSecondary;
 790                 mv_selection_keyboard = 0;
 791                 return true;
 792         }
 793
 794         if (bInputType != 0)
 795                 return false;
 796
 797         if ('0' <= nPrimary && nPrimary <= '9')
 798         {
 799                 imp = nPrimary - '0';
 800                 if (imp == 0) imp = 10;
 801                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 802                 return true;
 803         }
 804         switch(nPrimary)
 805         {
 806                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 807                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 808                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 809                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 810                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 811                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 812                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 813                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 814                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 815                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 816
 817                 case K_RIGHTARROW:
 818                         mv_selection_keyboard = 1;
 819                         mv_selection = MapVote_MoveRight(mv_selection);
 820                         return true;
 821                 case K_LEFTARROW:
 822                         mv_selection_keyboard = 1;
 823                         mv_selection = MapVote_MoveLeft(mv_selection);
 824                         return true;
 825                 case K_DOWNARROW:
 826                         mv_selection_keyboard = 1;
 827                         mv_selection = MapVote_MoveDown(mv_selection);
 828                         return true;
 829                 case K_UPARROW:
 830                         mv_selection_keyboard = 1;
 831                         mv_selection = MapVote_MoveUp(mv_selection);
 832                         return true;
 833                 case K_KP_ENTER:
 834                 case K_ENTER:
 835                 case K_SPACE:
 836                         if ( mv_selection_keyboard )
 837                                 MapVote_SendChoice(mv_selection);
 838                         return true;
 839         }
 840
 841         if (nPrimary == K_MOUSE1)
 842         {
 843                 mv_selection_keyboard = 0;
 844                 mv_selection = mv_mouse_selection;
 845                 if (mv_selection >= 0)
 846                 {
 847                         imp = min(mv_selection + 1, mv_num_maps);
 848                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 849                         return true;
 850                 }
 851         }
 852
 853         return false;
 854 }
 855
 856 void MapVote_UpdateMask()
 857 {
 858         MapVote_ReadMask();
 859         mv_top2_time = time;
 860 }
 861
 862 void MapVote_UpdateVotes()
 863 {
 864         int i;
 865         for(i = 0; i < mv_num_maps; ++i)
 866         {
 867                 if(mv_flags[i] & GTV_AVAILABLE)
 868                 {
 869                         if(mv_detail)
 870                                 mv_votes[i] = ReadByte();
 871                         else
 872                                 mv_votes[i] = 0;
 873                 }
 874                 else
 875                         mv_votes[i] = -1;
 876         }
 877
 878         mv_ownvote = ReadByte()-1;
 879 }
 880
 881 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 882 {
 883         make_pure(this);
 884         int sf = ReadByte();
 885         return = true;
 886
 887         if(sf & 1)
 888                 MapVote_Init();
 889
 890         if(sf & 2)
 891                 MapVote_UpdateMask();
 892
 893         if(sf & 4)
 894                 MapVote_UpdateVotes();
 895 }
 896
 897 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 898 {
 899         Net_MapVote_Picture();
 900         return true;
 901 }
 902
 903 void Net_MapVote_Picture()
 904 {
 905         int type = ReadByte();
 906         mv_preview[type] = true;
 907         mv_pics[type] = strzone(ReadPicture());
 908 }