qcsrc/client/miscfunctions.qc

   1 var float(string text, float handleColors, vector fontSize) stringwidth;
   2
   3 entity players;
   4 entity teams;
   5
   6 void serverAnnouncer()
   7 {
   8         // check for pending announcement, play it and remove it
   9         if(announce_snd != "")
  10         {
  11                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  12                 strunzone(announce_snd);
  13                 announce_snd = "";
  14         }
  15 }
  16
  17 void restartAnnouncer_Think() {
  18         float countdown_rounded, countdown;
  19         countdown = getstatf(STAT_GAMESTARTTIME) - time;
  20         countdown_rounded = floor(0.5 + countdown);
  21         if(countdown <= 0) {
  22                 if (!spectatee_status) //do cprint only for players
  23                         centerprint(_("^1Begin!"));
  24
  25                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
  26                 //reset maptime announcers now as well
  27                 announcer_5min = announcer_1min = FALSE;
  28
  29                 remove(self);
  30                 return;
  31         }
  32         else {
  33                 if (!spectatee_status) //do cprint only for players
  34                         centerprint(sprintf(_("^1Game starts in %d seconds"), countdown_rounded));
  35
  36                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
  37                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
  38                 }
  39
  40                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
  41         }
  42 }
  43
  44 /**
  45  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
  46  */
  47 void maptimeAnnouncer() {
  48         float timelimit;
  49         timelimit = getstatf(STAT_TIMELIMIT);
  50         float timeleft;
  51         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  52
  53         float warmuplimit;
  54         float warmuptimeleft;
  55         if(warmup_stage) {
  56                 warmuplimit = autocvar_g_warmup_limit;
  57                 if(warmuplimit > 0) {
  58                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time);
  59                 }
  60         }
  61
  62         //5 minute check
  63         if (autocvar_cl_sound_maptime_warning >= 2) {
  64                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  65                 if(announcer_5min)
  66                 {
  67                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
  68                                 announcer_5min = FALSE;
  69                 }
  70                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
  71                         //if we're in warmup mode, check whether there's a warmup timelimit
  72                         if not (warmuplimit == -1 && warmup_stage) {
  73                                 announcer_5min = TRUE;
  74                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
  75                         }
  76         }
  77
  78         //1 minute check
  79         if (autocvar_cl_sound_maptime_warning == 1 || autocvar_cl_sound_maptime_warning == 3) {
  80                 if (announcer_1min)
  81                 {
  82                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
  83                                 announcer_1min = FALSE;
  84                 }
  85                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
  86                         //if we're in warmup mode, check whether there's a warmup timelimit
  87                         if not (warmuplimit == -1 && warmup_stage) {
  88                                 announcer_1min = TRUE;
  89                                 sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
  90                         }
  91         }
  92 }
  93
  94 /**
  95  * Announce carried items (e.g. flags in CTF).
  96  */
  97 float redflag_prev;
  98 float blueflag_prev;
  99 void carrierAnnouncer() {
 100         float stat_items, redflag, blueflag;
 101         float pickup;
 102         string item;
 103
 104         if not(autocvar_cl_notify_carried_items)
 105                 return;
 106
 107         stat_items = getstati(STAT_ITEMS);
 108
 109         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 110         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 111
 112         if (redflag == 3 && redflag != redflag_prev) {
 113                 item = _("^1RED^7 flag");
 114                 pickup = (redflag_prev == 2);
 115         }
 116
 117         if (blueflag == 3 && blueflag != blueflag_prev) {
 118                 item = _("^4BLUE^7 flag");
 119                 pickup = (blueflag_prev == 2);
 120         }
 121
 122         if (item)
 123         {
 124                 if (pickup) {
 125                         if (autocvar_cl_notify_carried_items & 2)
 126                                 centerprint(sprintf(_("You picked up the %s!"), item));
 127                 }
 128                 else {
 129                         if (autocvar_cl_notify_carried_items & 1)
 130                                 centerprint(sprintf(_("You got the %s!"), item));
 131                 }
 132         }
 133
 134         blueflag_prev = blueflag;
 135         redflag_prev = redflag;
 136 }
 137
 138 /**
 139  * Add all future announcer sounds precaches here.
 140  * TODO: announcer queues
 141  */
 142 void Announcer_Precache () {
 143         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 144         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 145
 146         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 147         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 148         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 149         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 150         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 151         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 152         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 153         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 154         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 155         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 156         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 157         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 158         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 159         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 160         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 161
 162         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 163         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 164         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 167         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 169
 170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 176         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 180
 181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 183
 184         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 187 }
 188
 189 void AuditLists()
 190 {
 191         entity e;
 192         entity prev;
 193
 194         prev = players;
 195         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 196         {
 197                 if(prev != e.sort_prev)
 198                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 199         }
 200
 201         prev = teams;
 202         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 203         {
 204                 if(prev != e.sort_prev)
 205                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 206         }
 207 }
 208
 209
 210 float RegisterPlayer(entity player)
 211 {
 212         entity pl;
 213         AuditLists();
 214         for(pl = players.sort_next; pl; pl = pl.sort_next)
 215                 if(pl == player)
 216                         error("Player already registered!");
 217         player.sort_next = players.sort_next;
 218         player.sort_prev = players;
 219         if(players.sort_next)
 220                 players.sort_next.sort_prev = player;
 221         players.sort_next = player;
 222         AuditLists();
 223         return true;
 224 }
 225
 226 void RemovePlayer(entity player)
 227 {
 228         entity pl, parent;
 229         AuditLists();
 230         parent = players;
 231         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 232                 parent = pl;
 233
 234         if(!pl)
 235         {
 236                 error("Trying to remove a player which is not in the playerlist!");
 237                 return;
 238         }
 239         parent.sort_next = player.sort_next;
 240         if(player.sort_next)
 241                 player.sort_next.sort_prev = parent;
 242         AuditLists();
 243 }
 244
 245 void MoveToLast(entity e)
 246 {
 247         AuditLists();
 248         other = e.sort_next;
 249         while(other)
 250         {
 251                 SORT_SWAP(other, e);
 252                 other = e.sort_next;
 253         }
 254         AuditLists();
 255 }
 256
 257 float RegisterTeam(entity Team)
 258 {
 259         entity tm;
 260         AuditLists();
 261         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 262                 if(tm == Team)
 263                         error("Team already registered!");
 264         Team.sort_next = teams.sort_next;
 265         Team.sort_prev = teams;
 266         if(teams.sort_next)
 267                 teams.sort_next.sort_prev = Team;
 268         teams.sort_next = Team;
 269         AuditLists();
 270         return true;
 271 }
 272
 273 void RemoveTeam(entity Team)
 274 {
 275         entity tm, parent;
 276         AuditLists();
 277         parent = teams;
 278         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 279                 parent = tm;
 280
 281         if(!tm)
 282         {
 283                 print(_("Trying to remove a team which is not in the teamlist!"));
 284                 return;
 285         }
 286         parent.sort_next = Team.sort_next;
 287         if(Team.sort_next)
 288                 Team.sort_next.sort_prev = parent;
 289         AuditLists();
 290 }
 291
 292 entity GetTeam(float Team, float add)
 293 {
 294         float num;
 295         entity tm;
 296         num = (Team == COLOR_SPECTATOR) ? 16 : Team;
 297         if(teamslots[num])
 298                 return teamslots[num];
 299         if not(add)
 300                 return NULL;
 301         tm = spawn();
 302         tm.team = Team;
 303         teamslots[num] = tm;
 304         RegisterTeam(tm);
 305         return tm;
 306 }
 307
 308 vector HUD_GetFontsize(string cvarname)
 309 {
 310         vector v;
 311         v = stov(cvar_string(cvarname));
 312         if(v_x == 0)
 313                 v = '8 8 0';
 314         if(v_y == 0)
 315                 v_y = v_x;
 316         v_z = 0;
 317         return v;
 318 }
 319
 320 float PreviewExists(string name)
 321 {
 322         float f;
 323         string file;
 324
 325         if(autocvar_cl_readpicture_force)
 326                 return false;
 327
 328         if (fexists(strcat(name, ".tga"))) return true;
 329         if (fexists(strcat(name, ".png"))) return true;
 330         if (fexists(strcat(name, ".jpg"))) return true;
 331         if (fexists(strcat(name, ".pcx"))) return true;
 332
 333         return false;
 334 }
 335
 336 vector rotate(vector v, float a)
 337 {
 338         vector w;
 339         // FTEQCC SUCKS AGAIN
 340         w_x =      v_x * cos(a) + v_y * sin(a);
 341         w_y = -1 * v_x * sin(a) + v_y * cos(a);
 342         return w;
 343 }
 344
 345 float ColorTranslateMode;
 346
 347 string ColorTranslateRGB(string s)
 348 {
 349         if(ColorTranslateMode & 1)
 350                 return strdecolorize(s);
 351         else
 352                 return s;
 353 }
 354
 355 string Team_ColorCode(float teamid)
 356 {
 357     if (teamid == COLOR_TEAM1)
 358         return "^1";
 359     else if (teamid == COLOR_TEAM2)
 360         return "^4";
 361     else if (teamid == COLOR_TEAM3)
 362         return "^3";
 363     else if (teamid == COLOR_TEAM4)
 364         return "^6";
 365     else
 366         return "^7";
 367 }
 368
 369 // decolorizes and team colors the player name when needed
 370 string playername(string thename, float teamid)
 371 {
 372     string t;
 373     if (teamplay)
 374     {
 375         t = Team_ColorCode(teamid);
 376         return strcat(t, strdecolorize(thename));
 377     }
 378     else
 379         return strdecolorize(thename);
 380 }
 381
 382 float cvar_or(string cv, float v)
 383 {
 384         string s;
 385         s = cvar_string(cv);
 386         if(s == "")
 387                 return v;
 388         else
 389                 return stof(s);
 390 }
 391
 392 vector project_3d_to_2d(vector vec)
 393 {
 394         vec = cs_project(vec);
 395         if(cs_project_is_b0rked > 0)
 396         {
 397                 vec_x *= vid_conwidth / vid_width;
 398                 vec_y *= vid_conheight / vid_height;
 399         }
 400         return vec;
 401 }
 402
 403 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 404 {
 405 }
 406
 407 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 408 {
 409         return 1.2 / (1.2 - fadelerp);
 410 }
 411
 412 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 413 {
 414         boxsize_x *= boxxsizefactor; // easier interface for text
 415         return boxsize * (0.5 * (1 - sz));
 416 }
 417
 418 void drawborderlines(float thickness, vector pos, vector dim, vector color, float alpha, float drawflag)
 419 {
 420         vector line_dim;
 421
 422         // left and right lines
 423         pos_x -= thickness;
 424         line_dim_x = thickness;
 425         line_dim_y = dim_y;
 426         drawfill(pos, line_dim, color, alpha, drawflag);
 427         drawfill(pos + (dim_x + thickness) * '1 0 0', line_dim, color, alpha, drawflag);
 428
 429         // upper and lower lines
 430         pos_y -= thickness;
 431         line_dim_x = dim_x + thickness * 2; // make upper and lower lines longer
 432         line_dim_y = thickness;
 433         drawfill(pos, line_dim, color, alpha, drawflag);
 434         drawfill(pos + (dim_y + thickness) * '0 1 0', line_dim, color, alpha, drawflag);
 435 }
 436
 437 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float alpha, float drawflag)
 438 {
 439         vector current_pos, end_pos, new_size, ratio;
 440         end_pos = pos + area;
 441
 442         current_pos_y = pos_y;
 443         while (current_pos_y < end_pos_y)
 444         {
 445                 current_pos_x = pos_x;
 446                 while (current_pos_x < end_pos_x)
 447                 {
 448                         new_size_x = min(sz_x, end_pos_x - current_pos_x);
 449                         new_size_y = min(sz_y, end_pos_y - current_pos_y);
 450                         ratio_x = new_size_x / sz_x;
 451                         ratio_y = new_size_y / sz_y;
 452                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, alpha, drawflag);
 453                         current_pos_x += sz_x;
 454                 }
 455                 current_pos_y += sz_y;
 456         }
 457 }
 458
 459 // drawpic wrapper to draw an image as large as possible with preserved aspect ratio into a box
 460 var float _drawpic_imgaspect;
 461 var vector _drawpic_imgsize;
 462 var vector _drawpic_sz;
 463 var float _drawpic_oldsz;
 464 var string _drawpic_picpath;
 465 #define drawpic_aspect(pos,pic,mySize,color,alpha,drawflag)\
 466         do {\
 467                 _drawpic_imgsize = drawgetimagesize(pic);\
 468                 _drawpic_imgaspect = _drawpic_imgsize_x/_drawpic_imgsize_y;\
 469                 _drawpic_sz = mySize;\
 470                 if(_drawpic_sz_x/_drawpic_sz_y > _drawpic_imgaspect) {\
 471                         _drawpic_oldsz = _drawpic_sz_x;\
 472                         _drawpic_sz_x = _drawpic_sz_y * _drawpic_imgaspect;\
 473                         drawpic(pos + eX * (_drawpic_oldsz - _drawpic_sz_x) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
 474                 } else {\
 475                         _drawpic_oldsz = _drawpic_sz_y;\
 476                         _drawpic_sz_y = _drawpic_sz_x / _drawpic_imgaspect;\
 477                         drawpic(pos + eY * (_drawpic_oldsz - _drawpic_sz_y) * 0.5, pic, _drawpic_sz, color, alpha, drawflag);\
 478                 }\
 479         } while(0)
 480
 481 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 482 #define drawpic_aspect_skin(pos,pic,sz,color,alpha,drawflag)\
 483         do{\
 484                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
 485                 if(precache_pic(_drawpic_picpath) == "") {\
 486                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
 487                 }\
 488                 drawpic_aspect(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
 489                 _drawpic_picpath = string_null;\
 490         } while(0)
 491
 492 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 493 #define drawpic_skin(pos,pic,sz,color,alpha,drawflag)\
 494         do{\
 495                 _drawpic_picpath = strcat(hud_skin_path, "/", pic);\
 496                 if(precache_pic(_drawpic_picpath) == "") {\
 497                         _drawpic_picpath = strcat("gfx/hud/default/", pic);\
 498                 }\
 499                 drawpic(pos, _drawpic_picpath, sz, color, alpha, drawflag);\
 500                 _drawpic_picpath = string_null;\
 501         } while(0)
 502
 503 void drawpic_aspect_skin_expanding(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 504 {
 505         float sz;
 506         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 507
 508         drawpic_aspect_skin(position + expandingbox_resize_centered_box_offset(sz, scale, 1), pic, scale * sz, rgb, alpha * (1 - fadelerp), flag);
 509 }
 510
 511 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 512 {
 513         drawpic_aspect_skin_expanding(position, pic, scale, rgb, alpha, flag, fadelerp);
 514         drawpic_skin(position, pic, scale, rgb, alpha * fadelerp, flag);
 515 }
 516 #define SET_POS_AND_SZ_Y_ASPECT(allow_colors)\
 517         float textaspect, oldsz;\
 518         textaspect = stringwidth(text, allow_colors, '1 1 1' * sz_y) / sz_y;\
 519         if(sz_x/sz_y > textaspect) {\
 520                 oldsz = sz_x;\
 521                 sz_x = sz_y * textaspect;\
 522                 pos_x += (oldsz - sz_x) * 0.5;\
 523         } else {\
 524                 oldsz = sz_y;\
 525                 sz_y = sz_x / textaspect; \
 526                 pos_y += (oldsz - sz_y) * 0.5;\
 527         }
 528
 529 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 530 void drawstring_aspect(vector pos, string text, vector sz, vector color, float alpha, float drawflag) {
 531         SET_POS_AND_SZ_Y_ASPECT(FALSE)
 532         drawstring(pos, text, '1 1 0' * sz_y, color, alpha, drawflag);
 533 }
 534
 535 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 536 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float alpha, float drawflag) {
 537         SET_POS_AND_SZ_Y_ASPECT(TRUE)
 538         drawcolorcodedstring(pos, text, '1 1 0' * sz_y, alpha, drawflag);
 539 }
 540
 541 vector drawfontscale;
 542 void drawstring_expanding(vector position, string text, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 543 {
 544         float sz;
 545         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 546
 547         drawfontscale = sz * '1 1 0';
 548         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 549         drawstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, FALSE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), rgb, alpha * (1 - fadelerp), flag);
 550         // width parameter:
 551         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
 552         //    SIZE1
 553         drawfontscale = '1 1 0';
 554 }
 555
 556 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 557 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float alpha, float drawflag, float fadelerp) {
 558         SET_POS_AND_SZ_Y_ASPECT(FALSE)
 559         drawstring_expanding(pos, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
 560 }
 561
 562 void drawcolorcodedstring_expanding(vector position, string text, vector scale, float alpha, float flag, float fadelerp)
 563 {
 564         float sz;
 565         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 566
 567         drawfontscale = sz * '1 1 0';
 568         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 569         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, TRUE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), alpha * (1 - fadelerp), flag);
 570         drawfontscale = '1 1 0';
 571 }
 572
 573 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float alpha, float drawflag, float fadelerp) {
 574         SET_POS_AND_SZ_Y_ASPECT(TRUE)
 575         drawcolorcodedstring_expanding(pos, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
 576 }
 577
 578 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 579 float PolyDrawModelSurface(entity e, float i_s)
 580 {
 581         float i_t;
 582         float n_t;
 583         vector tri;
 584         string tex;
 585         tex = getsurfacetexture(e, i_s);
 586         if not(tex)
 587                 return 0; // this is beyond the last one
 588         n_t = getsurfacenumtriangles(e, i_s);
 589         for(i_t = 0; i_t < n_t; ++i_t)
 590         {
 591                 tri = getsurfacetriangle(e, i_s, i_t);
 592                 R_BeginPolygon(tex, 0);
 593                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_x), getsurfacepointattribute(e, i_s, tri_x, SPA_TEXCOORDS0), '1 1 1', 1);
 594                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_y), getsurfacepointattribute(e, i_s, tri_y, SPA_TEXCOORDS0), '1 1 1', 1);
 595                 R_PolygonVertex(getsurfacepoint(e, i_s, tri_z), getsurfacepointattribute(e, i_s, tri_z, SPA_TEXCOORDS0), '1 1 1', 1);
 596                 R_EndPolygon();
 597         }
 598         return 1;
 599 }
 600 void PolyDrawModel(entity e)
 601 {
 602         float i_s;
 603         for(i_s = 0; ; ++i_s)
 604                 if(!PolyDrawModelSurface(e, i_s))
 605                         break;
 606 }
 607
 608 void DrawCircleClippedPic(vector centre, float radius, string pic, float f, vector rgb, float a, float drawflag)
 609 {
 610         float x, y, q, d;
 611         vector ringsize, v, t;
 612         ringsize = radius * '1 1 0';
 613
 614         x = cos(f * 2 * M_PI);
 615         y = sin(f * 2 * M_PI);
 616         q = fabs(x) + fabs(y);
 617         x /= q;
 618         y /= q;
 619
 620         if(f >= 1)
 621         {
 622                 // draw full rectangle
 623                 R_BeginPolygon(pic, drawflag);
 624                         v = centre;                     t = '0.5 0.5 0';
 625                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 626                         R_PolygonVertex(v, t, rgb, a);
 627
 628                         v = centre;                     t = '0.5 0.5 0';
 629                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 630                         R_PolygonVertex(v, t, rgb, a);
 631
 632                         v = centre;                     t = '0.5 0.5 0';
 633                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 634                         R_PolygonVertex(v, t, rgb, a);
 635
 636                         v = centre;                     t = '0.5 0.5 0';
 637                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
 638                         R_PolygonVertex(v, t, rgb, a);
 639                 R_EndPolygon();
 640
 641                 d = q - 1;
 642                 if(d > 0)
 643                 {
 644                         R_BeginPolygon(pic, drawflag);
 645                                 v = centre;                     t = '0.5 0.5 0';
 646                                 R_PolygonVertex(v, t, rgb, a);
 647
 648                                 v = centre;                     t = '0.5 0.5 0';
 649                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 650                                 R_PolygonVertex(v, t, rgb, a);
 651                 }
 652         }
 653         else if(f > 0.75)
 654         {
 655                 // draw upper and first triangle
 656                 R_BeginPolygon(pic, drawflag);
 657                         v = centre;                     t = '0.5 0.5 0';
 658                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 659                         R_PolygonVertex(v, t, rgb, a);
 660
 661                         v = centre;                     t = '0.5 0.5 0';
 662                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 663                         R_PolygonVertex(v, t, rgb, a);
 664
 665                         v = centre;                     t = '0.5 0.5 0';
 666                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 667                         R_PolygonVertex(v, t, rgb, a);
 668                 R_EndPolygon();
 669                 R_BeginPolygon(pic, drawflag);
 670                         v = centre;                     t = '0.5 0.5 0';
 671                         R_PolygonVertex(v, t, rgb, a);
 672
 673                         v = centre;                     t = '0.5 0.5 0';
 674                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 675                         R_PolygonVertex(v, t, rgb, a);
 676
 677                         v = centre;                     t = '0.5 0.5 0';
 678                         v_y -= 0.5 * ringsize_y;        t -= '0.5 -0.5 0';
 679                         R_PolygonVertex(v, t, rgb, a);
 680
 681                 d = q - 0.75;
 682                 if(d <= 0)
 683                         R_EndPolygon();
 684         }
 685         else if(f > 0.5)
 686         {
 687                 // draw upper triangle
 688                 R_BeginPolygon(pic, drawflag);
 689                         v = centre;                     t = '0.5 0.5 0';
 690                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 691                         R_PolygonVertex(v, t, rgb, a);
 692
 693                         v = centre;                     t = '0.5 0.5 0';
 694                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 695                         R_PolygonVertex(v, t, rgb, a);
 696
 697                         v = centre;                     t = '0.5 0.5 0';
 698                         v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 699                         R_PolygonVertex(v, t, rgb, a);
 700                 R_EndPolygon();
 701
 702                 d = q - 0.5;
 703                 if(d > 0)
 704                 {
 705                         R_BeginPolygon(pic, drawflag);
 706                                 v = centre;                     t = '0.5 0.5 0';
 707                                 R_PolygonVertex(v, t, rgb, a);
 708
 709                                 v = centre;                     t = '0.5 0.5 0';
 710                                 v_x -= 0.5 * ringsize_x;        t -= '0.5 0.5 0';
 711                                 R_PolygonVertex(v, t, rgb, a);
 712                 }
 713         }
 714         else if(f > 0.25)
 715         {
 716                 // draw first triangle
 717                 R_BeginPolygon(pic, drawflag);
 718                         v = centre;                     t = '0.5 0.5 0';
 719                         R_PolygonVertex(v, t, rgb, a);
 720
 721                         v = centre;                     t = '0.5 0.5 0';
 722                         v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 723                         R_PolygonVertex(v, t, rgb, a);
 724
 725                         v = centre;                     t = '0.5 0.5 0';
 726                         v_y += 0.5 * ringsize_y;        t += '0.5 -0.5 0';
 727                         R_PolygonVertex(v, t, rgb, a);
 728
 729                 d = q - 0.25;
 730                 if(d <= 0)
 731                         R_EndPolygon();
 732         }
 733         else
 734         {
 735                 d = q;
 736                 if(d > 0)
 737                 {
 738                         R_BeginPolygon(pic, drawflag);
 739                                 v = centre;                     t = '0.5 0.5 0';
 740                                 R_PolygonVertex(v, t, rgb, a);
 741
 742                                 v = centre;                     t = '0.5 0.5 0';
 743                                 v_x += 0.5 * ringsize_x;        t += '0.5 0.5 0';
 744                                 R_PolygonVertex(v, t, rgb, a);
 745                 }
 746         }
 747
 748         if(d > 0)
 749         {
 750                         v = centre;                     t = '0.5 0.5 0';
 751                         v_x += x * 0.5 * ringsize_x;    t += x * '0.5 0.5 0';
 752                         v_y += y * 0.5 * ringsize_y;    t += y * '0.5 -0.5 0';
 753                         R_PolygonVertex(v, t, rgb, a);
 754                 R_EndPolygon();
 755         }
 756 }
 757
 758 const vector GETPLAYERORIGIN_ERROR = '1123581321 2357111317 3141592653'; // way out of bounds for anything on the map
 759 vector getplayerorigin(float pl)
 760 {
 761         string s;
 762         entity e;
 763
 764         s = getplayerkey(pl, "TEMPHACK_origin");
 765         if(s != "")
 766                 return stov(s);
 767
 768         e = entcs_receiver[pl];
 769         if(e.classname == "entcs_receiver")
 770                 return e.origin;
 771
 772         return GETPLAYERORIGIN_ERROR;
 773 }