qcsrc/client/mapvoting.qc

   1 #include "mapvoting.qh"
   2
   3 #include "hud/_mod.qh"
   4 #include "hud/panel/scoreboard.qh"
   5
   6 #include <common/mapinfo.qh>
   7
   8
   9 int mv_num_maps;
  10
  11 string mv_maps[MAPVOTE_COUNT];
  12 string mv_pics[MAPVOTE_COUNT];
  13 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
  14 string mv_desc[MAPVOTE_COUNT];
  15 float mv_preview[MAPVOTE_COUNT];
  16 float mv_votes[MAPVOTE_COUNT];
  17 float mv_flags[MAPVOTE_COUNT];
  18 float mv_flags_start[MAPVOTE_COUNT];
  19 entity mv_pk3list;
  20 float mv_abstain;
  21 float mv_ownvote;
  22 float mv_detail;
  23 float mv_timeout;
  24 float mv_top2_time;
  25 float mv_top2_alpha;
  26
  27 vector mv_mousepos;
  28 int mv_selection;
  29 int mv_columns;
  30 int mv_mouse_selection;
  31 int mv_selection_keyboard;
  32
  33 float gametypevote;
  34 string mapvote_chosenmap;
  35 vector gtv_text_size;
  36 vector gtv_text_size_small;
  37
  38 const int NUM_SSDIRS = 4;
  39 string ssdirs[NUM_SSDIRS];
  40 int n_ssdirs;
  41
  42 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
  43 {
  44     TC(int, id);
  45         string pre, post;
  46         pre = sprintf("%d. ", id+1);
  47         if(mv_detail)
  48         {
  49                 if(_count == 1)
  50                         post = _(" (1 vote)");
  51                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
  52                         post = sprintf(_(" (%d votes)"), _count);
  53                 else
  54                         post = "";
  55         }
  56         else
  57                 post = "";
  58         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
  59         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
  60         return strcat(pre, map, post);
  61 }
  62
  63 vector MapVote_RGB(int id)
  64 {
  65     TC(int, id);
  66         if(!(mv_flags[id] & GTV_AVAILABLE))
  67                 return '1 1 1';
  68         if(id == mv_ownvote)
  69                 return '0 1 0';
  70         else if (id == mv_selection)
  71                 return '1 1 0';
  72         else
  73                 return '1 1 1';
  74 }
  75
  76 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
  77 {
  78     TC(int, id);
  79         // Find the correct alpha
  80         float alpha;
  81         if(!(mv_flags_start[id] & GTV_AVAILABLE))
  82                 alpha = 0.2; // The gametype isn't supported by the map
  83         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
  84                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
  85         else
  86                 alpha = 1; // Normal, full alpha
  87         alpha *= panel_fg_alpha;
  88
  89         // Bounding box details
  90         float rect_margin = hud_fontsize.y / 2;
  91
  92         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  93         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
  94         maxh -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  95         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
  96
  97         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
  98         vector rect_size = '1 1 0';
  99         rect_size.x = tsize + rect_margin;
 100         rect_size.y = maxh + rect_margin;
 101
 102         // Highlight selected item
 103         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 104         {
 105                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 106         }
 107
 108         // Highlight current vote
 109         vector rgb = MapVote_RGB(id);
 110         if(id == mv_ownvote)
 111         {
 112                 drawfill(rect_pos, rect_size, rgb, 0.1 * alpha, DRAWFLAG_NORMAL);
 113                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
 114         }
 115
 116         vector offset = pos;
 117
 118         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
 119         pos.y += title_gap;
 120         maxh -= title_gap;
 121
 122         // Evaluate the image size
 123         vector image_size = '1 1 0' * gtv_text_size.x * 3;
 124         if ( maxh < image_size.y )
 125                 image_size = '1 1 0' * maxh;
 126         image_size *= 0.8;
 127         float desc_padding = gtv_text_size.x * 0.6;
 128         pos.x += image_size.x + desc_padding;
 129         tsize -= image_size.x + desc_padding;
 130
 131         // Split the description into lines
 132         entity title;
 133         title = spawn();
 134         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
 135
 136         string thelabel = mv_desc[id], ts;
 137         entity last = title;
 138         entity next = NULL;
 139         float nlines = 0;
 140         if( thelabel != "")
 141         {
 142                 float i,n = tokenizebyseparator(thelabel, "\n");
 143                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
 144                 {
 145                         getWrappedLine_remaining = argv(i);
 146                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
 147                         {
 148                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
 149                                 if (ts != "")
 150                                 {
 151                                         next = spawn();
 152                                         next.message = ts;
 153                                         next.origin = pos-offset;
 154                                         last.chain = next;
 155                                         last = next;
 156                                         pos.y += gtv_text_size_small.y;
 157                                         nlines++;
 158                                 }
 159                         }
 160                 }
 161         }
 162
 163         // Center the contents in the bounding box
 164         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
 165         if ( maxh > 0 )
 166                 offset.y += maxh/2;
 167
 168         // Draw the title
 169         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
 170
 171         // Draw the icon
 172         if(pic != "")
 173                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
 174
 175         // Draw the description
 176         for ( last = title.chain; last ; )
 177         {
 178                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
 179                 next = last;
 180                 last = last.chain;
 181                 delete(next);
 182         }
 183
 184         // Cleanup
 185         delete(title);
 186 }
 187
 188 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
 189 {
 190     TC(int, id);
 191         vector img_size = '0 0 0';
 192         string label;
 193         float text_size;
 194
 195         float rect_margin = hud_fontsize.y / 2;
 196
 197         pos.x += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 198         pos.y += rect_margin + autocvar_hud_panel_mapvote_highlight_border;
 199         isize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 200         tsize -= 2 * (rect_margin + autocvar_hud_panel_mapvote_highlight_border);
 201
 202         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
 203         vector rect_size = '1 1 0';
 204         rect_size.x = tsize + rect_margin;
 205         rect_size.y = isize + rect_margin;
 206
 207         float img_ar = 4/3;
 208         img_size.x = min(tsize, isize * img_ar);
 209         img_size.y = img_size.x / img_ar;
 210         img_size.y -= hud_fontsize.y;
 211         img_size.x = img_size.y * img_ar;
 212
 213         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
 214
 215         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
 216
 217         text_size = stringwidth(label, false, hud_fontsize);
 218
 219         float save_rect_sizex = rect_size.x;
 220         rect_size.x = max(img_size.x, text_size) + rect_margin;
 221         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
 222
 223         vector text_pos = '0 0 0';
 224         text_pos.x = pos.x + (tsize - text_size) / 2;
 225         text_pos.y = pos.y + img_size.y;
 226
 227         pos.x += (tsize - img_size.x) / 2;
 228
 229         float theAlpha;
 230         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
 231                 theAlpha = mv_top2_alpha;
 232         else
 233                 theAlpha = 1;
 234         theAlpha *= panel_fg_alpha;
 235
 236         // Highlight selected item
 237         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
 238                 drawfill(rect_pos, rect_size, '1 1 1', 0.1 * panel_fg_alpha, DRAWFLAG_NORMAL);
 239
 240         // Highlight current vote
 241         vector rgb = MapVote_RGB(id);
 242         if(id == mv_ownvote)
 243         {
 244                 drawfill(rect_pos, rect_size, rgb, 0.1 * theAlpha, DRAWFLAG_NORMAL);
 245                 drawborderlines(autocvar_hud_panel_mapvote_highlight_border, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
 246         }
 247
 248         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
 249
 250         if(pic == "")
 251         {
 252                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
 253         }
 254         else
 255         {
 256                 if(drawgetimagesize(pic) == '0 0 0')
 257                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 258                 else
 259                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
 260         }
 261 }
 262
 263 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
 264 {
 265     TC(int, id);
 266         vector rgb;
 267         float text_size;
 268         string label;
 269
 270         rgb = MapVote_RGB(id);
 271
 272         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
 273
 274         text_size = stringwidth(label, false, hud_fontsize);
 275
 276         pos.x -= text_size*0.5;
 277         drawstring(pos, label, hud_fontsize, rgb, panel_fg_alpha, DRAWFLAG_NORMAL);
 278 }
 279
 280 vector MapVote_GridVec(vector gridspec, int i, int m)
 281 {
 282     TC(int, i); TC(int, m);
 283         int r = i % m;
 284         return
 285                 '1 0 0' * (gridspec.x * r)
 286                 +
 287                 '0 1 0' * (gridspec.y * (i - r) / m);
 288 }
 289
 290 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
 291 {
 292
 293         float c, r;
 294
 295         mv_mouse_selection = -1;
 296
 297         for (r = 0; r < rows; ++r)
 298                 for (c = 0; c < columns; ++c)
 299                 {
 300                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
 301                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
 302                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
 303                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
 304                         {
 305                                 mv_mouse_selection = r * columns + c;
 306                                 break;
 307                         }
 308                 }
 309
 310         if (mv_mouse_selection >= mv_num_maps)
 311                 mv_mouse_selection = -1;
 312
 313         if (mv_abstain && mv_mouse_selection < 0)
 314                 mv_mouse_selection = mv_num_maps;
 315
 316         if ( mv_selection_keyboard )
 317                 return mv_selection;
 318
 319         return mv_mouse_selection;
 320 }
 321
 322 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
 323 void MapVote_Draw()
 324 {
 325         string map;
 326         int i;
 327         float tmp;
 328         vector pos;
 329         float center;
 330         float rows;
 331         vector dist = '0 0 0';
 332
 333         //if(intermission != 2) return;
 334         if(!mv_active)
 335                 return;
 336
 337         HUD_Panel_LoadCvars();
 338
 339         if (!autocvar_hud_cursormode)
 340         {
 341                 vector mpos = mv_mousepos + getmousepos();
 342                 mpos.x = bound(0, mpos.x, vid_conwidth);
 343                 mpos.y = bound(0, mpos.y, vid_conheight);
 344
 345                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
 346                         mv_selection_keyboard = 0;
 347                 mv_mousepos = mpos;
 348         }
 349
 350         center = (vid_conwidth - 1)/2;
 351         xmin = vid_conwidth * 0.08;
 352         xmax = vid_conwidth - xmin;
 353         ymin = 20;
 354         ymax = vid_conheight - ymin;
 355
 356         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
 357                 ymin += chat_sizey;
 358         else
 359                 ymax -= chat_sizey;
 360
 361         hud_fontsize = HUD_GetFontsize("hud_fontsize");
 362
 363         pos.y = ymin;
 364         pos.z = 0;
 365
 366         HUD_Scale_Disable();
 367         draw_beginBoldFont();
 368
 369         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
 370         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
 371         drawstring(pos, map, hud_fontsize * 2, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 372         pos.y += hud_fontsize.y * 2;
 373
 374         if( mapvote_chosenmap != "" )
 375         {
 376                 pos.y += hud_fontsize.y * 0.25;
 377                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
 378                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 379                 pos.y += hud_fontsize.y * 1.5;
 380         }
 381         pos.y += hud_fontsize.y * 0.5;
 382
 383         draw_endBoldFont();
 384
 385         i = ceil(max(0, mv_timeout - time));
 386         map = sprintf(_("%d seconds left"), i);
 387         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
 388         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', panel_fg_alpha, DRAWFLAG_NORMAL);
 389         pos.y += hud_fontsize.y * 1.5;
 390         pos.y += hud_fontsize.y * 0.5;
 391
 392         // base for multi-column stuff...
 393         pos.y += hud_fontsize.y;
 394         pos.x = xmin;
 395         ymin = pos.y;
 396         float abstain_spacing = panel_bg_border + hud_fontsize.y;
 397         if(mv_abstain)
 398         {
 399                 mv_num_maps -= 1;
 400                 ymax -= abstain_spacing;
 401         }
 402
 403         // higher than the image itself ratio for mapvote items to reserve space for long map names
 404         int item_aspect = (gametypevote) ? 3/1 : 5/3;
 405         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
 406         mv_columns = table_size.x;
 407         rows = table_size.y;
 408
 409         dist.x = (xmax - xmin) / mv_columns;
 410         dist.y = (ymax - pos.y) / rows;
 411
 412         // reduce size of too wide items
 413         tmp = vid_conwidth / 3; // max width
 414         if(dist.x > tmp)
 415         {
 416                 dist.x = tmp;
 417                 dist.y = min(dist.y, dist.x / item_aspect);
 418         }
 419         tmp = vid_conheight / 3; // max height
 420         if(dist.y > tmp)
 421         {
 422                 dist.y = tmp;
 423                 dist.x = min(dist.x, dist.y * item_aspect);
 424         }
 425
 426         // reduce size to fix aspect ratio
 427         if(dist.x / dist.y > item_aspect)
 428                 dist.x = dist.y * item_aspect;
 429         else
 430                 dist.y = dist.x / item_aspect;
 431
 432         // adjust table pos and size according to the new size
 433         float offset;
 434         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
 435         xmin = pos.x += offset;
 436         xmax -= offset;
 437         offset = ((ymax - pos.y) - dist.y * rows) / 2;
 438         ymax -= 2 * offset;
 439
 440         // override panel_pos and panel_size
 441         panel_pos.x = pos.x;
 442         panel_pos.y = pos.y;
 443         panel_size.x = xmax - xmin;
 444         panel_size.y = ymax - ymin;
 445         HUD_Panel_DrawBg();
 446
 447         if(panel_bg_padding)
 448         {
 449                 // FIXME item AR gets slightly changed here...
 450                 // it's rather hard to avoid it at this point
 451                 dist.x -= 2 * panel_bg_padding / mv_columns;
 452                 dist.y -= 2 * panel_bg_padding / rows;
 453                 xmin = pos.x += panel_bg_padding;
 454                 ymin = pos.y += panel_bg_padding;
 455                 xmax -= 2 * panel_bg_padding;
 456                 ymax -= 2 * panel_bg_padding;
 457         }
 458
 459         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
 460
 461         if (mv_top2_time)
 462                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
 463
 464         void (vector, float, float, string, string, float, float) DrawItem;
 465
 466         if(gametypevote)
 467                 DrawItem = GameTypeVote_DrawGameTypeItem;
 468         else
 469                 DrawItem = MapVote_DrawMapItem;
 470
 471         for(i = 0; i < mv_num_maps; ++i)
 472         {
 473                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
 474                 map = mv_maps[i];
 475                 if(mv_preview[i])
 476                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
 477                 else
 478                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
 479         }
 480
 481         if(mv_abstain)
 482                 ++mv_num_maps;
 483
 484         if(mv_abstain && i < mv_num_maps) {
 485                 tmp = mv_votes[i];
 486                 pos.y = ymax + abstain_spacing;
 487                 pos.x = (xmax+xmin)*0.5;
 488                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
 489         }
 490
 491         draw_cursor_normal(mv_mousepos, '1 1 1', panel_fg_alpha);
 492 }
 493
 494 void Cmd_MapVote_MapDownload(int argc)
 495 {
 496     TC(int, argc);
 497         entity pak;
 498
 499         if(argc != 2 || !mv_pk3list)
 500         {
 501                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
 502                 return;
 503         }
 504
 505         int id = stof(argv(1));
 506         for(pak = mv_pk3list; pak; pak = pak.chain)
 507                 if(pak.sv_entnum == id)
 508                         break;
 509
 510         if(!pak || pak.sv_entnum != id) {
 511                 LOG_INFO(_("^1Error:^7 Couldn't find pak index.\n"));
 512                 return;
 513         }
 514
 515         if(PreviewExists(pak.message))
 516         {
 517                 mv_preview[id] = true;
 518                 return;
 519         } else {
 520                 LOG_INFO(_("Requesting preview...\n"));
 521                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
 522         }
 523 }
 524
 525 void MapVote_CheckPK3(string pic, string pk3, int id)
 526 {
 527     TC(int, id);
 528         entity pak;
 529         pak = spawn();
 530         pak.netname = pk3;
 531         pak.message = pic;
 532         pak.sv_entnum = id;
 533
 534         pak.chain = mv_pk3list;
 535         mv_pk3list = pak;
 536
 537         if(pk3 != "")
 538         {
 539                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
 540         }
 541         else
 542         {
 543                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
 544         }
 545 }
 546
 547 void MapVote_CheckPic(string pic, string pk3, int id)
 548 {
 549     TC(int, id);
 550         // never try to retrieve a pic for the "don't care" 'map'
 551         if(mv_abstain && id == mv_num_maps - 1)
 552                 return;
 553
 554         if(PreviewExists(pic))
 555         {
 556                 mv_preview[id] = true;
 557                 return;
 558         }
 559         MapVote_CheckPK3(pic, pk3, id);
 560 }
 561
 562 void MapVote_ReadMask()
 563 {
 564         int i;
 565         if ( mv_num_maps < 24 )
 566         {
 567                 int mask, power;
 568                 if(mv_num_maps < 8)
 569                         mask = ReadByte();
 570                 else if(mv_num_maps < 16)
 571                         mask = ReadShort();
 572                 else
 573                         mask = ReadLong();
 574
 575                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
 576                 {
 577                         if ( mask & power )
 578                                 mv_flags[i] |= GTV_AVAILABLE;
 579                         else
 580                                 mv_flags[i] &= ~GTV_AVAILABLE;
 581                 }
 582         }
 583         else
 584         {
 585                 for(i = 0; i < mv_num_maps; ++i )
 586                         mv_flags[i] = ReadByte();
 587         }
 588 }
 589
 590 void MapVote_ReadOption(int i)
 591 {
 592     TC(int, i);
 593         string map = strzone(ReadString());
 594         string pk3 = strzone(ReadString());
 595         int j = bound(0, ReadByte(), n_ssdirs - 1);
 596
 597         mv_maps[i] = map;
 598         mv_pk3[i] = pk3;
 599         mv_flags[i] = GTV_AVAILABLE;
 600
 601         string pic = strzone(strcat(ssdirs[j], "/", map));
 602         mv_pics[i] = pic;
 603         mv_preview[i] = false;
 604         MapVote_CheckPic(pic, pk3, i);
 605 }
 606
 607 void GameTypeVote_ReadOption(int i)
 608 {
 609     TC(int, i);
 610         string gt = strzone(ReadString());
 611
 612         mv_maps[i] = gt;
 613         mv_flags[i] = ReadByte();
 614
 615         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
 616         if(precache_pic(mv_picpath) == "")
 617                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
 618         string pic = strzone(mv_picpath);
 619         mv_pics[i] = pic;
 620         mv_preview[i] = PreviewExists(pic);
 621
 622         if ( mv_flags[i] & GTV_CUSTOM )
 623         {
 624                 string name = ReadString();
 625                 if ( strlen(name) < 1 )
 626                         name = gt;
 627                 mv_pk3[i] = strzone(name);
 628                 mv_desc[i] = strzone(ReadString());
 629         }
 630         else
 631         {
 632                 Gametype type = MapInfo_Type_FromString(gt);
 633                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
 634                 mv_desc[i] = MapInfo_Type_Description(type);
 635         }
 636 }
 637
 638 void MapVote_Init()
 639 {
 640         mv_active = 1;
 641         if(autocvar_hud_cursormode) { setcursormode(1); }
 642         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
 643         mv_selection = -1;
 644         mv_selection_keyboard = 0;
 645
 646         string s;
 647         for(n_ssdirs = 0; ; ++n_ssdirs)
 648         {
 649                 s = ReadString();
 650                 if(s == "")
 651                         break;
 652                 if(n_ssdirs < NUM_SSDIRS)
 653                         ssdirs[n_ssdirs] = s;
 654         }
 655         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
 656
 657         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
 658         mv_abstain = ReadByte();
 659         if(mv_abstain)
 660                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
 661         mv_detail = ReadByte();
 662
 663         mv_ownvote = -1;
 664         mv_timeout = ReadCoord();
 665
 666         gametypevote = ReadByte();
 667
 668         if(gametypevote)
 669         {
 670                 mapvote_chosenmap = strzone(ReadString());
 671                 if ( gametypevote == 2 )
 672                         gametypevote = 0;
 673
 674                 gtv_text_size = hud_fontsize*1.4;
 675                 gtv_text_size_small = hud_fontsize*1.1;
 676         }
 677
 678         MapVote_ReadMask();
 679         int i;
 680         for(i = 0; i < mv_num_maps; ++i )
 681                 mv_flags_start[i] = mv_flags[i];
 682
 683         // Assume mv_pk3list is NULL, there should only be 1 mapvote per round
 684         mv_pk3list = NULL; // I'm still paranoid!
 685
 686         for(i = 0; i < mv_num_maps; ++i)
 687         {
 688                 mv_votes[i] = 0;
 689
 690                 if ( gametypevote )
 691                         GameTypeVote_ReadOption(i);
 692                 else
 693                         MapVote_ReadOption(i);
 694         }
 695
 696         for(i = 0; i < n_ssdirs; ++i)
 697                 ssdirs[n_ssdirs] = string_null;
 698         n_ssdirs = 0;
 699 }
 700
 701 void MapVote_SendChoice(int index)
 702 {
 703     TC(int, index);
 704         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
 705 }
 706
 707 int MapVote_MoveLeft(int pos)
 708 {
 709     TC(int, pos);
 710         int imp;
 711         if ( pos < 0 )
 712                 imp = mv_num_maps - 1;
 713         else
 714                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
 715         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 716                 imp = MapVote_MoveLeft(imp);
 717         return imp;
 718 }
 719 int MapVote_MoveRight(int pos)
 720 {
 721     TC(int, pos);
 722         int imp;
 723         if ( pos < 0 )
 724                 imp = 0;
 725         else
 726                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
 727         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 728                 imp = MapVote_MoveRight(imp);
 729         return imp;
 730 }
 731 int MapVote_MoveUp(int pos)
 732 {
 733     TC(int, pos);
 734         int imp;
 735         if ( pos < 0 )
 736                 imp = mv_num_maps - 1;
 737         else
 738         {
 739                 imp = pos - mv_columns;
 740                 if ( imp < 0 )
 741                 {
 742                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
 743                         if ( imp >= mv_num_maps )
 744                                 imp -= mv_columns;
 745                 }
 746         }
 747         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 748                 imp = MapVote_MoveUp(imp);
 749         return imp;
 750 }
 751 int MapVote_MoveDown(int pos)
 752 {
 753     TC(int, pos);
 754         int imp;
 755         if ( pos < 0 )
 756                 imp = 0;
 757         else
 758         {
 759                 imp = pos + mv_columns;
 760                 if ( imp >= mv_num_maps )
 761                         imp = imp % mv_columns;
 762         }
 763         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
 764                 imp = MapVote_MoveDown(imp);
 765         return imp;
 766 }
 767
 768 float MapVote_InputEvent(int bInputType, float nPrimary, float nSecondary)
 769 {
 770     TC(int, bInputType);
 771         float imp;
 772
 773         if (!mv_active)
 774                 return false;
 775
 776         if(bInputType == 3)
 777         {
 778                 mv_mousepos.x = nPrimary;
 779                 mv_mousepos.y = nSecondary;
 780                 mv_selection_keyboard = 0;
 781                 return true;
 782         }
 783
 784         if (bInputType != 0)
 785                 return false;
 786
 787         if ('0' <= nPrimary && nPrimary <= '9')
 788         {
 789                 imp = nPrimary - '0';
 790                 if (imp == 0) imp = 10;
 791                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 792                 return true;
 793         }
 794         switch(nPrimary)
 795         {
 796                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
 797                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
 798                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
 799                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
 800                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
 801                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
 802                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
 803                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
 804                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
 805                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
 806
 807                 case K_RIGHTARROW:
 808                         mv_selection_keyboard = 1;
 809                         mv_selection = MapVote_MoveRight(mv_selection);
 810                         return true;
 811                 case K_LEFTARROW:
 812                         mv_selection_keyboard = 1;
 813                         mv_selection = MapVote_MoveLeft(mv_selection);
 814                         return true;
 815                 case K_DOWNARROW:
 816                         mv_selection_keyboard = 1;
 817                         mv_selection = MapVote_MoveDown(mv_selection);
 818                         return true;
 819                 case K_UPARROW:
 820                         mv_selection_keyboard = 1;
 821                         mv_selection = MapVote_MoveUp(mv_selection);
 822                         return true;
 823                 case K_KP_ENTER:
 824                 case K_ENTER:
 825                 case K_SPACE:
 826                         if ( mv_selection_keyboard )
 827                                 MapVote_SendChoice(mv_selection);
 828                         return true;
 829         }
 830
 831         if (nPrimary == K_MOUSE1)
 832         {
 833                 mv_selection_keyboard = 0;
 834                 mv_selection = mv_mouse_selection;
 835                 if (mv_selection >= 0)
 836                 {
 837                         imp = min(mv_selection + 1, mv_num_maps);
 838                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
 839                         return true;
 840                 }
 841         }
 842
 843         return false;
 844 }
 845
 846 void MapVote_UpdateMask()
 847 {
 848         MapVote_ReadMask();
 849         mv_top2_time = time;
 850 }
 851
 852 void MapVote_UpdateVotes()
 853 {
 854         int i;
 855         for(i = 0; i < mv_num_maps; ++i)
 856         {
 857                 if(mv_flags[i] & GTV_AVAILABLE)
 858                 {
 859                         if(mv_detail)
 860                                 mv_votes[i] = ReadByte();
 861                         else
 862                                 mv_votes[i] = 0;
 863                 }
 864                 else
 865                         mv_votes[i] = -1;
 866         }
 867
 868         mv_ownvote = ReadByte()-1;
 869 }
 870
 871 NET_HANDLE(ENT_CLIENT_MAPVOTE, bool isnew)
 872 {
 873         make_pure(this);
 874         int sf = ReadByte();
 875         return = true;
 876
 877         if(sf & 1)
 878                 MapVote_Init();
 879
 880         if(sf & 2)
 881                 MapVote_UpdateMask();
 882
 883         if(sf & 4)
 884                 MapVote_UpdateVotes();
 885 }
 886
 887 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
 888 {
 889         Net_MapVote_Picture();
 890         return true;
 891 }
 892
 893 void Net_MapVote_Picture()
 894 {
 895         int type = ReadByte();
 896         mv_preview[type] = true;
 897         mv_pics[type] = strzone(ReadPicture());
 898 }