0ba6097701ebe85295efa9179652aa92f42bf0aa
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / miscfunctions.qc
1 var float(string text, float handleColors, vector fontSize) stringwidth;
2
3 entity players;
4 entity teams;
5
6 void serverAnnouncer()
7 {
8         // check for pending announcement, play it and remove it
9         if(announce_snd != "")
10         {
11                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
12                 strunzone(announce_snd);
13                 announce_snd = "";
14         }
15 }
16
17 void restartAnnouncer_Think() {
18         float countdown_rounded, countdown;
19         countdown = getstatf(STAT_GAMESTARTTIME) - time;
20         countdown_rounded = floor(0.5 + countdown);
21         if(countdown <= 0) {
22                 if (!spectatee_status) //do cprint only for players
23                         centerprint(_("^1Begin!"));
24
25                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
26                 //reset maptime announcers now as well
27                 announcer_5min = announcer_1min = FALSE;
28
29                 remove(self);
30                 return;
31         }
32         else {
33                 if (!spectatee_status) //do cprint only for players
34                         centerprint(sprintf(_("^1Game starts in %d seconds"), countdown_rounded));
35
36                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
37                         sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
38                 }
39
40                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
41         }
42 }
43
44 /**
45  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
46  */
47 void maptimeAnnouncer() {
48         float timelimit;
49         timelimit = getstatf(STAT_TIMELIMIT);
50         float timeleft;
51         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
52
53         float warmuplimit;
54         float warmuptimeleft;
55         if(warmup_stage) {
56                 warmuplimit = autocvar_g_warmup_limit;
57                 if(warmuplimit > 0) {
58                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time); 
59                 }
60         }
61
62         //5 minute check
63         if (autocvar_cl_sound_maptime_warning >= 2) {
64                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
65                 if(announcer_5min)
66                 {
67                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
68                                 announcer_5min = FALSE;
69                 }
70                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
71                         //if we're in warmup mode, check whether there's a warmup timelimit
72                         if not (warmuplimit == -1 && warmup_stage) {
73                                 announcer_5min = TRUE;
74                                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
75                         }
76         }
77
78         //1 minute check
79         if (autocvar_cl_sound_maptime_warning == 1 || autocvar_cl_sound_maptime_warning == 3) {
80                 if (announcer_1min)
81                 {
82                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
83                                 announcer_1min = FALSE;
84                 }
85                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
86                         //if we're in warmup mode, check whether there's a warmup timelimit
87                         if not (warmuplimit == -1 && warmup_stage) {
88                                 announcer_1min = TRUE;
89                                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
90                         }
91         }
92 }
93
94 /**
95  * Announce carried items (e.g. flags in CTF).
96  */
97 float redflag_prev;
98 float blueflag_prev;
99 void carrierAnnouncer() {
100         float stat_items, redflag, blueflag;
101         float pickup;
102         string item;
103
104         if not(autocvar_cl_notify_carried_items)
105                 return;
106
107         stat_items = getstati(STAT_ITEMS);
108
109         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
110         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
111
112         if (redflag == 3 && redflag != redflag_prev) {
113                 item = _("^1RED^7 flag");
114                 pickup = (redflag_prev == 2);
115         }
116
117         if (blueflag == 3 && blueflag != blueflag_prev) {
118                 item = _("^4BLUE^7 flag");
119                 pickup = (blueflag_prev == 2);
120         }
121
122         if (item)
123         {
124                 if (pickup) {
125                         if (autocvar_cl_notify_carried_items & 2)
126                                 centerprint(sprintf(_("You picked up the %s!"), item));
127                 }
128                 else {
129                         if (autocvar_cl_notify_carried_items & 1)
130                                 centerprint(sprintf(_("You got the %s!"), item));
131                 }
132         }
133
134         blueflag_prev = blueflag;
135         redflag_prev = redflag;
136 }
137
138 /**
139  * Add all future announcer sounds precaches here.
140  * TODO: announcer queues
141  */
142 void Announcer_Precache () {
143         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
144         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
145
146         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
147         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
148         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
149         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
150         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
151         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
152         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
153         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
154         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
155         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
156         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
157         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
158         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
159         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
160         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
161
162         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
163         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
164         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
167         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
169
170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
180
181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
183
184         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
187 }
188
189 void AuditLists()
190 {
191         entity e;
192         entity prev;
193
194         prev = players;
195         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
196         {
197                 if(prev != e.sort_prev)
198                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
199         }
200
201         prev = teams;
202         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
203         {
204                 if(prev != e.sort_prev)
205                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
206         }
207 }
208
209
210 float RegisterPlayer(entity player)
211 {
212         entity pl;
213         AuditLists();
214         for(pl = players.sort_next; pl; pl = pl.sort_next)
215                 if(pl == player)
216                         error("Player already registered!");
217         player.sort_next = players.sort_next;
218         player.sort_prev = players;
219         if(players.sort_next)
220                 players.sort_next.sort_prev = player;
221         players.sort_next = player;
222         AuditLists();
223         return true;
224 }
225
226 void RemovePlayer(entity player)
227 {
228         entity pl, parent;
229         AuditLists();
230         parent = players;
231         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
232                 parent = pl;
233
234         if(!pl)
235         {
236                 error("Trying to remove a player which is not in the playerlist!");
237                 return;
238         }
239         parent.sort_next = player.sort_next;
240         if(player.sort_next)
241                 player.sort_next.sort_prev = parent;
242         AuditLists();
243 }
244
245 void MoveToLast(entity e)
246 {
247         AuditLists();
248         other = e.sort_next;
249         while(other)
250         {
251                 SORT_SWAP(other, e);
252                 other = e.sort_next;
253         }
254         AuditLists();
255 }
256
257 float RegisterTeam(entity Team)
258 {
259         entity tm;
260         AuditLists();
261         for(tm = teams.sort_next; tm; tm = tm.sort_next)
262                 if(tm == Team)
263                         error("Team already registered!");
264         Team.sort_next = teams.sort_next;
265         Team.sort_prev = teams;
266         if(teams.sort_next)
267                 teams.sort_next.sort_prev = Team;
268         teams.sort_next = Team;
269         AuditLists();
270         return true;
271 }
272
273 void RemoveTeam(entity Team)
274 {
275         entity tm, parent;
276         AuditLists();
277         parent = teams;
278         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
279                 parent = tm;
280
281         if(!tm)
282         {
283                 print(_("Trying to remove a team which is not in the teamlist!"));
284                 return;
285         }
286         parent.sort_next = Team.sort_next;
287         if(Team.sort_next)
288                 Team.sort_next.sort_prev = parent;
289         AuditLists();
290 }
291
292 entity GetTeam(float Team, float add)
293 {
294         float num;
295         entity tm;
296         num = (Team == COLOR_SPECTATOR) ? 16 : Team;
297         if(teamslots[num])
298                 return teamslots[num];
299         if not(add)
300                 return NULL;
301         tm = spawn();
302         tm.team = Team;
303         teamslots[num] = tm;
304         RegisterTeam(tm);
305         return tm;
306 }
307
308 vector HUD_GetFontsize(string cvarname)
309 {
310         vector v;
311         v = stov(cvar_string(cvarname));
312         if(v_x == 0)
313                 v = '8 8 0';
314         if(v_y == 0)
315                 v_y = v_x;
316         v_z = 0;
317         return v;
318 }
319
320 float PreviewExists(string name)
321 {
322         if(autocvar_cl_readpicture_force)
323                 return false;
324
325         if (fexists(strcat(name, ".tga"))) return true;
326         if (fexists(strcat(name, ".png"))) return true;
327         if (fexists(strcat(name, ".jpg"))) return true;
328         if (fexists(strcat(name, ".pcx"))) return true;
329
330         return false;
331 }
332
333 vector rotate(vector v, float a)
334 {
335         vector w;
336         // FTEQCC SUCKS AGAIN
337         w_x =      v_x * cos(a) + v_y * sin(a);
338         w_y = -1 * v_x * sin(a) + v_y * cos(a);
339         return w;
340 }
341
342 float ColorTranslateMode;
343
344 string ColorTranslateRGB(string s)
345 {
346         if(ColorTranslateMode & 1)
347                 return strdecolorize(s);
348         else
349                 return s;
350 }
351
352 string Team_ColorCode(float teamid)
353 {
354     if (teamid == COLOR_TEAM1)
355         return "^1";
356     else if (teamid == COLOR_TEAM2)
357         return "^4";
358     else if (teamid == COLOR_TEAM3)
359         return "^3";
360     else if (teamid == COLOR_TEAM4)
361         return "^6";
362     else
363         return "^7";
364 }
365
366 // decolorizes and team colors the player name when needed
367 string playername(string thename, float teamid)
368 {
369     string t;
370     if (teamplay)
371     {
372         t = Team_ColorCode(teamid);
373         return strcat(t, strdecolorize(thename));
374     }
375     else
376         return strdecolorize(thename);
377 }
378
379 float cvar_or(string cv, float v)
380 {
381         string s;
382         s = cvar_string(cv);
383         if(s == "")
384                 return v;
385         else
386                 return stof(s);
387 }
388
389 vector project_3d_to_2d(vector vec)
390 {
391         vec = cs_project(vec);
392         if(cs_project_is_b0rked > 0)
393         {
394                 vec_x *= vid_conwidth / vid_width;
395                 vec_y *= vid_conheight / vid_height;
396         }
397         return vec;
398 }
399
400 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
401 {
402 }
403
404 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
405 {
406         return 1.2 / (1.2 - fadelerp);
407 }
408
409 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
410 {
411         boxsize_x *= boxxsizefactor; // easier interface for text
412         return boxsize * (0.5 * (1 - sz));
413 }
414
415 void drawborderlines(float thickness, vector pos, vector dim, vector color, float alpha, float drawflag)
416 {
417         vector line_dim;
418
419         // left and right lines
420         pos_x -= thickness;
421         line_dim_x = thickness;
422         line_dim_y = dim_y;
423         drawfill(pos, line_dim, color, alpha, drawflag);
424         drawfill(pos + (dim_x + thickness) * '1 0 0', line_dim, color, alpha, drawflag);
425
426         // upper and lower lines
427         pos_y -= thickness;
428         line_dim_x = dim_x + thickness * 2; // make upper and lower lines longer
429         line_dim_y = thickness;
430         drawfill(pos, line_dim, color, alpha, drawflag);
431         drawfill(pos + (dim_y + thickness) * '0 1 0', line_dim, color, alpha, drawflag);
432 }
433
434 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float alpha, float drawflag)
435 {
436         vector current_pos, end_pos, new_size, ratio;
437         end_pos = pos + area;
438
439         current_pos_y = pos_y;
440         while (current_pos_y < end_pos_y)
441         {
442                 current_pos_x = pos_x;
443                 while (current_pos_x < end_pos_x)
444                 {
445                         new_size_x = min(sz_x, end_pos_x - current_pos_x);
446                         new_size_y = min(sz_y, end_pos_y - current_pos_y);
447                         ratio_x = new_size_x / sz_x;
448                         ratio_y = new_size_y / sz_y;
449                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, alpha, drawflag);
450                         current_pos_x += sz_x;
451                 }
452                 current_pos_y += sz_y;
453         }
454 }
455
456 // drawpic wrapper to draw an image as large as possible with preserved aspect ratio into a box
457 var float _drawpic_imgaspect;
458 var vector _drawpic_imgsize;
459 var vector _drawpic_sz;
460 var float _drawpic_oldsz;
461 var string _drawpic_picpath;
462 #define drawpic_aspect(pos,pic,mySize,color,alpha,drawflag)\
463         do {\
464                 _drawpic_imgsize = drawgetimagesize(pic);\
465                 _drawpic_imgaspect = _drawpic_imgsize_x/_drawpic_imgsize_y;\
466                 _drawpic_sz = mySize;\
467                 if(_drawpic_sz_x/_drawpic_sz_y > _drawpic_imgaspect) {\
468                         _drawpic_oldsz = _drawpic_sz_x;\
469                         _drawpic_sz_x = _drawpic_sz_y * _drawpic_imgaspect;\
470                         drawpic(pos + eX * (_drawpic_oldsz - _drawpic_sz_x) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
471                 } else {\
472                         _drawpic_oldsz = _drawpic_sz_y;\
473                         _drawpic_sz_y = _drawpic_sz_x / _drawpic_imgaspect;\
474                         drawpic(pos + eY * (_drawpic_oldsz - _drawpic_sz_y) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
475                 }\
476         } while(0)
477
478 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
479 #define drawpic_aspect_skin(pos,pic,sz,color,alpha,drawflag)\
480         do{\
481                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
482                 if(precache_pic(_drawpic_picpath) == "") {\
483                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
484                 }\
485                 drawpic_aspect(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
486                 _drawpic_picpath = string_null;\
487         } while(0)
488
489 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
490 #define drawpic_skin(pos,pic,sz,color,alpha,drawflag)\
491         do{\
492                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
493                 if(precache_pic(_drawpic_picpath) == "") {\
494                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
495                 }\
496                 drawpic(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
497                 _drawpic_picpath = string_null;\
498         } while(0)
499
500 void drawpic_aspect_skin_expanding(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
501 {
502         float sz;
503         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
504
505         drawpic_aspect_skin(position + expandingbox_resize_centered_box_offset(sz, scale, 1), pic, scale * sz, rgb, alpha * (1 - fadelerp), flag);
506 }
507
508 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
509 {
510         drawpic_aspect_skin_expanding(position, pic, scale, rgb, alpha, flag, fadelerp);
511         drawpic_skin(position, pic, scale, rgb, alpha * fadelerp, flag);
512 }
513 #define SET_POS_AND_SZ_Y_ASPECT(allow_colors)\
514         float textaspect, oldsz;\
515         textaspect = stringwidth(text, allow_colors, '1 1 1' * sz_y) / sz_y;\
516         if(sz_x/sz_y > textaspect) {\
517                 oldsz = sz_x;\
518                 sz_x = sz_y * textaspect;\
519                 pos_x += (oldsz - sz_x) * 0.5;\
520         } else {\
521                 oldsz = sz_y;\
522                 sz_y = sz_x / textaspect; \
523                 pos_y += (oldsz - sz_y) * 0.5;\
524         }
525
526 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
527 void drawstring_aspect(vector pos, string text, vector sz, vector color, float alpha, float drawflag) {
528         SET_POS_AND_SZ_Y_ASPECT(FALSE)
529         drawstring(pos, text, '1 1 0' * sz_y, color, alpha, drawflag);
530 }
531
532 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
533 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float alpha, float drawflag) {
534         SET_POS_AND_SZ_Y_ASPECT(TRUE)
535         drawcolorcodedstring(pos, text, '1 1 0' * sz_y, alpha, drawflag);
536 }
537
538 vector drawfontscale;
539 void drawstring_expanding(vector position, string text, vector scale, vector rgb, float alpha, float flag, float fadelerp)
540 {
541         float sz;
542         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
543
544         drawfontscale = sz * '1 1 0';
545         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
546         drawstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, FALSE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), rgb, alpha * (1 - fadelerp), flag);
547         // width parameter:
548         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
549         //    SIZE1
550         drawfontscale = '1 1 0';
551 }
552
553 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
554 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float alpha, float drawflag, float fadelerp) {
555         SET_POS_AND_SZ_Y_ASPECT(FALSE)
556         drawstring_expanding(pos, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
557 }
558
559 void drawcolorcodedstring_expanding(vector position, string text, vector scale, float alpha, float flag, float fadelerp)
560 {
561         float sz;
562         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
563
564         drawfontscale = sz * '1 1 0';
565         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
566         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, TRUE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), alpha * (1 - fadelerp), flag);
567         drawfontscale = '1 1 0';
568 }
569
570 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float alpha, float drawflag, float fadelerp) {
571         SET_POS_AND_SZ_Y_ASPECT(TRUE)
572         drawcolorcodedstring_expanding(pos, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
573 }
574
575 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
576 float PolyDrawModelSurface(entity e, float i_s)
577 {
578         float i_t;
579         float n_t;
580         vector tri;
581         string tex;
582         tex = getsurfacetexture(e, i_s);
583         if not(tex)
584                 return 0; // this is beyond the last one
585         n_t = getsurfacenumtriangles(e, i_s);
586         for(i_t = 0; i_t < n_t; ++i_t)
587         {
588                 tri = getsurfacetriangle(e, i_s, i_t);
589                 R_BeginPolygon(tex, 0);
590                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_x), getsurfacepointattribute(e, i_s, tri_x, SPA_TEXCOORDS0), '1 1 1', 1);
591                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_y), getsurfacepointattribute(e, i_s, tri_y, SPA_TEXCOORDS0), '1 1 1', 1);
592                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_z), getsurfacepointattribute(e, i_s, tri_z, SPA_TEXCOORDS0), '1 1 1', 1);
593                 R_EndPolygon();
594         }
595         return 1;
596 }
597 void PolyDrawModel(entity e)
598 {
599         float i_s;
600         for(i_s = 0; ; ++i_s)
601                 if(!PolyDrawModelSurface(e, i_s))
602                         break;
603 }
604
605 void DrawCircleClippedPic(vector centre, float radius, string pic, float f, vector rgb, float a, float drawflag)
606 {
607         float x, y, q, d;
608         vector ringsize, v, t;
609         ringsize = radius * '1 1 0';
610
611         x = cos(f * 2 * M_PI);
612         y = sin(f * 2 * M_PI);
613         q = fabs(x) + fabs(y);
614         x /= q;
615         y /= q;
616
617         if(f >= 1)
618         {
619                 // draw full rectangle
620                 R_BeginPolygon(pic, drawflag);
621                         v = centre;                     t = '0.5 0.5 0';
622                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
623                         R_PolygonVertex(v, t, rgb, a);
624
625                         v = centre;                     t = '0.5 0.5 0';
626                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
627                         R_PolygonVertex(v, t, rgb, a);
628
629                         v = centre;                     t = '0.5 0.5 0';
630                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
631                         R_PolygonVertex(v, t, rgb, a);
632
633                         v = centre;                     t = '0.5 0.5 0';
634                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
635                         R_PolygonVertex(v, t, rgb, a);
636                 R_EndPolygon();
637
638                 d = q - 1;
639                 if(d > 0)
640                 {
641                         R_BeginPolygon(pic, drawflag);
642                                 v = centre;                     t = '0.5 0.5 0';
643                                 R_PolygonVertex(v, t, rgb, a);
644
645                                 v = centre;                     t = '0.5 0.5 0';
646                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
647                                 R_PolygonVertex(v, t, rgb, a);
648                 }
649         }
650         else if(f > 0.75)
651         {
652                 // draw upper and first triangle
653                 R_BeginPolygon(pic, drawflag);
654                         v = centre;                     t = '0.5 0.5 0';
655                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
656                         R_PolygonVertex(v, t, rgb, a);
657
658                         v = centre;                     t = '0.5 0.5 0';
659                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
660                         R_PolygonVertex(v, t, rgb, a);
661
662                         v = centre;                     t = '0.5 0.5 0';
663                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
664                         R_PolygonVertex(v, t, rgb, a);
665                 R_EndPolygon();
666                 R_BeginPolygon(pic, drawflag);
667                         v = centre;                     t = '0.5 0.5 0';
668                         R_PolygonVertex(v, t, rgb, a);
669
670                         v = centre;                     t = '0.5 0.5 0';
671                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
672                         R_PolygonVertex(v, t, rgb, a);
673
674                         v = centre;                     t = '0.5 0.5 0';
675                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
676                         R_PolygonVertex(v, t, rgb, a);
677
678                 d = q - 0.75;
679                 if(d <= 0)
680                         R_EndPolygon();
681         }
682         else if(f > 0.5)
683         {
684                 // draw upper triangle
685                 R_BeginPolygon(pic, drawflag);
686                         v = centre;                     t = '0.5 0.5 0';
687                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
688                         R_PolygonVertex(v, t, rgb, a);
689
690                         v = centre;                     t = '0.5 0.5 0';
691                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
692                         R_PolygonVertex(v, t, rgb, a);
693
694                         v = centre;                     t = '0.5 0.5 0';
695                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
696                         R_PolygonVertex(v, t, rgb, a);
697                 R_EndPolygon();
698
699                 d = q - 0.5;
700                 if(d > 0)
701                 {
702                         R_BeginPolygon(pic, drawflag);
703                                 v = centre;                     t = '0.5 0.5 0';
704                                 R_PolygonVertex(v, t, rgb, a);
705
706                                 v = centre;                     t = '0.5 0.5 0';
707                                 v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
708                                 R_PolygonVertex(v, t, rgb, a);
709                 }
710         }
711         else if(f > 0.25)
712         {
713                 // draw first triangle
714                 R_BeginPolygon(pic, drawflag);
715                         v = centre;                     t = '0.5 0.5 0';
716                         R_PolygonVertex(v, t, rgb, a);
717
718                         v = centre;                     t = '0.5 0.5 0';
719                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
720                         R_PolygonVertex(v, t, rgb, a);
721
722                         v = centre;                     t = '0.5 0.5 0';
723                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
724                         R_PolygonVertex(v, t, rgb, a);
725
726                 d = q - 0.25;
727                 if(d <= 0)
728                         R_EndPolygon();
729         }
730         else
731         {
732                 d = q;
733                 if(d > 0)
734                 {
735                         R_BeginPolygon(pic, drawflag);
736                                 v = centre;                     t = '0.5 0.5 0';
737                                 R_PolygonVertex(v, t, rgb, a);
738
739                                 v = centre;                     t = '0.5 0.5 0';
740                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
741                                 R_PolygonVertex(v, t, rgb, a);
742                 }
743         }
744
745         if(d > 0)
746         {
747                         v = centre;                     t = '0.5 0.5 0';
748                         v_x += x * 0.5 * ringsize_x;    t += x * '0.5 0.5 0';
749                         v_y += y * 0.5 * ringsize_y;    t += y * '0.5 -0.5 0';
750                         R_PolygonVertex(v, t, rgb, a);
751                 R_EndPolygon();
752         }
753 }
754
755 const vector GETPLAYERORIGIN_ERROR = '1123581321 2357111317 3141592653'; // way out of bounds for anything on the map
756 vector getplayerorigin(float pl)
757 {
758         string s;
759         entity e;
760
761         s = getplayerkey(pl, "TEMPHACK_origin");
762         if(s != "")
763                 return stov(s);
764
765         e = entcs_receiver[pl];
766         if(e)
767                 return e.origin;
768
769         return GETPLAYERORIGIN_ERROR;
770 }