qcsrc/client/miscfunctions.qc

   1 var float(string text, float handleColors, vector fontSize) stringwidth;
   2
   3 entity players;
   4 entity teams;
   5
   6 void serverAnnouncer()
   7 {
   8         // check for pending announcement, play it and remove it
   9         if(announce_snd != "")
  10         {
  11                 sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/", announce_snd, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  12                 strunzone(announce_snd);
  13                 announce_snd = "";
  14         }
  15 }
  16
  17 void restartAnnouncer_Think() {
  18         float countdown_rounded, countdown;
  19         countdown = getstatf(STAT_GAMESTARTTIME) - time;
  20         countdown_rounded = floor(0.5 + countdown);
  21         if(countdown <= 0) {
  22                 if (!spectatee_status) //do cprint only for players
  23                         centerprint("^1Begin!");
  24
  25                 sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/begin.wav"), VOL_BASEVOICE, ATTN_NONE);
  26                 //reset maptime announcers now as well
  27                 announcer_5min = announcer_1min = FALSE;
  28
  29                 remove(self);
  30                 return;
  31         }
  32         else {
  33                 if (!spectatee_status) //do cprint only for players
  34                         centerprint(strcat("^1Game starts in ", ftos(countdown_rounded), " seconds"));
  35
  36                 if(countdown_rounded <= 3 && countdown_rounded >= 1) {
  37                         sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/", ftos(countdown_rounded), ".wav"), VOL_BASEVOICE, ATTN_NONE);
  38                 }
  39
  40                 self.nextthink = getstatf(STAT_GAMESTARTTIME) - (countdown - 1);
  41         }
  42 }
  43
  44 /**
  45  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
  46  */
  47 void maptimeAnnouncer() {
  48         float timelimit;
  49         timelimit = getstatf(STAT_TIMELIMIT);
  50         float timeleft;
  51         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  52
  53         float warmuplimit;
  54         float warmuptimeleft;
  55         if(warmup_stage) {
  56                 warmuplimit = cvar("g_warmup_limit");
  57                 if(warmuplimit > 0) {
  58                         warmuptimeleft = max(0, warmuplimit + getstatf(STAT_GAMESTARTTIME) - time);
  59                 }
  60         }
  61
  62         //5 minute check
  63         if (cvar("cl_sound_maptime_warning") >= 2) {
  64                 //make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  65                 if(announcer_5min)
  66                 {
  67                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 300) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 300))
  68                                 announcer_5min = FALSE;
  69                 }
  70                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 300 && warmuptimeleft > 299))
  71                         //if we're in warmup mode, check whether there's a warmup timelimit
  72                         if not (warmuplimit == -1 && warmup_stage) {
  73                                 announcer_5min = TRUE;
  74                                 //dprint("i will play the sound, I promise!\n");
  75                                 sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/5minutesremain.wav"), VOL_BASEVOICE, ATTN_NONE);
  76                         }
  77         }
  78
  79         //1 minute check
  80         if (cvar("cl_sound_maptime_warning") == 1 || cvar("cl_sound_maptime_warning") == 3) {
  81                 if (announcer_1min)
  82                 {
  83                         if(((!warmup_stage || warmuplimit == 0) && timeleft > 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft > 60))
  84                                 announcer_1min = FALSE;
  85                 }
  86                 else if (((!warmup_stage || warmuplimit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && warmuplimit > 0 && warmuptimeleft < 60))
  87                         //if we're in warmup mode, check whether there's a warmup timelimit
  88                         if not (warmuplimit == -1 && warmup_stage) {
  89                                 announcer_1min = TRUE;
  90                                 sound(self, CHAN_VOICE, strcat("announcer/", cvar_string("cl_announcer"), "/1minuteremains.wav"), VOL_BASEVOICE, ATTN_NONE);
  91                         }
  92         }
  93 }
  94
  95 /**
  96  * Announce carried items (e.g. flags in CTF).
  97  */
  98 float redflag_prev;
  99 float blueflag_prev;
 100 void carrierAnnouncer() {
 101         float stat_items, redflag, blueflag;
 102         float pickup;
 103         string item;
 104
 105         if not(cvar("cl_notify_carried_items"))
 106                 return;
 107
 108         stat_items = getstati(STAT_ITEMS);
 109
 110         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 111         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 112
 113         if (redflag == 3 && redflag != redflag_prev) {
 114                 item = "^1RED^7 flag";
 115                 pickup = (redflag_prev == 2);
 116         }
 117
 118         if (blueflag == 3 && blueflag != blueflag_prev) {
 119                 item = "^4BLUE^7 flag";
 120                 pickup = (blueflag_prev == 2);
 121         }
 122
 123         if (item)
 124         {
 125                 if (pickup) {
 126                         if (cvar("cl_notify_carried_items") & 2)
 127                                 centerprint(strcat("You picked up the ", item, "!"));
 128                 }
 129                 else {
 130                         if (cvar("cl_notify_carried_items") & 1)
 131                                 centerprint(strcat("You got the ", item, "!"));
 132                 }
 133         }
 134
 135         blueflag_prev = blueflag;
 136         redflag_prev = redflag;
 137 }
 138
 139 /**
 140  * Add all future announcer sounds precaches here.
 141  * TODO: announcer queues
 142  */
 143 void Announcer_Precache () {
 144         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/1minuteremains.wav"));
 145         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/5minutesremain.wav"));
 146
 147         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/electrobitch.wav"));
 148         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/airshot.wav"));
 149         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/03kills.wav"));
 150         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/05kills.wav"));
 151         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/10kills.wav"));
 152         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/15kills.wav"));
 153         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/20kills.wav"));
 154         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/25kills.wav"));
 155         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/30kills.wav"));
 156         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/botlike.wav"));
 157         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/yoda.wav"));
 158         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/amazing.wav"));
 159         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/awesome.wav"));
 160         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/headshot.wav"));
 161         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/impressive.wav"));
 162
 163         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"));
 164         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/begin.wav"));
 165         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/timeoutcalled.wav"));
 166         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/1fragleft.wav"));
 167         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/2fragsleft.wav"));
 168         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/3fragsleft.wav"));
 169         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/terminated.wav"));
 170
 171         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/1.wav"));
 172         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/2.wav"));
 173         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/3.wav"));
 174         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/4.wav"));
 175         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/5.wav"));
 176         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/6.wav"));
 177         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/7.wav"));
 178         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/8.wav"));
 179         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/9.wav"));
 180         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/10.wav"));
 181
 182         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/lastsecond.wav"));
 183         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/narrowly.wav"));
 184
 185         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/voteaccept.wav"));
 186         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/votecall.wav"));
 187         precache_sound (strcat("announcer/", cvar_string("cl_announcer"), "/votefail.wav"));
 188 }
 189
 190 void AuditLists()
 191 {
 192         entity e;
 193         entity prev;
 194
 195         prev = players;
 196         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 197         {
 198                 if(prev != e.sort_prev)
 199                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 200         }
 201
 202         prev = teams;
 203         for(e = prev.sort_next; e; prev = e, e = e.sort_next)
 204         {
 205                 if(prev != e.sort_prev)
 206                         error(strcat("sort list chain error\nplease submit the output of 'prvm_edicts client' to the developers"));
 207         }
 208 }
 209
 210
 211 float RegisterPlayer(entity player)
 212 {
 213         entity pl;
 214         AuditLists();
 215         for(pl = players.sort_next; pl; pl = pl.sort_next)
 216                 if(pl == player)
 217                         error("Player already registered!");
 218         player.sort_next = players.sort_next;
 219         player.sort_prev = players;
 220         if(players.sort_next)
 221                 players.sort_next.sort_prev = player;
 222         players.sort_next = player;
 223         AuditLists();
 224         return true;
 225 }
 226
 227 void RemovePlayer(entity player)
 228 {
 229         entity pl, parent;
 230         AuditLists();
 231         parent = players;
 232         for(pl = players.sort_next; pl && pl != player; pl = pl.sort_next)
 233                 parent = pl;
 234
 235         if(!pl)
 236         {
 237                 error("Trying to remove a player which is not in the playerlist!");
 238                 return;
 239         }
 240         parent.sort_next = player.sort_next;
 241         if(player.sort_next)
 242                 player.sort_next.sort_prev = parent;
 243         AuditLists();
 244 }
 245
 246 void MoveToLast(entity e)
 247 {
 248         AuditLists();
 249         other = e.sort_next;
 250         while(other)
 251         {
 252                 SORT_SWAP(other, e);
 253                 other = e.sort_next;
 254         }
 255         AuditLists();
 256 }
 257
 258 float RegisterTeam(entity Team)
 259 {
 260         entity tm;
 261         AuditLists();
 262         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 263                 if(tm == Team)
 264                         error("Team already registered!");
 265         Team.sort_next = teams.sort_next;
 266         Team.sort_prev = teams;
 267         if(teams.sort_next)
 268                 teams.sort_next.sort_prev = Team;
 269         teams.sort_next = Team;
 270         AuditLists();
 271         return true;
 272 }
 273
 274 void RemoveTeam(entity Team)
 275 {
 276         entity tm, parent;
 277         AuditLists();
 278         parent = teams;
 279         for(tm = teams.sort_next; tm && tm != Team; tm = tm.sort_next)
 280                 parent = tm;
 281
 282         if(!tm)
 283         {
 284                 print("Trying to remove a team which is not in the teamlist!");
 285                 return;
 286         }
 287         parent.sort_next = Team.sort_next;
 288         if(Team.sort_next)
 289                 Team.sort_next.sort_prev = parent;
 290         AuditLists();
 291 }
 292
 293 entity GetTeam(float Team, float add)
 294 {
 295         float num;
 296         entity tm;
 297         num = (Team == COLOR_SPECTATOR) ? 16 : Team;
 298         if(teamslots[num])
 299                 return teamslots[num];
 300         if not(add)
 301                 return NULL;
 302         tm = spawn();
 303         tm.team = Team;
 304         teamslots[num] = tm;
 305         RegisterTeam(tm);
 306         return tm;
 307 }
 308
 309 void CSQC_CheckEngine()
 310 {
 311         hud_font = FONT_USER+1;
 312         hud_bigfont = FONT_USER+2;
 313 }
 314
 315 vector HUD_GetFontsize(string cvarname)
 316 {
 317         vector v;
 318         v = stov(cvar_string(cvarname));
 319         if(v_x == 0)
 320                 v = '8 8 0';
 321         if(v_y == 0)
 322                 v_y = v_x;
 323         v_z = 0;
 324         return v;
 325 }
 326
 327 float HUD_GetWidth(float teamcolumnwidth)
 328 {
 329         float f;
 330         f = cvar("hud_width");
 331         if(f == 0)
 332                 f = 640;
 333         if(f < 320)
 334                 f = 320;
 335         if(f > vid_conwidth - 2 * teamcolumnwidth)
 336                 f = vid_conwidth - 2 * teamcolumnwidth;
 337         return f;
 338 }
 339
 340 float PreviewExists(string name)
 341 {
 342         float f;
 343         string file;
 344
 345         if(cvar("cl_readpicture_force"))
 346                 return false;
 347
 348         file = strcat(name, ".tga");
 349         f = fopen(file, FILE_READ);
 350         if(f >= 0)
 351         {
 352                 fclose(f);
 353                 return true;
 354         }
 355         file = strcat(name, ".png");
 356         f = fopen(file, FILE_READ);
 357         if(f >= 0)
 358         {
 359                 fclose(f);
 360                 return true;
 361         }
 362         file = strcat(name, ".jpg");
 363         f = fopen(file, FILE_READ);
 364         if(f >= 0)
 365         {
 366                 fclose(f);
 367                 return true;
 368         }
 369         file = strcat(name, ".pcx");
 370         f = fopen(file, FILE_READ);
 371         if(f >= 0)
 372         {
 373                 fclose(f);
 374                 return true;
 375         }
 376         return false;
 377 }
 378
 379 vector rotate(vector v, float a)
 380 {
 381         vector w;
 382         // FTEQCC SUCKS AGAIN
 383         w_x =      v_x * cos(a) + v_y * sin(a);
 384         w_y = -1 * v_x * sin(a) + v_y * cos(a);
 385         return w;
 386 }
 387
 388 float ColorTranslateMode;
 389
 390 string ColorTranslateRGB(string s)
 391 {
 392         if(ColorTranslateMode & 1)
 393                 return strdecolorize(s);
 394         else
 395                 return s;
 396 }
 397
 398 float cvar_or(string cv, float v)
 399 {
 400         string s;
 401         s = cvar_string(cv);
 402         if(s == "")
 403                 return v;
 404         else
 405                 return stof(s);
 406 }
 407
 408 vector project_3d_to_2d(vector vec)
 409 {
 410         vec = cs_project(vec);
 411         if(cs_project_is_b0rked > 0)
 412         {
 413                 vec_x *= vid_conwidth / vid_width;
 414                 vec_y *= vid_conheight / vid_height;
 415         }
 416         return vec;
 417 }
 418
 419 void dummyfunction(float a1, float a2, float a3, float a4, float a5, float a6, float a7, float a8)
 420 {
 421 }
 422
 423 float expandingbox_sizefactor_from_fadelerp(float fadelerp)
 424 {
 425         return 1.2 / (1.2 - fadelerp);
 426 }
 427
 428 vector expandingbox_resize_centered_box_offset(float sz, vector boxsize, float boxxsizefactor)
 429 {
 430         boxsize_x *= boxxsizefactor; // easier interface for text
 431         return boxsize * (0.5 * (1 - sz));
 432 }
 433
 434 void drawborderlines(float thickness, vector pos, vector dim, vector color, float alpha, float drawflag)
 435 {
 436         vector line_dim;
 437
 438         // left and right lines
 439         pos_x -= thickness;
 440         line_dim_x = thickness;
 441         line_dim_y = dim_y;
 442         drawfill(pos, line_dim, color, alpha, drawflag);
 443         drawfill(pos + (dim_x + thickness) * '1 0 0', line_dim, color, alpha, drawflag);
 444
 445         // upper and lower lines
 446         pos_y -= thickness;
 447         line_dim_x = dim_x + thickness * 2; // make upper and lower lines longer
 448         line_dim_y = thickness;
 449         drawfill(pos, line_dim, color, alpha, drawflag);
 450         drawfill(pos + (dim_y + thickness) * '0 1 0', line_dim, color, alpha, drawflag);
 451 }
 452
 453 void drawpic_tiled(vector pos, string pic, vector sz, vector area, vector color, float alpha, float drawflag)
 454 {
 455         vector current_pos, end_pos, new_size, ratio;
 456         end_pos = pos + area;
 457
 458         current_pos_y = pos_y;
 459         while (current_pos_y < end_pos_y)
 460         {
 461                 current_pos_x = pos_x;
 462                 while (current_pos_x < end_pos_x)
 463                 {
 464                         new_size_x = min(sz_x, end_pos_x - current_pos_x);
 465                         new_size_y = min(sz_y, end_pos_y - current_pos_y);
 466                         ratio_x = new_size_x / sz_x;
 467                         ratio_y = new_size_y / sz_y;
 468                         drawsubpic(current_pos, new_size, pic, '0 0 0', ratio, color, alpha, drawflag);
 469                         current_pos_x += sz_x;
 470                 }
 471                 current_pos_y += sz_y;
 472         }
 473 }
 474
 475 // drawpic wrapper to draw an image as large as possible with preserved aspect ratio into a box
 476 var float imgaspect;
 477 var float aspect;
 478 #define drawpic_aspect(pos,pic,mySize,color,alpha,drawflag)\
 479         do {\
 480                 vector imgsize;\
 481                 imgsize = drawgetimagesize(pic);\
 482                 imgaspect = imgsize_x/imgsize_y;\
 483                 vector oldsz, sz;\
 484                 oldsz = sz = mySize;\
 485                 aspect = sz_x/sz_y;\
 486                 if(aspect > imgaspect) {\
 487                         sz_x = sz_y * imgaspect;\
 488                         drawpic(pos + eX * (oldsz_x - sz_x) * 0.5, pic, sz, color, alpha, drawflag);\
 489                 } else {\
 490                         sz_y = sz_x / imgaspect;\
 491                         drawpic(pos + eY * (oldsz_y - sz_y) * 0.5, pic, sz, color, alpha, drawflag);\
 492                 }\
 493         } while(0)
 494
 495 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 496 #define drawpic_aspect_skin(pos,pic,sz,color,alpha,drawflag)\
 497         do{\
 498                 picpath = strcat(hud_skin_path, "/", pic);\
 499                 if(precache_pic(picpath) == "") {\
 500                         picpath = strcat("gfx/hud/default/", pic);\
 501                 }\
 502                 drawpic_aspect(pos, picpath, sz, color, alpha, drawflag);\
 503         } while(0)
 504
 505 // draw HUD element with image from gfx/hud/hud_skin/foo.tga if it exists, otherwise gfx/hud/default/foo.tga
 506 #define drawpic_skin(pos,pic,sz,color,alpha,drawflag)\
 507         do{\
 508                 picpath = strcat(hud_skin_path, "/", pic);\
 509                 if(precache_pic(picpath) == "") {\
 510                         picpath = strcat("gfx/hud/default/", pic);\
 511                 }\
 512                 drawpic(pos, picpath, sz, color, alpha, drawflag);\
 513         } while(0)
 514
 515 void drawpic_aspect_skin_expanding(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 516 {
 517         float sz;
 518         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 519
 520         drawpic_skin(position + expandingbox_resize_centered_box_offset(sz, scale, 1), pic, scale * sz, rgb, alpha * (1 - fadelerp), flag);
 521 }
 522
 523 void drawpic_aspect_skin_expanding_two(vector position, string pic, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 524 {
 525         drawpic_aspect_skin_expanding(position, pic, scale, rgb, alpha, flag, fadelerp);
 526         drawpic_skin(position, pic, scale, rgb, alpha * fadelerp, flag);
 527 }
 528
 529 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 530 void drawstring_aspect(vector pos, string text, vector sz, vector color, float alpha, float drawflag) {
 531         vector textsize;
 532         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
 533
 534         float textaspect;
 535         textaspect = textsize_x/textsize_y;
 536
 537         vector oldsz;
 538         oldsz = sz;
 539         float aspect;
 540         aspect = sz_x/sz_y;
 541
 542         if(aspect > textaspect) {
 543                 sz_x = sz_y * textaspect;
 544                 drawstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
 545         } else {
 546                 sz_y = sz_x / textaspect;
 547                 drawstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag);
 548         }
 549 }
 550
 551 // drawstring wrapper to draw a colorcodedstring as large as possible with preserved aspect ratio into a box
 552 void drawcolorcodedstring_aspect(vector pos, string text, vector sz, float alpha, float drawflag) {
 553         vector textsize;
 554         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
 555
 556         float textaspect;
 557         textaspect = textsize_x/textsize_y;
 558
 559         vector oldsz;
 560         oldsz = sz;
 561         float aspect;
 562         aspect = sz_x/sz_y;
 563
 564         if(aspect > textaspect) {
 565                 sz_x = sz_y * textaspect;
 566                 drawcolorcodedstring(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
 567         } else {
 568                 sz_y = sz_x / textaspect;
 569                 drawcolorcodedstring(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag);
 570         }
 571 }
 572
 573 vector drawfontscale;
 574 void drawstring_expanding(vector position, string text, vector scale, vector rgb, float alpha, float flag, float fadelerp)
 575 {
 576         float sz;
 577         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 578
 579         drawfontscale = sz * '1 1 0';
 580         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 581         drawstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, FALSE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), rgb, alpha * (1 - fadelerp), flag);
 582         // width parameter:
 583         //    (scale_x * sz / drawfontscale_x) * drawfontscale_x * SIZE1 / (scale_x * sz)
 584         //    SIZE1
 585         drawfontscale = '1 1 0';
 586 }
 587
 588 // drawstring wrapper to draw a string as large as possible with preserved aspect ratio into a box
 589 void drawstring_aspect_expanding(vector pos, string text, vector sz, vector color, float alpha, float drawflag, float fadelerp) {
 590         vector textsize;
 591         textsize = eX * stringwidth(text, FALSE, '1 1 1' * sz_y) + eY * sz_y;
 592
 593         float textaspect;
 594         textaspect = textsize_x/textsize_y;
 595
 596         vector oldsz;
 597         oldsz = sz;
 598         float aspect;
 599         aspect = sz_x/sz_y;
 600
 601         if(aspect > textaspect) {
 602                 sz_x = sz_y * textaspect;
 603                 drawstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
 604         } else {
 605                 sz_y = sz_x / textaspect;
 606                 drawstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, color, alpha, drawflag, fadelerp);
 607         }
 608 }
 609
 610 void drawcolorcodedstring_expanding(vector position, string text, vector scale, float alpha, float flag, float fadelerp)
 611 {
 612         float sz;
 613         sz = expandingbox_sizefactor_from_fadelerp(fadelerp);
 614
 615         drawfontscale = sz * '1 1 0';
 616         dummyfunction(0, 0, 0, 0, 0, 0, 0, 0);
 617         drawcolorcodedstring(position + expandingbox_resize_centered_box_offset(sz, scale, stringwidth(text, TRUE, scale * (sz / drawfontscale_x)) / (scale_x * sz)), text, scale * (sz / drawfontscale_x), alpha * (1 - fadelerp), flag);
 618         drawfontscale = '1 1 0';
 619 }
 620
 621 void drawcolorcodedstring_aspect_expanding(vector pos, string text, vector sz, float alpha, float drawflag, float fadelerp) {
 622         vector textsize;
 623         textsize = eX * stringwidth(text, TRUE, '1 1 1' * sz_y) + eY * sz_y;
 624
 625         float textaspect;
 626         textaspect = textsize_x/textsize_y;
 627
 628         vector oldsz;
 629         oldsz = sz;
 630         float aspect;
 631         aspect = sz_x/sz_y;
 632
 633         if(aspect > textaspect) {
 634                 sz_x = sz_y * textaspect;
 635                 drawcolorcodedstring_expanding(pos + eX * (oldsz_x - sz_x) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
 636         } else {
 637                 sz_y = sz_x / textaspect;
 638                 drawcolorcodedstring_expanding(pos + eY * (oldsz_y - sz_y) * 0.5, text, '1 1 0' * sz_y, alpha, drawflag, fadelerp);
 639         }
 640 }
 641
 642 // this draws the triangles of a model DIRECTLY. Don't expect high performance, really...
 643 void PolyDrawModel(entity e)
 644 {
 645         float i_s, i_t;
 646         float n_t;
 647         vector tri;
 648         string tex;
 649         for(i_s = 0; ; ++i_s)
 650         {
 651                 tex = getsurfacetexture(e, i_s);
 652                 if not(tex)
 653                         break; // this is beyond the last one
 654                 n_t = getsurfacenumtriangles(e, i_s);
 655                 for(i_t = 0; i_t < n_t; ++i_t)
 656                 {
 657                         tri = getsurfacetriangle(e, i_s, i_t);
 658                         R_BeginPolygon(tex, 0);
 659                         R_PolygonVertex(getsurfacepoint(e, i_s, tri_x), getsurfacepointattribute(e, i_s, tri_x, SPA_TEXCOORDS0), '1 1 1', 1);
 660                         R_PolygonVertex(getsurfacepoint(e, i_s, tri_y), getsurfacepointattribute(e, i_s, tri_y, SPA_TEXCOORDS0), '1 1 1', 1);
 661                         R_PolygonVertex(getsurfacepoint(e, i_s, tri_z), getsurfacepointattribute(e, i_s, tri_z, SPA_TEXCOORDS0), '1 1 1', 1);
 662                         R_EndPolygon();
 663                 }
 664         }
 665 }