qcsrc/client/shownames.qc

   1 #include "shownames.qh"
   2
   3 #include "hud/all.qh"
   4
   5 #include "../common/constants.qh"
   6 #include "../common/mapinfo.qh"
   7 #include "../common/teams.qh"
   8
   9 #include "../lib/csqcmodel/cl_model.qh"
  10
  11 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
  12 // self.origin = player origin
  13 // self.healthvalue
  14 // self.armorvalue
  15 // self.sameteam = player is on same team as local client
  16 // self.fadedelay = time to wait before name tag starts fading in for enemies
  17 // self.pointtime = last time you pointed at this player
  18 // self.csqcmodel_isdead = value of csqcmodel_isdead to know when the player is dead or not
  19
  20 LinkedList shownames_ent;
  21 STATIC_INIT(shownames_ent)
  22 {
  23         shownames_ent = LL_NEW();
  24         for (int i = 0; i < maxclients; ++i)
  25         {
  26                 entity e = new(shownames_tag);
  27                 make_pure(e);
  28                 e.sv_entnum = i + 1;
  29                 LL_PUSH(shownames_ent, e);
  30         }
  31 }
  32
  33 const float SHOWNAMES_FADESPEED = 4;
  34 const float SHOWNAMES_FADEDELAY = 0.4;
  35 void Draw_ShowNames(entity this)
  36 {
  37         if (this.sv_entnum == player_localentnum)  // self or spectatee
  38                 if (!(autocvar_hud_shownames_self && autocvar_chase_active)) return;
  39         if (!this.sameteam && !autocvar_hud_shownames_enemies) return;
  40         bool hit;
  41         if (!autocvar_hud_shownames_crosshairdistance && this.sameteam)
  42         {
  43                 hit = true;
  44         }
  45         else
  46         {
  47                 traceline(view_origin, this.origin, MOVE_NORMAL, this);
  48                 hit = !(trace_fraction < 1 && (trace_networkentity != this.sv_entnum && trace_ent.entnum != this.sv_entnum));
  49         }
  50         // handle tag fading
  51         bool overlap = false;
  52         vector o = project_3d_to_2d(this.origin + eZ * autocvar_hud_shownames_offset);
  53         float dist = vlen(this.origin - view_origin);
  54         if (autocvar_hud_shownames_antioverlap)
  55         {
  56                 // fade tag out if another tag that is closer to you overlaps
  57                 LL_EACH(shownames_ent, it != this && entcs_receiver(i), LAMBDA(
  58                         vector eo = project_3d_to_2d(it.origin);
  59                         if (eo.z < 0 || eo.x < 0 || eo.y < 0 || eo.x > vid_conwidth || eo.y > vid_conheight) continue;
  60                         eo.z = 0;
  61                         if (vlen((eX * o.x + eY * o.y) - eo) < autocvar_hud_shownames_antioverlap_distance
  62                             && dist > vlen(it.origin - view_origin))
  63                         {
  64                                 overlap = true;
  65                                 break;
  66                         }
  67                 ));
  68         }
  69         bool onscreen = (o.z >= 0 && o.x >= 0 && o.y >= 0 && o.x <= vid_conwidth && o.y <= vid_conheight);
  70         float crosshairdistance = sqrt(pow(o.x - vid_conwidth / 2, 2) + pow(o.y - vid_conheight / 2, 2));
  71         if (autocvar_hud_shownames_crosshairdistance)
  72         {
  73                 if (autocvar_hud_shownames_crosshairdistance > crosshairdistance) this.pointtime = time;
  74                 if (this.pointtime + autocvar_hud_shownames_crosshairdistance_time <= time) overlap = true;
  75                 else overlap = (autocvar_hud_shownames_crosshairdistance_antioverlap ? overlap : false); // override what antioverlap says unless allowed by cvar.
  76         }
  77         if (!this.fadedelay) this.fadedelay = time + SHOWNAMES_FADEDELAY;
  78         if (this.csqcmodel_isdead)                                                                   // dead player, fade out slowly
  79         {
  80                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  81         }
  82         else if (!this.sameteam && (!onscreen || !hit)) // out of view, fade out
  83         {
  84                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
  85                 this.fadedelay = 0;                         // reset fade in delay, enemy has left the view
  86         }
  87         else if (overlap)                               // tag overlap detected, fade out
  88         {
  89                 this.alpha = max(0, this.alpha - SHOWNAMES_FADESPEED * frametime);
  90         }
  91         else if (this.sameteam)  // fade in for team mates
  92         {
  93                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
  94         }
  95         else if (time > this.fadedelay)  // fade in for enemies
  96         {
  97                 this.alpha = min(1, this.alpha + SHOWNAMES_FADESPEED * frametime);
  98         }
  99         float a = autocvar_hud_shownames_alpha * this.alpha;
 100         // multiply by player alpha
 101         if (!this.sameteam || (this.sv_entnum == player_localentnum))
 102         {
 103                 float f = entcs_GetAlpha(this.sv_entnum - 1);
 104                 if (f == 0) f = 1;
 105                 if (f < 0) f = 0;
 106                 // FIXME: alpha is negative when dead, breaking death fade
 107                 if (!this.csqcmodel_isdead) a *= f;
 108         }
 109         if (a < ALPHA_MIN_VISIBLE && gametype != MAPINFO_TYPE_CTS) return;
 110         if (autocvar_hud_shownames_maxdistance)
 111         {
 112                 if (dist >= autocvar_hud_shownames_maxdistance) return;
 113                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 114                 a *= (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 115         }
 116         if (!a) return;
 117         float resize = 1;
 118         if (autocvar_hud_shownames_resize)  // limit resize so its never smaller than 0.5... gets unreadable
 119         {
 120                 float f = autocvar_hud_shownames_maxdistance - autocvar_hud_shownames_mindistance;
 121                 resize = 0.5 + 0.5 * (f - max(0, dist - autocvar_hud_shownames_mindistance)) / f;
 122         }
 123         // draw the sprite image
 124         if (o.z >= 0)
 125         {
 126                 o.z = 0;
 127                 vector mySize = (eX * autocvar_hud_shownames_aspect + eY) * autocvar_hud_shownames_fontsize;
 128                 vector myPos = o - '0.5 0 0' * mySize.x - '0 1 0' * mySize.y;
 129                 // size scaling
 130                 mySize.x *= resize;
 131                 mySize.y *= resize;
 132                 myPos.x += 0.5 * (mySize.x / resize - mySize.x);
 133                 myPos.y += (mySize.y / resize - mySize.y);
 134                 // this is where the origin of the string
 135                 vector namepos = myPos;
 136                 float namewidth = mySize.x;
 137                 if (autocvar_hud_shownames_status && this.sameteam)
 138                 {
 139                         vector v = namepos + '0 1 0' * autocvar_hud_shownames_fontsize * resize;
 140                         vector s = eX * 0.5 * mySize.x + eY * resize * autocvar_hud_shownames_statusbar_height;
 141                         if (this.healthvalue > 0)
 142                         {
 143                                 HUD_Panel_DrawProgressBar(v, s, "nametag_statusbar",
 144                                         this.healthvalue / autocvar_hud_panel_healtharmor_maxhealth, false, 1, '1 0 0', a,
 145                                         DRAWFLAG_NORMAL);
 146                         }
 147                         if (this.armorvalue > 0)
 148                         {
 149                                 HUD_Panel_DrawProgressBar(v + eX * 0.5 * mySize.x, s, "nametag_statusbar",
 150                                         this.armorvalue / autocvar_hud_panel_healtharmor_maxarmor, false, 0, '0 1 0', a,
 151                                         DRAWFLAG_NORMAL);
 152                         }
 153                 }
 154                 string s = entcs_GetName(this.sv_entnum - 1);
 155                 if ((autocvar_hud_shownames_decolorize == 1 && teamplay)
 156                     || autocvar_hud_shownames_decolorize == 2) s = playername(s, entcs_GetTeam(this.sv_entnum - 1));
 157                 drawfontscale = '1 1 0' * resize;
 158                 s = textShortenToWidth(s, namewidth, '1 1 0' * autocvar_hud_shownames_fontsize, stringwidth_colors);
 159                 float width = stringwidth(s, true, '1 1 0' * autocvar_hud_shownames_fontsize);
 160                 if (width != namewidth) namepos.x += (namewidth - width) / 2;
 161                 drawcolorcodedstring(namepos, s, '1 1 0' * autocvar_hud_shownames_fontsize, a, DRAWFLAG_NORMAL);
 162                 drawfontscale = '1 1 0';
 163         }
 164 }
 165
 166 void Draw_ShowNames_All()
 167 {
 168         if (!autocvar_hud_shownames) return;
 169         LL_EACH(shownames_ent, true, LAMBDA(
 170                 entity entcs = entcs_receiver(i);
 171                 if (!entcs)
 172                 {
 173                         make_pure(it);
 174                         continue;
 175                 }
 176                 make_impure(it);
 177                 assert(entcs.think, eprint(entcs));
 178                 WITH(entity, self, entcs, entcs.think());
 179                 if (!entcs.has_origin) continue;
 180                 if (entcs.m_entcs_private)
 181                 {
 182                         it.healthvalue = entcs.healthvalue;
 183                         it.armorvalue = entcs.armorvalue;
 184                         it.sameteam = true;
 185                 }
 186                 else
 187                 {
 188                         it.healthvalue = 0;
 189                         it.armorvalue = 0;
 190                         it.sameteam = false;
 191                 }
 192                 bool dead = entcs_IsDead(i) || entcs_IsSpectating(i);
 193                 if (!it.csqcmodel_isdead) setorigin(it, entcs.origin);
 194                 it.csqcmodel_isdead = dead;
 195                 Draw_ShowNames(it);
 196         ));
 197 }